qcsrc/common/weapons/w_hook.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id */ HOOK,
   4 /* function */ w_hook,
   5 /* ammotype */ IT_CELLS|IT_FUEL,
   6 /* impulse  */ 0,
   7 /* flags    */ WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating   */ 0,
   9 /* model    */ "hookgun",
  10 /* netname  */ "hook",
  11 /* fullname */ _("Grappling Hook")
  12 );
  13
  14 #define HOOK_SETTINGS(weapon) \
  15         WEP_ADD_CVAR(weapon, MO_BOTH, animtime) \
  16         WEP_ADD_CVAR(weapon, MO_BOTH, ammo) \
  17         WEP_ADD_CVAR(weapon, MO_BOTH, refire) \
  18         WEP_ADD_CVAR(weapon, MO_PRI,  hooked_ammo) \
  19         WEP_ADD_CVAR(weapon, MO_PRI,  hooked_time_free) \
  20         WEP_ADD_CVAR(weapon, MO_PRI,  hooked_time_max) \
  21         WEP_ADD_CVAR(weapon, MO_SEC,  damage) \
  22         WEP_ADD_CVAR(weapon, MO_SEC,  duration) \
  23         WEP_ADD_CVAR(weapon, MO_SEC,  edgedamage) \
  24         WEP_ADD_CVAR(weapon, MO_SEC,  force) \
  25         WEP_ADD_CVAR(weapon, MO_SEC,  gravity) \
  26         WEP_ADD_CVAR(weapon, MO_SEC,  lifetime) \
  27         WEP_ADD_CVAR(weapon, MO_SEC,  power) \
  28         WEP_ADD_CVAR(weapon, MO_SEC,  radius) \
  29         WEP_ADD_CVAR(weapon, MO_SEC,  speed) \
  30         WEP_ADD_CVAR(weapon, MO_SEC,  health) \
  31         WEP_ADD_CVAR(weapon, MO_SEC,  damageforcescale) \
  32         WEP_ADD_PROP(weapon, reloading_ammo, reload_ammo) \
  33         WEP_ADD_PROP(weapon, reloading_time, reload_time) \
  34         WEP_ADD_PROP(weapon, switchdelay_raise, switchdelay_raise) \
  35         WEP_ADD_PROP(weapon, switchdelay_drop, switchdelay_drop)
  36
  37 #ifdef SVQC
  38 HOOK_SETTINGS(hook)
  39
  40 .float dmg;
  41 .float dmg_edge;
  42 .float dmg_radius;
  43 .float dmg_force;
  44 .float dmg_power;
  45 .float dmg_duration;
  46 .float dmg_last;
  47 .float hook_refire;
  48 .float hook_time_hooked;
  49 .float hook_time_fueldecrease;
  50 #endif
  51 #else
  52 #ifdef SVQC
  53
  54 void spawnfunc_weapon_hook()
  55 {
  56         if(g_grappling_hook) // offhand hook
  57         {
  58                 startitem_failed = TRUE;
  59                 remove(self);
  60                 return;
  61         }
  62         weapon_defaultspawnfunc(WEP_HOOK);
  63 }
  64
  65 void W_Hook_ExplodeThink (void)
  66 {
  67         float dt, dmg_remaining_next, f;
  68
  69         dt = time - self.teleport_time;
  70         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  71
  72         f = self.dmg_last - dmg_remaining_next;
  73         self.dmg_last = dmg_remaining_next;
  74
  75         RadiusDamage (self, self.realowner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.realowner, world, self.dmg_force * f, self.projectiledeathtype, world);
  76         self.projectiledeathtype |= HITTYPE_BOUNCE;
  77         //RadiusDamage (self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, world, self.dmg_force * f, self.projectiledeathtype, world);
  78
  79         if(dt < self.dmg_duration)
  80                 self.nextthink = time + 0.05; // soon
  81         else
  82                 remove(self);
  83 }
  84
  85 void W_Hook_Explode2 (void)
  86 {
  87         self.event_damage = func_null;
  88         self.touch = func_null;
  89         self.effects |= EF_NODRAW;
  90
  91         self.think = W_Hook_ExplodeThink;
  92         self.nextthink = time;
  93         self.dmg = WEP_CVAR_SEC(hook, damage);
  94         self.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
  95         self.dmg_radius = WEP_CVAR_SEC(hook, radius);
  96         self.dmg_force = WEP_CVAR_SEC(hook, force);
  97         self.dmg_power = WEP_CVAR_SEC(hook, power);
  98         self.dmg_duration = WEP_CVAR_SEC(hook, duration);
  99         self.teleport_time = time;
 100         self.dmg_last = 1;
 101         self.movetype = MOVETYPE_NONE;
 102 }
 103
 104 void W_Hook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 105 {
 106         if (self.health <= 0)
 107                 return;
 108
 109         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 110                 return; // g_projectiles_damage says to halt
 111
 112         self.health = self.health - damage;
 113
 114         if (self.health <= 0)
 115                 W_PrepareExplosionByDamage(self.realowner, W_Hook_Explode2);
 116 }
 117
 118 void W_Hook_Touch2 (void)
 119 {
 120         PROJECTILE_TOUCH;
 121         self.use();
 122 }
 123
 124 void W_Hook_Attack2()
 125 {
 126         entity gren;
 127
 128         W_DecreaseAmmo(ammo_cells, WEP_CVAR_SEC(hook, ammo), FALSE);
 129         W_SetupShot (self, FALSE, 4, "weapons/hookbomb_fire.wav", CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 130
 131         gren = spawn ();
 132         gren.owner = gren.realowner = self;
 133         gren.classname = "hookbomb";
 134         gren.bot_dodge = TRUE;
 135         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 136         gren.movetype = MOVETYPE_TOSS;
 137         PROJECTILE_MAKETRIGGER(gren);
 138         gren.projectiledeathtype = WEP_HOOK | HITTYPE_SECONDARY;
 139         setorigin(gren, w_shotorg);
 140         setsize(gren, '0 0 0', '0 0 0');
 141
 142         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 143         gren.think = adaptor_think2use_hittype_splash;
 144         gren.use = W_Hook_Explode2;
 145         gren.touch = W_Hook_Touch2;
 146
 147         gren.takedamage = DAMAGE_YES;
 148         gren.health = WEP_CVAR_SEC(hook, health);
 149         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 150         gren.event_damage = W_Hook_Damage;
 151         gren.damagedbycontents = TRUE;
 152         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 153
 154         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 155         if(autocvar_g_projectiles_newton_style)
 156                 gren.velocity = gren.velocity + self.velocity;
 157
 158         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 159         //W_SetupProjectileVelocity(gren); // just falling down!
 160
 161         gren.angles = '0 0 0';
 162         gren.flags = FL_PROJECTILE;
 163
 164         CSQCProjectile(gren, TRUE, PROJECTILE_HOOKBOMB, TRUE);
 165
 166         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 167 }
 168
 169 float w_hook(float req)
 170 {
 171         float hooked_time_max, hooked_fuel;
 172
 173         switch(req)
 174         {
 175                 case WR_AIM:
 176                 {
 177                         // no bot AI for hook (yet?)
 178                         return TRUE;
 179                 }
 180                 case WR_THINK:
 181                 {
 182                         if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 183                         {
 184                                 if(!self.hook)
 185                                 if not(self.hook_state & HOOK_WAITING_FOR_RELEASE)
 186                                 if not(self.hook_state & HOOK_FIRING)
 187                                 if (time > self.hook_refire)
 188                                 if (weapon_prepareattack(0, -1))
 189                                 {
 190                                         W_DecreaseAmmo(ammo_fuel, WEP_CVAR_PRI(hook, ammo), FALSE);
 191                                         self.hook_state |= HOOK_FIRING;
 192                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 193                                 }
 194                         }
 195
 196                         if (self.BUTTON_ATCK2)
 197                         {
 198                                 if (weapon_prepareattack(1, WEP_CVAR_SEC(hook, refire)))
 199                                 {
 200                                         W_Hook_Attack2();
 201                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 202                                 }
 203                         }
 204
 205                         if(self.hook)
 206                         {
 207                                 // if hooked, no bombs, and increase the timer
 208                                 self.hook_refire = max(self.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor());
 209
 210                                 // hook also inhibits health regeneration, but only for 1 second
 211                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 212                                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 213                         }
 214
 215                         if(self.hook && self.hook.state == 1)
 216                         {
 217                                 hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 218                                 if (hooked_time_max > 0)
 219                                 {
 220                                         if ( time > self.hook_time_hooked + hooked_time_max )
 221                                                 self.hook_state |= HOOK_REMOVING;
 222                                 }
 223
 224                                 hooked_fuel = WEP_CVAR_PRI(hook, hooked_ammo);
 225                                 if (hooked_fuel > 0)
 226                                 {
 227                                         if ( time > self.hook_time_fueldecrease )
 228                                         {
 229                                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 230                                                 {
 231                                                         if ( self.ammo_fuel >= (time - self.hook_time_fueldecrease) * hooked_fuel )
 232                                                         {
 233                                                                 W_DecreaseAmmo(ammo_fuel, (time - self.hook_time_fueldecrease) * hooked_fuel, FALSE);
 234                                                                 self.hook_time_fueldecrease = time;
 235                                                                 // decrease next frame again
 236                                                         }
 237                                                         else
 238                                                         {
 239                                                                 self.ammo_fuel = 0;
 240                                                                 self.hook_state |= HOOK_REMOVING;
 241                                                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 242                                                         }
 243                                                 }
 244                                         }
 245                                 }
 246                         }
 247                         else
 248                         {
 249                                 self.hook_time_hooked = time;
 250                                 self.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 251                         }
 252
 253                         if (self.BUTTON_CROUCH)
 254                         {
 255                                 self.hook_state &= ~HOOK_PULLING;
 256                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 257                                         self.hook_state &= ~HOOK_RELEASING;
 258                                 else
 259                                         self.hook_state |= HOOK_RELEASING;
 260                         }
 261                         else
 262                         {
 263                                 self.hook_state |= HOOK_PULLING;
 264                                 self.hook_state &= ~HOOK_RELEASING;
 265
 266                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 267                                 {
 268                                         // already fired
 269                                         if(self.hook)
 270                                                 self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 271                                 }
 272                                 else
 273                                 {
 274                                         self.hook_state |= HOOK_REMOVING;
 275                                         self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 276                                 }
 277                         }
 278
 279                         return TRUE;
 280                 }
 281                 case WR_INIT:
 282                 {
 283                         precache_model ("models/weapons/g_hookgun.md3");
 284                         precache_model ("models/weapons/v_hookgun.md3");
 285                         precache_model ("models/weapons/h_hookgun.iqm");
 286                         precache_sound ("weapons/hook_impact.wav"); // done by g_hook.qc
 287                         precache_sound ("weapons/hook_fire.wav");
 288                         precache_sound ("weapons/hookbomb_fire.wav");
 289                         WEP_SET_PROPS(HOOK_SETTINGS(hook), WEP_HOOK)
 290                         return TRUE;
 291                 }
 292                 case WR_SETUP:
 293                 {
 294                         self.current_ammo = ammo_fuel;
 295                         self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 296                         return TRUE;
 297                 }
 298                 case WR_CHECKAMMO1:
 299                 {
 300                         if(self.hook)
 301                                 return self.ammo_fuel > 0;
 302                         else
 303                                 return self.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 304                 }
 305                 case WR_CHECKAMMO2:
 306                 {
 307                         return self.ammo_cells >= WEP_CVAR_SEC(hook, ammo);
 308                 }
 309                 case WR_CONFIG:
 310                 {
 311                         WEP_CONFIG_SETTINGS(HOOK_SETTINGS(hook))
 312                         return TRUE;
 313                 }
 314                 case WR_RESETPLAYER:
 315                 {
 316                         self.hook_refire = time;
 317                         return TRUE;
 318                 }
 319                 case WR_SUICIDEMESSAGE:
 320                 {
 321                         return FALSE;
 322                 }
 323                 case WR_KILLMESSAGE:
 324                 {
 325                         return WEAPON_HOOK_MURDER;
 326                 }
 327         }
 328         return TRUE;
 329 }
 330 #endif
 331 #ifdef CSQC
 332 float w_hook(float req)
 333 {
 334         switch(req)
 335         {
 336                 case WR_IMPACTEFFECT:
 337                 {
 338                         vector org2;
 339                         org2 = w_org + w_backoff * 2;
 340                         pointparticles(particleeffectnum("hookbomb_explode"), org2, '0 0 0', 1);
 341                         if(!w_issilent)
 342                                 sound(self, CH_SHOTS, "weapons/hookbomb_impact.wav", VOL_BASE, ATTN_NORM);
 343
 344                         return TRUE;
 345                 }
 346                 case WR_INIT:
 347                 {
 348                         precache_sound("weapons/hookbomb_impact.wav");
 349                         return TRUE;
 350                 }
 351         }
 352         return TRUE;
 353 }
 354 #endif
 355 #endif