qcsrc/common/monsters/monster/shambler.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SHAMBLER,
   4 /* function   */ m_shambler,
   5 /* spawnflags */ MONSTER_SIZE_BROKEN | MON_FLAG_SUPERMONSTER | MON_FLAG_MELEE | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-41 -41 -31', '41 41 65',
   7 /* model      */ "shambler.mdl",
   8 /* netname    */ "shambler",
   9 /* fullname   */ _("Shambler")
  10 );
  11
  12 #define SHAMBLER_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_smash_damage) \
  15         MON_ADD_CVAR(monster, attack_claw_damage) \
  16         MON_ADD_CVAR(monster, attack_lightning_damage) \
  17         MON_ADD_CVAR(monster, attack_lightning_force) \
  18         MON_ADD_CVAR(monster, attack_lightning_radius) \
  19         MON_ADD_CVAR(monster, attack_lightning_radius_zap) \
  20         MON_ADD_CVAR(monster, attack_lightning_speed) \
  21         MON_ADD_CVAR(monster, attack_lightning_speed_up) \
  22         MON_ADD_CVAR(monster, speed_stop) \
  23         MON_ADD_CVAR(monster, speed_run) \
  24         MON_ADD_CVAR(monster, speed_walk)
  25
  26 #ifdef SVQC
  27 SHAMBLER_SETTINGS(shambler)
  28 #endif // SVQC
  29 #else
  30 #ifdef SVQC
  31 const float shambler_anim_stand         = 0;
  32 const float shambler_anim_walk          = 1;
  33 const float shambler_anim_run           = 2;
  34 const float shambler_anim_smash         = 3;
  35 const float shambler_anim_swingr        = 4;
  36 const float shambler_anim_swingl        = 5;
  37 const float shambler_anim_magic         = 6;
  38 const float shambler_anim_pain          = 7;
  39 const float shambler_anim_death         = 8;
  40
  41 .float shambler_lastattack; // delay attacks separately
  42
  43 void shambler_smash()
  44 {
  45         makevectors(self.angles);
  46         pointparticles(particleeffectnum("explosion_medium"), (self.origin + (v_forward * 150)) - ('0 0 1' * self.maxs_z), '0 0 0', 1);
  47         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
  48
  49         tracebox(self.origin + v_forward * 50, self.mins * 0.5, self.maxs * 0.5, self.origin + v_forward * 500, MOVE_NORMAL, self);
  50
  51         if(trace_ent.takedamage)
  52                 Damage(trace_ent, self, self, MON_CVAR(shambler, attack_smash_damage) * Monster_SkillModifier(), DEATH_MONSTER_SHAMBLER_SMASH, trace_ent.origin, normalize(trace_ent.origin - self.origin));
  53 }
  54
  55 void shambler_swing()
  56 {
  57         float r = (random() < 0.5);
  58         monster_melee(self.enemy, MON_CVAR(shambler, attack_claw_damage), ((r) ? shambler_anim_swingr : shambler_anim_swingl), self.attack_range, 0.8, DEATH_MONSTER_SHAMBLER_CLAW, TRUE);
  59         if(r)
  60         {
  61                 defer(0.5, shambler_swing);
  62                 self.attack_finished_single += 0.5;
  63         }
  64 }
  65
  66 void shambler_lightning_explode()
  67 {
  68         entity head;
  69
  70         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTEN_NORM);
  71         pointparticles(particleeffectnum("electro_impact"), '0 0 0', '0 0 0', 1);
  72
  73         self.event_damage = func_null;
  74         self.takedamage = DAMAGE_NO;
  75         self.movetype = MOVETYPE_NONE;
  76         self.velocity = '0 0 0';
  77         UpdateCSQCProjectile(self);
  78
  79         if(self.movetype == MOVETYPE_NONE)
  80                 self.velocity = self.oldvelocity;
  81
  82         RadiusDamage (self, self.realowner, MON_CVAR(shambler, attack_lightning_damage), MON_CVAR(shambler, attack_lightning_damage), MON_CVAR(shambler, attack_lightning_radius), world, MON_CVAR(shambler, attack_lightning_force), self.projectiledeathtype, other);
  83
  84         for(head = findradius(self.origin, MON_CVAR(shambler, attack_lightning_radius_zap)); head; head = head.chain) if(head != self.realowner)
  85         {
  86                 te_csqc_lightningarc(self.origin, head.origin);
  87                 Damage(head, self, self.realowner, MON_CVAR(shambler, attack_lightning_damage) * Monster_SkillModifier(), DEATH_MONSTER_SHAMBLER_ZAP, head.origin, '0 0 0');
  88         }
  89
  90         self.think = SUB_Remove;
  91         self.nextthink = time + 0.2;
  92 }
  93
  94 void shambler_lightning_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  95 {
  96         if (self.health <= 0)
  97                 return;
  98
  99         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 100                 return; // g_projectiles_damage says to halt
 101
 102         self.health = self.health - damage;
 103
 104         if (self.health <= 0)
 105                 W_PrepareExplosionByDamage(attacker, self.use);
 106 }
 107
 108 void shambler_lightning_touch()
 109 {
 110         PROJECTILE_TOUCH;
 111
 112         self.use ();
 113 }
 114
 115 void shambler_lightning_think()
 116 {
 117         self.nextthink = time;
 118         if (time > self.cnt)
 119         {
 120                 other = world;
 121                 shambler_lightning_explode();
 122                 return;
 123         }
 124 }
 125
 126 void shambler_lightning()
 127 {
 128         entity gren;
 129
 130         monster_makevectors(self.enemy);
 131
 132         gren = spawn ();
 133         gren.owner = gren.realowner = self;
 134         gren.classname = "grenade";
 135         gren.bot_dodge = TRUE;
 136         gren.bot_dodgerating = MON_CVAR(shambler, attack_lightning_damage);
 137         gren.movetype = MOVETYPE_BOUNCE;
 138         PROJECTILE_MAKETRIGGER(gren);
 139         gren.projectiledeathtype = DEATH_MONSTER_SHAMBLER_ZAP;
 140         setorigin(gren, CENTER_OR_VIEWOFS(self));
 141         setsize(gren, '-8 -8 -8', '8 8 8');
 142         gren.scale = 2.5;
 143
 144         gren.cnt = time + 5;
 145         gren.nextthink = time;
 146         gren.think = shambler_lightning_think;
 147         gren.use = shambler_lightning_explode;
 148         gren.touch = shambler_lightning_touch;
 149
 150         gren.takedamage = DAMAGE_YES;
 151         gren.health = 50;
 152         gren.damageforcescale = 0;
 153         gren.event_damage = shambler_lightning_damage;
 154         gren.damagedbycontents = TRUE;
 155         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 156         W_SetupProjectileVelocityEx(gren, v_forward, v_up, MON_CVAR(shambler, attack_lightning_speed), MON_CVAR(shambler, attack_lightning_speed_up), 0, 0, FALSE);
 157
 158         gren.angles = vectoangles (gren.velocity);
 159         gren.flags = FL_PROJECTILE;
 160
 161         CSQCProjectile(gren, TRUE, PROJECTILE_SHAMBLER_LIGHTNING, TRUE);
 162 }
 163
 164 float shambler_attack(float attack_type)
 165 {
 166         switch(attack_type)
 167         {
 168                 case MONSTER_ATTACK_MELEE:
 169                 {
 170                         shambler_swing();
 171                         return TRUE;
 172                 }
 173                 case MONSTER_ATTACK_RANGED:
 174                 {
 175                         if(time >= self.shambler_lastattack) // shambler doesn't attack much
 176                         if(random() <= 0.5 && vlen(self.enemy.origin - self.origin) <= 500)
 177                         {
 178                                 self.frame = shambler_anim_smash;
 179                                 defer(0.7, shambler_smash);
 180                                 self.attack_finished_single = time + 1.1;
 181                                 self.shambler_lastattack = time + 3;
 182                                 return TRUE;
 183                         }
 184                         else if(random() <= 0.1) // small chance, don't want this spammed
 185                         {
 186                                 self.frame = shambler_anim_magic;
 187                                 self.attack_finished_single = time + 1.1;
 188                                 self.shambler_lastattack = time + 3;
 189                                 defer(0.6, shambler_lightning);
 190                                 return TRUE;
 191                         }
 192
 193                         return FALSE;
 194                 }
 195         }
 196
 197         return FALSE;
 198 }
 199
 200 void spawnfunc_monster_shambler()
 201 {
 202         self.classname = "monster_shambler";
 203
 204         self.monster_spawnfunc = spawnfunc_monster_shambler;
 205
 206         if(Monster_CheckAppearFlags(self))
 207                 return;
 208
 209         if not(monster_initialize(MON_SHAMBLER, FALSE)) { remove(self); return; }
 210 }
 211
 212 float m_shambler(float req)
 213 {
 214         switch(req)
 215         {
 216                 case MR_THINK:
 217                 {
 218                         monster_move(MON_CVAR(shambler, speed_run), MON_CVAR(shambler, speed_walk), MON_CVAR(shambler, speed_stop), shambler_anim_run, shambler_anim_walk, shambler_anim_stand);
 219                         return TRUE;
 220                 }
 221                 case MR_DEATH:
 222                 {
 223                         self.frame = shambler_anim_death;
 224                         return TRUE;
 225                 }
 226                 case MR_SETUP:
 227                 {
 228                         if not(self.health) self.health = MON_CVAR(shambler, health);
 229                         if not(self.attack_range) self.attack_range = 150;
 230
 231                         self.monster_loot = spawnfunc_item_health_mega;
 232                         self.monster_attackfunc = shambler_attack;
 233                         self.frame = shambler_anim_stand;
 234                         self.weapon = WEP_NEX;
 235
 236                         return TRUE;
 237                 }
 238                 case MR_PRECACHE:
 239                 {
 240                         precache_model ("models/monsters/shambler.mdl");
 241                         return TRUE;
 242                 }
 243                 case MR_CONFIG:
 244                 {
 245                         MON_CONFIG_SETTINGS(SHAMBLER_SETTINGS(shambler))
 246                         return TRUE;
 247                 }
 248         }
 249
 250         return TRUE;
 251 }
 252
 253 #endif // SVQC
 254 #ifdef CSQC
 255 float m_shambler(float req)
 256 {
 257         switch(req)
 258         {
 259                 case MR_PRECACHE:
 260                 {
 261                         precache_model ("models/monsters/shambler.mdl");
 262                         return TRUE;
 263                 }
 264         }
 265
 266         return TRUE;
 267 }
 268
 269 #endif // CSQC
 270 #endif // REGISTER_MONSTER