qcsrc/common/weapons/w_blaster.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ BLASTER,
   4 /* function  */ W_Blaster,
   5 /* ammotype  */ ammo_none,
   6 /* impulse   */ 1,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ 0,
   9 /* color     */ '1 0.5 0.5',
  10 /* modelname */ "laser",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairlaser 0.4",
  13 /* refname   */ "laser",
  14 /* wepname   */ _("Blaster")
  15 );
  16
  17 #define BLASTER_SETTINGS(w_cvar,w_prop) BLASTER_SETTINGS_LIST(w_cvar, w_prop, BLASTER, blaster)
  18 #define BLASTER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  19         w_cvar(id, sn, BOTH, animtime) \
  20         w_cvar(id, sn, BOTH, damage) \
  21         w_cvar(id, sn, BOTH, delay) \
  22         w_cvar(id, sn, BOTH, edgedamage) \
  23         w_cvar(id, sn, BOTH, force) \
  24         w_cvar(id, sn, BOTH, lifetime) \
  25         w_cvar(id, sn, BOTH, radius) \
  26         w_cvar(id, sn, BOTH, refire) \
  27         w_cvar(id, sn, BOTH, shotangle) \
  28         w_cvar(id, sn, BOTH, speed) \
  29         w_cvar(id, sn, BOTH, spread) \
  30         w_cvar(id, sn, NONE, secondary) \
  31         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  32         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  33         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  34         w_prop(id, sn, float,  weaponstart, weaponstart) \
  35         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  36
  37 #ifdef SVQC
  38 BLASTER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  39 .float blaster_damage;
  40 .float blaster_edgedamage;
  41 .float blaster_radius;
  42 .float blaster_force;
  43 .float blaster_lifetime;
  44 #endif
  45 #else
  46 #ifdef SVQC
  47 void spawnfunc_weapon_blaster() { weapon_defaultspawnfunc(WEP_BLASTER); }
  48 void spawnfunc_weapon_laser() { spawnfunc_weapon_blaster(); }
  49
  50 void W_Blaster_Touch()
  51 {
  52         PROJECTILE_TOUCH;
  53
  54         self.event_damage = func_null;
  55
  56         RadiusDamage(
  57                 self,
  58                 self.realowner,
  59                 self.blaster_damage,
  60                 self.blaster_edgedamage,
  61                 self.blaster_radius,
  62                 world,
  63                 world,
  64                 self.blaster_force,
  65                 self.projectiledeathtype,
  66                 other
  67         );
  68
  69         remove(self);
  70 }
  71
  72 void W_Blaster_Think()
  73 {
  74         self.movetype = MOVETYPE_FLY;
  75         self.think = SUB_Remove;
  76         self.nextthink = time + self.blaster_lifetime;
  77         CSQCProjectile(self, TRUE, PROJECTILE_BLASTER, TRUE);
  78 }
  79
  80 void W_Blaster_Attack(
  81         float atk_shotangle,
  82         float atk_damage,
  83         float atk_edgedamage,
  84         float atk_radius,
  85         float atk_force,
  86         float atk_speed,
  87         float atk_spread,
  88         float atk_delay,
  89         float atk_lifetime)
  90 {
  91         vector s_forward = v_forward * cos(atk_shotangle * DEG2RAD) + v_up * sin(atk_shotangle * DEG2RAD);
  92
  93         W_SetupShot_Dir(self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CH_WEAPON_B, atk_damage);
  94         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  95
  96         entity missile = spawn();
  97         missile.owner = missile.realowner = self;
  98         missile.classname = "blasterbolt";
  99         missile.bot_dodge = TRUE;
 100         missile.bot_dodgerating = atk_damage;
 101         PROJECTILE_MAKETRIGGER(missile);
 102
 103         missile.blaster_damage = atk_damage;
 104         missile.blaster_edgedamage = atk_edgedamage;
 105         missile.blaster_radius = atk_radius;
 106         missile.blaster_force = atk_force;
 107         missile.blaster_lifetime = atk_lifetime;
 108
 109         setorigin(missile, w_shotorg);
 110         setsize(missile, '0 0 0', '0 0 0');
 111
 112         W_SetupProjVelocity_Explicit(
 113                 missile,
 114                 w_shotdir,
 115                 v_up,
 116                 atk_speed,
 117                 0,
 118                 0,
 119                 atk_spread,
 120                 FALSE
 121         );
 122
 123         missile.angles = vectoangles(missile.velocity);
 124
 125         //missile.glow_color = 250; // 244, 250
 126         //missile.glow_size = 120;
 127
 128         missile.touch = W_Blaster_Touch;
 129         missile.flags = FL_PROJECTILE;
 130         missile.missile_flags = MIF_SPLASH;
 131         missile.projectiledeathtype = WEP_BLASTER;
 132         missile.think = W_Blaster_Think;
 133         missile.nextthink = time + atk_delay;
 134
 135         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 136
 137         if(time >= missile.nextthink)
 138         {
 139                 entity oldself;
 140                 oldself = self;
 141                 self = missile;
 142                 self.think();
 143                 self = oldself;
 144         }
 145 }
 146 float W_Blaster(float request)
 147 {
 148         switch(request)
 149         {
 150                 case WR_AIM:
 151                 {
 152                         if(WEP_CVAR(blaster, secondary))
 153                         {
 154                                 if((random() * (WEP_CVAR_PRI(blaster, damage) + WEP_CVAR_SEC(blaster, damage))) > WEP_CVAR_PRI(blaster, damage))
 155                                         { self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(blaster, speed), 0, WEP_CVAR_SEC(blaster, lifetime), FALSE); }
 156                                 else
 157                                         { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 158                         }
 159                         else
 160                                 { self.BUTTON_ATCK = bot_aim(WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), FALSE); }
 161
 162                         return TRUE;
 163                 }
 164
 165                 case WR_THINK:
 166                 {
 167                         if(self.BUTTON_ATCK)
 168                         {
 169                                 if(weapon_prepareattack(0, WEP_CVAR_PRI(blaster, refire)))
 170                                 {
 171                                         W_Blaster_Attack(
 172                                                 WEP_CVAR_PRI(blaster, shotangle),
 173                                                 WEP_CVAR_PRI(blaster, damage),
 174                                                 WEP_CVAR_PRI(blaster, edgedamage),
 175                                                 WEP_CVAR_PRI(blaster, radius),
 176                                                 WEP_CVAR_PRI(blaster, force),
 177                                                 WEP_CVAR_PRI(blaster, speed),
 178                                                 WEP_CVAR_PRI(blaster, spread),
 179                                                 WEP_CVAR_PRI(blaster, delay),
 180                                                 WEP_CVAR_PRI(blaster, lifetime)
 181                                         );
 182                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR_PRI(blaster, animtime), w_ready);
 183                                 }
 184                         }
 185                         else if(self.BUTTON_ATCK2)
 186                         {
 187                                 switch(WEP_CVAR(blaster, secondary))
 188                                 {
 189                                         case 0: // switch to last used weapon
 190                                         {
 191                                                 if(self.switchweapon == WEP_BLASTER) // don't do this if already switching
 192                                                         W_LastWeapon();
 193                                                 break;
 194                                         }
 195
 196                                         case 1: // normal projectile secondary
 197                                         {
 198                                                 if(weapon_prepareattack(1, WEP_CVAR_SEC(blaster, refire)))
 199                                                 {
 200                                                         W_Blaster_Attack(
 201                                                                 WEP_CVAR_SEC(blaster, shotangle),
 202                                                                 WEP_CVAR_SEC(blaster, damage),
 203                                                                 WEP_CVAR_SEC(blaster, edgedamage),
 204                                                                 WEP_CVAR_SEC(blaster, radius),
 205                                                                 WEP_CVAR_SEC(blaster, force),
 206                                                                 WEP_CVAR_SEC(blaster, speed),
 207                                                                 WEP_CVAR_SEC(blaster, spread),
 208                                                                 WEP_CVAR_SEC(blaster, delay),
 209                                                                 WEP_CVAR_SEC(blaster, lifetime)
 210                                                         );
 211                                                         weapon_thinkf(WFRAME_FIRE2, WEP_CVAR_SEC(blaster, animtime), w_ready);
 212                                                 }
 213
 214                                                 break;
 215                                         }
 216                                 }
 217                         }
 218                         return TRUE;
 219                 }
 220
 221                 case WR_INIT:
 222                 {
 223                         precache_model("models/weapons/g_laser.md3");
 224                         precache_model("models/weapons/v_laser.md3");
 225                         precache_model("models/weapons/h_laser.iqm");
 226                         precache_sound("weapons/lasergun_fire.wav");
 227                         BLASTER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP)
 228                         return TRUE;
 229                 }
 230
 231                 case WR_SETUP:
 232                 {
 233                         self.ammo_field = ammo_none;
 234                         return TRUE;
 235                 }
 236
 237                 case WR_CHECKAMMO1:
 238                 case WR_CHECKAMMO2:
 239                 {
 240                         return TRUE; // laser has infinite ammo
 241                 }
 242
 243                 case WR_CONFIG:
 244                 {
 245                         BLASTER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 246                         return TRUE;
 247                 }
 248
 249                 case WR_SUICIDEMESSAGE:
 250                 {
 251                         return WEAPON_LASER_SUICIDE;
 252                 }
 253
 254                 case WR_KILLMESSAGE:
 255                 {
 256                         return WEAPON_LASER_MURDER;
 257                 }
 258         }
 259
 260         return TRUE;
 261 }
 262 #endif
 263 #ifdef CSQC
 264 float W_Blaster(float request)
 265 {
 266         switch(request)
 267         {
 268                 case WR_IMPACTEFFECT:
 269                 {
 270                         vector org2;
 271                         org2 = w_org + w_backoff * 6;
 272                         pointparticles(particleeffectnum("new_laser_impact"), org2, w_backoff * 1000, 1);
 273                         if(!w_issilent) { sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM); }
 274                         return TRUE;
 275                 }
 276
 277                 case WR_INIT:
 278                 {
 279                         precache_sound("weapons/laserimpact.wav");
 280                         return TRUE;
 281                 }
 282                 case WR_ZOOMRETICLE:
 283                 {
 284                         // no weapon specific image for this weapon
 285                         return FALSE;
 286                 }
 287         }
 288
 289         return TRUE;
 290 }
 291 #endif
 292 #endif