qcsrc/common/mutators/mutator/itemstime.qc

   1 #ifdef IMPLEMENTATION
   2 REGISTER_MUTATOR(itemstime, true);
   3
   4 REGISTER_NET_TEMP(itemstime)
   5
   6 #ifdef SVQC
   7 void IT_Write(entity e, int i, float f) {
   8     if (!IS_REAL_CLIENT(e)) return;
   9     msg_entity = e;
  10     WriteHeader(MSG_ONE, itemstime);
  11     WriteByte(MSG_ONE, i);
  12     WriteFloat(MSG_ONE, f);
  13 }
  14 #endif
  15
  16 #ifdef CSQC
  17 float ItemsTime_time[Items_MAX];
  18 float ItemsTime_availableTime[Items_MAX];
  19 NET_HANDLE(itemstime, bool isNew)
  20 {
  21     int i = ReadByte();
  22     float f = ReadFloat();
  23     return = true;
  24     ItemsTime_time[i] = f;
  25 }
  26 #endif
  27
  28 #ifdef CSQC
  29 void Item_ItemsTime_Init()
  30 {
  31     FOREACH(Items, true, LAMBDA(
  32         ItemsTime_time[it.m_id] = -1;
  33     ));
  34 }
  35
  36 STATIC_INIT(ItemsTime_Init) {
  37     Item_ItemsTime_Init();
  38 }
  39
  40 int autocvar_hud_panel_itemstime = 2;
  41 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  42 float autocvar_hud_panel_itemstime_ratio = 2;
  43 int autocvar_hud_panel_itemstime_iconalign;
  44 bool autocvar_hud_panel_itemstime_progressbar = 0;
  45 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  46 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  47 float autocvar_hud_panel_itemstime_progressbar_reduced;
  48 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  49 bool autocvar_hud_panel_itemstime_hidelarge = false;
  50 int autocvar_hud_panel_itemstime_text = 1;
  51 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
  52 #else
  53 #define hud_panel_itemstime_hidelarge false
  54 #endif
  55
  56 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  57 {
  58     return (false
  59     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
  60     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
  61     );
  62 }
  63
  64 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons)
  65 {
  66     return (false
  67     || it.instanceOfPowerup
  68     || Item_ItemsTime_SpectatorOnly(it)
  69     || it == ITEM_JetpackRegen
  70     || (_weapons & WEPSET_SUPERWEAPONS)
  71     );
  72 }
  73
  74 #ifdef SVQC
  75
  76 float it_times[Items_MAX];
  77
  78 void Item_ItemsTime_Init()
  79 {
  80     FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
  81         it_times[it.m_id] = -1;
  82     ));
  83 }
  84
  85 STATIC_INIT(ItemsTime_Init) {
  86     // items time
  87     Item_ItemsTime_Init();
  88 }
  89
  90 void Item_ItemsTime_ResetTimes()
  91 {
  92     FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
  93         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  94     ));
  95 }
  96
  97 void Item_ItemsTime_ResetTimesForPlayer(entity e)
  98 {
  99     FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 100         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
 101     ));
 102 }
 103
 104 void Item_ItemsTime_SetTimesForPlayer(entity e)
 105 {
 106     FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 107         IT_Write(e, it.m_id, it_times[it.m_id]);
 108     ));
 109 }
 110
 111 void Item_ItemsTime_SetTime(entity e, float t)
 112 {
 113     if (!autocvar_sv_itemstime)
 114         return;
 115
 116     GameItem item = e.itemdef;
 117     if (item.instanceOfGameItem && !item.instanceOfWeaponPickup)
 118     {
 119         it_times[item.m_id] = t;
 120     }
 121 }
 122
 123 void Item_ItemsTime_SetTimesForAllPlayers()
 124 {
 125     FOREACH_CLIENT(IS_REAL_CLIENT(it) && (warmup_stage || !IS_PLAYER(it)), LAMBDA(Item_ItemsTime_SetTimesForPlayer(it)));
 126 }
 127
 128 float Item_ItemsTime_UpdateTime(entity e, float t)
 129 {
 130     bool isavailable = (t == 0);
 131     FOREACH_ENTITY(it.itemdef == e.itemdef || ((it.weapons & WEPSET_SUPERWEAPONS) && clienttype(it) == CLIENTTYPE_NOTACLIENT), LAMBDA(
 132         if (e == it) continue;
 133         if (it.scheduledrespawntime <= time)
 134             isavailable = true;
 135         else if (t == 0 || it.scheduledrespawntime < t)
 136             t = it.scheduledrespawntime;
 137     ));
 138     if (isavailable)
 139         t = -t; // let know the client there's another available item
 140     return t;
 141 }
 142
 143 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 144 {SELFPARAM();
 145     Item_ItemsTime_ResetTimes();
 146     // ALL the times need to be reset before .reset()ing each item
 147     // since Item_Reset schedules respawn of superweapons and powerups
 148     FOREACH_ENTITY(IS_NOT_A_CLIENT(it), LAMBDA(
 149         if (it.reset) Item_ItemsTime_SetTime(it, 0);
 150     ));
 151     Item_ItemsTime_SetTimesForAllPlayers();
 152 }
 153
 154 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 155 {SELFPARAM();
 156     Item_ItemsTime_SetTimesForPlayer(self);
 157 }
 158
 159 MUTATOR_HOOKFUNCTION(itemstime, ClientConnect, CBC_ORDER_LAST)
 160 {SELFPARAM();
 161         if(IS_PLAYER(self))
 162         {
 163                 // client became player on connection skipping putObserverInServer step
 164                 if (IS_REAL_CLIENT(self))
 165                 if (warmup_stage)
 166                         Item_ItemsTime_SetTimesForPlayer(self);
 167         }
 168 }
 169
 170 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 171 {SELFPARAM();
 172     if (warmup_stage) return;
 173     Item_ItemsTime_ResetTimesForPlayer(self);
 174 }
 175
 176 #endif
 177
 178 #ifdef CSQC
 179
 180 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, entity item, float item_time, bool item_available, float item_availableTime)
 181 {
 182     float t = 0;
 183     vector color = '0 0 0';
 184     float picalpha;
 185
 186     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 187         picalpha = 1;
 188     else if (item_available)
 189     {
 190         float BLINK_FACTOR = 0.15;
 191         float BLINK_BASE = 0.85;
 192         float BLINK_FREQ = 5;
 193         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 194     }
 195     else
 196         picalpha = 0.5;
 197     t = floor(item_time - time + 0.999);
 198     if (t < 5)
 199         color = '0.7 0 0';
 200     else if (t < 10)
 201         color = '0.7 0.7 0';
 202     else
 203         color = '1 1 1';
 204
 205     vector picpos, numpos;
 206     if (autocvar_hud_panel_itemstime_iconalign)
 207     {
 208         numpos = myPos;
 209         picpos = myPos + eX * (ar - 1) * mySize_y;
 210     }
 211     else
 212     {
 213         numpos = myPos + eX * mySize_y;
 214         picpos = myPos;
 215     }
 216
 217     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 218     {
 219         vector p_pos, p_size;
 220         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 221         {
 222             p_pos = numpos;
 223             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 224         }
 225         else
 226         {
 227             p_pos = myPos;
 228             p_size = mySize;
 229         }
 230         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 231     }
 232
 233     if(autocvar_hud_panel_itemstime_text)
 234     {
 235         if(t > 0)
 236             drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 237         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 238             drawpic_aspect_skin(numpos, "checkmark", eX * (ar - 1) * mySize_y + eY * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 239         else // legacy code, if the image is missing just center the icon
 240             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 241     }
 242     if (item_availableTime)
 243         drawpic_aspect_skin_expanding(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 244     drawpic_aspect_skin(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 245 }
 246
 247 void HUD_ItemsTime()
 248 {
 249     if (!autocvar__hud_configure)
 250     {
 251         if (!(
 252             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 253         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage))
 254             )) { return; }
 255     }
 256     else
 257     {
 258         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 259         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 260         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 261         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 262     }
 263
 264     int count = 0;
 265     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 266         FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 267             count += (ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time);
 268         ));
 269     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 270         FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 271             count += (ItemsTime_time[it.m_id] > time);
 272         ));
 273     else
 274         FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 275             count += (ItemsTime_time[it.m_id] != -1);
 276         ));
 277     if (count == 0)
 278         return;
 279
 280     HUD_Panel_UpdateCvars();
 281
 282     vector pos, mySize;
 283     pos = panel_pos;
 284     mySize = panel_size;
 285
 286     if (panel_bg_padding)
 287     {
 288         pos += '1 1 0' * panel_bg_padding;
 289         mySize -= '2 2 0' * panel_bg_padding;
 290     }
 291
 292     float rows, columns;
 293     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 294     rows = HUD_GetRowCount(count, mySize, ar);
 295     columns = ceil(count/rows);
 296
 297     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 298
 299     vector offset = '0 0 0';
 300     float newSize;
 301     if (autocvar_hud_panel_itemstime_dynamicsize)
 302     {
 303         if (autocvar__hud_configure)
 304         if (menu_enabled != 2)
 305             HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 306
 307         // reduce panel to avoid spacing items
 308         if (itemstime_size.x / itemstime_size.y < ar)
 309         {
 310             newSize = rows * itemstime_size.x / ar;
 311             pos.y += (mySize.y - newSize) / 2;
 312             mySize.y = newSize;
 313             itemstime_size.y = mySize.y / rows;
 314         }
 315         else
 316         {
 317             newSize = columns * itemstime_size.y * ar;
 318             pos.x += (mySize.x - newSize) / 2;
 319             mySize.x = newSize;
 320             itemstime_size.x = mySize.x / columns;
 321         }
 322         panel_pos = pos - '1 1 0' * panel_bg_padding;
 323         panel_size = mySize + '2 2 0' * panel_bg_padding;
 324     }
 325     else
 326     {
 327         if (itemstime_size.x/itemstime_size.y > ar)
 328         {
 329             newSize = ar * itemstime_size.y;
 330             offset.x = itemstime_size.x - newSize;
 331             pos.x += offset.x/2;
 332             itemstime_size.x = newSize;
 333         }
 334         else
 335         {
 336             newSize = 1/ar * itemstime_size.x;
 337             offset.y = itemstime_size.y - newSize;
 338             pos.y += offset.y/2;
 339             itemstime_size.y = newSize;
 340         }
 341     }
 342
 343     HUD_Panel_DrawBg(1);
 344
 345     float row = 0, column = 0;
 346     bool item_available;
 347     FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0') && ItemsTime_time[it.m_id] != -1, LAMBDA(
 348         float item_time = ItemsTime_time[it.m_id];
 349         if (item_time < -1)
 350         {
 351             item_available = true;
 352             item_time = -item_time;
 353         }
 354         else
 355             item_available = (item_time <= time);
 356
 357         if (ItemsTime_time[it.m_id] >= 0)
 358         {
 359             if (time <= ItemsTime_time[it.m_id])
 360                 ItemsTime_availableTime[it.m_id] = 0;
 361             else if (ItemsTime_availableTime[it.m_id] == 0)
 362                 ItemsTime_availableTime[it.m_id] = time;
 363         }
 364         else if (ItemsTime_availableTime[it.m_id] == 0)
 365             ItemsTime_availableTime[it.m_id] = time;
 366
 367         float f = (time - ItemsTime_availableTime[it.m_id]) * 2;
 368         f = (f > 1) ? 0 : bound(0, f, 1);
 369
 370         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 371             if (!(ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time))
 372                 continue;
 373
 374         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 375             if (!(ItemsTime_time[it.m_id] > time))
 376                 continue;
 377
 378         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, it, item_time, item_available, f);
 379         ++row;
 380         if (row >= rows)
 381         {
 382             row = 0;
 383             column = column + 1;
 384         }
 385     ));
 386 }
 387
 388 #endif
 389 #endif