qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
 635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
 636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
 637
 638 float adjust_respawntime(float normal_respawntime) {
 639         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
 640         float o = autocvar_g_pickup_respawntime_scaling_offset;
 641         float l = autocvar_g_pickup_respawntime_scaling_linear;
 642
 643         if (r == 0 && l == 1) {
 644                 return normal_respawntime;
 645         }
 646
 647         CheckAllowedTeams(NULL);
 648         GetTeamCounts(NULL);
 649         int players = 0;
 650         if (c1 != -1) players += c1;
 651         if (c2 != -1) players += c2;
 652         if (c3 != -1) players += c3;
 653         if (c4 != -1) players += c4;
 654
 655         if (players >= 2) {
 656                 return normal_respawntime * (r / (players + o) + l);
 657         } else {
 658                 return normal_respawntime;
 659         }
 660 }
 661
 662 void Item_ScheduleRespawn(entity e)
 663 {
 664         if(e.respawntime > 0)
 665         {
 666                 Item_Show(e, 0);
 667
 668                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
 669                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
 670
 671                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
 672                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
 673                 Item_ScheduleRespawnIn(e, actual_time);
 674         }
 675         else // if respawntime is -1, this item does not respawn
 676                 Item_Show(e, -1);
 677 }
 678
 679 void Item_ScheduleInitialRespawn(entity e)
 680 {
 681         Item_Show(e, 0);
 682         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 683 }
 684
 685 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax)
 686 {
 687         if (!item.(ammotype))
 688                 return false;
 689
 690         if (item.spawnshieldtime)
 691         {
 692                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 693                 {
 694                         float amount = item.(ammotype);
 695                         if ((player.(ammotype) + amount) > ammomax)
 696                         {
 697                                 amount = ammomax - player.(ammotype);
 698                         }
 699                         GiveResource(player, GetResourceType(ammotype), amount);
 700                         return true;
 701                 }
 702         }
 703         else if(g_weapon_stay == 2)
 704         {
 705                 float mi = min(item.(ammotype), ammomax);
 706                 if (player.(ammotype) < mi)
 707                 {
 708                         GiveResource(player, GetResourceType(ammotype), mi -
 709                                 player.(ammotype));
 710                 }
 711                 return true;
 712         }
 713         return false;
 714 }
 715
 716 float Item_GiveTo(entity item, entity player)
 717 {
 718         float pickedup;
 719
 720         // if nothing happens to player, just return without taking the item
 721         pickedup = false;
 722         int _switchweapon = 0;
 723         // in case the player has autoswitch enabled do the following:
 724         // if the player is using their best weapon before items are given, they
 725         // probably want to switch to an even better weapon after items are given
 726
 727         if(CS(player).autoswitch)
 728         {
 729                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 730                 {
 731                         .entity weaponentity = weaponentities[slot];
 732                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 733                         {
 734                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 735                                         _switchweapon |= BIT(slot);
 736
 737                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 738                                         _switchweapon |= BIT(slot);
 739                         }
 740                 }
 741         }
 742         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health);
 743         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue);
 744         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max);
 745         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max);
 746         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max);
 747         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max);
 748         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max);
 749         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max);
 750         if (item.itemdef.instanceOfWeaponPickup)
 751         {
 752                 WepSet w;
 753                 w = item.weapons;
 754                 w &= ~player.weapons;
 755
 756                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 757                 {
 758                         pickedup = true;
 759                         FOREACH(Weapons, it != WEP_Null, {
 760                                 if(w & (it.m_wepset))
 761                                 {
 762                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 763                                         {
 764                                                 .entity weaponentity = weaponentities[slot];
 765                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 766                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 767                                         }
 768                                         W_GiveWeapon(player, it.m_id);
 769                                 }
 770                         });
 771                 }
 772         }
 773
 774         if (item.itemdef.instanceOfPowerup)
 775         {
 776                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 777                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 778                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 779                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 780         }
 781
 782         int its;
 783         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 784         {
 785                 pickedup = true;
 786                 player.items |= its;
 787                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 788         }
 789
 790         if (item.strength_finished)
 791         {
 792                 pickedup = true;
 793                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 794         }
 795         if (item.invincible_finished)
 796         {
 797                 pickedup = true;
 798                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 799         }
 800         if (item.superweapons_finished)
 801         {
 802                 pickedup = true;
 803                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 804         }
 805
 806 LABEL(skip)
 807
 808         // always eat teamed entities
 809         if(item.team)
 810                 pickedup = true;
 811
 812         if (!pickedup)
 813                 return 0;
 814
 815         // crude hack to enforce switching weapons
 816         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 817         {
 818                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 819                 {
 820                         .entity weaponentity = weaponentities[slot];
 821                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 822                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 823                 }
 824                 return 1;
 825         }
 826
 827         if(_switchweapon)
 828         {
 829                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 830                 {
 831                         .entity weaponentity = weaponentities[slot];
 832                         if(_switchweapon & BIT(slot))
 833                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 834                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 835                 }
 836         }
 837
 838         return 1;
 839 }
 840
 841 void Item_Touch(entity this, entity toucher)
 842 {
 843
 844         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 845         if (this.classname == "droppedweapon")
 846         {
 847                 if (ITEM_TOUCH_NEEDKILL())
 848                 {
 849                         delete(this);
 850                         return;
 851                 }
 852         }
 853
 854         if(!(toucher.flags & FL_PICKUPITEMS)
 855         || STAT(FROZEN, toucher)
 856         || IS_DEAD(toucher)
 857         || (this.solid != SOLID_TRIGGER)
 858         || (this.owner == toucher)
 859         || (time < this.item_spawnshieldtime)
 860         ) { return; }
 861
 862         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 863         {
 864                 case MUT_ITEMTOUCH_RETURN: { return; }
 865                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 866         }
 867
 868         toucher = M_ARGV(1, entity);
 869
 870         if (this.classname == "droppedweapon")
 871         {
 872                 this.strength_finished = max(0, this.strength_finished - time);
 873                 this.invincible_finished = max(0, this.invincible_finished - time);
 874                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 875         }
 876         entity it = this.itemdef;
 877         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 878         if (!gave)
 879         {
 880                 if (this.classname == "droppedweapon")
 881                 {
 882                         // undo what we did above
 883                         this.strength_finished += time;
 884                         this.invincible_finished += time;
 885                         this.superweapons_finished += time;
 886                 }
 887                 return;
 888         }
 889
 890 LABEL(pickup)
 891
 892         toucher.last_pickup = time;
 893
 894         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 895         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 896
 897         if (this.classname == "droppedweapon")
 898                 delete(this);
 899         else if (this.spawnshieldtime)
 900         {
 901                 entity e;
 902                 if(this.team)
 903                 {
 904                         RandomSelection_Init();
 905                         IL_EACH(g_items, it.team == this.team,
 906                         {
 907                                 if(it.itemdef) // is a registered item
 908                                 {
 909                                         Item_Show(it, -1);
 910                                         RandomSelection_AddEnt(it, it.cnt, 0);
 911                                 }
 912                         });
 913                         e = RandomSelection_chosen_ent;
 914                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 915                 }
 916                 else
 917                         e = this;
 918                 Item_ScheduleRespawn(e);
 919         }
 920 }
 921
 922 void Item_Reset(entity this)
 923 {
 924         Item_Show(this, !this.state);
 925         setorigin(this, this.origin);
 926
 927         if (this.classname != "droppedweapon")
 928         {
 929                 setthink(this, Item_Think);
 930                 this.nextthink = time;
 931
 932                 if (this.waypointsprite_attached)
 933                         WaypointSprite_Kill(this.waypointsprite_attached);
 934
 935                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 936                         Item_ScheduleInitialRespawn(this);
 937         }
 938 }
 939
 940 void Item_FindTeam(entity this)
 941 {
 942         entity e;
 943
 944         if(this.effects & EF_NODRAW)
 945         {
 946                 // marker for item team search
 947                 LOG_TRACE("Initializing item team ", ftos(this.team));
 948                 RandomSelection_Init();
 949                 IL_EACH(g_items, it.team == this.team,
 950                 {
 951                         if(it.itemdef) // is a registered item
 952                                 RandomSelection_AddEnt(it, it.cnt, 0);
 953                 });
 954
 955                 e = RandomSelection_chosen_ent;
 956                 e.state = 0;
 957                 Item_Show(e, 1);
 958
 959                 IL_EACH(g_items, it.team == this.team,
 960                 {
 961                         if(it.itemdef) // is a registered item
 962                         {
 963                                 if(it != e)
 964                                 {
 965                                         // make it non-spawned
 966                                         Item_Show(it, -1);
 967                                         it.state = 1; // state 1 = initially hidden item, apparently
 968                                 }
 969                                 it.effects &= ~EF_NODRAW;
 970                         }
 971                 });
 972
 973                 Item_Reset(this);
 974         }
 975 }
 976
 977 // Savage: used for item garbage-collection
 978 void RemoveItem(entity this)
 979 {
 980         if(wasfreed(this) || !this) { return; }
 981         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 982         delete(this);
 983 }
 984
 985 // pickup evaluation functions
 986 // these functions decide how desirable an item is to the bots
 987
 988 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 989
 990 float weapon_pickupevalfunc(entity player, entity item)
 991 {
 992         // See if I have it already
 993         if(player.weapons & item.weapons)
 994         {
 995                 // If I can pick it up
 996                 if(!item.spawnshieldtime)
 997                         return 0;
 998                 return ammo_pickupevalfunc(player, item);
 999         }
1000
1001         // reduce weapon value if bot already got a good arsenal
1002         float c = 1;
1003         int weapons_value = 0;
1004         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1005                 weapons_value += it.bot_pickupbasevalue;
1006         });
1007         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1008
1009         return item.bot_pickupbasevalue * c;
1010 }
1011
1012 float ammo_pickupevalfunc(entity player, entity item)
1013 {
1014         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1015         entity wpn = NULL;
1016         float c = 0;
1017         float rating = 0;
1018
1019         // Detect needed ammo
1020         if(item.itemdef.instanceOfWeaponPickup)
1021         {
1022                 entity ammo = NULL;
1023                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1024                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1025                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1026                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1027                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1028                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1029
1030                 if(!ammo)
1031                         return 0;
1032                 wpn = item;
1033                 rating = ammo.m_botvalue;
1034         }
1035         else
1036         {
1037                 FOREACH(Weapons, it != WEP_Null, {
1038                         if(!(player.weapons & (it.m_wepset)))
1039                                 continue;
1040
1041                         switch(it.ammo_field)
1042                         {
1043                                 case ammo_shells:  need_shells  = true; break;
1044                                 case ammo_nails:   need_nails   = true; break;
1045                                 case ammo_rockets: need_rockets = true; break;
1046                                 case ammo_cells:   need_cells   = true; break;
1047                                 case ammo_plasma:  need_plasma  = true; break;
1048                                 case ammo_fuel:    need_fuel    = true; break;
1049                         }
1050                 });
1051                 rating = item.bot_pickupbasevalue;
1052         }
1053
1054         float noammorating = 0.5;
1055
1056         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1057                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1058
1059         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1060                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1061
1062         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1063                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1064
1065         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1066                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1067
1068         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1069                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1070
1071         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1072                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1073
1074         rating *= min(c, 2);
1075         if(wpn)
1076                 rating += wpn.bot_pickupbasevalue * 0.1;
1077         return rating;
1078 }
1079
1080 .int item_group;
1081 .int item_group_count;
1082 float healtharmor_pickupevalfunc(entity player, entity item)
1083 {
1084         float c = 0;
1085         float rating = item.bot_pickupbasevalue;
1086
1087         float itemarmor = item.armorvalue;
1088         float itemhealth = item.health;
1089
1090         if(item.item_group)
1091         {
1092                 itemarmor *= min(4, item.item_group_count);
1093                 itemhealth *= min(4, item.item_group_count);
1094         }
1095
1096         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1097                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1098
1099         if (itemhealth && (player.health < item.max_health))
1100                 c = itemhealth / max(1, player.health);
1101
1102         rating *= min(2, c);
1103         return rating;
1104 }
1105
1106 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1107 {
1108         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1109                 RemoveItem(this);
1110 }
1111
1112 void item_use(entity this, entity actor, entity trigger)
1113 {
1114         // use the touch function to handle collection
1115         gettouch(this)(this, actor);
1116 }
1117
1118 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1119 {
1120         string itemname = def.m_name;
1121         Model itemmodel = def.m_model;
1122     Sound pickupsound = def.m_sound;
1123         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1124         float pickupbasevalue = def.m_botvalue;
1125         int itemflags = def.m_itemflags;
1126
1127         startitem_failed = false;
1128
1129         this.item_model_ent = itemmodel;
1130     this.item_pickupsound_ent = pickupsound;
1131
1132     if(def.m_iteminit)
1133         def.m_iteminit(this);
1134
1135         if(!this.respawntime) // both need to be set
1136         {
1137                 this.respawntime = defaultrespawntime;
1138                 this.respawntimejitter = defaultrespawntimejitter;
1139         }
1140
1141         if(!this.pickup_anyway && def.m_pickupanyway)
1142                 this.pickup_anyway = def.m_pickupanyway();
1143
1144         int itemid = def.m_itemid;
1145         this.items = itemid;
1146         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1147         this.weapon = weaponid;
1148
1149         if(!this.fade_end)
1150         {
1151                 this.fade_start = autocvar_g_items_mindist;
1152                 this.fade_end = autocvar_g_items_maxdist;
1153         }
1154
1155         if(weaponid)
1156                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1157
1158         this.flags = FL_ITEM | itemflags;
1159         IL_PUSH(g_items, this);
1160
1161         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1162         {
1163                 startitem_failed = true;
1164                 delete(this);
1165                 return;
1166         }
1167
1168         // is it a dropped weapon?
1169         if (this.classname == "droppedweapon")
1170         {
1171                 this.reset = SUB_Remove;
1172                 // it's a dropped weapon
1173                 set_movetype(this, MOVETYPE_TOSS);
1174
1175                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1176                 setthink(this, RemoveItem);
1177                 this.nextthink = time + 20;
1178
1179                 this.takedamage = DAMAGE_YES;
1180                 this.event_damage = Item_Damage;
1181
1182                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1183                 {
1184                         // if item is worthless after a timer, have it expire then
1185                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1186                 }
1187
1188                 // don't drop if in a NODROP zone (such as lava)
1189                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1190                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1191                 {
1192                         startitem_failed = true;
1193                         delete(this);
1194                         return;
1195                 }
1196         }
1197         else
1198         {
1199                 if(!have_pickup_item(this))
1200                 {
1201                         startitem_failed = true;
1202                         delete(this);
1203                         return;
1204                 }
1205
1206                 if(this.angles != '0 0 0')
1207                         this.SendFlags |= ISF_ANGLES;
1208
1209                 this.reset = Item_Reset;
1210                 // it's a level item
1211                 if(this.spawnflags & 1)
1212                         this.noalign = 1;
1213                 if (this.noalign > 0)
1214                         set_movetype(this, MOVETYPE_NONE);
1215                 else
1216                         set_movetype(this, MOVETYPE_TOSS);
1217                 // do item filtering according to game mode and other things
1218                 if (this.noalign <= 0)
1219                 {
1220                         // first nudge it off the floor a little bit to avoid math errors
1221                         setorigin(this, this.origin + '0 0 1');
1222                         // set item size before we spawn a spawnfunc_waypoint
1223                         setsize(this, def.m_mins, def.m_maxs);
1224                         this.SendFlags |= ISF_SIZE;
1225                         // note droptofloor returns false if stuck/or would fall too far
1226                         if (!this.noalign)
1227                                 droptofloor(this);
1228                         waypoint_spawnforitem(this);
1229                 }
1230
1231                 /*
1232                  * can't do it that way, as it would break maps
1233                  * TODO make a target_give like entity another way, that perhaps has
1234                  * the weapon name in a key
1235                 if(this.targetname)
1236                 {
1237                         // target_give not yet supported; maybe later
1238                         print("removed targeted ", this.classname, "\n");
1239                         startitem_failed = true;
1240                         delete(this);
1241                         return;
1242                 }
1243                 */
1244
1245                 if(this.targetname != "" && (this.spawnflags & 16))
1246                         this.use = item_use;
1247
1248                 if(autocvar_spawn_debug >= 2)
1249                 {
1250             // why not flags & fl_item?
1251                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1252                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1253                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1254                 error("Mapper sucks.");
1255             });
1256                         this.is_item = true;
1257                 }
1258
1259                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1260
1261                 precache_model(this.model);
1262                 precache_sound(this.item_pickupsound);
1263
1264                 if (   def.instanceOfPowerup
1265                         || def.instanceOfWeaponPickup
1266                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1267                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1268                         || (itemid & (IT_KEY1 | IT_KEY2))
1269                 ) this.target = "###item###"; // for finding the nearest item using find()
1270
1271                 Item_ItemsTime_SetTime(this, 0);
1272         }
1273
1274         this.bot_pickup = true;
1275         this.bot_pickupevalfunc = pickupevalfunc;
1276         this.bot_pickupbasevalue = pickupbasevalue;
1277         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1278         this.netname = itemname;
1279         settouch(this, Item_Touch);
1280         setmodel(this, MDL_Null); // precision set below
1281         //this.effects |= EF_LOWPRECISION;
1282
1283         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1284
1285         this.SendFlags |= ISF_SIZE;
1286
1287         if (!(this.spawnflags & 1024)) {
1288                 if(def.instanceOfPowerup)
1289                         this.ItemStatus |= ITS_ANIMATE1;
1290
1291                 if(this.armorvalue || this.health)
1292                         this.ItemStatus |= ITS_ANIMATE2;
1293         }
1294
1295         if(def.instanceOfWeaponPickup)
1296         {
1297                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1298                         this.colormap = 1024; // color shirt=0 pants=0 grey
1299                 else
1300                         this.gravity = 1;
1301                 if (!(this.spawnflags & 1024))
1302                         this.ItemStatus |= ITS_ANIMATE1;
1303                 this.SendFlags |= ISF_COLORMAP;
1304         }
1305
1306         this.state = 0;
1307         if(this.team) // broken, no idea why.
1308         {
1309                 if(!this.cnt)
1310                         this.cnt = 1; // item probability weight
1311
1312                 this.effects |= EF_NODRAW; // marker for item team search
1313                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1314         }
1315         else
1316                 Item_Reset(this);
1317
1318         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1319
1320         // call this hook after everything else has been done
1321         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1322         {
1323                 startitem_failed = true;
1324                 delete(this);
1325                 return;
1326         }
1327
1328         setItemGroup(this);
1329 }
1330
1331 void StartItem(entity this, GameItem def)
1332 {
1333     _StartItem(
1334         this,
1335         this.itemdef = def,
1336         def.m_respawntime(), // defaultrespawntime
1337         def.m_respawntimejitter() // defaultrespawntimejitter
1338         );
1339 }
1340
1341 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1342 int group_count = 1;
1343
1344 void setItemGroup(entity this)
1345 {
1346         if(!IS_SMALL(this.itemdef))
1347                 return;
1348
1349         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1350         {
1351                 if(!this.item_group)
1352                 {
1353                         if(!it.item_group)
1354                         {
1355                                 it.item_group = group_count;
1356                                 group_count++;
1357                         }
1358                         this.item_group = it.item_group;
1359                 }
1360                 else // spawning item is already part of a item_group X
1361                 {
1362                         if(!it.item_group)
1363                                 it.item_group = this.item_group;
1364                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1365                         {
1366                                 int grY = it.item_group;
1367                                 // move all items of item_group Y to item_group X
1368                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1369                                 {
1370                                         if(it.item_group == grY)
1371                                                 it.item_group = this.item_group;
1372                                 });
1373                         }
1374                 }
1375         });
1376 }
1377
1378 void setItemGroupCount()
1379 {
1380         for (int k = 1; k <= group_count; k++)
1381         {
1382                 int count = 0;
1383                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1384                 if (count)
1385                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1386         }
1387 }
1388
1389 spawnfunc(item_rockets)
1390 {
1391     StartItem(this, ITEM_Rockets);
1392 }
1393
1394 spawnfunc(item_bullets)
1395 {
1396         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1397            (this.classname != "droppedweapon"))
1398         {
1399                 weaponswapping = true;
1400                 spawnfunc_item_shells(this);
1401                 weaponswapping = false;
1402                 return;
1403         }
1404
1405     StartItem(this, ITEM_Bullets);
1406 }
1407
1408 spawnfunc(item_cells)
1409 {
1410         StartItem(this, ITEM_Cells);
1411 }
1412
1413 spawnfunc(item_plasma)
1414 {
1415         StartItem(this, ITEM_Plasma);
1416 }
1417
1418 spawnfunc(item_shells)
1419 {
1420         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1421            (this.classname != "droppedweapon"))
1422         {
1423                 weaponswapping = true;
1424                 spawnfunc_item_bullets(this);
1425                 weaponswapping = false;
1426                 return;
1427         }
1428
1429         StartItem(this, ITEM_Shells);
1430 }
1431
1432 spawnfunc(item_armor_small)
1433 {
1434         StartItem(this, ITEM_ArmorSmall);
1435 }
1436
1437 spawnfunc(item_armor_medium)
1438 {
1439         StartItem(this, ITEM_ArmorMedium);
1440 }
1441
1442 spawnfunc(item_armor_big)
1443 {
1444         StartItem(this, ITEM_ArmorBig);
1445 }
1446
1447 spawnfunc(item_armor_mega)
1448 {
1449         StartItem(this, ITEM_ArmorMega);
1450 }
1451
1452 spawnfunc(item_health_small)
1453 {
1454         StartItem(this, ITEM_HealthSmall);
1455 }
1456
1457 spawnfunc(item_health_medium)
1458 {
1459     StartItem(this, ITEM_HealthMedium);
1460 }
1461
1462 spawnfunc(item_health_big)
1463 {
1464         StartItem(this, ITEM_HealthBig);
1465 }
1466
1467 spawnfunc(item_health_mega)
1468 {
1469     StartItem(this, ITEM_HealthMega);
1470 }
1471
1472 // support old misnamed entities
1473 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1474 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1475 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1476 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1477 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1478 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1479 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1480
1481 spawnfunc(item_strength)
1482 {
1483         StartItem(this, ITEM_Strength);
1484 }
1485
1486 spawnfunc(item_invincible)
1487 {
1488         StartItem(this, ITEM_Shield);
1489 }
1490
1491 // compatibility:
1492 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1493
1494 void target_items_use(entity this, entity actor, entity trigger)
1495 {
1496         if(actor.classname == "droppedweapon")
1497         {
1498                 EXACTTRIGGER_TOUCH(this, trigger);
1499                 delete(actor);
1500                 return;
1501         }
1502
1503         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1504                 return;
1505
1506         if(trigger.solid == SOLID_TRIGGER)
1507         {
1508                 EXACTTRIGGER_TOUCH(this, trigger);
1509         }
1510
1511         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1512         {
1513                 delete(it);
1514         });
1515
1516         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1517                 centerprint(actor, this.message);
1518 }
1519
1520 spawnfunc(target_items)
1521 {
1522         int n;
1523         string s;
1524
1525         this.use = target_items_use;
1526         if(!this.strength_finished)
1527                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1528         if(!this.invincible_finished)
1529                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1530         if(!this.superweapons_finished)
1531                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1532
1533         n = tokenize_console(this.netname);
1534         if(argv(0) == "give")
1535         {
1536                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1537         }
1538         else
1539         {
1540                 for(int j = 0; j < n; ++j)
1541                 {
1542                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1543                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1544                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1545                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1546                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1547                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1548                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1549                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1550                         else
1551                         {
1552                                 FOREACH(Buffs, it != BUFF_Null,
1553                                 {
1554                                         s = Buff_UndeprecateName(argv(j));
1555                                         if(s == it.m_name)
1556                                         {
1557                                                 this.buffs |= (it.m_itemid);
1558                                                 break;
1559                                         }
1560                                 });
1561                                 FOREACH(Weapons, it != WEP_Null, {
1562                                         s = W_UndeprecateName(argv(j));
1563                                         if(s == it.netname)
1564                                         {
1565                                                 this.weapons |= (it.m_wepset);
1566                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1567                                                         it.wr_init(it);
1568                                                 break;
1569                                         }
1570                                 });
1571                         }
1572                 }
1573
1574                 string itemprefix, valueprefix;
1575                 if(this.spawnflags == 0)
1576                 {
1577                         itemprefix = "";
1578                         valueprefix = "";
1579                 }
1580                 else if(this.spawnflags == 1)
1581                 {
1582                         itemprefix = "max ";
1583                         valueprefix = "max ";
1584                 }
1585                 else if(this.spawnflags == 2)
1586                 {
1587                         itemprefix = "min ";
1588                         valueprefix = "min ";
1589                 }
1590                 else if(this.spawnflags == 4)
1591                 {
1592                         itemprefix = "minus ";
1593                         valueprefix = "max ";
1594                 }
1595                 else
1596                 {
1597                         error("invalid spawnflags");
1598                         itemprefix = valueprefix = string_null;
1599                 }
1600
1601                 this.netname = "";
1602                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1603                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1604                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1605                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1606                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1607                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1608                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1609                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1610                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1611                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1612                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1613                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1614                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1615                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1616                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1617                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1618                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1619         }
1620         this.netname = strzone(this.netname);
1621         //print(this.netname, "\n");
1622
1623         n = tokenize_console(this.netname);
1624         for(int j = 0; j < n; ++j)
1625         {
1626                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1627             it.wr_init(it);
1628             break;
1629                 });
1630         }
1631 }
1632
1633 spawnfunc(item_fuel)
1634 {
1635         StartItem(this, ITEM_JetpackFuel);
1636 }
1637
1638 spawnfunc(item_fuel_regen)
1639 {
1640         if(start_items & ITEM_JetpackRegen.m_itemid)
1641         {
1642                 spawnfunc_item_fuel(this);
1643                 return;
1644         }
1645         StartItem(this, ITEM_JetpackRegen);
1646 }
1647
1648 spawnfunc(item_jetpack)
1649 {
1650         if(start_items & ITEM_Jetpack.m_itemid)
1651         {
1652                 spawnfunc_item_fuel(this);
1653                 return;
1654         }
1655         StartItem(this, ITEM_Jetpack);
1656 }
1657
1658 float GiveWeapon(entity e, float wpn, float op, float val)
1659 {
1660         WepSet v0, v1;
1661         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1662         v0 = (e.weapons & s);
1663         switch(op)
1664         {
1665                 case OP_SET:
1666                         if(val > 0)
1667                                 e.weapons |= s;
1668                         else
1669                                 e.weapons &= ~s;
1670                         break;
1671                 case OP_MIN:
1672                 case OP_PLUS:
1673                         if(val > 0)
1674                                 e.weapons |= s;
1675                         break;
1676                 case OP_MAX:
1677                         if(val <= 0)
1678                                 e.weapons &= ~s;
1679                         break;
1680                 case OP_MINUS:
1681                         if(val > 0)
1682                                 e.weapons &= ~s;
1683                         break;
1684         }
1685         v1 = (e.weapons & s);
1686         return (v0 != v1);
1687 }
1688
1689 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1690 {
1691         bool had_buff = (e.buffs & thebuff.m_itemid);
1692         switch(op)
1693         {
1694                 case OP_SET:
1695                         if(val > 0)
1696                                 e.buffs |= thebuff.m_itemid;
1697                         else
1698                                 e.buffs &= ~thebuff.m_itemid;
1699                         break;
1700                 case OP_MIN:
1701                 case OP_PLUS:
1702                         if(val > 0)
1703                                 e.buffs |= thebuff.m_itemid;
1704                         break;
1705                 case OP_MAX:
1706                         if(val <= 0)
1707                                 e.buffs &= ~thebuff.m_itemid;
1708                         break;
1709                 case OP_MINUS:
1710                         if(val > 0)
1711                                 e.buffs &= ~thebuff.m_itemid;
1712                         break;
1713         }
1714         bool have_buff = (e.buffs & thebuff.m_itemid);
1715         return (had_buff != have_buff);
1716 }
1717
1718 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1719 {
1720         if(v1 == v0)
1721                 return;
1722         if(v1 <= v0 - t)
1723         {
1724                 if(snd_decr != NULL)
1725                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1726         }
1727         else if(v0 >= v0 + t)
1728         {
1729                 if(snd_incr != NULL)
1730                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1731         }
1732 }
1733
1734 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1735 {
1736         if(v0 < v1)
1737                 e.(rotfield) = max(e.(rotfield), time + rottime);
1738         else if(v0 > v1)
1739                 e.(regenfield) = max(e.(regenfield), time + regentime);
1740 }
1741 float GiveItems(entity e, float beginarg, float endarg)
1742 {
1743         float got, i, val, op;
1744         string cmd;
1745
1746         val = 999;
1747         op = OP_SET;
1748
1749         got = 0;
1750
1751         int _switchweapon = 0;
1752
1753         if(CS(e).autoswitch)
1754         {
1755                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1756                 {
1757                         .entity weaponentity = weaponentities[slot];
1758                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1759                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1760                                 _switchweapon |= BIT(slot);
1761                 }
1762         }
1763
1764         e.strength_finished = max(0, e.strength_finished - time);
1765         e.invincible_finished = max(0, e.invincible_finished - time);
1766         e.superweapons_finished = max(0, e.superweapons_finished - time);
1767
1768         PREGIVE(e, items);
1769         PREGIVE_WEAPONS(e);
1770         PREGIVE(e, strength_finished);
1771         PREGIVE(e, invincible_finished);
1772         PREGIVE(e, superweapons_finished);
1773         PREGIVE(e, ammo_nails);
1774         PREGIVE(e, ammo_cells);
1775         PREGIVE(e, ammo_plasma);
1776         PREGIVE(e, ammo_shells);
1777         PREGIVE(e, ammo_rockets);
1778         PREGIVE(e, ammo_fuel);
1779         PREGIVE(e, armorvalue);
1780         PREGIVE(e, health);
1781
1782         for(i = beginarg; i < endarg; ++i)
1783         {
1784                 cmd = argv(i);
1785
1786                 if(cmd == "0" || stof(cmd))
1787                 {
1788                         val = stof(cmd);
1789                         continue;
1790                 }
1791                 switch(cmd)
1792                 {
1793                         case "no":
1794                                 op = OP_MAX;
1795                                 val = 0;
1796                                 continue;
1797                         case "max":
1798                                 op = OP_MAX;
1799                                 continue;
1800                         case "min":
1801                                 op = OP_MIN;
1802                                 continue;
1803                         case "plus":
1804                                 op = OP_PLUS;
1805                                 continue;
1806                         case "minus":
1807                                 op = OP_MINUS;
1808                                 continue;
1809                         case "ALL":
1810                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1811                                 got += GiveValue(e, strength_finished, op, val);
1812                                 got += GiveValue(e, invincible_finished, op, val);
1813                                 got += GiveValue(e, superweapons_finished, op, val);
1814                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1815                         case "all":
1816                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1817                                 got += GiveValue(e, health, op, val);
1818                                 got += GiveValue(e, armorvalue, op, val);
1819                         case "allweapons":
1820                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1821                         //case "allbuffs": // all buffs makes a player god, do not want!
1822                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1823                         case "allammo":
1824                                 got += GiveValue(e, ammo_cells, op, val);
1825                                 got += GiveValue(e, ammo_plasma, op, val);
1826                                 got += GiveValue(e, ammo_shells, op, val);
1827                                 got += GiveValue(e, ammo_nails, op, val);
1828                                 got += GiveValue(e, ammo_rockets, op, val);
1829                                 got += GiveValue(e, ammo_fuel, op, val);
1830                                 break;
1831                         case "unlimited_ammo":
1832                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1833                                 break;
1834                         case "unlimited_weapon_ammo":
1835                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1836                                 break;
1837                         case "unlimited_superweapons":
1838                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1839                                 break;
1840                         case "jetpack":
1841                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1842                                 break;
1843                         case "fuel_regen":
1844                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1845                                 break;
1846                         case "strength":
1847                                 got += GiveValue(e, strength_finished, op, val);
1848                                 break;
1849                         case "invincible":
1850                                 got += GiveValue(e, invincible_finished, op, val);
1851                                 break;
1852                         case "superweapons":
1853                                 got += GiveValue(e, superweapons_finished, op, val);
1854                                 break;
1855                         case "cells":
1856                                 got += GiveValue(e, ammo_cells, op, val);
1857                                 break;
1858                         case "plasma":
1859                                 got += GiveValue(e, ammo_plasma, op, val);
1860                                 break;
1861                         case "shells":
1862                                 got += GiveValue(e, ammo_shells, op, val);
1863                                 break;
1864                         case "nails":
1865                         case "bullets":
1866                                 got += GiveValue(e, ammo_nails, op, val);
1867                                 break;
1868                         case "rockets":
1869                                 got += GiveValue(e, ammo_rockets, op, val);
1870                                 break;
1871                         case "health":
1872                                 got += GiveValue(e, health, op, val);
1873                                 break;
1874                         case "armor":
1875                                 got += GiveValue(e, armorvalue, op, val);
1876                                 break;
1877                         case "fuel":
1878                                 got += GiveValue(e, ammo_fuel, op, val);
1879                                 break;
1880                         default:
1881                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1882                                 {
1883                                         got += GiveBuff(e, it, op, val);
1884                                         break;
1885                                 });
1886                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1887                     got += GiveWeapon(e, it.m_id, op, val);
1888                     break;
1889                                 });
1890                                 break;
1891                 }
1892                 val = 999;
1893                 op = OP_SET;
1894         }
1895
1896         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1897         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1898         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1899         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1900         FOREACH(Weapons, it != WEP_Null, {
1901                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1902                 if(!(save_weapons & (it.m_wepset)))
1903                         if(e.weapons & (it.m_wepset))
1904                                 it.wr_init(it);
1905         });
1906         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1907         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1908         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1909         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1910         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1911         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1912         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1913         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1914         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1915         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1916         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1917
1918         if(e.superweapons_finished <= 0)
1919                 if(e.weapons & WEPSET_SUPERWEAPONS)
1920                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1921
1922         if(e.strength_finished <= 0)
1923                 e.strength_finished = 0;
1924         else
1925                 e.strength_finished += time;
1926         if(e.invincible_finished <= 0)
1927                 e.invincible_finished = 0;
1928         else
1929                 e.invincible_finished += time;
1930         if(e.superweapons_finished <= 0)
1931                 e.superweapons_finished = 0;
1932         else
1933                 e.superweapons_finished += time;
1934
1935         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1936         {
1937                 .entity weaponentity = weaponentities[slot];
1938                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1939                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1940                         _switchweapon |= BIT(slot);
1941         }
1942
1943         if(_switchweapon)
1944         {
1945                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1946                 {
1947                         .entity weaponentity = weaponentities[slot];
1948                         if(_switchweapon & BIT(slot))
1949                         {
1950                                 Weapon wep = w_getbestweapon(e, weaponentity);
1951                                 if(wep != e.(weaponentity).m_switchweapon)
1952                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1953                         }
1954                 }
1955         }
1956
1957         return got;
1958 }
1959 #endif