qcsrc/common/monsters/monster/spider.qc

   1 #include "spider.qh"
   2
   3 #ifdef SVQC
   4
   5 .float spider_slowness; // effect time of slowness inflicted by spiders
   6
   7 .float spider_web_delay;
   8
   9 float autocvar_g_monster_spider_attack_web_damagetime;
  10 float autocvar_g_monster_spider_attack_web_speed;
  11 float autocvar_g_monster_spider_attack_web_speed_up;
  12 float autocvar_g_monster_spider_attack_web_delay;
  13
  14 float autocvar_g_monster_spider_attack_bite_damage;
  15 float autocvar_g_monster_spider_attack_bite_delay;
  16
  17 void M_Spider_Attack_Web(entity this);
  18
  19 REGISTER_MUTATOR(spiderweb, true);
  20
  21 MUTATOR_HOOKFUNCTION(spiderweb, PlayerPhysics_UpdateStats)
  22 {
  23         entity player = M_ARGV(0, entity);
  24
  25         if(time < player.spider_slowness)
  26                 STAT(MOVEVARS_HIGHSPEED, player) *= 0.5;
  27 }
  28
  29 MUTATOR_HOOKFUNCTION(spiderweb, MonsterMove)
  30 {
  31     entity mon = M_ARGV(0, entity);
  32
  33         if(time < mon.spider_slowness)
  34         {
  35                 M_ARGV(1, float) *= 0.5; // run speed
  36                 M_ARGV(2, float) *= 0.5; // walk speed
  37         }
  38 }
  39
  40 MUTATOR_HOOKFUNCTION(spiderweb, PlayerSpawn)
  41 {
  42         entity player = M_ARGV(0, entity);
  43
  44         player.spider_slowness = 0;
  45         return false;
  46 }
  47
  48 MUTATOR_HOOKFUNCTION(spiderweb, MonsterSpawn)
  49 {
  50     entity mon = M_ARGV(0, entity);
  51
  52         mon.spider_slowness = 0;
  53 }
  54
  55 SOUND(SpiderAttack_FIRE, W_Sound("electro_fire"));
  56 METHOD(SpiderAttack, wr_think, void(SpiderAttack thiswep, entity actor, .entity weaponentity, int fire))
  57 {
  58     TC(SpiderAttack, thiswep);
  59     bool isPlayer = IS_PLAYER(actor);
  60     if (fire & 1)
  61     if ((!isPlayer && time >= actor.spider_web_delay) || weapon_prepareattack(thiswep, actor, weaponentity, false, autocvar_g_monster_spider_attack_web_delay)) {
  62                 if (!isPlayer) {
  63                         actor.spider_web_delay = time + 3;
  64                         setanim(actor, actor.anim_shoot, true, true, true);
  65                         actor.attack_finished_single[0] = time + (autocvar_g_monster_spider_attack_web_delay);
  66                         actor.anim_finished = time + 1;
  67                 }
  68         if (isPlayer) actor.enemy = Monster_FindTarget(actor);
  69         monster_makevectors(actor, actor.enemy);
  70         W_SetupShot_Dir(actor, weaponentity, v_forward, false, 0, SND_SpiderAttack_FIRE, CH_WEAPON_B, 0, DEATH_MONSTER_SPIDER.m_id);
  71         if (!isPlayer) w_shotdir = normalize((actor.enemy.origin + '0 0 10') - actor.origin);
  72                 M_Spider_Attack_Web(actor);
  73         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, w_ready);
  74         return;
  75     }
  76     if (fire & 2)
  77     if (!isPlayer || weapon_prepareattack(thiswep, actor, weaponentity, true, 0.5)) {
  78         if (isPlayer) {
  79                 actor.enemy = Monster_FindTarget(actor);
  80                 actor.attack_range = 60;
  81         }
  82         Monster_Attack_Melee(actor, actor.enemy, (autocvar_g_monster_spider_attack_bite_damage), ((random() > 0.5) ? actor.anim_melee : actor.anim_shoot), actor.attack_range, (autocvar_g_monster_spider_attack_bite_delay), DEATH_MONSTER_SPIDER.m_id, true);
  83         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, 0, w_ready);
  84     }
  85 }
  86
  87 float autocvar_g_monster_spider_health;
  88 float autocvar_g_monster_spider_damageforcescale = 0.6;
  89 float autocvar_g_monster_spider_speed_stop;
  90 float autocvar_g_monster_spider_speed_run;
  91 float autocvar_g_monster_spider_speed_walk;
  92
  93 /*
  94 const float spider_anim_idle            = 0;
  95 const float spider_anim_walk            = 1;
  96 const float spider_anim_attack          = 2;
  97 const float spider_anim_attack2         = 3;
  98 */
  99
 100 void M_Spider_Attack_Web_Explode(entity this)
 101 {
 102         if(this)
 103         {
 104                 Send_Effect(EFFECT_ELECTRO_IMPACT, this.origin, '0 0 0', 1);
 105                 RadiusDamage(this, this.realowner, 0, 0, 25, NULL, NULL, 25, this.projectiledeathtype, DMG_NOWEP, NULL);
 106
 107                 FOREACH_ENTITY_RADIUS(this.origin, 25, it != this && it.takedamage && !IS_DEAD(it) && GetResource(it, RES_HEALTH) > 0 && it.monsterdef != MON_SPIDER,
 108                 {
 109                         it.spider_slowness = time + (autocvar_g_monster_spider_attack_web_damagetime);
 110                 });
 111
 112                 delete(this);
 113         }
 114 }
 115
 116 void M_Spider_Attack_Web_Explode_use(entity this, entity actor, entity trigger)
 117 {
 118         M_Spider_Attack_Web_Explode(this);
 119 }
 120
 121 void M_Spider_Attack_Web_Touch(entity this, entity toucher)
 122 {
 123         PROJECTILE_TOUCH(this, toucher);
 124
 125         M_Spider_Attack_Web_Explode(this);
 126 }
 127
 128 void M_Spider_Attack_Web(entity this)
 129 {
 130         sound(this, CH_SHOTS, SND_ELECTRO_FIRE2, VOL_BASE, ATTEN_NORM);
 131
 132         entity proj = new(plasma);
 133         proj.owner = proj.realowner = this;
 134         proj.use = M_Spider_Attack_Web_Explode_use;
 135         setthink(proj, adaptor_think2use_hittype_splash);
 136         proj.bot_dodge = true;
 137         proj.bot_dodgerating = 0;
 138         proj.nextthink = time + 5;
 139         PROJECTILE_MAKETRIGGER(proj);
 140         proj.projectiledeathtype = DEATH_MONSTER_SPIDER.m_id;
 141         setorigin(proj, CENTER_OR_VIEWOFS(this));
 142
 143         //proj.glow_size = 50;
 144         //proj.glow_color = 45;
 145         set_movetype(proj, MOVETYPE_BOUNCE);
 146         W_SetupProjVelocity_Explicit(proj, v_forward, v_up, (autocvar_g_monster_spider_attack_web_speed), (autocvar_g_monster_spider_attack_web_speed_up), 0, 0, false);
 147         settouch(proj, M_Spider_Attack_Web_Touch);
 148         setsize(proj, '-4 -4 -4', '4 4 4');
 149         proj.takedamage = DAMAGE_NO;
 150         proj.damageforcescale = 0;
 151         SetResourceExplicit(proj, RES_HEALTH, 500);
 152         proj.event_damage = func_null;
 153         proj.flags = FL_PROJECTILE;
 154         IL_PUSH(g_projectiles, proj);
 155         IL_PUSH(g_bot_dodge, proj);
 156         proj.damagedbycontents = true;
 157         IL_PUSH(g_damagedbycontents, proj);
 158
 159         proj.bouncefactor = 0.3;
 160         proj.bouncestop = 0.05;
 161         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 162
 163         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, true);
 164 }
 165
 166 bool M_Spider_Attack(int attack_type, entity actor, entity targ, .entity weaponentity)
 167 {
 168         Weapon wep = WEP_SPIDER_ATTACK;
 169         switch(attack_type)
 170         {
 171                 case MONSTER_ATTACK_MELEE:
 172                 {
 173                         wep.wr_think(wep, actor, weaponentity, 2);
 174                         return true;
 175                 }
 176                 case MONSTER_ATTACK_RANGED:
 177                 {
 178                         wep.wr_think(wep, actor, weaponentity, 1);
 179                         return true;
 180                 }
 181         }
 182
 183         return false;
 184 }
 185
 186 spawnfunc(monster_spider) { Monster_Spawn(this, true, MON_SPIDER); }
 187 #endif // SVQC
 188
 189 #ifdef SVQC
 190 METHOD(Spider, mr_think, bool(Spider this, entity actor))
 191 {
 192     TC(Spider, this);
 193     return true;
 194 }
 195
 196 METHOD(Spider, mr_pain, float(Spider this, entity actor, float damage_take, entity attacker, float deathtype))
 197 {
 198     TC(Spider, this);
 199     return damage_take;
 200 }
 201
 202 METHOD(Spider, mr_death, bool(Spider this, entity actor))
 203 {
 204     TC(Spider, this);
 205     setanim(actor, actor.anim_melee, false, true, true);
 206     actor.angles_x = 180;
 207     return true;
 208 }
 209 #endif
 210 #ifdef GAMEQC
 211 METHOD(Spider, mr_anim, bool(Spider this, entity actor))
 212 {
 213     TC(Spider, this);
 214     vector none = '0 0 0';
 215     actor.anim_walk = animfixfps(actor, '1 1 1', none);
 216     actor.anim_idle = animfixfps(actor, '0 1 1', none);
 217     actor.anim_melee = animfixfps(actor, '2 1 5', none); // analyze models and set framerate
 218     actor.anim_shoot = animfixfps(actor, '3 1 5', none); // analyze models and set framerate
 219     actor.anim_run = animfixfps(actor, '1 1 1', none);
 220     return true;
 221 }
 222 #endif
 223 #ifdef SVQC
 224 METHOD(Spider, mr_setup, bool(Spider this, entity actor))
 225 {
 226     TC(Spider, this);
 227     if(!GetResource(this, RES_HEALTH)) SetResourceExplicit(actor, RES_HEALTH, autocvar_g_monster_spider_health);
 228     if(!actor.speed) { actor.speed = (autocvar_g_monster_spider_speed_walk); }
 229     if(!actor.speed2) { actor.speed2 = (autocvar_g_monster_spider_speed_run); }
 230     if(!actor.stopspeed) { actor.stopspeed = (autocvar_g_monster_spider_speed_stop); }
 231     if(!actor.damageforcescale) { actor.damageforcescale = (autocvar_g_monster_spider_damageforcescale); }
 232
 233     actor.monster_loot = ITEM_HealthMedium;
 234     actor.monster_attackfunc = M_Spider_Attack;
 235
 236     return true;
 237 }
 238 #endif