qcsrc/common/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "items/_mod.qh"
   4
   5 #if defined(SVQC)
   6
   7     #include "../server/bot/api.qh"
   8
   9     #include <server/mutators/_mod.qh>
  10
  11     #include "../server/weapons/common.qh"
  12     #include "../server/weapons/selection.qh"
  13     #include "../server/weapons/weaponsystem.qh"
  14
  15     #include "constants.qh"
  16     #include <common/deathtypes/all.qh>
  17     #include <common/notifications/all.qh>
  18         #include "triggers/subs.qh"
  19     #include "util.qh"
  20
  21     #include <common/monsters/_mod.qh>
  22
  23     #include <common/weapons/_all.qh>
  24
  25     #include <common/mutators/mutator/buffs/buffs.qh>
  26
  27     #include "../lib/warpzone/util_server.qh"
  28 #elif defined(CSQC)
  29         #include "physics/movetypes/movetypes.qh"
  30         #include <common/weapons/_all.qh>
  31         #include "../lib/csqcmodel/cl_model.qh"
  32         #include "../lib/csqcmodel/common.qh"
  33 #endif
  34
  35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
  36
  37 #ifdef CSQC
  38 bool autocvar_cl_ghost_items_vehicle = true;
  39 .vector item_glowmod;
  40 void Item_SetAlpha(entity this)
  41 {
  42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
  43
  44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
  45         {
  46                 this.alpha = 1;
  47                 this.colormod = '1 1 1';
  48                 this.glowmod = this.item_glowmod;
  49         }
  50         else
  51         {
  52                 if (autocvar_cl_ghost_items_color)
  53                 {
  54                         this.alpha = autocvar_cl_ghost_items;
  55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
  56                 }
  57                 else
  58                         this.alpha = -1;
  59         }
  60
  61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
  62         {
  63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
  64                 this.alpha = autocvar_cl_weapon_stay_alpha;
  65         }
  66
  67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
  68 }
  69
  70 void ItemDraw(entity this)
  71 {
  72     if(this.gravity)
  73     {
  74         Movetype_Physics_MatchServer(this, false);
  75         if(IS_ONGROUND(this))
  76         { // For some reason avelocity gets set to '0 0 0' here ...
  77             this.oldorigin = this.origin;
  78             this.gravity = 0;
  79
  80             if(autocvar_cl_animate_items)
  81             { // ... so reset it if animations are requested.
  82                 if(this.ItemStatus & ITS_ANIMATE1)
  83                     this.avelocity = '0 180 0';
  84
  85                 if(this.ItemStatus & ITS_ANIMATE2)
  86                     this.avelocity = '0 -90 0';
  87             }
  88
  89             // delay is for blocking item's position for a while;
  90             // it's a workaround for dropped weapons that receive the position
  91             // another time right after they spawn overriding animation position
  92             this.onground_time = time + 0.5;
  93         }
  94     }
  95     else if (autocvar_cl_animate_items)
  96     {
  97         if(this.ItemStatus & ITS_ANIMATE1)
  98         {
  99             this.angles += this.avelocity * frametime;
 100             float fade_in = bound(0, time - this.onground_time, 1);
 101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
 102         }
 103
 104         if(this.ItemStatus & ITS_ANIMATE2)
 105         {
 106             this.angles += this.avelocity * frametime;
 107             float fade_in = bound(0, time - this.onground_time, 1);
 108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
 109         }
 110     }
 111
 112     Item_SetAlpha(this);
 113 }
 114
 115 void ItemDrawSimple(entity this)
 116 {
 117     if(this.gravity)
 118     {
 119         Movetype_Physics_MatchServer(this, false);
 120
 121         if(IS_ONGROUND(this))
 122             this.gravity = 0;
 123     }
 124
 125     Item_SetAlpha(this);
 126 }
 127
 128 void Item_PreDraw(entity this)
 129 {
 130         if(warpzone_warpzones_exist)
 131         {
 132                 setpredraw(this, func_null); // no need to keep running this
 133                 return;
 134         }
 135         float alph;
 136         vector org = getpropertyvec(VF_ORIGIN);
 137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
 138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
 139         if(this.fade_start)
 140         {
 141                 if(vdist(org - this.origin, >, this.fade_end))
 142                         alph = 0; // save on some processing
 143                 else if(vdist(org - this.origin, <, this.fade_start))
 144                         alph = 1; // more processing saved
 145                 else
 146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 147         }
 148         else
 149                 alph = 1;
 150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
 152                 this.alpha = alph;
 153         if(alph <= 0)
 154                 this.drawmask = 0;
 155         //else
 156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
 157 }
 158
 159 void ItemRemove(entity this)
 160 {
 161         if(this.mdl)
 162                 strunzone(this.mdl);
 163 }
 164
 165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
 166 {
 167     int sf = ReadByte();
 168
 169     if(sf & ISF_LOCATION)
 170     {
 171         this.origin_x = ReadCoord();
 172         this.origin_y = ReadCoord();
 173         this.origin_z = ReadCoord();
 174         setorigin(this, this.origin);
 175         this.oldorigin = this.origin;
 176     }
 177
 178     if(sf & ISF_ANGLES)
 179     {
 180         this.angles_x = ReadAngle();
 181         this.angles_y = ReadAngle();
 182         this.angles_z = ReadAngle();
 183     }
 184
 185     if(sf & ISF_SIZE)
 186     {
 187         float use_bigsize = ReadByte();
 188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 189     }
 190
 191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
 192     {
 193         this.ItemStatus = ReadByte();
 194
 195         Item_SetAlpha(this);
 196
 197         if(autocvar_cl_fullbright_items)
 198             if(this.ItemStatus & ITS_ALLOWFB)
 199                 this.effects |= EF_FULLBRIGHT;
 200
 201         if(this.ItemStatus & ITS_GLOW)
 202         {
 203             if(this.ItemStatus & ITS_AVAILABLE)
 204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 205             else
 206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 207         }
 208     }
 209
 210     if(sf & ISF_MODEL)
 211     {
 212         this.drawmask  = MASK_NORMAL;
 213                 set_movetype(this, MOVETYPE_TOSS);
 214                 if (isnew) IL_PUSH(g_drawables, this);
 215         this.draw       = ItemDraw;
 216         this.solid = SOLID_TRIGGER;
 217         //this.flags |= FL_ITEM;
 218
 219         bool use_bigsize = ReadByte();
 220
 221         this.fade_end = ReadShort();
 222         this.fade_start = ReadShort();
 223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
 224                 setpredraw(this, Item_PreDraw);
 225
 226         if(this.mdl)
 227             strunzone(this.mdl);
 228
 229         this.mdl = "";
 230         string _fn = ReadString();
 231
 232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
 233         {
 234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 235             this.draw = ItemDrawSimple;
 236
 237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
 238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
 239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
 240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
 241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
 242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
 243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
 244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
 245             else
 246             {
 247                 this.draw = ItemDraw;
 248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
 249             }
 250         }
 251
 252         if(this.draw != ItemDrawSimple)
 253             this.mdl = strzone(_fn);
 254
 255
 256         if(this.mdl == "")
 257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
 258
 259         precache_model(this.mdl);
 260         _setmodel(this, this.mdl);
 261
 262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
 263     }
 264
 265     if(sf & ISF_COLORMAP)
 266     {
 267         this.colormap = ReadShort();
 268         this.item_glowmod_x = ReadByte() / 255.0;
 269         this.item_glowmod_y = ReadByte() / 255.0;
 270         this.item_glowmod_z = ReadByte() / 255.0;
 271     }
 272
 273     if(sf & ISF_DROP)
 274     {
 275         this.gravity = 1;
 276         this.pushable = true;
 277         //this.angles = '0 0 0';
 278         set_movetype(this, MOVETYPE_TOSS);
 279         this.velocity_x = ReadCoord();
 280         this.velocity_y = ReadCoord();
 281         this.velocity_z = ReadCoord();
 282         setorigin(this, this.oldorigin);
 283
 284         if(!this.move_time)
 285         {
 286             this.move_time = time;
 287             this.spawntime = time;
 288         }
 289         else
 290             this.move_time = max(this.move_time, time);
 291     }
 292
 293     if(autocvar_cl_animate_items)
 294     {
 295         if(this.ItemStatus & ITS_ANIMATE1)
 296             this.avelocity = '0 180 0';
 297
 298         if(this.ItemStatus & ITS_ANIMATE2)
 299             this.avelocity = '0 -90 0';
 300     }
 301
 302     this.entremove = ItemRemove;
 303
 304     return true;
 305 }
 306
 307 #endif
 308
 309 #ifdef SVQC
 310 bool ItemSend(entity this, entity to, int sf)
 311 {
 312         if(this.gravity)
 313                 sf |= ISF_DROP;
 314         else
 315                 sf &= ~ISF_DROP;
 316
 317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
 318         WriteByte(MSG_ENTITY, sf);
 319
 320         //WriteByte(MSG_ENTITY, this.cnt);
 321         if(sf & ISF_LOCATION)
 322         {
 323                 WriteCoord(MSG_ENTITY, this.origin.x);
 324                 WriteCoord(MSG_ENTITY, this.origin.y);
 325                 WriteCoord(MSG_ENTITY, this.origin.z);
 326         }
 327
 328         if(sf & ISF_ANGLES)
 329         {
 330                 WriteAngle(MSG_ENTITY, this.angles_x);
 331                 WriteAngle(MSG_ENTITY, this.angles_y);
 332                 WriteAngle(MSG_ENTITY, this.angles_z);
 333         }
 334
 335         if(sf & ISF_SIZE)
 336         {
 337                 Pickup p = this.itemdef;
 338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 339         }
 340
 341         if(sf & ISF_STATUS)
 342                 WriteByte(MSG_ENTITY, this.ItemStatus);
 343
 344         if(sf & ISF_MODEL)
 345         {
 346                 Pickup p = this.itemdef;
 347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
 348                 WriteShort(MSG_ENTITY, this.fade_end);
 349                 WriteShort(MSG_ENTITY, this.fade_start);
 350
 351                 if(this.mdl == "")
 352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
 353
 354                 WriteString(MSG_ENTITY, this.mdl);
 355         }
 356
 357
 358         if(sf & ISF_COLORMAP)
 359         {
 360                 WriteShort(MSG_ENTITY, this.colormap);
 361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
 362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
 363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
 364         }
 365
 366         if(sf & ISF_DROP)
 367         {
 368                 WriteCoord(MSG_ENTITY, this.velocity.x);
 369                 WriteCoord(MSG_ENTITY, this.velocity.y);
 370                 WriteCoord(MSG_ENTITY, this.velocity.z);
 371         }
 372
 373         return true;
 374 }
 375
 376 void ItemUpdate(entity this)
 377 {
 378         this.oldorigin = this.origin;
 379         this.SendFlags |= ISF_LOCATION;
 380 }
 381
 382 void UpdateItemAfterTeleport(entity this)
 383 {
 384         if(getSendEntity(this) == ItemSend)
 385                 ItemUpdate(this);
 386 }
 387
 388 bool have_pickup_item(entity this)
 389 {
 390         if(this.itemdef.instanceOfPowerup)
 391         {
 392                 if(autocvar_g_powerups > 0)
 393                         return true;
 394                 if(autocvar_g_powerups == 0)
 395                         return false;
 396         }
 397         else
 398         {
 399                 if(autocvar_g_pickup_items > 0)
 400                         return true;
 401                 if(autocvar_g_pickup_items == 0)
 402                         return false;
 403                 if(g_weaponarena)
 404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
 405                                 return false;
 406         }
 407         return true;
 408 }
 409
 410 /*
 411 float Item_Customize()
 412 {
 413         if(this.spawnshieldtime)
 414                 return true;
 415         if(this.weapons & ~other.weapons)
 416         {
 417                 this.colormod = '0 0 0';
 418                 this.glowmod = this.colormod;
 419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 420                 return true;
 421         }
 422         else
 423         {
 424                 if(g_ghost_items)
 425                 {
 426                         this.colormod = stov(autocvar_g_ghost_items_color);
 427                         this.glowmod = this.colormod;
 428                         this.alpha = g_ghost_items;
 429                         return true;
 430                 }
 431                 else
 432                         return false;
 433         }
 434 }
 435 */
 436
 437 void Item_Show (entity e, float mode)
 438 {
 439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 440         e.ItemStatus &= ~ITS_STAYWEP;
 441         entity def = e.itemdef;
 442         if (mode > 0)
 443         {
 444                 // make the item look normal, and be touchable
 445                 e.model = e.mdl;
 446                 e.solid = SOLID_TRIGGER;
 447                 e.spawnshieldtime = 1;
 448                 e.ItemStatus |= ITS_AVAILABLE;
 449         }
 450         else if (mode < 0)
 451         {
 452                 // hide the item completely
 453                 e.model = string_null;
 454                 e.solid = SOLID_NOT;
 455                 e.spawnshieldtime = 1;
 456                 e.ItemStatus &= ~ITS_AVAILABLE;
 457         }
 458         else
 459         {
 460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
 461                         || e.team // weapon stay isn't supported for teamed weapons
 462                         ;
 463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
 464                 {
 465                         // make the item translucent and not touchable
 466                         e.model = e.mdl;
 467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
 468                         e.effects |= EF_STARDUST;
 469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 471                 }
 472                 else
 473                 {
 474                         //setmodel(e, "null");
 475                         e.solid = SOLID_NOT;
 476                         e.colormod = '0 0 0';
 477                         //e.glowmod = e.colormod;
 478                         e.spawnshieldtime = 1;
 479                         e.ItemStatus &= ~ITS_AVAILABLE;
 480                 }
 481         }
 482
 483         if (def.m_glow)
 484                 e.ItemStatus |= ITS_GLOW;
 485
 486         if (autocvar_g_nodepthtestitems)
 487                 e.effects |= EF_NODEPTHTEST;
 488
 489
 490         if (autocvar_g_fullbrightitems)
 491                 e.ItemStatus |= ITS_ALLOWFB;
 492
 493         if (autocvar_sv_simple_items)
 494                 e.ItemStatus |= ITS_ALLOWSI;
 495
 496         // relink entity (because solid may have changed)
 497         setorigin(e, e.origin);
 498         e.SendFlags |= ISF_STATUS;
 499 }
 500
 501 void Item_Think(entity this)
 502 {
 503         this.nextthink = time;
 504         if(this.origin != this.oldorigin)
 505                 ItemUpdate(this);
 506 }
 507
 508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
 509 bool Item_ItemsTime_Allow(GameItem it);
 510 float Item_ItemsTime_UpdateTime(entity e, float t);
 511 void Item_ItemsTime_SetTime(entity e, float t);
 512 void Item_ItemsTime_SetTimesForAllPlayers();
 513
 514 void Item_Respawn (entity this)
 515 {
 516         Item_Show(this, 1);
 517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
 518         setorigin(this, this.origin);
 519
 520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
 521         {
 522                 float t = Item_ItemsTime_UpdateTime(this, 0);
 523                 Item_ItemsTime_SetTime(this, t);
 524                 Item_ItemsTime_SetTimesForAllPlayers();
 525         }
 526
 527         setthink(this, Item_Think);
 528         this.nextthink = time;
 529
 530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 532 }
 533
 534 void Item_RespawnCountdown (entity this)
 535 {
 536         if(this.count >= ITEM_RESPAWN_TICKS)
 537         {
 538                 if(this.waypointsprite_attached)
 539                         WaypointSprite_Kill(this.waypointsprite_attached);
 540                 Item_Respawn(this);
 541         }
 542         else
 543         {
 544                 this.nextthink = time + 1;
 545                 this.count += 1;
 546                 if(this.count == 1)
 547                 {
 548                         do {
 549                                 {
 550                                         entity wi = Weapons_from(this.weapon);
 551                                         if (wi != WEP_Null) {
 552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
 553                                                 wp.wp_extra = wi.m_id;
 554                                                 break;
 555                                         }
 556                                 }
 557                                 {
 558                                         entity ii = this.itemdef;
 559                                         if (ii != NULL) {
 560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
 561                                                 wp.wp_extra = ii.m_id;
 562                                                 break;
 563                                         }
 564                                 }
 565                         } while (0);
 566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
 567             if(this.waypointsprite_attached)
 568             {
 569                 GameItem def = this.itemdef;
 570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
 571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 573             }
 574                 }
 575
 576                 if(this.waypointsprite_attached)
 577                 {
 578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
 580                                 {
 581                                         msg_entity = it;
 582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
 583                                 }
 584                         });
 585
 586                         WaypointSprite_Ping(this.waypointsprite_attached);
 587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
 588                 }
 589         }
 590 }
 591
 592 void Item_RespawnThink(entity this)
 593 {
 594         this.nextthink = time;
 595         if(this.origin != this.oldorigin)
 596                 ItemUpdate(this);
 597
 598         if(time >= this.wait)
 599                 Item_Respawn(this);
 600 }
 601
 602 void Item_ScheduleRespawnIn(entity e, float t)
 603 {
 604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
 605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
 606         {
 607                 setthink(e, Item_RespawnCountdown);
 608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 610                 e.count = 0;
 611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 612                 {
 613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 614                         Item_ItemsTime_SetTime(e, t);
 615                         Item_ItemsTime_SetTimesForAllPlayers();
 616                 }
 617         }
 618         else
 619         {
 620                 setthink(e, Item_RespawnThink);
 621                 e.nextthink = time;
 622                 e.scheduledrespawntime = time + t;
 623                 e.wait = time + t;
 624
 625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
 626                 {
 627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
 628                         Item_ItemsTime_SetTime(e, t);
 629                         Item_ItemsTime_SetTimesForAllPlayers();
 630                 }
 631         }
 632 }
 633
 634 void Item_ScheduleRespawn(entity e)
 635 {
 636         if(e.respawntime > 0)
 637         {
 638                 Item_Show(e, 0);
 639                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 640         }
 641         else // if respawntime is -1, this item does not respawn
 642                 Item_Show(e, -1);
 643 }
 644
 645 void Item_ScheduleInitialRespawn(entity e)
 646 {
 647         Item_Show(e, 0);
 648         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
 649 }
 650
 651 void GivePlayerHealth(entity player, float amount)
 652 {
 653         if (amount == 0)
 654         {
 655                 return;
 656         }
 657         // Ugly hack. We do not check if health goes beyond hard limit since
 658         // currently it is done in player_regen. We need to bring back this check
 659         // when other code is ported to this function.
 660         player.health = bound(player.health, player.health + amount,
 661                 autocvar_g_balance_health_limit);
 662         // Correct code:
 663         //player.health = bound(player.health, player.health + amount,
 664         //      min(autocvar_g_balance_health_limit, ITEM_COUNT_HARD_LIMIT));
 665         player.pauserothealth_finished = max(player.pauserothealth_finished, time +
 666                 autocvar_g_balance_pause_health_rot);
 667 }
 668
 669 void GivePlayerArmor(entity player, float amount)
 670 {
 671         if (amount == 0)
 672         {
 673                 return;
 674         }
 675         // Ugly hack. We do not check if armor goes beyond hard limit since
 676         // currently it is done in player_regen. We need to bring back this check
 677         // when other code is ported to this function.
 678         player.armorvalue = bound(player.armorvalue, player.armorvalue + amount,
 679                 autocvar_g_balance_armor_limit);
 680         // Correct code:
 681         //player.armorvalue = bound(player.armorvalue, player.armorvalue + amount,
 682         //      min(autocvar_g_balance_armor_limit, ITEM_COUNT_HARD_LIMIT));
 683         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time +
 684                 autocvar_g_balance_pause_armor_rot);
 685 }
 686
 687 void GivePlayerAmmo(entity player, .float ammotype, float amount)
 688 {
 689         float maxvalue = 999;
 690         switch (ammotype)
 691         {
 692                 case ammo_shells:
 693                 {
 694                         maxvalue = g_pickup_shells_max;
 695                         break;
 696                 }
 697                 case ammo_cells:
 698                 {
 699                         maxvalue = g_pickup_cells_max;
 700                         break;
 701                 }
 702                 case ammo_rockets:
 703                 {
 704                         maxvalue = g_pickup_rockets_max;
 705                         break;
 706                 }
 707                 case ammo_plasma:
 708                 {
 709                         maxvalue = g_pickup_plasma_max;
 710                         break;
 711                 }
 712                 case ammo_nails:
 713                 {
 714                         maxvalue = g_pickup_nails_max;
 715                         break;
 716                 }
 717         }
 718         player.(ammotype) = min(player.(ammotype) + amount,
 719                 min(maxvalue, ITEM_COUNT_HARD_LIMIT));
 720 }
 721
 722 void GivePlayerFuel(entity player, float amount)
 723 {
 724         if (amount == 0)
 725         {
 726                 return;
 727         }
 728         player.ammo_fuel = bound(player.ammo_fuel, player.ammo_fuel + amount,
 729                  min(g_pickup_fuel_max, ITEM_COUNT_HARD_LIMIT));
 730         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time +
 731                 autocvar_g_balance_pause_fuel_rot);
 732 }
 733
 734 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 735 {
 736         if (!item.(ammotype))
 737                 return false;
 738
 739         if (item.spawnshieldtime)
 740         {
 741                 if ((player.(ammotype) < ammomax) || item.pickup_anyway > 0)
 742                 {
 743                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 744                         goto YEAH;
 745                 }
 746         }
 747         else if(g_weapon_stay == 2)
 748         {
 749                 float mi = min(item.(ammotype), ammomax);
 750                 if (player.(ammotype) < mi)
 751                 {
 752                         player.(ammotype) = mi;
 753                         goto YEAH;
 754                 }
 755         }
 756
 757         return false;
 758
 759 LABEL(YEAH)
 760         switch(mode)
 761         {
 762                 case ITEM_MODE_FUEL:
 763                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 764                         break;
 765                 case ITEM_MODE_HEALTH:
 766                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 767                         break;
 768                 case ITEM_MODE_ARMOR:
 769                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 770                         break;
 771                 default:
 772                         break;
 773         }
 774         return true;
 775 }
 776
 777 float Item_GiveTo(entity item, entity player)
 778 {
 779         float pickedup;
 780
 781         // if nothing happens to player, just return without taking the item
 782         pickedup = false;
 783         int _switchweapon = 0;
 784         // in case the player has autoswitch enabled do the following:
 785         // if the player is using their best weapon before items are given, they
 786         // probably want to switch to an even better weapon after items are given
 787
 788         if(CS(player).autoswitch)
 789         {
 790                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 791                 {
 792                         .entity weaponentity = weaponentities[slot];
 793                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 794                         {
 795                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
 796                                         _switchweapon |= BIT(slot);
 797
 798                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
 799                                         _switchweapon |= BIT(slot);
 800                         }
 801                 }
 802         }
 803
 804         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 805         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 806         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 807         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 808         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 809         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 810         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 811         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 812
 813         if (item.itemdef.instanceOfWeaponPickup)
 814         {
 815                 WepSet w;
 816                 w = item.weapons;
 817                 w &= ~player.weapons;
 818
 819                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
 820                 {
 821                         pickedup = true;
 822                         FOREACH(Weapons, it != WEP_Null, {
 823                                 if(w & (it.m_wepset))
 824                                 {
 825                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 826                                         {
 827                                                 .entity weaponentity = weaponentities[slot];
 828                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 829                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
 830                                         }
 831                                         W_GiveWeapon(player, it.m_id);
 832                                 }
 833                         });
 834                 }
 835         }
 836
 837         if (item.itemdef.instanceOfPowerup)
 838         {
 839                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
 840                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
 841                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
 842                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
 843         }
 844
 845         int its;
 846         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 847         {
 848                 pickedup = true;
 849                 player.items |= its;
 850                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 851         }
 852
 853         if (item.strength_finished)
 854         {
 855                 pickedup = true;
 856                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 857         }
 858         if (item.invincible_finished)
 859         {
 860                 pickedup = true;
 861                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 862         }
 863         if (item.superweapons_finished)
 864         {
 865                 pickedup = true;
 866                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 867         }
 868
 869 LABEL(skip)
 870
 871         // always eat teamed entities
 872         if(item.team)
 873                 pickedup = true;
 874
 875         if (!pickedup)
 876                 return 0;
 877
 878         // crude hack to enforce switching weapons
 879         if(g_cts && item.itemdef.instanceOfWeaponPickup)
 880         {
 881                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 882                 {
 883                         .entity weaponentity = weaponentities[slot];
 884                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
 885                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
 886                 }
 887                 return 1;
 888         }
 889
 890         if(_switchweapon)
 891         {
 892                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 893                 {
 894                         .entity weaponentity = weaponentities[slot];
 895                         if(_switchweapon & BIT(slot))
 896                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
 897                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
 898                 }
 899         }
 900
 901         return 1;
 902 }
 903
 904 void Item_Touch(entity this, entity toucher)
 905 {
 906
 907         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 908         if (this.classname == "droppedweapon")
 909         {
 910                 if (ITEM_TOUCH_NEEDKILL())
 911                 {
 912                         delete(this);
 913                         return;
 914                 }
 915         }
 916
 917         if(!(toucher.flags & FL_PICKUPITEMS)
 918         || STAT(FROZEN, toucher)
 919         || IS_DEAD(toucher)
 920         || (this.solid != SOLID_TRIGGER)
 921         || (this.owner == toucher)
 922         || (time < this.item_spawnshieldtime)
 923         ) { return; }
 924
 925         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
 926         {
 927                 case MUT_ITEMTOUCH_RETURN: { return; }
 928                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
 929         }
 930
 931         toucher = M_ARGV(1, entity);
 932
 933         if (this.classname == "droppedweapon")
 934         {
 935                 this.strength_finished = max(0, this.strength_finished - time);
 936                 this.invincible_finished = max(0, this.invincible_finished - time);
 937                 this.superweapons_finished = max(0, this.superweapons_finished - time);
 938         }
 939         entity it = this.itemdef;
 940         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
 941         if (!gave)
 942         {
 943                 if (this.classname == "droppedweapon")
 944                 {
 945                         // undo what we did above
 946                         this.strength_finished += time;
 947                         this.invincible_finished += time;
 948                         this.superweapons_finished += time;
 949                 }
 950                 return;
 951         }
 952
 953 LABEL(pickup)
 954
 955         toucher.last_pickup = time;
 956
 957         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 958         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
 959
 960         if (this.classname == "droppedweapon")
 961                 delete(this);
 962         else if (this.spawnshieldtime)
 963         {
 964                 entity e;
 965                 if(this.team)
 966                 {
 967                         RandomSelection_Init();
 968                         IL_EACH(g_items, it.team == this.team,
 969                         {
 970                                 if(it.itemdef) // is a registered item
 971                                 {
 972                                         Item_Show(it, -1);
 973                                         RandomSelection_AddEnt(it, it.cnt, 0);
 974                                 }
 975                         });
 976                         e = RandomSelection_chosen_ent;
 977                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
 978                 }
 979                 else
 980                         e = this;
 981                 Item_ScheduleRespawn(e);
 982         }
 983 }
 984
 985 void Item_Reset(entity this)
 986 {
 987         Item_Show(this, !this.state);
 988         setorigin(this, this.origin);
 989
 990         if (this.classname != "droppedweapon")
 991         {
 992                 setthink(this, Item_Think);
 993                 this.nextthink = time;
 994
 995                 if (this.waypointsprite_attached)
 996                         WaypointSprite_Kill(this.waypointsprite_attached);
 997
 998                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 999                         Item_ScheduleInitialRespawn(this);
1000         }
1001 }
1002
1003 void Item_FindTeam(entity this)
1004 {
1005         entity e;
1006
1007         if(this.effects & EF_NODRAW)
1008         {
1009                 // marker for item team search
1010                 LOG_TRACE("Initializing item team ", ftos(this.team));
1011                 RandomSelection_Init();
1012                 IL_EACH(g_items, it.team == this.team,
1013                 {
1014                         if(it.itemdef) // is a registered item
1015                                 RandomSelection_AddEnt(it, it.cnt, 0);
1016                 });
1017
1018                 e = RandomSelection_chosen_ent;
1019                 e.state = 0;
1020                 Item_Show(e, 1);
1021
1022                 IL_EACH(g_items, it.team == this.team,
1023                 {
1024                         if(it.itemdef) // is a registered item
1025                         {
1026                                 if(it != e)
1027                                 {
1028                                         // make it non-spawned
1029                                         Item_Show(it, -1);
1030                                         it.state = 1; // state 1 = initially hidden item, apparently
1031                                 }
1032                                 it.effects &= ~EF_NODRAW;
1033                         }
1034                 });
1035
1036                 Item_Reset(this);
1037         }
1038 }
1039
1040 // Savage: used for item garbage-collection
1041 void RemoveItem(entity this)
1042 {
1043         if(wasfreed(this) || !this) { return; }
1044         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
1045         delete(this);
1046 }
1047
1048 // pickup evaluation functions
1049 // these functions decide how desirable an item is to the bots
1050
1051 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1052
1053 float weapon_pickupevalfunc(entity player, entity item)
1054 {
1055         // See if I have it already
1056         if(player.weapons & item.weapons)
1057         {
1058                 // If I can pick it up
1059                 if(!item.spawnshieldtime)
1060                         return 0;
1061                 return ammo_pickupevalfunc(player, item);
1062         }
1063
1064         // reduce weapon value if bot already got a good arsenal
1065         float c = 1;
1066         int weapons_value = 0;
1067         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
1068                 weapons_value += it.bot_pickupbasevalue;
1069         });
1070         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1071
1072         return item.bot_pickupbasevalue * c;
1073 }
1074
1075 float ammo_pickupevalfunc(entity player, entity item)
1076 {
1077         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1078         entity wpn = NULL;
1079         float c = 0;
1080         float rating = 0;
1081
1082         // Detect needed ammo
1083         if(item.itemdef.instanceOfWeaponPickup)
1084         {
1085                 entity ammo = NULL;
1086                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1087                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1088                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1089                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1090                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1091                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1092
1093                 if(!ammo)
1094                         return 0;
1095                 wpn = item;
1096                 rating = ammo.m_botvalue;
1097         }
1098         else
1099         {
1100                 FOREACH(Weapons, it != WEP_Null, {
1101                         if(!(player.weapons & (it.m_wepset)))
1102                                 continue;
1103
1104                         switch(it.ammo_field)
1105                         {
1106                                 case ammo_shells:  need_shells  = true; break;
1107                                 case ammo_nails:   need_nails   = true; break;
1108                                 case ammo_rockets: need_rockets = true; break;
1109                                 case ammo_cells:   need_cells   = true; break;
1110                                 case ammo_plasma:  need_plasma  = true; break;
1111                                 case ammo_fuel:    need_fuel    = true; break;
1112                         }
1113                 });
1114                 rating = item.bot_pickupbasevalue;
1115         }
1116
1117         float noammorating = 0.5;
1118
1119         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1120                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1121
1122         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1123                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1124
1125         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1126                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1127
1128         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1129                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1130
1131         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1132                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1133
1134         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1135                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1136
1137         rating *= min(c, 2);
1138         if(wpn)
1139                 rating += wpn.bot_pickupbasevalue * 0.1;
1140         return rating;
1141 }
1142
1143 .int item_group;
1144 .int item_group_count;
1145 float healtharmor_pickupevalfunc(entity player, entity item)
1146 {
1147         float c = 0;
1148         float rating = item.bot_pickupbasevalue;
1149
1150         float itemarmor = item.armorvalue;
1151         float itemhealth = item.health;
1152
1153         if(item.item_group)
1154         {
1155                 itemarmor *= min(4, item.item_group_count);
1156                 itemhealth *= min(4, item.item_group_count);
1157         }
1158
1159         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1160                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1161
1162         if (itemhealth && (player.health < item.max_health))
1163                 c = itemhealth / max(1, player.health);
1164
1165         rating *= min(2, c);
1166         return rating;
1167 }
1168
1169 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1170 {
1171         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1172                 RemoveItem(this);
1173 }
1174
1175 void item_use(entity this, entity actor, entity trigger)
1176 {
1177         // use the touch function to handle collection
1178         gettouch(this)(this, actor);
1179 }
1180
1181 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1182 {
1183         string itemname = def.m_name;
1184         Model itemmodel = def.m_model;
1185     Sound pickupsound = def.m_sound;
1186         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1187         float pickupbasevalue = def.m_botvalue;
1188         int itemflags = def.m_itemflags;
1189
1190         startitem_failed = false;
1191
1192         this.item_model_ent = itemmodel;
1193     this.item_pickupsound_ent = pickupsound;
1194
1195     if(def.m_iteminit)
1196         def.m_iteminit(this);
1197
1198         if(!this.respawntime) // both need to be set
1199         {
1200                 this.respawntime = defaultrespawntime;
1201                 this.respawntimejitter = defaultrespawntimejitter;
1202         }
1203
1204         if(!this.pickup_anyway && def.m_pickupanyway)
1205                 this.pickup_anyway = def.m_pickupanyway();
1206
1207         int itemid = def.m_itemid;
1208         this.items = itemid;
1209         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1210         this.weapon = weaponid;
1211
1212         if(!this.fade_end)
1213         {
1214                 this.fade_start = autocvar_g_items_mindist;
1215                 this.fade_end = autocvar_g_items_maxdist;
1216         }
1217
1218         if(weaponid)
1219                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1220
1221         this.flags = FL_ITEM | itemflags;
1222         IL_PUSH(g_items, this);
1223
1224         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1225         {
1226                 startitem_failed = true;
1227                 delete(this);
1228                 return;
1229         }
1230
1231         // is it a dropped weapon?
1232         if (this.classname == "droppedweapon")
1233         {
1234                 this.reset = SUB_Remove;
1235                 // it's a dropped weapon
1236                 set_movetype(this, MOVETYPE_TOSS);
1237
1238                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1239                 setthink(this, RemoveItem);
1240                 this.nextthink = time + 20;
1241
1242                 this.takedamage = DAMAGE_YES;
1243                 this.event_damage = Item_Damage;
1244
1245                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1246                 {
1247                         // if item is worthless after a timer, have it expire then
1248                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1249                 }
1250
1251                 // don't drop if in a NODROP zone (such as lava)
1252                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1253                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1254                 {
1255                         startitem_failed = true;
1256                         delete(this);
1257                         return;
1258                 }
1259         }
1260         else
1261         {
1262                 if(!have_pickup_item(this))
1263                 {
1264                         startitem_failed = true;
1265                         delete(this);
1266                         return;
1267                 }
1268
1269                 if(this.angles != '0 0 0')
1270                         this.SendFlags |= ISF_ANGLES;
1271
1272                 this.reset = Item_Reset;
1273                 // it's a level item
1274                 if(this.spawnflags & 1)
1275                         this.noalign = 1;
1276                 if (this.noalign > 0)
1277                         set_movetype(this, MOVETYPE_NONE);
1278                 else
1279                         set_movetype(this, MOVETYPE_TOSS);
1280                 // do item filtering according to game mode and other things
1281                 if (this.noalign <= 0)
1282                 {
1283                         // first nudge it off the floor a little bit to avoid math errors
1284                         setorigin(this, this.origin + '0 0 1');
1285                         // set item size before we spawn a spawnfunc_waypoint
1286                         setsize(this, def.m_mins, def.m_maxs);
1287                         this.SendFlags |= ISF_SIZE;
1288                         // note droptofloor returns false if stuck/or would fall too far
1289                         if (!this.noalign)
1290                                 droptofloor(this);
1291                         waypoint_spawnforitem(this);
1292                 }
1293
1294                 /*
1295                  * can't do it that way, as it would break maps
1296                  * TODO make a target_give like entity another way, that perhaps has
1297                  * the weapon name in a key
1298                 if(this.targetname)
1299                 {
1300                         // target_give not yet supported; maybe later
1301                         print("removed targeted ", this.classname, "\n");
1302                         startitem_failed = true;
1303                         delete(this);
1304                         return;
1305                 }
1306                 */
1307
1308                 if(this.targetname != "" && (this.spawnflags & 16))
1309                         this.use = item_use;
1310
1311                 if(autocvar_spawn_debug >= 2)
1312                 {
1313             // why not flags & fl_item?
1314                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1315                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1316                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1317                 error("Mapper sucks.");
1318             });
1319                         this.is_item = true;
1320                 }
1321
1322                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1323
1324                 precache_model(this.model);
1325                 precache_sound(this.item_pickupsound);
1326
1327                 if (   def.instanceOfPowerup
1328                         || def.instanceOfWeaponPickup
1329                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1330                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1331                         || (itemid & (IT_KEY1 | IT_KEY2))
1332                 ) this.target = "###item###"; // for finding the nearest item using find()
1333
1334                 Item_ItemsTime_SetTime(this, 0);
1335         }
1336
1337         this.bot_pickup = true;
1338         this.bot_pickupevalfunc = pickupevalfunc;
1339         this.bot_pickupbasevalue = pickupbasevalue;
1340         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1341         this.netname = itemname;
1342         settouch(this, Item_Touch);
1343         setmodel(this, MDL_Null); // precision set below
1344         //this.effects |= EF_LOWPRECISION;
1345
1346         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1347
1348         this.SendFlags |= ISF_SIZE;
1349
1350         if (!(this.spawnflags & 1024)) {
1351                 if(def.instanceOfPowerup)
1352                         this.ItemStatus |= ITS_ANIMATE1;
1353
1354                 if(this.armorvalue || this.health)
1355                         this.ItemStatus |= ITS_ANIMATE2;
1356         }
1357
1358         if(def.instanceOfWeaponPickup)
1359         {
1360                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1361                         this.colormap = 1024; // color shirt=0 pants=0 grey
1362                 else
1363                         this.gravity = 1;
1364                 if (!(this.spawnflags & 1024))
1365                         this.ItemStatus |= ITS_ANIMATE1;
1366                 this.SendFlags |= ISF_COLORMAP;
1367         }
1368
1369         this.state = 0;
1370         if(this.team) // broken, no idea why.
1371         {
1372                 if(!this.cnt)
1373                         this.cnt = 1; // item probability weight
1374
1375                 this.effects |= EF_NODRAW; // marker for item team search
1376                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1377         }
1378         else
1379                 Item_Reset(this);
1380
1381         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1382
1383         // call this hook after everything else has been done
1384         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1385         {
1386                 startitem_failed = true;
1387                 delete(this);
1388                 return;
1389         }
1390
1391         setItemGroup(this);
1392 }
1393
1394 void StartItem(entity this, GameItem def)
1395 {
1396     _StartItem(
1397         this,
1398         this.itemdef = def,
1399         def.m_respawntime(), // defaultrespawntime
1400         def.m_respawntimejitter() // defaultrespawntimejitter
1401         );
1402 }
1403
1404 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1405 int group_count = 1;
1406
1407 void setItemGroup(entity this)
1408 {
1409         if(!IS_SMALL(this.itemdef))
1410                 return;
1411
1412         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1413         {
1414                 if(!this.item_group)
1415                 {
1416                         if(!it.item_group)
1417                         {
1418                                 it.item_group = group_count;
1419                                 group_count++;
1420                         }
1421                         this.item_group = it.item_group;
1422                 }
1423                 else // spawning item is already part of a item_group X
1424                 {
1425                         if(!it.item_group)
1426                                 it.item_group = this.item_group;
1427                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1428                         {
1429                                 int grY = it.item_group;
1430                                 // move all items of item_group Y to item_group X
1431                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1432                                 {
1433                                         if(it.item_group == grY)
1434                                                 it.item_group = this.item_group;
1435                                 });
1436                         }
1437                 }
1438         });
1439 }
1440
1441 void setItemGroupCount()
1442 {
1443         for (int k = 1; k <= group_count; k++)
1444         {
1445                 int count = 0;
1446                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1447                 if (count)
1448                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1449         }
1450 }
1451
1452 spawnfunc(item_rockets)
1453 {
1454     StartItem(this, ITEM_Rockets);
1455 }
1456
1457 spawnfunc(item_bullets)
1458 {
1459         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1460            (this.classname != "droppedweapon"))
1461         {
1462                 weaponswapping = true;
1463                 spawnfunc_item_shells(this);
1464                 weaponswapping = false;
1465                 return;
1466         }
1467
1468     StartItem(this, ITEM_Bullets);
1469 }
1470
1471 spawnfunc(item_cells)
1472 {
1473         StartItem(this, ITEM_Cells);
1474 }
1475
1476 spawnfunc(item_plasma)
1477 {
1478         StartItem(this, ITEM_Plasma);
1479 }
1480
1481 spawnfunc(item_shells)
1482 {
1483         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1484            (this.classname != "droppedweapon"))
1485         {
1486                 weaponswapping = true;
1487                 spawnfunc_item_bullets(this);
1488                 weaponswapping = false;
1489                 return;
1490         }
1491
1492         StartItem(this, ITEM_Shells);
1493 }
1494
1495 spawnfunc(item_armor_small)
1496 {
1497         StartItem(this, ITEM_ArmorSmall);
1498 }
1499
1500 spawnfunc(item_armor_medium)
1501 {
1502         StartItem(this, ITEM_ArmorMedium);
1503 }
1504
1505 spawnfunc(item_armor_big)
1506 {
1507         StartItem(this, ITEM_ArmorBig);
1508 }
1509
1510 spawnfunc(item_armor_mega)
1511 {
1512         StartItem(this, ITEM_ArmorMega);
1513 }
1514
1515 spawnfunc(item_health_small)
1516 {
1517         StartItem(this, ITEM_HealthSmall);
1518 }
1519
1520 spawnfunc(item_health_medium)
1521 {
1522     StartItem(this, ITEM_HealthMedium);
1523 }
1524
1525 spawnfunc(item_health_big)
1526 {
1527         StartItem(this, ITEM_HealthBig);
1528 }
1529
1530 spawnfunc(item_health_mega)
1531 {
1532     StartItem(this, ITEM_HealthMega);
1533 }
1534
1535 // support old misnamed entities
1536 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1537 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1538 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1539 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1540 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1541 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1542 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1543
1544 spawnfunc(item_strength)
1545 {
1546         StartItem(this, ITEM_Strength);
1547 }
1548
1549 spawnfunc(item_invincible)
1550 {
1551         StartItem(this, ITEM_Shield);
1552 }
1553
1554 // compatibility:
1555 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1556
1557 void target_items_use(entity this, entity actor, entity trigger)
1558 {
1559         if(actor.classname == "droppedweapon")
1560         {
1561                 EXACTTRIGGER_TOUCH(this, trigger);
1562                 delete(actor);
1563                 return;
1564         }
1565
1566         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1567                 return;
1568
1569         if(trigger.solid == SOLID_TRIGGER)
1570         {
1571                 EXACTTRIGGER_TOUCH(this, trigger);
1572         }
1573
1574         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1575         {
1576                 delete(it);
1577         });
1578
1579         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1580                 centerprint(actor, this.message);
1581 }
1582
1583 spawnfunc(target_items)
1584 {
1585         int n;
1586         string s;
1587
1588         this.use = target_items_use;
1589         if(!this.strength_finished)
1590                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1591         if(!this.invincible_finished)
1592                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1593         if(!this.superweapons_finished)
1594                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1595
1596         n = tokenize_console(this.netname);
1597         if(argv(0) == "give")
1598         {
1599                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1600         }
1601         else
1602         {
1603                 for(int j = 0; j < n; ++j)
1604                 {
1605                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1606                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1607                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1608                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1609                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1610                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1611                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1612                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1613                         else
1614                         {
1615                                 FOREACH(Buffs, it != BUFF_Null,
1616                                 {
1617                                         s = Buff_UndeprecateName(argv(j));
1618                                         if(s == it.m_name)
1619                                         {
1620                                                 this.buffs |= (it.m_itemid);
1621                                                 break;
1622                                         }
1623                                 });
1624                                 FOREACH(Weapons, it != WEP_Null, {
1625                                         s = W_UndeprecateName(argv(j));
1626                                         if(s == it.netname)
1627                                         {
1628                                                 this.weapons |= (it.m_wepset);
1629                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1630                                                         it.wr_init(it);
1631                                                 break;
1632                                         }
1633                                 });
1634                         }
1635                 }
1636
1637                 string itemprefix, valueprefix;
1638                 if(this.spawnflags == 0)
1639                 {
1640                         itemprefix = "";
1641                         valueprefix = "";
1642                 }
1643                 else if(this.spawnflags == 1)
1644                 {
1645                         itemprefix = "max ";
1646                         valueprefix = "max ";
1647                 }
1648                 else if(this.spawnflags == 2)
1649                 {
1650                         itemprefix = "min ";
1651                         valueprefix = "min ";
1652                 }
1653                 else if(this.spawnflags == 4)
1654                 {
1655                         itemprefix = "minus ";
1656                         valueprefix = "max ";
1657                 }
1658                 else
1659                 {
1660                         error("invalid spawnflags");
1661                         itemprefix = valueprefix = string_null;
1662                 }
1663
1664                 this.netname = "";
1665                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1666                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1667                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1668                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1669                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1670                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1671                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1672                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1673                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1674                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1675                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1676                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1677                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1678                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1679                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1680                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1681                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1682         }
1683         this.netname = strzone(this.netname);
1684         //print(this.netname, "\n");
1685
1686         n = tokenize_console(this.netname);
1687         for(int j = 0; j < n; ++j)
1688         {
1689                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1690             it.wr_init(it);
1691             break;
1692                 });
1693         }
1694 }
1695
1696 spawnfunc(item_fuel)
1697 {
1698         StartItem(this, ITEM_JetpackFuel);
1699 }
1700
1701 spawnfunc(item_fuel_regen)
1702 {
1703         if(start_items & ITEM_JetpackRegen.m_itemid)
1704         {
1705                 spawnfunc_item_fuel(this);
1706                 return;
1707         }
1708         StartItem(this, ITEM_JetpackRegen);
1709 }
1710
1711 spawnfunc(item_jetpack)
1712 {
1713         if(start_items & ITEM_Jetpack.m_itemid)
1714         {
1715                 spawnfunc_item_fuel(this);
1716                 return;
1717         }
1718         StartItem(this, ITEM_Jetpack);
1719 }
1720
1721 float GiveWeapon(entity e, float wpn, float op, float val)
1722 {
1723         WepSet v0, v1;
1724         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1725         v0 = (e.weapons & s);
1726         switch(op)
1727         {
1728                 case OP_SET:
1729                         if(val > 0)
1730                                 e.weapons |= s;
1731                         else
1732                                 e.weapons &= ~s;
1733                         break;
1734                 case OP_MIN:
1735                 case OP_PLUS:
1736                         if(val > 0)
1737                                 e.weapons |= s;
1738                         break;
1739                 case OP_MAX:
1740                         if(val <= 0)
1741                                 e.weapons &= ~s;
1742                         break;
1743                 case OP_MINUS:
1744                         if(val > 0)
1745                                 e.weapons &= ~s;
1746                         break;
1747         }
1748         v1 = (e.weapons & s);
1749         return (v0 != v1);
1750 }
1751
1752 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1753 {
1754         bool had_buff = (e.buffs & thebuff.m_itemid);
1755         switch(op)
1756         {
1757                 case OP_SET:
1758                         if(val > 0)
1759                                 e.buffs |= thebuff.m_itemid;
1760                         else
1761                                 e.buffs &= ~thebuff.m_itemid;
1762                         break;
1763                 case OP_MIN:
1764                 case OP_PLUS:
1765                         if(val > 0)
1766                                 e.buffs |= thebuff.m_itemid;
1767                         break;
1768                 case OP_MAX:
1769                         if(val <= 0)
1770                                 e.buffs &= ~thebuff.m_itemid;
1771                         break;
1772                 case OP_MINUS:
1773                         if(val > 0)
1774                                 e.buffs &= ~thebuff.m_itemid;
1775                         break;
1776         }
1777         bool have_buff = (e.buffs & thebuff.m_itemid);
1778         return (had_buff != have_buff);
1779 }
1780
1781 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1782 {
1783         if(v1 == v0)
1784                 return;
1785         if(v1 <= v0 - t)
1786         {
1787                 if(snd_decr != NULL)
1788                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1789         }
1790         else if(v0 >= v0 + t)
1791         {
1792                 if(snd_incr != NULL)
1793                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1794         }
1795 }
1796
1797 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1798 {
1799         if(v0 < v1)
1800                 e.(rotfield) = max(e.(rotfield), time + rottime);
1801         else if(v0 > v1)
1802                 e.(regenfield) = max(e.(regenfield), time + regentime);
1803 }
1804 float GiveItems(entity e, float beginarg, float endarg)
1805 {
1806         float got, i, val, op;
1807         string cmd;
1808
1809         val = 999;
1810         op = OP_SET;
1811
1812         got = 0;
1813
1814         int _switchweapon = 0;
1815
1816         if(CS(e).autoswitch)
1817         {
1818                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1819                 {
1820                         .entity weaponentity = weaponentities[slot];
1821                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1822                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1823                                 _switchweapon |= BIT(slot);
1824                 }
1825         }
1826
1827         e.strength_finished = max(0, e.strength_finished - time);
1828         e.invincible_finished = max(0, e.invincible_finished - time);
1829         e.superweapons_finished = max(0, e.superweapons_finished - time);
1830
1831         PREGIVE(e, items);
1832         PREGIVE_WEAPONS(e);
1833         PREGIVE(e, strength_finished);
1834         PREGIVE(e, invincible_finished);
1835         PREGIVE(e, superweapons_finished);
1836         PREGIVE(e, ammo_nails);
1837         PREGIVE(e, ammo_cells);
1838         PREGIVE(e, ammo_plasma);
1839         PREGIVE(e, ammo_shells);
1840         PREGIVE(e, ammo_rockets);
1841         PREGIVE(e, ammo_fuel);
1842         PREGIVE(e, armorvalue);
1843         PREGIVE(e, health);
1844
1845         for(i = beginarg; i < endarg; ++i)
1846         {
1847                 cmd = argv(i);
1848
1849                 if(cmd == "0" || stof(cmd))
1850                 {
1851                         val = stof(cmd);
1852                         continue;
1853                 }
1854                 switch(cmd)
1855                 {
1856                         case "no":
1857                                 op = OP_MAX;
1858                                 val = 0;
1859                                 continue;
1860                         case "max":
1861                                 op = OP_MAX;
1862                                 continue;
1863                         case "min":
1864                                 op = OP_MIN;
1865                                 continue;
1866                         case "plus":
1867                                 op = OP_PLUS;
1868                                 continue;
1869                         case "minus":
1870                                 op = OP_MINUS;
1871                                 continue;
1872                         case "ALL":
1873                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1874                                 got += GiveValue(e, strength_finished, op, val);
1875                                 got += GiveValue(e, invincible_finished, op, val);
1876                                 got += GiveValue(e, superweapons_finished, op, val);
1877                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1878                         case "all":
1879                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1880                                 got += GiveValue(e, health, op, val);
1881                                 got += GiveValue(e, armorvalue, op, val);
1882                         case "allweapons":
1883                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1884                         //case "allbuffs": // all buffs makes a player god, do not want!
1885                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1886                         case "allammo":
1887                                 got += GiveValue(e, ammo_cells, op, val);
1888                                 got += GiveValue(e, ammo_plasma, op, val);
1889                                 got += GiveValue(e, ammo_shells, op, val);
1890                                 got += GiveValue(e, ammo_nails, op, val);
1891                                 got += GiveValue(e, ammo_rockets, op, val);
1892                                 got += GiveValue(e, ammo_fuel, op, val);
1893                                 break;
1894                         case "unlimited_ammo":
1895                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1896                                 break;
1897                         case "unlimited_weapon_ammo":
1898                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1899                                 break;
1900                         case "unlimited_superweapons":
1901                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1902                                 break;
1903                         case "jetpack":
1904                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1905                                 break;
1906                         case "fuel_regen":
1907                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1908                                 break;
1909                         case "strength":
1910                                 got += GiveValue(e, strength_finished, op, val);
1911                                 break;
1912                         case "invincible":
1913                                 got += GiveValue(e, invincible_finished, op, val);
1914                                 break;
1915                         case "superweapons":
1916                                 got += GiveValue(e, superweapons_finished, op, val);
1917                                 break;
1918                         case "cells":
1919                                 got += GiveValue(e, ammo_cells, op, val);
1920                                 break;
1921                         case "plasma":
1922                                 got += GiveValue(e, ammo_plasma, op, val);
1923                                 break;
1924                         case "shells":
1925                                 got += GiveValue(e, ammo_shells, op, val);
1926                                 break;
1927                         case "nails":
1928                         case "bullets":
1929                                 got += GiveValue(e, ammo_nails, op, val);
1930                                 break;
1931                         case "rockets":
1932                                 got += GiveValue(e, ammo_rockets, op, val);
1933                                 break;
1934                         case "health":
1935                                 got += GiveValue(e, health, op, val);
1936                                 break;
1937                         case "armor":
1938                                 got += GiveValue(e, armorvalue, op, val);
1939                                 break;
1940                         case "fuel":
1941                                 got += GiveValue(e, ammo_fuel, op, val);
1942                                 break;
1943                         default:
1944                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1945                                 {
1946                                         got += GiveBuff(e, it, op, val);
1947                                         break;
1948                                 });
1949                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1950                     got += GiveWeapon(e, it.m_id, op, val);
1951                     break;
1952                                 });
1953                                 break;
1954                 }
1955                 val = 999;
1956                 op = OP_SET;
1957         }
1958
1959         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1960         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1961         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1962         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1963         FOREACH(Weapons, it != WEP_Null, {
1964                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1965                 if(!(save_weapons & (it.m_wepset)))
1966                         if(e.weapons & (it.m_wepset))
1967                                 it.wr_init(it);
1968         });
1969         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1970         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1971         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1972         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1973         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1974         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1975         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1976         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1977         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1978         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1979         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1980
1981         if(e.superweapons_finished <= 0)
1982                 if(e.weapons & WEPSET_SUPERWEAPONS)
1983                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1984
1985         if(e.strength_finished <= 0)
1986                 e.strength_finished = 0;
1987         else
1988                 e.strength_finished += time;
1989         if(e.invincible_finished <= 0)
1990                 e.invincible_finished = 0;
1991         else
1992                 e.invincible_finished += time;
1993         if(e.superweapons_finished <= 0)
1994                 e.superweapons_finished = 0;
1995         else
1996                 e.superweapons_finished += time;
1997
1998         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1999         {
2000                 .entity weaponentity = weaponentities[slot];
2001                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
2002                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
2003                         _switchweapon |= BIT(slot);
2004         }
2005
2006         if(_switchweapon)
2007         {
2008                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2009                 {
2010                         .entity weaponentity = weaponentities[slot];
2011                         if(_switchweapon & BIT(slot))
2012                         {
2013                                 Weapon wep = w_getbestweapon(e, weaponentity);
2014                                 if(wep != e.(weaponentity).m_switchweapon)
2015                                         W_SwitchWeapon_Force(e, wep, weaponentity);
2016                         }
2017                 }
2018         }
2019
2020         return got;
2021 }
2022 #endif