qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void M_Item_Touch ()
   7 {
   8         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   9         {
  10                 Item_Touch();
  11                 self.think = SUB_Remove;
  12                 self.nextthink = time + 0.1;
  13         }
  14 }
  15
  16 void monster_item_spawn()
  17 {
  18         if(self.monster_loot)
  19                 self.monster_loot();
  20
  21         self.gravity = 1;
  22         self.velocity = randomvec() * 175 + '0 0 325';
  23         self.touch = M_Item_Touch;
  24
  25         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  26 }
  27
  28 void monster_dropitem()
  29 {
  30         if(!self.candrop || !self.monster_loot)
  31                 return;
  32
  33         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  34         entity e = spawn();
  35
  36         setorigin(e, org);
  37
  38         e.monster_loot = self.monster_loot;
  39
  40         other = e;
  41         MUTATOR_CALLHOOK(MonsterDropItem);
  42         e = other;
  43
  44         e.think = monster_item_spawn;
  45         e.nextthink = time + 0.3;
  46 }
  47
  48 void monsters_setframe(float _frame)
  49 {
  50         if(self.frame == _frame)
  51                 return;
  52
  53         self.anim_start_time = time;
  54         self.frame = _frame;
  55         self.SendFlags |= MSF_ANIM;
  56 }
  57
  58 float monster_isvalidtarget (entity targ, entity ent)
  59 {
  60         if(!targ || !ent)
  61                 return FALSE; // someone doesn't exist
  62
  63         if(targ == ent)
  64                 return FALSE; // don't attack ourselves
  65
  66         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  67
  68         if(trace_ent != targ)
  69         {
  70                 if(trace_ent != world)
  71                         targ = trace_ent;
  72                 else
  73                         return FALSE;
  74         }
  75
  76         if(targ.vehicle_flags & VHF_ISVEHICLE)
  77         if not((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED)
  78                 return FALSE; // melee attacks are useless against vehicles
  79
  80         if(time < game_starttime)
  81                 return FALSE; // monsters do nothing before the match has started
  82
  83         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  84                 return FALSE; // enemy is too far away
  85
  86         if(targ.takedamage == DAMAGE_NO)
  87                 return FALSE; // enemy can't be damaged
  88
  89         if(targ.items & IT_INVISIBILITY)
  90                 return FALSE; // enemy is invisible
  91
  92         if(substring(targ.classname, 0, 10) == "onslaught_")
  93                 return FALSE; // don't attack onslaught targets
  94
  95         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  96                 return FALSE; // enemy is a spectator
  97
  98         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  99         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
 100                 return FALSE; // enemy/self is dead
 101
 102         if(ent.monster_owner == targ)
 103                 return FALSE; // don't attack our master
 104
 105         if(targ.monster_owner == ent)
 106                 return FALSE; // don't attack our pet
 107
 108         if not(targ.vehicle_flags & VHF_ISVEHICLE)
 109         if(targ.flags & FL_NOTARGET)
 110                 return FALSE; // enemy can't be targeted
 111
 112         if not(autocvar_g_monsters_typefrag)
 113         if(targ.BUTTON_CHAT)
 114                 return FALSE; // no typefragging!
 115
 116         if not(IsDifferentTeam(targ, ent))
 117                 return FALSE; // enemy is on our team
 118
 119         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 120         if(ent.enemy != targ)
 121         {
 122                 float dot;
 123
 124                 makevectors (ent.angles);
 125                 dot = normalize (targ.origin - ent.origin) * v_forward;
 126
 127                 if(dot <= 0.3)
 128                         return FALSE;
 129         }
 130
 131         return TRUE;
 132 }
 133
 134 entity FindTarget (entity ent)
 135 {
 136         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 137
 138         entity head, closest_target = world;
 139         head = findradius(ent.origin, ent.target_range);
 140
 141         while(head) // find the closest acceptable target to pass to
 142         {
 143                 if(monster_isvalidtarget(head, ent))
 144                 {
 145                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 146                         vector head_center = CENTER_OR_VIEWOFS(head);
 147                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 148
 149                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 150                         if(closest_target)
 151                         {
 152                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 153                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 154                                         { closest_target = head; }
 155                         }
 156                         else { closest_target = head; }
 157                 }
 158
 159                 head = head.chain;
 160         }
 161
 162         return closest_target;
 163 }
 164
 165 void MonsterTouch ()
 166 {
 167         if(other == world)
 168                 return;
 169
 170         if(self.enemy != other)
 171         if not(other.flags & FL_MONSTER)
 172         if(monster_isvalidtarget(other, self))
 173                 self.enemy = other;
 174 }
 175
 176 string get_monster_model_datafilename(string m, float sk, string fil)
 177 {
 178         if(m)
 179                 m = strcat(m, "_");
 180         else
 181                 m = "models/monsters/*_";
 182         if(sk >= 0)
 183                 m = strcat(m, ftos(sk));
 184         else
 185                 m = strcat(m, "*");
 186         return strcat(m, ".", fil);
 187 }
 188
 189 void PrecacheMonsterSounds(string f)
 190 {
 191         float fh;
 192         string s;
 193         fh = fopen(f, FILE_READ);
 194         if(fh < 0)
 195                 return;
 196         while((s = fgets(fh)))
 197         {
 198                 if(tokenize_console(s) != 3)
 199                 {
 200                         dprint("Invalid sound info line: ", s, "\n");
 201                         continue;
 202                 }
 203                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 204         }
 205         fclose(fh);
 206 }
 207
 208 void precache_monstersounds()
 209 {
 210         string m = (get_monsterinfo(self.monsterid)).model;
 211         float globhandle, n, i;
 212         string f;
 213
 214         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 215         if (globhandle < 0)
 216                 return;
 217         n = search_getsize(globhandle);
 218         for (i = 0; i < n; ++i)
 219         {
 220                 //print(search_getfilename(globhandle, i), "\n");
 221                 f = search_getfilename(globhandle, i);
 222                 PrecacheMonsterSounds(f);
 223         }
 224         search_end(globhandle);
 225 }
 226
 227 void ClearMonsterSounds()
 228 {
 229 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 230         ALLMONSTERSOUNDS
 231 #undef _MSOUND
 232 }
 233
 234 .string GetMonsterSoundSampleField(string type)
 235 {
 236         GetMonsterSoundSampleField_notFound = 0;
 237         switch(type)
 238         {
 239 #define _MSOUND(m) case #m: return monstersound_##m;
 240                 ALLMONSTERSOUNDS
 241 #undef _MSOUND
 242         }
 243         GetMonsterSoundSampleField_notFound = 1;
 244         return string_null;
 245 }
 246
 247 float LoadMonsterSounds(string f, float first)
 248 {
 249         float fh;
 250         string s;
 251         var .string field;
 252         fh = fopen(f, FILE_READ);
 253         if(fh < 0)
 254         {
 255                 dprint("Monster sound file not found: ", f, "\n");
 256                 return 0;
 257         }
 258         while((s = fgets(fh)))
 259         {
 260                 if(tokenize_console(s) != 3)
 261                         continue;
 262                 field = GetMonsterSoundSampleField(argv(0));
 263                 if(GetMonsterSoundSampleField_notFound)
 264                         continue;
 265                 if(self.field)
 266                         strunzone(self.field);
 267                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 268         }
 269         fclose(fh);
 270         return 1;
 271 }
 272
 273 .float skin_for_monstersound;
 274 void UpdateMonsterSounds()
 275 {
 276         entity mon = get_monsterinfo(self.monsterid);
 277
 278         if(self.skin == self.skin_for_monstersound)
 279                 return;
 280         self.skin_for_monstersound = self.skin;
 281         ClearMonsterSounds();
 282         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 283         if(!autocvar_g_debug_defaultsounds)
 284         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 285                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 286 }
 287
 288 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 289 {
 290         if(delaytoo && time < self.msound_delay)
 291                 return; // too early
 292         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 293
 294         self.msound_delay = time + sound_delay;
 295 }
 296
 297 void monster_makevectors(entity e)
 298 {
 299         vector v;
 300
 301         v = CENTER_OR_VIEWOFS(e);
 302         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 303         self.v_angle_x = -self.v_angle_x;
 304
 305         makevectors(self.v_angle);
 306 }
 307
 308 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 309 {
 310         float rdmg = damg * random();
 311
 312         if (self.health <= 0)
 313                 return FALSE; // attacking while dead?!
 314
 315         if(dostop)
 316         {
 317                 self.velocity_x = 0;
 318                 self.velocity_y = 0;
 319                 self.state = MONSTER_STATE_ATTACK_MELEE;
 320                 self.SendFlags |= MSF_MOVE;
 321         }
 322
 323         monsters_setframe(anim);
 324
 325         if(anim_finished != 0)
 326                 self.attack_finished_single = time + anim_finished;
 327
 328         monster_makevectors(targ);
 329
 330         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 331
 332         if(trace_ent.takedamage)
 333                 Damage(trace_ent, self, self, rdmg * monster_skill, deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 334
 335         return TRUE;
 336 }
 337
 338 void Monster_CheckMinibossFlag ()
 339 {
 340         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 341                 return;
 342
 343         float chance = random() * 100;
 344
 345         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 346         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 347         {
 348                 self.health += autocvar_g_monsters_miniboss_healthboost;
 349                 if not(self.weapon)
 350                         self.weapon = WEP_NEX;
 351         }
 352 }
 353
 354 float Monster_CanRespawn(entity ent)
 355 {
 356         other = ent;
 357         if(MUTATOR_CALLHOOK(MonsterRespawn))
 358                 return TRUE; // enabled by a mutator
 359
 360         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 361                 return FALSE;
 362
 363         if not(autocvar_g_monsters_respawn)
 364                 return FALSE;
 365
 366         return TRUE;
 367 }
 368
 369 void Monster_Fade ()
 370 {
 371         if(Monster_CanRespawn(self))
 372         {
 373                 self.monster_respawned = TRUE;
 374                 self.think = self.monster_spawnfunc;
 375                 self.nextthink = time + self.respawntime;
 376                 self.deadflag = DEAD_RESPAWNING;
 377                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 378                 {
 379                         self.pos1 = self.origin;
 380                         self.pos2 = self.angles;
 381                 }
 382                 self.event_damage = func_null;
 383                 self.takedamage = DAMAGE_NO;
 384                 setorigin(self, self.pos1);
 385                 self.angles = self.pos2;
 386                 self.health = self.max_health;
 387
 388                 self.SendFlags |= MSF_MOVE;
 389                 self.SendFlags |= MSF_STATUS;
 390         }
 391         else
 392                 SUB_SetFade(self, time + 3, 1);
 393 }
 394
 395 float Monster_CanJump (vector vel)
 396 {
 397         if(self.state)
 398                 return FALSE; // already attacking
 399         if not(self.flags & FL_ONGROUND)
 400                 return FALSE; // not on the ground
 401         if(self.health <= 0)
 402                 return FALSE; // called when dead?
 403         if(time < self.attack_finished_single)
 404                 return FALSE; // still attacking
 405
 406         vector old = self.velocity;
 407
 408         self.velocity = vel;
 409         tracetoss(self, self);
 410         self.velocity = old;
 411         if (trace_ent != self.enemy)
 412                 return FALSE;
 413
 414         return TRUE;
 415 }
 416
 417 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 418 {
 419         if(!Monster_CanJump(vel))
 420                 return FALSE;
 421
 422         monsters_setframe(anm);
 423         self.state = MONSTER_STATE_ATTACK_LEAP;
 424         self.touch = touchfunc;
 425         self.origin_z += 1;
 426         self.velocity = vel;
 427         self.flags &= ~FL_ONGROUND;
 428
 429         self.attack_finished_single = time + anim_finished;
 430
 431         return TRUE;
 432 }
 433
 434 void monster_checkattack(entity e, entity targ)
 435 {
 436         if(e == world)
 437                 return;
 438         if(targ == world)
 439                 return;
 440
 441         if not(e.monster_attackfunc)
 442                 return;
 443
 444         if(time < e.attack_finished_single)
 445                 return;
 446
 447         if(vlen(targ.origin - e.origin) <= e.attack_range)
 448         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 449         {
 450                 //monster_sound(e.msound_attack_melee, 0, FALSE);
 451                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 452                 return;
 453         }
 454
 455         if(vlen(targ.origin - e.origin) > e.attack_range)
 456         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 457         {
 458                 //monster_sound(e.msound_attack_ranged, 0, FALSE);
 459                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 460                 return;
 461         }
 462 }
 463
 464 void monster_use ()
 465 {
 466         if not(self.enemy)
 467         if(self.health > 0)
 468         if(monster_isvalidtarget(activator, self))
 469                 self.enemy = activator;
 470 }
 471
 472 .float last_trace;
 473 .float last_enemycheck; // for checking enemy
 474 vector monster_pickmovetarget(entity targ)
 475 {
 476         // enemy is always preferred target
 477         if(self.enemy)
 478         {
 479                 makevectors(self.angles);
 480                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 481                 self.last_trace = time + 1.2;
 482                 return self.enemy.origin;
 483         }
 484
 485         switch(self.monster_moveflags)
 486         {
 487                 case MONSTER_MOVE_OWNER:
 488                 {
 489                         self.monster_movestate = MONSTER_MOVE_OWNER;
 490                         self.last_trace = time + 0.3;
 491                         if(self.monster_owner)
 492                                 return self.monster_owner.origin;
 493                 }
 494                 case MONSTER_MOVE_SPAWNLOC:
 495                 {
 496                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 497                         self.last_trace = time + 2;
 498                         return self.pos1;
 499                 }
 500                 case MONSTER_MOVE_NOMOVE:
 501                 {
 502                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 503                         self.last_trace = time + 2;
 504                         return self.origin;
 505                 }
 506                 default:
 507                 case MONSTER_MOVE_WANDER:
 508                 {
 509                         vector pos;
 510                         self.monster_movestate = MONSTER_MOVE_WANDER;
 511                         self.last_trace = time + 2;
 512
 513                         self.angles_y = rint(random() * 500);
 514                         makevectors(self.angles);
 515                         pos = self.origin + v_forward * 600;
 516
 517                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 518                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 519                         {
 520                                 pos_z = random() * 200;
 521                                 if(random() >= 0.5)
 522                                         pos_z *= -1;
 523                         }
 524
 525                         if(targ)
 526                         {
 527                                 self.last_trace = time + 0.5;
 528                                 pos = targ.origin;
 529                         }
 530
 531                         return pos;
 532                 }
 533         }
 534 }
 535
 536 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 537 {
 538         fixedmakevectors(self.angles);
 539
 540         if(self.target2)
 541                 self.goalentity = find(world, targetname, self.target2);
 542
 543         entity targ;
 544
 545         if(self.frozen)
 546         {
 547                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 548                 self.health = max(1, self.max_health * self.revive_progress);
 549
 550                 self.SendFlags |= MSF_STATUS;
 551
 552                 movelib_beak_simple(stopspeed);
 553
 554                 self.velocity = '0 0 0';
 555                 self.enemy = world;
 556                 self.nextthink = time + 0.1;
 557
 558                 if(self.revive_progress >= 1)
 559                         Unfreeze(self); // wait for next think before attacking
 560
 561                 // don't bother updating angles here?
 562                 if(self.origin != self.oldorigin)
 563                 {
 564                         self.oldorigin = self.origin;
 565                         self.SendFlags |= MSF_MOVE;
 566                 }
 567
 568                 return; // no moving while frozen
 569         }
 570
 571         if(self.flags & FL_SWIM)
 572         {
 573                 if(self.waterlevel < WATERLEVEL_WETFEET)
 574                 {
 575                         if(time >= self.last_trace)
 576                         {
 577                                 self.fish_wasdrowning = TRUE;
 578                                 self.last_trace = time + 0.4;
 579
 580                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 581                                 self.angles = '90 90 0';
 582                                 if(random() < 0.5)
 583                                 {
 584                                         self.velocity_y += random() * 50;
 585                                         self.velocity_x -= random() * 50;
 586                                 }
 587                                 else
 588                                 {
 589                                         self.velocity_y -= random() * 50;
 590                                         self.velocity_x += random() * 50;
 591                                 }
 592                                 self.velocity_z += random() * 150;
 593                         }
 594
 595
 596                         self.movetype = MOVETYPE_BOUNCE;
 597                         //self.velocity_z = -200;
 598
 599                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 600
 601                         return;
 602                 }
 603                 else if(self.fish_wasdrowning)
 604                 {
 605                         self.fish_wasdrowning = FALSE;
 606                         self.angles_x = 0;
 607                         self.movetype = MOVETYPE_WALK;
 608                 }
 609         }
 610
 611         targ = self.goalentity;
 612
 613         monster_target = targ;
 614         monster_speed_run = runspeed;
 615         monster_speed_walk = walkspeed;
 616
 617         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 618         {
 619                 runspeed = walkspeed = 0;
 620                 if(time >= self.spawn_time)
 621                         monsters_setframe(manim_idle);
 622                 movelib_beak_simple(stopspeed);
 623                 if(self.oldorigin != self.origin)
 624                 {
 625                         self.oldorigin = self.origin;
 626                         self.SendFlags |= MSF_MOVE;
 627                 }
 628                 return;
 629         }
 630
 631         targ = monster_target;
 632         runspeed = monster_speed_run;
 633         walkspeed = monster_speed_walk;
 634
 635         if(teamplay)
 636         if(autocvar_g_monsters_teams)
 637         if(IsDifferentTeam(self.monster_owner, self))
 638                 self.monster_owner = world;
 639
 640         if(self.enemy && self.enemy.health < 1)
 641                 self.enemy = world; // enough!
 642
 643         if(time >= self.last_enemycheck)
 644         {
 645                 if not(monster_isvalidtarget(self.enemy, self))
 646                         self.enemy = world;
 647
 648                 if not(self.enemy)
 649                 {
 650                         self.enemy = FindTarget(self);
 651                         if(self.enemy)
 652                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 653                                 //monster_sound(self.msound_sight, 0, FALSE);
 654                 }
 655
 656                 self.last_enemycheck = time + 2;
 657         }
 658
 659         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 660                 self.state = 0;
 661
 662         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 663         if(time >= self.last_trace || self.enemy) // update enemy instantly
 664                 self.moveto = monster_pickmovetarget(targ);
 665
 666         if not(self.enemy)
 667                 MonsterSound(monstersound_idle, 5, TRUE, CH_VOICE);
 668                 //monster_sound(self.msound_idle, 5, TRUE);
 669
 670         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 671                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 672
 673         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 674         {
 675                 self.state = 0;
 676                 self.touch = MonsterTouch;
 677         }
 678
 679         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 680
 681         float turny = 0;
 682         vector real_angle = vectoangles(self.steerto) - self.angles;
 683
 684         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 685                 turny = 20;
 686
 687         if(self.flags & FL_SWIM)
 688                 turny = vlen(self.angles - self.moveto);
 689
 690         if(turny)
 691         {
 692                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 693                 self.angles_y += turny;
 694         }
 695
 696         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 697                 self.moveto = self.origin;
 698
 699         if(self.enemy && self.enemy.vehicle)
 700                 runspeed = 0;
 701
 702         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 703                 v_forward = normalize(self.moveto - self.origin);
 704         else
 705                 self.moveto_z = self.origin_z;
 706
 707         if(vlen(self.origin - self.moveto) > 64)
 708         {
 709                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 710                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 711                 else
 712                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 713
 714                 if(time > self.pain_finished)
 715                 if(time > self.attack_finished_single)
 716                 if(vlen(self.velocity) > 10)
 717                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 718                 else
 719                         monsters_setframe(manim_idle);
 720         }
 721         else
 722         {
 723                 entity e = find(world, targetname, self.target2);
 724                 if(e.target2)
 725                         self.target2 = e.target2;
 726                 else if(e.target)
 727                         self.target2 = e.target;
 728
 729                 movelib_beak_simple(stopspeed);
 730                 if(time > self.attack_finished_single)
 731                 if(time > self.pain_finished)
 732                 if (vlen(self.velocity) <= 30)
 733                         monsters_setframe(manim_idle);
 734         }
 735
 736         monster_checkattack(self, self.enemy);
 737
 738         if(self.angles != self.oldangles)
 739         {
 740                 self.oldangles = self.angles;
 741                 self.SendFlags |= MSF_ANG;
 742         }
 743
 744         if(self.origin != self.oldorigin)
 745         {
 746                 self.oldorigin = self.origin;
 747                 self.SendFlags |= MSF_MOVE;
 748         }
 749 }
 750
 751 void monster_dead_think()
 752 {
 753         self.think = monster_dead_think;
 754         self.nextthink = time + 0.3; // don't need to update so often now
 755
 756         self.deadflag = DEAD_DEAD;
 757
 758         if(self.ltime != 0)
 759         if(time >= self.ltime)
 760         {
 761                 Monster_Fade();
 762                 return;
 763         }
 764
 765         if(self.oldorigin != self.origin)
 766         {
 767                 self.oldorigin = self.origin;
 768                 self.SendFlags |= MSF_MOVE;
 769         }
 770 }
 771
 772 void monsters_setstatus()
 773 {
 774         self.stat_monsters_total = monsters_total;
 775         self.stat_monsters_killed = monsters_killed;
 776 }
 777
 778 void Monster_Appear()
 779 {
 780         self.enemy = activator;
 781         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 782         self.monster_spawnfunc();
 783 }
 784
 785 float Monster_CheckAppearFlags(entity ent)
 786 {
 787         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 788                 return FALSE;
 789
 790         ent.think = func_null;
 791         ent.nextthink = 0;
 792         ent.use = Monster_Appear;
 793         ent.flags = FL_MONSTER; // set so this monster can get butchered
 794
 795         return TRUE;
 796 }
 797
 798 void monsters_reset()
 799 {
 800         setorigin(self, self.pos1);
 801         self.angles = self.pos2;
 802
 803         self.health = self.max_health;
 804         self.velocity = '0 0 0';
 805         self.enemy = world;
 806         self.goalentity = world;
 807         self.attack_finished_single = 0;
 808         self.moveto = self.origin;
 809
 810         self.SendFlags |= MSF_STATUS;
 811 }
 812
 813 float monster_send(entity to, float sf)
 814 {
 815         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 816         WriteByte(MSG_ENTITY, sf);
 817         if(sf & MSF_SETUP)
 818         {
 819             WriteByte(MSG_ENTITY, self.monsterid);
 820
 821             WriteCoord(MSG_ENTITY, self.origin_x);
 822             WriteCoord(MSG_ENTITY, self.origin_y);
 823             WriteCoord(MSG_ENTITY, self.origin_z);
 824
 825             WriteAngle(MSG_ENTITY, self.angles_x);
 826             WriteAngle(MSG_ENTITY, self.angles_y);
 827
 828                 WriteByte(MSG_ENTITY, self.skin);
 829                 WriteByte(MSG_ENTITY, self.team);
 830     }
 831
 832     if(sf & MSF_ANG)
 833     {
 834         WriteShort(MSG_ENTITY, rint(self.angles_x));
 835         WriteShort(MSG_ENTITY, rint(self.angles_y));
 836     }
 837
 838     if(sf & MSF_MOVE)
 839     {
 840         WriteShort(MSG_ENTITY, rint(self.origin_x));
 841         WriteShort(MSG_ENTITY, rint(self.origin_y));
 842         WriteShort(MSG_ENTITY, rint(self.origin_z));
 843
 844         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 845         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 846         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 847
 848         WriteShort(MSG_ENTITY, rint(self.angles_y));
 849     }
 850
 851     if(sf & MSF_ANIM)
 852     {
 853         WriteCoord(MSG_ENTITY, self.anim_start_time);
 854         WriteByte(MSG_ENTITY, self.frame);
 855     }
 856
 857     if(sf & MSF_STATUS)
 858     {
 859                 WriteByte(MSG_ENTITY, self.skin);
 860
 861         WriteByte(MSG_ENTITY, self.team);
 862
 863                 WriteByte(MSG_ENTITY, self.deadflag);
 864
 865         if(self.health <= 0)
 866             WriteByte(MSG_ENTITY, 0);
 867         else
 868             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 869     }
 870
 871         return TRUE;
 872 }
 873
 874 void monster_link(void() spawnproc)
 875 {
 876     Net_LinkEntity(self, TRUE, 0, monster_send);
 877     self.think      = spawnproc;
 878     self.nextthink  = time;
 879 }
 880
 881 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 882 {
 883         self.health -= damage;
 884
 885         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 886
 887         if(self.health <= -100) // 100 health until gone?
 888         {
 889                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 890
 891                 self.think = SUB_Remove;
 892                 self.nextthink = time + 0.1;
 893         }
 894 }
 895
 896 void monster_die()
 897 {
 898         self.think = monster_dead_think;
 899         self.nextthink = self.ticrate;
 900         self.ltime = time + 5;
 901
 902         monster_dropitem();
 903
 904         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 905         //monster_sound(self.msound_death, 0, FALSE);
 906
 907         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 908                 monsters_killed += 1;
 909
 910         if(self.candrop && self.weapon)
 911                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 912
 913         if(IS_CLIENT(self.realowner))
 914                 self.realowner.monstercount -= 1;
 915
 916         self.event_damage       = monsters_corpse_damage;
 917         self.solid                      = SOLID_CORPSE;
 918         self.takedamage         = DAMAGE_AIM;
 919         self.enemy                      = world;
 920         self.movetype           = MOVETYPE_TOSS;
 921         self.moveto                     = self.origin;
 922         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 923
 924         if not(self.flags & FL_FLY)
 925                 self.velocity = '0 0 0';
 926
 927         self.SendFlags |= MSF_MOVE;
 928
 929         // number of monsters spawned with mobspawn command
 930         totalspawned -= 1;
 931
 932         MON_ACTION(self.monsterid, MR_DEATH);
 933 }
 934
 935 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 936 {
 937         if(self.frozen && deathtype != DEATH_KILL)
 938                 return;
 939
 940         if(time < self.pain_finished && deathtype != DEATH_KILL)
 941                 return;
 942
 943         if(time < self.spawnshieldtime)
 944                 return;
 945
 946         vector v;
 947         float take, save;
 948
 949         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, damage);
 950         take = v_x;
 951         save = v_y;
 952
 953         self.health -= take;
 954
 955         self.dmg_time = time;
 956
 957         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 958                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 959
 960         self.velocity += force * self.damageforcescale;
 961
 962         if(deathtype != DEATH_DROWN)
 963         {
 964                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 965                 if (take > 50)
 966                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 967                 if (take > 100)
 968                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 969         }
 970
 971         if(self.health <= 0)
 972         {
 973                 if(deathtype == DEATH_KILL)
 974                         self.candrop = FALSE; // killed by mobkill command
 975
 976                 // TODO: fix this?
 977                 activator = attacker;
 978                 other = self.enemy;
 979                 SUB_UseTargets();
 980                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 981
 982                 monster_die();
 983
 984                 frag_attacker = attacker;
 985                 frag_target = self;
 986                 MUTATOR_CALLHOOK(MonsterDies);
 987
 988                 if(self.health <= -100) // check if we're already gibbed
 989                 {
 990                         Violence_GibSplash(self, 1, 0.5, attacker);
 991
 992                         self.think = SUB_Remove;
 993                         self.nextthink = time + 0.1;
 994                 }
 995         }
 996
 997         self.SendFlags |= MSF_STATUS;
 998 }
 999
1000 void monster_think()
1001 {
1002         self.think = monster_think;
1003         self.nextthink = self.ticrate;
1004
1005         MON_ACTION(self.monsterid, MR_THINK);
1006 }
1007
1008 void monster_spawn()
1009 {
1010         MON_ACTION(self.monsterid, MR_SETUP);
1011
1012         if not(self.monster_respawned)
1013                 Monster_CheckMinibossFlag();
1014
1015         self.max_health = self.health;
1016         self.pain_finished = self.nextthink;
1017         self.anim_start_time = time;
1018
1019         if not(self.noalign)
1020         {
1021                 setorigin(self, self.origin + '0 0 20');
1022                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1023                 setorigin(self, trace_endpos);
1024         }
1025
1026         if not(self.monster_respawned)
1027         if not(self.skin)
1028                 self.skin = rint(random() * 4);
1029
1030         if not(self.attack_range)
1031                 self.attack_range = autocvar_g_monsters_attack_range;
1032
1033         self.pos1 = self.origin;
1034
1035         //monster_setupsounds(self.netname);
1036         precache_monstersounds();
1037         UpdateMonsterSounds();
1038         //monster_precachesounds(self);
1039
1040         if(teamplay)
1041                 self.monster_attack = TRUE; // we can have monster enemies in team games
1042
1043         //monster_sound(self.msound_spawn, 0, FALSE);
1044         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
1045
1046         self.think = monster_think;
1047         self.nextthink = time + self.ticrate;
1048
1049         self.SendFlags |= MSF_SETUP;
1050
1051         MUTATOR_CALLHOOK(MonsterSpawn);
1052 }
1053
1054 float monster_initialize(float mon_id, float nodrop)
1055 {
1056         if not(autocvar_g_monsters)
1057                 return FALSE;
1058
1059         entity mon = get_monsterinfo(mon_id);
1060
1061         // support for quake style removing monsters based on skill
1062         switch(monster_skill)
1063         {
1064                 case 0:
1065                 case 1: if(self.spawnflags & MONSTERSKILL_NOTEASY)              return FALSE; break;
1066                 case 2: if(self.spawnflags & MONSTERSKILL_NOTMEDIUM)    return FALSE; break;
1067                 default:
1068                 case 3: if(self.spawnflags & MONSTERSKILL_NOTHARD)              return FALSE; break;
1069         }
1070
1071         if(self.team && !teamplay)
1072                 self.team = 0;
1073
1074         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
1075         if not(self.monster_respawned)
1076                 monsters_total += 1;
1077
1078         setsize(self, mon.mins, mon.maxs);
1079         self.flags                              = FL_MONSTER;
1080         self.takedamage                 = DAMAGE_AIM;
1081         self.bot_attack                 = TRUE;
1082         self.iscreature                 = TRUE;
1083         self.teleportable               = TRUE;
1084         self.damagedbycontents  = TRUE;
1085         self.monsterid                  = mon_id;
1086         self.damageforcescale   = 0;
1087         self.event_damage               = monsters_damage;
1088         self.touch                              = MonsterTouch;
1089         self.use                                = monster_use;
1090         self.solid                              = SOLID_BBOX;
1091         self.movetype                   = MOVETYPE_WALK;
1092         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1093         self.enemy                              = world;
1094         self.velocity                   = '0 0 0';
1095         self.moveto                             = self.origin;
1096         self.pos2                               = self.angles;
1097         self.reset                              = monsters_reset;
1098         self.netname                    = mon.netname;
1099         self.monster_name               = M_NAME(mon_id);
1100         self.candrop                    = TRUE;
1101         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1102         self.oldtarget2                 = self.target2;
1103         self.deadflag                   = DEAD_NO;
1104         self.scale                              = 1;
1105         self.noalign                    = nodrop;
1106         self.spawn_time                 = time;
1107         self.gravity                    = 1;
1108         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1109
1110         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1111                 self.flags |= FL_SWIM;
1112
1113         if(mon.spawnflags & MONSTER_TYPE_FLY)
1114         {
1115                 self.flags |= FL_FLY;
1116                 self.movetype = MOVETYPE_FLY;
1117         }
1118
1119         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1120                 self.scale = 1.3;
1121
1122         if not(self.ticrate)
1123                 self.ticrate = autocvar_g_monsters_think_delay;
1124
1125         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1126
1127         if not(self.m_armor_blockpercent)
1128                 self.m_armor_blockpercent = 0.5;
1129
1130         if not(self.target_range)
1131                 self.target_range = autocvar_g_monsters_target_range;
1132
1133         if not(self.respawntime)
1134                 self.respawntime = autocvar_g_monsters_respawn_delay;
1135
1136         if not(self.monster_moveflags)
1137                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1138
1139         monster_link(monster_spawn);
1140
1141         return TRUE;
1142 }