qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void monster_item_spawn()
   7 {
   8         if(self.monster_loot)
   9                 self.monster_loot();
  10
  11         self.gravity = 1;
  12         self.reset = SUB_Remove;
  13         self.noalign = TRUE;
  14         self.velocity = randomvec() * 175 + '0 0 325';
  15         self.classname = "droppedweapon"; // hax
  16         self.item_spawnshieldtime = time + 0.7;
  17
  18         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  19 }
  20
  21 void monster_dropitem()
  22 {
  23         if(!self.candrop || !self.monster_loot)
  24                 return;
  25
  26         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  27         entity e = spawn();
  28
  29         setorigin(e, org);
  30
  31         e.monster_loot = self.monster_loot;
  32
  33         other = e;
  34         MUTATOR_CALLHOOK(MonsterDropItem);
  35         e = other;
  36
  37         if(e)
  38         {
  39                 e.think = monster_item_spawn;
  40                 e.nextthink = time + 0.3;
  41         }
  42 }
  43
  44 float monster_isvalidtarget (entity targ, entity ent)
  45 {
  46         if(!targ || !ent)
  47                 return FALSE; // someone doesn't exist
  48
  49         if(targ == ent)
  50                 return FALSE; // don't attack ourselves
  51
  52         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  53
  54         if(trace_ent != targ)
  55                 return FALSE;
  56
  57         if(targ.vehicle_flags & VHF_ISVEHICLE)
  58         if not((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED)
  59                 return FALSE; // melee attacks are useless against vehicles
  60
  61         if(time < game_starttime)
  62                 return FALSE; // monsters do nothing before the match has started
  63
  64         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  65                 return FALSE; // enemy is too far away
  66
  67         if(targ.takedamage == DAMAGE_NO)
  68                 return FALSE; // enemy can't be damaged
  69
  70         if(targ.items & IT_INVISIBILITY)
  71                 return FALSE; // enemy is invisible
  72
  73         if(substring(targ.classname, 0, 10) == "onslaught_")
  74                 return FALSE; // don't attack onslaught targets
  75
  76         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  77                 return FALSE; // enemy is a spectator
  78
  79         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  80         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  81                 return FALSE; // enemy/self is dead
  82
  83         if(ent.monster_owner == targ)
  84                 return FALSE; // don't attack our master
  85
  86         if(targ.monster_owner == ent)
  87                 return FALSE; // don't attack our pet
  88
  89         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  90         if(targ.flags & FL_NOTARGET)
  91                 return FALSE; // enemy can't be targeted
  92
  93         if not(autocvar_g_monsters_typefrag)
  94         if(targ.BUTTON_CHAT)
  95                 return FALSE; // no typefragging!
  96
  97         if(SAME_TEAM(targ, ent))
  98                 return FALSE; // enemy is on our team
  99
 100         if (targ.frozen == 1 || (targ.frozen == 2 && ent.monsterid != MON_SPIDER))
 101                 return FALSE; // ignore frozen
 102
 103         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 104         if(ent.enemy != targ)
 105         {
 106                 float dot;
 107
 108                 makevectors (ent.angles);
 109                 dot = normalize (targ.origin - ent.origin) * v_forward;
 110
 111                 if(dot <= 0.3)
 112                         return FALSE;
 113         }
 114
 115         return TRUE;
 116 }
 117
 118 entity FindTarget (entity ent)
 119 {
 120         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 121
 122         entity head, closest_target = world;
 123         head = findradius(ent.origin, ent.target_range);
 124
 125         while(head) // find the closest acceptable target to pass to
 126         {
 127                 if(head.monster_attack)
 128                 if(monster_isvalidtarget(head, ent))
 129                 {
 130                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 131                         vector head_center = CENTER_OR_VIEWOFS(head);
 132                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 133
 134                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 135                         if(closest_target)
 136                         {
 137                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 138                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 139                                         { closest_target = head; }
 140                         }
 141                         else { closest_target = head; }
 142                 }
 143
 144                 head = head.chain;
 145         }
 146
 147         return closest_target;
 148 }
 149
 150 void MonsterTouch ()
 151 {
 152         if(other == world)
 153                 return;
 154
 155         if(self.enemy != other)
 156         if not(other.flags & FL_MONSTER)
 157         if(monster_isvalidtarget(other, self))
 158                 self.enemy = other;
 159 }
 160
 161 string get_monster_model_datafilename(string m, float sk, string fil)
 162 {
 163         if(m)
 164                 m = strcat(m, "_");
 165         else
 166                 m = "models/monsters/*_";
 167         if(sk >= 0)
 168                 m = strcat(m, ftos(sk));
 169         else
 170                 m = strcat(m, "*");
 171         return strcat(m, ".", fil);
 172 }
 173
 174 void PrecacheMonsterSounds(string f)
 175 {
 176         float fh;
 177         string s;
 178         fh = fopen(f, FILE_READ);
 179         if(fh < 0)
 180                 return;
 181         while((s = fgets(fh)))
 182         {
 183                 if(tokenize_console(s) != 3)
 184                 {
 185                         dprint("Invalid sound info line: ", s, "\n");
 186                         continue;
 187                 }
 188                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 189         }
 190         fclose(fh);
 191 }
 192
 193 void precache_monstersounds()
 194 {
 195         string m = (get_monsterinfo(self.monsterid)).model;
 196         float globhandle, n, i;
 197         string f;
 198
 199         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 200         if (globhandle < 0)
 201                 return;
 202         n = search_getsize(globhandle);
 203         for (i = 0; i < n; ++i)
 204         {
 205                 //print(search_getfilename(globhandle, i), "\n");
 206                 f = search_getfilename(globhandle, i);
 207                 PrecacheMonsterSounds(f);
 208         }
 209         search_end(globhandle);
 210 }
 211
 212 void ClearMonsterSounds()
 213 {
 214 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 215         ALLMONSTERSOUNDS
 216 #undef _MSOUND
 217 }
 218
 219 .string GetMonsterSoundSampleField(string type)
 220 {
 221         GetMonsterSoundSampleField_notFound = 0;
 222         switch(type)
 223         {
 224 #define _MSOUND(m) case #m: return monstersound_##m;
 225                 ALLMONSTERSOUNDS
 226 #undef _MSOUND
 227         }
 228         GetMonsterSoundSampleField_notFound = 1;
 229         return string_null;
 230 }
 231
 232 float LoadMonsterSounds(string f, float first)
 233 {
 234         float fh;
 235         string s;
 236         var .string field;
 237         fh = fopen(f, FILE_READ);
 238         if(fh < 0)
 239         {
 240                 dprint("Monster sound file not found: ", f, "\n");
 241                 return 0;
 242         }
 243         while((s = fgets(fh)))
 244         {
 245                 if(tokenize_console(s) != 3)
 246                         continue;
 247                 field = GetMonsterSoundSampleField(argv(0));
 248                 if(GetMonsterSoundSampleField_notFound)
 249                         continue;
 250                 if(self.field)
 251                         strunzone(self.field);
 252                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 253         }
 254         fclose(fh);
 255         return 1;
 256 }
 257
 258 .float skin_for_monstersound;
 259 void UpdateMonsterSounds()
 260 {
 261         entity mon = get_monsterinfo(self.monsterid);
 262
 263         if(self.skin == self.skin_for_monstersound)
 264                 return;
 265         self.skin_for_monstersound = self.skin;
 266         ClearMonsterSounds();
 267         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 268         if(!autocvar_g_debug_defaultsounds)
 269         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 270                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 271 }
 272
 273 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 274 {
 275         if(delaytoo && time < self.msound_delay)
 276                 return; // too early
 277         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 278
 279         self.msound_delay = time + sound_delay;
 280 }
 281
 282 void monster_makevectors(entity e)
 283 {
 284         vector v;
 285
 286         v = e.origin + (e.mins + e.maxs) * 0.5;
 287         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 288         self.v_angle_x = -self.v_angle_x;
 289
 290         makevectors(self.v_angle);
 291 }
 292
 293 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 294 {
 295         float rdmg = damg * random();
 296
 297         if (self.health <= 0)
 298                 return FALSE; // attacking while dead?!
 299
 300         if(dostop)
 301         {
 302                 self.velocity_x = 0;
 303                 self.velocity_y = 0;
 304                 self.state = MONSTER_STATE_ATTACK_MELEE;
 305         }
 306
 307         self.frame = anim;
 308
 309         if(anim_finished != 0)
 310                 self.attack_finished_single = time + anim_finished;
 311
 312         monster_makevectors(targ);
 313
 314         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 315
 316         if(trace_ent.takedamage)
 317                 Damage(trace_ent, self, self, rdmg * monster_skill, deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 318
 319         return TRUE;
 320 }
 321
 322 void Monster_CheckMinibossFlag ()
 323 {
 324         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 325                 return;
 326
 327         float chance = random() * 100;
 328
 329         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 330         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 331         {
 332                 self.health += autocvar_g_monsters_miniboss_healthboost;
 333                 self.effects |= EF_RED;
 334                 if not(self.weapon)
 335                         self.weapon = WEP_NEX;
 336         }
 337 }
 338
 339 float Monster_CanRespawn(entity ent)
 340 {
 341         other = ent;
 342         if(ent.deadflag == DEAD_DEAD) // don't call when monster isn't dead
 343         if(MUTATOR_CALLHOOK(MonsterRespawn))
 344                 return TRUE; // enabled by a mutator
 345
 346         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 347                 return FALSE;
 348
 349         if not(autocvar_g_monsters_respawn)
 350                 return FALSE;
 351
 352         return TRUE;
 353 }
 354
 355 void Monster_Fade ()
 356 {
 357         if(Monster_CanRespawn(self))
 358         {
 359                 self.monster_respawned = TRUE;
 360                 self.think = self.monster_spawnfunc;
 361                 self.nextthink = time + self.respawntime;
 362                 self.ltime = 0;
 363                 self.deadflag = DEAD_RESPAWNING;
 364                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 365                 {
 366                         self.pos1 = self.origin;
 367                         self.pos2 = self.angles;
 368                 }
 369                 self.event_damage = func_null;
 370                 self.takedamage = DAMAGE_NO;
 371                 setorigin(self, self.pos1);
 372                 self.angles = self.pos2;
 373                 self.health = self.max_health;
 374                 setmodel(self, "null");
 375         }
 376         else
 377                 SUB_SetFade(self, time + 3, 1);
 378 }
 379
 380 float Monster_CanJump (vector vel)
 381 {
 382         if(self.state)
 383                 return FALSE; // already attacking
 384         if not(self.flags & FL_ONGROUND)
 385                 return FALSE; // not on the ground
 386         if(self.health <= 0)
 387                 return FALSE; // called when dead?
 388         if(time < self.attack_finished_single)
 389                 return FALSE; // still attacking
 390
 391         vector old = self.velocity;
 392
 393         self.velocity = vel;
 394         tracetoss(self, self);
 395         self.velocity = old;
 396         if (trace_ent != self.enemy)
 397                 return FALSE;
 398
 399         return TRUE;
 400 }
 401
 402 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 403 {
 404         if(!Monster_CanJump(vel))
 405                 return FALSE;
 406
 407         self.frame = anm;
 408         self.state = MONSTER_STATE_ATTACK_LEAP;
 409         self.touch = touchfunc;
 410         self.origin_z += 1;
 411         self.velocity = vel;
 412         self.flags &= ~FL_ONGROUND;
 413
 414         self.attack_finished_single = time + anim_finished;
 415
 416         return TRUE;
 417 }
 418
 419 void monster_checkattack(entity e, entity targ)
 420 {
 421         if(e == world)
 422                 return;
 423         if(targ == world)
 424                 return;
 425
 426         if not(e.monster_attackfunc)
 427                 return;
 428
 429         if(time < e.attack_finished_single)
 430                 return;
 431
 432         if(vlen(targ.origin - e.origin) <= e.attack_range)
 433         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 434         {
 435                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 436                 return;
 437         }
 438
 439         if(vlen(targ.origin - e.origin) > e.attack_range)
 440         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 441         {
 442                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 443                 return;
 444         }
 445 }
 446
 447 void monster_use ()
 448 {
 449         if not(self.enemy)
 450         if(self.health > 0)
 451         if(monster_isvalidtarget(activator, self))
 452                 self.enemy = activator;
 453 }
 454
 455 .float last_trace;
 456 .float last_enemycheck; // for checking enemy
 457 vector monster_pickmovetarget(entity targ)
 458 {
 459         // enemy is always preferred target
 460         if(self.enemy)
 461         {
 462                 makevectors(self.angles);
 463                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 464                 self.last_trace = time + 1.2;
 465                 return self.enemy.origin;
 466         }
 467
 468         switch(self.monster_moveflags)
 469         {
 470                 case MONSTER_MOVE_OWNER:
 471                 {
 472                         self.monster_movestate = MONSTER_MOVE_OWNER;
 473                         self.last_trace = time + 0.3;
 474                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 475                 }
 476                 case MONSTER_MOVE_SPAWNLOC:
 477                 {
 478                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 479                         self.last_trace = time + 2;
 480                         return self.pos1;
 481                 }
 482                 case MONSTER_MOVE_NOMOVE:
 483                 {
 484                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 485                         self.last_trace = time + 2;
 486                         return self.origin;
 487                 }
 488                 default:
 489                 case MONSTER_MOVE_WANDER:
 490                 {
 491                         vector pos;
 492                         self.monster_movestate = MONSTER_MOVE_WANDER;
 493                         self.last_trace = time + 2;
 494
 495                         self.angles_y = rint(random() * 500);
 496                         makevectors(self.angles);
 497                         pos = self.origin + v_forward * 600;
 498
 499                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 500                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 501                         {
 502                                 pos_z = random() * 200;
 503                                 if(random() >= 0.5)
 504                                         pos_z *= -1;
 505                         }
 506
 507                         if(targ)
 508                         {
 509                                 self.last_trace = time + 0.5;
 510                                 pos = targ.origin;
 511                         }
 512
 513                         return pos;
 514                 }
 515         }
 516 }
 517
 518 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 519 {
 520         fixedmakevectors(self.angles);
 521
 522         if(self.target2)
 523                 self.goalentity = find(world, targetname, self.target2);
 524
 525         entity targ;
 526
 527         if(self.frozen)
 528         {
 529                 self.revive_progress = bound(0, self.revive_progress + self.ticrate * self.revive_speed, 1);
 530                 self.health = max(1, self.max_health * self.revive_progress);
 531
 532                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 533
 534                 movelib_beak_simple(stopspeed);
 535
 536                 self.frame = manim_idle;
 537
 538                 self.enemy = world;
 539                 self.nextthink = time + self.ticrate;
 540
 541                 if(self.revive_progress >= 1)
 542                         Unfreeze(self); // wait for next think before attacking
 543
 544                 return; // no moving while frozen
 545         }
 546
 547         if(self.flags & FL_SWIM)
 548         {
 549                 if(self.waterlevel < WATERLEVEL_WETFEET)
 550                 {
 551                         if(time >= self.last_trace)
 552                         {
 553                                 self.fish_wasdrowning = TRUE;
 554                                 self.last_trace = time + 0.4;
 555
 556                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 557                                 self.angles = '90 90 0';
 558                                 if(random() < 0.5)
 559                                 {
 560                                         self.velocity_y += random() * 50;
 561                                         self.velocity_x -= random() * 50;
 562                                 }
 563                                 else
 564                                 {
 565                                         self.velocity_y -= random() * 50;
 566                                         self.velocity_x += random() * 50;
 567                                 }
 568                                 self.velocity_z += random() * 150;
 569                         }
 570
 571
 572                         self.movetype = MOVETYPE_BOUNCE;
 573                         //self.velocity_z = -200;
 574
 575                         return;
 576                 }
 577                 else if(self.fish_wasdrowning)
 578                 {
 579                         self.fish_wasdrowning = FALSE;
 580                         self.angles_x = 0;
 581                         self.movetype = MOVETYPE_WALK;
 582                 }
 583         }
 584
 585         targ = self.goalentity;
 586
 587         monster_target = targ;
 588         monster_speed_run = runspeed;
 589         monster_speed_walk = walkspeed;
 590
 591         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 592         {
 593                 runspeed = walkspeed = 0;
 594                 if(time >= self.spawn_time)
 595                         self.frame = manim_idle;
 596                 movelib_beak_simple(stopspeed);
 597                 return;
 598         }
 599
 600         targ = monster_target;
 601         runspeed = monster_speed_run;
 602         walkspeed = monster_speed_walk;
 603
 604         if(teamplay)
 605         if(autocvar_g_monsters_teams)
 606         if(DIFF_TEAM(self.monster_owner, self))
 607                 self.monster_owner = world;
 608
 609         if(self.enemy && self.enemy.health < 1)
 610                 self.enemy = world; // enough!
 611
 612         if(time >= self.last_enemycheck)
 613         {
 614                 if not(monster_isvalidtarget(self.enemy, self))
 615                         self.enemy = world;
 616
 617                 if not(self.enemy)
 618                 {
 619                         self.enemy = FindTarget(self);
 620                         if(self.enemy)
 621                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 622                 }
 623
 624                 self.last_enemycheck = time + 0.5;
 625         }
 626
 627         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 628                 self.state = 0;
 629
 630         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 631         if(time >= self.last_trace || self.enemy) // update enemy instantly
 632                 self.moveto = monster_pickmovetarget(targ);
 633
 634         if not(self.enemy)
 635                 MonsterSound(monstersound_idle, 5, TRUE, CH_VOICE);
 636
 637         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 638                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 639
 640         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 641         {
 642                 self.state = 0;
 643                 self.touch = MonsterTouch;
 644         }
 645
 646         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 647
 648         float turny = 0;
 649         vector real_angle = vectoangles(self.steerto) - self.angles;
 650
 651         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 652                 turny = 20;
 653
 654         if(self.flags & FL_SWIM)
 655                 turny = vlen(self.angles - self.moveto);
 656
 657         if(turny)
 658         {
 659                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 660                 self.angles_y += turny;
 661         }
 662
 663         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 664                 self.moveto = self.origin;
 665
 666         if(self.enemy && self.enemy.vehicle)
 667                 runspeed = 0;
 668
 669         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 670                 v_forward = normalize(self.moveto - self.origin);
 671         else
 672                 self.moveto_z = self.origin_z;
 673
 674         if(vlen(self.origin - self.moveto) > 64)
 675         {
 676                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 677                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 678                 else
 679                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 680
 681                 if(time > self.pain_finished)
 682                 if(time > self.attack_finished_single)
 683                 if(vlen(self.velocity) > 10)
 684                         self.frame = ((self.enemy) ? manim_run : manim_walk);
 685                 else
 686                         self.frame = manim_idle;
 687         }
 688         else
 689         {
 690                 entity e = find(world, targetname, self.target2);
 691                 if(e.target2)
 692                         self.target2 = e.target2;
 693                 else if(e.target)
 694                         self.target2 = e.target;
 695
 696                 movelib_beak_simple(stopspeed);
 697                 if(time > self.attack_finished_single)
 698                 if(time > self.pain_finished)
 699                 if (vlen(self.velocity) <= 30)
 700                         self.frame = manim_idle;
 701         }
 702
 703         monster_checkattack(self, self.enemy);
 704 }
 705
 706 void monster_remove(entity mon)
 707 {
 708         if not(mon)
 709                 return; // nothing to remove
 710
 711         pointparticles(particleeffectnum("item_pickup"), mon.origin, '0 0 0', 1);
 712
 713         if(mon.weaponentity)
 714                 remove(mon.weaponentity);
 715
 716         if(mon.iceblock)
 717                 remove(mon.iceblock);
 718
 719         WaypointSprite_Kill(mon.sprite);
 720
 721         remove(mon);
 722 }
 723
 724 void monster_dead_think()
 725 {
 726         self.nextthink = time + self.ticrate;
 727
 728         CSQCMODEL_AUTOUPDATE();
 729
 730         if(self.ltime != 0)
 731         if(time >= self.ltime)
 732         {
 733                 Monster_Fade();
 734                 return;
 735         }
 736 }
 737
 738 void monsters_setstatus()
 739 {
 740         self.stat_monsters_total = monsters_total;
 741         self.stat_monsters_killed = monsters_killed;
 742 }
 743
 744 void Monster_Appear()
 745 {
 746         self.enemy = activator;
 747         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 748         self.monster_spawnfunc();
 749 }
 750
 751 float Monster_CheckAppearFlags(entity ent)
 752 {
 753         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 754                 return FALSE;
 755
 756         ent.think = func_null;
 757         ent.nextthink = 0;
 758         ent.use = Monster_Appear;
 759         ent.flags = FL_MONSTER; // set so this monster can get butchered
 760
 761         return TRUE;
 762 }
 763
 764 void monsters_reset()
 765 {
 766         setorigin(self, self.pos1);
 767         self.angles = self.pos2;
 768
 769         Unfreeze(self); // remove any icy remains
 770
 771         self.health = self.max_health;
 772         self.velocity = '0 0 0';
 773         self.enemy = world;
 774         self.goalentity = world;
 775         self.attack_finished_single = 0;
 776         self.moveto = self.origin;
 777 }
 778
 779 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 780 {
 781         self.health -= damage;
 782
 783         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 784
 785         if(self.health <= -100) // 100 health until gone?
 786         {
 787                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 788
 789                 if(IS_CLIENT(self.realowner))
 790                 if not(self.monster_respawned)
 791                         self.realowner.monstercount -= 1;
 792
 793                 self.think = SUB_Remove;
 794                 self.nextthink = time + 0.1;
 795         }
 796 }
 797
 798 void monster_die(entity attacker, float gibbed)
 799 {
 800         self.think = monster_dead_think;
 801         self.nextthink = time;
 802         self.ltime = time + 5;
 803
 804         if ( self.frozen )
 805         {
 806                 Unfreeze(self); // remove any icy remains
 807                 self.health = 0; // reset by Unfreeze
 808         }
 809
 810         monster_dropitem();
 811
 812         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 813
 814         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 815                 monsters_killed += 1;
 816
 817         if(IS_PLAYER(attacker))
 818         if( autocvar_g_monsters_score_spawned ||
 819                         ( !(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned) )
 820                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
 821
 822         if(!Monster_CanRespawn(self) || gibbed)
 823         {
 824                 // number of monsters spawned with mobspawn command
 825                 totalspawned -= 1;
 826
 827                 if(IS_CLIENT(self.realowner))
 828                 if not(self.monster_respawned)
 829                         self.realowner.monstercount -= 1;
 830         }
 831
 832         if(self.candrop && self.weapon)
 833                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 834
 835         self.event_damage       = monsters_corpse_damage;
 836         self.solid                      = SOLID_CORPSE;
 837         self.takedamage         = DAMAGE_AIM;
 838         self.deadflag           = DEAD_DEAD;
 839         self.enemy                      = world;
 840         self.movetype           = MOVETYPE_TOSS;
 841         self.moveto                     = self.origin;
 842         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 843         self.reset                      = func_null;
 844         self.state                      = 0;
 845         self.attack_finished_single = 0;
 846
 847         if not(self.flags & FL_FLY)
 848                 self.velocity = '0 0 0';
 849
 850         MON_ACTION(self.monsterid, MR_DEATH);
 851 }
 852
 853 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 854 {
 855
 856         if(self.frozen && deathtype != DEATH_KILL)
 857                 return;
 858
 859         if(time < self.pain_finished && deathtype != DEATH_KILL)
 860                 return;
 861
 862         if(time < self.spawnshieldtime && deathtype != DEATH_KILL)
 863                 return;
 864
 865         vector v;
 866         float take, save;
 867
 868         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, deathtype, damage);
 869         take = v_x;
 870         save = v_y;
 871
 872         self.health -= take;
 873
 874         WaypointSprite_UpdateHealth(self.sprite, self.health);
 875
 876         self.dmg_time = time;
 877
 878         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 879                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 880
 881         self.velocity += force * self.damageforcescale;
 882
 883         if(deathtype != DEATH_DROWN)
 884         {
 885                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 886                 if (take > 50)
 887                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 888                 if (take > 100)
 889                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 890         }
 891
 892         if(self.health <= 0)
 893         {
 894                 if(deathtype == DEATH_KILL)
 895                         self.candrop = FALSE; // killed by mobkill command
 896
 897                 // TODO: fix this?
 898                 activator = attacker;
 899                 other = self.enemy;
 900                 SUB_UseTargets();
 901                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 902
 903                 monster_die(attacker, (self.health <= -100 || deathtype == DEATH_KILL));
 904
 905                 WaypointSprite_Kill(self.sprite);
 906
 907                 frag_attacker = attacker;
 908                 frag_target = self;
 909                 MUTATOR_CALLHOOK(MonsterDies);
 910
 911                 if(self.health <= -100 || deathtype == DEATH_KILL) // check if we're already gibbed
 912                 {
 913                         Violence_GibSplash(self, 1, 0.5, attacker);
 914
 915                         self.think = SUB_Remove;
 916                         self.nextthink = time + 0.1;
 917                 }
 918         }
 919 }
 920
 921 void monster_think()
 922 {
 923         self.think = monster_think;
 924         self.nextthink = self.ticrate;
 925
 926         if(self.ltime)
 927         if(time >= self.ltime)
 928         {
 929                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL, self.origin, self.origin);
 930                 return;
 931         }
 932
 933         MON_ACTION(self.monsterid, MR_THINK);
 934
 935         CSQCMODEL_AUTOUPDATE();
 936 }
 937
 938 void monster_spawn()
 939 {
 940         MON_ACTION(self.monsterid, MR_SETUP);
 941
 942         if not(self.monster_respawned)
 943                 Monster_CheckMinibossFlag();
 944
 945         self.max_health = self.health;
 946         self.pain_finished = self.nextthink;
 947
 948         if(IS_PLAYER(self.monster_owner))
 949                 self.effects |= EF_DIMLIGHT;
 950
 951         if not(self.monster_respawned)
 952         if not(self.skin)
 953                 self.skin = rint(random() * 4);
 954
 955         if not(self.attack_range)
 956                 self.attack_range = autocvar_g_monsters_attack_range;
 957
 958         precache_monstersounds();
 959         UpdateMonsterSounds();
 960
 961         if(teamplay)
 962                 self.monster_attack = TRUE; // we can have monster enemies in team games
 963
 964         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
 965
 966         WaypointSprite_Spawn(M_NAME(self.monsterid), 0, 1024, self, '0 0 1' * (self.maxs_z + 15), world, self.team, self, sprite, TRUE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 967         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 968         WaypointSprite_UpdateHealth(self.sprite, self.health);
 969
 970         self.think = monster_think;
 971         self.nextthink = time + self.ticrate;
 972
 973         MUTATOR_CALLHOOK(MonsterSpawn);
 974 }
 975
 976 float monster_initialize(float mon_id, float nodrop)
 977 {
 978         if not(autocvar_g_monsters)
 979                 return FALSE;
 980
 981         entity mon = get_monsterinfo(mon_id);
 982
 983         if(mon.spawnflags & MON_FLAG_MUTATORBLOCKED && !(self.spawnflags & MONSTERFLAG_SPAWNED))
 984         {
 985                 dprint("Attempted to spawn a mutator-blocked monster rejected");
 986                 return FALSE;
 987         }
 988
 989         // support for quake style removing monsters based on skill
 990         if(monster_skill <= 1) if(self.spawnflags & MONSTERSKILL_NOTEASY) { return FALSE; }
 991         if(monster_skill == 2) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { return FALSE; }
 992         if(monster_skill >= 3) if(self.spawnflags & MONSTERSKILL_NOTHARD) { return FALSE; }
 993
 994         if(self.team && !teamplay)
 995                 self.team = 0;
 996
 997         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 998         if not(self.monster_respawned)
 999                 monsters_total += 1;
1000
1001         setmodel(self, mon.model);
1002         setsize(self, mon.mins, mon.maxs);
1003         self.flags                              = FL_MONSTER;
1004         self.takedamage                 = DAMAGE_AIM;
1005         self.bot_attack                 = TRUE;
1006         self.iscreature                 = TRUE;
1007         self.teleportable               = TRUE;
1008         self.damagedbycontents  = TRUE;
1009         self.monsterid                  = mon_id;
1010         self.damageforcescale   = 0;
1011         self.event_damage               = monsters_damage;
1012         self.touch                              = MonsterTouch;
1013         self.use                                = monster_use;
1014         self.solid                              = SOLID_BBOX;
1015         self.movetype                   = MOVETYPE_WALK;
1016         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1017         self.enemy                              = world;
1018         self.velocity                   = '0 0 0';
1019         self.moveto                             = self.origin;
1020         self.pos1                               = self.origin;
1021         self.pos2                               = self.angles;
1022         self.reset                              = monsters_reset;
1023         self.netname                    = mon.netname;
1024         self.monster_name               = M_NAME(mon_id);
1025         self.candrop                    = TRUE;
1026         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1027         self.oldtarget2                 = self.target2;
1028         self.deadflag                   = DEAD_NO;
1029         self.scale                              = 1;
1030         self.noalign                    = nodrop;
1031         self.spawn_time                 = time;
1032         self.gravity                    = 1;
1033         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1034
1035         if(autocvar_g_fullbrightplayers)
1036                 self.effects |= EF_FULLBRIGHT;
1037
1038         if(autocvar_g_nodepthtestplayers)
1039                 self.effects |= EF_NODEPTHTEST;
1040
1041         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1042                 self.flags |= FL_SWIM;
1043
1044         if(mon.spawnflags & MONSTER_TYPE_FLY)
1045         {
1046                 self.flags |= FL_FLY;
1047                 self.movetype = MOVETYPE_FLY;
1048         }
1049
1050         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1051                 self.scale = 1.3;
1052
1053         if not(self.ticrate)
1054                 self.ticrate = autocvar_g_monsters_think_delay;
1055
1056         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1057
1058         if not(self.m_armor_blockpercent)
1059                 self.m_armor_blockpercent = 0.5;
1060
1061         if not(self.target_range)
1062                 self.target_range = autocvar_g_monsters_target_range;
1063
1064         if not(self.respawntime)
1065                 self.respawntime = autocvar_g_monsters_respawn_delay;
1066
1067         if not(self.monster_moveflags)
1068                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1069
1070         if not(self.noalign)
1071         {
1072                 setorigin(self, self.origin + '0 0 20');
1073                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1074                 setorigin(self, trace_endpos);
1075         }
1076
1077         monster_spawn();
1078
1079         CSQCMODEL_AUTOINIT();
1080
1081         return TRUE;
1082 }