qcsrc/common/physics.qc

   1 #include "physics.qh"
   2 #include "triggers/include.qh"
   3 #include "viewloc.qh"
   4
   5 #ifdef SVQC
   6
   7 #include "../server/miscfunctions.qh"
   8 #include "triggers/trigger/viewloc.qh"
   9
  10 // client side physics
  11 bool Physics_Valid(string thecvar)
  12 {
  13         return autocvar_g_physics_clientselect && strhasword(autocvar_g_physics_clientselect_options, thecvar);
  14 }
  15
  16 float Physics_ClientOption(entity this, string option)
  17 {
  18         if(Physics_Valid(this.cvar_cl_physics))
  19         {
  20                 string s = sprintf("g_physics_%s_%s", this.cvar_cl_physics, option);
  21                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  22                         return cvar(s);
  23         }
  24         if(autocvar_g_physics_clientselect && autocvar_g_physics_clientselect_default)
  25         {
  26                 string s = sprintf("g_physics_%s_%s", autocvar_g_physics_clientselect_default, option);
  27                 if(cvar_type(s) & CVAR_TYPEFLAG_EXISTS)
  28                         return cvar(s);
  29         }
  30         return cvar(strcat("sv_", option));
  31 }
  32
  33 void Physics_UpdateStats(entity this, float maxspd_mod)
  34 {
  35         STAT(MOVEVARS_AIRACCEL_QW, this) = AdjustAirAccelQW(Physics_ClientOption(this, "airaccel_qw"), maxspd_mod);
  36         STAT(MOVEVARS_AIRSTRAFEACCEL_QW, this) = (Physics_ClientOption(this, "airstrafeaccel_qw"))
  37                 ? AdjustAirAccelQW(Physics_ClientOption(this, "airstrafeaccel_qw"), maxspd_mod)
  38                 : 0;
  39         STAT(MOVEVARS_AIRSPEEDLIMIT_NONQW, this) = Physics_ClientOption(this, "airspeedlimit_nonqw") * maxspd_mod;
  40         STAT(MOVEVARS_MAXSPEED, this) = Physics_ClientOption(this, "maxspeed") * maxspd_mod; // also slow walking
  41
  42         // old stats
  43         // fix some new settings
  44         STAT(MOVEVARS_AIRACCEL_QW_STRETCHFACTOR, this) = Physics_ClientOption(this, "airaccel_qw_stretchfactor");
  45         STAT(MOVEVARS_MAXAIRSTRAFESPEED, this) = Physics_ClientOption(this, "maxairstrafespeed");
  46         STAT(MOVEVARS_MAXAIRSPEED, this) = Physics_ClientOption(this, "maxairspeed");
  47         STAT(MOVEVARS_AIRSTRAFEACCELERATE, this) = Physics_ClientOption(this, "airstrafeaccelerate");
  48         STAT(MOVEVARS_WARSOWBUNNY_TURNACCEL, this) = Physics_ClientOption(this, "warsowbunny_turnaccel");
  49         STAT(MOVEVARS_AIRACCEL_SIDEWAYS_FRICTION, this) = Physics_ClientOption(this, "airaccel_sideways_friction");
  50         STAT(MOVEVARS_AIRCONTROL, this) = Physics_ClientOption(this, "aircontrol");
  51         STAT(MOVEVARS_AIRCONTROL_POWER, this) = Physics_ClientOption(this, "aircontrol_power");
  52         STAT(MOVEVARS_AIRCONTROL_PENALTY, this) = Physics_ClientOption(this, "aircontrol_penalty");
  53         STAT(MOVEVARS_WARSOWBUNNY_AIRFORWARDACCEL, this) = Physics_ClientOption(this, "warsowbunny_airforwardaccel");
  54         STAT(MOVEVARS_WARSOWBUNNY_TOPSPEED, this) = Physics_ClientOption(this, "warsowbunny_topspeed");
  55         STAT(MOVEVARS_WARSOWBUNNY_ACCEL, this) = Physics_ClientOption(this, "warsowbunny_accel");
  56         STAT(MOVEVARS_WARSOWBUNNY_BACKTOSIDERATIO, this) = Physics_ClientOption(this, "warsowbunny_backtosideratio");
  57         STAT(MOVEVARS_FRICTION, this) = Physics_ClientOption(this, "friction");
  58         STAT(MOVEVARS_ACCELERATE, this) = Physics_ClientOption(this, "accelerate");
  59         STAT(MOVEVARS_STOPSPEED, this) = Physics_ClientOption(this, "stopspeed");
  60         STAT(MOVEVARS_AIRACCELERATE, this) = Physics_ClientOption(this, "airaccelerate");
  61         STAT(MOVEVARS_AIRSTOPACCELERATE, this) = Physics_ClientOption(this, "airstopaccelerate");
  62         STAT(MOVEVARS_JUMPVELOCITY, this) = Physics_ClientOption(this, "jumpvelocity");
  63         STAT(MOVEVARS_TRACK_CANJUMP, this) = Physics_ClientOption(this, "track_canjump");
  64 }
  65 #endif
  66
  67 float IsMoveInDirection(vector mv, float ang) // key mix factor
  68 {
  69         if (mv_x == 0 && mv_y == 0)
  70                 return 0; // avoid division by zero
  71         ang -= RAD2DEG * atan2(mv_y, mv_x);
  72         ang = remainder(ang, 360) / 45;
  73         return ang > 1 ? 0 : ang < -1 ? 0 : 1 - fabs(ang);
  74 }
  75
  76 float GeomLerp(float a, float lerp, float b)
  77 {
  78         return a == 0 ? (lerp < 1 ? 0 : b)
  79                 : b == 0 ? (lerp > 0 ? 0 : a)
  80                 : a * pow(fabs(b / a), lerp);
  81 }
  82
  83 #define unstick_offsets(X) \
  84 /* 1 no nudge (just return the original if this test passes) */ \
  85         X(' 0.000  0.000  0.000') \
  86 /* 6 simple nudges */ \
  87         X(' 0.000  0.000  0.125') X('0.000  0.000 -0.125') \
  88         X('-0.125  0.000  0.000') X('0.125  0.000  0.000') \
  89         X(' 0.000 -0.125  0.000') X('0.000  0.125  0.000') \
  90 /* 4 diagonal flat nudges */ \
  91         X('-0.125 -0.125  0.000') X('0.125 -0.125  0.000') \
  92         X('-0.125  0.125  0.000') X('0.125  0.125  0.000') \
  93 /* 8 diagonal upward nudges */ \
  94         X('-0.125  0.000  0.125') X('0.125  0.000  0.125') \
  95         X(' 0.000 -0.125  0.125') X('0.000  0.125  0.125') \
  96         X('-0.125 -0.125  0.125') X('0.125 -0.125  0.125') \
  97         X('-0.125  0.125  0.125') X('0.125  0.125  0.125') \
  98 /* 8 diagonal downward nudges */ \
  99         X('-0.125  0.000 -0.125') X('0.125  0.000 -0.125') \
 100         X(' 0.000 -0.125 -0.125') X('0.000  0.125 -0.125') \
 101         X('-0.125 -0.125 -0.125') X('0.125 -0.125 -0.125') \
 102         X('-0.125  0.125 -0.125') X('0.125  0.125 -0.125') \
 103 /**/
 104
 105 void PM_ClientMovement_Unstick(entity this)
 106 {
 107         #define X(unstick_offset) \
 108         { \
 109                 vector neworigin = unstick_offset + this.origin; \
 110                 tracebox(neworigin, PL_CROUCH_MIN, PL_CROUCH_MAX, neworigin, MOVE_NORMAL, this); \
 111                 if (!trace_startsolid) \
 112                 { \
 113                         setorigin(this, neworigin); \
 114                         return; \
 115                 } \
 116         }
 117         unstick_offsets(X);
 118         #undef X
 119 }
 120
 121 void PM_ClientMovement_UpdateStatus(entity this, bool ground)
 122 {
 123 #ifdef CSQC
 124         // make sure player is not stuck
 125         if(autocvar_cl_movement != 3)
 126                 PM_ClientMovement_Unstick(this);
 127
 128         // set crouched
 129         if (PHYS_INPUT_BUTTON_CROUCH(this))
 130         {
 131                 // wants to crouch, this always works
 132                 if (!IS_DUCKED(this)) SET_DUCKED(this);
 133         }
 134         else
 135         {
 136                 // wants to stand, if currently crouching we need to check for a low ceiling first
 137                 if (IS_DUCKED(this))
 138                 {
 139                         tracebox(this.origin, PL_MIN, PL_MAX, this.origin, MOVE_NORMAL, this);
 140                         if (!trace_startsolid) UNSET_DUCKED(this);
 141                 }
 142         }
 143
 144         // set onground
 145         vector origin1 = this.origin + '0 0 1';
 146         vector origin2 = this.origin - '0 0 1';
 147
 148         if (ground && autocvar_cl_movement != 3)
 149         {
 150                 tracebox(origin1, this.mins, this.maxs, origin2, MOVE_NORMAL, this);
 151                 if (trace_fraction < 1.0 && trace_plane_normal.z > 0.7)
 152                 {
 153                         SET_ONGROUND(this);
 154
 155                         // this code actually "predicts" an impact; so let's clip velocity first
 156                         this.velocity -= this.velocity * trace_plane_normal * trace_plane_normal;
 157                 }
 158                 else
 159                         UNSET_ONGROUND(this);
 160         }
 161
 162         if(autocvar_cl_movement != 3)
 163         {
 164                 // set watertype/waterlevel
 165                 origin1 = this.origin;
 166                 origin1.z += this.mins_z + 1;
 167                 this.waterlevel = WATERLEVEL_NONE;
 168
 169                 int thepoint = pointcontents(origin1);
 170
 171                 this.watertype = (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME);
 172
 173                 if (this.watertype)
 174                 {
 175                         this.waterlevel = WATERLEVEL_WETFEET;
 176                         origin1.z = this.origin.z + (this.mins.z + this.maxs.z) * 0.5;
 177                         thepoint = pointcontents(origin1);
 178                         if (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 179                         {
 180                                 this.waterlevel = WATERLEVEL_SWIMMING;
 181                                 origin1.z = this.origin.z + 22;
 182                                 thepoint = pointcontents(origin1);
 183                                 if (thepoint == CONTENT_WATER || thepoint == CONTENT_LAVA || thepoint == CONTENT_SLIME)
 184                                         this.waterlevel = WATERLEVEL_SUBMERGED;
 185                         }
 186                 }
 187         }
 188
 189         if (IS_ONGROUND(this) || this.velocity.z <= 0 || PHYS_TELEPORT_TIME(this) <= 0)
 190                 PHYS_TELEPORT_TIME(this) = 0;
 191 #endif
 192 }
 193
 194 void PM_ClientMovement_Move(entity this)
 195 {
 196 #ifdef CSQC
 197
 198         PM_ClientMovement_UpdateStatus(this, false);
 199         if(autocvar_cl_movement == 3)
 200                 return;
 201
 202         int bump;
 203         float t;
 204         float f;
 205         vector neworigin;
 206         vector currentorigin2;
 207         vector neworigin2;
 208         vector primalvelocity;
 209
 210         vector trace1_endpos = '0 0 0';
 211         vector trace2_endpos = '0 0 0';
 212         vector trace3_endpos = '0 0 0';
 213         float trace1_fraction = 0;
 214         float trace2_fraction = 0;
 215         float trace3_fraction = 0;
 216         vector trace1_plane_normal = '0 0 0';
 217         vector trace2_plane_normal = '0 0 0';
 218         vector trace3_plane_normal = '0 0 0';
 219
 220         primalvelocity = this.velocity;
 221         for(bump = 0, t = PHYS_INPUT_TIMELENGTH; bump < 8 && (this.velocity * this.velocity) > 0; bump++)
 222         {
 223                 neworigin = this.origin + t * this.velocity;
 224                 tracebox(this.origin, this.mins, this.maxs, neworigin, MOVE_NORMAL, this);
 225                 trace1_endpos = trace_endpos;
 226                 trace1_fraction = trace_fraction;
 227                 trace1_plane_normal = trace_plane_normal;
 228                 if(trace1_fraction < 1 && trace1_plane_normal_z == 0)
 229                 {
 230                         // may be a step or wall, try stepping up
 231                         // first move forward at a higher level
 232                         currentorigin2 = this.origin;
 233                         currentorigin2_z += PHYS_STEPHEIGHT;
 234                         neworigin2 = neworigin;
 235                         neworigin2_z += PHYS_STEPHEIGHT;
 236                         tracebox(currentorigin2, this.mins, this.maxs, neworigin2, MOVE_NORMAL, this);
 237                         trace2_endpos = trace_endpos;
 238                         trace2_fraction = trace_fraction;
 239                         trace2_plane_normal = trace_plane_normal;
 240                         if(!trace_startsolid)
 241                         {
 242                                 // then move down from there
 243                                 currentorigin2 = trace2_endpos;
 244                                 neworigin2 = trace2_endpos;
 245                                 neworigin2_z = this.origin_z;
 246                                 tracebox(currentorigin2, this.mins, this.maxs, neworigin2, MOVE_NORMAL, this);
 247                                 trace3_endpos = trace_endpos;
 248                                 trace3_fraction = trace_fraction;
 249                                 trace3_plane_normal = trace_plane_normal;
 250                                 // accept the new trace if it made some progress
 251                                 if(fabs(trace3_endpos_x - trace1_endpos_x) >= 0.03125 || fabs(trace3_endpos_y - trace1_endpos_y) >= 0.03125)
 252                                 {
 253                                         trace1_endpos = trace2_endpos;
 254                                         trace1_fraction = trace2_fraction;
 255                                         trace1_plane_normal = trace2_plane_normal;
 256                                         trace1_endpos = trace3_endpos;
 257                                 }
 258                         }
 259                 }
 260
 261                 // check if it moved at all
 262                 if(trace1_fraction >= 0.001)
 263                         setorigin(this, trace1_endpos);
 264
 265                 // check if it moved all the way
 266                 if(trace1_fraction == 1)
 267                         break;
 268
 269                 // this is only really needed for nogravityonground combined with gravityunaffectedbyticrate
 270                 // <LordHavoc> I'm pretty sure I commented it out solely because it seemed redundant
 271                 // this got commented out in a change that supposedly makes the code match QW better
 272                 // so if this is broken, maybe put it in an if(cls.protocol != PROTOCOL_QUAKEWORLD) block
 273                 if(trace1_plane_normal_z > 0.7)
 274                         SET_ONGROUND(this);
 275
 276                 t -= t * trace1_fraction;
 277
 278                 f = (this.velocity * trace1_plane_normal);
 279                 this.velocity = this.velocity + -f * trace1_plane_normal;
 280         }
 281         if(PHYS_TELEPORT_TIME(this) > 0)
 282                 this.velocity = primalvelocity;
 283 #endif
 284 }
 285
 286 void CPM_PM_Aircontrol(entity this, vector wishdir, float wishspeed)
 287 {
 288         float k = 32 * (2 * IsMoveInDirection(this.movement, 0) - 1);
 289         if (k <= 0)
 290                 return;
 291
 292         k *= bound(0, wishspeed / PHYS_MAXAIRSPEED(this), 1);
 293
 294         float zspeed = this.velocity_z;
 295         this.velocity_z = 0;
 296         float xyspeed = vlen(this.velocity);
 297         this.velocity = normalize(this.velocity);
 298
 299         float dot = this.velocity * wishdir;
 300
 301         if (dot > 0) // we can't change direction while slowing down
 302         {
 303                 k *= pow(dot, PHYS_AIRCONTROL_POWER(this)) * PHYS_INPUT_TIMELENGTH;
 304                 xyspeed = max(0, xyspeed - PHYS_AIRCONTROL_PENALTY(this) * sqrt(max(0, 1 - dot*dot)) * k/32);
 305                 k *= PHYS_AIRCONTROL(this);
 306                 this.velocity = normalize(this.velocity * xyspeed + wishdir * k);
 307         }
 308
 309         this.velocity = this.velocity * xyspeed;
 310         this.velocity_z = zspeed;
 311 }
 312
 313 float AdjustAirAccelQW(float accelqw, float factor)
 314 {
 315         return copysign(bound(0.000001, 1 - (1 - fabs(accelqw)) * factor, 1), accelqw);
 316 }
 317
 318 // example config for alternate speed clamping:
 319 //   sv_airaccel_qw 0.8
 320 //   sv_airaccel_sideways_friction 0
 321 //   prvm_globalset server speedclamp_mode 1
 322 //     (or 2)
 323 void PM_Accelerate(entity this, vector wishdir, float wishspeed, float wishspeed0, float accel, float accelqw, float stretchfactor, float sidefric, float speedlimit)
 324 {
 325         float speedclamp = stretchfactor > 0 ? stretchfactor
 326         : accelqw < 0 ? 1 // full clamping, no stretch
 327         : -1; // no clamping
 328
 329         accelqw = fabs(accelqw);
 330
 331         if (GAMEPLAYFIX_Q2AIRACCELERATE)
 332                 wishspeed0 = wishspeed; // don't need to emulate this Q1 bug
 333
 334         float vel_straight = this.velocity * wishdir;
 335         float vel_z = this.velocity_z;
 336         vector vel_xy = vec2(this.velocity);
 337         vector vel_perpend = vel_xy - vel_straight * wishdir;
 338
 339         float step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
 340
 341         float vel_xy_current  = vlen(vel_xy);
 342         if (speedlimit)
 343                 accelqw = AdjustAirAccelQW(accelqw, (speedlimit - bound(wishspeed, vel_xy_current, speedlimit)) / max(1, speedlimit - wishspeed));
 344         float vel_xy_forward =  vel_xy_current  + bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
 345         float vel_xy_backward = vel_xy_current  - bound(0, wishspeed + vel_xy_current, step) * accelqw - step * (1 - accelqw);
 346         vel_xy_backward = max(0, vel_xy_backward); // not that it REALLY occurs that this would cause wrong behaviour afterwards
 347         vel_straight =          vel_straight    + bound(0, wishspeed - vel_straight,   step) * accelqw + step * (1 - accelqw);
 348
 349         if (sidefric < 0 && (vel_perpend*vel_perpend))
 350                 // negative: only apply so much sideways friction to stay below the speed you could get by "braking"
 351         {
 352                 float f = max(0, 1 + PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 353                 float themin = (vel_xy_backward * vel_xy_backward - vel_straight * vel_straight) / (vel_perpend * vel_perpend);
 354                 // assume: themin > 1
 355                 // vel_xy_backward*vel_xy_backward - vel_straight*vel_straight > vel_perpend*vel_perpend
 356                 // vel_xy_backward*vel_xy_backward > vel_straight*vel_straight + vel_perpend*vel_perpend
 357                 // vel_xy_backward*vel_xy_backward > vel_xy * vel_xy
 358                 // obviously, this cannot be
 359                 if (themin <= 0)
 360                         vel_perpend *= f;
 361                 else
 362                 {
 363                         themin = sqrt(themin);
 364                         vel_perpend *= max(themin, f);
 365                 }
 366         }
 367         else
 368                 vel_perpend *= max(0, 1 - PHYS_INPUT_TIMELENGTH * wishspeed * sidefric);
 369
 370         vel_xy = vel_straight * wishdir + vel_perpend;
 371
 372         if (speedclamp >= 0)
 373         {
 374                 float vel_xy_preclamp;
 375                 vel_xy_preclamp = vlen(vel_xy);
 376                 if (vel_xy_preclamp > 0) // prevent division by zero
 377                 {
 378                         vel_xy_current += (vel_xy_forward - vel_xy_current) * speedclamp;
 379                         if (vel_xy_current < vel_xy_preclamp)
 380                                 vel_xy *= (vel_xy_current / vel_xy_preclamp);
 381                 }
 382         }
 383
 384         this.velocity = vel_xy + vel_z * '0 0 1';
 385 }
 386
 387 void PM_AirAccelerate(entity this, vector wishdir, float wishspeed)
 388 {
 389         if (wishspeed == 0)
 390                 return;
 391
 392         vector curvel = this.velocity;
 393         curvel_z = 0;
 394         float curspeed = vlen(curvel);
 395
 396         if (wishspeed > curspeed * 1.01)
 397                 wishspeed = min(wishspeed, curspeed + PHYS_WARSOWBUNNY_AIRFORWARDACCEL(this) * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH);
 398         else
 399         {
 400                 float f = max(0, (PHYS_WARSOWBUNNY_TOPSPEED(this) - curspeed) / (PHYS_WARSOWBUNNY_TOPSPEED(this) - PHYS_MAXSPEED(this)));
 401                 wishspeed = max(curspeed, PHYS_MAXSPEED(this)) + PHYS_WARSOWBUNNY_ACCEL(this) * f * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH;
 402         }
 403         vector wishvel = wishdir * wishspeed;
 404         vector acceldir = wishvel - curvel;
 405         float addspeed = vlen(acceldir);
 406         acceldir = normalize(acceldir);
 407
 408         float accelspeed = min(addspeed, PHYS_WARSOWBUNNY_TURNACCEL(this) * PHYS_MAXSPEED(this) * PHYS_INPUT_TIMELENGTH);
 409
 410         if (PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this) < 1)
 411         {
 412                 vector curdir = normalize(curvel);
 413                 float dot = acceldir * curdir;
 414                 if (dot < 0)
 415                         acceldir -= (1 - PHYS_WARSOWBUNNY_BACKTOSIDERATIO(this)) * dot * curdir;
 416         }
 417
 418         this.velocity += accelspeed * acceldir;
 419 }
 420
 421
 422 /*
 423 =============
 424 PlayerJump
 425
 426 When you press the jump key
 427 returns true if handled
 428 =============
 429 */
 430 bool PlayerJump(entity this)
 431 {
 432         if (PHYS_FROZEN(this))
 433                 return true; // no jumping in freezetag when frozen
 434
 435 #ifdef SVQC
 436         if (this.player_blocked)
 437                 return true; // no jumping while blocked
 438 #endif
 439
 440         bool doublejump = false;
 441         float mjumpheight = PHYS_JUMPVELOCITY(this);
 442
 443         if (MUTATOR_CALLHOOK(PlayerJump, this, doublejump, mjumpheight))
 444                 return true;
 445
 446         doublejump = player_multijump;
 447         mjumpheight = player_jumpheight;
 448
 449         if (this.waterlevel >= WATERLEVEL_SWIMMING)
 450         {
 451                 this.velocity_z = PHYS_MAXSPEED(this) * 0.7;
 452                 return true;
 453         }
 454
 455         if (!doublejump)
 456                 if (!IS_ONGROUND(this))
 457                         return IS_JUMP_HELD(this);
 458
 459         bool track_jump = PHYS_CL_TRACK_CANJUMP(this);
 460         if(PHYS_TRACK_CANJUMP(this))
 461                 track_jump = true;
 462
 463         if (track_jump)
 464                 if (IS_JUMP_HELD(this))
 465                         return true;
 466
 467         // sv_jumpspeedcap_min/sv_jumpspeedcap_max act as baseline
 468         // velocity bounds.  Final velocity is bound between (jumpheight *
 469         // min + jumpheight) and (jumpheight * max + jumpheight);
 470
 471         if(PHYS_JUMPSPEEDCAP_MIN != "")
 472         {
 473                 float minjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MIN);
 474
 475                 if (this.velocity_z < minjumpspeed)
 476                         mjumpheight += minjumpspeed - this.velocity_z;
 477         }
 478
 479         if(PHYS_JUMPSPEEDCAP_MAX != "")
 480         {
 481                 // don't do jump speedcaps on ramps to preserve old xonotic ramjump style
 482                 tracebox(this.origin + '0 0 0.01', this.mins, this.maxs, this.origin - '0 0 0.01', MOVE_NORMAL, this);
 483
 484                 if (!(trace_fraction < 1 && trace_plane_normal_z < 0.98 && PHYS_JUMPSPEEDCAP_DISABLE_ONRAMPS))
 485                 {
 486                         float maxjumpspeed = mjumpheight * stof(PHYS_JUMPSPEEDCAP_MAX);
 487
 488                         if (this.velocity_z > maxjumpspeed)
 489                                 mjumpheight -= this.velocity_z - maxjumpspeed;
 490                 }
 491         }
 492
 493         if (!WAS_ONGROUND(this))
 494         {
 495 #ifdef SVQC
 496                 if(autocvar_speedmeter)
 497                         LOG_TRACE(strcat("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")\n"));
 498 #endif
 499                 if(this.lastground < time - 0.3)
 500                 {
 501                         this.velocity_x *= (1 - PHYS_FRICTION_ONLAND);
 502                         this.velocity_y *= (1 - PHYS_FRICTION_ONLAND);
 503                 }
 504 #ifdef SVQC
 505                 if(this.jumppadcount > 1)
 506                         LOG_TRACE(strcat(ftos(this.jumppadcount), "x jumppad combo\n"));
 507                 this.jumppadcount = 0;
 508 #endif
 509         }
 510
 511         this.velocity_z += mjumpheight;
 512
 513         UNSET_ONGROUND(this);
 514         SET_JUMP_HELD(this);
 515
 516 #ifdef SVQC
 517
 518         this.oldvelocity_z = this.velocity_z;
 519
 520         animdecide_setaction(this, ANIMACTION_JUMP, true);
 521
 522         if (autocvar_g_jump_grunt)
 523                 WITH(entity, self, this, PlayerSound(playersound_jump, CH_PLAYER, VOICETYPE_PLAYERSOUND));
 524 #endif
 525         return true;
 526 }
 527
 528 void CheckWaterJump(entity this)
 529 {
 530 // check for a jump-out-of-water
 531         makevectors(this.v_angle);
 532         vector start = this.origin;
 533         start_z += 8;
 534         v_forward_z = 0;
 535         normalize(v_forward);
 536         vector end = start + v_forward*24;
 537         traceline (start, end, true, this);
 538         if (trace_fraction < 1)
 539         {       // solid at waist
 540                 start_z = start_z + this.maxs_z - 8;
 541                 end = start + v_forward*24;
 542                 this.movedir = trace_plane_normal * -50;
 543                 traceline(start, end, true, this);
 544                 if (trace_fraction == 1)
 545                 {       // open at eye level
 546                         this.velocity_z = 225;
 547                         this.flags |= FL_WATERJUMP;
 548                         SET_JUMP_HELD(this);
 549                         PHYS_TELEPORT_TIME(this) = time + 2;    // safety net
 550                 }
 551         }
 552 }
 553
 554
 555 #ifdef SVQC
 556         #define JETPACK_JUMP(s) s.cvar_cl_jetpack_jump
 557 #elif defined(CSQC)
 558         float autocvar_cl_jetpack_jump;
 559         #define JETPACK_JUMP(s) autocvar_cl_jetpack_jump
 560 #endif
 561 .float jetpack_stopped;
 562 void CheckPlayerJump(entity this)
 563 {
 564 #ifdef SVQC
 565         float was_flying = ITEMS_STAT(this) & IT_USING_JETPACK;
 566 #endif
 567         if (JETPACK_JUMP(this) < 2)
 568                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 569
 570         if(PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this))
 571         {
 572                 float air_jump = !PlayerJump(this) || player_multijump; // PlayerJump() has important side effects
 573                 float activate = JETPACK_JUMP(this) && air_jump && PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_JETPACK(this);
 574                 float has_fuel = !PHYS_JETPACK_FUEL || PHYS_AMMO_FUEL(this) || ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO;
 575
 576                 if (!(ITEMS_STAT(this) & ITEM_Jetpack.m_itemid)) { }
 577                 else if (this.jetpack_stopped) { }
 578                 else if (!has_fuel)
 579                 {
 580 #ifdef SVQC
 581                         if (was_flying) // TODO: ran out of fuel message
 582                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 583                         else if (activate)
 584                                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_JETPACK_NOFUEL);
 585 #endif
 586                         this.jetpack_stopped = true;
 587                         ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 588                 }
 589                 else if (activate && !PHYS_FROZEN(this))
 590                         ITEMS_STAT(this) |= IT_USING_JETPACK;
 591         }
 592         else
 593         {
 594                 this.jetpack_stopped = false;
 595                 ITEMS_STAT(this) &= ~IT_USING_JETPACK;
 596         }
 597         if (!PHYS_INPUT_BUTTON_JUMP(this))
 598                 UNSET_JUMP_HELD(this);
 599
 600         if (this.waterlevel == WATERLEVEL_SWIMMING)
 601                 CheckWaterJump(this);
 602 }
 603
 604 float racecar_angle(float forward, float down)
 605 {
 606         if (forward < 0)
 607         {
 608                 forward = -forward;
 609                 down = -down;
 610         }
 611
 612         float ret = vectoyaw('0 1 0' * down + '1 0 0' * forward);
 613
 614         float angle_mult = forward / (800 + forward);
 615
 616         if (ret > 180)
 617                 return ret * angle_mult + 360 * (1 - angle_mult);
 618         else
 619                 return ret * angle_mult;
 620 }
 621
 622 string specialcommand = "xwxwxsxsxaxdxaxdx1x ";
 623 .float specialcommand_pos;
 624 void SpecialCommand()
 625 {
 626 #ifdef SVQC
 627         if (!CheatImpulse(99))
 628                 LOG_INFO("A hollow voice says \"Plugh\".\n");
 629 #endif
 630 }
 631
 632 float PM_check_specialcommand(entity this, float buttons)
 633 {
 634 #ifdef SVQC
 635         string c;
 636         if (!buttons)
 637                 c = "x";
 638         else if (buttons == 1)
 639                 c = "1";
 640         else if (buttons == 2)
 641                 c = " ";
 642         else if (buttons == 128)
 643                 c = "s";
 644         else if (buttons == 256)
 645                 c = "w";
 646         else if (buttons == 512)
 647                 c = "a";
 648         else if (buttons == 1024)
 649                 c = "d";
 650         else
 651                 c = "?";
 652
 653         if (c == substring(specialcommand, this.specialcommand_pos, 1))
 654         {
 655                 this.specialcommand_pos += 1;
 656                 if (this.specialcommand_pos >= strlen(specialcommand))
 657                 {
 658                         this.specialcommand_pos = 0;
 659                         SpecialCommand();
 660                         return true;
 661                 }
 662         }
 663         else if (this.specialcommand_pos && (c != substring(specialcommand, this.specialcommand_pos - 1, 1)))
 664                 this.specialcommand_pos = 0;
 665 #endif
 666         return false;
 667 }
 668
 669 void PM_check_nickspam(entity this)
 670 {
 671 #ifdef SVQC
 672         if (time >= this.nickspamtime)
 673                 return;
 674         if (this.nickspamcount >= autocvar_g_nick_flood_penalty_yellow)
 675         {
 676                 // slight annoyance for nick change scripts
 677                 this.movement = -1 * this.movement;
 678                 this.BUTTON_ATCK = this.BUTTON_JUMP = this.BUTTON_ATCK2 = this.BUTTON_ZOOM = this.BUTTON_CROUCH = this.BUTTON_HOOK = this.BUTTON_USE = 0;
 679
 680                 if (this.nickspamcount >= autocvar_g_nick_flood_penalty_red) // if you are persistent and the slight annoyance above does not stop you, I'll show you!
 681                 {
 682                         this.v_angle_x = random() * 360;
 683                         this.v_angle_y = random() * 360;
 684                         // at least I'm not forcing retardedview by also assigning to angles_z
 685                         this.fixangle = true;
 686                 }
 687         }
 688 #endif
 689 }
 690
 691 void PM_check_punch(entity this)
 692 {
 693 #ifdef SVQC
 694         if (this.punchangle != '0 0 0')
 695         {
 696                 float f = vlen(this.punchangle) - 10 * PHYS_INPUT_TIMELENGTH;
 697                 if (f > 0)
 698                         this.punchangle = normalize(this.punchangle) * f;
 699                 else
 700                         this.punchangle = '0 0 0';
 701         }
 702
 703         if (this.punchvector != '0 0 0')
 704         {
 705                 float f = vlen(this.punchvector) - 30 * PHYS_INPUT_TIMELENGTH;
 706                 if (f > 0)
 707                         this.punchvector = normalize(this.punchvector) * f;
 708                 else
 709                         this.punchvector = '0 0 0';
 710         }
 711 #endif
 712 }
 713
 714 // predict frozen movement, as frozen players CAN move in some cases
 715 void PM_check_frozen(entity this)
 716 {
 717         if (!PHYS_FROZEN(this))
 718                 return;
 719         if (PHYS_DODGING_FROZEN
 720 #ifdef SVQC
 721         && IS_REAL_CLIENT(this)
 722 #endif
 723         )
 724         {
 725                 this.movement_x = bound(-5, this.movement.x, 5);
 726                 this.movement_y = bound(-5, this.movement.y, 5);
 727                 this.movement_z = bound(-5, this.movement.z, 5);
 728         }
 729         else
 730                 this.movement = '0 0 0';
 731
 732         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 733         if (pointcontents(midpoint) == CONTENT_WATER)
 734         {
 735                 this.velocity = this.velocity * 0.5;
 736
 737                 if (pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 738                         this.velocity_z = 200;
 739         }
 740 }
 741
 742 void PM_check_hitground(entity this)
 743 {
 744 #ifdef SVQC
 745         if (!IS_PLAYER(this)) return; // no fall sounds for observers thank you very much
 746         if (!IS_ONGROUND(this)) return;
 747         if (!this.wasFlying) return;
 748     this.wasFlying = false;
 749     if (this.waterlevel >= WATERLEVEL_SWIMMING) return;
 750     if (time < this.ladder_time) return;
 751     if (this.hook) return;
 752     this.nextstep = time + 0.3 + random() * 0.1;
 753     trace_dphitq3surfaceflags = 0;
 754     tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 755     if ((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)) return;
 756     entity fall = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS) ? GS_FALL_METAL : GS_FALL;
 757     WITH(entity, self, this, GlobalSound(fall, CH_PLAYER, VOICETYPE_PLAYERSOUND));
 758 #endif
 759 }
 760
 761 void PM_check_blocked(entity this)
 762 {
 763 #ifdef SVQC
 764         if (!this.player_blocked)
 765                 return;
 766         this.movement = '0 0 0';
 767         this.disableclientprediction = 1;
 768 #endif
 769 }
 770
 771 void PM_fly(entity this, float maxspd_mod)
 772 {
 773         // noclipping or flying
 774         UNSET_ONGROUND(this);
 775
 776         this.velocity = this.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this));
 777         makevectors(this.v_angle);
 778         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 779         vector wishvel = v_forward * this.movement.x
 780                                         + v_right * this.movement.y
 781                                         + '0 0 1' * this.movement.z;
 782         // acceleration
 783         vector wishdir = normalize(wishvel);
 784         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod);
 785         if(time >= PHYS_TELEPORT_TIME(this))
 786                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this) * maxspd_mod, 1, 0, 0, 0);
 787         PM_ClientMovement_Move(this);
 788 }
 789
 790 void PM_swim(entity this, float maxspd_mod)
 791 {
 792         // swimming
 793         UNSET_ONGROUND(this);
 794
 795         float jump = PHYS_INPUT_BUTTON_JUMP(this);
 796         // water jump only in certain situations
 797         // this mimics quakeworld code
 798         if (jump && this.waterlevel == WATERLEVEL_SWIMMING && this.velocity_z >= -180)
 799         {
 800                 vector yawangles = '0 1 0' * this.v_angle.y;
 801                 makevectors(yawangles);
 802                 vector forward = v_forward;
 803                 vector spot = this.origin + 24 * forward;
 804                 spot_z += 8;
 805                 traceline(spot, spot, MOVE_NOMONSTERS, this);
 806                 if (trace_startsolid)
 807                 {
 808                         spot_z += 24;
 809                         traceline(spot, spot, MOVE_NOMONSTERS, this);
 810                         if (!trace_startsolid)
 811                         {
 812                                 this.velocity = forward * 50;
 813                                 this.velocity_z = 310;
 814                                 PHYS_TELEPORT_TIME(this) = 2;
 815                                 UNSET_ONGROUND(this);
 816                                 SET_JUMP_HELD(this);
 817                         }
 818                 }
 819         }
 820         makevectors(this.v_angle);
 821         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 822         vector wishvel = v_forward * this.movement.x
 823                                         + v_right * this.movement.y
 824                                         + '0 0 1' * this.movement.z;
 825         if (wishvel == '0 0 0')
 826                 wishvel = '0 0 -60'; // drift towards bottom
 827
 828         vector wishdir = normalize(wishvel);
 829         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod) * 0.7;
 830
 831         if (IS_DUCKED(this))
 832         wishspeed *= 0.5;
 833
 834 //      if (pmove_waterjumptime <= 0) // TODO: use
 835     {
 836                 // water friction
 837                 float f = 1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this);
 838                 f = min(max(0, f), 1);
 839                 this.velocity *= f;
 840
 841                 f = wishspeed - this.velocity * wishdir;
 842                 if (f > 0)
 843                 {
 844                         float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, f);
 845                         this.velocity += accelspeed * wishdir;
 846                 }
 847
 848                 // holding jump button swims upward slowly
 849                 if (jump)
 850                 {
 851 #if 0
 852                         if (this.watertype & CONTENT_LAVA)
 853                                 this.velocity_z =  50;
 854                         else if (this.watertype & CONTENT_SLIME)
 855                                 this.velocity_z =  80;
 856                         else
 857                         {
 858                                 if (IS_NEXUIZ_DERIVED(gamemode))
 859 #endif
 860                                         this.velocity_z = 200;
 861 #if 0
 862                                 else
 863                                         this.velocity_z = 100;
 864                         }
 865 #endif
 866                 }
 867         }
 868         // water acceleration
 869         PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this) * maxspd_mod, 1, 0, 0, 0);
 870         PM_ClientMovement_Move(this);
 871 }
 872
 873 void PM_ladder(entity this, float maxspd_mod)
 874 {
 875         // on a spawnfunc_func_ladder or swimming in spawnfunc_func_water
 876         UNSET_ONGROUND(this);
 877
 878         float g;
 879         g = PHYS_GRAVITY(this) * PHYS_INPUT_TIMELENGTH;
 880         if (PHYS_ENTGRAVITY(this))
 881                 g *= PHYS_ENTGRAVITY(this);
 882         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 883         {
 884                 g *= 0.5;
 885                 this.velocity_z += g;
 886         }
 887
 888         this.velocity = this.velocity * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this));
 889         makevectors(this.v_angle);
 890         //wishvel = v_forward * this.movement.x + v_right * this.movement.y + v_up * this.movement.z;
 891         vector wishvel = v_forward * this.movement_x
 892                                         + v_right * this.movement_y
 893                                         + '0 0 1' * this.movement_z;
 894         this.velocity_z += g;
 895         if (this.ladder_entity.classname == "func_water")
 896         {
 897                 float f = vlen(wishvel);
 898                 if (f > this.ladder_entity.speed)
 899                         wishvel *= (this.ladder_entity.speed / f);
 900
 901                 this.watertype = this.ladder_entity.skin;
 902                 f = this.ladder_entity.origin_z + this.ladder_entity.maxs_z;
 903                 if ((this.origin_z + this.view_ofs_z) < f)
 904                         this.waterlevel = WATERLEVEL_SUBMERGED;
 905                 else if ((this.origin_z + (this.mins_z + this.maxs_z) * 0.5) < f)
 906                         this.waterlevel = WATERLEVEL_SWIMMING;
 907                 else if ((this.origin_z + this.mins_z + 1) < f)
 908                         this.waterlevel = WATERLEVEL_WETFEET;
 909                 else
 910                 {
 911                         this.waterlevel = WATERLEVEL_NONE;
 912                         this.watertype = CONTENT_EMPTY;
 913                 }
 914         }
 915         // acceleration
 916         vector wishdir = normalize(wishvel);
 917         float wishspeed = min(vlen(wishvel), PHYS_MAXSPEED(this) * maxspd_mod);
 918         if(time >= PHYS_TELEPORT_TIME(this))
 919                 // water acceleration
 920                 PM_Accelerate(this, wishdir, wishspeed, wishspeed, PHYS_ACCELERATE(this)*maxspd_mod, 1, 0, 0, 0);
 921         PM_ClientMovement_Move(this);
 922 }
 923
 924 void PM_jetpack(entity this, float maxspd_mod)
 925 {
 926         //makevectors(this.v_angle.y * '0 1 0');
 927         makevectors(this.v_angle);
 928         vector wishvel = v_forward * this.movement_x
 929                                         + v_right * this.movement_y;
 930         // add remaining speed as Z component
 931         float maxairspd = PHYS_MAXAIRSPEED(this) * max(1, maxspd_mod);
 932         // fix speedhacks :P
 933         wishvel = normalize(wishvel) * min(1, vlen(wishvel) / maxairspd);
 934         // add the unused velocity as up component
 935         wishvel_z = 0;
 936
 937         // if (this.BUTTON_JUMP)
 938                 wishvel_z = sqrt(max(0, 1 - wishvel * wishvel));
 939
 940         // it is now normalized, so...
 941         float a_side = PHYS_JETPACK_ACCEL_SIDE;
 942         float a_up = PHYS_JETPACK_ACCEL_UP;
 943         float a_add = PHYS_JETPACK_ANTIGRAVITY * PHYS_GRAVITY(this);
 944
 945         wishvel_x *= a_side;
 946         wishvel_y *= a_side;
 947         wishvel_z *= a_up;
 948         wishvel_z += a_add;
 949
 950         float best = 0;
 951         //////////////////////////////////////////////////////////////////////////////////////
 952         // finding the maximum over all vectors of above form
 953         // with wishvel having an absolute value of 1
 954         //////////////////////////////////////////////////////////////////////////////////////
 955         // we're finding the maximum over
 956         //   f(a_side, a_up, a_add, z) := a_side * (1 - z^2) + (a_add + a_up * z)^2;
 957         // for z in the range from -1 to 1
 958         //////////////////////////////////////////////////////////////////////////////////////
 959         // maximum is EITHER attained at the single extreme point:
 960         float a_diff = a_side * a_side - a_up * a_up;
 961         float f;
 962         if (a_diff != 0)
 963         {
 964                 f = a_add * a_up / a_diff; // this is the zero of diff(f(a_side, a_up, a_add, z), z)
 965                 if (f > -1 && f < 1) // can it be attained?
 966                 {
 967                         best = (a_diff + a_add * a_add) * (a_diff + a_up * a_up) / a_diff;
 968                         //print("middle\n");
 969                 }
 970         }
 971         // OR attained at z = 1:
 972         f = (a_up + a_add) * (a_up + a_add);
 973         if (f > best)
 974         {
 975                 best = f;
 976                 //print("top\n");
 977         }
 978         // OR attained at z = -1:
 979         f = (a_up - a_add) * (a_up - a_add);
 980         if (f > best)
 981         {
 982                 best = f;
 983                 //print("bottom\n");
 984         }
 985         best = sqrt(best);
 986         //////////////////////////////////////////////////////////////////////////////////////
 987
 988         //print("best possible acceleration: ", ftos(best), "\n");
 989
 990         float fxy, fz;
 991         fxy = bound(0, 1 - (this.velocity * normalize(wishvel_x * '1 0 0' + wishvel_y * '0 1 0')) / PHYS_JETPACK_MAXSPEED_SIDE, 1);
 992         if (wishvel_z - PHYS_GRAVITY(this) > 0)
 993                 fz = bound(0, 1 - this.velocity_z / PHYS_JETPACK_MAXSPEED_UP, 1);
 994         else
 995                 fz = bound(0, 1 + this.velocity_z / PHYS_JETPACK_MAXSPEED_UP, 1);
 996
 997         float fvel;
 998         fvel = vlen(wishvel);
 999         wishvel_x *= fxy;
1000         wishvel_y *= fxy;
1001         wishvel_z = (wishvel_z - PHYS_GRAVITY(this)) * fz + PHYS_GRAVITY(this);
1002
1003         fvel = min(1, vlen(wishvel) / best);
1004         if (PHYS_JETPACK_FUEL && !(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
1005                 f = min(1, PHYS_AMMO_FUEL(this) / (PHYS_JETPACK_FUEL * PHYS_INPUT_TIMELENGTH * fvel));
1006         else
1007                 f = 1;
1008
1009         //print("this acceleration: ", ftos(vlen(wishvel) * f), "\n");
1010
1011         if (f > 0 && wishvel != '0 0 0')
1012         {
1013                 this.velocity = this.velocity + wishvel * f * PHYS_INPUT_TIMELENGTH;
1014                 UNSET_ONGROUND(this);
1015
1016 #ifdef SVQC
1017                 if (!(ITEMS_STAT(this) & IT_UNLIMITED_WEAPON_AMMO))
1018                         this.ammo_fuel -= PHYS_JETPACK_FUEL * PHYS_INPUT_TIMELENGTH * fvel * f;
1019
1020                 ITEMS_STAT(this) |= IT_USING_JETPACK;
1021
1022                 // jetpack also inhibits health regeneration, but only for 1 second
1023                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
1024 #endif
1025         }
1026
1027 #ifdef CSQC
1028         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1029         if(autocvar_cl_movement != 3)
1030         {
1031                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1032                         this.velocity_z -= g * 0.5;
1033                 else
1034                         this.velocity_z -= g;
1035         }
1036         PM_ClientMovement_Move(this);
1037         if(autocvar_cl_movement != 3)
1038         {
1039                 if (!IS_ONGROUND(this) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1040                         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1041                                 this.velocity_z -= g * 0.5;
1042         }
1043 #endif
1044 }
1045
1046 void PM_walk(entity this, float maxspd_mod)
1047 {
1048         if (!WAS_ONGROUND(this))
1049         {
1050 #ifdef SVQC
1051                 if (autocvar_speedmeter)
1052                         LOG_TRACE(strcat("landing velocity: ", vtos(this.velocity), " (abs: ", ftos(vlen(this.velocity)), ")\n"));
1053 #endif
1054                 if (this.lastground < time - 0.3)
1055                         this.velocity *= (1 - PHYS_FRICTION_ONLAND);
1056 #ifdef SVQC
1057                 if (this.jumppadcount > 1)
1058                         LOG_TRACE(strcat(ftos(this.jumppadcount), "x jumppad combo\n"));
1059                 this.jumppadcount = 0;
1060 #endif
1061         }
1062
1063         // walking
1064         makevectors(this.v_angle.y * '0 1 0');
1065         const vector wishvel = v_forward * this.movement.x
1066                                                 + v_right * this.movement.y;
1067         // acceleration
1068         const vector wishdir = normalize(wishvel);
1069         float wishspeed = vlen(wishvel);
1070         wishspeed = min(wishspeed, PHYS_MAXSPEED(this) * maxspd_mod);
1071         if (IS_DUCKED(this)) wishspeed *= 0.5;
1072
1073         // apply edge friction
1074         const float f2 = vlen2(vec2(this.velocity));
1075         if (f2 > 0)
1076         {
1077                 trace_dphitq3surfaceflags = 0;
1078                 tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
1079                 // TODO: apply edge friction
1080                 // apply ground friction
1081                 const int realfriction = (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
1082                         ? PHYS_FRICTION_SLICK
1083                         : PHYS_FRICTION(this);
1084
1085                 float f = sqrt(f2);
1086                 f = 1 - PHYS_INPUT_TIMELENGTH * realfriction * ((f < PHYS_STOPSPEED(this)) ? (PHYS_STOPSPEED(this) / f) : 1);
1087                 f = max(0, f);
1088                 this.velocity *= f;
1089                 /*
1090                    Mathematical analysis time!
1091
1092                    Our goal is to invert this mess.
1093
1094                    For the two cases we get:
1095                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * (PHYS_STOPSPEED(this) / v0) * PHYS_FRICTION(this))
1096                           = v0 - PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
1097                         v0 = v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this)
1098                    and
1099                         v = v0 * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1100                         v0 = v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1101
1102                    These cases would be chosen ONLY if:
1103                         v0 < PHYS_STOPSPEED(this)
1104                         v + PHYS_INPUT_TIMELENGTH * PHYS_STOPSPEED(this) * PHYS_FRICTION(this) < PHYS_STOPSPEED(this)
1105                         v < PHYS_STOPSPEED(this) * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1106                    and, respectively:
1107                         v0 >= PHYS_STOPSPEED(this)
1108                         v / (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this)) >= PHYS_STOPSPEED(this)
1109                         v >= PHYS_STOPSPEED(this) * (1 - PHYS_INPUT_TIMELENGTH * PHYS_FRICTION(this))
1110                  */
1111         }
1112         const float addspeed = wishspeed - this.velocity * wishdir;
1113         if (addspeed > 0)
1114         {
1115                 const float accelspeed = min(PHYS_ACCELERATE(this) * PHYS_INPUT_TIMELENGTH * wishspeed, addspeed);
1116                 this.velocity += accelspeed * wishdir;
1117         }
1118 #ifdef CSQC
1119         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1120         if(autocvar_cl_movement != 3)
1121         {
1122                 if (!(GAMEPLAYFIX_NOGRAVITYONGROUND))
1123                         this.velocity_z -= g * (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1);
1124         }
1125         if (vdist(this.velocity, >, 0))
1126                 PM_ClientMovement_Move(this);
1127         if(autocvar_cl_movement != 3)
1128         {
1129                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1130                         if (!IS_ONGROUND(this) || !GAMEPLAYFIX_NOGRAVITYONGROUND)
1131                                 this.velocity_z -= g * 0.5;
1132         }
1133 #endif
1134 }
1135
1136 void PM_air(entity this, float buttons_prev, float maxspd_mod)
1137 {
1138         makevectors(this.v_angle.y * '0 1 0');
1139         vector wishvel = v_forward * this.movement.x
1140                                         + v_right * this.movement.y;
1141         // acceleration
1142         vector wishdir = normalize(wishvel);
1143         float wishspeed = vlen(wishvel);
1144
1145         if(PHYS_TELEPORT_TIME(this) < time)
1146         {
1147                 float maxairspd = PHYS_MAXAIRSPEED(this) * min(maxspd_mod, 1);
1148
1149                 // apply air speed limit
1150                 float airaccelqw = PHYS_AIRACCEL_QW(this);
1151                 float wishspeed0 = wishspeed;
1152                 wishspeed = min(wishspeed, maxairspd);
1153                 if (IS_DUCKED(this))
1154                         wishspeed *= 0.5;
1155                 float airaccel = PHYS_AIRACCELERATE(this) * min(maxspd_mod, 1);
1156
1157                 float accelerating = (this.velocity * wishdir > 0);
1158                 float wishspeed2 = wishspeed;
1159
1160                 // CPM: air control
1161                 if (PHYS_AIRSTOPACCELERATE(this))
1162                 {
1163                         vector curdir = normalize(vec2(this.velocity));
1164                         airaccel += (PHYS_AIRSTOPACCELERATE(this)*maxspd_mod - airaccel) * max(0, -(curdir * wishdir));
1165                 }
1166                 // note that for straight forward jumping:
1167                 // step = accel * PHYS_INPUT_TIMELENGTH * wishspeed0;
1168                 // accel  = bound(0, wishspeed - vel_xy_current, step) * accelqw + step * (1 - accelqw);
1169                 // -->
1170                 // dv/dt = accel * maxspeed (when slow)
1171                 // dv/dt = accel * maxspeed * (1 - accelqw) (when fast)
1172                 // log dv/dt = logaccel + logmaxspeed (when slow)
1173                 // log dv/dt = logaccel + logmaxspeed + log(1 - accelqw) (when fast)
1174                 float strafity = IsMoveInDirection(this.movement, -90) + IsMoveInDirection(this.movement, +90); // if one is nonzero, other is always zero
1175                 if (PHYS_MAXAIRSTRAFESPEED(this))
1176                         wishspeed = min(wishspeed, GeomLerp(PHYS_MAXAIRSPEED(this)*maxspd_mod, strafity, PHYS_MAXAIRSTRAFESPEED(this)*maxspd_mod));
1177                 if (PHYS_AIRSTRAFEACCELERATE(this))
1178                         airaccel = GeomLerp(airaccel, strafity, PHYS_AIRSTRAFEACCELERATE(this)*maxspd_mod);
1179                 if (PHYS_AIRSTRAFEACCEL_QW(this))
1180                         airaccelqw =
1181                 (((strafity > 0.5 ? PHYS_AIRSTRAFEACCEL_QW(this) : PHYS_AIRACCEL_QW(this)) >= 0) ? +1 : -1)
1182                 *
1183                 (1 - GeomLerp(1 - fabs(PHYS_AIRACCEL_QW(this)), strafity, 1 - fabs(PHYS_AIRSTRAFEACCEL_QW(this))));
1184                 // !CPM
1185
1186                 if (PHYS_WARSOWBUNNY_TURNACCEL(this) && accelerating && this.movement.y == 0 && this.movement.x != 0)
1187                         PM_AirAccelerate(this, wishdir, wishspeed2);
1188                 else
1189                         PM_Accelerate(this, wishdir, wishspeed, wishspeed0, airaccel, airaccelqw, PHYS_AIRACCEL_QW_STRETCHFACTOR(this), PHYS_AIRACCEL_SIDEWAYS_FRICTION(this) / maxairspd, PHYS_AIRSPEEDLIMIT_NONQW(this));
1190
1191                 if (PHYS_AIRCONTROL(this))
1192                         CPM_PM_Aircontrol(this, wishdir, wishspeed2);
1193         }
1194 #ifdef CSQC
1195         float g = PHYS_GRAVITY(this) * PHYS_ENTGRAVITY(this) * PHYS_INPUT_TIMELENGTH;
1196         if(autocvar_cl_movement != 3)
1197         if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1198                 this.velocity_z -= g * 0.5;
1199         else
1200                 this.velocity_z -= g;
1201 #endif
1202         PM_ClientMovement_Move(this);
1203 #ifdef CSQC
1204         if(autocvar_cl_movement != 3)
1205         if (!IS_ONGROUND(this) || !(GAMEPLAYFIX_NOGRAVITYONGROUND))
1206                 if (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
1207                         this.velocity_z -= g * 0.5;
1208 #endif
1209 }
1210
1211 // used for calculating airshots
1212 bool IsFlying(entity this)
1213 {
1214         if(IS_ONGROUND(this))
1215                 return false;
1216         if(this.waterlevel >= WATERLEVEL_SWIMMING)
1217                 return false;
1218         traceline(this.origin, this.origin - '0 0 48', MOVE_NORMAL, this);
1219         if(trace_fraction < 1)
1220                 return false;
1221         return true;
1222 }
1223
1224 void PM_Main(entity this)
1225 {
1226         int buttons = PHYS_INPUT_BUTTON_MASK(this);
1227 #ifdef CSQC
1228         this.items = getstati(STAT_ITEMS, 0, 24);
1229
1230         this.movement = PHYS_INPUT_MOVEVALUES(this);
1231
1232         vector oldv_angle = this.v_angle;
1233         vector oldangles = this.angles; // we need to save these, as they're abused by other code
1234         this.v_angle = PHYS_INPUT_ANGLES(this);
1235         this.angles = PHYS_WORLD_ANGLES(this);
1236
1237         this.team = myteam + 1; // is this correct?
1238         if (!(PHYS_INPUT_BUTTON_JUMP(this))) // !jump
1239                 UNSET_JUMP_HELD(this); // canjump = true
1240         PHYS_TELEPORT_TIME(this) -= PHYS_INPUT_TIMELENGTH;
1241
1242         PM_ClientMovement_UpdateStatus(this, true);
1243 #endif
1244
1245
1246 #ifdef SVQC
1247         WarpZone_PlayerPhysics_FixVAngle();
1248 #endif
1249         float maxspeed_mod = 1;
1250         maxspeed_mod *= PHYS_HIGHSPEED;
1251
1252 #ifdef SVQC
1253         Physics_UpdateStats(this, maxspeed_mod);
1254
1255         if (this.PlayerPhysplug)
1256                 if (this.PlayerPhysplug())
1257                         return;
1258 #endif
1259
1260 #ifdef SVQC
1261         anticheat_physics(this);
1262 #endif
1263
1264         if (PM_check_specialcommand(this, buttons))
1265                 return;
1266 #ifdef SVQC
1267         if (sv_maxidle > 0)
1268         {
1269                 if (buttons != this.buttons_old || this.movement != this.movement_old || this.v_angle != this.v_angle_old)
1270                         this.parm_idlesince = time;
1271         }
1272 #endif
1273         int buttons_prev = this.buttons_old;
1274         this.buttons_old = buttons;
1275         this.movement_old = this.movement;
1276         this.v_angle_old = this.v_angle;
1277
1278         PM_check_nickspam(this);
1279
1280         PM_check_punch(this);
1281 #ifdef SVQC
1282         if (IS_BOT_CLIENT(this))
1283         {
1284                 if (playerdemo_read(this))
1285                         return;
1286                 WITH(entity, self, this, bot_think());
1287         }
1288 #endif
1289
1290 #ifdef SVQC
1291         if (IS_PLAYER(this))
1292         {
1293                 const bool allowed_to_move = (time >= game_starttime);
1294                 if (!allowed_to_move)
1295                 {
1296                         this.velocity = '0 0 0';
1297                         this.movetype = MOVETYPE_NONE;
1298                         this.disableclientprediction = 2;
1299                 }
1300                 else if (this.disableclientprediction == 2)
1301                 {
1302                         if (this.movetype == MOVETYPE_NONE)
1303                                 this.movetype = MOVETYPE_WALK;
1304                         this.disableclientprediction = 0;
1305                 }
1306         }
1307 #endif
1308
1309 #ifdef SVQC
1310         if (this.movetype == MOVETYPE_NONE)
1311                 return;
1312
1313         // when we get here, disableclientprediction cannot be 2
1314         this.disableclientprediction = 0;
1315 #endif
1316
1317         viewloc_PlayerPhysics(this);
1318
1319         PM_check_frozen(this);
1320
1321         PM_check_blocked(this);
1322
1323         maxspeed_mod = 1;
1324
1325         if (this.in_swamp)
1326                 maxspeed_mod *= this.swamp_slowdown; //cvar("g_balance_swamp_moverate");
1327
1328         // conveyors: first fix velocity
1329         if (this.conveyor.state)
1330                 this.velocity -= this.conveyor.movedir;
1331
1332         MUTATOR_CALLHOOK(PlayerPhysics, this);
1333
1334 #ifdef SVQC
1335         if (!IS_PLAYER(this))
1336         {
1337                 maxspeed_mod = autocvar_sv_spectator_speed_multiplier;
1338                 if (!this.spectatorspeed)
1339                         this.spectatorspeed = maxspeed_mod;
1340                 if (this.impulse && this.impulse <= 19 || (this.impulse >= 200 && this.impulse <= 209) || (this.impulse >= 220 && this.impulse <= 229))
1341                 {
1342                         if (this.lastclassname != "player")
1343                         {
1344                                 if (this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209))
1345                                         this.spectatorspeed = bound(1, this.spectatorspeed + 0.5, 5);
1346                                 else if (this.impulse == 11)
1347                                         this.spectatorspeed = maxspeed_mod;
1348                                 else if (this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229))
1349                                         this.spectatorspeed = bound(1, this.spectatorspeed - 0.5, 5);
1350                                 else if (this.impulse >= 1 && this.impulse <= 9)
1351                                         this.spectatorspeed = 1 + 0.5 * (this.impulse - 1);
1352                         } // otherwise just clear
1353                         this.impulse = 0;
1354                 }
1355                 maxspeed_mod = this.spectatorspeed;
1356         }
1357
1358         float spd = max(PHYS_MAXSPEED(this), PHYS_MAXAIRSPEED(this)) * maxspeed_mod;
1359         if(this.speed != spd)
1360         {
1361                 this.speed = spd;
1362                 string temps = ftos(spd);
1363                 stuffcmd(this, strcat("cl_forwardspeed ", temps, "\n"));
1364                 stuffcmd(this, strcat("cl_backspeed ", temps, "\n"));
1365                 stuffcmd(this, strcat("cl_sidespeed ", temps, "\n"));
1366                 stuffcmd(this, strcat("cl_upspeed ", temps, "\n"));
1367         }
1368
1369         if(this.stat_jumpspeedcap_min != PHYS_JUMPSPEEDCAP_MIN)
1370         {
1371                 this.stat_jumpspeedcap_min = PHYS_JUMPSPEEDCAP_MIN;
1372                 stuffcmd(this, strcat("cl_jumpspeedcap_min ", PHYS_JUMPSPEEDCAP_MIN, "\n"));
1373         }
1374         if(this.stat_jumpspeedcap_max != PHYS_JUMPSPEEDCAP_MAX)
1375         {
1376                 this.stat_jumpspeedcap_min = PHYS_JUMPSPEEDCAP_MAX;
1377                 stuffcmd(this, strcat("cl_jumpspeedcap_max ", PHYS_JUMPSPEEDCAP_MAX, "\n"));
1378         }
1379 #endif
1380
1381         if(PHYS_DEAD(this))
1382         {
1383                 // handle water here
1384                 vector midpoint = ((this.absmin + this.absmax) * 0.5);
1385                 if(pointcontents(midpoint) == CONTENT_WATER)
1386                 {
1387                         this.velocity = this.velocity * 0.5;
1388
1389                         // do we want this?
1390                         //if(pointcontents(midpoint + '0 0 2') == CONTENT_WATER)
1391                                 //{ this.velocity_z = 70; }
1392                 }
1393                 goto end;
1394         }
1395
1396 #ifdef SVQC
1397         if (!this.fixangle)
1398                 this.angles = '0 1 0' * this.v_angle.y;
1399 #endif
1400
1401         PM_check_hitground(this);
1402
1403         if(IsFlying(this))
1404                 this.wasFlying = 1;
1405
1406         if (IS_PLAYER(this))
1407                 CheckPlayerJump(this);
1408
1409         if (this.flags & FL_WATERJUMP)
1410         {
1411                 this.velocity_x = this.movedir.x;
1412                 this.velocity_y = this.movedir.y;
1413                 if (time > PHYS_TELEPORT_TIME(this) || this.waterlevel == WATERLEVEL_NONE)
1414                 {
1415                         this.flags &= ~FL_WATERJUMP;
1416                         PHYS_TELEPORT_TIME(this) = 0;
1417                 }
1418         }
1419
1420         else if (MUTATOR_CALLHOOK(PM_Physics, this, maxspeed_mod))
1421                 { }
1422
1423 #ifdef SVQC
1424         else if (this.movetype == MOVETYPE_NOCLIP || this.movetype == MOVETYPE_FLY || this.movetype == MOVETYPE_FLY_WORLDONLY || MUTATOR_CALLHOOK(IsFlying, this))
1425 #elif defined(CSQC)
1426         else if (this.move_movetype == MOVETYPE_NOCLIP || this.move_movetype == MOVETYPE_FLY || this.move_movetype == MOVETYPE_FLY_WORLDONLY || MUTATOR_CALLHOOK(IsFlying, this))
1427 #endif
1428                 PM_fly(this, maxspeed_mod);
1429
1430         else if (this.waterlevel >= WATERLEVEL_SWIMMING)
1431                 PM_swim(this, maxspeed_mod);
1432
1433         else if (time < this.ladder_time)
1434                 PM_ladder(this, maxspeed_mod);
1435
1436         else if (ITEMS_STAT(this) & IT_USING_JETPACK)
1437                 PM_jetpack(this, maxspeed_mod);
1438
1439         else if (IS_ONGROUND(this))
1440                 PM_walk(this, maxspeed_mod);
1441
1442         else
1443                 PM_air(this, buttons_prev, maxspeed_mod);
1444
1445 :end
1446         if (IS_ONGROUND(this))
1447                 this.lastground = time;
1448
1449         // conveyors: then break velocity again
1450         if(this.conveyor.state)
1451                 this.velocity += this.conveyor.movedir;
1452
1453         this.lastflags = this.flags;
1454
1455         this.lastclassname = this.classname;
1456
1457 #ifdef CSQC
1458         this.v_angle = oldv_angle;
1459         this.angles = oldangles;
1460 #endif
1461 }
1462
1463 #if defined(SVQC)
1464 void SV_PlayerPhysics()
1465 #elif defined(CSQC)
1466 void CSQC_ClientMovement_PlayerMove_Frame(entity this)
1467 #endif
1468 {
1469 #ifdef SVQC
1470         SELFPARAM();
1471 #endif
1472         PM_Main(this);
1473 }