qcsrc/common/notifications.qh

   1 #ifndef NOTIFICATIONS_H
   2 #define NOTIFICATIONS_H
   3
   4 #include <common/command/all.qh>
   5
   6 #include "constants.qh"
   7 #include "teams.qh"
   8 #include "util.qh"
   9
  10 // ================================================
  11 //  Unified notification system, written by Samual
  12 //  Last updated: March, 2013
  13 // ================================================
  14
  15 // main types/groups of notifications
  16 const int MSG_ANNCE = 1; // "Global" AND "personal" announcer messages
  17 const int MSG_INFO = 2; // "Global" information messages
  18 const int MSG_CENTER = 3; // "Personal" centerprint messages
  19 const int MSG_MULTI = 5; // Subcall MSG_INFO and/or MSG_CENTER notifications
  20 const int MSG_CHOICE = 6; // Choose which subcall wrapper to activate
  21
  22 const int MSG_CENTER_CPID = 4; // Kill centerprint message
  23
  24 string Get_Notif_TypeName(int net_type)
  25 {
  26         switch (net_type)
  27         {
  28                 case MSG_ANNCE: return "MSG_ANNCE";
  29                 case MSG_INFO: return "MSG_INFO";
  30                 case MSG_CENTER: return "MSG_CENTER";
  31                 case MSG_CENTER_CPID: return "MSG_CENTER_CPID";
  32                 case MSG_MULTI: return "MSG_MULTI";
  33                 case MSG_CHOICE: return "MSG_CHOICE";
  34         }
  35         backtrace(sprintf("Get_Notif_TypeName(%d): Improper net type!\n", net_type));
  36         return "";
  37 }
  38
  39 typedef entity Notification;
  40
  41 // negative confirmations
  42 /** allows various things to know when no information is added */
  43 Notification NO_MSG;
  44 STATIC_INIT(NO_MSG) { NO_MSG = new(Notification); }
  45 /** @deprecated */
  46 const int NO_MSG_ = -12345;
  47 /** allows Send_Notification to safely abort sending */
  48 Notification NOTIF_ABORT;
  49 STATIC_INIT(NOTIF_ABORT) { NOTIF_ABORT = new(Notification); }
  50
  51 // used for notification system multi-team identifiers
  52 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  53 /** @deprecated use APP_TEAM_NUM */
  54 #define APP_TEAM_ENT(ent, prefix) APP_TEAM_NUM(ent.team, prefix)
  55
  56 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  57         VARITEM(1, 0, s1) \
  58         VARITEM(2, 0, XPD(s1, s2)) \
  59         VARITEM(3, 0, XPD(s1, s2, s3)) \
  60         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  61         VARITEM(0, 1, f1) \
  62         VARITEM(1, 1, XPD(s1, f1)) \
  63         VARITEM(2, 1, XPD(s1, s2, f1)) \
  64         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  65         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  66         VARITEM(0, 2, XPD(f1, f2)) \
  67         VARITEM(1, 2, XPD(s1, f1, f2)) \
  68         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  69         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  70         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
  71         VARITEM(0, 3, XPD(f1, f2, f3)) \
  72         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
  73         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
  74         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
  75         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
  76         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
  77         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
  78         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
  79         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
  80         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
  81
  82 void Destroy_All_Notifications();
  83 void Create_Notification_Entity(entity notif,
  84         float var_default,
  85         float var_cvar,
  86         float typeId,
  87         float nameid,
  88         string namestring);
  89 void Create_Notification_Entity_Annce(entity notif,
  90                                                                                 float var_cvar,
  91                                                                                 string namestring,
  92                                                                                 /* MSG_ANNCE */
  93                                                                                 float channel,
  94                                                                                 string snd,
  95                                                                                 float vol,
  96                                                                                 float position);
  97
  98 void Create_Notification_Entity_InfoCenter(entity notif,
  99                                                                                         float var_cvar,
 100                                                                                         string namestring,
 101                                                                                         int strnum,
 102                                                                                         int flnum,
 103                                                                                         /* MSG_INFO & MSG_CENTER */
 104                                                                                         string args,
 105                                                                                         string hudargs,
 106                                                                                         string icon,
 107                                                                                         float cpid,
 108                                                                                         string durcnt,
 109                                                                                         string normal,
 110                                                                                         string gentle);
 111
 112 void Create_Notification_Entity_Multi(entity notif,
 113                                                                                 float var_cvar,
 114                                                                                 string namestring,
 115                                                                                 /* MSG_MULTI */
 116                                                                                 Notification anncename,
 117                                                                                 Notification infoname,
 118                                                                                 Notification centername);
 119
 120 void Create_Notification_Entity_Choice(entity notif,
 121                                                                                 float var_cvar,
 122                                                                                 string namestring,
 123                                                                                 /* MSG_CHOICE */
 124                                                                                 float challow_def,
 125                                                                                 float challow_var,
 126                                                                                 int chtype,
 127                                                                                 Notification optiona,
 128                                                                                 Notification optionb);
 129
 130 void Dump_Notifications(int fh, bool alsoprint);
 131
 132 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
 133 {
 134         switch (request)
 135         {
 136                 case CMD_REQUEST_COMMAND:
 137                 {
 138                         #ifndef MENUQC
 139                         string filename = argv(1);
 140                         bool alsoprint = false;
 141                         if (filename == "")
 142                         {
 143                                 filename = "notifications_dump.cfg";
 144                                 alsoprint = false;
 145                         }
 146                         else if (filename == "-")
 147                         {
 148                                 filename = "notifications_dump.cfg";
 149                                 alsoprint = true;
 150                         }
 151                         int fh = fopen(filename, FILE_WRITE);
 152                         if (fh >= 0)
 153                         {
 154                                 Dump_Notifications(fh, alsoprint);
 155                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 156                                 fclose(fh);
 157                         }
 158                         else
 159                         {
 160                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!\n", filename);
 161                         }
 162                         #else
 163                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 164                         #endif
 165                         return;
 166                 }
 167                 default:
 168                 case CMD_REQUEST_USAGE:
 169                 {
 170                         LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 171                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 172                         LOG_INFO("  if supplied with '-' output to console as well as default,\n");
 173                         LOG_INFO("  if left blank, it will only write to default.\n");
 174                         return;
 175                 }
 176         }
 177 }
 178
 179 #ifdef NOTIFICATIONS_DEBUG
 180 void Debug_Notification(string input)
 181 {
 182         switch (autocvar_notification_debug)
 183         {
 184                 case 1: { LOG_TRACE(input); break; }
 185                 case 2: { LOG_INFO(input); break; }
 186         }
 187 }
 188 #endif
 189
 190 void Local_Notification(int net_type, Notification net_name, ...count);
 191 /** glue for networking, forwards to `Local_Notification` */
 192 void Local_Notification_WOVA(
 193         float net_type, Notification net_name,
 194         float stringcount, float floatcount,
 195         string s1, string s2, string s3, string s4,
 196         float f1, float f2, float f3, float f4);
 197
 198 #ifdef CSQC
 199 string prev_soundfile;
 200 float prev_soundtime;
 201 #endif
 202
 203 #ifdef SVQC
 204 ENUMCLASS(NOTIF)
 205         /** send to one client and their spectators */
 206         CASE(NOTIF, ONE)
 207         /** send ONLY to one client */
 208         CASE(NOTIF, ONE_ONLY)
 209         /** send only to X team and their spectators */
 210         CASE(NOTIF, TEAM)
 211         /** send only to X team and their spectators, except for Y person and their spectators */
 212         CASE(NOTIF, TEAM_EXCEPT)
 213         /** send to everyone */
 214         CASE(NOTIF, ALL)
 215         /** send to everyone except X person and their spectators */
 216         CASE(NOTIF, ALL_EXCEPT)
 217 ENUMCLASS_END(NOTIF)
 218
 219 #ifdef NOTIFICATIONS_DEBUG
 220 string Get_Notif_BroadcastName(float broadcast)
 221 {
 222         switch (broadcast)
 223         {
 224                 case NOTIF_ONE: return "NOTIF_ONE";
 225                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 226                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 227                 case NOTIF_ALL: return "NOTIF_ALL";
 228                 case NOTIF_TEAM: return "NOTIF_TEAM";
 229                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 230         }
 231         backtrace(sprintf("Get_Notif_BroadcastName(%d): Improper broadcast!\n", broadcast));
 232         return "";
 233 }
 234 #endif
 235
 236 void Kill_Notification(
 237         NOTIF broadcast, entity client,
 238         float net_type, float net_name);
 239 void Send_Notification(
 240         NOTIF broadcast, entity client,
 241         float net_type, Notification net_name,
 242         ...count);
 243 void Send_Notification_WOVA(
 244         NOTIF broadcast, entity client,
 245         float net_type, Notification net_name,
 246         float stringcount, float floatcount,
 247         string s1, string s2, string s3, string s4,
 248         float f1, float f2, float f3, float f4);
 249 void Send_Notification_WOCOVA(
 250         NOTIF broadcast, entity client,
 251         float net_type, Notification net_name,
 252         string s1, string s2, string s3, string s4,
 253         float f1, float f2, float f3, float f4);
 254 #endif
 255
 256 // ===========================
 257 //  Special CVAR Declarations
 258 // ===========================
 259
 260 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 261 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 262
 263 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 264
 265 float autocvar_notification_show_location = false;
 266 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 267 float autocvar_notification_show_sprees = true;
 268 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 269 float autocvar_notification_show_sprees_info_newline = true;
 270 float autocvar_notification_show_sprees_info_specialonly = true;
 271 float autocvar_notification_errors_are_fatal = true;
 272 float autocvar_notification_lifetime_runtime = 0.5;
 273 float autocvar_notification_lifetime_mapload = 10;
 274 float autocvar_notification_debug = false;
 275
 276 #ifdef SVQC
 277 .float FRAG_VERBOSE;
 278 void Notification_GetCvars();
 279 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 280 #else
 281 float autocvar_notification_item_centerprinttime = 1.5;
 282
 283 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 284 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 285 float autocvar_notification_allow_chatboxprint = 0;
 286
 287 float autocvar_notification_show_sprees_center = true;
 288 float autocvar_notification_show_sprees_center_specialonly = true;
 289 #endif
 290
 291
 292 // ============================
 293 //  Notification Argument List
 294 // ============================
 295 /*
 296  These arguments get replaced with the Local_Notification_sprintf
 297  and other such functions found in notifications.qc to supply data
 298  from networked notifications to their usage in sprintf... It
 299  allows for more dynamic data to be inferred by the local
 300  notification parser, so that the server does not have to network
 301  anything too crazy on a per-client/per-situation basis.
 302
 303  Pay attention to the CSQC/SVQC relations, some of these are redefined
 304  in slightly different ways for different programs, this is because the
 305  server does a more conservative approach to the notifs than the client.
 306
 307  All arguments are swapped into strings, so be sure that your
 308  sprintf usage matches with proper %s placement.
 309
 310  Argument descriptions:
 311         s1-s4: string arguments to be literally swapped into sprintf
 312         s2loc: s2 string of locations of deaths or other events
 313         s3loc: s3 string of locations of deaths or other events
 314         f1-f4: float arguments expanded into strings to be swapped into sprintf
 315         f1p2dec: f1 float to string with 2 decimal places
 316         f2p2dec: f2 float to string with 2 decimal places
 317         f2primsec: f2 float primary or secondary selection for weapons
 318         f3primsec: f3 float primary or secondary selection for weapons
 319         f1secs: count_seconds of f1
 320         f1points: point or points depending on f1
 321         f1ord: count_ordinal of f1
 322         f1time: process_time of f1
 323         f1race_time: mmssss of f1
 324         f2race_time: mmssss of f2
 325         race_col: color of race time/position (i.e. good or bad)
 326         race_diff: show time difference between f2 and f3
 327         missing_teams: show which teams still need players
 328         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 329         frag_ping: show the ping of a player
 330         frag_stats: show health/armor/ping of a player
 331         frag_pos: show score status and position in the match of a player
 332         spree_cen: centerprint notif for kill spree/how many kills they have
 333         spree_inf: info notif for kill spree/how many kills they have
 334         spree_end: placed at the end of murder messages to show ending of sprees
 335         spree_lost: placed at the end of suicide messages to show losing of sprees
 336         item_wepname: return full name of a weapon from weaponid
 337         item_wepammo: ammo display for weapon from string
 338         item_centime: amount of time to display weapon message in centerprint
 339         item_buffname: return full name of a buff from buffid
 340         death_team: show the full name of the team a player is switching from
 341         minigame1_name: return human readable name of a minigame from its id(s1)
 342         minigame1_d: return descriptor name of a minigame from its id(s1)
 343 */
 344
 345 const float NOTIF_MAX_ARGS = 7;
 346 const float NOTIF_MAX_HUDARGS = 2;
 347 const float NOTIF_MAX_DURCNT = 2;
 348
 349 string arg_slot[NOTIF_MAX_ARGS];
 350
 351 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 352 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 353 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 354 const float ARG_CS = 4; // unique result to CSQC
 355 const float ARG_SV = 5; // unique result to SVQC
 356 const float ARG_DC = 6; // unique result to durcnt/centerprint
 357
 358 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 359 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 360
 361 string BUFF_NAME(int i);
 362
 363 #define NOTIF_ARGUMENT_LIST \
 364         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 365         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 366         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 367         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 368         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 369         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 370         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 371         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 372         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 373         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 374         ARG_CASE(ARG_CS_SV,     "f1p2dec",       ftos_decimals(f1/100, 2)) \
 375         ARG_CASE(ARG_CS_SV,     "f2p2dec",       ftos_decimals(f2/100, 2)) \
 376         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 377         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 378         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 379         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 380         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 381         ARG_CASE(ARG_CS,        "f1time",        process_time(2, f1)) \
 382         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 383         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 384         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 385         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 386         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 387         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 388         ARG_CASE(ARG_CS,        "pass_key",      ((((tmp_s = getcommandkey("pass", "+use")) != "pass") && !(strstrofs(tmp_s, "not bound", 0) >= 0)) ? sprintf(CCR(_(" ^F1(Press %s)")), tmp_s) : "")) \
 389         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 390         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 391         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 392         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 393         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 394         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 395         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 396         ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 397         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 398         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 399         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 400         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 401         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 402         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 403         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(world,netname,s1).descriptor.message) \
 404         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(world,netname,s1).descriptor.netname)
 405
 406 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 407         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 408 } MACRO_END
 409 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 410
 411 #define KILL_SPREE_LIST \
 412         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 413         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 414         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 415         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 416         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 417         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 418         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 419
 420 #ifdef CSQC
 421 string notif_arg_frag_ping(bool newline, float fping)
 422 {
 423         string s = newline ? "\n" : " ";
 424         if (fping == NO_MSG_)
 425                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 426         else
 427                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 428 }
 429
 430 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 431 {
 432         string s = notif_arg_frag_ping(false, fping);
 433         if (fhealth > 1)
 434                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 435         else
 436                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 437 }
 438
 439 string notif_arg_missing_teams(float f1)
 440 {
 441         return sprintf("%s%s%s%s",
 442                 ((f1 & BIT(0)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_1), (f1 & (BIT(1) | BIT(2) | BIT(3)) ? ", " : "")) : ""),
 443                 ((f1 & BIT(1)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_2), (f1 & (         BIT(2) | BIT(3)) ? ", " : "")) : ""),
 444                 ((f1 & BIT(2)) ? sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_3), (f1 & (                  BIT(3)) ? ", " : "")) : ""),
 445                 ((f1 & BIT(3)) ?                 Team_ColoredFullName(NUM_TEAM_4)                                                 : "")
 446         );
 447 }
 448
 449 string notif_arg_spree_cen(float spree)
 450 {
 451         // 0 = off, 1 = target (but only for first victim) and attacker
 452         if(autocvar_notification_show_sprees_center)
 453         {
 454                 if(spree > 1)
 455                 {
 456                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 457                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 458
 459                         switch(spree)
 460                         {
 461                                 KILL_SPREE_LIST
 462                                 default:
 463                                 {
 464                                         if (!autocvar_notification_show_sprees_center_specialonly)
 465                                         {
 466                                                 return
 467                                                         sprintf(
 468                                                                 normal_or_gentle(
 469                                                                         _("%d frag spree! "),
 470                                                                         _("%d score spree! ")
 471                                                                 ),
 472                                                                 spree);
 473                                         }
 474                                         else { return ""; } // don't show spree information if it isn't an achievement
 475                                 }
 476                         }
 477
 478                         #undef SPREE_ITEM
 479                 }
 480                 else if(spree == -1) // first blood
 481                 {
 482                         return normal_or_gentle(_("First blood! "), _("First score! "));
 483                 }
 484                 else if(spree == -2) // first victim
 485                 {
 486                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 487                 }
 488         }
 489         return "";
 490 }
 491 #endif
 492
 493 string notif_arg_spree_inf(float type, string input, string player, float spree)
 494 {
 495         switch(type)
 496         {
 497                 case 1: // attacker kill spree
 498                 {
 499                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 500                         // this conditional (& 2) is true for 2 and 3
 501                         if(autocvar_notification_show_sprees_info & 2)
 502                         {
 503                                 #ifdef CSQC
 504                                 string spree_newline =
 505                                         ( autocvar_notification_show_sprees_info_newline ?
 506                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 507                                 #else
 508                                 string spree_newline =
 509                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 510                                 #endif
 511
 512                                 if(spree > 1)
 513                                 {
 514                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 515                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 516
 517                                         switch(spree)
 518                                         {
 519                                                 KILL_SPREE_LIST
 520                                                 default:
 521                                                 {
 522                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 523                                                         {
 524                                                                 return
 525                                                                         sprintf(
 526                                                                                 CCR(normal_or_gentle(
 527                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 528                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 529                                                                                 )),
 530                                                                                 player,
 531                                                                                 spree,
 532                                                                                 spree_newline
 533                                                                         );
 534                                                         }
 535                                                         else { return ""; } // don't show spree information if it isn't an achievement
 536                                                 }
 537                                         }
 538
 539                                         #undef SPREE_ITEM
 540                                 }
 541                                 else if(spree == -1) // firstblood
 542                                 {
 543                                         return
 544                                                 sprintf(
 545                                                         CCR(normal_or_gentle(
 546                                                                 _("%s^K1 drew first blood! %s^BG"),
 547                                                                 _("%s^K1 got the first score! %s^BG")
 548                                                         )),
 549                                                         player,
 550                                                         spree_newline
 551                                                 );
 552                                 }
 553                         }
 554                         break;
 555                 }
 556
 557                 case -1: // kill spree ended
 558                 {
 559                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 560                         {
 561                                 return
 562                                         sprintf(normal_or_gentle(
 563                                                 _(", ending their %d frag spree"),
 564                                                 _(", ending their %d score spree")
 565                                                 ),
 566                                                 spree
 567                                         );
 568                         }
 569                         break;
 570                 }
 571
 572                 case -2: // kill spree lost
 573                 {
 574                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 575                         {
 576                                 return
 577                                         sprintf(normal_or_gentle(
 578                                                 _(", losing their %d frag spree"),
 579                                                 _(", losing their %d score spree")
 580                                                 ),
 581                                                 spree
 582                                         );
 583                         }
 584                         break;
 585                 }
 586         }
 587         return "";
 588 }
 589
 590
 591 // ====================================
 592 //  Initialization/Create Declarations
 593 // ====================================
 594
 595 enum {
 596         NO_CPID
 597 ,   CPID_ASSAULT_ROLE
 598 ,   CPID_ROUND
 599 ,   CPID_CAMPCHECK
 600 ,   CPID_CTF_CAPSHIELD
 601 ,   CPID_CTF_LOWPRIO
 602 ,   CPID_CTF_PASS
 603 ,   CPID_STALEMATE
 604 ,   CPID_NADES
 605 ,   CPID_IDLING
 606 ,   CPID_ITEM
 607 ,   CPID_PREVENT_JOIN
 608 ,   CPID_KEEPAWAY
 609 ,   CPID_KEEPAWAY_WARN
 610 ,   CPID_KEYHUNT
 611 ,   CPID_KEYHUNT_OTHER
 612 ,   CPID_LMS
 613 ,   CPID_MISSING_TEAMS
 614 ,   CPID_MISSING_PLAYERS
 615 ,   CPID_INSTAGIB_FINDAMMO
 616 ,   CPID_MOTD
 617 ,   CPID_NIX
 618 ,   CPID_ONSLAUGHT
 619 ,   CPID_ONS_CAPSHIELD
 620 ,   CPID_OVERTIME
 621 ,   CPID_POWERUP
 622 ,   CPID_RACE_FINISHLAP
 623 ,   CPID_TEAMCHANGE
 624 ,   CPID_TIMEOUT
 625 ,   CPID_VEHICLES
 626 ,   CPID_VEHICLES_OTHER
 627 // always last
 628 ,   NOTIF_CPID_COUNT
 629 };
 630 // notification counts
 631 /** @deprecated */
 632 const int NOTIF_FIRST = 1;
 633 int NOTIF_ANNCE_COUNT;
 634 int NOTIF_INFO_COUNT;
 635 int NOTIF_CENTER_COUNT;
 636 int NOTIF_MULTI_COUNT;
 637 int NOTIF_CHOICE_COUNT;
 638
 639 // notification limits -- INCREASE AS NECESSARY
 640 const int NOTIF_ANNCE_MAX   = 400;
 641 const int NOTIF_INFO_MAX    = 450;
 642 const int NOTIF_CENTER_MAX  = 350;
 643 const int NOTIF_MULTI_MAX   = 300;
 644 const int NOTIF_CHOICE_MAX  = 50;
 645
 646 // notification entities
 647 Notification msg_annce_notifs[NOTIF_ANNCE_MAX];
 648 Notification msg_info_notifs[NOTIF_INFO_MAX];
 649 Notification msg_center_notifs[NOTIF_CENTER_MAX];
 650 Notification msg_multi_notifs[NOTIF_MULTI_MAX];
 651 Notification msg_choice_notifs[NOTIF_CHOICE_MAX];
 652
 653 Notification Get_Notif_Ent(int net_type, int net_name)
 654 {
 655         switch (net_type)
 656         {
 657                 case MSG_ANNCE: return msg_annce_notifs[net_name - 1];
 658                 case MSG_INFO: return msg_info_notifs[net_name - 1];
 659                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
 660                 case MSG_MULTI: return msg_multi_notifs[net_name - 1];
 661                 case MSG_CHOICE: return msg_choice_notifs[net_name - 1];
 662         }
 663         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
 664         return NULL;
 665 }
 666
 667 // common notification entity values
 668 .float nent_default;
 669 .float nent_enabled;
 670 .float nent_type;
 671 .float nent_id;
 672 .string nent_name;
 673 .int nent_stringcount;
 674 .int nent_floatcount;
 675
 676 // MSG_ANNCE entity values
 677 .float nent_channel;
 678 .string nent_snd;
 679 .float nent_vol;
 680 .float nent_position;
 681
 682 // MSG_INFO and MSG_CENTER entity values
 683 .string nent_args; // used by both
 684 .string nent_hudargs; // used by info
 685 .string nent_icon; // used by info
 686 .float nent_cpid; // used by center
 687 .string nent_durcnt; // used by center
 688 .string nent_string; // used by both
 689
 690 // MSG_MULTI entity values
 691 .entity nent_msgannce;
 692 .entity nent_msginfo;
 693 .entity nent_msgcenter;
 694
 695 // MSG_CHOICE entity values
 696 .float nent_challow_def;
 697 .float nent_challow_var;
 698 .entity nent_optiona;
 699 .entity nent_optionb;
 700
 701 // networked notification entity values
 702 #ifdef SVQC
 703 .NOTIF nent_broadcast;
 704 #endif
 705 .entity nent_client;
 706 .float nent_net_type;
 707 .float nent_net_name;
 708 .string nent_strings[4];
 709 .float nent_floats[4];
 710
 711 // other notification properties
 712 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 713
 714 #define ACVNN(name) autocvar_notification_##name
 715
 716 // initialization error detection
 717 bool notif_error;
 718 bool notif_global_error;
 719
 720 #define MSG_ANNCE_NOTIF(name, default, sound, channel, volume, position) \
 721         MSG_ANNCE_NOTIF_(ANNCE_##name, default, sound, channel, volume, position)
 722 #define MSG_ANNCE_NOTIF_(name, default, sound, channel, volume, position) \
 723         NOTIF_ADD_AUTOCVAR(name, default) \
 724         Notification name; \
 725         void RegisterNotification_##name() \
 726         { \
 727                 int name##_ = 0; \
 728                 SET_FIELD_COUNT(name##_, NOTIF_FIRST, NOTIF_ANNCE_COUNT) \
 729                 CHECK_MAX_COUNT(name##_, NOTIF_ANNCE_MAX, NOTIF_ANNCE_COUNT, "MSG_ANNCE") \
 730                 entity this = name = msg_annce_notifs[name##_ - 1] = new_pure(msg_annce_notification); \
 731                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_ANNCE, name##_, strtoupper(#name)); \
 732                 Create_Notification_Entity_Annce(this, ACVNN(name), strtoupper(#name), \
 733                         channel,   /* channel  */ \
 734                         sound,     /* snd      */ \
 735                         volume,    /* vol      */ \
 736                         position); /* position */ \
 737         } \
 738         ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 739
 740 #define MSG_INFO_NOTIF(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 741         MSG_INFO_NOTIF_(INFO_##name, default, strnum, flnum, args, hudargs, icon, normal, gentle)
 742 #define MSG_INFO_NOTIF_(name, default, strnum, flnum, args, hudargs, icon, normal, gentle) \
 743         NOTIF_ADD_AUTOCVAR(name, default) \
 744         Notification name; \
 745         void RegisterNotification_##name() \
 746         { \
 747                 int name##_ = 0; \
 748                 SET_FIELD_COUNT(name##_, NOTIF_FIRST, NOTIF_INFO_COUNT) \
 749                 CHECK_MAX_COUNT(name##_, NOTIF_INFO_MAX, NOTIF_INFO_COUNT, "MSG_INFO") \
 750                 entity this = name = msg_info_notifs[name##_ - 1] = new_pure(msg_info_notification); \
 751                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, name##_, strtoupper(#name)); \
 752                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 753                         args,     /* args    */ \
 754                         hudargs,  /* hudargs */ \
 755                         icon,     /* icon    */ \
 756                         NO_MSG_,  /* cpid    */ \
 757                         "",       /* durcnt  */ \
 758                         normal,   /* normal  */ \
 759                         gentle);  /* gentle  */ \
 760         } \
 761         ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 762
 763 .string nent_iconargs;
 764 #define MULTIICON_INFO(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 765         MULTIICON_INFO_(INFO_##name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 766 #define MULTIICON_INFO_(name, default, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 767         NOTIF_ADD_AUTOCVAR(name, default) \
 768         Notification name; \
 769         void RegisterNotification_##name() \
 770         { \
 771                 int name##_ = 0; \
 772                 SET_FIELD_COUNT(name##_, NOTIF_FIRST, NOTIF_INFO_COUNT) \
 773                 CHECK_MAX_COUNT(name##_, NOTIF_INFO_MAX, NOTIF_INFO_COUNT, "MSG_INFO") \
 774                 entity this = name = msg_info_notifs[name##_ - 1] = new_pure(msg_info_notification); \
 775                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_INFO, name##_, strtoupper(#name)); \
 776                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 777                         args,     /* args    */ \
 778                         hudargs,  /* hudargs */ \
 779                         icon,     /* icon    */ \
 780                         NO_MSG_,  /* cpid    */ \
 781                         "",       /* durcnt  */ \
 782                         normal,   /* normal  */ \
 783                         gentle);  /* gentle  */ \
 784                 this.nent_iconargs = iconargs; \
 785         } \
 786         ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 787
 788 #define MSG_CENTER_NOTIF(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 789         MSG_CENTER_NOTIF_(CENTER_##name, default, strnum, flnum, args, cpid, durcnt, normal, gentle)
 790 #define MSG_CENTER_NOTIF_(name, default, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 791         NOTIF_ADD_AUTOCVAR(name, default) \
 792         Notification name; \
 793         void RegisterNotification_##name() \
 794         { \
 795                 int name##_ = 0; \
 796                 SET_FIELD_COUNT(name##_, NOTIF_FIRST, NOTIF_CENTER_COUNT) \
 797                 CHECK_MAX_COUNT(name##_, NOTIF_CENTER_MAX, NOTIF_CENTER_COUNT, "MSG_CENTER") \
 798                 entity this = name = msg_center_notifs[name##_ - 1] = new_pure(msg_center_notification); \
 799                 Create_Notification_Entity           (this, default, ACVNN(name), MSG_CENTER, name##_, strtoupper(#name)); \
 800                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 801                         args,    /* args    */ \
 802                         "",      /* hudargs */ \
 803                         "",      /* icon    */ \
 804                         cpid,    /* cpid    */ \
 805                         durcnt,  /* durcnt  */ \
 806                         normal,  /* normal  */ \
 807                         gentle); /* gentle  */ \
 808         } \
 809         ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 810
 811 #define MSG_MULTI_NOTIF(name, default, anncename, infoname, centername) \
 812         NOTIF_ADD_AUTOCVAR(name, default) \
 813         Notification name; \
 814         void RegisterNotification_##name() \
 815         { \
 816                 int name##_ = 0; \
 817                 SET_FIELD_COUNT(name##_, NOTIF_FIRST, NOTIF_MULTI_COUNT) \
 818                 CHECK_MAX_COUNT(name##_, NOTIF_MULTI_MAX, NOTIF_MULTI_COUNT, "MSG_MULTI") \
 819                 entity this = name = msg_multi_notifs[name##_ - 1] = new_pure(msg_multi_notification); \
 820                 Create_Notification_Entity      (this, default, ACVNN(name), MSG_MULTI, name##_, strtoupper(#name)); \
 821                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 822                         anncename,   /* anncename  */ \
 823                         infoname,    /* infoname   */ \
 824                         centername); /* centername */ \
 825         } \
 826         ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 827
 828 #define MSG_CHOICE_NOTIF(name, default, challow, chtype, optiona, optionb) \
 829         MSG_CHOICE_NOTIF_(CHOICE_##name, default, challow, chtype, optiona, optionb)
 830 #define MSG_CHOICE_NOTIF_(name, default, challow, chtype, optiona, optionb) \
 831         NOTIF_ADD_AUTOCVAR(name, default) \
 832         NOTIF_ADD_AUTOCVAR(name##_ALLOWED, challow) \
 833         Notification name; \
 834         void RegisterNotification_##name() \
 835         { \
 836                 int name##_ = 0; \
 837                 SET_FIELD_COUNT(name##_, NOTIF_FIRST, NOTIF_CHOICE_COUNT) \
 838                 CHECK_MAX_COUNT(name##_, NOTIF_CHOICE_MAX, NOTIF_CHOICE_COUNT, "MSG_CHOICE") \
 839                 entity this = name = msg_choice_notifs[name##_ - 1] = new_pure(msg_choice_notification); \
 840                 Create_Notification_Entity       (this, default, ACVNN(name), MSG_CHOICE, name##_, strtoupper(#name)); \
 841                 Create_Notification_Entity_Choice(this, ACVNN(name), strtoupper(#name), \
 842                         challow,                                 /* challow_def */ \
 843                         autocvar_notification_##name##_ALLOWED,  /* challow_var */ \
 844                         chtype,                                  /* chtype      */ \
 845                         optiona,                                 /* optiona     */ \
 846                         optionb);                                /* optionb     */ \
 847         } \
 848         ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 849
 850 void RegisterNotifications_First()
 851 {
 852         notif_global_error = false;
 853 }
 854
 855 void RegisterNotifications_Done()
 856 {
 857         if(notif_global_error)
 858         {
 859                 // shit happened... stop the loading of the program now if this is unacceptable
 860                 if(autocvar_notification_errors_are_fatal)
 861                         LOG_FATAL("Notification initialization failed! Read above and fix the errors!\n");
 862                 else
 863                         LOG_SEVERE("Notification initialization failed! Read above and fix the errors!\n");
 864         }
 865 }
 866
 867 // NOW we actually activate the declarations
 868 ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotifications_First)
 869 #include "notifications.inc"
 870 ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotifications_Done)
 871
 872 STATIC_INIT(RegisterNotifications) { CALL_ACCUMULATED_FUNCTION(RegisterNotifications); }
 873
 874 #endif