qcsrc/common/monsters/monster/shambler.qc

   1 CLASS(Shambler, Monster)
   2     ATTRIB(Shambler, spawnflags, int, MONSTER_SIZE_BROKEN | MON_FLAG_SUPERMONSTER | MON_FLAG_MELEE | MON_FLAG_RANGED);
   3     ATTRIB(Shambler, mins, vector, '-41 -41 -31');
   4     ATTRIB(Shambler, maxs, vector, '41 41 65');
   5     ATTRIB(Shambler, mdl, string, "shambler.mdl");
   6     ATTRIB(Shambler, model, string, strzone(strcat("models/monsters/", this.mdl)));
   7     ATTRIB(Shambler, netname, string, "shambler");
   8     ATTRIB(Shambler, monster_name, string, _("Shambler"));
   9 ENDCLASS(Shambler)
  10
  11 REGISTER_MONSTER(SHAMBLER, NEW(Shambler)) {
  12 #ifndef MENUQC
  13     MON_ACTION(this, MR_PRECACHE);
  14 #endif
  15 }
  16
  17 #ifdef SVQC
  18 float autocvar_g_monster_shambler_health;
  19 float autocvar_g_monster_shambler_damageforcescale = 0.1;
  20 float autocvar_g_monster_shambler_attack_smash_damage;
  21 float autocvar_g_monster_shambler_attack_smash_range;
  22 float autocvar_g_monster_shambler_attack_claw_damage;
  23 float autocvar_g_monster_shambler_attack_lightning_damage;
  24 float autocvar_g_monster_shambler_attack_lightning_damage_zap = 15;
  25 float autocvar_g_monster_shambler_attack_lightning_force;
  26 float autocvar_g_monster_shambler_attack_lightning_radius;
  27 float autocvar_g_monster_shambler_attack_lightning_radius_zap;
  28 float autocvar_g_monster_shambler_attack_lightning_speed;
  29 float autocvar_g_monster_shambler_attack_lightning_speed_up;
  30 float autocvar_g_monster_shambler_speed_stop;
  31 float autocvar_g_monster_shambler_speed_run;
  32 float autocvar_g_monster_shambler_speed_walk;
  33
  34 /*
  35 const float shambler_anim_stand         = 0;
  36 const float shambler_anim_walk          = 1;
  37 const float shambler_anim_run           = 2;
  38 const float shambler_anim_smash         = 3;
  39 const float shambler_anim_swingr        = 4;
  40 const float shambler_anim_swingl        = 5;
  41 const float shambler_anim_magic         = 6;
  42 const float shambler_anim_pain          = 7;
  43 const float shambler_anim_death         = 8;
  44 */
  45
  46 .float shambler_lastattack; // delay attacks separately
  47
  48 void M_Shambler_Attack_Smash()
  49 {SELFPARAM();
  50         makevectors(self.angles);
  51         Send_Effect(EFFECT_EXPLOSION_MEDIUM, (self.origin + (v_forward * 150)) - ('0 0 1' * self.maxs.z), '0 0 0', 1);
  52         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
  53
  54         // RadiusDamage does NOT support custom starting location, which means we must use this hack...
  55
  56         tracebox(self.origin + v_forward * 50, self.mins * 0.5, self.maxs * 0.5, self.origin + v_forward * autocvar_g_monster_shambler_attack_smash_range, MOVE_NORMAL, self);
  57
  58         if(trace_ent.takedamage)
  59                 Damage(trace_ent, self, self, (autocvar_g_monster_shambler_attack_smash_damage) * MONSTER_SKILLMOD(self), DEATH_MONSTER_SHAMBLER_SMASH, trace_ent.origin, normalize(trace_ent.origin - self.origin));
  60 }
  61
  62 void M_Shambler_Attack_Swing()
  63 {SELFPARAM();
  64         float r = (random() < 0.5);
  65         if(r && Monster_Attack_Melee(self.enemy, (autocvar_g_monster_shambler_attack_claw_damage), ((r) ? self.anim_melee2 : self.anim_melee3), self.attack_range, 0.8, DEATH_MONSTER_SHAMBLER_CLAW, true))
  66         {
  67                 Monster_Delay(1, 0, 0.5, M_Shambler_Attack_Swing);
  68                 self.attack_finished_single += 0.5;
  69                 self.anim_finished = self.attack_finished_single;
  70         }
  71 }
  72
  73 void M_Shambler_Attack_Lightning_Explode()
  74 {SELFPARAM();
  75         entity head;
  76
  77         sound(self, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
  78         Send_Effect(EFFECT_ELECTRO_IMPACT, '0 0 0', '0 0 0', 1);
  79
  80         self.event_damage = func_null;
  81         self.takedamage = DAMAGE_NO;
  82         self.movetype = MOVETYPE_NONE;
  83         self.velocity = '0 0 0';
  84
  85         if(self.movetype == MOVETYPE_NONE)
  86                 self.velocity = self.oldvelocity;
  87
  88         RadiusDamage (self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_radius), world, world, (autocvar_g_monster_shambler_attack_lightning_force), self.projectiledeathtype, other);
  89
  90         for(head = findradius(self.origin, (autocvar_g_monster_shambler_attack_lightning_radius_zap)); head; head = head.chain) if(head != self.realowner) if(head.takedamage)
  91         {
  92                 te_csqc_lightningarc(self.origin, head.origin);
  93                 Damage(head, self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage_zap) * MONSTER_SKILLMOD(self), DEATH_MONSTER_SHAMBLER_ZAP, head.origin, '0 0 0');
  94         }
  95
  96         self.think = SUB_Remove;
  97         self.nextthink = time + 0.2;
  98 }
  99
 100 void M_Shambler_Attack_Lightning_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 101 {SELFPARAM();
 102         if (self.health <= 0)
 103                 return;
 104
 105         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 106                 return; // g_projectiles_damage says to halt
 107
 108         self.health = self.health - damage;
 109
 110         if (self.health <= 0)
 111                 W_PrepareExplosionByDamage(attacker, self.use);
 112 }
 113
 114 void M_Shambler_Attack_Lightning_Touch()
 115 {SELFPARAM();
 116         PROJECTILE_TOUCH;
 117
 118         self.use ();
 119 }
 120
 121 void M_Shambler_Attack_Lightning_Think()
 122 {SELFPARAM();
 123         self.nextthink = time;
 124         if (time > self.cnt)
 125         {
 126                 other = world;
 127                 M_Shambler_Attack_Lightning_Explode();
 128                 return;
 129         }
 130 }
 131
 132 void M_Shambler_Attack_Lightning()
 133 {SELFPARAM();
 134         entity gren;
 135
 136         monster_makevectors(self.enemy);
 137
 138         gren = spawn ();
 139         gren.owner = gren.realowner = self;
 140         gren.classname = "grenade";
 141         gren.bot_dodge = true;
 142         gren.bot_dodgerating = (autocvar_g_monster_shambler_attack_lightning_damage);
 143         gren.movetype = MOVETYPE_BOUNCE;
 144         PROJECTILE_MAKETRIGGER(gren);
 145         gren.projectiledeathtype = DEATH_MONSTER_SHAMBLER_ZAP;
 146         setorigin(gren, CENTER_OR_VIEWOFS(self));
 147         setsize(gren, '-8 -8 -8', '8 8 8');
 148         gren.scale = 2.5;
 149
 150         gren.cnt = time + 5;
 151         gren.nextthink = time;
 152         gren.think = M_Shambler_Attack_Lightning_Think;
 153         gren.use = M_Shambler_Attack_Lightning_Explode;
 154         gren.touch = M_Shambler_Attack_Lightning_Touch;
 155
 156         gren.takedamage = DAMAGE_YES;
 157         gren.health = 50;
 158         gren.damageforcescale = 0;
 159         gren.event_damage = M_Shambler_Attack_Lightning_Damage;
 160         gren.damagedbycontents = true;
 161         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 162         W_SetupProjVelocity_Explicit(gren, v_forward, v_up, (autocvar_g_monster_shambler_attack_lightning_speed), (autocvar_g_monster_shambler_attack_lightning_speed_up), 0, 0, false);
 163
 164         gren.angles = vectoangles (gren.velocity);
 165         gren.flags = FL_PROJECTILE;
 166
 167         CSQCProjectile(gren, true, PROJECTILE_SHAMBLER_LIGHTNING, true);
 168 }
 169
 170 float M_Shambler_Attack(float attack_type)
 171 {SELFPARAM();
 172         switch(attack_type)
 173         {
 174                 case MONSTER_ATTACK_MELEE:
 175                 {
 176                         M_Shambler_Attack_Swing();
 177                         return true;
 178                 }
 179                 case MONSTER_ATTACK_RANGED:
 180                 {
 181                         float randomness = random(), enemy_len = vlen(self.enemy.origin - self.origin);
 182
 183                         if(time >= self.shambler_lastattack) // shambler doesn't attack much
 184                         if(self.flags & FL_ONGROUND)
 185                         if(randomness <= 0.5 && enemy_len <= autocvar_g_monster_shambler_attack_smash_range)
 186                         {
 187                                 setanim(self, self.anim_melee2, true, true, false);
 188                                 Monster_Delay(1, 0, 0.7, M_Shambler_Attack_Smash);
 189                                 self.attack_finished_single = time + 1.1;
 190                                 self.anim_finished = time + 1.1;
 191                                 self.state = MONSTER_ATTACK_MELEE; // kinda a melee attack
 192                                 self.shambler_lastattack = time + 3 + random() * 1.5;
 193                                 return true;
 194                         }
 195                         else if(randomness <= 0.1 && enemy_len >= autocvar_g_monster_shambler_attack_smash_range * 1.5) // small chance, don't want this spammed
 196                         {
 197                                 setanim(self, self.anim_shoot, true, true, false);
 198                                 self.state = MONSTER_ATTACK_MELEE; // maybe we should rename this to something more general
 199                                 self.attack_finished_single = time + 1.1;
 200                                 self.anim_finished = 1.1;
 201                                 self.shambler_lastattack = time + 3 + random() * 1.5;
 202                                 Monster_Delay(1, 0, 0.6, M_Shambler_Attack_Lightning);
 203                                 return true;
 204                         }
 205
 206                         return false;
 207                 }
 208         }
 209
 210         return false;
 211 }
 212
 213 void spawnfunc_monster_shambler() { Monster_Spawn(MON_SHAMBLER.monsterid); }
 214 #endif // SVQC
 215
 216                 #ifdef SVQC
 217                 METHOD(Shambler, mr_think, bool(Shambler thismon))
 218                 {
 219                         return true;
 220                 }
 221                 METHOD(Shambler, mr_pain, bool(Shambler thismon))
 222                 {
 223                         SELFPARAM();
 224                         self.pain_finished = time + 0.5;
 225                         setanim(self, self.anim_pain1, true, true, false);
 226                         return true;
 227                 }
 228                 METHOD(Shambler, mr_death, bool(Shambler thismon))
 229                 {
 230                         SELFPARAM();
 231                         setanim(self, self.anim_die1, false, true, true);
 232                         return true;
 233                 }
 234                 #endif
 235                 #ifndef MENUQC
 236                 METHOD(Shambler, mr_anim, bool(Shambler thismon))
 237                 {
 238                         SELFPARAM();
 239                         vector none = '0 0 0';
 240                         self.anim_die1 = animfixfps(self, '8 1 0.5', none); // 2 seconds
 241                         self.anim_walk = animfixfps(self, '1 1 1', none);
 242                         self.anim_idle = animfixfps(self, '0 1 1', none);
 243                         self.anim_pain1 = animfixfps(self, '7 1 2', none); // 0.5 seconds
 244                         self.anim_melee1 = animfixfps(self, '3 1 5', none); // analyze models and set framerate
 245                         self.anim_melee2 = animfixfps(self, '4 1 5', none); // analyze models and set framerate
 246                         self.anim_melee3 = animfixfps(self, '5 1 5', none); // analyze models and set framerate
 247                         self.anim_shoot = animfixfps(self, '6 1 5', none); // analyze models and set framerate
 248                         self.anim_run = animfixfps(self, '2 1 1', none);
 249
 250                         return true;
 251                 }
 252                 #endif
 253                 #ifdef SVQC
 254                 METHOD(Shambler, mr_setup, bool(Shambler thismon))
 255                 {
 256                         SELFPARAM();
 257                         if(!self.health) self.health = (autocvar_g_monster_shambler_health);
 258                         if(!self.attack_range) self.attack_range = 150;
 259                         if(!self.speed) { self.speed = (autocvar_g_monster_shambler_speed_walk); }
 260                         if(!self.speed2) { self.speed2 = (autocvar_g_monster_shambler_speed_run); }
 261                         if(!self.stopspeed) { self.stopspeed = (autocvar_g_monster_shambler_speed_stop); }
 262                         if(!self.damageforcescale) { self.damageforcescale = (autocvar_g_monster_shambler_damageforcescale); }
 263
 264                         self.monster_loot = spawnfunc_item_health_mega;
 265                         self.weapon = WEP_ELECTRO.m_id; // matches attacks better than WEP_VORTEX
 266
 267                         setanim(self, self.anim_shoot, false, true, true);
 268                         self.spawn_time = self.animstate_endtime;
 269                         self.spawnshieldtime = self.spawn_time;
 270                         self.monster_attackfunc = M_Shambler_Attack;
 271
 272                         return true;
 273                 }
 274                 METHOD(Shambler, mr_precache, bool(Shambler thismon))
 275                 {
 276                         return true;
 277                 }
 278                 #endif