qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8 #include <common/sounds/sound.qh>
   9 #include <common/weapons/all.qh>
  10
  11 // Operator for bold notifications
  12 #define BOLD_OPERATOR "^BOLD"
  13
  14 /** main types/groups of notifications */
  15 ENUMCLASS(MSG)
  16         /** "Global" AND "personal" announcer messages */
  17         CASE(MSG, ANNCE)
  18         /** "Global" information messages */
  19         CASE(MSG, INFO)
  20         /** "Personal" centerprint messages */
  21         CASE(MSG, CENTER)
  22         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  23         CASE(MSG, MULTI)
  24         /** Choose which subcall wrapper to activate */
  25         CASE(MSG, CHOICE)
  26         /** Kill centerprint message @deprecated */
  27         CASE(MSG, CENTER_KILL)
  28         /** Medal notification */
  29         CASE(MSG, MEDAL)
  30 ENUMCLASS_END(MSG)
  31
  32 string Get_Notif_TypeName(MSG net_type)
  33 {
  34         switch (net_type)
  35         {
  36                 case MSG_ANNCE: return "MSG_ANNCE";
  37                 case MSG_INFO: return "MSG_INFO";
  38                 case MSG_CENTER: return "MSG_CENTER";
  39                 case MSG_MULTI: return "MSG_MULTI";
  40                 case MSG_CHOICE: return "MSG_CHOICE";
  41                 case MSG_MEDAL: return "MSG_MEDAL";
  42         }
  43         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  44         return "";
  45 }
  46
  47 ENUMCLASS(CPID)
  48         CASE(CPID, ASSAULT_ROLE)
  49         CASE(CPID, ROUND)
  50         CASE(CPID, CAMPCHECK)
  51         CASE(CPID, CTF_CAPSHIELD)
  52         CASE(CPID, CTF_LOWPRIO)
  53         CASE(CPID, CTF_PASS)
  54         CASE(CPID, STALEMATE)
  55         CASE(CPID, NADES)
  56         CASE(CPID, IDLING)
  57         CASE(CPID, ITEM)
  58         CASE(CPID, PREVENT_JOIN)
  59         CASE(CPID, KEEPAWAY)
  60         CASE(CPID, KEEPAWAY_WARN)
  61         CASE(CPID, KEYHUNT)
  62         CASE(CPID, KEYHUNT_OTHER)
  63         CASE(CPID, LMS)
  64         CASE(CPID, MISSING_TEAMS)
  65         CASE(CPID, MISSING_PLAYERS)
  66         CASE(CPID, MISSING_READY)
  67         CASE(CPID, INSTAGIB_FINDAMMO)
  68         CASE(CPID, CAMPAIGN_MESSAGE)
  69         CASE(CPID, MOTD)
  70         CASE(CPID, NIX)
  71         CASE(CPID, ONSLAUGHT)
  72         CASE(CPID, ONS_CAPSHIELD)
  73         CASE(CPID, OVERTIME)
  74         CASE(CPID, POWERUP)
  75         CASE(CPID, RACE_FINISHLAP)
  76         CASE(CPID, TEAMCHANGE)
  77         CASE(CPID, TIMEOUT)
  78         CASE(CPID, TIMEIN)
  79         CASE(CPID, VEHICLES)
  80         CASE(CPID, VEHICLES_OTHER)
  81         /** always last */
  82         CASE(CPID, LAST)
  83 ENUMCLASS_END(CPID)
  84
  85 USING(Notification, entity);
  86
  87 // used for notification system multi-team identifiers
  88 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  89 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  90
  91 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  92         VARITEM(1, 0, s1) \
  93         VARITEM(2, 0, XPD(s1, s2)) \
  94         VARITEM(3, 0, XPD(s1, s2, s3)) \
  95         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  96         VARITEM(0, 1, f1) \
  97         VARITEM(1, 1, XPD(s1, f1)) \
  98         VARITEM(2, 1, XPD(s1, s2, f1)) \
  99         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
 100         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
 101         VARITEM(0, 2, XPD(f1, f2)) \
 102         VARITEM(1, 2, XPD(s1, f1, f2)) \
 103         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
 104         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
 105         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 106         VARITEM(0, 3, XPD(f1, f2, f3)) \
 107         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 108         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 109         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 110         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 111         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 112         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 113         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 114         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 115         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 116
 117 void Destroy_All_Notifications();
 118 void Create_Notification_Entity(entity notif,
 119         float var_default,
 120         float var_cvar,
 121         MSG typeId,
 122         string namestring,
 123         int teamnum);
 124 void Create_Notification_Entity_Annce(entity notif,
 125                                                                                 float var_cvar,
 126                                                                                 string namestring,
 127                                                                                 /* MSG_ANNCE */
 128                                                                                 float channel,
 129                                                                                 string snd,
 130                                                                                 float vol,
 131                                                                                 float position,
 132                                                                                 float queuetime);
 133
 134 void Create_Notification_Entity_InfoCenter(entity notif,
 135                                                                                         float var_cvar,
 136                                                                                         string namestring,
 137                                                                                         int strnum,
 138                                                                                         int flnum,
 139                                                                                         /* MSG_INFO & MSG_CENTER */
 140                                                                                         string args,
 141                                                                                         string hudargs,
 142                                                                                         string icon,
 143                                                                                         CPID cpid,
 144                                                                                         string durcnt,
 145                                                                                         string normal,
 146                                                                                         string gentle);
 147
 148 void Create_Notification_Entity_Multi(entity notif,
 149                                                                                 float var_cvar,
 150                                                                                 string namestring,
 151                                                                                 /* MSG_MULTI */
 152                                                                                 Notification anncename,
 153                                                                                 Notification infoname,
 154                                                                                 Notification centername);
 155
 156 void Create_Notification_Entity_Choice(entity notif,
 157                                                                                 float var_cvar,
 158                                                                                 string namestring,
 159                                                                                 /* MSG_CHOICE */
 160                                                                                 float challow_def,
 161                                                                                 float challow_var,
 162                                                                                 MSG chtype,
 163                                                                                 Notification optiona,
 164                                                                                 Notification optionb);
 165
 166 void Create_Notification_Entity_Medal(entity notif,
 167                                                                                 float var_cvar,
 168                                                                                 string namestring,
 169                                                                                 /* MSG_MEDAL */
 170                                                                                 string icon,
 171                                                                                 Notification anncename);
 172
 173 void Dump_Notifications(int fh, bool alsoprint);
 174
 175 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt", false)
 176 {
 177         switch (request)
 178         {
 179                 case CMD_REQUEST_COMMAND:
 180                 {
 181                         #ifdef GAMEQC
 182                         string filename = argv(1);
 183                         bool alsoprint = false;
 184                         if (filename == "")
 185                         {
 186                                 filename = "notifications_dump.cfg";
 187                                 alsoprint = false;
 188                         }
 189                         else if (filename == "-")
 190                         {
 191                                 filename = "notifications_dump.cfg";
 192                                 alsoprint = true;
 193                         }
 194                         int fh = fopen(filename, FILE_WRITE);
 195                         if (fh >= 0)
 196                         {
 197                                 Dump_Notifications(fh, alsoprint);
 198                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 199                                 fclose(fh);
 200                         }
 201                         else
 202                         {
 203                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 204                         }
 205                         #else
 206                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd."));
 207                         #endif
 208                         return;
 209                 }
 210                 default:
 211                 case CMD_REQUEST_USAGE:
 212                 {
 213                         LOG_HELP("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]");
 214                         LOG_HELP("  Where 'filename' is the file to write (default is notifications_dump.cfg),");
 215                         LOG_HELP("  if supplied with '-' output to console as well as default,");
 216                         LOG_HELP("  if left blank, it will only write to default.");
 217                         return;
 218                 }
 219         }
 220 }
 221
 222 #ifdef NOTIFICATIONS_DEBUG
 223 bool autocvar_notification_debug = false;
 224 void Debug_Notification(string input)
 225 {
 226         switch (autocvar_notification_debug)
 227         {
 228                 case 1: { LOG_TRACE(input); break; }
 229                 case 2: { LOG_INFO(input); break; }
 230         }
 231 }
 232 #endif
 233
 234 void Local_Notification(MSG net_type, Notification net_name, ...count);
 235 /** glue for networking, forwards to `Local_Notification` */
 236 void Local_Notification_WOVA(
 237         MSG net_type, Notification net_name,
 238         float stringcount, float floatcount,
 239         string s1, string s2, string s3, string s4,
 240         float f1, float f2, float f3, float f4);
 241
 242 #ifdef CSQC
 243 string prev_soundfile;
 244 float prev_soundtime;
 245 #endif
 246
 247 #ifdef SVQC
 248 IntrusiveList g_notifications;
 249 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 250 #endif
 251
 252 #ifdef SVQC
 253 ENUMCLASS(NOTIF)
 254         /** send to one client and their spectators */
 255         CASE(NOTIF, ONE)
 256         /** send ONLY to one client */
 257         CASE(NOTIF, ONE_ONLY)
 258         /** send only to X team and their spectators */
 259         CASE(NOTIF, TEAM)
 260         /** send only to X team and their spectators, except for Y person and their spectators */
 261         CASE(NOTIF, TEAM_EXCEPT)
 262         /** send to everyone */
 263         CASE(NOTIF, ALL)
 264         /** send to everyone except X person and their spectators */
 265         CASE(NOTIF, ALL_EXCEPT)
 266 ENUMCLASS_END(NOTIF)
 267
 268 string Get_Notif_BroadcastName(NOTIF broadcast)
 269 {
 270         switch (broadcast)
 271         {
 272                 case NOTIF_ONE: return "NOTIF_ONE";
 273                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 274                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 275                 case NOTIF_ALL: return "NOTIF_ALL";
 276                 case NOTIF_TEAM: return "NOTIF_TEAM";
 277                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 278         }
 279         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 280         return "";
 281 }
 282
 283 void Kill_Notification(
 284         NOTIF broadcast, entity client,
 285         MSG net_type, CPID net_name);
 286 void Send_Notification(
 287         NOTIF broadcast, entity client,
 288         MSG net_type, Notification net_name,
 289         ...count);
 290 void Send_Notification_WOVA(
 291         NOTIF broadcast, entity client,
 292         MSG net_type, Notification net_name,
 293         float stringcount, float floatcount,
 294         string s1, string s2, string s3, string s4,
 295         float f1, float f2, float f3, float f4);
 296 void Send_Notification_WOCOVA(
 297         NOTIF broadcast, entity client,
 298         MSG net_type, Notification net_name,
 299         string s1, string s2, string s3, string s4,
 300         float f1, float f2, float f3, float f4);
 301 #endif
 302
 303 // ===========================
 304 //  Special CVAR Declarations
 305 // ===========================
 306
 307 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 308 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 309
 310 #define NOTIF_ADD_AUTOCVAR(name,defaultvalue) float autocvar_notification_##name = defaultvalue;
 311
 312 float autocvar_notification_show_location = false;
 313 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 314 float autocvar_notification_show_sprees = true;
 315 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 316 float autocvar_notification_show_sprees_info_newline = true;
 317 float autocvar_notification_show_sprees_info_specialonly = true;
 318 float autocvar_notification_errors_are_fatal = true;
 319 #ifdef SVQC
 320 float autocvar_notification_lifetime_runtime = 0.5;
 321 float autocvar_notification_lifetime_mapload = 10;
 322 #endif
 323
 324 #ifdef SVQC
 325 void Notification_GetCvars(entity this);
 326 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 327 #else
 328 float autocvar_notification_item_centerprinttime = 1.5;
 329
 330 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 331 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 332 float autocvar_notification_allow_chatboxprint = 0;
 333
 334 float autocvar_notification_show_sprees_center = true;
 335 float autocvar_notification_show_sprees_center_specialonly = true;
 336 #endif
 337
 338
 339 // ============================
 340 //  Notification Argument List
 341 // ============================
 342 /*
 343  These arguments get replaced with the Local_Notification_sprintf
 344  and other such functions found in all.qc to supply data
 345  from networked notifications to their usage in sprintf... It
 346  allows for more dynamic data to be inferred by the local
 347  notification parser, so that the server does not have to network
 348  anything too crazy on a per-client/per-situation basis.
 349
 350  Pay attention to the CSQC/SVQC relations, some of these are redefined
 351  in slightly different ways for different programs, this is because the
 352  server does a more conservative approach to the notifs than the client.
 353
 354  All arguments are swapped into strings, so be sure that your
 355  sprintf usage matches with proper %s placement.
 356
 357  Argument descriptions:
 358         s1-s4: string arguments to be literally swapped into sprintf
 359         s2loc: s2 string of locations of deaths or other events
 360         s3loc: s3 string of locations of deaths or other events
 361         f1-f4: float arguments expanded into strings to be swapped into sprintf
 362         f1p2dec: f1 float to string with 2 decimal places
 363         f2p2dec: f2 float to string with 2 decimal places
 364         f2primsec: f2 float primary or secondary selection for weapons
 365         f3primsec: f3 float primary or secondary selection for weapons
 366         f1secs: count_seconds of f1
 367         f1points: point or points depending on f1
 368         f1ord: count_ordinal of f1
 369         f1time: process_time of f1
 370         f1race_time: mmssss of f1
 371         f2race_time: mmssss of f2
 372         race_col: color of race time/position (i.e. good or bad)
 373         race_diff: show time difference between f2 and f3
 374         missing_teams: show which teams still need players
 375         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 376         nade_key: find the keybind for nade throwing
 377         frag_ping: show the ping of a player
 378         frag_stats: show health/armor/ping of a player
 379         frag_pos: show score status and position in the match of a player
 380         spree_cen: centerprint notif for kill spree/how many kills they have
 381         spree_inf: info notif for kill spree/how many kills they have
 382         spree_end: placed at the end of murder messages to show ending of sprees
 383         spree_lost: placed at the end of suicide messages to show losing of sprees
 384         item_wepname: return full name of a weapon from weaponid
 385         item_wepammo: ammo display for weapon from f1 and f2
 386         item_centime: amount of time to display weapon message in centerprint
 387         item_buffname: return full name of a buff from buffid
 388         death_team: show the full name of the team a player is switching from
 389         minigame1_name: return human readable name of a minigame from its id(s1)
 390         minigame1_d: return descriptor name of a minigame from its id(s1)
 391 */
 392
 393 const float NOTIF_MAX_ARGS = 7;
 394 const float NOTIF_MAX_HUDARGS = 2;
 395 const float NOTIF_MAX_DURCNT = 2;
 396
 397 #ifdef CSQC
 398 const int NOTIF_QUEUE_MAX = 10;
 399 entity notif_queue_entity[NOTIF_QUEUE_MAX];
 400 MSG notif_queue_type[NOTIF_QUEUE_MAX];
 401 float notif_queue_time[NOTIF_QUEUE_MAX];
 402 float notif_queue_f1[NOTIF_QUEUE_MAX];
 403
 404 float notif_queue_next_time;
 405 int notif_queue_length;
 406
 407 void Local_Notification_Queue_Process();
 408 #endif
 409
 410 string arg_slot[NOTIF_MAX_ARGS];
 411
 412 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 413 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 414 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 415 const float ARG_CS = 4; // unique result to CSQC
 416 const float ARG_SV = 5; // unique result to SVQC
 417 const float ARG_DC = 6; // unique result to durcnt/centerprint
 418
 419 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 420 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 421
 422 string BUFF_NAME(int i);
 423
 424 #define NOTIF_ARGUMENT_LIST \
 425         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 426         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 427         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 428         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 429         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 430         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 431         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 432         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 433         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 434         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 435         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 436         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 437         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 438         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 439         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 440         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 441         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 442         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 443         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 444         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 445         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 446         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 447         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 448         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 449         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 450         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 451         ARG_CASE(ARG_CS,        "join_key",      getcommandkey(_("jump"), "+jump")) \
 452         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 453         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 454         ARG_CASE(ARG_CS,        "frag_pos",      notif_arg_frag_pos(f2)) \
 455         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 456         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 457         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 458         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 459         ARG_CASE(ARG_CS_SV,     "item_wepname",  REGISTRY_GET(Weapons, f1).m_name) \
 460         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 461         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 462         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (f2 > 0 ? notif_arg_item_wepammo(f1, f2) : "")) \
 463         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 464         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 465         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 466         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 467         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 468
 469 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN \
 470         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 471 MACRO_END
 472
 473 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 474
 475 #define KILL_SPREE_LIST \
 476         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 477         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 478         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 479         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 480
 481 #ifdef CSQC
 482 string notif_arg_frag_pos(int score)
 483 {
 484         entity pl;
 485         int place = 1;
 486         string str, color, tail;
 487         bool tied = false;
 488
 489         for(pl = players.sort_next; pl; pl = pl.sort_next) {
 490                 if(pl.team == NUM_SPECTATOR) continue;
 491                 if(pl.(scores(SP_SCORE)) == score) break;
 492                 ++place;
 493         }
 494
 495         entity prev = pl.sort_prev;
 496         entity next = pl.sort_next;
 497         if(prev && prev.(scores(SP_SCORE)) == score) {
 498                 tied = true;
 499                 --place; // We're tied always for the best place
 500         }
 501         if(next && next.(scores(SP_SCORE)) == score) {
 502                 tied = true;
 503         }
 504
 505         switch(place) {
 506                 case 1:
 507                         color = "^4";
 508                         break;
 509                 case 2:
 510                         color = "^1";
 511                         break;
 512                 case 3:
 513                         color = "^3";
 514                         break;
 515                 default:
 516                         color = "";
 517         }
 518
 519         switch(place % 10) {
 520                 case 1:
 521                         tail = "st";
 522                         break;
 523                 case 2:
 524                         tail = "nd";
 525                         break;
 526                 case 3:
 527                         tail = "rd";
 528                         break;
 529                 default:
 530                         tail = "th";
 531         }
 532
 533         str = strcat(color, ftos(place), tail);
 534         if(tied)
 535                 return strcat("Tied for ", str);
 536         else
 537                 return str;
 538 }
 539
 540 string notif_arg_frag_ping(bool newline, float fping)
 541 {
 542         string s = newline ? "\n" : " ";
 543         if (fping < 0)
 544                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 545         else
 546                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 547 }
 548
 549 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 550 {
 551         string s = notif_arg_frag_ping(false, fping);
 552         if (fhealth > 1)
 553                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 554         else
 555                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 556 }
 557
 558 string notif_arg_missing_teams(float f1)
 559 {
 560         return strcat(
 561                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 562                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 563                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 564                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 565         );
 566 }
 567
 568 string notif_arg_spree_cen(float spree)
 569 {
 570         // 0 = off, 1 = target (but only for first victim) and attacker
 571         if(autocvar_notification_show_sprees_center)
 572         {
 573                 if(spree > 1)
 574                 {
 575                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 576                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 577
 578                         switch(spree)
 579                         {
 580                                 KILL_SPREE_LIST
 581                                 default:
 582                                 {
 583                                         if (!autocvar_notification_show_sprees_center_specialonly)
 584                                         {
 585                                                 return
 586                                                         sprintf(
 587                                                                 normal_or_gentle(
 588                                                                         _("%d frag spree! "),
 589                                                                         _("%d score spree! ")
 590                                                                 ),
 591                                                                 spree);
 592                                         }
 593                                         else { return ""; } // don't show spree information if it isn't an achievement
 594                                 }
 595                         }
 596
 597                         #undef SPREE_ITEM
 598                 }
 599                 else if(spree == -1) // first blood
 600                 {
 601                         return normal_or_gentle(_("First blood! "), _("First score! "));
 602                 }
 603                 else if(spree == -2) // first victim
 604                 {
 605                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 606                 }
 607         }
 608         return "";
 609 }
 610 #endif
 611
 612 string notif_arg_spree_inf(float type, string input, string player, float spree)
 613 {
 614         switch(type)
 615         {
 616                 case 1: // attacker kill spree
 617                 {
 618                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 619                         // this conditional (& 2) is true for 2 and 3
 620                         if(autocvar_notification_show_sprees_info & 2)
 621                         {
 622                                 #ifdef CSQC
 623                                 string spree_newline =
 624                                         ( autocvar_notification_show_sprees_info_newline ?
 625                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 626                                 #else
 627                                 string spree_newline =
 628                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 629                                 #endif
 630
 631                                 if(spree > 1)
 632                                 {
 633                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 634                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 635
 636                                         switch(spree)
 637                                         {
 638                                                 KILL_SPREE_LIST
 639                                                 default:
 640                                                 {
 641                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 642                                                         {
 643                                                                 return
 644                                                                         sprintf(
 645                                                                                 CCR(normal_or_gentle(
 646                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 647                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 648                                                                                 )),
 649                                                                                 player,
 650                                                                                 spree,
 651                                                                                 spree_newline
 652                                                                         );
 653                                                         }
 654                                                         else { return ""; } // don't show spree information if it isn't an achievement
 655                                                 }
 656                                         }
 657
 658                                         #undef SPREE_ITEM
 659                                 }
 660                                 else if(spree == -1) // firstblood
 661                                 {
 662                                         return
 663                                                 sprintf(
 664                                                         CCR(normal_or_gentle(
 665                                                                 _("%s^K1 drew first blood! %s^BG"),
 666                                                                 _("%s^K1 got the first score! %s^BG")
 667                                                         )),
 668                                                         player,
 669                                                         spree_newline
 670                                                 );
 671                                 }
 672                         }
 673                         break;
 674                 }
 675
 676                 case -1: // kill spree ended
 677                 {
 678                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 679                         {
 680                                 return
 681                                         sprintf(normal_or_gentle(
 682                                                 _(", ending their %d frag spree"),
 683                                                 _(", ending their %d score spree")
 684                                                 ),
 685                                                 spree
 686                                         );
 687                         }
 688                         break;
 689                 }
 690
 691                 case -2: // kill spree lost
 692                 {
 693                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 694                         {
 695                                 return
 696                                         sprintf(normal_or_gentle(
 697                                                 _(", losing their %d frag spree"),
 698                                                 _(", losing their %d score spree")
 699                                                 ),
 700                                                 spree
 701                                         );
 702                         }
 703                         break;
 704                 }
 705         }
 706         return "";
 707 }
 708
 709 string notif_arg_item_wepammo(float f1, float f2)
 710 {
 711         string ammoitems = "";
 712         Weapon wep = REGISTRY_GET(Weapons, f1);
 713         switch (wep.ammo_type)
 714         {
 715                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 716                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 717                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 718                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 719                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 720                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 721                 default: return ""; // doesn't use ammo
 722         }
 723         return sprintf(_(" with %d %s"), f2, ammoitems);
 724 }
 725
 726
 727 // ====================================
 728 //  Initialization/Create Declarations
 729 // ====================================
 730
 731 // common notification entity values
 732 .int nent_default;
 733 .bool nent_enabled;
 734 .MSG nent_type;
 735 .string nent_name;
 736 .int nent_stringcount;
 737 .int nent_floatcount;
 738 .int nent_teamnum;
 739
 740 // MSG_ANNCE entity values
 741 .int nent_channel;
 742 .string nent_snd;
 743 .float nent_vol;
 744 .float nent_position;
 745 .float nent_queuetime;
 746
 747 // MSG_INFO and MSG_CENTER entity values
 748 .string nent_args; // used by both
 749 .string nent_hudargs; // used by info
 750 .string nent_icon; // used by info
 751 .CPID nent_cpid; // used by center
 752 .string nent_durcnt; // used by center
 753 .string nent_string; // used by both
 754
 755 // MSG_MULTI entity values
 756 .entity nent_msgannce;
 757 .entity nent_msginfo;
 758 .entity nent_msgcenter;
 759
 760 // MSG_CHOICE entity values
 761 .float nent_challow_def;
 762 .float nent_challow_var;
 763 .entity nent_optiona;
 764 .entity nent_optionb;
 765
 766 // networked notification entity values
 767 #ifdef SVQC
 768 .NOTIF nent_broadcast;
 769 #endif
 770 .entity nent_client;
 771 .MSG nent_net_type;
 772 .float nent_net_name;
 773 .string nent_strings[4];
 774 .float nent_floats[4];
 775
 776 #define ACVNN(name) autocvar_notification_##name
 777
 778 REGISTRY(Notifications, BITS(11))
 779 REGISTER_REGISTRY(Notifications)
 780 REGISTRY_SORT(Notifications);
 781
 782 REGISTRY_DEFINE_GET(Notifications, NULL)
 783 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 784 REGISTRY_CHECK(Notifications)
 785
 786 const int NOTIF_CHOICE_MAX = 20;
 787 // NOTE: a team choice is actually made of 4 choices (one per team) with the same nent_choice_idx
 788 // thus they are counted as 1 in nent_choice_count
 789 int nent_choice_count = 0;
 790 .int nent_choice_idx;
 791 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 792 // initialization error detection
 793 bool notif_error;
 794 bool notif_global_error;
 795
 796 STATIC_INIT_LATE(Notif_Choices)
 797 {
 798         if (nent_choice_count > NOTIF_CHOICE_MAX)
 799                 LOG_FATALF("Too many MSG_CHOICE notifications (%d), hit NOTIF_CHOICE_MAX (%d) limit",
 800                         nent_choice_count, NOTIF_CHOICE_MAX);
 801 }
 802
 803 string Get_Notif_CvarName(Notification notif)
 804 {
 805         if(!notif.nent_teamnum)
 806                 return notif.nent_name;
 807         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 808 }
 809
 810 Notification Get_Notif_Ent(MSG net_type, int net_name)
 811 {
 812         Notification it = REGISTRY_GET(Notifications, net_name);
 813         if (it.nent_type != net_type) {
 814                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 815                         Get_Notif_TypeName(net_type), net_type,
 816                         it.registered_id, net_name,
 817                         Get_Notif_TypeName(it.nent_type)
 818                 );
 819                 return NULL;
 820         }
 821         return it;
 822 }
 823
 824 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position, queuetime) \
 825         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, defaultvalue, sound, channel, volume, position, queuetime)
 826
 827 #define MSG_ANNCE_NOTIF(name, defaultvalue, sound, channel, volume, position, queuetime) \
 828         NOTIF_ADD_AUTOCVAR(ANNCE_##name, defaultvalue) \
 829         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, defaultvalue, sound, channel, volume, position, queuetime)
 830
 831 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position, queuetime) \
 832         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 833                 Create_Notification_Entity      (this, defaultvalue, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 834                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 835                         channel,    /* channel   */ \
 836                         sound,      /* snd       */ \
 837                         volume,     /* vol       */ \
 838                         position,   /* position  */ \
 839                         queuetime); /* queuetime */ \
 840         }
 841
 842 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 843         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 844
 845 #define MSG_INFO_NOTIF(name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 846         NOTIF_ADD_AUTOCVAR(INFO_##name, defaultvalue) \
 847         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 848
 849 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 850         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 851                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 852                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 853                         args,     /* args    */ \
 854                         hudargs,  /* hudargs */ \
 855                         icon,     /* icon    */ \
 856                         CPID_Null,/* cpid    */ \
 857                         "",       /* durcnt  */ \
 858                         normal,   /* normal  */ \
 859                         gentle);  /* gentle  */ \
 860         }
 861
 862 .string nent_iconargs;
 863 #define MULTIICON_INFO(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 864         MULTIICON_INFO_(INFO_##name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 865 #define MULTIICON_INFO_(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 866         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 867         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 868                 Create_Notification_Entity           (this, defaultvalue, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 869                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 870                         args,     /* args    */ \
 871                         hudargs,  /* hudargs */ \
 872                         icon,     /* icon    */ \
 873                         CPID_Null,/* cpid    */ \
 874                         "",       /* durcnt  */ \
 875                         normal,   /* normal  */ \
 876                         gentle);  /* gentle  */ \
 877                 this.nent_iconargs = iconargs; \
 878         }
 879
 880 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 881         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 882
 883 #define MSG_CENTER_NOTIF(name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 884         NOTIF_ADD_AUTOCVAR(CENTER_##name, defaultvalue) \
 885         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 886
 887 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 888         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 889                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 890                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 891                         args,    /* args    */ \
 892                         "",      /* hudargs */ \
 893                         "",      /* icon    */ \
 894                         cpid,    /* cpid    */ \
 895                         durcnt,  /* durcnt  */ \
 896                         normal,  /* normal  */ \
 897                         gentle); /* gentle  */ \
 898         }
 899
 900 #define MSG_MULTI_NOTIF(name, defaultvalue, anncename, infoname, centername) \
 901         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 902         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 903                 Create_Notification_Entity      (this, defaultvalue, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 904                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 905                         anncename,   /* anncename  */ \
 906                         infoname,    /* infoname   */ \
 907                         centername); /* centername */ \
 908         }
 909
 910 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 911         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, defaultvalue, challow, chtype, optiona, optionb)
 912
 913 #define MSG_CHOICE_NOTIF(name, defaultvalue, challow, chtype, optiona, optionb) \
 914         NOTIF_ADD_AUTOCVAR(CHOICE_##name, defaultvalue) \
 915         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 916         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, defaultvalue, challow, chtype, optiona, optionb)
 917
 918 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 919         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 920                 this.nent_choice_idx = nent_choice_count; \
 921                 if (!teamnum || teamnum == NUM_TEAM_4) \
 922                         nent_choice_count++; \
 923                 Create_Notification_Entity       (this, defaultvalue, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 924                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 925                         challow,                                 /* challow_def */ \
 926                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 927                         chtype,                                  /* chtype      */ \
 928                         optiona,                                 /* optiona     */ \
 929                         optionb);                                /* optionb     */ \
 930         }
 931
 932 #define MSG_MEDAL_NOTIF(name, defaultvalue, icon, anncename) \
 933         NOTIF_ADD_AUTOCVAR(MEDAL_##name, defaultvalue) \
 934         MSG_MEDAL_NOTIF_(0, MEDAL_##name, MEDAL_##name, defaultvalue, icon, anncename)
 935
 936 #define MSG_MEDAL_NOTIF_(teamnum, name, cvarname, defaultvalue, icon, anncename) \
 937         REGISTER(Notifications, name, m_id, new_pure(msg_medal_notification)) { \
 938                 Create_Notification_Entity      (this, defaultvalue, ACVNN(cvarname), MSG_MEDAL, strtoupper(#name), teamnum); \
 939                 Create_Notification_Entity_Medal(this, ACVNN(cvarname), strtoupper(#name), \
 940                         icon, \
 941                         anncename); \
 942         }
 943
 944 REGISTRY_BEGIN(Notifications)
 945 {
 946         notif_global_error = false;
 947 }
 948
 949 REGISTRY_END(Notifications)
 950 {
 951         if (!notif_global_error) return;
 952         // shit happened... stop the loading of the program now if this is unacceptable
 953         if (autocvar_notification_errors_are_fatal)
 954                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 955         else
 956                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 957 }
 958
 959 #ifdef CSQC
 960 .int cvar_value;
 961 void ReplicateVars(bool would_destroy)
 962 {
 963         if (!would_destroy)
 964                 FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 965                         string cvarname = strcat("notification_", Get_Notif_CvarName(it));
 966                         // NOTE: REPLICATE_SIMPLE can return;
 967                         REPLICATE_SIMPLE(it.cvar_value, cvarname);
 968                 });
 969 }
 970 #endif
 971
 972 #include "all.inc"