qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include <client/defs.qh>
   7         #include "../constants.qh"
   8         #include "../stats.qh"
   9         #include <lib/warpzone/anglestransform.qh>
  10         #include <lib/warpzone/common.qh>
  11         #include <lib/warpzone/client.qh>
  12         #include "../util.qh"
  13         #include <client/autocvars.qh>
  14         #include "../deathtypes/all.qh"
  15         #include <lib/csqcmodel/interpolate.qh>
  16         #include "../physics/movetypes/movetypes.qh"
  17         #include <client/main.qh>
  18         #include <lib/csqcmodel/cl_model.qh>
  19 #elif defined(MENUQC)
  20 #elif defined(SVQC)
  21         #include <common/items/_mod.qh>
  22     #include <lib/warpzone/anglestransform.qh>
  23     #include <lib/warpzone/common.qh>
  24     #include <lib/warpzone/util_server.qh>
  25     #include <lib/warpzone/server.qh>
  26     #include "../constants.qh"
  27     #include "../stats.qh"
  28     #include "../teams.qh"
  29     #include "../util.qh"
  30     #include "../monsters/_mod.qh"
  31     #include "config.qh"
  32     #include <server/weapons/csqcprojectile.qh>
  33     #include <server/weapons/tracing.qh>
  34     #include "../t_items.qh"
  35     #include <server/autocvars.qh>
  36     #include <server/constants.qh>
  37     #include <server/defs.qh>
  38     #include "../notifications/all.qh"
  39     #include "../deathtypes/all.qh"
  40     #include <server/mutators/_mod.qh>
  41     #include "../mapinfo.qh"
  42     #include <server/command/_mod.qh>
  43     #include <lib/csqcmodel/sv_model.qh>
  44     #include <server/portals.qh>
  45     #include <server/g_hook.qh>
  46 #endif
  47 #ifdef GAMEQC
  48         #include "calculations.qc"
  49 #endif
  50 #ifdef SVQC
  51         #include "config.qc"
  52 #endif
  53 #define IMPLEMENTATION
  54 #include "all.inc"
  55 #undef IMPLEMENTATION
  56
  57 // WEAPON PLUGIN SYSTEM
  58
  59 WepSet _WepSet_FromWeapon(int a)
  60 {
  61         a -= WEP_FIRST;
  62         if (Weapons_MAX > 24)
  63                 if (a >= 24)
  64                 {
  65                         a -= 24;
  66                         if (Weapons_MAX > 48)
  67                                 if (a >= 24)
  68                                 {
  69                                         a -= 24;
  70                                         return '0 0 1' * power2of(a);
  71                                 }
  72                         return '0 1 0' * power2of(a);
  73                 }
  74         return '1 0 0' * power2of(a);
  75 }
  76 #ifdef SVQC
  77         void WriteWepSet(float dst, WepSet w)
  78         {
  79                 if (Weapons_MAX > 48) WriteInt72_t(dst, w);
  80                 else if (Weapons_MAX > 24) WriteInt48_t(dst, w);
  81                 else WriteInt24_t(dst, w.x);
  82         }
  83 #endif
  84 #ifdef CSQC
  85         WepSet WepSet_GetFromStat()
  86         {
  87                 return STAT(WEAPONS);
  88         }
  89         WepSet WepSet_GetFromStat_InMap()
  90         {
  91                 return STAT(WEAPONSINMAP);
  92         }
  93         WepSet ReadWepSet()
  94         {
  95                 if (Weapons_MAX > 48) return ReadInt72_t();
  96                 if (Weapons_MAX > 24) return ReadInt48_t();
  97                 return ReadInt24_t() * '1 0 0';
  98         }
  99 #endif
 100
 101 string W_FixWeaponOrder(string order, float complete)
 102 {
 103         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 104 }
 105 string W_NameWeaponOrder_MapFunc(string s)
 106 {
 107         int i = stof(s);
 108         if (s == "0" || i)
 109         {
 110                 entity wi = Weapons_from(i);
 111                 if (wi != WEP_Null) return wi.netname;
 112         }
 113         return s;
 114 }
 115
 116 string W_UndeprecateName(string s)
 117 {
 118         switch (s)
 119         {
 120                 case "nex": return "vortex";
 121                 case "rocketlauncher": return "devastator";
 122                 case "laser": return "blaster";
 123                 case "minstanex": return "vaporizer";
 124                 case "grenadelauncher": return "mortar";
 125                 case "uzi": return "machinegun";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[Weapons_MAX];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = Weapons_from(si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = Weapons_from(sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 163                 sprintf(" %d ", si), 0)
 164                -
 165                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 166                 sprintf(" %d ", sj), 0)
 167         ;  // low char index first!
 168 }
 169 string W_FixWeaponOrder_BuildImpulseList(string o)
 170 {
 171         int i;
 172         W_FixWeaponOrder_BuildImpulseList_order = o;
 173         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 174                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 175         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 176                 NULL);
 177         o = "";
 178         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 179                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 180         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 181         return substring(o, 1, -1);
 182 }
 183
 184 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 185 {
 186         return W_FixWeaponOrder(order, 0);
 187 }
 188
 189 string W_FixWeaponOrder_ForceComplete(string order)
 190 {
 191         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 192         return W_FixWeaponOrder(order, 1);
 193 }
 194
 195 void W_RandomWeapons(entity e, float n)
 196 {
 197         int i;
 198         WepSet remaining;
 199         WepSet result;
 200         remaining = e.weapons;
 201         result = '0 0 0';
 202         for (i = 0; i < n; ++i)
 203         {
 204                 RandomSelection_Init();
 205                 FOREACH(Weapons, it != WEP_Null, {
 206                         if (remaining & (it.m_wepset))
 207                                 RandomSelection_AddEnt(it, 1, 1);
 208                 });
 209                 Weapon w = RandomSelection_chosen_ent;
 210                 result |= WepSet_FromWeapon(w);
 211                 remaining &= ~WepSet_FromWeapon(w);
 212         }
 213         e.weapons = result;
 214 }
 215
 216 string GetAmmoPicture(.int ammotype)
 217 {
 218         switch (ammotype)
 219         {
 220                 case ammo_shells:  return ITEM_Shells.m_icon;
 221                 case ammo_nails:   return ITEM_Bullets.m_icon;
 222                 case ammo_rockets: return ITEM_Rockets.m_icon;
 223                 case ammo_cells:   return ITEM_Cells.m_icon;
 224                 case ammo_plasma:  return ITEM_Plasma.m_icon;
 225                 case ammo_fuel:    return ITEM_JetpackFuel.m_icon;
 226                 default: return "";  // wtf, no ammo type?
 227         }
 228 }
 229
 230 #ifdef CSQC
 231         .int GetAmmoFieldFromNum(int i)
 232         {
 233                 switch (i)
 234                 {
 235                         case 0: return ammo_shells;
 236                         case 1: return ammo_nails;
 237                         case 2: return ammo_rockets;
 238                         case 3: return ammo_cells;
 239                         case 4: return ammo_plasma;
 240                         case 5: return ammo_fuel;
 241                         default: return ammo_none;
 242                 }
 243         }
 244
 245         int GetAmmoStat(.int ammotype)
 246         {
 247                 switch (ammotype)
 248                 {
 249                         case ammo_shells: return STAT_SHELLS;
 250                         case ammo_nails: return STAT_NAILS;
 251                         case ammo_rockets: return STAT_ROCKETS;
 252                         case ammo_cells: return STAT_CELLS;
 253                         case ammo_plasma: return STAT_PLASMA.m_id;
 254                         case ammo_fuel: return STAT_FUEL.m_id;
 255                         default: return -1;
 256                 }
 257         }
 258 #endif
 259
 260 string W_Sound(string w_snd)
 261 {
 262         string output = strcat("weapons/", w_snd);
 263 #ifdef SVQC
 264                 MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 265                 return M_ARGV(1, string);
 266 #else
 267                 return output;
 268 #endif
 269 }
 270
 271 string W_Model(string w_mdl)
 272 {
 273         string output = strcat("models/weapons/", w_mdl);
 274         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 275         return M_ARGV(1, string);
 276 }
 277
 278 #ifdef GAMEQC
 279 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 280 {
 281         switch (algn)
 282         {
 283                 default:
 284                 case 3:
 285                         // right alignment
 286                         break;
 287                 case 4:
 288                         // left
 289                         vecs.y = -vecs.y;
 290                         break;
 291                 case 1:
 292                 case 2:
 293                         // center
 294                         vecs.y = 0;
 295                         vecs.z -= 2;
 296                         break;
 297         }
 298         return vecs;
 299 }
 300
 301 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 302 {
 303 #ifdef SVQC
 304         string s;
 305 #endif
 306         if (visual)
 307         {
 308                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 309         }
 310 #ifdef SVQC
 311         else if (autocvar_g_shootfromeye)
 312         {
 313                 vecs.y = vecs.z = 0;
 314         }
 315         else if (autocvar_g_shootfromcenter)
 316         {
 317                 vecs.y = 0;
 318                 vecs.z -= 2;
 319         }
 320         else if ((s = autocvar_g_shootfromfixedorigin) != "")
 321         {
 322                 vector v = stov(s);
 323                 if (y_is_right) v.y = -v.y;
 324                 if (v.x != 0) vecs.x = v.x;
 325                 vecs.y = v.y;
 326                 vecs.z = v.z;
 327         }
 328 #endif
 329         else  // just do the same as top
 330         {
 331                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 332         }
 333
 334         return vecs;
 335 }
 336
 337 #define shotorg_adjust shotorg_adjust_values
 338
 339 /**
 340  * supported formats:
 341  *
 342  * 1. simple animated model, muzzle flash handling on h_ model:
 343  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 344  *      tags:
 345  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 346  *        shell = casings ejection point (must be on the right hand side of the gun)
 347  *        weapon = attachment for v_tuba.md3
 348  *    v_tuba.md3 - first and third person model
 349  *    g_tuba.md3 - pickup model
 350  *
 351  * 2. simple animated model, muzzle flash handling on v_ model:
 352  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 353  *      tags:
 354  *        weapon = attachment for v_tuba.md3
 355  *    v_tuba.md3 - first and third person model
 356  *      tags:
 357  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 358  *        shell = casings ejection point (must be on the right hand side of the gun)
 359  *    g_tuba.md3 - pickup model
 360  *
 361  * 3. fully animated model, muzzle flash handling on h_ model:
 362  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 363  *      tags:
 364  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 365  *        shell = casings ejection point (must be on the right hand side of the gun)
 366  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 367  *    v_tuba.md3 - third person model
 368  *    g_tuba.md3 - pickup model
 369  *
 370  * 4. fully animated model, muzzle flash handling on v_ model:
 371  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 372  *      tags:
 373  *        shot = muzzle end (shot origin)
 374  *        shell = casings ejection point (must be on the right hand side of the gun)
 375  *    v_tuba.md3 - third person model
 376  *      tags:
 377  *        shot = muzzle end (for muzzle flashes)
 378  *    g_tuba.md3 - pickup model
 379  *
 380  * writes:
 381  *   this.origin, this.angles
 382  *   this.weaponchild
 383  *   this.movedir, this.view_ofs
 384  *   attachment stuff
 385  *   anim stuff
 386  * to free:
 387  *   call again with ""
 388  *   remove the ent
 389  */
 390 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 391 {
 392         if (name == "")
 393         {
 394                 vector oldmin = this.mins, oldmax = this.maxs;
 395                 setmodel(this, MDL_Null);
 396                 setsize(this, oldmin, oldmax);
 397                 if (this.weaponchild) delete(this.weaponchild);
 398                 this.weaponchild = NULL;
 399                 this.movedir = '0 0 0';
 400                 this.spawnorigin = '0 0 0';
 401                 this.oldorigin = '0 0 0';
 402                 this.anim_fire1  = '0 1 0.01';
 403                 this.anim_fire2  = '0 1 0.01';
 404                 this.anim_idle   = '0 1 0.01';
 405                 this.anim_reload = '0 1 0.01';
 406         }
 407         else
 408         {
 409                 // if there is a child entity, hide it until we're sure we use it
 410                 if (this.weaponchild) this.weaponchild.model = "";
 411                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 412                 int v_shot_idx;  // used later
 413                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 414
 415                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 416                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 417                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 418                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 419                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 420                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 421
 422                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 423                 // if we don't, this is a "real" animated model
 424                 string t;
 425                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 426                 {
 427                         if (!this.weaponchild)
 428                         {
 429                                 this.weaponchild = new(weaponchild);
 430 #ifdef CSQC
 431                                 this.weaponchild.drawmask = MASK_NORMAL;
 432                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 433 #endif
 434                         }
 435                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 436                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 437                         setattachment(this.weaponchild, this, t);
 438                 }
 439                 else
 440                 {
 441                         if (this.weaponchild) delete(this.weaponchild);
 442                         this.weaponchild = NULL;
 443                 }
 444
 445                 setsize(this, '0 0 0', '0 0 0');
 446                 setorigin(this, '0 0 0');
 447                 this.angles = '0 0 0';
 448                 this.frame = 0;
 449 #ifdef SVQC
 450                 this.viewmodelforclient = NULL;
 451 #else
 452                 this.renderflags &= ~RF_VIEWMODEL;
 453 #endif
 454                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 455                 {
 456                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 457                 }
 458                 else
 459                 {
 460                         int idx;
 461                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 462                         {
 463                                 this.movedir = gettaginfo(this, idx);
 464                         }
 465                         else
 466                         {
 467                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 468                                         this.model);
 469                                 this.movedir = '0 0 0';
 470                         }
 471                 }
 472                 {
 473                         int idx = 0;
 474                         // v_ model attached to invisible h_ model
 475                         if (this.weaponchild
 476                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 477                         {
 478                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 479                         }
 480                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 481                         {
 482                                 this.spawnorigin = gettaginfo(this, idx);
 483                         }
 484                         else
 485                         {
 486                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 487                                         this.model);
 488                                 this.spawnorigin = this.movedir;
 489                         }
 490                 }
 491                 if (v_shot_idx)
 492                 {
 493                         this.oldorigin = '0 0 0';  // use regular attachment
 494                 }
 495                 else
 496                 {
 497                         int idx;
 498                         if (this.weaponchild)
 499                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 500                         else
 501                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 502                         if (idx)
 503                         {
 504                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 505                         }
 506                         else
 507                         {
 508                                 LOG_WARNF(
 509                                         "weapon model %s does not support the 'handle' tag "
 510                                         "and neither does the v_ model support the 'shot' tag, "
 511                                         "will display muzzle flashes TOTALLY wrong\n",
 512                                         this.model);
 513                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 514                         }
 515                 }
 516
 517 #ifdef SVQC
 518                 this.viewmodelforclient = this.owner;
 519 #else
 520                 this.renderflags |= RF_VIEWMODEL;
 521 #endif
 522         }
 523
 524         this.view_ofs = '0 0 0';
 525
 526         if (this.movedir.x >= 0)
 527         {
 528                 //int algn = STAT(GUNALIGN, this.owner);
 529                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 530         #ifdef SVQC
 531                 this.m_gunalign = algn;
 532         #endif
 533                 vector v = this.movedir;
 534                 this.movedir = shotorg_adjust(v, false, false, algn);
 535                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 536         }
 537         int compressed_shotorg = compressShotOrigin(this.movedir);
 538         // make them match perfectly
 539 #ifdef SVQC
 540         this.movedir = decompressShotOrigin(this.owner.stat_shotorg = compressed_shotorg);
 541 #else
 542         this.movedir = decompressShotOrigin(compressed_shotorg);
 543 #endif
 544
 545         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 546
 547         // check if an instant weapon switch occurred
 548         setorigin(this, this.view_ofs);
 549         if (!_anim) return;
 550         // reset animstate now
 551         this.wframe = WFRAME_IDLE;
 552         setanim(this, this.anim_idle, true, false, true);
 553 }
 554 #endif
 555
 556 #ifdef GAMEQC
 557
 558 REGISTER_NET_TEMP(wframe)
 559 #ifdef CSQC
 560 NET_HANDLE(wframe, bool isNew)
 561 {
 562         vector a;
 563         a.x = ReadCoord();
 564     a.y = ReadCoord();
 565     a.z = ReadCoord();
 566     int slot = ReadByte();
 567         bool restartanim = ReadByte();
 568         entity wepent = viewmodels[slot];
 569         anim_set(wepent, a, !restartanim, restartanim, restartanim);
 570         wepent.state = ReadByte();
 571         wepent.weapon_nextthink = ReadFloat();
 572         switch (wepent.state)
 573         {
 574                 case WS_RAISE:
 575                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 576                         break;
 577                 case WS_DROP:
 578                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 579                         break;
 580         default:
 581             wepent.weapon_switchdelay = 0;
 582             break;
 583         }
 584         return true;
 585 }
 586 #endif
 587
 588 #ifdef SVQC
 589 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim)
 590 {
 591         if (!IS_REAL_CLIENT(actor)) return;
 592         int channel = MSG_ONE;
 593         msg_entity = actor;
 594         WriteHeader(channel, wframe);
 595         WriteCoord(channel, a.x);
 596         WriteCoord(channel, a.y);
 597         WriteCoord(channel, a.z);
 598         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 599         WriteByte(channel, restartanim);
 600         WriteByte(channel, weaponentity.state);
 601         WriteFloat(channel, weaponentity.weapon_nextthink);
 602 }
 603 #endif
 604
 605 REGISTER_NET_C2S(w_whereis)
 606 #ifdef SVQC
 607 void Weapon_whereis(Weapon this, entity cl);
 608 NET_HANDLE(w_whereis, bool)
 609 {
 610         Weapon wpn = ReadRegistered(Weapons);
 611         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 612         return true;
 613 }
 614 #else
 615 void w_whereis(Weapon this)
 616 {
 617         int channel = MSG_C2S;
 618         WriteHeader(channel, w_whereis);
 619         WriteRegistered(Weapons, channel, this);
 620 }
 621 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 622 {
 623         switch (request)
 624         {
 625                 case CMD_REQUEST_COMMAND:
 626                 {
 627                         string s = argv(1);
 628                         if (s == "all")
 629                         {
 630                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 631                                 return;
 632                         }
 633                         if (s == "unowned")
 634                         {
 635                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 636                                 return;
 637                         }
 638                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 639                         {
 640                                 w_whereis(it);
 641                                 return;
 642                         });
 643                 }
 644                 default:
 645                 {
 646                         LOG_INFOF("Incorrect parameters for ^2%s^7\n", "weapon_find");
 647                 }
 648                 case CMD_REQUEST_USAGE:
 649                 {
 650                         LOG_INFO("\nUsage:^3 cl_cmd weapon_find weapon\n");
 651                         LOG_INFO("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.\n");
 652                         return;
 653                 }
 654         }
 655 }
 656 #endif
 657
 658
 659 #endif
 660
 661 #endif