qcsrc/common/vehicles/vehicle/racer.qc

   1 #ifndef VEHICLE_RACER
   2 #define VEHICLE_RACER
   3
   4 CLASS(Racer, Vehicle)
   5 /* spawnflags */ ATTRIB(Racer, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   6 /* mins       */ ATTRIB(Racer, mins, vector, '-120 -120 -40' * 0.5);
   7 /* maxs       */ ATTRIB(Racer, maxs, vector, '120 120 40' * 0.5);
   8 /* model          */ ATTRIB(Racer, mdl, string, "models/vehicles/wakizashi.dpm");
   9 /* model          */ ATTRIB(Racer, model, string, "models/vehicles/wakizashi.dpm");
  10 /* head_model */ ATTRIB(Racer, head_model, string, "null");
  11 /* hud_model  */ ATTRIB(Racer, hud_model, string, "models/vehicles/wakizashi_cockpit.dpm");
  12 /* tags       */ ATTRIB(Racer, tag_head, string, "");
  13 /* tags       */ ATTRIB(Racer, tag_hud, string, "");
  14 /* tags       */ ATTRIB(Racer, tag_hview, string, "tag_viewport");
  15 /* netname    */ ATTRIB(Racer, netname, string, "racer");
  16 /* fullname   */ ATTRIB(Racer, vehicle_name, string, _("Racer"));
  17 /* icon       */ ATTRIB(Racer, m_icon, string, "vehicle_racer");
  18 ENDCLASS(Racer)
  19
  20 REGISTER_VEHICLE(RACER, NEW(Racer));
  21
  22 #include "../../weapons/all.qh"
  23
  24 CLASS(RacerAttack, PortoLaunch)
  25 /* flags     */ ATTRIB(RacerAttack, spawnflags, int, WEP_TYPE_OTHER);
  26 /* impulse   */ ATTRIB(RacerAttack, impulse, int, 3);
  27 /* refname   */ ATTRIB(RacerAttack, netname, string, "racercannon");
  28 /* wepname   */ ATTRIB(RacerAttack, message, string, _("Racer cannon"));
  29 ENDCLASS(RacerAttack)
  30 REGISTER_WEAPON(RACER, NEW(RacerAttack));
  31
  32 #endif
  33
  34 #ifdef IMPLEMENTATION
  35 #ifdef SVQC
  36 #include "../../effects/effects.qh"
  37 #include "../../triggers/trigger/impulse.qh"
  38
  39 void racer_fire_cannon(vector org, vector dir);
  40 void racer_fire_rocket(vector org, vector dir, entity trg);
  41 METHOD(RacerAttack, wr_think, bool(entity thiswep, bool fire1, bool fire2)) {
  42         SELFPARAM();
  43         if (fire1)
  44         if (weapon_prepareattack(false, 0.2)) {
  45                 W_SetupShot_Dir(self, v_forward, false, 0, "", CH_WEAPON_B, 0);
  46                 racer_fire_cannon(w_shotorg, w_shotdir);
  47                 weapon_thinkf(WFRAME_FIRE1, 0, w_ready);
  48         }
  49         if (fire2)
  50         if (weapon_prepareattack(false, 0.2)) {
  51                 W_SetupShot_Dir(self, v_forward, false, 0, "", CH_WEAPON_B, 0);
  52                 racer_fire_rocket(w_shotorg, w_shotdir, NULL);
  53                 weapon_thinkf(WFRAME_FIRE2, 0, w_ready);
  54         }
  55         return true;
  56 }
  57
  58 bool autocvar_g_vehicle_racer;
  59
  60 float autocvar_g_vehicle_racer_speed_afterburn;
  61 float autocvar_g_vehicle_racer_afterburn_cost;
  62
  63 float autocvar_g_vehicle_racer_waterburn_cost;
  64 float autocvar_g_vehicle_racer_waterburn_speed;
  65
  66 float autocvar_g_vehicle_racer_water_speed_forward;
  67 float autocvar_g_vehicle_racer_water_speed_strafe;
  68
  69 float autocvar_g_vehicle_racer_pitchlimit = 30;
  70
  71 float autocvar_g_vehicle_racer_water_downforce = 0.03;
  72 float autocvar_g_vehicle_racer_water_upforcedamper = 15;
  73
  74 float autocvar_g_vehicle_racer_anglestabilizer;
  75 float autocvar_g_vehicle_racer_downforce;
  76
  77 float autocvar_g_vehicle_racer_speed_forward;
  78 float autocvar_g_vehicle_racer_speed_strafe;
  79 float autocvar_g_vehicle_racer_springlength;
  80 float autocvar_g_vehicle_racer_upforcedamper;
  81 float autocvar_g_vehicle_racer_friction;
  82
  83 float autocvar_g_vehicle_racer_water_time = 5;
  84
  85 float autocvar_g_vehicle_racer_hovertype;
  86 float autocvar_g_vehicle_racer_hoverpower;
  87
  88 float autocvar_g_vehicle_racer_turnroll;
  89 float autocvar_g_vehicle_racer_turnspeed;
  90 float autocvar_g_vehicle_racer_pitchspeed;
  91
  92 float autocvar_g_vehicle_racer_energy;
  93 float autocvar_g_vehicle_racer_energy_regen;
  94 float autocvar_g_vehicle_racer_energy_regen_pause;
  95
  96 float autocvar_g_vehicle_racer_health;
  97 float autocvar_g_vehicle_racer_health_regen;
  98 float autocvar_g_vehicle_racer_health_regen_pause;
  99
 100 float autocvar_g_vehicle_racer_shield;
 101 float autocvar_g_vehicle_racer_shield_regen;
 102 float autocvar_g_vehicle_racer_shield_regen_pause;
 103
 104 float autocvar_g_vehicle_racer_cannon_cost;
 105 float autocvar_g_vehicle_racer_cannon_damage;
 106 float autocvar_g_vehicle_racer_cannon_radius;
 107 float autocvar_g_vehicle_racer_cannon_refire;
 108 float autocvar_g_vehicle_racer_cannon_speed;
 109 float autocvar_g_vehicle_racer_cannon_spread;
 110 float autocvar_g_vehicle_racer_cannon_force;
 111
 112 float autocvar_g_vehicle_racer_rocket_accel;
 113 float autocvar_g_vehicle_racer_rocket_damage;
 114 float autocvar_g_vehicle_racer_rocket_radius;
 115 float autocvar_g_vehicle_racer_rocket_force;
 116 float autocvar_g_vehicle_racer_rocket_refire;
 117 float autocvar_g_vehicle_racer_rocket_speed;
 118 float autocvar_g_vehicle_racer_rocket_turnrate;
 119
 120 float autocvar_g_vehicle_racer_rocket_locktarget;
 121 float autocvar_g_vehicle_racer_rocket_locking_time;
 122 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
 123 float autocvar_g_vehicle_racer_rocket_locked_time;
 124 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
 125 float autocvar_g_vehicle_racer_rocket_climbspeed;
 126
 127 float autocvar_g_vehicle_racer_respawntime;
 128
 129 float autocvar_g_vehicle_racer_blowup_radius;
 130 float autocvar_g_vehicle_racer_blowup_coredamage;
 131 float autocvar_g_vehicle_racer_blowup_edgedamage;
 132 float autocvar_g_vehicle_racer_blowup_forceintensity;
 133
 134 float autocvar_g_vehicle_racer_bouncefactor;
 135 float autocvar_g_vehicle_racer_bouncestop;
 136 vector autocvar_g_vehicle_racer_bouncepain;
 137
 138 .float racer_watertime;
 139
 140 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
 141
 142 void racer_align4point(float _delta)
 143 {SELFPARAM();
 144         vector push_vector;
 145         float fl_push, fr_push, bl_push, br_push;
 146
 147         push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 148         fr_push   = force_fromtag_normpower;
 149         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 150
 151         push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 152         fl_push   = force_fromtag_normpower;
 153         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 154
 155         push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 156         br_push   = force_fromtag_normpower;
 157         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 158
 159         push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
 160         bl_push   = force_fromtag_normpower;
 161         //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
 162
 163         self.velocity += push_vector * _delta;
 164
 165         float uforce = autocvar_g_vehicle_racer_upforcedamper;
 166
 167         int cont = pointcontents(self.origin - '0 0 64');
 168         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 169         {
 170                 uforce = autocvar_g_vehicle_racer_water_upforcedamper;
 171
 172                 if(self.owner.BUTTON_CROUCH && time < self.air_finished)
 173                         self.velocity_z += 30;
 174                 else
 175                         self.velocity_z += 200;
 176         }
 177
 178
 179         // Anti ocilation
 180         if(self.velocity_z > 0)
 181                 self.velocity_z *= 1 - uforce * _delta;
 182
 183         push_vector_x =  (fl_push - bl_push);
 184         push_vector_x += (fr_push - br_push);
 185         push_vector_x *= 360;
 186
 187         push_vector_z = (fr_push - fl_push);
 188         push_vector_z += (br_push - bl_push);
 189         push_vector_z *= 360;
 190
 191         // Apply angle diffrance
 192         self.angles_z += push_vector_z * _delta;
 193         self.angles_x += push_vector_x * _delta;
 194
 195         // Apply stabilizer
 196         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 197         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 198 }
 199
 200 void racer_fire_cannon(vector org, vector dir)
 201 {SELFPARAM();
 202         entity bolt = vehicles_projectile(EFFECT_RACER_MUZZLEFLASH.eent_eff_name, SND(LASERGUN_FIRE),
 203                                                    org, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 204                                                    autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 205                                                    DEATH_VH_WAKI_GUN, PROJECTILE_WAKICANNON, 0, true, true, self.owner);
 206         bolt.velocity = normalize(dir) * autocvar_g_vehicle_racer_cannon_speed;
 207 }
 208 void racer_fire_cannon_aim(string tagname)
 209 {
 210         SELFPARAM();
 211         vector org = gettaginfo(self, gettagindex(self, tagname));
 212         // Fix z-aim (for chase mode)
 213         vector dir = normalize(trace_endpos - org);
 214         v_forward.z = dir.z * 0.5;
 215         racer_fire_cannon(org, v_forward);
 216 }
 217
 218 void racer_rocket_groundhugger()
 219 {SELFPARAM();
 220         vector olddir, newdir;
 221         float oldvel, newvel;
 222
 223         self.nextthink  = time;
 224
 225         if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 226         {
 227                 self.use();
 228                 return;
 229         }
 230
 231         if(!self.realowner.vehicle)
 232         {
 233                 UpdateCSQCProjectile(self);
 234                 return;
 235         }
 236
 237         olddir = normalize(self.velocity);
 238         oldvel = vlen(self.velocity);
 239         newvel = oldvel + self.lip;
 240
 241         tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 242         if(trace_fraction <= 0.5)
 243         {
 244                 // Hitting somethign soon, just speed ahead
 245                 self.velocity = olddir * newvel;
 246                 UpdateCSQCProjectile(self);
 247                 return;
 248         }
 249
 250         traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 251         if(trace_fraction != 1.0)
 252         {
 253                 newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 254                 self.velocity = normalize(olddir + newdir) * newvel;
 255         }
 256         else
 257         {
 258                 self.velocity = olddir * newvel;
 259                 self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 260         }
 261
 262         int cont = pointcontents(self.origin - '0 0 32');
 263         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 264                 self.velocity_z += 200;
 265
 266         UpdateCSQCProjectile(self);
 267         return;
 268 }
 269
 270 void racer_rocket_tracker()
 271 {SELFPARAM();
 272         vector olddir, newdir;
 273         float oldvel, newvel;
 274
 275         self.nextthink  = time;
 276
 277         if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 278         {
 279                 self.use();
 280                 return;
 281         }
 282
 283         if(!self.realowner.vehicle)
 284         {
 285                 UpdateCSQCProjectile(self);
 286                 return;
 287         }
 288
 289         olddir = normalize(self.velocity);
 290         oldvel = vlen(self.velocity);
 291         newvel = oldvel + self.lip;
 292         makevectors(vectoangles(olddir));
 293
 294         float time_to_impact = min(vlen(self.enemy.origin - self.origin) / vlen(self.velocity), 1);
 295         vector predicted_origin = self.enemy.origin + self.enemy.velocity * time_to_impact;
 296
 297         traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 298         newdir = normalize(predicted_origin - self.origin);
 299
 300         //vector
 301         float height_diff = predicted_origin_z - self.origin_z;
 302
 303         if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 304         {
 305                 //bprint("Target lost!\n");
 306                 //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 307                 self.think = racer_rocket_groundhugger;
 308                 return;
 309         }
 310
 311         if(trace_fraction != 1.0 && trace_ent != self.enemy)
 312                 newdir_z += 16 * sys_frametime;
 313
 314         self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 315         self.velocity_z -= 800 * sys_frametime;
 316         self.velocity_z += max(height_diff, autocvar_g_vehicle_racer_rocket_climbspeed) * sys_frametime ;
 317
 318         UpdateCSQCProjectile(self);
 319         return;
 320 }
 321
 322 void racer_fire_rocket(vector org, vector dir, entity trg)
 323 {SELFPARAM();
 324         entity rocket = vehicles_projectile(EFFECT_RACER_ROCKETLAUNCH.eent_eff_name, SND(ROCKET_FIRE),
 325                                                    org, dir * autocvar_g_vehicle_racer_rocket_speed,
 326                                                    autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 327                                                    DEATH_VH_WAKI_ROCKET, PROJECTILE_WAKIROCKET, 20, false, false, self.owner);
 328
 329         rocket.lip                        = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 330         rocket.wait                      = autocvar_g_vehicle_racer_rocket_turnrate;
 331         rocket.nextthink                = time;
 332         rocket.enemy                    = trg;
 333         rocket.cnt                        = time + 15;
 334
 335         if(trg)
 336                 rocket.think                    = racer_rocket_tracker;
 337         else
 338                 rocket.think                    = racer_rocket_groundhugger;
 339 }
 340
 341 void racer_fire_rocket_aim(string tagname, entity trg)
 342 {
 343         SELFPARAM();
 344         vector v = gettaginfo(self, gettagindex(self, tagname));
 345         racer_fire_rocket(v, v_forward, trg);
 346 }
 347
 348 float racer_frame()
 349 {SELFPARAM();
 350         entity player, racer;
 351         vector df;
 352         float ftmp;
 353
 354         if(intermission_running)
 355         {
 356                 self.vehicle.velocity = '0 0 0';
 357                 self.vehicle.avelocity = '0 0 0';
 358                 return 1;
 359         }
 360
 361         player  = self;
 362         racer   = self.vehicle;
 363         setself(racer);
 364
 365         vehicles_painframe();
 366
 367         if(pointcontents(racer.origin) != CONTENT_WATER)
 368                 racer.air_finished = time + autocvar_g_vehicle_racer_water_time;
 369
 370         if(racer.deadflag != DEAD_NO)
 371         {
 372                 setself(player);
 373                 player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 374                 return 1;
 375         }
 376
 377         racer_align4point(PHYS_INPUT_TIMELENGTH);
 378
 379         player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 380
 381         crosshair_trace(player);
 382
 383         racer.angles_x *= -1;
 384
 385         // Yaw
 386         ftmp = autocvar_g_vehicle_racer_turnspeed * PHYS_INPUT_TIMELENGTH;
 387         ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - racer.angles_y, racer.angles_y), ftmp);
 388         racer.angles_y = anglemods(racer.angles_y + ftmp);
 389
 390         // Roll
 391         racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * PHYS_INPUT_TIMELENGTH;
 392
 393         // Pitch
 394         ftmp = autocvar_g_vehicle_racer_pitchspeed  * PHYS_INPUT_TIMELENGTH;
 395         ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - racer.angles_x, racer.angles_x), ftmp);
 396         racer.angles_x = bound(-autocvar_g_vehicle_racer_pitchlimit, anglemods(racer.angles_x + ftmp), autocvar_g_vehicle_racer_pitchlimit);
 397
 398         makevectors(racer.angles);
 399         racer.angles_x *= -1;
 400
 401         //ftmp = racer.velocity_z;
 402         df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 403         //racer.velocity_z = ftmp;
 404
 405         int cont = pointcontents(racer.origin);
 406         if(vlen(player.movement) != 0)
 407         {
 408                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 409                 {
 410                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_water_speed_forward : -autocvar_g_vehicle_racer_water_speed_forward); }
 411                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_water_speed_strafe : -autocvar_g_vehicle_racer_water_speed_strafe); }
 412                 }
 413                 else
 414                 {
 415                         if(player.movement_x) { df += v_forward * ((player.movement_x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward); }
 416                         if(player.movement_y) { df += v_right * ((player.movement_y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe); }
 417                 }
 418
 419 #ifdef SVQC
 420                 if(self.sound_nexttime < time || self.sounds != 1)
 421                 {
 422                         self.sounds = 1;
 423                         self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 424                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_MOVE, VOL_VEHICLEENGINE, ATTEN_NORM);
 425                 }
 426 #endif
 427         }
 428 #ifdef SVQC
 429         else
 430         {
 431                 if(self.sound_nexttime < time || self.sounds != 0)
 432                 {
 433                         self.sounds = 0;
 434                         self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 435                         sound (self, CH_TRIGGER_SINGLE, SND_VEH_RACER_IDLE, VOL_VEHICLEENGINE, ATTEN_NORM);
 436                 }
 437         }
 438 #endif
 439
 440         // Afterburn
 441         if (PHYS_INPUT_BUTTON_JUMP(player) && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH))
 442         {
 443 #ifdef SVQC
 444                 if(time - racer.wait > 0.2)
 445                         pointparticles(particleeffectnum(EFFECT_RACER_BOOSTER), self.origin - v_forward * 32, v_forward  * vlen(self.velocity), 1);
 446 #endif
 447
 448                 racer.wait = time;
 449
 450                 if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 451                 {
 452                         racer.vehicle_energy -= autocvar_g_vehicle_racer_waterburn_cost * PHYS_INPUT_TIMELENGTH;
 453                         df += (v_forward * autocvar_g_vehicle_racer_waterburn_speed);
 454                 }
 455                 else
 456                 {
 457                         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * PHYS_INPUT_TIMELENGTH;
 458                         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 459                 }
 460
 461 #ifdef SVQC
 462                 if(racer.invincible_finished < time)
 463                 {
 464                         traceline(racer.origin, racer.origin - '0 0 256', MOVE_NORMAL, self);
 465                         if(trace_fraction != 1.0)
 466                                 pointparticles(particleeffectnum(EFFECT_SMOKE_SMALL), trace_endpos, '0 0 0', 1);
 467
 468                         racer.invincible_finished = time + 0.1 + (random() * 0.1);
 469                 }
 470
 471                 if(racer.strength_finished < time)
 472                 {
 473                         racer.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 474                         sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RACER_BOOST, VOL_VEHICLEENGINE, ATTEN_NORM);
 475                 }
 476 #endif
 477         }
 478         else
 479         {
 480                 racer.strength_finished = 0;
 481                 sound (racer.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 482         }
 483
 484         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 485                 racer.racer_watertime = time;
 486
 487         float dforce = autocvar_g_vehicle_racer_downforce;
 488         if(time - racer.racer_watertime <= 3)
 489                 dforce = autocvar_g_vehicle_racer_water_downforce;
 490
 491         df -= v_up * (vlen(racer.velocity) * dforce);
 492         player.movement = racer.velocity += df * PHYS_INPUT_TIMELENGTH;
 493
 494 #ifdef SVQC
 495         if(!forbidWeaponUse(player))
 496         if(player.BUTTON_ATCK)
 497         if(time > racer.attack_finished_single)
 498         if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 499         {
 500                 racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 501                 racer.wait = time;
 502
 503                 crosshair_trace(player);
 504                 if(racer.cnt)
 505                 {
 506                         racer_fire_cannon_aim("tag_fire1");
 507                         racer.cnt = 0;
 508                 }
 509                 else
 510                 {
 511                         racer_fire_cannon_aim("tag_fire2");
 512                         racer.cnt = 1;
 513                 }
 514                 racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 515         }
 516
 517         if(autocvar_g_vehicle_racer_rocket_locktarget)
 518         {
 519                 vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 520                                                  (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 521                                                  autocvar_g_vehicle_racer_rocket_locked_time);
 522
 523                 if(self.lock_target)
 524                 {
 525                         if(racer.lock_strength == 1)
 526                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 527                         else if(self.lock_strength > 0.5)
 528                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 529                         else if(self.lock_strength < 0.5)
 530                                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 531                 }
 532         }
 533
 534         if(!forbidWeaponUse(player))
 535         if(time > racer.delay)
 536         if(player.BUTTON_ATCK2)
 537         {
 538                 racer.misc_bulletcounter += 1;
 539                 racer.delay = time + 0.3;
 540
 541                 if(racer.misc_bulletcounter == 1)
 542                 {
 543                         racer_fire_rocket_aim("tag_rocket_r", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 544                         player.vehicle_ammo2 = 50;
 545                 }
 546                 else if(racer.misc_bulletcounter == 2)
 547                 {
 548                         racer_fire_rocket_aim("tag_rocket_l", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 549                         racer.lock_strength  = 0;
 550                         racer.lock_target       = world;
 551                         racer.misc_bulletcounter = 0;
 552                         racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 553                         racer.lip = time;
 554                         player.vehicle_ammo2 = 0;
 555                 }
 556         }
 557         else if(racer.misc_bulletcounter == 0)
 558                 player.vehicle_ammo2 = 100;
 559
 560         player.vehicle_reload2 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 561
 562         if(racer.vehicle_flags  & VHF_SHIELDREGEN)
 563                 vehicles_regen(racer.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime, true);
 564
 565         if(racer.vehicle_flags  & VHF_HEALTHREGEN)
 566                 vehicles_regen(racer.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime, false);
 567
 568         if(racer.vehicle_flags  & VHF_ENERGYREGEN)
 569                 vehicles_regen(racer.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime, false);
 570
 571
 572         VEHICLE_UPDATE_PLAYER(player, health, racer);
 573         VEHICLE_UPDATE_PLAYER(player, energy, racer);
 574
 575         if(racer.vehicle_flags & VHF_HASSHIELD)
 576                 VEHICLE_UPDATE_PLAYER(player, shield, racer);
 577
 578         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 579 #endif
 580
 581         setorigin(player,racer.origin + '0 0 32');
 582         player.velocity = racer.velocity;
 583
 584         setself(player);
 585         return 1;
 586 }
 587
 588 void racer_think()
 589 {SELFPARAM();
 590         self.nextthink = time;
 591
 592         float pushdeltatime = time - self.lastpushtime;
 593         if (pushdeltatime > 0.15) pushdeltatime = 0;
 594         self.lastpushtime = time;
 595         if(!pushdeltatime) return;
 596
 597         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NOMONSTERS, self);
 598
 599         vector df = self.velocity * -autocvar_g_vehicle_racer_friction;
 600         df_z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 601
 602         float forced = autocvar_g_vehicle_racer_upforcedamper;
 603
 604         int cont = pointcontents(self.origin - '0 0 64');
 605         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 606         {
 607                 forced = autocvar_g_vehicle_racer_water_upforcedamper;
 608                 self.velocity_z += 200;
 609         }
 610
 611         self.velocity += df * pushdeltatime;
 612         if(self.velocity_z > 0)
 613                 self.velocity_z *= 1 - forced * pushdeltatime;
 614
 615         self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 616         self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 617
 618         CSQCMODEL_AUTOUPDATE(self);
 619 }
 620
 621 void racer_exit(float eject)
 622 {SELFPARAM();
 623         vector spot;
 624
 625         self.think        = racer_think;
 626         self.nextthink  = time;
 627         self.movetype   = MOVETYPE_BOUNCE;
 628         sound (self.tur_head, CH_TRIGGER_SINGLE, SND_Null, VOL_VEHICLEENGINE, ATTEN_NORM);
 629
 630         if(!self.owner)
 631                 return;
 632
 633         makevectors(self.angles);
 634         if(eject)
 635         {
 636                 spot = self.origin + v_forward * 100 + '0 0 64';
 637                 spot = vehicles_findgoodexit(spot);
 638                 setorigin(self.owner , spot);
 639                 self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 640                 self.owner.oldvelocity = self.owner.velocity;
 641         }
 642         else
 643         {
 644                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 645                 {
 646                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 647                         self.owner.velocity_z += 200;
 648                         spot = self.origin + v_forward * 32 + '0 0 32';
 649                         spot = vehicles_findgoodexit(spot);
 650                 }
 651                 else
 652                 {
 653                         self.owner.velocity = self.velocity * 0.5;
 654                         self.owner.velocity_z += 10;
 655                         spot = self.origin - v_forward * 200 + '0 0 32';
 656                         spot = vehicles_findgoodexit(spot);
 657                 }
 658                 self.owner.oldvelocity = self.owner.velocity;
 659                 setorigin(self.owner , spot);
 660         }
 661         antilag_clear(self.owner);
 662         self.owner = world;
 663 }
 664
 665 void racer_blowup()
 666 {SELFPARAM();
 667         self.deadflag   = DEAD_DEAD;
 668         self.vehicle_exit(VHEF_NORMAL);
 669
 670         RadiusDamage (self, self.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 671                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 672                                         autocvar_g_vehicle_racer_blowup_radius, world, world,
 673                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 674                                         DEATH_VH_WAKI_DEATH, world);
 675
 676         self.nextthink  = time + autocvar_g_vehicle_racer_respawntime;
 677         self.think        = vehicles_spawn;
 678         self.movetype   = MOVETYPE_NONE;
 679         self.effects    = EF_NODRAW;
 680
 681         self.colormod  = '0 0 0';
 682         self.avelocity = '0 0 0';
 683         self.velocity  = '0 0 0';
 684
 685         setorigin(self, self.pos1);
 686 }
 687
 688 void racer_blowup_think()
 689 {SELFPARAM();
 690         self.nextthink = time;
 691
 692         if(time >= self.delay)
 693                 racer_blowup();
 694
 695         CSQCMODEL_AUTOUPDATE(self);
 696 }
 697
 698 void racer_deadtouch()
 699 {SELFPARAM();
 700         self.avelocity_x *= 0.7;
 701         self.cnt -= 1;
 702         if(self.cnt <= 0)
 703                 racer_blowup();
 704 }
 705
 706 void spawnfunc_vehicle_racer()
 707 {SELFPARAM();
 708         if(!autocvar_g_vehicle_racer) { remove(self); return; }
 709         if(!vehicle_initialize(VEH_RACER, false)) { remove(self); return; }
 710 }
 711
 712 #endif // SVQC
 713
 714 #ifdef CSQC
 715 #if 0
 716 void racer_draw()
 717 {SELFPARAM();
 718         float pushdeltatime = time - self.lastpushtime;
 719         if (pushdeltatime > 0.15) pushdeltatime = 0;
 720         self.lastpushtime = time;
 721         if(!pushdeltatime) return;
 722
 723         tracebox(self.move_origin, self.mins, self.maxs, self.move_origin - ('0 0 1' * getstatf(STAT_VEH_RACER_SPRINGLENGTH)), MOVE_NOMONSTERS, self);
 724
 725         vector df = self.move_velocity * -getstatf(STAT_VEH_RACER_FRICTION);
 726         df_z += (1 - trace_fraction) * getstatf(STAT_VEH_RACER_HOVERPOWER) + sin(time * 2) * (getstatf(STAT_VEH_RACER_SPRINGLENGTH) * 2);
 727
 728         float forced = getstatf(STAT_VEH_RACER_UPFORCEDAMPER);
 729
 730         int cont = pointcontents(self.move_origin - '0 0 64');
 731         if(cont == CONTENT_WATER || cont == CONTENT_LAVA || cont == CONTENT_SLIME)
 732         {
 733                 forced = getstatf(STAT_VEH_RACER_WATER_UPFORCEDAMPER);
 734                 self.move_velocity_z += 200;
 735         }
 736
 737         self.move_velocity += df * pushdeltatime;
 738         if(self.move_velocity_z > 0)
 739                 self.move_velocity_z *= 1 - forced * pushdeltatime;
 740
 741         self.move_angles_x *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 742         self.move_angles_z *= 1 - (getstatf(STAT_VEH_RACER_ANGLESTABILIZER) * pushdeltatime);
 743
 744         Movetype_Physics_MatchServer(false);
 745 }
 746 #endif
 747 #endif
 748
 749                 METHOD(Racer, vr_impact, bool(Racer thisveh))
 750                 {
 751                 #ifdef SVQC
 752                         if(autocvar_g_vehicle_racer_bouncepain)
 753                                 vehicles_impact(autocvar_g_vehicle_racer_bouncepain_x, autocvar_g_vehicle_racer_bouncepain_y, autocvar_g_vehicle_racer_bouncepain_z);
 754                 #endif
 755                         return true;
 756                 }
 757
 758                 METHOD(Racer, vr_enter, bool(Racer thisveh))
 759                 {
 760                 #ifdef SVQC
 761                         self.movetype = MOVETYPE_BOUNCE;
 762                         self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 763                         self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 764
 765                         if(self.owner.flagcarried)
 766                            setorigin(self.owner.flagcarried, '-190 0 96');
 767                 #elif defined(CSQC)
 768
 769                         self.move_movetype = MOVETYPE_BOUNCE;
 770                 #endif
 771
 772                         return true;
 773                 }
 774
 775                 METHOD(Racer, vr_spawn, bool(Racer thisveh))
 776                 {
 777                 #ifdef SVQC
 778                         if(self.scale != 0.5)
 779                         {
 780                                 if(autocvar_g_vehicle_racer_hovertype != 0)
 781                                         racer_force_from_tag = vehicles_force_fromtag_maglev;
 782                                 else
 783                                         racer_force_from_tag = vehicles_force_fromtag_hover;
 784
 785                                 // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 786                                 self.scale = 0.5;
 787                                 setattachment(self.vehicle_hudmodel, self, "");
 788                                 setattachment(self.vehicle_viewport, self, "tag_viewport");
 789
 790                                 self.mass                          = 900;
 791                         }
 792
 793                         self.think                = racer_think;
 794                         self.nextthink    = time;
 795                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 796                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 797
 798                         self.movetype     = MOVETYPE_TOSS;
 799                         self.solid                = SOLID_SLIDEBOX;
 800                         self.delay                = time;
 801                         self.scale                = 0.5;
 802
 803                         self.PlayerPhysplug = racer_frame;
 804
 805                         self.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 806                         self.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 807                         self.damageforcescale = 0.5;
 808                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 809                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 810                 #endif
 811                         return true;
 812                 }
 813
 814                 METHOD(Racer, vr_death, bool(Racer thisveh))
 815                 {
 816                 #ifdef SVQC
 817                         self.SendEntity         = func_null; // stop networking this racer (for now)
 818                         self.health                     = 0;
 819                         self.event_damage       = func_null;
 820                         self.solid                      = SOLID_CORPSE;
 821                         self.takedamage         = DAMAGE_NO;
 822                         self.deadflag           = DEAD_DYING;
 823                         self.movetype           = MOVETYPE_BOUNCE;
 824                         self.wait                       = time;
 825                         self.delay                      = 2 + time + random() * 3;
 826                         self.cnt                        = 1 + random() * 2;
 827                         self.touch                      = racer_deadtouch;
 828
 829                         Send_Effect(EFFECT_EXPLOSION_MEDIUM, self.origin, '0 0 0', 1);
 830
 831                         if(random() < 0.5)
 832                                 self.avelocity_z = 32;
 833                         else
 834                                 self.avelocity_z = -32;
 835
 836                         self.avelocity_x = -vlen(self.velocity) * 0.2;
 837                         self.velocity += '0 0 700';
 838                         self.colormod = '-0.5 -0.5 -0.5';
 839
 840                         self.think = racer_blowup_think;
 841                         self.nextthink = time;
 842                 #endif
 843                         return true;
 844                 }
 845
 846 #ifdef CSQC
 847                 METHOD(Racer, vr_hud, bool(Racer thisveh))
 848                 {
 849                         Vehicles_drawHUD(VEH_RACER.m_icon, "vehicle_racer_weapon1", "vehicle_racer_weapon2",
 850                                                          "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 851                                                          "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color,
 852                                                          vCROSS_GUIDE);
 853                         return true;
 854                 }
 855 #endif
 856                 METHOD(Racer, vr_setup, bool(Racer thisveh))
 857                 {
 858                 #ifdef SVQC
 859                         self.vehicle_exit = racer_exit;
 860                 #endif
 861
 862                 #ifdef SVQC
 863                         // we have no need to network energy
 864                         if(autocvar_g_vehicle_racer_energy)
 865                         if(autocvar_g_vehicle_racer_energy_regen)
 866                                 self.vehicle_flags |= VHF_ENERGYREGEN;
 867
 868                         if(autocvar_g_vehicle_racer_shield)
 869                                 self.vehicle_flags |= VHF_HASSHIELD;
 870
 871                         if(autocvar_g_vehicle_racer_shield_regen)
 872                                 self.vehicle_flags |= VHF_SHIELDREGEN;
 873
 874                         if(autocvar_g_vehicle_racer_health_regen)
 875                                 self.vehicle_flags |= VHF_HEALTHREGEN;
 876
 877                         self.respawntime = autocvar_g_vehicle_racer_respawntime;
 878                         self.vehicle_health = autocvar_g_vehicle_racer_health;
 879                         self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 880                         self.max_health = self.vehicle_health;
 881                 #endif
 882
 883                 #ifdef CSQC
 884                         AuxiliaryXhair[0].axh_image = vCROSS_LOCK; // Rocket
 885                 #endif
 886                         return true;
 887                 }
 888
 889                 METHOD(Racer, vr_precache, bool(Racer thisveh))
 890                 {
 891                         return true;
 892                 }
 893
 894 #endif // REGISTER_VEHICLE