qcsrc/common/weapons/w_hook.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ HOOK,
   4 /* function  */ W_Hook,
   5 /* ammotype  */ ammo_fuel,
   6 /* impulse   */ 0,
   7 /* flags     */ WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ 0,
   9 /* color     */ '0 0.5 0',
  10 /* modelname */ "hookgun",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairhook 0.5",
  13 /* refname   */ "hook",
  14 /* wepname   */ _("Grappling Hook")
  15 );
  16
  17 #define HOOK_SETTINGS(w_cvar,w_prop) HOOK_SETTINGS_LIST(w_cvar, w_prop, HOOK, hook)
  18 #define HOOK_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  19         w_cvar(id, sn, BOTH, animtime) \
  20         w_cvar(id, sn, BOTH, refire) \
  21         w_cvar(id, sn, PRI,  ammo) \
  22         w_cvar(id, sn, PRI,  hooked_ammo) \
  23         w_cvar(id, sn, PRI,  hooked_time_free) \
  24         w_cvar(id, sn, PRI,  hooked_time_max) \
  25         w_cvar(id, sn, SEC,  damage) \
  26         w_cvar(id, sn, SEC,  duration) \
  27         w_cvar(id, sn, SEC,  edgedamage) \
  28         w_cvar(id, sn, SEC,  force) \
  29         w_cvar(id, sn, SEC,  gravity) \
  30         w_cvar(id, sn, SEC,  lifetime) \
  31         w_cvar(id, sn, SEC,  power) \
  32         w_cvar(id, sn, SEC,  radius) \
  33         w_cvar(id, sn, SEC,  speed) \
  34         w_cvar(id, sn, SEC,  health) \
  35         w_cvar(id, sn, SEC,  damageforcescale) \
  36         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  37         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  38         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  39         w_prop(id, sn, float,  weaponstart, weaponstart) \
  40         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  41
  42 #ifdef SVQC
  43 HOOK_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  44
  45 .float dmg;
  46 .float dmg_edge;
  47 .float dmg_radius;
  48 .float dmg_force;
  49 .float dmg_power;
  50 .float dmg_duration;
  51 .float dmg_last;
  52 .float hook_refire;
  53 .float hook_time_hooked;
  54 .float hook_time_fueldecrease;
  55 #endif
  56 #else
  57 #ifdef SVQC
  58
  59 void spawnfunc_weapon_hook()
  60 {
  61         if(g_grappling_hook) // offhand hook
  62         {
  63                 startitem_failed = TRUE;
  64                 remove(self);
  65                 return;
  66         }
  67         weapon_defaultspawnfunc(WEP_HOOK);
  68 }
  69
  70 void W_Hook_ExplodeThink (void)
  71 {
  72         float dt, dmg_remaining_next, f;
  73
  74         dt = time - self.teleport_time;
  75         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  76
  77         f = self.dmg_last - dmg_remaining_next;
  78         self.dmg_last = dmg_remaining_next;
  79
  80         RadiusDamage (self, self.realowner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.realowner, world, self.dmg_force * f, self.projectiledeathtype, world);
  81         self.projectiledeathtype |= HITTYPE_BOUNCE;
  82         //RadiusDamage (self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, world, self.dmg_force * f, self.projectiledeathtype, world);
  83
  84         if(dt < self.dmg_duration)
  85                 self.nextthink = time + 0.05; // soon
  86         else
  87                 remove(self);
  88 }
  89
  90 void W_Hook_Explode2 (void)
  91 {
  92         self.event_damage = func_null;
  93         self.touch = func_null;
  94         self.effects |= EF_NODRAW;
  95
  96         self.think = W_Hook_ExplodeThink;
  97         self.nextthink = time;
  98         self.dmg = WEP_CVAR_SEC(hook, damage);
  99         self.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
 100         self.dmg_radius = WEP_CVAR_SEC(hook, radius);
 101         self.dmg_force = WEP_CVAR_SEC(hook, force);
 102         self.dmg_power = WEP_CVAR_SEC(hook, power);
 103         self.dmg_duration = WEP_CVAR_SEC(hook, duration);
 104         self.teleport_time = time;
 105         self.dmg_last = 1;
 106         self.movetype = MOVETYPE_NONE;
 107 }
 108
 109 void W_Hook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 110 {
 111         if (self.health <= 0)
 112                 return;
 113
 114         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 115                 return; // g_projectiles_damage says to halt
 116
 117         self.health = self.health - damage;
 118
 119         if (self.health <= 0)
 120                 W_PrepareExplosionByDamage(self.realowner, W_Hook_Explode2);
 121 }
 122
 123 void W_Hook_Touch2 (void)
 124 {
 125         PROJECTILE_TOUCH;
 126         self.use();
 127 }
 128
 129 void W_Hook_Attack2()
 130 {
 131         entity gren;
 132
 133         //W_DecreaseAmmo(WEP_CVAR_SEC(hook, ammo)); // WEAPONTODO: Figure out how to handle ammo with hook secondary (gravitybomb)
 134         W_SetupShot (self, FALSE, 4, "weapons/hookbomb_fire.wav", CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 135
 136         gren = spawn ();
 137         gren.owner = gren.realowner = self;
 138         gren.classname = "hookbomb";
 139         gren.bot_dodge = TRUE;
 140         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 141         gren.movetype = MOVETYPE_TOSS;
 142         PROJECTILE_MAKETRIGGER(gren);
 143         gren.projectiledeathtype = WEP_HOOK | HITTYPE_SECONDARY;
 144         setorigin(gren, w_shotorg);
 145         setsize(gren, '0 0 0', '0 0 0');
 146
 147         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 148         gren.think = adaptor_think2use_hittype_splash;
 149         gren.use = W_Hook_Explode2;
 150         gren.touch = W_Hook_Touch2;
 151
 152         gren.takedamage = DAMAGE_YES;
 153         gren.health = WEP_CVAR_SEC(hook, health);
 154         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 155         gren.event_damage = W_Hook_Damage;
 156         gren.damagedbycontents = TRUE;
 157         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 158
 159         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 160         if(autocvar_g_projectiles_newton_style)
 161                 gren.velocity = gren.velocity + self.velocity;
 162
 163         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 164         //W_SetupProjVelocity_Basic(gren); // just falling down!
 165
 166         gren.angles = '0 0 0';
 167         gren.flags = FL_PROJECTILE;
 168
 169         CSQCProjectile(gren, TRUE, PROJECTILE_HOOKBOMB, TRUE);
 170
 171         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 172 }
 173
 174 float W_Hook(float req)
 175 {
 176         float hooked_time_max, hooked_fuel;
 177
 178         switch(req)
 179         {
 180                 case WR_AIM:
 181                 {
 182                         // no bot AI for hook (yet?)
 183                         return TRUE;
 184                 }
 185                 case WR_THINK:
 186                 {
 187                         if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 188                         {
 189                                 if(!self.hook)
 190                                 if(!(self.hook_state & HOOK_WAITING_FOR_RELEASE))
 191                                 if(!(self.hook_state & HOOK_FIRING))
 192                                 if (time > self.hook_refire)
 193                                 if (weapon_prepareattack(0, -1))
 194                                 {
 195                                         W_DecreaseAmmo(WEP_CVAR_PRI(hook, ammo));
 196                                         self.hook_state |= HOOK_FIRING;
 197                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 198                                 }
 199                         }
 200
 201                         if (self.BUTTON_ATCK2)
 202                         {
 203                                 if (weapon_prepareattack(1, WEP_CVAR_SEC(hook, refire)))
 204                                 {
 205                                         W_Hook_Attack2();
 206                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 207                                 }
 208                         }
 209
 210                         if(self.hook)
 211                         {
 212                                 // if hooked, no bombs, and increase the timer
 213                                 self.hook_refire = max(self.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor());
 214
 215                                 // hook also inhibits health regeneration, but only for 1 second
 216                                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 217                                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 218                         }
 219
 220                         if(self.hook && self.hook.state == 1)
 221                         {
 222                                 hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 223                                 if (hooked_time_max > 0)
 224                                 {
 225                                         if ( time > self.hook_time_hooked + hooked_time_max )
 226                                                 self.hook_state |= HOOK_REMOVING;
 227                                 }
 228
 229                                 hooked_fuel = WEP_CVAR_PRI(hook, hooked_ammo);
 230                                 if (hooked_fuel > 0)
 231                                 {
 232                                         if ( time > self.hook_time_fueldecrease )
 233                                         {
 234                                                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 235                                                 {
 236                                                         if ( self.ammo_fuel >= (time - self.hook_time_fueldecrease) * hooked_fuel )
 237                                                         {
 238                                                                 W_DecreaseAmmo((time - self.hook_time_fueldecrease) * hooked_fuel);
 239                                                                 self.hook_time_fueldecrease = time;
 240                                                                 // decrease next frame again
 241                                                         }
 242                                                         else
 243                                                         {
 244                                                                 self.ammo_fuel = 0;
 245                                                                 self.hook_state |= HOOK_REMOVING;
 246                                                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 247                                                         }
 248                                                 }
 249                                         }
 250                                 }
 251                         }
 252                         else
 253                         {
 254                                 self.hook_time_hooked = time;
 255                                 self.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 256                         }
 257
 258                         if (self.BUTTON_CROUCH)
 259                         {
 260                                 self.hook_state &= ~HOOK_PULLING;
 261                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 262                                         self.hook_state &= ~HOOK_RELEASING;
 263                                 else
 264                                         self.hook_state |= HOOK_RELEASING;
 265                         }
 266                         else
 267                         {
 268                                 self.hook_state |= HOOK_PULLING;
 269                                 self.hook_state &= ~HOOK_RELEASING;
 270
 271                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 272                                 {
 273                                         // already fired
 274                                         if(self.hook)
 275                                                 self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 276                                 }
 277                                 else
 278                                 {
 279                                         self.hook_state |= HOOK_REMOVING;
 280                                         self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 281                                 }
 282                         }
 283
 284                         return TRUE;
 285                 }
 286                 case WR_INIT:
 287                 {
 288                         precache_model ("models/weapons/g_hookgun.md3");
 289                         precache_model ("models/weapons/v_hookgun.md3");
 290                         precache_model ("models/weapons/h_hookgun.iqm");
 291                         precache_sound ("weapons/hook_impact.wav"); // done by g_hook.qc
 292                         precache_sound ("weapons/hook_fire.wav");
 293                         precache_sound ("weapons/hookbomb_fire.wav");
 294                         HOOK_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 295                         return TRUE;
 296                 }
 297                 case WR_SETUP:
 298                 {
 299                         self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 300                         return TRUE;
 301                 }
 302                 case WR_CHECKAMMO1:
 303                 {
 304                         if(self.hook)
 305                                 return self.ammo_fuel > 0;
 306                         else
 307                                 return self.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 308                 }
 309                 case WR_CHECKAMMO2:
 310                 {
 311                         // infinite ammo for now
 312                         return TRUE; // self.ammo_cells >= WEP_CVAR_SEC(hook, ammo); // WEAPONTODO: see above
 313                 }
 314                 case WR_CONFIG:
 315                 {
 316                         HOOK_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 317                         return TRUE;
 318                 }
 319                 case WR_RESETPLAYER:
 320                 {
 321                         self.hook_refire = time;
 322                         return TRUE;
 323                 }
 324                 case WR_SUICIDEMESSAGE:
 325                 {
 326                         return FALSE;
 327                 }
 328                 case WR_KILLMESSAGE:
 329                 {
 330                         return WEAPON_HOOK_MURDER;
 331                 }
 332         }
 333         return TRUE;
 334 }
 335 #endif
 336 #ifdef CSQC
 337 float W_Hook(float req)
 338 {
 339         switch(req)
 340         {
 341                 case WR_IMPACTEFFECT:
 342                 {
 343                         vector org2;
 344                         org2 = w_org + w_backoff * 2;
 345                         pointparticles(particleeffectnum("hookbomb_explode"), org2, '0 0 0', 1);
 346                         if(!w_issilent)
 347                                 sound(self, CH_SHOTS, "weapons/hookbomb_impact.wav", VOL_BASE, ATTN_NORM);
 348
 349                         return TRUE;
 350                 }
 351                 case WR_INIT:
 352                 {
 353                         precache_sound("weapons/hookbomb_impact.wav");
 354                         return TRUE;
 355                 }
 356                 case WR_ZOOMRETICLE:
 357                 {
 358                         // no weapon specific image for this weapon
 359                         return FALSE;
 360                 }
 361         }
 362         return TRUE;
 363 }
 364 #endif
 365 #endif