qcsrc/common/weapons/w_hook.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ HOOK,
   4 /* function  */ W_Hook,
   5 /* ammotype  */ ammo_fuel,
   6 /* impulse   */ 0,
   7 /* flags     */ WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ 0,
   9 /* color     */ '0 0.5 0',
  10 /* model     */ "hookgun",
  11 /* crosshair */ "gfx/crosshairhook 0.5",
  12 /* refname   */ "hook",
  13 /* wepname   */ _("Grappling Hook")
  14 );
  15
  16 #define HOOK_SETTINGS(w_cvar,w_prop) HOOK_SETTINGS_LIST(w_cvar, w_prop, HOOK, hook)
  17 #define HOOK_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  18         w_cvar(id, sn, BOTH, animtime) \
  19         w_cvar(id, sn, BOTH, refire) \
  20         w_cvar(id, sn, PRI,  ammo) \
  21         w_cvar(id, sn, PRI,  hooked_ammo) \
  22         w_cvar(id, sn, PRI,  hooked_time_free) \
  23         w_cvar(id, sn, PRI,  hooked_time_max) \
  24         w_cvar(id, sn, SEC,  damage) \
  25         w_cvar(id, sn, SEC,  duration) \
  26         w_cvar(id, sn, SEC,  edgedamage) \
  27         w_cvar(id, sn, SEC,  force) \
  28         w_cvar(id, sn, SEC,  gravity) \
  29         w_cvar(id, sn, SEC,  lifetime) \
  30         w_cvar(id, sn, SEC,  power) \
  31         w_cvar(id, sn, SEC,  radius) \
  32         w_cvar(id, sn, SEC,  speed) \
  33         w_cvar(id, sn, SEC,  health) \
  34         w_cvar(id, sn, SEC,  damageforcescale) \
  35         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  36         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  37         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  38         w_prop(id, sn, float,  weaponstart, weaponstart) \
  39         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  40
  41 #ifdef SVQC
  42 HOOK_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  43
  44 .float dmg;
  45 .float dmg_edge;
  46 .float dmg_radius;
  47 .float dmg_force;
  48 .float dmg_power;
  49 .float dmg_duration;
  50 .float dmg_last;
  51 .float hook_refire;
  52 .float hook_time_hooked;
  53 .float hook_time_fueldecrease;
  54 #endif
  55 #else
  56 #ifdef SVQC
  57
  58 void spawnfunc_weapon_hook()
  59 {
  60         if(g_grappling_hook) // offhand hook
  61         {
  62                 startitem_failed = TRUE;
  63                 remove(self);
  64                 return;
  65         }
  66         weapon_defaultspawnfunc(WEP_HOOK);
  67 }
  68
  69 void W_Hook_ExplodeThink (void)
  70 {
  71         float dt, dmg_remaining_next, f;
  72
  73         dt = time - self.teleport_time;
  74         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  75
  76         f = self.dmg_last - dmg_remaining_next;
  77         self.dmg_last = dmg_remaining_next;
  78
  79         RadiusDamage (self, self.realowner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.realowner, world, self.dmg_force * f, self.projectiledeathtype, world);
  80         self.projectiledeathtype |= HITTYPE_BOUNCE;
  81         //RadiusDamage (self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, world, self.dmg_force * f, self.projectiledeathtype, world);
  82
  83         if(dt < self.dmg_duration)
  84                 self.nextthink = time + 0.05; // soon
  85         else
  86                 remove(self);
  87 }
  88
  89 void W_Hook_Explode2 (void)
  90 {
  91         self.event_damage = func_null;
  92         self.touch = func_null;
  93         self.effects |= EF_NODRAW;
  94
  95         self.think = W_Hook_ExplodeThink;
  96         self.nextthink = time;
  97         self.dmg = WEP_CVAR_SEC(hook, damage);
  98         self.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
  99         self.dmg_radius = WEP_CVAR_SEC(hook, radius);
 100         self.dmg_force = WEP_CVAR_SEC(hook, force);
 101         self.dmg_power = WEP_CVAR_SEC(hook, power);
 102         self.dmg_duration = WEP_CVAR_SEC(hook, duration);
 103         self.teleport_time = time;
 104         self.dmg_last = 1;
 105         self.movetype = MOVETYPE_NONE;
 106 }
 107
 108 void W_Hook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 109 {
 110         if (self.health <= 0)
 111                 return;
 112
 113         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 114                 return; // g_projectiles_damage says to halt
 115
 116         self.health = self.health - damage;
 117
 118         if (self.health <= 0)
 119                 W_PrepareExplosionByDamage(self.realowner, W_Hook_Explode2);
 120 }
 121
 122 void W_Hook_Touch2 (void)
 123 {
 124         PROJECTILE_TOUCH;
 125         self.use();
 126 }
 127
 128 void W_Hook_Attack2()
 129 {
 130         entity gren;
 131
 132         //W_DecreaseAmmo(WEP_CVAR_SEC(hook, ammo)); // WEAPONTODO: Figure out how to handle ammo with hook secondary (gravitybomb)
 133         W_SetupShot (self, FALSE, 4, "weapons/hookbomb_fire.wav", CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 134
 135         gren = spawn ();
 136         gren.owner = gren.realowner = self;
 137         gren.classname = "hookbomb";
 138         gren.bot_dodge = TRUE;
 139         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 140         gren.movetype = MOVETYPE_TOSS;
 141         PROJECTILE_MAKETRIGGER(gren);
 142         gren.projectiledeathtype = WEP_HOOK | HITTYPE_SECONDARY;
 143         setorigin(gren, w_shotorg);
 144         setsize(gren, '0 0 0', '0 0 0');
 145
 146         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 147         gren.think = adaptor_think2use_hittype_splash;
 148         gren.use = W_Hook_Explode2;
 149         gren.touch = W_Hook_Touch2;
 150
 151         gren.takedamage = DAMAGE_YES;
 152         gren.health = WEP_CVAR_SEC(hook, health);
 153         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 154         gren.event_damage = W_Hook_Damage;
 155         gren.damagedbycontents = TRUE;
 156         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 157
 158         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 159         if(autocvar_g_projectiles_newton_style)
 160                 gren.velocity = gren.velocity + self.velocity;
 161
 162         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 163         //W_SetupProjVelocity_Basic(gren); // just falling down!
 164
 165         gren.angles = '0 0 0';
 166         gren.flags = FL_PROJECTILE;
 167
 168         CSQCProjectile(gren, TRUE, PROJECTILE_HOOKBOMB, TRUE);
 169
 170         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 171 }
 172
 173 float W_Hook(float req)
 174 {
 175         float hooked_time_max, hooked_fuel;
 176
 177         switch(req)
 178         {
 179                 case WR_AIM:
 180                 {
 181                         // no bot AI for hook (yet?)
 182                         return TRUE;
 183                 }
 184                 case WR_THINK:
 185                 {
 186                         if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 187                         {
 188                                 if(!self.hook)
 189                                 if(!(self.hook_state & HOOK_WAITING_FOR_RELEASE))
 190                                 if(!(self.hook_state & HOOK_FIRING))
 191                                 if (time > self.hook_refire)
 192                                 if (weapon_prepareattack(0, -1))
 193                                 {
 194                                         W_DecreaseAmmo(WEP_CVAR_PRI(hook, ammo));
 195                                         self.hook_state |= HOOK_FIRING;
 196                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 197                                 }
 198                         }
 199
 200                         if (self.BUTTON_ATCK2)
 201                         {
 202                                 if (weapon_prepareattack(1, WEP_CVAR_SEC(hook, refire)))
 203                                 {
 204                                         W_Hook_Attack2();
 205                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 206                                 }
 207                         }
 208
 209                         if(self.hook)
 210                         {
 211                                 // if hooked, no bombs, and increase the timer
 212                                 self.hook_refire = max(self.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor());
 213
 214                                 // hook also inhibits health regeneration, but only for 1 second
 215                                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 216                                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 217                         }
 218
 219                         if(self.hook && self.hook.state == 1)
 220                         {
 221                                 hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 222                                 if (hooked_time_max > 0)
 223                                 {
 224                                         if ( time > self.hook_time_hooked + hooked_time_max )
 225                                                 self.hook_state |= HOOK_REMOVING;
 226                                 }
 227
 228                                 hooked_fuel = WEP_CVAR_PRI(hook, hooked_ammo);
 229                                 if (hooked_fuel > 0)
 230                                 {
 231                                         if ( time > self.hook_time_fueldecrease )
 232                                         {
 233                                                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 234                                                 {
 235                                                         if ( self.ammo_fuel >= (time - self.hook_time_fueldecrease) * hooked_fuel )
 236                                                         {
 237                                                                 W_DecreaseAmmo((time - self.hook_time_fueldecrease) * hooked_fuel);
 238                                                                 self.hook_time_fueldecrease = time;
 239                                                                 // decrease next frame again
 240                                                         }
 241                                                         else
 242                                                         {
 243                                                                 self.ammo_fuel = 0;
 244                                                                 self.hook_state |= HOOK_REMOVING;
 245                                                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 246                                                         }
 247                                                 }
 248                                         }
 249                                 }
 250                         }
 251                         else
 252                         {
 253                                 self.hook_time_hooked = time;
 254                                 self.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 255                         }
 256
 257                         if (self.BUTTON_CROUCH)
 258                         {
 259                                 self.hook_state &= ~HOOK_PULLING;
 260                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 261                                         self.hook_state &= ~HOOK_RELEASING;
 262                                 else
 263                                         self.hook_state |= HOOK_RELEASING;
 264                         }
 265                         else
 266                         {
 267                                 self.hook_state |= HOOK_PULLING;
 268                                 self.hook_state &= ~HOOK_RELEASING;
 269
 270                                 if (self.BUTTON_ATCK || (!(self.items & IT_JETPACK) && self.BUTTON_HOOK))
 271                                 {
 272                                         // already fired
 273                                         if(self.hook)
 274                                                 self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 275                                 }
 276                                 else
 277                                 {
 278                                         self.hook_state |= HOOK_REMOVING;
 279                                         self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 280                                 }
 281                         }
 282
 283                         return TRUE;
 284                 }
 285                 case WR_INIT:
 286                 {
 287                         precache_model ("models/weapons/g_hookgun.md3");
 288                         precache_model ("models/weapons/v_hookgun.md3");
 289                         precache_model ("models/weapons/h_hookgun.iqm");
 290                         precache_sound ("weapons/hook_impact.wav"); // done by g_hook.qc
 291                         precache_sound ("weapons/hook_fire.wav");
 292                         precache_sound ("weapons/hookbomb_fire.wav");
 293                         HOOK_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 294                         return TRUE;
 295                 }
 296                 case WR_SETUP:
 297                 {
 298                         self.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 299                         return TRUE;
 300                 }
 301                 case WR_CHECKAMMO1:
 302                 {
 303                         if(self.hook)
 304                                 return self.ammo_fuel > 0;
 305                         else
 306                                 return self.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 307                 }
 308                 case WR_CHECKAMMO2:
 309                 {
 310                         // infinite ammo for now
 311                         return TRUE; // self.ammo_cells >= WEP_CVAR_SEC(hook, ammo); // WEAPONTODO: see above
 312                 }
 313                 case WR_CONFIG:
 314                 {
 315                         HOOK_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 316                         return TRUE;
 317                 }
 318                 case WR_RESETPLAYER:
 319                 {
 320                         self.hook_refire = time;
 321                         return TRUE;
 322                 }
 323                 case WR_SUICIDEMESSAGE:
 324                 {
 325                         return FALSE;
 326                 }
 327                 case WR_KILLMESSAGE:
 328                 {
 329                         return WEAPON_HOOK_MURDER;
 330                 }
 331         }
 332         return TRUE;
 333 }
 334 #endif
 335 #ifdef CSQC
 336 float W_Hook(float req)
 337 {
 338         switch(req)
 339         {
 340                 case WR_IMPACTEFFECT:
 341                 {
 342                         vector org2;
 343                         org2 = w_org + w_backoff * 2;
 344                         pointparticles(particleeffectnum("hookbomb_explode"), org2, '0 0 0', 1);
 345                         if(!w_issilent)
 346                                 sound(self, CH_SHOTS, "weapons/hookbomb_impact.wav", VOL_BASE, ATTN_NORM);
 347
 348                         return TRUE;
 349                 }
 350                 case WR_INIT:
 351                 {
 352                         precache_sound("weapons/hookbomb_impact.wav");
 353                         return TRUE;
 354                 }
 355                 case WR_ZOOMRETICLE:
 356                 {
 357                         // no weapon specific image for this weapon
 358                         return FALSE;
 359                 }
 360         }
 361         return TRUE;
 362 }
 363 #endif
 364 #endif