qcsrc/common/triggers/func/breakable.qc

   1 #ifdef SVQC
   2 #include "../../../server/weapons/common.qh"
   3
   4 .entity sprite;
   5
   6 .float dmg;
   7 .float dmg_edge;
   8 .float dmg_radius;
   9 .float dmg_force;
  10 .float debrismovetype;
  11 .float debrissolid;
  12 .vector debrisvelocity;
  13 .vector debrisvelocityjitter;
  14 .vector debrisavelocityjitter;
  15 .float debristime;
  16 .float debristimejitter;
  17 .float debrisfadetime;
  18 .float debrisdamageforcescale;
  19 .float debrisskin;
  20
  21 .string mdl_dead; // or "" to hide when broken
  22 .string debris; // space separated list of debris models
  23 // other fields:
  24 //   mdl = particle effect name
  25 //   count = particle effect multiplier
  26 //   targetname = target to trigger to unbreak the model
  27 //   target = targets to trigger when broken
  28 //   health = amount of damage it can take
  29 //   spawnflags:
  30 //     1 = start disabled (needs to be triggered to activate)
  31 //     2 = indicate damage
  32 // notes:
  33 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  34 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  35 //   want that!
  36
  37 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  38
  39 //
  40 // func_breakable
  41 // - basically func_assault_destructible for general gameplay use
  42 //
  43 void LaunchDebris (string debrisname, vector force)
  44 {
  45         entity dbr = spawn();
  46         setorigin(dbr, self.absmin
  47                    + '1 0 0' * random() * (self.absmax.x - self.absmin.x)
  48                    + '0 1 0' * random() * (self.absmax.y - self.absmin.y)
  49                    + '0 0 1' * random() * (self.absmax.z - self.absmin.z));
  50         setmodel (dbr, debrisname );
  51         dbr.skin = self.debrisskin;
  52         dbr.colormap = self.colormap; // inherit team colors
  53         dbr.owner = self; // do not be affected by our own explosion
  54         dbr.movetype = self.debrismovetype;
  55         dbr.solid = self.debrissolid;
  56         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  57                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  58         dbr.velocity_x = self.debrisvelocity.x + self.debrisvelocityjitter.x * crandom();
  59         dbr.velocity_y = self.debrisvelocity.y + self.debrisvelocityjitter.y * crandom();
  60         dbr.velocity_z = self.debrisvelocity.z + self.debrisvelocityjitter.z * crandom();
  61         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  62         dbr.avelocity_x = random()*self.debrisavelocityjitter.x;
  63         dbr.avelocity_y = random()*self.debrisavelocityjitter.y;
  64         dbr.avelocity_z = random()*self.debrisavelocityjitter.z;
  65         dbr.damageforcescale = self.debrisdamageforcescale;
  66         if(dbr.damageforcescale)
  67                 dbr.takedamage = DAMAGE_YES;
  68         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  69 }
  70
  71 void func_breakable_colormod()
  72 {
  73         float h;
  74         if (!(self.spawnflags & 2))
  75                 return;
  76         h = self.health / self.max_health;
  77         if(h < 0.25)
  78                 self.colormod = '1 0 0';
  79         else if(h <= 0.75)
  80                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  81         else
  82                 self.colormod = '1 1 1';
  83
  84         CSQCMODEL_AUTOUPDATE();
  85 }
  86
  87 void func_breakable_look_destroyed()
  88 {
  89         float floorZ;
  90
  91         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
  92                 self.dropped_origin = self.origin;
  93
  94         if(self.mdl_dead == "")
  95                 self.model = "";
  96         else {
  97                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
  98                         floorZ = self.absmin.z;
  99                         setorigin(self,((self.absmax+self.absmin)*.5));
 100                         self.origin_z = floorZ;
 101                 }
 102                 setmodel(self, self.mdl_dead);
 103         }
 104
 105         self.solid = SOLID_NOT;
 106 }
 107
 108 void func_breakable_look_restore()
 109 {
 110         setmodel(self, self.mdl);
 111         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 112                 setorigin(self, self.dropped_origin);
 113         self.solid = SOLID_BSP;
 114 }
 115
 116 void func_breakable_behave_destroyed()
 117 {
 118         self.health = self.max_health;
 119         self.takedamage = DAMAGE_NO;
 120         self.bot_attack = false;
 121         self.event_damage = func_null;
 122         self.state = 1;
 123         func_breakable_colormod();
 124 }
 125
 126 void func_breakable_behave_restore()
 127 {
 128         self.health = self.max_health;
 129         if(self.sprite)
 130         {
 131                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 132                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 133         }
 134         self.takedamage = DAMAGE_AIM;
 135         self.bot_attack = true;
 136         self.event_damage = func_breakable_damage;
 137         self.state = 0;
 138         self.nextthink = 0; // cancel auto respawn
 139         func_breakable_colormod();
 140 }
 141
 142 void func_breakable_destroyed()
 143 {
 144         func_breakable_look_destroyed();
 145         func_breakable_behave_destroyed();
 146
 147         CSQCMODEL_AUTOUPDATE();
 148 }
 149
 150 void func_breakable_restore()
 151 {
 152         func_breakable_look_restore();
 153         func_breakable_behave_restore();
 154
 155         CSQCMODEL_AUTOUPDATE();
 156 }
 157
 158 vector debrisforce; // global, set before calling this
 159 void func_breakable_destroy() {
 160         float n, i;
 161         string oldmsg;
 162
 163         activator = self.owner;
 164         self.owner = world; // set by W_PrepareExplosionByDamage
 165
 166         // now throw around the debris
 167         n = tokenize_console(self.debris);
 168         for(i = 0; i < n; ++i)
 169                 LaunchDebris(argv(i), debrisforce);
 170
 171         func_breakable_destroyed();
 172
 173         if(self.noise)
 174                 sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 175
 176         if(self.dmg)
 177                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, world, self.dmg_force, DEATH_HURTTRIGGER, world);
 178
 179         if(self.cnt)
 180                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 181
 182         if(self.respawntime)
 183         {
 184                 self.think = func_breakable_restore;
 185                 self.nextthink = time + self.respawntime + crandom() * self.respawntimejitter;
 186         }
 187
 188         oldmsg = self.message;
 189         self.message = "";
 190         SUB_UseTargets();
 191         self.message = oldmsg;
 192 }
 193
 194 void func_breakable_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 195 {
 196         if(self.state == 1)
 197                 return;
 198         if(self.spawnflags & DOOR_NOSPLASH)
 199                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 200                         return;
 201         if(self.team)
 202                 if(attacker.team == self.team)
 203                         return;
 204         self.health = self.health - damage;
 205         if(self.sprite)
 206         {
 207                 WaypointSprite_Ping(self.sprite);
 208                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 209         }
 210         func_breakable_colormod();
 211
 212         if(self.health <= 0)
 213         {
 214                 debrisforce = force;
 215                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 216         }
 217 }
 218
 219 void func_breakable_reset()
 220 {
 221         self.team = self.team_saved;
 222         func_breakable_look_restore();
 223         if(self.spawnflags & 1)
 224                 func_breakable_behave_destroyed();
 225         else
 226                 func_breakable_behave_restore();
 227
 228         CSQCMODEL_AUTOUPDATE();
 229 }
 230
 231 // destructible walls that can be used to trigger target_objective_decrease
 232 void spawnfunc_func_breakable() {
 233         float n, i;
 234         if(!self.health)
 235                 self.health = 100;
 236         self.max_health = self.health;
 237
 238         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 239         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 240         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 241         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 242         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 243         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 244         if(!self.debristime) self.debristime = 3.5;
 245         if(!self.debristimejitter) self.debristime = 2.5;
 246
 247         if(self.mdl != "")
 248                 self.cnt = particleeffectnum(self.mdl);
 249         if(self.count == 0)
 250                 self.count = 1;
 251
 252         if(self.message == "")
 253                 self.message = "got too close to an explosion";
 254         if(self.message2 == "")
 255                 self.message2 = "was pushed into an explosion by";
 256         if(!self.dmg_radius)
 257                 self.dmg_radius = 150;
 258         if(!self.dmg_force)
 259                 self.dmg_force = 200;
 260
 261         self.mdl = self.model;
 262         SetBrushEntityModel();
 263
 264         self.use = func_breakable_restore;
 265
 266         // precache all the models
 267         if (self.mdl_dead)
 268                 precache_model(self.mdl_dead);
 269         n = tokenize_console(self.debris);
 270         for(i = 0; i < n; ++i)
 271                 precache_model(argv(i));
 272         if(self.noise)
 273                 precache_sound(self.noise);
 274
 275         self.team_saved = self.team;
 276         self.dropped_origin = self.origin;
 277
 278         self.reset = func_breakable_reset;
 279         func_breakable_reset();
 280
 281         CSQCMODEL_AUTOINIT();
 282 }
 283
 284 // for use in maps with a "model" key set
 285 void spawnfunc_misc_breakablemodel() {
 286         spawnfunc_func_breakable();
 287 }
 288 #endif