qcsrc/common/weapons/w_hook.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ HOOK,
   4 /* function */ w_hook,
   5 /* ammotype */ IT_CELLS|IT_FUEL,
   6 /* impulse  */ 0,
   7 /* flags    */ WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ 0,
   9 /* model    */ "hookgun",
  10 /* netname  */ "hook",
  11 /* fullname */ _("Grappling Hook")
  12 );
  13 #define HOOK_SETTINGS(weapon) \
  14         WEP_ADD_CVAR(weapon, MO_BOTH, animtime) \
  15         WEP_ADD_CVAR(weapon, MO_BOTH, ammo) \
  16         WEP_ADD_CVAR(weapon, MO_BOTH, refire) \
  17         WEP_ADD_CVAR(weapon, MO_PRI,  hooked_ammo) \
  18         WEP_ADD_CVAR(weapon, MO_PRI,  hooked_time_free) \
  19         WEP_ADD_CVAR(weapon, MO_PRI,  hooked_time_max) \
  20         WEP_ADD_CVAR(weapon, MO_SEC,  damage) \
  21         WEP_ADD_CVAR(weapon, MO_SEC,  duration) \
  22         WEP_ADD_CVAR(weapon, MO_SEC,  edgedamage) \
  23         WEP_ADD_CVAR(weapon, MO_SEC,  force) \
  24         WEP_ADD_CVAR(weapon, MO_SEC,  gravity) \
  25         WEP_ADD_CVAR(weapon, MO_SEC,  lifetime) \
  26         WEP_ADD_CVAR(weapon, MO_SEC,  power) \
  27         WEP_ADD_CVAR(weapon, MO_SEC,  radius) \
  28         WEP_ADD_CVAR(weapon, MO_SEC,  speed) \
  29         WEP_ADD_CVAR(weapon, MO_SEC,  health) \
  30         WEP_ADD_CVAR(weapon, MO_SEC,  damageforcescale) \
  31         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  32         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  33         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  34         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  35
  36 #ifdef SVQC
  37 HOOK_SETTINGS(hook)
  38
  39 .float dmg;
  40 .float dmg_edge;
  41 .float dmg_radius;
  42 .float dmg_force;
  43 .float dmg_power;
  44 .float dmg_duration;
  45 .float dmg_last;
  46 .float hook_refire;
  47 .float hook_time_hooked;
  48 .float hook_time_fueldecrease;
  49 #endif
  50 #else
  51 #ifdef SVQC
  52
  53 void spawnfunc_weapon_hook()
  54 {
  55         if(g_grappling_hook) // offhand hook
  56         {
  57                 startitem_failed = TRUE;
  58                 remove(self);
  59                 return;
  60         }
  61         weapon_defaultspawnfunc(WEP_HOOK);
  62 }
  63
  64 void W_Hook_ExplodeThink (void)
  65 {
  66         float dt, dmg_remaining_next, f;
  67
  68         dt = time - self.teleport_time;
  69         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  70
  71         f = self.dmg_last - dmg_remaining_next;
  72         self.dmg_last = dmg_remaining_next;
  73
  74         RadiusDamage (self, self.realowner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.realowner, world, self.dmg_force * f, self.projectiledeathtype, world);
  75         self.projectiledeathtype |= HITTYPE_BOUNCE;
  76         //RadiusDamage (self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, world, self.dmg_force * f, self.projectiledeathtype, world);
  77
  78         if(dt < self.dmg_duration)
  79                 self.nextthink = time + 0.05; // soon
  80         else
  81                 remove(self);
  82 }
  83
  84 void W_Hook_Explode2 (void)
  85 {
  86         self.event_damage = func_null;
  87         self.touch = func_null;
  88         self.effects |= EF_NODRAW;
  89
  90         self.think = W_Hook_ExplodeThink;
  91         self.nextthink = time;
  92         self.dmg = WEP_CVAR_SEC(hook, damage);
  93         self.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
  94         self.dmg_radius = WEP_CVAR_SEC(hook, radius);
  95         self.dmg_force = WEP_CVAR_SEC(hook, force);
  96         self.dmg_power = WEP_CVAR_SEC(hook, power);
  97         self.dmg_duration = WEP_CVAR_SEC(hook, duration);
  98         self.teleport_time = time;
  99         self.dmg_last = 1;
 100         self.movetype = MOVETYPE_NONE;
 101 }
 102
 103 void W_Hook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 104 {
 105         if (self.health <= 0)
 106                 return;
 107
 108         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 109                 return; // g_projectiles_damage says to halt
 110
 111         self.health = self.health - damage;
 112
 113         if (self.health <= 0)
 114                 W_PrepareExplosionByDamage(self.realowner, W_Hook_Explode2);
 115 }
 116
 117 void W_Hook_Touch2 (void)
 118 {
 119         PROJECTILE_TOUCH;
 120         self.use();
 121 }
 122
 123 void W_Hook_Attack2()
 124 {
 125         entity gren;
 126
 127         W_DecreaseAmmo(ammo_cells, WEP_CVAR_SEC(hook, ammo), FALSE);
 128         W_SetupShot (self, FALSE, 4, "weapons/hookbomb_fire.wav", CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 129
 130         gren = spawn ();
 131         gren.owner = gren.realowner = self;
 132         gren.classname = "hookbomb";
 133         gren.bot_dodge = TRUE;
 134         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 135         gren.movetype = MOVETYPE_TOSS;
 136         PROJECTILE_MAKETRIGGER(gren);
 137         gren.projectiledeathtype = WEP_HOOK | HITTYPE_SECONDARY;
 138         setorigin(gren, w_shotorg);
 139         setsize(gren, '0 0 0', '0 0 0');
 140
 141         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 142         gren.think = adaptor_think2use_hittype_splash;
 143         gren.use = W_Hook_Explode2;
 144         gren.touch = W_Hook_Touch2;
 145
 146         gren.takedamage = DAMAGE_YES;
 147         gren.health = WEP_CVAR_SEC(hook, health);
 148         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 149         gren.event_damage = W_Hook_Damage;
 150         gren.damagedbycontents = TRUE;
 151         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 152
 153         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 154         if(autocvar_g_projectiles_newton_style)
 155                 gren.velocity = gren.velocity + self.velocity;
 156
 157         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 158         //W_SetupProjectileVelocity(gren); // just falling down!
 159
 160         gren.angles = '0 0 0';
 161         gren.flags = FL_PROJECTILE;
 162
 163         CSQCProjectile(gren, TRUE, PROJECTILE_HOOKBOMB, TRUE);
 164
 165         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 166 }
 167
 168 float w_hook(float req)
 169 {
 170         float hooked_time_max, hooked_fuel;
 171
 172         switch(req)
 173         {
 174                 case WR_AIM:
 175                 {
 176                         // no bot AI for hook (yet?)
 177                         return TRUE;
 178                 }
 179                 case WR_THINK:
 180                 {
 181                         if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 182                         {
 183                                 if(!self.hook)
 184                                 if not(self.hook_state & HOOK_WAITING_FOR_RELEASE)
 185                                 if not(self.hook_state & HOOK_FIRING)
 186                                 if (time > self.hook_refire)
 187                                 if (weapon_prepareattack(0, -1))
 188                                 {
 189                                         W_DecreaseAmmo(ammo_fuel, WEP_CVAR_PRI(hook, ammo), FALSE);
 190                                         self.hook_state |= HOOK_FIRING;
 191                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 192                                 }
 193                         }
 194
 195                         if (self.BUTTON_ATCK2)
 196                         {
 197                                 if (weapon_prepareattack(1, WEP_CVAR_SEC(hook, refire)))
 198                                 {
 199                                         W_Hook_Attack2();
 200                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 201                                 }
 202                         }
 203
 204                         if(self.hook)
 205                         {
 206                                 // if hooked, no bombs, and increase the timer
 207                                 self.hook_refire = max(self.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor());
 208
 209                                 // hook also inhibits health regeneration, but only for 1 second
 210                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 211                                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 212                         }
 213
 214                         if(self.hook && self.hook.state == 1)
 215                         {
 216                                 hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 217                                 if (hooked_time_max > 0)
 218                                 {
 219                                         if ( time > self.hook_time_hooked + hooked_time_max )
 220                                                 self.hook_state |= HOOK_REMOVING;
 221                                 }
 222
 223                                 hooked_fuel = WEP_CVAR_PRI(hook, hooked_ammo);
 224                                 if (hooked_fuel > 0)
 225                                 {
 226                                         if ( time > self.hook_time_fueldecrease )
 227                                         {
 228                                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 229                                                 {
 230                                                         if ( self.ammo_fuel >= (time - self.hook_time_fueldecrease) * hooked_fuel )
 231                                                         {
 232                                                                 W_DecreaseAmmo(ammo_fuel, (time - self.hook_time_fueldecrease) * hooked_fuel, FALSE);
 233                                                                 self.hook_time_fueldecrease = time;
 234                                                                 // decrease next frame again
 235                                                         }
 236                                                         else
 237                                                         {
 238                                                                 self.ammo_fuel = 0;
 239                                                                 self.hook_state |= HOOK_REMOVING;
 240                                                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 241                                                         }
 242                                                 }
 243                                         }
 244                                 }
 245                         }
 246                         else
 247                         {
 248                                 self.hook_time_hooked = time;
 249                                 self.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 250                         }
 251
 252                         if (self.BUTTON_CROUCH)
 253                         {
 254                                 self.hook_state &~= HOOK_PULLING;
 255                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 256                                         self.hook_state &~= HOOK_RELEASING;
 257                                 else
 258                                         self.hook_state |= HOOK_RELEASING;
 259                         }
 260                         else
 261                         {
 262                                 self.hook_state |= HOOK_PULLING;
 263                                 self.hook_state &~= HOOK_RELEASING;
 264
 265                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 266                                 {
 267                                         // already fired
 268                                         if(self.hook)
 269                                                 self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 270                                 }
 271                                 else
 272                                 {
 273                                         self.hook_state |= HOOK_REMOVING;
 274                                         self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 275                                 }
 276                         }
 277
 278                         return TRUE;
 279                 }
 280                 case WR_INIT:
 281                 {
 282                         precache_model ("models/weapons/g_hookgun.md3");
 283                         precache_model ("models/weapons/v_hookgun.md3");
 284                         precache_model ("models/weapons/h_hookgun.iqm");
 285                         precache_sound ("weapons/hook_impact.wav"); // done by g_hook.qc
 286                         precache_sound ("weapons/hook_fire.wav");
 287                         precache_sound ("weapons/hookbomb_fire.wav");
 288                         #define WEP_ADD_CVAR(weapon,mode,name) /*nothing*/
 289                         #define WEP_ADD_PROP(weapon,prop,name) WEP_SET_PROP(WEP_HOOK,weapon,prop,name)
 290                         HOOK_SETTINGS(hook)
 291                         #undef WEP_ADD_CVAR
 292                         #undef WEP_ADD_PROP
 293                         return TRUE;
 294                 }
 295                 case WR_SETUP:
 296                 {
 297                         weapon_setup(WEP_HOOK);
 298                         self.current_ammo = ammo_fuel;
 299                         self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 300                         return TRUE;
 301                 }
 302                 case WR_CHECKAMMO1:
 303                 {
 304                         if(self.hook)
 305                                 return self.ammo_fuel > 0;
 306                         else
 307                                 return self.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 308                 }
 309                 case WR_CHECKAMMO2:
 310                 {
 311                         return self.ammo_cells >= WEP_CVAR_SEC(hook, ammo);
 312                 }
 313                 case WR_RESETPLAYER:
 314                 {
 315                         self.hook_refire = time;
 316                         return TRUE;
 317                 }
 318                 case WR_SUICIDEMESSAGE:
 319                 {
 320                         return FALSE;
 321                 }
 322                 case WR_KILLMESSAGE:
 323                 {
 324                         return WEAPON_HOOK_MURDER;
 325                 }
 326         }
 327         return TRUE;
 328 }
 329 #endif
 330 #ifdef CSQC
 331 float w_hook(float req)
 332 {
 333         switch(req)
 334         {
 335                 case WR_IMPACTEFFECT:
 336                 {
 337                         vector org2;
 338                         org2 = w_org + w_backoff * 2;
 339                         pointparticles(particleeffectnum("hookbomb_explode"), org2, '0 0 0', 1);
 340                         if(!w_issilent)
 341                                 sound(self, CH_SHOTS, "weapons/hookbomb_impact.wav", VOL_BASE, ATTN_NORM);
 342
 343                         return TRUE;
 344                 }
 345                 case WR_INIT:
 346                 {
 347                         precache_sound("weapons/hookbomb_impact.wav");
 348                         return TRUE;
 349                 }
 350         }
 351         return TRUE;
 352 }
 353 #endif
 354 #endif