qcsrc/common/vehicles/vehicle/bumblebee.qc

   1 #include "bumblebee.qh"
   2
   3 const float BRG_SETUP = 2;
   4 const float BRG_START = 4;
   5 const float BRG_END = 8;
   6
   7 #ifdef SVQC
   8 float autocvar_g_vehicle_bumblebee_respawntime = 60;
   9
  10 float autocvar_g_vehicle_bumblebee_speed_forward = 350;
  11 float autocvar_g_vehicle_bumblebee_speed_strafe = 350;
  12 float autocvar_g_vehicle_bumblebee_speed_up = 350;
  13 float autocvar_g_vehicle_bumblebee_speed_down = 350;
  14 float autocvar_g_vehicle_bumblebee_turnspeed = 120;
  15 float autocvar_g_vehicle_bumblebee_pitchspeed = 60;
  16 float autocvar_g_vehicle_bumblebee_pitchlimit = 60;
  17 float autocvar_g_vehicle_bumblebee_friction = 0.5;
  18 bool autocvar_g_vehicle_bumblebee_swim = false;
  19
  20 float autocvar_g_vehicle_bumblebee_energy = 500;
  21 float autocvar_g_vehicle_bumblebee_energy_regen = 50;
  22 float autocvar_g_vehicle_bumblebee_energy_regen_pause = 1;
  23
  24 float autocvar_g_vehicle_bumblebee_health = 1000;
  25 float autocvar_g_vehicle_bumblebee_health_regen = 65;
  26 float autocvar_g_vehicle_bumblebee_health_regen_pause = 10;
  27
  28 float autocvar_g_vehicle_bumblebee_shield = 400;
  29 float autocvar_g_vehicle_bumblebee_shield_regen = 150;
  30 float autocvar_g_vehicle_bumblebee_shield_regen_pause = 0.75;
  31
  32 float autocvar_g_vehicle_bumblebee_cannon_ammo = 100;
  33 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen = 100;
  34 float autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause = 1;
  35
  36 float autocvar_g_vehicle_bumblebee_cannon_lock = 0;
  37
  38 float autocvar_g_vehicle_bumblebee_cannon_turnspeed = 160;
  39 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down = 60;
  40 float autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up = 60;
  41 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_in = 20;
  42 float autocvar_g_vehicle_bumblebee_cannon_turnlimit_out = 80;
  43
  44
  45 float autocvar_g_vehicle_bumblebee_raygun_turnspeed = 180;
  46 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down = 20;
  47 float autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up = 5;
  48 float autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides = 35;
  49
  50 bool autocvar_g_vehicle_bumblebee_raygun = false;
  51 float autocvar_g_vehicle_bumblebee_raygun_range = 2048;
  52 float autocvar_g_vehicle_bumblebee_raygun_dps = 250;
  53 float autocvar_g_vehicle_bumblebee_raygun_aps = 100;
  54 float autocvar_g_vehicle_bumblebee_raygun_fps = 100;
  55
  56 float autocvar_g_vehicle_bumblebee_healgun_hps = 150;
  57 float autocvar_g_vehicle_bumblebee_healgun_hmax = 100;
  58 float autocvar_g_vehicle_bumblebee_healgun_aps = 75;
  59 float autocvar_g_vehicle_bumblebee_healgun_amax = 100;
  60 float autocvar_g_vehicle_bumblebee_healgun_sps = 100;
  61 float autocvar_g_vehicle_bumblebee_healgun_locktime = 2.5;
  62
  63 float autocvar_g_vehicle_bumblebee_blowup_radius = 500;
  64 float autocvar_g_vehicle_bumblebee_blowup_coredamage = 500;
  65 float autocvar_g_vehicle_bumblebee_blowup_edgedamage = 100;
  66 float autocvar_g_vehicle_bumblebee_blowup_forceintensity = 600;
  67 vector autocvar_g_vehicle_bumblebee_bouncepain = '1 100 200';
  68
  69 bool autocvar_g_vehicle_bumblebee = true;
  70
  71 bool bumblebee_gunner_frame(entity this, float dt)
  72 {
  73         entity vehic = this.vehicle.owner;
  74         entity gun = this.vehicle;
  75         return = true;
  76
  77         // this isn't technically a vehicle (yet), let's not do frame functions on it (yet)
  78         // vehicles_frame(gun, player);
  79
  80         vehic.solid = SOLID_NOT;
  81         // setorigin(this, vehic.origin);
  82         this.velocity = vehic.velocity;
  83
  84         float _in, _out;
  85         vehic.angles_x *= -1;
  86         makevectors(vehic.angles);
  87         vehic.angles_x *= -1;
  88         if (gun == vehic.gun1) {
  89                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  90                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  91                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * 128);
  92         } else {
  93                 _in = autocvar_g_vehicle_bumblebee_cannon_turnlimit_out;
  94                 _out = autocvar_g_vehicle_bumblebee_cannon_turnlimit_in;
  95                 setorigin(this, vehic.origin + v_up * -16 + v_forward * -16 + v_right * -128);
  96         }
  97         this.oldorigin = this.origin; // negate fall damage
  98
  99         crosshair_trace(this);
 100         vector _ct = trace_endpos;
 101         vector ad;
 102
 103         if (autocvar_g_vehicle_bumblebee_cannon_lock) {
 104                 if (gun.lock_time < time) {
 105                         gun.enemy = NULL;
 106                 }
 107
 108                 if (trace_ent) {
 109                         if (trace_ent.move_movetype) {
 110                                 if (trace_ent.takedamage) {
 111                                         if (!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent)) {
 112                                                 if (DIFF_TEAM(trace_ent, this)) {
 113                                                         gun.enemy = trace_ent;
 114                                                         gun.lock_time = time + 5;
 115                                                 }
 116                                         }
 117                                 }
 118                         }
 119                 }
 120         }
 121
 122         if (gun.enemy) {
 123                 float distance, impact_time;
 124
 125                 vector vf = real_origin(gun.enemy);
 126                 vector _vel = gun.enemy.velocity;
 127                 if (gun.enemy.move_movetype == MOVETYPE_WALK) {
 128                         _vel.z *= 0.1;
 129                 }
 130
 131
 132                 ad = vf;
 133                 distance = vlen(ad - this.origin);
 134                 impact_time = distance / autocvar_g_vehicle_bumblebee_cannon_speed;
 135                 ad = vf + _vel * impact_time;
 136                 trace_endpos = ad;
 137
 138
 139                 UpdateAuxiliaryXhair(this, ad, '1 0 1', 1);
 140                 vehicle_aimturret(vehic, trace_endpos, gun, "fire",
 141                         autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 142                         _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 143         } else {
 144                 vehicle_aimturret(vehic, _ct, gun, "fire",
 145                         autocvar_g_vehicle_bumblebee_cannon_pitchlimit_down * -1, autocvar_g_vehicle_bumblebee_cannon_pitchlimit_up,
 146                         _out * -1,  _in,  autocvar_g_vehicle_bumblebee_cannon_turnspeed);
 147         }
 148
 149         if (!forbidWeaponUse(this)) {
 150                 if (PHYS_INPUT_BUTTON_ATCK(this)) {
 151                         if (time > gun.attack_finished_single[0]) {
 152                                 if (gun.vehicle_energy >= autocvar_g_vehicle_bumblebee_cannon_cost) {
 153                                         gun.vehicle_energy -= autocvar_g_vehicle_bumblebee_cannon_cost;
 154                                         bumblebee_fire_cannon(vehic, gun, "fire", this);
 155                                         gun.delay = time;
 156                                         gun.attack_finished_single[0] = time + autocvar_g_vehicle_bumblebee_cannon_refire;
 157                                 }
 158                         }
 159                 }
 160         }
 161
 162         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 163
 164         if (vehic.vehicle_flags & VHF_HASSHIELD) {
 165                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 166         }
 167
 168         ad = gettaginfo(gun, gettagindex(gun, "fire"));
 169         traceline(ad, ad + v_forward * max_shot_distance, MOVE_NORMAL, gun);
 170
 171         UpdateAuxiliaryXhair(this, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' * (1 - this.vehicle_reload1)), 0);
 172
 173         if (vehic.owner) {
 174                 UpdateAuxiliaryXhair(vehic.owner, trace_endpos, ('1 0 0' * this.vehicle_reload1) + ('0 1 0' * (1 - this.vehicle_reload1)), ((this == vehic.gunner1) ? 1 : 2));
 175         }
 176
 177         vehic.solid = SOLID_BBOX;
 178         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 179         this.vehicle_energy = (gun.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 180 }
 181
 182 vector bumblebee_gunner_findgoodexit(vector prefer_spot, entity gunner, entity player)
 183 {
 184         // vector exitspot;
 185         float mysize;
 186
 187         tracebox(gunner.origin + '0 0 32', STAT(PL_MIN, player), STAT(PL_MAX, player), prefer_spot, MOVE_NORMAL, player);
 188         if (trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid) {
 189                 return prefer_spot;
 190         }
 191
 192         mysize = 1.5 * vlen(STAT(PL_MAX, player) - STAT(PL_MIN, player)); // can't use gunner's size, as they don't have a size
 193         float i;
 194         vector v, v2;
 195         v2 = 0.5 * (gunner.absmin + gunner.absmax);
 196         for (i = 0; i < 100; ++i) {
 197                 v = randomvec();
 198                 v_z = 0;
 199                 v = v2 + normalize(v) * mysize;
 200                 tracebox(v2, STAT(PL_MIN, player), STAT(PL_MAX, player), v, MOVE_NORMAL, player);
 201                 if (trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid) {
 202                         return v;
 203                 }
 204         }
 205
 206         return prefer_spot; // this should be considered a fallback?!
 207 }
 208
 209 void bumblebee_gunner_exit(entity this, int _exitflag)
 210 {
 211         entity player = ((this.owner.gun1 == this) ? this.owner.gunner1 : this.owner.gunner2);
 212         entity gunner = this;
 213         entity vehic = gunner.owner;
 214
 215         if (IS_REAL_CLIENT(player)) {
 216                 msg_entity = player;
 217                 WriteByte(MSG_ONE, SVC_SETVIEWPORT);
 218                 WriteEntity(MSG_ONE, player);
 219
 220                 WriteByte(MSG_ONE, SVC_SETVIEWANGLES);
 221                 WriteAngle(MSG_ONE, 0);
 222                 WriteAngle(MSG_ONE, vehic.angles.y);
 223                 WriteAngle(MSG_ONE, 0);
 224         }
 225
 226         CSQCVehicleSetup(player, HUD_NORMAL);
 227         setsize(player, STAT(PL_MIN, player), STAT(PL_MAX, player));
 228
 229         player.takedamage     = DAMAGE_AIM;
 230         player.solid          = SOLID_SLIDEBOX;
 231         set_movetype(player, MOVETYPE_WALK);
 232         player.effects       &= ~EF_NODRAW;
 233         player.alpha          = 1;
 234         player.PlayerPhysplug = func_null;
 235         player.view_ofs       = STAT(PL_VIEW_OFS, player);
 236         player.event_damage   = PlayerDamage;
 237         player.hud            = HUD_NORMAL;
 238         player.teleportable   = TELEPORT_NORMAL;
 239         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot) {
 240                 .entity weaponentity = weaponentities[slot];
 241                 player.(weaponentity).m_switchweapon = gunner.(weaponentity).m_switchweapon;
 242                 delete(gunner.(weaponentity));
 243         }
 244         player.vehicle_enter_delay = time + 2;
 245
 246         fixedmakevectors(vehic.angles);
 247
 248         if (player == vehic.gunner1) { vehic.gunner1 = NULL; }
 249         if (player == vehic.gunner2) { vehic.gunner2 = NULL; v_right *= -1; }
 250
 251         vector spot = real_origin(gunner);
 252         spot = spot + v_up * 128 + v_forward * 300 + v_right * 150;
 253         spot = bumblebee_gunner_findgoodexit(spot, gunner, player);
 254
 255         // TODO: figure a way to move player out of the gunner
 256
 257         player.velocity = 0.75 * vehic.velocity + normalize(spot - vehic.origin) * 200;
 258         player.velocity_z += 10;
 259
 260         gunner.phase = time + 5;
 261         gunner.vehicle_hudmodel.viewmodelforclient = gunner;
 262
 263         MUTATOR_CALLHOOK(VehicleExit, player, gunner);
 264
 265         player.vehicle = NULL;
 266 }
 267
 268 bool bumblebee_gunner_enter(entity this, entity player)
 269 {
 270         entity vehic = this;
 271         entity gunner = NULL;
 272
 273         if (!vehic.gunner1 && !vehic.gunner2 && ((time >= vehic.gun1.phase) + (time >= vehic.gun2.phase)) == 2) {
 274                 // we can have some fun
 275                 vector v1 = gettaginfo(vehic, gettagindex(vehic, "cannon_right"));
 276                 vector v2 = gettaginfo(vehic, gettagindex(vehic, "cannon_left"));
 277                 if (vlen2(player.origin - v1) < vlen2(player.origin - v2)) {
 278                         gunner = vehic.gun1;
 279                         vehic.gunner1 = player;
 280                 } else {
 281                         gunner = vehic.gun2;
 282                         vehic.gunner2 = player;
 283                 }
 284         } else if (!vehic.gunner1 && time >= vehic.gun1.phase) {
 285                 gunner = vehic.gun1;
 286                 vehic.gunner1 = player;
 287         } else if (!vehic.gunner2 && time >= vehic.gun2.phase) {
 288                 gunner = vehic.gun2;
 289                 vehic.gunner2 = player;
 290         } else { LOG_TRACE("Vehicle is full, fail"); return false; }
 291
 292         player.vehicle          = gunner;
 293         player.angles           = vehic.angles;
 294         player.takedamage       = DAMAGE_NO;
 295         player.solid            = SOLID_NOT;
 296         player.alpha            = -1;
 297         set_movetype(player, MOVETYPE_NOCLIP);
 298         player.event_damage     = func_null;
 299         player.view_ofs         = '0 0 0';
 300         player.hud              = gunner.hud;
 301         player.teleportable     = false;
 302         player.PlayerPhysplug   = gunner.PlayerPhysplug;
 303         player.vehicle_ammo1    = vehic.vehicle_ammo1;
 304         player.vehicle_ammo2    = vehic.vehicle_ammo2;
 305         player.vehicle_reload1  = vehic.vehicle_reload1;
 306         player.vehicle_reload2  = vehic.vehicle_reload2;
 307         player.vehicle_energy   = vehic.vehicle_energy;
 308         UNSET_ONGROUND(player);
 309
 310         RemoveGrapplingHooks(player);
 311
 312         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot) {
 313                 .entity weaponentity = weaponentities[slot];
 314
 315                 gunner.(weaponentity) = new(temp_wepent);
 316                 gunner.(weaponentity).m_switchweapon = player.(weaponentity).m_switchweapon;
 317         }
 318         gunner.vehicle_exit = bumblebee_gunner_exit;
 319         gunner.vehicle_hudmodel.viewmodelforclient = player;
 320
 321         if (IS_REAL_CLIENT(player)) {
 322                 msg_entity = player;
 323                 WriteByte(MSG_ONE,      SVC_SETVIEWPORT);
 324                 WriteEntity(MSG_ONE,    gunner.vehicle_viewport);
 325
 326                 WriteByte(MSG_ONE,      SVC_SETVIEWANGLES);
 327                 WriteAngle(MSG_ONE,     gunner.angles_x + vehic.angles_x); // tilt
 328                 WriteAngle(MSG_ONE,     gunner.angles_y + vehic.angles_y); // yaw
 329                 WriteAngle(MSG_ONE,     0);                                // roll
 330         }
 331
 332         CSQCVehicleSetup(player, player.hud);
 333
 334         MUTATOR_CALLHOOK(VehicleEnter, player, gunner);
 335
 336         return true;
 337 }
 338
 339 bool vehicles_valid_pilot(entity this, entity toucher)
 340 {
 341         if (IS_BOT_CLIENT(toucher) && !autocvar_g_vehicles_allow_bots) {
 342                 return false;
 343         }
 344
 345         if ((!IS_PLAYER(toucher))
 346                 || (IS_DEAD(toucher))
 347                 || (toucher.vehicle)
 348                 || (DIFF_TEAM(toucher, this))
 349         ) { return false; }
 350
 351         return true;
 352 }
 353
 354 void bumblebee_touch(entity this, entity toucher)
 355 {
 356         if (autocvar_g_vehicles_enter) { return; }
 357
 358         if (this.gunner1 != NULL && this.gunner2 != NULL) {
 359                 vehicles_touch(this, toucher);
 360                 return;
 361         }
 362
 363         if (vehicles_valid_pilot(this, toucher)) {
 364                 float phase_time = (time >= this.gun1.phase) + (time >= this.gun2.phase);
 365
 366                 if (time >= toucher.vehicle_enter_delay && phase_time) {
 367                         if (bumblebee_gunner_enter(this, toucher)) {
 368                                 return;
 369                         }
 370                 }
 371         }
 372
 373         vehicles_touch(this, toucher);
 374 }
 375
 376 void bumblebee_regen(entity this, float dt)
 377 {
 378         if (this.gun1.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time) {
 379                 this.gun1.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 380                         this.gun1.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 381         }
 382
 383         if (this.gun2.delay + autocvar_g_vehicle_bumblebee_cannon_ammo_regen_pause < time) {
 384                 this.gun2.vehicle_energy = min(autocvar_g_vehicle_bumblebee_cannon_ammo,
 385                         this.gun2.vehicle_energy + autocvar_g_vehicle_bumblebee_cannon_ammo_regen * dt);
 386         }
 387
 388         if (this.vehicle_flags  & VHF_SHIELDREGEN) {
 389                 vehicles_regen(this, this.dmg_time, vehicle_shield, autocvar_g_vehicle_bumblebee_shield, autocvar_g_vehicle_bumblebee_shield_regen_pause, autocvar_g_vehicle_bumblebee_shield_regen, dt, true);
 390         }
 391
 392         if (this.vehicle_flags  & VHF_HEALTHREGEN) {
 393                 vehicles_regen(this, this.dmg_time, vehicle_health, autocvar_g_vehicle_bumblebee_health, autocvar_g_vehicle_bumblebee_health_regen_pause, autocvar_g_vehicle_bumblebee_health_regen, dt, false);
 394         }
 395
 396         if (this.vehicle_flags  & VHF_ENERGYREGEN) {
 397                 vehicles_regen(this, this.wait, vehicle_energy, autocvar_g_vehicle_bumblebee_energy, autocvar_g_vehicle_bumblebee_energy_regen_pause, autocvar_g_vehicle_bumblebee_energy_regen, dt, false);
 398         }
 399 }
 400
 401 bool bumblebee_pilot_frame(entity this, float dt)
 402 {
 403         entity vehic = this.vehicle;
 404         return = true;
 405
 406         if (game_stopped) {
 407                 vehic.solid = SOLID_NOT;
 408                 vehic.takedamage = DAMAGE_NO;
 409                 set_movetype(vehic, MOVETYPE_NONE);
 410                 return;
 411         }
 412
 413         vehicles_frame(vehic, this);
 414
 415         if (IS_DEAD(vehic)) {
 416                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 417                 return;
 418         }
 419
 420         bumblebee_regen(vehic, dt);
 421
 422         crosshair_trace(this);
 423
 424         vector vang = vehic.angles;
 425         vector newvel = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 426         vang.x *= -1;
 427         newvel.x *= -1;
 428         if (newvel.x > 180) { newvel.x -= 360; }
 429         if (newvel.x < -180) { newvel.x += 360; }
 430         if (newvel.y > 180) { newvel.y -= 360; }
 431         if (newvel.y < -180) { newvel.y += 360; }
 432
 433         float ftmp = shortangle_f(this.v_angle.y - vang.y, vang.y);
 434         if (ftmp > 180) { ftmp -= 360; }
 435         if (ftmp < -180) { ftmp += 360; }
 436         vehic.avelocity_y = bound(-autocvar_g_vehicle_bumblebee_turnspeed, ftmp + vehic.avelocity.y * 0.9, autocvar_g_vehicle_bumblebee_turnspeed);
 437
 438         // Pitch
 439         ftmp = 0;
 440         if (CS(this).movement.x > 0 && vang.x < autocvar_g_vehicle_bumblebee_pitchlimit) {
 441                 ftmp = 4;
 442         } else if (CS(this).movement.x < 0 && vang.x > -autocvar_g_vehicle_bumblebee_pitchlimit) {
 443                 ftmp = -8;
 444         }
 445
 446         newvel.x = bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x, autocvar_g_vehicle_bumblebee_pitchlimit);
 447         ftmp = vang.x - bound(-autocvar_g_vehicle_bumblebee_pitchlimit, newvel.x + ftmp, autocvar_g_vehicle_bumblebee_pitchlimit);
 448         vehic.avelocity_x = bound(-autocvar_g_vehicle_bumblebee_pitchspeed, ftmp + vehic.avelocity.x * 0.9, autocvar_g_vehicle_bumblebee_pitchspeed);
 449
 450         vehic.angles_x = anglemods(vehic.angles.x);
 451         vehic.angles_y = anglemods(vehic.angles.y);
 452         vehic.angles_z = anglemods(vehic.angles.z);
 453
 454         makevectors('0 1 0' * vehic.angles.y);
 455         newvel = vehic.velocity * -autocvar_g_vehicle_bumblebee_friction;
 456
 457         if (CS(this).movement.x != 0) {
 458                 if (CS(this).movement.x > 0) {
 459                         newvel += v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 460                 } else if (CS(this).movement.x < 0) {
 461                         newvel -= v_forward  * autocvar_g_vehicle_bumblebee_speed_forward;
 462                 }
 463         }
 464
 465         if (CS(this).movement.y != 0) {
 466                 if (CS(this).movement.y < 0) {
 467                         newvel -= v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 468                 } else if (CS(this).movement.y > 0) {
 469                         newvel += v_right * autocvar_g_vehicle_bumblebee_speed_strafe;
 470                 }
 471                 ftmp = newvel * v_right;
 472                 ftmp *= dt * 0.1;
 473                 vehic.angles_z = bound(-15, vehic.angles.z + ftmp, 15);
 474         } else {
 475                 vehic.angles_z *= 0.95;
 476                 if (vehic.angles.z >= -1 && vehic.angles.z <= -1) {
 477                         vehic.angles_z = 0;
 478                 }
 479         }
 480
 481         if (PHYS_INPUT_BUTTON_CROUCH(this)) {
 482                 newvel -=   v_up * autocvar_g_vehicle_bumblebee_speed_down;
 483         } else if (PHYS_INPUT_BUTTON_JUMP(this)) {
 484                 newvel +=  v_up * autocvar_g_vehicle_bumblebee_speed_up;
 485         }
 486
 487         vehic.velocity  += newvel * dt;
 488         this.velocity = CS(this).movement  = vehic.velocity;
 489
 490
 491         if (autocvar_g_vehicle_bumblebee_healgun_locktime) {
 492                 if (vehic.tur_head.lock_time < time || IS_DEAD(vehic.tur_head.enemy) || STAT(FROZEN, vehic.tur_head.enemy)) {
 493                         vehic.tur_head.enemy = NULL;
 494                 }
 495
 496                 if (trace_ent) {
 497                         if (trace_ent.move_movetype) {
 498                                 if (trace_ent.takedamage) {
 499                                         if (!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent)) {
 500                                                 if (teamplay) {
 501                                                         if (trace_ent.team == this.team) {
 502                                                                 vehic.tur_head.enemy = trace_ent;
 503                                                                 vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 504                                                         }
 505                                                 } else {
 506                                                         vehic.tur_head.enemy = trace_ent;
 507                                                         vehic.tur_head.lock_time = time + autocvar_g_vehicle_bumblebee_healgun_locktime;
 508                                                 }
 509                                         }
 510                                 }
 511                         }
 512                 }
 513
 514                 if (vehic.tur_head.enemy) {
 515                         trace_endpos = real_origin(vehic.tur_head.enemy);
 516                         UpdateAuxiliaryXhair(this, trace_endpos, '0 0.75 0', 0);
 517                 }
 518         }
 519
 520         vang = vehicle_aimturret(vehic, trace_endpos, vehic.gun3, "fire",
 521                 autocvar_g_vehicle_bumblebee_raygun_pitchlimit_down * -1,  autocvar_g_vehicle_bumblebee_raygun_pitchlimit_up,
 522                 autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides * -1,  autocvar_g_vehicle_bumblebee_raygun_turnlimit_sides,  autocvar_g_vehicle_bumblebee_raygun_turnspeed);
 523
 524         if (!forbidWeaponUse(this)) {
 525                 if ((PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) && (vehic.vehicle_energy > autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME || autocvar_g_vehicle_bumblebee_raygun == 0)) {
 526                         vehic.gun3.enemy.realowner = this;
 527                         vehic.gun3.enemy.effects &= ~EF_NODRAW;
 528
 529                         vehic.gun3.enemy.hook_start = gettaginfo(vehic.gun3, gettagindex(vehic.gun3, "fire"));
 530                         vehic.gun3.enemy.SendFlags |= BRG_START;
 531
 532                         traceline(vehic.gun3.enemy.hook_start, vehic.gun3.enemy.hook_start + v_forward * autocvar_g_vehicle_bumblebee_raygun_range, MOVE_NORMAL, vehic);
 533
 534                         if (trace_ent) {
 535                                 if (autocvar_g_vehicle_bumblebee_raygun) {
 536                                         Damage(trace_ent, vehic, this, autocvar_g_vehicle_bumblebee_raygun_dps * PHYS_INPUT_FRAMETIME, DEATH_GENERIC.m_id, trace_endpos, v_forward * autocvar_g_vehicle_bumblebee_raygun_fps * PHYS_INPUT_FRAMETIME);
 537                                         vehic.vehicle_energy -= autocvar_g_vehicle_bumblebee_raygun_aps * PHYS_INPUT_FRAMETIME;
 538                                 } else {
 539                                         if (!IS_DEAD(trace_ent)) {
 540                                                 if ((teamplay && trace_ent.team == this.team) || !teamplay) {
 541                                                         if (IS_VEHICLE(trace_ent)) {
 542                                                                 if (autocvar_g_vehicle_bumblebee_healgun_sps && trace_ent.vehicle_health <= trace_ent.max_health) {
 543                                                                         trace_ent.vehicle_shield = min(trace_ent.vehicle_shield + autocvar_g_vehicle_bumblebee_healgun_sps * dt, trace_ent.tur_head.max_health);
 544                                                                 }
 545
 546                                                                 if (autocvar_g_vehicle_bumblebee_healgun_hps) {
 547                                                                         trace_ent.vehicle_health = min(trace_ent.vehicle_health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 548                                                                 }
 549                                                         } else if (IS_CLIENT(trace_ent)) {
 550                                                                 if (trace_ent.health <= autocvar_g_vehicle_bumblebee_healgun_hmax && autocvar_g_vehicle_bumblebee_healgun_hps) {
 551                                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 552                                                                 }
 553
 554                                                                 if (trace_ent.armorvalue <= autocvar_g_vehicle_bumblebee_healgun_amax && autocvar_g_vehicle_bumblebee_healgun_aps) {
 555                                                                         trace_ent.armorvalue = min(trace_ent.armorvalue + autocvar_g_vehicle_bumblebee_healgun_aps * dt, autocvar_g_vehicle_bumblebee_healgun_amax);
 556                                                                 }
 557
 558                                                                 trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, autocvar_g_vehicle_bumblebee_healgun_hmax);
 559                                                         } else if (IS_TURRET(trace_ent)) {
 560                                                                 if (trace_ent.health  <= trace_ent.max_health && autocvar_g_vehicle_bumblebee_healgun_hps) {
 561                                                                         trace_ent.health = min(trace_ent.health + autocvar_g_vehicle_bumblebee_healgun_hps * dt, trace_ent.max_health);
 562                                                                 }
 563                                                                 // else ..hmmm what? ammo?
 564
 565                                                                 trace_ent.SendFlags |= TNSF_STATUS;
 566                                                         }
 567                                                 }
 568                                         }
 569                                 }
 570                         }
 571
 572                         vehic.gun3.enemy.hook_end = trace_endpos;
 573                         setorigin(vehic.gun3.enemy, trace_endpos);
 574                         vehic.gun3.enemy.SendFlags |= BRG_END;
 575
 576                         vehic.wait = time + 1;
 577                 } else {
 578                         vehic.gun3.enemy.effects |= EF_NODRAW;
 579                 }
 580         }
 581         /*{
 582             if(vehic.gun3.enemy)
 583                 remove(vehic.gun3.enemy);
 584
 585             vehic.gun3.enemy = NULL;
 586         }
 587         */
 588
 589         VEHICLE_UPDATE_PLAYER(this, vehic, health, bumblebee);
 590         VEHICLE_UPDATE_PLAYER(this, vehic, energy, bumblebee);
 591
 592         this.vehicle_ammo1 = (vehic.gun1.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 593         this.vehicle_ammo2 = (vehic.gun2.vehicle_energy / autocvar_g_vehicle_bumblebee_cannon_ammo) * 100;
 594
 595         if (vehic.vehicle_flags & VHF_HASSHIELD) {
 596                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, bumblebee);
 597         }
 598
 599         vehic.angles_x *= -1;
 600         makevectors(vehic.angles);
 601         vehic.angles_x *= -1;
 602         setorigin(this, vehic.origin + v_up * 48 + v_forward * 160);
 603         this.oldorigin = this.origin; // negate fall damage
 604
 605         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 606 }
 607
 608 void bumblebee_land(entity this)
 609 {
 610         float hgt;
 611
 612         hgt = vehicle_altitude(this, 512);
 613         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * PHYS_INPUT_FRAMETIME);
 614         this.angles_x *= 0.95;
 615         this.angles_z *= 0.95;
 616
 617         if (hgt < 16) {
 618                 setthink(this, vehicles_think);
 619         }
 620
 621         this.nextthink = time;
 622
 623         CSQCMODEL_AUTOUPDATE(this);
 624 }
 625
 626 void bumblebee_exit(entity this, int eject)
 627 {
 628         if (this.owner.vehicleid == VEH_BUMBLEBEE.vehicleid) {
 629                 bumblebee_gunner_exit(this, eject);
 630                 return;
 631         }
 632
 633         settouch(this, vehicles_touch);
 634
 635         if (!IS_DEAD(this)) {
 636                 setthink(this, bumblebee_land);
 637                 this.nextthink  = time;
 638         }
 639
 640         set_movetype(this, MOVETYPE_TOSS);
 641
 642         if (!this.owner) {
 643                 return;
 644         }
 645
 646         fixedmakevectors(this.angles);
 647         vector spot;
 648         if (vdist(this.velocity, >, autocvar_g_vehicle_bumblebee_speed_forward * 0.5)) {
 649                 spot = this.origin + v_up * 128 + v_forward * 300;
 650         } else {
 651                 spot = this.origin + v_up * 128 - v_forward * 300;
 652         }
 653
 654         spot = vehicles_findgoodexit(this, this.owner, spot);
 655
 656         // Hide beam
 657         if (this.gun3.enemy || !wasfreed(this.gun3.enemy)) {
 658                 this.gun3.enemy.effects |= EF_NODRAW;
 659         }
 660
 661         this.owner.velocity = 0.75 * this.vehicle.velocity + normalize(spot - this.vehicle.origin) * 200;
 662         this.owner.velocity_z += 10;
 663         setorigin(this.owner, spot);
 664
 665         antilag_clear(this.owner, CS(this.owner));
 666         this.owner = NULL;
 667 }
 668
 669 void bumblebee_blowup(entity this)
 670 {
 671         RadiusDamage(this, this.enemy, autocvar_g_vehicle_bumblebee_blowup_coredamage,
 672                 autocvar_g_vehicle_bumblebee_blowup_edgedamage,
 673                 autocvar_g_vehicle_bumblebee_blowup_radius, this, NULL,
 674                 autocvar_g_vehicle_bumblebee_blowup_forceintensity,
 675                 DEATH_VH_BUMB_DEATH.m_id, NULL);
 676
 677         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 678         Send_Effect(EFFECT_EXPLOSION_BIG, (this.origin + '0 0 100') + (randomvec() * 80), '0 0 0', 1);
 679
 680         if (this.owner.deadflag == DEAD_DYING) {
 681                 this.owner.deadflag = DEAD_DEAD;
 682         }
 683
 684         delete(this);
 685 }
 686
 687 void bumblebee_dead_touch(entity this, entity toucher)
 688 {
 689         bumblebee_blowup(this);
 690 }
 691
 692 void bumblebee_diethink(entity this)
 693 {
 694         if (time >= this.wait) {
 695                 setthink(this, bumblebee_blowup);
 696         }
 697
 698         if (random() < 0.1) {
 699                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 700                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 701         }
 702
 703         this.nextthink = time + 0.1;
 704 }
 705
 706 spawnfunc(vehicle_bumblebee)
 707 {
 708         if (!autocvar_g_vehicle_bumblebee) { delete(this); return; }
 709         if (!vehicle_initialize(this, VEH_BUMBLEBEE, false)) { delete(this); return; }
 710 }
 711
 712 METHOD(Bumblebee, vr_impact, void(Bumblebee thisveh, entity instance))
 713 {
 714         if (autocvar_g_vehicle_bumblebee_bouncepain) {
 715                 vehicles_impact(instance, autocvar_g_vehicle_bumblebee_bouncepain_x, autocvar_g_vehicle_bumblebee_bouncepain_y, autocvar_g_vehicle_bumblebee_bouncepain_z);
 716         }
 717 }
 718 METHOD(Bumblebee, vr_enter, void(Bumblebee thisveh, entity instance))
 719 {
 720         settouch(instance, bumblebee_touch);
 721         instance.nextthink = 0;
 722         set_movetype(instance, MOVETYPE_BOUNCEMISSILE);
 723 }
 724 METHOD(Bumblebee, vr_gunner_enter, void(Bumblebee thisveh, entity instance, entity actor))
 725 {
 726         if (!instance.gunner1) {
 727                 if (time >= instance.gun1.phase) {
 728                         if (instance.gun1.vehicle_enter) {
 729                                 if (instance.gun1.vehicle_enter(instance, actor)) {
 730                                         return;
 731                                 }
 732                         }
 733                 }
 734         }
 735
 736         if (!instance.gunner2) {
 737                 if (time >= instance.gun2.phase) {
 738                         if (instance.gun2.vehicle_enter) {
 739                                 if (instance.gun2.vehicle_enter(instance, actor)) {
 740                                         return;
 741                                 }
 742                         }
 743                 }
 744         }
 745 }
 746 METHOD(Bumblebee, vr_think, void(Bumblebee thisveh, entity instance))
 747 {
 748         instance.angles_z *= 0.8;
 749         instance.angles_x *= 0.8;
 750
 751         instance.nextthink = time;
 752
 753         if (!instance.owner) {
 754                 if (instance.gunner1) {
 755                         entity e = instance.gunner1;
 756                         instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 757                         instance.phase = 0;
 758                         gettouch(instance)(instance, e);
 759                         return;
 760                 }
 761
 762                 if (instance.gunner2) {
 763                         entity e = instance.gunner2;
 764                         instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 765                         instance.phase = 0;
 766                         gettouch(instance)(instance, e);
 767                         return;
 768                 }
 769         }
 770 }
 771 METHOD(Bumblebee, vr_death, void(Bumblebee thisveh, entity instance))
 772 {
 773         CSQCModel_UnlinkEntity(instance);
 774
 775         // hide beam
 776         if (instance.gun3.enemy || !wasfreed(instance.gun3.enemy)) {
 777                 instance.gun3.enemy.effects |= EF_NODRAW;
 778         }
 779
 780         if (instance.gunner1) {
 781                 instance.gun1.vehicle_exit(instance.gun1, VHEF_EJECT);
 782         }
 783
 784         if (instance.gunner2) {
 785                 instance.gun2.vehicle_exit(instance.gun2, VHEF_EJECT);
 786         }
 787
 788         instance.vehicle_exit(instance, VHEF_EJECT);
 789
 790         fixedmakevectors(instance.angles);
 791         vehicle_tossgib(instance, instance.gun1, instance.velocity + v_right * 300 + v_up * 100 + randomvec() * 200, "cannon_right", rint(random()), rint(random()), 6, randomvec() * 200);
 792         vehicle_tossgib(instance, instance.gun2, instance.velocity + v_right * -300 + v_up * 100 + randomvec() * 200, "cannon_left", rint(random()), rint(random()), 6, randomvec() * 200);
 793         vehicle_tossgib(instance, instance.gun3, instance.velocity + v_forward * 300 + v_up * -100 + randomvec() * 200, "raygun", rint(random()), rint(random()), 6, randomvec() * 300);
 794
 795         entity _body = vehicle_tossgib(instance, instance, instance.velocity + randomvec() * 200, "", rint(random()), rint(random()), 6, randomvec() * 100);
 796
 797         if (random() > 0.5) {
 798                 settouch(_body, bumblebee_dead_touch);
 799         } else {
 800                 settouch(_body, func_null);
 801         }
 802
 803         setthink(_body, bumblebee_diethink);
 804         _body.nextthink = time;
 805         _body.wait = time + 2 + (random() * 8);
 806         _body.owner = instance;
 807         _body.enemy = instance.enemy;
 808         _body.scale = 1.5;
 809         _body.angles = instance.angles;
 810
 811         Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation(instance.origin, 16), '0 0 0', 1);
 812
 813         instance.health         = 0;
 814         instance.event_damage   = func_null;
 815         instance.solid          = SOLID_NOT;
 816         instance.takedamage     = DAMAGE_NO;
 817         instance.deadflag       = DEAD_DYING;
 818         set_movetype(instance, MOVETYPE_NONE);
 819         instance.effects        = EF_NODRAW;
 820         instance.colormod       = '0 0 0';
 821         instance.avelocity      = '0 0 0';
 822         instance.velocity       = '0 0 0';
 823         settouch(instance, func_null);
 824         instance.nextthink      = 0;
 825
 826         setorigin(instance, instance.pos1);
 827 }
 828 METHOD(Bumblebee, vr_spawn, void(Bumblebee thisveh, entity instance))
 829 {
 830         if (!instance.gun1) {
 831                 // for some reason, autosizing of the shield entity refuses to work for this one so set it up in advance.
 832                 instance.vehicle_shieldent = spawn();
 833                 instance.vehicle_shieldent.effects = EF_LOWPRECISION;
 834                 setmodel(instance.vehicle_shieldent, MDL_VEH_BUMBLEBEE_SHIELD);
 835                 setattachment(instance.vehicle_shieldent, instance, "");
 836                 setorigin(instance.vehicle_shieldent, real_origin(instance) - instance.origin);
 837                 instance.vehicle_shieldent.scale       = 512 / vlen(instance.maxs - instance.mins);
 838                 setthink(instance.vehicle_shieldent, shieldhit_think);
 839                 instance.vehicle_shieldent.alpha = -1;
 840                 instance.vehicle_shieldent.effects = EF_LOWPRECISION | EF_NODRAW;
 841
 842                 instance.gun1 = new(vehicle_playerslot);
 843                 instance.gun2 = new(vehicle_playerslot);
 844                 instance.gun3 = new(bumblebee_raygun);
 845
 846                 instance.vehicle_flags |= VHF_MULTISLOT;
 847
 848                 instance.gun1.owner = instance;
 849                 instance.gun2.owner = instance;
 850                 instance.gun3.owner = instance;
 851
 852                 setmodel(instance.gun1, MDL_VEH_BUMBLEBEE_CANNON_RIGHT);
 853                 setmodel(instance.gun2, MDL_VEH_BUMBLEBEE_CANNON_LEFT);
 854                 setmodel(instance.gun3, MDL_VEH_BUMBLEBEE_CANNON_CENTER);
 855
 856                 setattachment(instance.gun1, instance, "cannon_right");
 857                 setattachment(instance.gun2, instance, "cannon_left");
 858
 859                 // Angled bones are no fun, messes up gun-aim; so work arround it.
 860                 instance.gun3.pos1 = instance.angles;
 861                 instance.angles = '0 0 0';
 862                 vector ofs = gettaginfo(instance, gettagindex(instance, "raygun"));
 863                 ofs -= instance.origin;
 864                 setattachment(instance.gun3, instance, "");
 865                 setorigin(instance.gun3, ofs);
 866                 instance.angles = instance.gun3.pos1;
 867
 868                 vehicle_addplayerslot(instance, instance.gun1, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 869                 vehicle_addplayerslot(instance, instance.gun2, HUD_BUMBLEBEE_GUN, MDL_VEH_BUMBLEBEE_GUNCOCKPIT, bumblebee_gunner_frame, bumblebee_gunner_exit, bumblebee_gunner_enter);
 870
 871                 setorigin(instance.vehicle_hudmodel, '50 0 -5'); // Move cockpit forward - down.
 872                 setorigin(instance.vehicle_viewport, '5 0 2');   // Move camera forward up
 873
 874                 // fixme-model-bones
 875                 setorigin(instance.gun1.vehicle_hudmodel, '90 -27 -23');
 876                 setorigin(instance.gun1.vehicle_viewport, '-85 0 50');
 877                 // fixme-model-bones
 878                 setorigin(instance.gun2.vehicle_hudmodel, '90 27 -23');
 879                 setorigin(instance.gun2.vehicle_viewport, '-85 0 50');
 880
 881                 instance.scale = 1.5;
 882
 883                 // Raygun beam
 884                 if (instance.gun3.enemy == NULL) {
 885                         instance.gun3.enemy = spawn();
 886                         Net_LinkEntity(instance.gun3.enemy, true, 0, bumble_raygun_send);
 887                         instance.gun3.enemy.SendFlags = BRG_SETUP;
 888                         instance.gun3.enemy.cnt = autocvar_g_vehicle_bumblebee_raygun;
 889                         instance.gun3.enemy.effects = EF_NODRAW | EF_LOWPRECISION;
 890                 }
 891         }
 892
 893         if (!autocvar_g_vehicle_bumblebee_swim) {
 894                 instance.dphitcontentsmask |= DPCONTENTS_LIQUIDSMASK;
 895         }
 896
 897         instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 898         instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 899         instance.solid = SOLID_BBOX;
 900         set_movetype(instance, MOVETYPE_TOSS);
 901         instance.damageforcescale = 0.025;
 902
 903         instance.PlayerPhysplug = bumblebee_pilot_frame;
 904
 905         setorigin(instance, instance.origin + '0 0 25');
 906 }
 907 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 908 {
 909         if (autocvar_g_vehicle_bumblebee_energy) {
 910                 if (autocvar_g_vehicle_bumblebee_energy_regen) {
 911                         instance.vehicle_flags |= VHF_ENERGYREGEN;
 912                 }
 913         }
 914
 915         if (autocvar_g_vehicle_bumblebee_shield) {
 916                 instance.vehicle_flags |= VHF_HASSHIELD;
 917         }
 918
 919         if (autocvar_g_vehicle_bumblebee_shield_regen) {
 920                 instance.vehicle_flags |= VHF_SHIELDREGEN;
 921         }
 922
 923         if (autocvar_g_vehicle_bumblebee_health_regen) {
 924                 instance.vehicle_flags |= VHF_HEALTHREGEN;
 925         }
 926
 927         instance.vehicle_exit = bumblebee_exit;
 928         instance.respawntime = autocvar_g_vehicle_bumblebee_respawntime;
 929         instance.vehicle_health = autocvar_g_vehicle_bumblebee_health;
 930         instance.max_health = instance.vehicle_health;
 931         instance.vehicle_shield = autocvar_g_vehicle_bumblebee_shield;
 932 }
 933
 934 #endif // SVQC
 935 #ifdef CSQC
 936
 937 void CSQC_BUMBLE_GUN_HUD()
 938 {
 939         Vehicles_drawHUD("vehicle_gunner", "vehicle_gunner_weapon1", string_null,
 940                 "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 941                 string_null, '0 0 0');
 942 }
 943
 944 METHOD(Bumblebee, vr_hud, void(Bumblebee thisveh))
 945 {
 946         Vehicles_drawHUD(VEH_BUMBLEBEE.m_icon, "vehicle_bumble_weapon1", "vehicle_bumble_weapon2",
 947                 "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 948                 "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color);
 949
 950         float hudAlpha = autocvar_hud_panel_fg_alpha;
 951         float blinkValue = 0.55 + sin(time * 7) * 0.45;
 952         vector tmpPos  = '0 0 0';
 953         vector tmpSize = '1 1 1' * hud_fontsize;
 954         tmpPos.x = vehicleHud_Pos.x + vehicleHud_Size.x * (520 / 768);
 955
 956         if (!AuxiliaryXhair[1].draw2d) {
 957                 tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (96 / 256) - tmpSize.y;
 958                 drawstring(tmpPos, _("No right gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 959         }
 960
 961         if (!AuxiliaryXhair[2].draw2d) {
 962                 tmpPos.y = vehicleHud_Pos.y + vehicleHud_Size.y * (160 / 256);
 963                 drawstring(tmpPos, _("No left gunner!"), tmpSize, '1 1 1', hudAlpha * blinkValue, DRAWFLAG_NORMAL);
 964         }
 965 }
 966 METHOD(Bumblebee, vr_crosshair, void(Bumblebee thisveh, entity player))
 967 {
 968         Vehicles_drawCrosshair(vCROSS_HEAL);
 969 }
 970 METHOD(Bumblebee, vr_setup, void(Bumblebee thisveh, entity instance))
 971 {
 972         AuxiliaryXhair[0].axh_image = vCROSS_LOCK;  // Raygun-locked
 973         AuxiliaryXhair[1].axh_image = vCROSS_BURST; // Gunner1
 974         AuxiliaryXhair[2].axh_image = vCROSS_BURST; // Gunner2
 975 }
 976
 977 #endif