qcsrc/common/mutators/mutator/dodging/sv_dodging.qc

   1 #include "sv_dodging.qh"
   2
   3 #define PHYS_DODGING                                            g_dodging
   4 #define PHYS_DODGING_DELAY                                      autocvar_sv_dodging_delay
   5 #define PHYS_DODGING_DISTANCE_THRESHOLD         autocvar_sv_dodging_wall_distance_threshold
   6 #define PHYS_DODGING_FROZEN_NODOUBLETAP         autocvar_sv_dodging_frozen_doubletap
   7 #define PHYS_DODGING_HEIGHT_THRESHOLD           autocvar_sv_dodging_height_threshold
   8 #define PHYS_DODGING_HORIZ_SPEED                        autocvar_sv_dodging_horiz_speed
   9 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         autocvar_sv_dodging_horiz_speed_frozen
  10 #define PHYS_DODGING_RAMP_TIME                          autocvar_sv_dodging_ramp_time
  11 #define PHYS_DODGING_UP_SPEED                           autocvar_sv_dodging_up_speed
  12 #define PHYS_DODGING_WALL                                       autocvar_sv_dodging_wall_dodging
  13 #define PHYS_DODGING_AIR                                        autocvar_sv_dodging_air_dodging
  14 #define PHYS_DODGING_MAXSPEED                           autocvar_sv_dodging_maxspeed
  15
  16 // we ran out of stats slots! TODO: re-enable this when prediction is available for dodging
  17 #if 0
  18 #define PHYS_DODGING                                            STAT(DODGING, this)
  19 #define PHYS_DODGING_DELAY                                      STAT(DODGING_DELAY, this)
  20 #define PHYS_DODGING_DISTANCE_THRESHOLD         STAT(DODGING_DISTANCE_THRESHOLD, this)
  21 #define PHYS_DODGING_FROZEN_NODOUBLETAP         STAT(DODGING_FROZEN_NO_DOUBLETAP, this)
  22 #define PHYS_DODGING_HEIGHT_THRESHOLD           STAT(DODGING_HEIGHT_THRESHOLD, this)
  23 #define PHYS_DODGING_HORIZ_SPEED                        STAT(DODGING_HORIZ_SPEED, this)
  24 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         STAT(DODGING_HORIZ_SPEED_FROZEN, this)
  25 #define PHYS_DODGING_RAMP_TIME                          STAT(DODGING_RAMP_TIME, this)
  26 #define PHYS_DODGING_UP_SPEED                           STAT(DODGING_UP_SPEED, this)
  27 #define PHYS_DODGING_WALL                                       STAT(DODGING_WALL, this)
  28 #define PHYS_DODGING_AIR                                        STAT(DODGING_AIR, this)
  29 #define PHYS_DODGING_MAXSPEED                           STAT(DODGING_MAXSPEED, this)
  30 #endif
  31
  32 #ifdef CSQC
  33         #define PHYS_DODGING_FRAMETIME                          (1 / (frametime <= 0 ? 60 : frametime))
  34         #define PHYS_DODGING_TIMEOUT(s)                         STAT(DODGING_TIMEOUT)
  35         #define PHYS_DODGING_PRESSED_KEYS(s)            (s).pressedkeys
  36 #elif defined(SVQC)
  37         #define PHYS_DODGING_FRAMETIME                          sys_frametime
  38         #define PHYS_DODGING_TIMEOUT(s)                         CS(s).cvar_cl_dodging_timeout
  39         #define PHYS_DODGING_PRESSED_KEYS(s)            CS(s).pressedkeys
  40 #endif
  41
  42 #ifdef SVQC
  43
  44 bool autocvar_sv_dodging_sound;
  45
  46 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  47 .float dodging_action;
  48
  49 // the jump part of the dodge cannot be ramped
  50 .float dodging_single_action;
  51
  52 #include <common/animdecide.qh>
  53 #include <common/physics/player.qh>
  54
  55 .float cvar_cl_dodging_timeout;
  56
  57 REGISTER_MUTATOR(dodging, cvar("g_dodging"))
  58 {
  59         // this just turns on the cvar.
  60         MUTATOR_ONADD
  61         {
  62                 g_dodging = cvar("g_dodging");
  63         }
  64
  65         // this just turns off the cvar.
  66         MUTATOR_ONROLLBACK_OR_REMOVE
  67         {
  68                 g_dodging = 0;
  69         }
  70
  71         return false;
  72 }
  73
  74 #elif defined(CSQC)
  75 REGISTER_MUTATOR(dodging, true);
  76 #endif
  77
  78 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  79 .float dodging_action;
  80
  81 // the jump part of the dodge cannot be ramped
  82 .float dodging_single_action;
  83
  84
  85 // these are used to store the last key press time for each of the keys..
  86 .float last_FORWARD_KEY_time;
  87 .float last_BACKWARD_KEY_time;
  88 .float last_LEFT_KEY_time;
  89 .float last_RIGHT_KEY_time;
  90
  91 // these store the movement direction at the time of the dodge action happening.
  92 .vector dodging_direction;
  93
  94 // this indicates the last time a dodge was executed. used to check if another one is allowed
  95 // and to ramp up the dodge acceleration in the physics hook.
  96 .float last_dodging_time;
  97
  98 // This is the velocity gain to be added over the ramp time.
  99 // It will decrease from frame to frame during dodging_action = 1
 100 // until it's 0.
 101 .float dodging_velocity_gain;
 102
 103 #ifdef CSQC
 104 .int pressedkeys;
 105 #endif
 106
 107 // returns true if the player is close to a wall
 108 bool check_close_to_wall(entity this, float threshold)
 109 {
 110         if (PHYS_DODGING_WALL == 0) { return false; }
 111
 112 #define X(dir) \
 113         tracebox(this.origin, this.mins, this.maxs, this.origin + threshold * dir, true, this); \
 114         if (trace_fraction < 1 && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)) \
 115                 return true;
 116
 117         X(v_right);
 118         X(-v_right);
 119         X(v_forward);
 120         X(-v_forward);
 121 #undef X
 122
 123         return false;
 124 }
 125
 126 bool check_close_to_ground(entity this, float threshold)
 127 {
 128         return IS_ONGROUND(this) ? true : false;
 129 }
 130
 131 bool PM_dodging_checkpressedkeys(entity this)
 132 {
 133         // first check if the last dodge is far enough back in time so we can dodge again
 134         if ((time - this.last_dodging_time) < PHYS_DODGING_DELAY)
 135                 return false;
 136
 137         makevectors(this.angles);
 138
 139         bool wall_dodge = false;
 140
 141         if(!PHYS_DODGING_AIR)
 142         if(!check_close_to_ground(this, PHYS_DODGING_HEIGHT_THRESHOLD))
 143         {
 144                 wall_dodge = check_close_to_wall(this, PHYS_DODGING_DISTANCE_THRESHOLD);
 145                 if(!wall_dodge) // we're not on the ground, and wall dodging isn't allowed, end it!
 146                         return true;
 147         }
 148
 149         if(!wall_dodge && PHYS_DODGING_MAXSPEED && vdist(this.velocity, >, PHYS_DODGING_MAXSPEED))
 150                 return false;
 151
 152         bool frozen_dodging = (PHYS_FROZEN(this) && PHYS_DODGING_FROZEN(this));
 153         bool frozen_no_doubletap = (frozen_dodging && !PHYS_DODGING_FROZEN_NODOUBLETAP);
 154
 155         float tap_direction_x = 0;
 156         float tap_direction_y = 0;
 157         bool dodge_detected = false;
 158         vector mymovement = PHYS_CS(this).movement;
 159
 160         #define X(COND,BTN,RESULT)                                                                                                                      \
 161         if (mymovement_##COND)                                                                                          \
 162                 /* is this a state change? */                                                                                                   \
 163                 if(!(PHYS_DODGING_PRESSED_KEYS(this) & KEY_##BTN) || frozen_no_doubletap) {             \
 164                                 tap_direction_##RESULT;                                                                                                 \
 165                                 if ((time - this.last_##BTN##_KEY_time) < PHYS_DODGING_TIMEOUT(this) || frozen_no_doubletap)    \
 166                                         dodge_detected = true;                                                                                          \
 167                                 if(PHYS_INPUT_BUTTON_DODGE(this))                                                                               \
 168                                         dodge_detected = true;                                                                                          \
 169                                 this.last_##BTN##_KEY_time = time;                                                                              \
 170                 }
 171         X(x < 0, BACKWARD,      x--);
 172         X(x > 0, FORWARD,       x++);
 173         X(y < 0, LEFT,          y--);
 174         X(y > 0, RIGHT,         y++);
 175         #undef X
 176
 177         if (dodge_detected)
 178         {
 179                 this.last_dodging_time = time;
 180
 181                 this.dodging_action = 1;
 182                 this.dodging_single_action = 1;
 183
 184                 this.dodging_velocity_gain = PHYS_DODGING_HORIZ_SPEED;
 185
 186                 this.dodging_direction_x = tap_direction_x;
 187                 this.dodging_direction_y = tap_direction_y;
 188
 189                 // normalize the dodging_direction vector.. (unlike UT99) XD
 190                 float length = this.dodging_direction_x * this.dodging_direction_x
 191                                         + this.dodging_direction_y * this.dodging_direction_y;
 192                 length = sqrt(length);
 193
 194                 this.dodging_direction_x = this.dodging_direction_x * 1.0 / length;
 195                 this.dodging_direction_y = this.dodging_direction_y * 1.0 / length;
 196                 return true;
 197         }
 198         return false;
 199 }
 200
 201 void PM_dodging(entity this)
 202 {
 203         // when swimming or dead, no dodging allowed..
 204         if (this.waterlevel >= WATERLEVEL_SWIMMING || IS_DEAD(this))
 205         {
 206                 this.dodging_action = 0;
 207                 this.dodging_direction_x = 0;
 208                 this.dodging_direction_y = 0;
 209                 return;
 210         }
 211
 212         // make sure v_up, v_right and v_forward are sane
 213         if(PHYS_DODGING_AIR)
 214                 makevectors(this.v_angle);
 215         else
 216                 makevectors(this.angles);
 217
 218         // if we have e.g. 0.5 sec ramptime and a frametime of 0.25, then the ramp code
 219         // will be called ramp_time/frametime times = 2 times. so, we need to
 220         // add 0.5 * the total speed each frame until the dodge action is done..
 221         float common_factor = PHYS_DODGING_FRAMETIME / PHYS_DODGING_RAMP_TIME;
 222
 223         // if ramp time is smaller than frametime we get problems ;D
 224         common_factor = min(common_factor, 1);
 225
 226         float horiz_speed = PHYS_FROZEN(this) ? PHYS_DODGING_HORIZ_SPEED_FROZEN : PHYS_DODGING_HORIZ_SPEED;
 227         float new_velocity_gain = this.dodging_velocity_gain - (common_factor * horiz_speed);
 228         new_velocity_gain = max(0, new_velocity_gain);
 229
 230         float velocity_difference = this.dodging_velocity_gain - new_velocity_gain;
 231
 232         // ramp up dodging speed by adding some velocity each frame.. TODO: do it! :D
 233         if (this.dodging_action == 1)
 234         {
 235                 //disable jump key during dodge accel phase
 236                 if(PHYS_CS(this).movement.z > 0) { PHYS_CS(this).movement_z = 0; }
 237
 238                 this.velocity += ((this.dodging_direction_y * velocity_difference) * v_right)
 239                                         + ((this.dodging_direction_x * velocity_difference) * v_forward);
 240
 241                 this.dodging_velocity_gain = this.dodging_velocity_gain - velocity_difference;
 242         }
 243
 244         // the up part of the dodge is a single shot action
 245         if (this.dodging_single_action == 1)
 246         {
 247                 UNSET_ONGROUND(this);
 248
 249                 this.velocity += PHYS_DODGING_UP_SPEED * v_up;
 250
 251 #ifdef SVQC
 252                 if (autocvar_sv_dodging_sound)
 253                         PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 254
 255                 animdecide_setaction(this, ANIMACTION_JUMP, true);
 256 #endif
 257
 258                 this.dodging_single_action = 0;
 259         }
 260
 261         // are we done with the dodging ramp yet?
 262         if((this.dodging_action == 1) && ((time - this.last_dodging_time) > PHYS_DODGING_RAMP_TIME))
 263         {
 264                 // reset state so next dodge can be done correctly
 265                 this.dodging_action = 0;
 266                 this.dodging_direction_x = 0;
 267                 this.dodging_direction_y = 0;
 268         }
 269 }
 270
 271 void PM_dodging_GetPressedKeys(entity this)
 272 {
 273 #ifdef CSQC
 274         PM_dodging_checkpressedkeys(this);
 275
 276         int keys = this.pressedkeys;
 277         keys = BITSET(keys, KEY_FORWARD,        PHYS_CS(this).movement.x > 0);
 278         keys = BITSET(keys, KEY_BACKWARD,       PHYS_CS(this).movement.x < 0);
 279         keys = BITSET(keys, KEY_RIGHT,          PHYS_CS(this).movement.y > 0);
 280         keys = BITSET(keys, KEY_LEFT,           PHYS_CS(this).movement.y < 0);
 281
 282         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
 283         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
 284         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
 285         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
 286         this.pressedkeys = keys;
 287 #endif
 288 }
 289
 290 MUTATOR_HOOKFUNCTION(dodging, PlayerPhysics)
 291 {
 292         entity player = M_ARGV(0, entity);
 293
 294         // print("dodging_PlayerPhysics\n");
 295         PM_dodging_GetPressedKeys(player);
 296         PM_dodging(player);
 297 }
 298
 299 #ifdef SVQC
 300
 301 REPLICATE(cvar_cl_dodging_timeout, float, "cl_dodging_timeout");
 302
 303 MUTATOR_HOOKFUNCTION(dodging, PlayerPreThink)
 304 {
 305         entity player = M_ARGV(0, entity);
 306
 307         STAT(DODGING_TIMEOUT, player) = CS(player).cvar_cl_dodging_timeout;
 308 }
 309
 310 MUTATOR_HOOKFUNCTION(dodging, GetPressedKeys)
 311 {
 312         entity player = M_ARGV(0, entity);
 313
 314         PM_dodging_checkpressedkeys(player);
 315 }
 316
 317 #endif