qcsrc/common/vehicles/vehicle/bumblebee_weapons.qc

   1 #include "bumblebee_weapons.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 REGISTER_NET_LINKED(ENT_CLIENT_BUMBLE_RAYGUN)
   6
   7 #ifdef SVQC
   8
   9 void bumblebee_fire_cannon(entity this, entity _gun, string _tagname, entity _owner)
  10 {
  11     vector v = gettaginfo(_gun, gettagindex(_gun, _tagname));
  12     vehicles_projectile(this, EFFECT_BIGPLASMA_MUZZLEFLASH.eent_eff_name, SND_VEH_BUMBLEBEE_FIRE,
  13                         v, normalize(v_forward + randomvec() * autocvar_g_vehicle_bumblebee_cannon_spread) * autocvar_g_vehicle_bumblebee_cannon_speed,
  14                         autocvar_g_vehicle_bumblebee_cannon_damage, autocvar_g_vehicle_bumblebee_cannon_radius, autocvar_g_vehicle_bumblebee_cannon_force,  0,
  15                         DEATH_VH_BUMB_GUN.m_id, PROJECTILE_BUMBLE_GUN, 0, true, true, _owner);
  16 }
  17
  18 bool bumble_raygun_send(entity this, entity to, float sf)
  19 {
  20     WriteHeader(MSG_ENTITY, ENT_CLIENT_BUMBLE_RAYGUN);
  21
  22     WriteByte(MSG_ENTITY, sf);
  23     if(sf & BRG_SETUP)
  24     {
  25         WriteByte(MSG_ENTITY, etof(this.realowner));
  26         WriteByte(MSG_ENTITY, this.realowner.team);
  27         WriteByte(MSG_ENTITY, this.cnt);
  28     }
  29
  30     if(sf & BRG_START)
  31     {
  32         WriteCoord(MSG_ENTITY, this.hook_start_x);
  33         WriteCoord(MSG_ENTITY, this.hook_start_y);
  34         WriteCoord(MSG_ENTITY, this.hook_start_z);
  35     }
  36
  37     if(sf & BRG_END)
  38     {
  39         WriteCoord(MSG_ENTITY, this.hook_end_x);
  40         WriteCoord(MSG_ENTITY, this.hook_end_y);
  41         WriteCoord(MSG_ENTITY, this.hook_end_z);
  42     }
  43
  44     return true;
  45 }
  46
  47 #endif
  48
  49 #ifdef CSQC
  50
  51 void bumble_raygun_draw(entity this);
  52
  53 .vector bumble_origin;
  54
  55 NET_HANDLE(ENT_CLIENT_BUMBLE_RAYGUN, bool isnew)
  56 {
  57     int sf = ReadByte();
  58
  59     if(sf & BRG_SETUP)
  60     {
  61         this.cnt  = ReadByte();
  62         this.team = ReadByte();
  63         this.count  = ReadByte();
  64
  65         if(this.count)
  66             this.colormod = '1 0 0';
  67         else
  68             this.colormod = '0 1 0';
  69
  70         this.traileffect = EFFECT_BUMBLEBEE_HEAL_MUZZLEFLASH.m_id;
  71         this.lip = particleeffectnum(EFFECT_BUMBLEBEE_HEAL_IMPACT);
  72
  73         this.draw = bumble_raygun_draw;
  74         if (isnew) IL_PUSH(g_drawables, this);
  75     }
  76
  77
  78     if(sf & BRG_START)
  79     {
  80         this.origin_x = ReadCoord();
  81         this.origin_y = ReadCoord();
  82         this.origin_z = ReadCoord();
  83         setorigin(this, this.origin);
  84     }
  85
  86     if(sf & BRG_END)
  87     {
  88         this.bumble_origin_x = ReadCoord();
  89         this.bumble_origin_y = ReadCoord();
  90         this.bumble_origin_z = ReadCoord();
  91     }
  92     return true;
  93 }
  94
  95 .float bumble_raygun_nextdraw;
  96 void bumble_raygun_draw(entity this)
  97 {
  98     float _len;
  99     vector _dir;
 100     vector _vtmp1, _vtmp2;
 101
 102     _len = vlen(this.origin - this.bumble_origin);
 103     _dir = normalize(this.bumble_origin - this.origin);
 104
 105     if(this.bumble_raygun_nextdraw < time)
 106     {
 107         boxparticles(particleeffectnum(Effects_from(this.traileffect)), this, this.origin, this.origin + _dir * -64, _dir * -_len , _dir * -_len, 1, PARTICLES_USEALPHA);
 108         boxparticles(this.lip, this, this.bumble_origin, this.bumble_origin + _dir * -64, _dir * -200 , _dir * -200, 1, PARTICLES_USEALPHA);
 109         this.bumble_raygun_nextdraw = time + 0.1;
 110     }
 111
 112     float i, df, sz, al;
 113     for(i = -0.1; i < 0.2; i += 0.1)
 114     {
 115         df = DRAWFLAG_NORMAL; //((random() < 0.5) ? DRAWFLAG_ADDITIVE : DRAWFLAG_SCREEN);
 116         sz = 5 + random() * 5;
 117         al = 0.25 + random() * 0.5;
 118         _vtmp1 = this.origin + _dir * _len * (0.25 + i);
 119         _vtmp1 += (randomvec() * (_len * 0.2) * (frametime * 2));       //this.raygun_l1;
 120         Draw_CylindricLine(this.origin, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, this.colormod, al, df, view_origin);
 121
 122         _vtmp2 = this.origin + _dir * _len * (0.5 + i);
 123         _vtmp2 += (randomvec() * (_len * 0.2) * (frametime * 5));       //this.raygun_l2;
 124         Draw_CylindricLine(_vtmp1, _vtmp2, sz, "gfx/colors/white.tga", 1, 1, this.colormod, al, df, view_origin);
 125
 126         _vtmp1 = this.origin + _dir * _len * (0.75 + i);
 127         _vtmp1 += randomvec() * (_len * 0.2) * (frametime * 10);     //this.raygun_l3;
 128         Draw_CylindricLine(_vtmp2, _vtmp1, sz, "gfx/colors/white.tga", 1, 1, this.colormod, al, df, view_origin);
 129
 130         Draw_CylindricLine(_vtmp1, this.bumble_origin +  randomvec() * 32, sz, "gfx/colors/white.tga", 1, 1, this.colormod, al, df, view_origin);
 131     }
 132 }
 133
 134 #endif
 135
 136 #endif