qcsrc/common/triggers/trigger/jumppads.qc

   1 #include "jumppads.qh"
   2 // TODO: split target_push and put it in the target folder
   3 #ifdef SVQC
   4 #include "jumppads.qh"
   5 #include <common/physics/movetypes/movetypes.qh>
   6
   7 void trigger_push_use(entity this, entity actor, entity trigger)
   8 {
   9         if(teamplay)
  10         {
  11                 this.team = actor.team;
  12                 this.SendFlags |= 2;
  13         }
  14 }
  15 #endif
  16
  17 REGISTER_NET_LINKED(ENT_CLIENT_TRIGGER_PUSH)
  18 REGISTER_NET_LINKED(ENT_CLIENT_TARGET_PUSH)
  19
  20 /*
  21         trigger_push_calculatevelocity
  22
  23         Arguments:
  24           org - origin of the object which is to be pushed
  25           tgt - target entity (can be either a point or a model entity; if it is
  26                 the latter, its midpoint is used)
  27           ht  - jump height, measured from the higher one of org and tgt's midpoint
  28
  29         Returns: velocity for the jump
  30         the global trigger_push_calculatevelocity_flighttime is set to the total
  31         jump time
  32  */
  33
  34 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  35 {
  36         float grav, sdist, zdist, vs, vz, jumpheight;
  37         vector sdir, torg;
  38
  39         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  40
  41         grav = PHYS_GRAVITY(other);
  42         if(PHYS_ENTGRAVITY(other))
  43                 grav *= PHYS_ENTGRAVITY(other);
  44
  45         zdist = torg.z - org.z;
  46         sdist = vlen(torg - org - zdist * '0 0 1');
  47         sdir = normalize(torg - org - zdist * '0 0 1');
  48
  49         // how high do we need to push the player?
  50         jumpheight = fabs(ht);
  51         if(zdist > 0)
  52                 jumpheight = jumpheight + zdist;
  53
  54         /*
  55                 STOP.
  56
  57                 You will not understand the following equations anyway...
  58                 But here is what I did to get them.
  59
  60                 I used the functions
  61
  62                   s(t) = t * vs
  63                   z(t) = t * vz - 1/2 grav t^2
  64
  65                 and solved for:
  66
  67                   s(ti) = sdist
  68                   z(ti) = zdist
  69                   max(z, ti) = jumpheight
  70
  71                 From these three equations, you will find the three parameters vs, vz
  72                 and ti.
  73          */
  74
  75         // push him so high...
  76         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
  77
  78         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  79         if(ht < 0)
  80                 if(zdist < 0)
  81                         vz = -vz;
  82
  83         vector solution;
  84         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  85         // ALWAYS solvable because jumpheight >= zdist
  86         if(!solution.z)
  87                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  88         if(zdist == 0)
  89                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  90
  91         if(zdist < 0)
  92         {
  93                 // down-jump
  94                 if(ht < 0)
  95                 {
  96                         // almost straight line type
  97                         // jump apex is before the jump
  98                         // we must take the larger one
  99                         trigger_push_calculatevelocity_flighttime = solution.y;
 100                 }
 101                 else
 102                 {
 103                         // regular jump
 104                         // jump apex is during the jump
 105                         // we must take the larger one too
 106                         trigger_push_calculatevelocity_flighttime = solution.y;
 107                 }
 108         }
 109         else
 110         {
 111                 // up-jump
 112                 if(ht < 0)
 113                 {
 114                         // almost straight line type
 115                         // jump apex is after the jump
 116                         // we must take the smaller one
 117                         trigger_push_calculatevelocity_flighttime = solution.x;
 118                 }
 119                 else
 120                 {
 121                         // regular jump
 122                         // jump apex is during the jump
 123                         // we must take the larger one
 124                         trigger_push_calculatevelocity_flighttime = solution.y;
 125                 }
 126         }
 127         vs = sdist / trigger_push_calculatevelocity_flighttime;
 128
 129         // finally calculate the velocity
 130         return sdir * vs + '0 0 1' * vz;
 131 }
 132
 133 bool jumppad_push(entity this, entity targ)
 134 {
 135         if (!isPushable(targ))
 136                 return false;
 137
 138         if(this.enemy)
 139         {
 140                 targ.velocity = trigger_push_calculatevelocity(targ.origin, this.enemy, this.height);
 141         }
 142         else if(this.target && this.target != "")
 143         {
 144                 entity e;
 145                 RandomSelection_Init();
 146                 for(e = NULL; (e = find(e, targetname, this.target)); )
 147                 {
 148                         if(e.cnt)
 149                                 RandomSelection_AddEnt(e, e.cnt, 1);
 150                         else
 151                                 RandomSelection_AddEnt(e, 1, 1);
 152                 }
 153                 targ.velocity = trigger_push_calculatevelocity(targ.origin, RandomSelection_chosen_ent, this.height);
 154         }
 155         else
 156         {
 157                 targ.velocity = this.movedir;
 158         }
 159
 160         UNSET_ONGROUND(targ);
 161
 162 #ifdef CSQC
 163         if (targ.flags & FL_PROJECTILE)
 164         {
 165                 targ.angles = vectoangles (targ.velocity);
 166                 switch(targ.move_movetype)
 167                 {
 168                         case MOVETYPE_FLY:
 169                                 set_movetype(targ, MOVETYPE_TOSS);
 170                                 targ.gravity = 1;
 171                                 break;
 172                         case MOVETYPE_BOUNCEMISSILE:
 173                                 set_movetype(targ, MOVETYPE_BOUNCE);
 174                                 targ.gravity = 1;
 175                                 break;
 176                 }
 177         }
 178 #endif
 179
 180 #ifdef SVQC
 181         if (IS_PLAYER(targ))
 182         {
 183                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 184                 targ.oldvelocity = targ.velocity;
 185
 186                 if(this.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 187                 {
 188                         // flash when activated
 189                         Send_Effect(EFFECT_JUMPPAD, targ.origin, targ.velocity, 1);
 190                         _sound (targ, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 191                         this.pushltime = time + 0.2;
 192                 }
 193                 if(IS_REAL_CLIENT(targ) || IS_BOT_CLIENT(targ))
 194                 {
 195                         bool found = false;
 196                         for(int i = 0; i < targ.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 197                                 if(targ.(jumppadsused[i]) == this)
 198                                         found = true;
 199                         if(!found)
 200                         {
 201                                 targ.(jumppadsused[targ.jumppadcount % NUM_JUMPPADSUSED]) = this;
 202                                 targ.jumppadcount = targ.jumppadcount + 1;
 203                         }
 204
 205                         if(IS_REAL_CLIENT(targ))
 206                         {
 207                                 if(this.message)
 208                                         centerprint(targ, this.message);
 209                         }
 210                         else
 211                                 targ.lastteleporttime = time;
 212
 213                         if (!IS_DEAD(targ))
 214                                 animdecide_setaction(targ, ANIMACTION_JUMP, true);
 215                 }
 216                 else
 217                         targ.jumppadcount = true;
 218
 219                 // reset tracking of who pushed you into a hazard (for kill credit)
 220                 targ.pushltime = 0;
 221                 targ.istypefrag = 0;
 222         }
 223
 224         if(this.enemy.target)
 225                 SUB_UseTargets(this.enemy, targ, targ); // TODO: do we need targ as trigger too?
 226
 227         if (targ.flags & FL_PROJECTILE)
 228         {
 229                 targ.angles = vectoangles (targ.velocity);
 230                 targ.com_phys_gravity_factor = 1;
 231                 switch(targ.move_movetype)
 232                 {
 233                         case MOVETYPE_FLY:
 234                                 set_movetype(targ, MOVETYPE_TOSS);
 235                                 targ.gravity = 1;
 236                                 break;
 237                         case MOVETYPE_BOUNCEMISSILE:
 238                                 set_movetype(targ, MOVETYPE_BOUNCE);
 239                                 targ.gravity = 1;
 240                                 break;
 241                 }
 242                 UpdateCSQCProjectile(targ);
 243         }
 244 #endif
 245
 246         return true;
 247 }
 248
 249 void trigger_push_touch(entity this, entity toucher)
 250 {
 251         if (this.active == ACTIVE_NOT)
 252                 return;
 253
 254         if(this.team)
 255                 if(((this.spawnflags & 4) == 0) == (DIFF_TEAM(this, toucher)))
 256                         return;
 257
 258         EXACTTRIGGER_TOUCH(this, toucher);
 259
 260         noref bool success = jumppad_push(this, toucher);
 261
 262 #ifdef SVQC
 263         if (success && (this.spawnflags & PUSH_ONCE))
 264         {
 265                 settouch(this, func_null);
 266                 setthink(this, SUB_Remove);
 267                 this.nextthink = time;
 268         }
 269 #endif
 270 }
 271
 272 #ifdef SVQC
 273 void trigger_push_link(entity this);
 274 void trigger_push_updatelink(entity this);
 275 #endif
 276 void trigger_push_findtarget(entity this)
 277 {
 278         // first calculate a typical start point for the jump
 279         vector org = (this.absmin + this.absmax) * 0.5;
 280         org.z = this.absmax.z - PL_MIN_CONST.z;
 281
 282         if (this.target)
 283         {
 284                 int n = 0;
 285                 for(entity t = NULL; (t = find(t, targetname, this.target)); )
 286                 {
 287                         ++n;
 288 #ifdef SVQC
 289                         entity e = spawn();
 290                         setorigin(e, org);
 291                         setsize(e, PL_MIN_CONST, PL_MAX_CONST);
 292                         e.velocity = trigger_push_calculatevelocity(org, t, this.height);
 293                         tracetoss(e, e);
 294                         if(e.move_movetype == MOVETYPE_NONE)
 295                                 waypoint_spawnforteleporter(this, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 296                         delete(e);
 297 #endif
 298                 }
 299
 300                 if(!n)
 301                 {
 302                         // no dest!
 303 #ifdef SVQC
 304                         objerror (this, "Jumppad with nonexistant target");
 305 #endif
 306                         return;
 307                 }
 308                 else if(n == 1)
 309                 {
 310                         // exactly one dest - bots love that
 311                         this.enemy = find(NULL, targetname, this.target);
 312                 }
 313                 else
 314                 {
 315                         // have to use random selection every single time
 316                         this.enemy = NULL;
 317                 }
 318         }
 319 #ifdef SVQC
 320         else
 321         {
 322                 entity e = spawn();
 323                 setorigin(e, org);
 324                 setsize(e, PL_MIN_CONST, PL_MAX_CONST);
 325                 e.velocity = this.movedir;
 326                 tracetoss(e, e);
 327                 waypoint_spawnforteleporter(this, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 328                 delete(e);
 329         }
 330
 331         defer(this, 0.1, trigger_push_updatelink);
 332 #endif
 333 }
 334
 335 #ifdef SVQC
 336 float trigger_push_send(entity this, entity to, float sf)
 337 {
 338         WriteHeader(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
 339
 340         WriteByte(MSG_ENTITY, this.team);
 341         WriteInt24_t(MSG_ENTITY, this.spawnflags);
 342         WriteByte(MSG_ENTITY, this.active);
 343         WriteCoord(MSG_ENTITY, this.height);
 344
 345         WriteCoord(MSG_ENTITY, this.movedir_x);
 346         WriteCoord(MSG_ENTITY, this.movedir_y);
 347         WriteCoord(MSG_ENTITY, this.movedir_z);
 348
 349         trigger_common_write(this, true);
 350
 351         return true;
 352 }
 353
 354 void trigger_push_updatelink(entity this)
 355 {
 356         this.SendFlags |= 1;
 357 }
 358
 359 void trigger_push_link(entity this)
 360 {
 361         trigger_link(this, trigger_push_send);
 362 }
 363
 364 /*
 365  * ENTITY PARAMETERS:
 366  *
 367  *   target:  target of jump
 368  *   height:  the absolute value is the height of the highest point of the jump
 369  *            trajectory above the higher one of the player and the target.
 370  *            the sign indicates whether the highest point is INSIDE (positive)
 371  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 372  *            positive values for targets mounted on the floor, and use negative
 373  *            values to target a point on the ceiling.
 374  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 375  */
 376 spawnfunc(trigger_push)
 377 {
 378         SetMovedir(this);
 379
 380         trigger_init(this);
 381
 382         this.active = ACTIVE_ACTIVE;
 383         this.use = trigger_push_use;
 384         settouch(this, trigger_push_touch);
 385
 386         // normal push setup
 387         if (!this.speed)
 388                 this.speed = 1000;
 389         this.movedir = this.movedir * this.speed * 10;
 390
 391         if (!this.noise)
 392                 this.noise = "misc/jumppad.wav";
 393         precache_sound (this.noise);
 394
 395         trigger_push_link(this); // link it now
 396
 397         // this must be called to spawn the teleport waypoints for bots
 398         InitializeEntity(this, trigger_push_findtarget, INITPRIO_FINDTARGET);
 399 }
 400
 401
 402 bool target_push_send(entity this, entity to, float sf)
 403 {
 404         WriteHeader(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
 405
 406         WriteByte(MSG_ENTITY, this.cnt);
 407         WriteString(MSG_ENTITY, this.targetname);
 408         WriteCoord(MSG_ENTITY, this.origin_x);
 409         WriteCoord(MSG_ENTITY, this.origin_y);
 410         WriteCoord(MSG_ENTITY, this.origin_z);
 411
 412         WriteAngle(MSG_ENTITY, this.angles_x);
 413         WriteAngle(MSG_ENTITY, this.angles_y);
 414         WriteAngle(MSG_ENTITY, this.angles_z);
 415
 416         return true;
 417 }
 418
 419 void target_push_use(entity this, entity actor, entity trigger)
 420 {
 421         jumppad_push(this, actor);
 422 }
 423
 424 void target_push_link(entity this)
 425 {
 426         BITSET_ASSIGN(this.effects, EF_NODEPTHTEST);
 427         Net_LinkEntity(this, false, 0, target_push_send);
 428         //this.SendFlags |= 1; // update
 429 }
 430
 431 void target_push_init(entity this)
 432 {
 433         this.mangle = this.angles;
 434         setorigin(this, this.origin);
 435         target_push_link(this);
 436 }
 437
 438 void target_push_init2(entity this)
 439 {
 440         if(this.target && this.target != "") // we have an old style pusher!
 441         {
 442                 InitializeEntity(this, trigger_push_findtarget, INITPRIO_FINDTARGET);
 443                 this.use = target_push_use;
 444         }
 445
 446         target_push_init(this); // normal push target behaviour can be combined with a legacy pusher?
 447 }
 448
 449 spawnfunc(target_push) { target_push_init2(this); }
 450 spawnfunc(info_notnull) { target_push_init(this); }
 451 spawnfunc(target_position) { target_push_init(this); }
 452
 453 #elif defined(CSQC)
 454
 455 NET_HANDLE(ENT_CLIENT_TRIGGER_PUSH, bool isnew)
 456 {
 457         this.classname = "jumppad";
 458         int mytm = ReadByte(); if(mytm) { this.team = mytm - 1; }
 459         this.spawnflags = ReadInt24_t();
 460         this.active = ReadByte();
 461         this.height = ReadCoord();
 462
 463         this.movedir_x = ReadCoord();
 464         this.movedir_y = ReadCoord();
 465         this.movedir_z = ReadCoord();
 466
 467         trigger_common_read(this, true);
 468
 469         this.entremove = trigger_remove_generic;
 470         this.solid = SOLID_TRIGGER;
 471         settouch(this, trigger_push_touch);
 472         this.move_time = time;
 473         defer(this, 0.25, trigger_push_findtarget);
 474
 475         return true;
 476 }
 477
 478 void target_push_remove(entity this)
 479 {
 480         if(this.classname)
 481                 strunzone(this.classname);
 482         this.classname = string_null;
 483
 484         if(this.targetname)
 485                 strunzone(this.targetname);
 486         this.targetname = string_null;
 487 }
 488
 489 NET_HANDLE(ENT_CLIENT_TARGET_PUSH, bool isnew)
 490 {
 491         this.classname = "push_target";
 492         this.cnt = ReadByte();
 493         this.targetname = strzone(ReadString());
 494         this.origin_x = ReadCoord();
 495         this.origin_y = ReadCoord();
 496         this.origin_z = ReadCoord();
 497
 498         this.angles_x = ReadAngle();
 499         this.angles_y = ReadAngle();
 500         this.angles_z = ReadAngle();
 501
 502         return = true;
 503
 504         setorigin(this, this.origin);
 505
 506         this.drawmask = MASK_NORMAL;
 507         this.entremove = target_push_remove;
 508 }
 509 #endif