qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8 #include <common/sounds/sound.qh>
   9 #include <common/weapons/all.qh>
  10
  11 // Operator for bold notifications
  12 #define BOLD_OPERATOR "^BOLD"
  13
  14 /** main types/groups of notifications */
  15 ENUMCLASS(MSG)
  16         /** "Global" AND "personal" announcer messages */
  17         CASE(MSG, ANNCE)
  18         /** "Global" information messages */
  19         CASE(MSG, INFO)
  20         /** "Personal" centerprint messages */
  21         CASE(MSG, CENTER)
  22         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  23         CASE(MSG, MULTI)
  24         /** Choose which subcall wrapper to activate */
  25         CASE(MSG, CHOICE)
  26         /** Kill centerprint message @deprecated */
  27         CASE(MSG, CENTER_KILL)
  28 ENUMCLASS_END(MSG)
  29
  30 string Get_Notif_TypeName(MSG net_type)
  31 {
  32         switch (net_type)
  33         {
  34                 case MSG_ANNCE: return "MSG_ANNCE";
  35                 case MSG_INFO: return "MSG_INFO";
  36                 case MSG_CENTER: return "MSG_CENTER";
  37                 case MSG_MULTI: return "MSG_MULTI";
  38                 case MSG_CHOICE: return "MSG_CHOICE";
  39                 case MSG_CENTER_KILL: return "MSG_CENTER_KILL";
  40         }
  41         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  42         return "";
  43 }
  44
  45 ENUMCLASS(CPID)
  46         CASE(CPID, ASSAULT_ROLE)
  47         CASE(CPID, ROUND)
  48         CASE(CPID, CAMPCHECK)
  49         CASE(CPID, CTF_CAPSHIELD)
  50         CASE(CPID, CTF_LOWPRIO)
  51         CASE(CPID, CTF_PASS)
  52         CASE(CPID, STALEMATE)
  53         CASE(CPID, NADES)
  54         CASE(CPID, IDLING)
  55         CASE(CPID, ITEM)
  56         CASE(CPID, PREVENT_JOIN)
  57         CASE(CPID, KEEPAWAY)
  58         CASE(CPID, KEEPAWAY_WARN)
  59         CASE(CPID, KEYHUNT)
  60         CASE(CPID, KEYHUNT_OTHER)
  61         CASE(CPID, LMS)
  62         CASE(CPID, BR_DOWN)
  63         CASE(CPID, BR_DROP)
  64         CASE(CPID, MISSING_TEAMS)
  65         CASE(CPID, MISSING_PLAYERS)
  66         CASE(CPID, INSTAGIB_FINDAMMO)
  67         CASE(CPID, MOTD)
  68         CASE(CPID, NIX)
  69         CASE(CPID, ONSLAUGHT)
  70         CASE(CPID, ONS_CAPSHIELD)
  71         CASE(CPID, OVERTIME)
  72         CASE(CPID, POWERUP)
  73         CASE(CPID, RACE_FINISHLAP)
  74         CASE(CPID, TEAMCHANGE)
  75         CASE(CPID, TIMEOUT)
  76         CASE(CPID, TIMEIN)
  77         CASE(CPID, VEHICLES)
  78         CASE(CPID, VEHICLES_OTHER)
  79         /** always last */
  80         CASE(CPID, LAST)
  81 ENUMCLASS_END(CPID)
  82
  83 USING(Notification, entity);
  84
  85 // used for notification system multi-team identifiers
  86 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  87 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  88
  89 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  90         VARITEM(1, 0, s1) \
  91         VARITEM(2, 0, XPD(s1, s2)) \
  92         VARITEM(3, 0, XPD(s1, s2, s3)) \
  93         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  94         VARITEM(0, 1, f1) \
  95         VARITEM(1, 1, XPD(s1, f1)) \
  96         VARITEM(2, 1, XPD(s1, s2, f1)) \
  97         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  98         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  99         VARITEM(0, 2, XPD(f1, f2)) \
 100         VARITEM(1, 2, XPD(s1, f1, f2)) \
 101         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
 102         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
 103         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 104         VARITEM(0, 3, XPD(f1, f2, f3)) \
 105         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 106         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 107         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 108         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 109         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 110         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 111         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 112         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 113         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 114
 115 void Destroy_All_Notifications();
 116 void Create_Notification_Entity(entity notif,
 117         float var_default,
 118         float var_cvar,
 119         MSG typeId,
 120         string namestring,
 121         int teamnum);
 122 void Create_Notification_Entity_Annce(entity notif,
 123                                                                                 float var_cvar,
 124                                                                                 string namestring,
 125                                                                                 /* MSG_ANNCE */
 126                                                                                 float channel,
 127                                                                                 string snd,
 128                                                                                 float vol,
 129                                                                                 float position);
 130
 131 void Create_Notification_Entity_InfoCenter(entity notif,
 132                                                                                         float var_cvar,
 133                                                                                         string namestring,
 134                                                                                         int strnum,
 135                                                                                         int flnum,
 136                                                                                         /* MSG_INFO & MSG_CENTER */
 137                                                                                         string args,
 138                                                                                         string hudargs,
 139                                                                                         string icon,
 140                                                                                         CPID cpid,
 141                                                                                         string durcnt,
 142                                                                                         string normal,
 143                                                                                         string gentle);
 144
 145 void Create_Notification_Entity_Multi(entity notif,
 146                                                                                 float var_cvar,
 147                                                                                 string namestring,
 148                                                                                 /* MSG_MULTI */
 149                                                                                 Notification anncename,
 150                                                                                 Notification infoname,
 151                                                                                 Notification centername);
 152
 153 void Create_Notification_Entity_Choice(entity notif,
 154                                                                                 float var_cvar,
 155                                                                                 string namestring,
 156                                                                                 /* MSG_CHOICE */
 157                                                                                 float challow_def,
 158                                                                                 float challow_var,
 159                                                                                 MSG chtype,
 160                                                                                 Notification optiona,
 161                                                                                 Notification optionb);
 162
 163 void Dump_Notifications(int fh, bool alsoprint);
 164
 165 #define DEFAULT_FILENAME "notifications_dump.cfg"
 166 // NOTE: dumpeffectinfo, dumpnotifs, dumpturrets and dumpweapons use similar code
 167 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into " DEFAULT_FILENAME, false)
 168 {
 169         switch (request)
 170         {
 171                 case CMD_REQUEST_COMMAND:
 172                 {
 173                         #ifdef GAMEQC
 174                         string filename = argv(1);
 175                         bool alsoprint = false;
 176                         if (filename == "")
 177                         {
 178                                 filename = DEFAULT_FILENAME;
 179                                 alsoprint = false;
 180                         }
 181                         else if (filename == "-")
 182                         {
 183                                 filename = DEFAULT_FILENAME;
 184                                 alsoprint = true;
 185                         }
 186                         int fh = fopen(filename, FILE_WRITE);
 187                         if (fh >= 0)
 188                         {
 189                                 Dump_Notifications(fh, alsoprint);
 190                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 191                                 fclose(fh);
 192                         }
 193                         else
 194                         {
 195                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 196                         }
 197                         #else
 198                         LOG_INFO("Notification dump command only works with cl_cmd and sv_cmd.");
 199                         #endif
 200                         return;
 201                 }
 202                 default:
 203                 case CMD_REQUEST_USAGE:
 204                 {
 205                         LOG_HELP("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [<filename>]");
 206                         LOG_HELPF("  Where <filename> is the file to write (default is %s),", DEFAULT_FILENAME);
 207                         LOG_HELP("  if supplied with '-' output to console as well as default,");
 208                         LOG_HELP("  if left blank, it will only write to default.");
 209                         return;
 210                 }
 211         }
 212 }
 213 #undef DEFAULT_FILENAME
 214
 215 #ifdef NOTIFICATIONS_DEBUG
 216 bool autocvar_notification_debug = false;
 217 void Debug_Notification(string input)
 218 {
 219         switch (autocvar_notification_debug)
 220         {
 221                 case 1: { LOG_TRACE(input); break; }
 222                 case 2: { LOG_INFO(input); break; }
 223         }
 224 }
 225 #endif
 226
 227 void Local_Notification(MSG net_type, Notification net_name, ...count);
 228 /** glue for networking, forwards to `Local_Notification` */
 229 void Local_Notification_WOVA(
 230         MSG net_type, Notification net_name,
 231         float stringcount, float floatcount,
 232         string s1, string s2, string s3, string s4,
 233         float f1, float f2, float f3, float f4);
 234
 235 #ifdef CSQC
 236 string prev_soundfile;
 237 float prev_soundtime;
 238 #endif
 239
 240 #ifdef SVQC
 241 IntrusiveList g_notifications;
 242 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 243 #endif
 244
 245 #ifdef SVQC
 246 ENUMCLASS(NOTIF)
 247         /** send to one client and their spectators */
 248         CASE(NOTIF, ONE)
 249         /** send ONLY to one client */
 250         CASE(NOTIF, ONE_ONLY)
 251         /** send only to X team and their spectators */
 252         CASE(NOTIF, TEAM)
 253         /** send only to X team and their spectators, except for Y person and their spectators */
 254         CASE(NOTIF, TEAM_EXCEPT)
 255         /** send to everyone */
 256         CASE(NOTIF, ALL)
 257         /** send to everyone except X person and their spectators */
 258         CASE(NOTIF, ALL_EXCEPT)
 259 ENUMCLASS_END(NOTIF)
 260
 261 string Get_Notif_BroadcastName(NOTIF broadcast)
 262 {
 263         switch (broadcast)
 264         {
 265                 case NOTIF_ONE: return "NOTIF_ONE";
 266                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 267                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 268                 case NOTIF_ALL: return "NOTIF_ALL";
 269                 case NOTIF_TEAM: return "NOTIF_TEAM";
 270                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 271         }
 272         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 273         return "";
 274 }
 275
 276 void Kill_Notification(
 277         NOTIF broadcast, entity client,
 278         MSG net_type, CPID net_name);
 279 void Send_Notification(
 280         NOTIF broadcast, entity client,
 281         MSG net_type, Notification net_name,
 282         ...count);
 283 void Send_Notification_WOVA(
 284         NOTIF broadcast, entity client,
 285         MSG net_type, Notification net_name,
 286         float stringcount, float floatcount,
 287         string s1, string s2, string s3, string s4,
 288         float f1, float f2, float f3, float f4);
 289 void Send_Notification_WOCOVA(
 290         NOTIF broadcast, entity client,
 291         MSG net_type, Notification net_name,
 292         string s1, string s2, string s3, string s4,
 293         float f1, float f2, float f3, float f4);
 294 #endif
 295
 296 // ===========================
 297 //  Special CVAR Declarations
 298 // ===========================
 299
 300 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 301 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 302
 303 #define NOTIF_ADD_AUTOCVAR(name,defaultvalue) float autocvar_notification_##name = defaultvalue;
 304
 305 float autocvar_notification_show_location = false;
 306 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 307 float autocvar_notification_show_sprees = true;
 308 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 309 float autocvar_notification_show_sprees_info_newline = true;
 310 float autocvar_notification_show_sprees_info_specialonly = true;
 311 float autocvar_notification_errors_are_fatal = true;
 312 #ifdef SVQC
 313 float autocvar_notification_lifetime_runtime = 0.5;
 314 float autocvar_notification_lifetime_mapload = 10;
 315 #endif
 316
 317 #ifdef SVQC
 318 void Notification_GetCvars(entity this, entity store);
 319 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 320 #else
 321 float autocvar_notification_item_centerprinttime = 1.5;
 322
 323 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 324 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 325 float autocvar_notification_allow_chatboxprint = 0;
 326
 327 float autocvar_notification_show_sprees_center = true;
 328 float autocvar_notification_show_sprees_center_specialonly = true;
 329 #endif
 330
 331
 332 // ============================
 333 //  Notification Argument List
 334 // ============================
 335 /*
 336  These arguments get replaced with the Local_Notification_sprintf
 337  and other such functions found in all.qc to supply data
 338  from networked notifications to their usage in sprintf... It
 339  allows for more dynamic data to be inferred by the local
 340  notification parser, so that the server does not have to network
 341  anything too crazy on a per-client/per-situation basis.
 342
 343  Pay attention to the CSQC/SVQC relations, some of these are redefined
 344  in slightly different ways for different programs, this is because the
 345  server does a more conservative approach to the notifs than the client.
 346
 347  All arguments are swapped into strings, so be sure that your
 348  sprintf usage matches with proper %s placement.
 349
 350  Argument descriptions:
 351         s1-s4: string arguments to be literally swapped into sprintf
 352         s2loc: s2 string of locations of deaths or other events
 353         s3loc: s3 string of locations of deaths or other events
 354         f1-f4: float arguments expanded into strings to be swapped into sprintf
 355         f1p2dec: f1 float to string with 2 decimal places
 356         f2p2dec: f2 float to string with 2 decimal places
 357         f2primsec: f2 float primary or secondary selection for weapons
 358         f3primsec: f3 float primary or secondary selection for weapons
 359         f1secs: count_seconds of f1
 360         f1points: point or points depending on f1
 361         f1ord: count_ordinal of f1
 362         f1time: process_time of f1
 363         f1race_time: TIME_ENCODED_TOSTRING of f1
 364         f2race_time: TIME_ENCODED_TOSTRING of f2
 365         race_col: color of race time/position (i.e. good or bad)
 366         race_diff: show time difference between f2 and f3
 367         missing_teams: show which teams still need players
 368         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 369         nade_key: find the keybind for nade throwing
 370         frag_ping: show the ping of a player
 371         frag_stats: show health/armor/ping of a player
 372         frag_pos: show score status and position in the match of a player
 373         spree_cen: centerprint notif for kill spree/how many kills they have
 374         spree_inf: info notif for kill spree/how many kills they have
 375         spree_end: placed at the end of murder messages to show ending of sprees
 376         spree_lost: placed at the end of suicide messages to show losing of sprees
 377         item_wepname: return full name of a weapon from weaponid
 378         item_wepammo: ammo display for weapon from f1 and f2
 379         item_centime: amount of time to display weapon message in centerprint
 380         item_buffname: return full name of a buff from buffid
 381         death_team: show the full name of the team a player is switching from
 382         minigame1_name: return human readable name of a minigame from its id(s1)
 383         minigame1_d: return descriptor name of a minigame from its id(s1)
 384 */
 385
 386 const float NOTIF_MAX_ARGS = 7;
 387 const float NOTIF_MAX_HUDARGS = 2;
 388 const float NOTIF_MAX_DURCNT = 2;
 389
 390 string arg_slot[NOTIF_MAX_ARGS];
 391
 392 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 393 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 394 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 395 const float ARG_CS = 4; // unique result to CSQC
 396 const float ARG_SV = 5; // unique result to SVQC
 397 const float ARG_DC = 6; // unique result to durcnt/centerprint
 398
 399 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 400 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 401
 402 string BUFF_NAME(int i);
 403
 404 #define NOTIF_ARGUMENT_LIST \
 405         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 406         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 407         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 408         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 409         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 410         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 411         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 412         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 413         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 414         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 415         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 416         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 417         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 418         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 419         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 420         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 421         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 422         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 423         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   TIME_ENCODED_TOSTRING(f1, true)) \
 424         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   TIME_ENCODED_TOSTRING(f2, true)) \
 425         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   TIME_ENCODED_TOSTRING(f3, true)) \
 426         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 427         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), TIME_ENCODED_TOSTRING(f2 - f3, true)) : sprintf(CCR("^2[-%s]"), TIME_ENCODED_TOSTRING(f3 - f2, true)))) \
 428         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 429         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 430         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 431         ARG_CASE(ARG_CS,        "join_key",      getcommandkey(_("jump"), "+jump")) \
 432         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 433         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 434         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 435         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 436         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 437         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 438         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 439         ARG_CASE(ARG_CS_SV,     "item_wepname",  REGISTRY_GET(Weapons, f1).m_name) \
 440         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 441         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 442         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (f2 > 0 ? notif_arg_item_wepammo(f1, f2) : "")) \
 443         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 444         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 445         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 446         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 447         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 448
 449 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN \
 450         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 451 MACRO_END
 452
 453 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 454
 455 #define KILL_SPREE_LIST \
 456         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 457         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 458         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 459         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 460         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 461         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 462         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 463
 464 #ifdef CSQC
 465 string notif_arg_frag_ping(bool newline, float fping)
 466 {
 467         string s = newline ? "\n" : " ";
 468         if (fping < 0)
 469                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 470         else
 471                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 472 }
 473
 474 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 475 {
 476         string s = notif_arg_frag_ping(false, fping);
 477         if (fhealth > 1)
 478                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 479         else
 480                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 481 }
 482
 483 string notif_arg_missing_teams(float f1)
 484 {
 485         return strcat(
 486                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 487                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 488                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 489                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 490         );
 491 }
 492
 493 string notif_arg_spree_cen(float spree)
 494 {
 495         // 0 = off, 1 = target (but only for first victim) and attacker
 496         if(autocvar_notification_show_sprees_center)
 497         {
 498                 if(spree > 1)
 499                 {
 500                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 501                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 502
 503                         switch(spree)
 504                         {
 505                                 KILL_SPREE_LIST
 506                                 default:
 507                                 {
 508                                         if (!autocvar_notification_show_sprees_center_specialonly)
 509                                         {
 510                                                 return
 511                                                         sprintf(
 512                                                                 normal_or_gentle(
 513                                                                         _("%d frag spree! "),
 514                                                                         _("%d score spree! ")
 515                                                                 ),
 516                                                                 spree);
 517                                         }
 518                                         else { return ""; } // don't show spree information if it isn't an achievement
 519                                 }
 520                         }
 521
 522                         #undef SPREE_ITEM
 523                 }
 524                 else if(spree == -1) // first blood
 525                 {
 526                         return normal_or_gentle(_("First blood! "), _("First score! "));
 527                 }
 528                 else if(spree == -2) // first victim
 529                 {
 530                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 531                 }
 532         }
 533         return "";
 534 }
 535 #endif
 536
 537 string notif_arg_spree_inf(float type, string input, string player, float spree)
 538 {
 539         switch(type)
 540         {
 541                 case 1: // attacker kill spree
 542                 {
 543                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 544                         // this conditional (& 2) is true for 2 and 3
 545                         if(autocvar_notification_show_sprees_info & 2)
 546                         {
 547                                 #ifdef CSQC
 548                                 string spree_newline =
 549                                         ( autocvar_notification_show_sprees_info_newline ?
 550                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 551                                 #else
 552                                 string spree_newline =
 553                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 554                                 #endif
 555
 556                                 if(spree > 1)
 557                                 {
 558                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 559                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 560
 561                                         switch(spree)
 562                                         {
 563                                                 KILL_SPREE_LIST
 564                                                 default:
 565                                                 {
 566                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 567                                                         {
 568                                                                 return
 569                                                                         sprintf(
 570                                                                                 CCR(normal_or_gentle(
 571                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 572                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 573                                                                                 )),
 574                                                                                 player,
 575                                                                                 spree,
 576                                                                                 spree_newline
 577                                                                         );
 578                                                         }
 579                                                         else { return ""; } // don't show spree information if it isn't an achievement
 580                                                 }
 581                                         }
 582
 583                                         #undef SPREE_ITEM
 584                                 }
 585                                 else if(spree == -1) // firstblood
 586                                 {
 587                                         return
 588                                                 sprintf(
 589                                                         CCR(normal_or_gentle(
 590                                                                 _("%s^K1 drew first blood! %s^BG"),
 591                                                                 _("%s^K1 got the first score! %s^BG")
 592                                                         )),
 593                                                         player,
 594                                                         spree_newline
 595                                                 );
 596                                 }
 597                         }
 598                         break;
 599                 }
 600
 601                 case -1: // kill spree ended
 602                 {
 603                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 604                         {
 605                                 return
 606                                         sprintf(normal_or_gentle(
 607                                                 _(", ending their %d frag spree"),
 608                                                 _(", ending their %d score spree")
 609                                                 ),
 610                                                 spree
 611                                         );
 612                         }
 613                         break;
 614                 }
 615
 616                 case -2: // kill spree lost
 617                 {
 618                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 619                         {
 620                                 return
 621                                         sprintf(normal_or_gentle(
 622                                                 _(", losing their %d frag spree"),
 623                                                 _(", losing their %d score spree")
 624                                                 ),
 625                                                 spree
 626                                         );
 627                         }
 628                         break;
 629                 }
 630         }
 631         return "";
 632 }
 633
 634 string notif_arg_item_wepammo(float f1, float f2)
 635 {
 636         string ammoitems = "";
 637         Weapon wep = REGISTRY_GET(Weapons, f1);
 638         // TODO: registry handles
 639         switch (wep.ammo_type)
 640         {
 641                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 642                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 643                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 644                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 645                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 646                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 647                 default: return ""; // doesn't use ammo
 648         }
 649         return sprintf(_(" with %d %s"), f2, ammoitems);
 650 }
 651
 652
 653 // ====================================
 654 //  Initialization/Create Declarations
 655 // ====================================
 656
 657 // common notification entity values
 658 .int nent_default;
 659 .bool nent_enabled;
 660 .MSG nent_type;
 661 .string nent_name;
 662 .int nent_stringcount;
 663 .int nent_floatcount;
 664 .int nent_teamnum;
 665
 666 // MSG_ANNCE entity values
 667 .int nent_channel;
 668 .string nent_snd;
 669 .float nent_vol;
 670 .float nent_position;
 671
 672 // MSG_INFO and MSG_CENTER entity values
 673 .string nent_args; // used by both
 674 .string nent_hudargs; // used by info
 675 .string nent_icon; // used by info
 676 .CPID nent_cpid; // used by center
 677 .string nent_durcnt; // used by center
 678 .string nent_string; // used by both
 679
 680 // MSG_MULTI entity values
 681 .entity nent_msgannce;
 682 .entity nent_msginfo;
 683 .entity nent_msgcenter;
 684
 685 // MSG_CHOICE entity values
 686 .float nent_challow_def;
 687 .float nent_challow_var;
 688 .entity nent_optiona;
 689 .entity nent_optionb;
 690
 691 // networked notification entity values
 692 #ifdef SVQC
 693 .NOTIF nent_broadcast;
 694 #endif
 695 .entity nent_client;
 696 .MSG nent_net_type;
 697 .float nent_net_name;
 698 .string nent_strings[4];
 699 .float nent_floats[4];
 700
 701 #define ACVNN(name) autocvar_notification_##name
 702
 703 REGISTRY(Notifications, BITS(11))
 704 REGISTER_REGISTRY(Notifications)
 705 REGISTRY_SORT(Notifications);
 706
 707 REGISTRY_DEFINE_GET(Notifications, NULL)
 708 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 709 REGISTRY_CHECK(Notifications)
 710
 711 const int NOTIF_CHOICE_MAX = 20;
 712 // NOTE: a team choice is actually made of 4 choices (one per team) with the same nent_choice_idx
 713 // thus they are counted as 1 in nent_choice_count
 714 int nent_choice_count = 0;
 715 .int nent_choice_idx;
 716 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 717 // initialization error detection
 718 bool notif_error;
 719 bool notif_global_error;
 720
 721 STATIC_INIT_LATE(Notif_Choices)
 722 {
 723         if (nent_choice_count > NOTIF_CHOICE_MAX)
 724                 LOG_FATALF("Too many MSG_CHOICE notifications (%d), hit NOTIF_CHOICE_MAX (%d) limit",
 725                         nent_choice_count, NOTIF_CHOICE_MAX);
 726 }
 727
 728 string Get_Notif_CvarName(Notification notif)
 729 {
 730         if(!notif.nent_teamnum)
 731                 return notif.nent_name;
 732         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 733 }
 734
 735 Notification Get_Notif_Ent(MSG net_type, int net_name)
 736 {
 737         Notification it = REGISTRY_GET(Notifications, net_name);
 738         if (it.nent_type != net_type) {
 739                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 740                         Get_Notif_TypeName(net_type), net_type,
 741                         it.registered_id, net_name,
 742                         Get_Notif_TypeName(it.nent_type)
 743                 );
 744                 return NULL;
 745         }
 746         return it;
 747 }
 748
 749 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position) \
 750         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, defaultvalue, sound, channel, volume, position)
 751
 752 #define MSG_ANNCE_NOTIF(name, defaultvalue, sound, channel, volume, position) \
 753         NOTIF_ADD_AUTOCVAR(ANNCE_##name, defaultvalue) \
 754         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, defaultvalue, sound, channel, volume, position)
 755
 756 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position) \
 757         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 758                 Create_Notification_Entity      (this, defaultvalue, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 759                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 760                         channel,   /* channel  */ \
 761                         sound,     /* snd      */ \
 762                         volume,    /* vol      */ \
 763                         position); /* position */ \
 764         }
 765
 766 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 767         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 768
 769 #define MSG_INFO_NOTIF(name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 770         NOTIF_ADD_AUTOCVAR(INFO_##name, defaultvalue) \
 771         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 772
 773 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 774         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 775                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 776                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 777                         args,     /* args    */ \
 778                         hudargs,  /* hudargs */ \
 779                         icon,     /* icon    */ \
 780                         CPID_Null,/* cpid    */ \
 781                         "",       /* durcnt  */ \
 782                         normal,   /* normal  */ \
 783                         gentle);  /* gentle  */ \
 784         }
 785
 786 .string nent_iconargs;
 787 #define MULTIICON_INFO(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 788         MULTIICON_INFO_(INFO_##name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 789 #define MULTIICON_INFO_(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 790         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 791         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 792                 Create_Notification_Entity           (this, defaultvalue, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 793                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 794                         args,     /* args    */ \
 795                         hudargs,  /* hudargs */ \
 796                         icon,     /* icon    */ \
 797                         CPID_Null,/* cpid    */ \
 798                         "",       /* durcnt  */ \
 799                         normal,   /* normal  */ \
 800                         gentle);  /* gentle  */ \
 801                 this.nent_iconargs = iconargs; \
 802         }
 803
 804 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 805         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 806
 807 #define MSG_CENTER_NOTIF(name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 808         NOTIF_ADD_AUTOCVAR(CENTER_##name, defaultvalue) \
 809         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 810
 811 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 812         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 813                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 814                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 815                         args,    /* args    */ \
 816                         "",      /* hudargs */ \
 817                         "",      /* icon    */ \
 818                         cpid,    /* cpid    */ \
 819                         durcnt,  /* durcnt  */ \
 820                         normal,  /* normal  */ \
 821                         gentle); /* gentle  */ \
 822         }
 823
 824 #define MSG_MULTI_NOTIF(name, defaultvalue, anncename, infoname, centername) \
 825         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 826         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 827                 Create_Notification_Entity      (this, defaultvalue, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 828                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 829                         anncename,   /* anncename  */ \
 830                         infoname,    /* infoname   */ \
 831                         centername); /* centername */ \
 832         }
 833
 834 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 835         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, defaultvalue, challow, chtype, optiona, optionb)
 836
 837 #define MSG_CHOICE_NOTIF(name, defaultvalue, challow, chtype, optiona, optionb) \
 838         NOTIF_ADD_AUTOCVAR(CHOICE_##name, defaultvalue) \
 839         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 840         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, defaultvalue, challow, chtype, optiona, optionb)
 841
 842 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 843         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 844                 this.nent_choice_idx = nent_choice_count; \
 845                 if (!teamnum || teamnum == NUM_TEAM_4) \
 846                         nent_choice_count++; \
 847                 Create_Notification_Entity       (this, defaultvalue, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 848                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 849                         challow,                                 /* challow_def */ \
 850                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 851                         chtype,                                  /* chtype      */ \
 852                         optiona,                                 /* optiona     */ \
 853                         optionb);                                /* optionb     */ \
 854         }
 855
 856 REGISTRY_BEGIN(Notifications)
 857 {
 858         notif_global_error = false;
 859 }
 860
 861 REGISTRY_END(Notifications)
 862 {
 863         if (!notif_global_error) return;
 864         // shit happened... stop the loading of the program now if this is unacceptable
 865         if (autocvar_notification_errors_are_fatal)
 866                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 867         else
 868                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 869 }
 870
 871 #ifdef CSQC
 872 .int cvar_value;
 873 void ReplicateVars(bool would_destroy)
 874 {
 875         if (!would_destroy)
 876                 FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 877                         string cvarname = strcat("notification_", Get_Notif_CvarName(it));
 878                         // NOTE: REPLICATE_SIMPLE can return;
 879                         REPLICATE_SIMPLE(it.cvar_value, cvarname);
 880                 });
 881 }
 882 #endif
 883
 884 #include "all.inc"