qcsrc/common/mutators/mutator/itemstime.qc

   1 #ifdef IMPLEMENTATION
   2 REGISTER_MUTATOR(itemstime, true);
   3
   4 REGISTER_NET_TEMP(itemstime)
   5
   6 #ifdef SVQC
   7 void IT_Write(entity e, int i, float f) {
   8     if (!IS_REAL_CLIENT(e)) return;
   9     msg_entity = e;
  10     WriteHeader(MSG_ONE, itemstime);
  11     WriteByte(MSG_ONE, i);
  12     WriteFloat(MSG_ONE, f);
  13 }
  14 #endif
  15
  16 #ifdef CSQC
  17 // reserve one more spot for superweapons time
  18 float ItemsTime_time[Items_MAX + 1];
  19 float ItemsTime_availableTime[Items_MAX + 1];
  20 NET_HANDLE(itemstime, bool isNew)
  21 {
  22     int i = ReadByte();
  23     float f = ReadFloat();
  24     return = true;
  25     ItemsTime_time[i] = f;
  26 }
  27 #endif
  28
  29 #ifdef CSQC
  30 void Item_ItemsTime_Init()
  31 {
  32     FOREACH(Items, true, LAMBDA(
  33         ItemsTime_time[it.m_id] = -1;
  34     ));
  35     ItemsTime_time[Items_MAX] = -1;
  36 }
  37
  38 STATIC_INIT(ItemsTime_Init) {
  39     Item_ItemsTime_Init();
  40 }
  41
  42 int autocvar_hud_panel_itemstime = 2;
  43 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  44 float autocvar_hud_panel_itemstime_ratio = 2;
  45 int autocvar_hud_panel_itemstime_iconalign;
  46 bool autocvar_hud_panel_itemstime_progressbar = 0;
  47 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  48 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  49 float autocvar_hud_panel_itemstime_progressbar_reduced;
  50 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  51 bool autocvar_hud_panel_itemstime_hidelarge = false;
  52 int autocvar_hud_panel_itemstime_text = 1;
  53 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
  54 #else
  55 #define hud_panel_itemstime_hidelarge false
  56 #endif
  57
  58 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  59 {
  60     return (false
  61     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
  62     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
  63     );
  64 }
  65
  66 bool Item_ItemsTime_Allow(GameItem it)
  67 {
  68     return (false
  69     || it.instanceOfPowerup
  70     || Item_ItemsTime_SpectatorOnly(it)
  71     );
  72 }
  73
  74 #ifdef SVQC
  75
  76 // reserve one more spot for superweapons time
  77 float it_times[Items_MAX + 1];
  78
  79 void Item_ItemsTime_Init()
  80 {
  81     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  82         it_times[it.m_id] = -1;
  83     ));
  84     it_times[Items_MAX] = -1;
  85 }
  86
  87 STATIC_INIT(ItemsTime_Init) {
  88     // items time
  89     Item_ItemsTime_Init();
  90 }
  91
  92 void Item_ItemsTime_ResetTimes()
  93 {
  94     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  95         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  96     ));
  97     it_times[Items_MAX] = (it_times[Items_MAX] == -1) ? -1 : 0;
  98 }
  99
 100 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 101 {
 102     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 103         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
 104     ));
 105     IT_Write(e, Items_MAX, (it_times[Items_MAX] == -1) ? -1 : 0);
 106 }
 107
 108 void Item_ItemsTime_SetTimesForPlayer(entity e)
 109 {
 110     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 111         IT_Write(e, it.m_id, it_times[it.m_id]);
 112     ));
 113     IT_Write(e, Items_MAX, it_times[Items_MAX]);
 114 }
 115
 116 void Item_ItemsTime_SetTime(entity e, float t)
 117 {
 118     if (!autocvar_sv_itemstime)
 119         return;
 120
 121     GameItem item = e.itemdef;
 122     if (item.instanceOfGameItem)
 123     {
 124                 if (!item.instanceOfWeaponPickup)
 125                         it_times[item.m_id] = t;
 126                 else if (e.weapons & WEPSET_SUPERWEAPONS)
 127                         it_times[Items_MAX] = t;
 128     }
 129 }
 130
 131 void Item_ItemsTime_SetTimesForAllPlayers()
 132 {
 133     FOREACH_CLIENT(IS_REAL_CLIENT(it) && (warmup_stage || !IS_PLAYER(it)), LAMBDA(Item_ItemsTime_SetTimesForPlayer(it)));
 134 }
 135
 136 float Item_ItemsTime_UpdateTime(entity e, float t)
 137 {
 138     bool isavailable = (t == 0);
 139     FOREACH_ENTITY(it.itemdef == e.itemdef || ((e.weapons & WEPSET_SUPERWEAPONS) && (it.weapons & WEPSET_SUPERWEAPONS) && clienttype(it) == CLIENTTYPE_NOTACLIENT), LAMBDA(
 140         if (e == it) continue;
 141         if (it.scheduledrespawntime <= time)
 142             isavailable = true;
 143         else if (t == 0 || it.scheduledrespawntime < t)
 144             t = it.scheduledrespawntime;
 145     ));
 146     if (isavailable)
 147         t = -t; // let know the client there's another available item
 148     return t;
 149 }
 150
 151 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 152 {
 153     Item_ItemsTime_ResetTimes();
 154     // ALL the times need to be reset before .reset()ing each item
 155     // since Item_Reset schedules respawn of superweapons and powerups
 156     FOREACH_ENTITY(IS_NOT_A_CLIENT(it), LAMBDA(
 157         if (it.reset) Item_ItemsTime_SetTime(it, 0);
 158     ));
 159     Item_ItemsTime_SetTimesForAllPlayers();
 160 }
 161
 162 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 163 {SELFPARAM();
 164     Item_ItemsTime_SetTimesForPlayer(self);
 165 }
 166
 167 MUTATOR_HOOKFUNCTION(itemstime, ClientConnect, CBC_ORDER_LAST)
 168 {SELFPARAM();
 169         if(IS_PLAYER(self))
 170         {
 171                 // client became player on connection skipping putObserverInServer step
 172                 if (IS_REAL_CLIENT(self))
 173                 if (warmup_stage)
 174                         Item_ItemsTime_SetTimesForPlayer(self);
 175         }
 176 }
 177
 178 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 179 {
 180     if (warmup_stage) return;
 181     entity player = M_ARGV(0, entity);
 182
 183     Item_ItemsTime_ResetTimesForPlayer(player);
 184 }
 185
 186 #endif
 187
 188 #ifdef CSQC
 189
 190 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, string item_icon, float item_time, bool item_available, float item_availableTime)
 191 {
 192     float t = 0;
 193     vector color = '0 0 0';
 194     float picalpha;
 195
 196     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 197         picalpha = 1;
 198     else if (item_available)
 199     {
 200         float BLINK_FACTOR = 0.15;
 201         float BLINK_BASE = 0.85;
 202         float BLINK_FREQ = 5;
 203         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 204     }
 205     else
 206         picalpha = 0.5;
 207     t = floor(item_time - time + 0.999);
 208     if (t < 5)
 209         color = '0.7 0 0';
 210     else if (t < 10)
 211         color = '0.7 0.7 0';
 212     else
 213         color = '1 1 1';
 214
 215     vector picpos, numpos;
 216     if (autocvar_hud_panel_itemstime_iconalign)
 217     {
 218         numpos = myPos;
 219         picpos = myPos + eX * (ar - 1) * mySize_y;
 220     }
 221     else
 222     {
 223         numpos = myPos + eX * mySize_y;
 224         picpos = myPos;
 225     }
 226
 227     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 228     {
 229         vector p_pos, p_size;
 230         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 231         {
 232             p_pos = numpos;
 233             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 234         }
 235         else
 236         {
 237             p_pos = myPos;
 238             p_size = mySize;
 239         }
 240         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 241     }
 242
 243     if(autocvar_hud_panel_itemstime_text)
 244     {
 245         if(t > 0)
 246             drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 247         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 248             drawpic_aspect_skin(numpos, "checkmark", eX * (ar - 1) * mySize_y + eY * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 249         else // legacy code, if the image is missing just center the icon
 250             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 251     }
 252     if (item_availableTime)
 253         drawpic_aspect_skin_expanding(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 254     drawpic_aspect_skin(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 255 }
 256
 257 void HUD_ItemsTime()
 258 {
 259     if (!autocvar__hud_configure)
 260     {
 261         if (!(
 262             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 263         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage))
 264             )) { return; }
 265     }
 266     else
 267     {
 268         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 269         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 270         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 271         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 272     }
 273
 274     int count = 0;
 275     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 276     {
 277         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 278             count += (ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time);
 279         ));
 280         count += (ItemsTime_time[Items_MAX] > time || -ItemsTime_time[Items_MAX] > time);
 281     }
 282     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 283     {
 284         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 285             count += (ItemsTime_time[it.m_id] > time);
 286         ));
 287         count += (ItemsTime_time[Items_MAX] > time);
 288     }
 289     else
 290     {
 291         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 292             count += (ItemsTime_time[it.m_id] != -1);
 293         ));
 294         count += (ItemsTime_time[Items_MAX] != -1);
 295     }
 296     if (count == 0)
 297         return;
 298
 299     HUD_Panel_UpdateCvars();
 300
 301     vector pos, mySize;
 302     pos = panel_pos;
 303     mySize = panel_size;
 304
 305     if (panel_bg_padding)
 306     {
 307         pos += '1 1 0' * panel_bg_padding;
 308         mySize -= '2 2 0' * panel_bg_padding;
 309     }
 310
 311     float rows, columns;
 312     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 313     rows = HUD_GetRowCount(count, mySize, ar);
 314     columns = ceil(count/rows);
 315
 316     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 317
 318     vector offset = '0 0 0';
 319     float newSize;
 320     if (autocvar_hud_panel_itemstime_dynamicsize)
 321     {
 322         if (autocvar__hud_configure)
 323         if (menu_enabled != 2)
 324             HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 325
 326         // reduce panel to avoid spacing items
 327         if (itemstime_size.x / itemstime_size.y < ar)
 328         {
 329             newSize = rows * itemstime_size.x / ar;
 330             pos.y += (mySize.y - newSize) / 2;
 331             mySize.y = newSize;
 332             itemstime_size.y = mySize.y / rows;
 333         }
 334         else
 335         {
 336             newSize = columns * itemstime_size.y * ar;
 337             pos.x += (mySize.x - newSize) / 2;
 338             mySize.x = newSize;
 339             itemstime_size.x = mySize.x / columns;
 340         }
 341         panel_pos = pos - '1 1 0' * panel_bg_padding;
 342         panel_size = mySize + '2 2 0' * panel_bg_padding;
 343     }
 344     else
 345     {
 346         if (itemstime_size.x/itemstime_size.y > ar)
 347         {
 348             newSize = ar * itemstime_size.y;
 349             offset.x = itemstime_size.x - newSize;
 350             pos.x += offset.x/2;
 351             itemstime_size.x = newSize;
 352         }
 353         else
 354         {
 355             newSize = 1/ar * itemstime_size.x;
 356             offset.y = itemstime_size.y - newSize;
 357             pos.y += offset.y/2;
 358             itemstime_size.y = newSize;
 359         }
 360     }
 361
 362     HUD_Scale_Enable();
 363     HUD_Panel_DrawBg(1);
 364
 365     float row = 0, column = 0;
 366     bool item_available;
 367     int id = 0;
 368     string icon = "";
 369     FOREACH(Items, Item_ItemsTime_Allow(it) && ItemsTime_time[it.m_id] != -1, LAMBDA(
 370         id = it.m_id;
 371         icon = it.m_icon;
 372
 373 LABEL(iteration)
 374         float item_time = ItemsTime_time[id];
 375         if (item_time < -1)
 376         {
 377             item_available = true;
 378             item_time = -item_time;
 379         }
 380         else
 381             item_available = (item_time <= time);
 382
 383         if (ItemsTime_time[id] >= 0)
 384         {
 385             if (time <= ItemsTime_time[id])
 386                 ItemsTime_availableTime[id] = 0;
 387             else if (ItemsTime_availableTime[id] == 0)
 388                 ItemsTime_availableTime[id] = time;
 389         }
 390         else if (ItemsTime_availableTime[id] == 0)
 391             ItemsTime_availableTime[id] = time;
 392
 393         float f = (time - ItemsTime_availableTime[id]) * 2;
 394         f = (f > 1) ? 0 : bound(0, f, 1);
 395
 396         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 397             if (!(ItemsTime_time[id] > time || -ItemsTime_time[id] > time))
 398                 continue;
 399
 400         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 401             if (!(ItemsTime_time[id] > time))
 402                 continue;
 403
 404         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, icon, item_time, item_available, f);
 405         ++row;
 406         if (row >= rows)
 407         {
 408             row = 0;
 409             column = column + 1;
 410         }
 411         if(id == Items_MAX) // can happen only in the last fake iteration
 412                 break;
 413     ));
 414     // add another fake iteration for superweapons time
 415     if(id < Items_MAX && ItemsTime_time[Items_MAX] != -1)
 416     {
 417                 id = Items_MAX;
 418                 icon = "superweapons";
 419                 goto iteration;
 420     }
 421 }
 422
 423 #endif
 424 #endif