qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3         #include <common/util.qh>
   4         #include <common/weapons/_all.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7         #include <common/util.qh>
   8         #include <common/monsters/_mod.qh>
   9 #endif
  10
  11 bool autocvar_g_mapinfo_arena_compat = true;
  12 bool autocvar_g_mapinfo_arena_generate = false;
  13
  14 #ifdef MENUQC
  15 #define WARN_COND false
  16 #else
  17 bool autocvar_g_mapinfo_ignore_warnings;
  18 #define WARN_COND (!autocvar_g_mapinfo_ignore_warnings && MapInfo_Map_bspname == mi_shortname)
  19 #endif
  20
  21 // generic string stuff
  22
  23 int _MapInfo_Cache_Active;
  24 int _MapInfo_Cache_DB_NameToIndex;
  25 int _MapInfo_Cache_Buf_IndexToMapData;
  26
  27 void MapInfo_Cache_Destroy()
  28 {
  29         if(!_MapInfo_Cache_Active)
  30                 return;
  31
  32         db_close(_MapInfo_Cache_DB_NameToIndex);
  33         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  34         _MapInfo_Cache_Active = 0;
  35 }
  36
  37 void MapInfo_Cache_Create()
  38 {
  39         MapInfo_Cache_Destroy();
  40         _MapInfo_Cache_DB_NameToIndex = db_create();
  41         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  42         _MapInfo_Cache_Active = 1;
  43 }
  44
  45 void MapInfo_Cache_Invalidate()
  46 {
  47         if(!_MapInfo_Cache_Active)
  48                 return;
  49
  50         MapInfo_Cache_Create();
  51 }
  52
  53 void MapInfo_Cache_Store()
  54 {
  55         float i;
  56         string s;
  57         if(!_MapInfo_Cache_Active)
  58                 return;
  59
  60         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  61         if(s == "")
  62         {
  63                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  64                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  65         }
  66         else
  67                 i = stof(s);
  68
  69         // now store all the stuff
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  75         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  76         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  77         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  78 }
  79
  80 float MapInfo_Cache_Retrieve(string map)
  81 {
  82         float i;
  83         string s;
  84         if(!_MapInfo_Cache_Active)
  85                 return 0;
  86
  87         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  88         if(s == "")
  89                 return 0;
  90         i = stof(s);
  91
  92         // now retrieve all the stuff
  93         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  94         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  95         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  96         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  97         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  98         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  99         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 100         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 101
 102         return 1;
 103 }
 104
 105 // GLOB HANDLING (for all BSP files)
 106 float _MapInfo_globopen;
 107 float _MapInfo_globcount;
 108 float _MapInfo_globhandle;
 109 string _MapInfo_GlobItem(float i)
 110 {
 111         string s;
 112         if(!_MapInfo_globopen)
 113                 return string_null;
 114         s = search_getfilename(_MapInfo_globhandle, i);
 115         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 116 }
 117
 118 void MapInfo_Enumerate()
 119 {
 120         if(_MapInfo_globopen)
 121         {
 122                 search_end(_MapInfo_globhandle);
 123                 _MapInfo_globopen = 0;
 124         }
 125         MapInfo_Cache_Invalidate();
 126         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 127         if(_MapInfo_globhandle >= 0)
 128         {
 129                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 130                 _MapInfo_globopen = 1;
 131         }
 132         else
 133                 _MapInfo_globcount = 0;
 134 }
 135
 136 // filter the info by game type mask (updates MapInfo_count)
 137 //
 138 float _MapInfo_filtered;
 139 float _MapInfo_filtered_allocated;
 140 float MapInfo_FilterList_Lookup(float i)
 141 {
 142         return stof(bufstr_get(_MapInfo_filtered, i));
 143 }
 144
 145 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 146 {
 147         string h;
 148         h = bufstr_get(_MapInfo_filtered, i);
 149         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 150         bufstr_set(_MapInfo_filtered, j, h);
 151 }
 152
 153 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 154 {
 155         string a, b;
 156         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 157         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 158         return strcasecmp(a, b);
 159 }
 160
 161 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 162 {
 163         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 164 }
 165 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 166 {
 167         float i, j;
 168         if (!_MapInfo_filtered_allocated)
 169         {
 170                 _MapInfo_filtered_allocated = 1;
 171                 _MapInfo_filtered = buf_create();
 172         }
 173         MapInfo_count = 0;
 174         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 175         {
 176                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 177                         if(pAbortOnGenerate)
 178                         {
 179                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 180                                 MapInfo_progress = i / _MapInfo_globcount;
 181                                 return 0;
 182                         }
 183                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 184                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 185                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 186                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 187                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 188         }
 189         MapInfo_count = j + 1;
 190         MapInfo_ClearTemps();
 191
 192         // sometimes the glob isn't sorted nicely, so fix it here...
 193         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 194
 195         return 1;
 196 }
 197 void MapInfo_FilterString(string sf)
 198 {
 199         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 200         float i, j;
 201         string title;
 202
 203         for(i = 0, j = -1; i < MapInfo_count; ++i)
 204         {
 205                 if (MapInfo_Get_ByID(i))
 206                 {
 207                         // prepare for keyword filter
 208                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 209                                 title = MapInfo_Map_title;
 210                         else
 211                                 title = MapInfo_Map_bspname;
 212                         // keyword filter
 213                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 214                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 215                 }
 216         }
 217         MapInfo_count = j + 1;
 218         MapInfo_ClearTemps();
 219
 220         // sometimes the glob isn't sorted nicely, so fix it here...
 221         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 222 }
 223
 224 void MapInfo_Filter_Free()
 225 {
 226         if(_MapInfo_filtered_allocated)
 227         {
 228                 buf_del(_MapInfo_filtered);
 229                 _MapInfo_filtered_allocated = 0;
 230         }
 231 }
 232
 233 // load info about the i-th map into the MapInfo_Map_* globals
 234 string MapInfo_BSPName_ByID(float i)
 235 {
 236         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 237 }
 238
 239 string unquote(string s)
 240 {
 241         float l = strlen(s);
 242         for(float i = 0; i < l; ++i)
 243         {
 244                 string ch = substring(s, i, 1);
 245                 if((ch != " ") && (ch != "\""))
 246                 {
 247                         for(float j = l - i - 1; j > 0; --j)
 248                         {
 249                                 ch = substring(s, i+j, 1);
 250                                 if(ch != " ") if(ch != "\"")
 251                                         return substring(s, i, j+1);
 252                         }
 253                         return substring(s, i, 1);
 254                 }
 255         }
 256         return "";
 257 }
 258
 259 bool MapInfo_Get_ByID(int i)
 260 {
 261         return MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL) ? true : false;
 262 }
 263
 264 string _MapInfo_Map_worldspawn_music;
 265
 266 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 267 {
 268         string fn;
 269         float fh;
 270         string s, k, v;
 271         vector o;
 272         float i;
 273         float inWorldspawn;
 274         float r;
 275         float diameter, spawnpoints;
 276         float spawnplaces;
 277
 278         vector mapMins, mapMaxs;
 279
 280         r = 1;
 281         fn = strcat("maps/", pFilename, ".ent");
 282         fh = fopen(fn, FILE_READ);
 283         if(fh < 0)
 284         {
 285                 r = 2;
 286                 fn = strcat("maps/", pFilename, ".bsp");
 287                 fh = fopen(fn, FILE_READ);
 288         }
 289         if(fh < 0)
 290                 return 0;
 291         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
 292
 293         inWorldspawn = 2;
 294         MapInfo_Map_flags = 0;
 295         MapInfo_Map_supportedGametypes = 0;
 296         spawnpoints = 0;
 297         spawnplaces = 0;
 298         _MapInfo_Map_worldspawn_music = "";
 299         mapMins = '0 0 0';
 300         mapMaxs = '0 0 0';
 301
 302         if(autocvar_g_mapinfo_arena_generate)
 303         {
 304                 // try for .arena or .defi files, as they may have more accurate information
 305                 bool isdefi = false;
 306                 string arena_fn = _MapInfo_FindArenaFile(pFilename, ".arena");
 307                 int arena_fh = fopen(arena_fn, FILE_READ);
 308                 if(arena_fh < 0)
 309                 {
 310                         isdefi = true;
 311                         arena_fn = _MapInfo_FindArenaFile(pFilename, ".defi");
 312                         arena_fh = fopen(arena_fn, FILE_READ);
 313                 }
 314                 if(arena_fh >= 0)
 315                 {
 316                         _MapInfo_ParseArena(arena_fn, arena_fh, pFilename, NULL, isdefi, true);
 317                         fclose(arena_fh);
 318                 }
 319         }
 320
 321         for (;;)
 322         {
 323                 if (!((s = fgets(fh))))
 324                         break;
 325                 if(inWorldspawn == 1)
 326                         if(startsWith(s, "}"))
 327                                 inWorldspawn = 0;
 328                 k = unquote(car(s));
 329                 v = unquote(cdr(s));
 330                 if(inWorldspawn)
 331                 {
 332                         if(k == "classname" && v == "worldspawn")
 333                                 inWorldspawn = 1;
 334                         else if(k == "author")
 335                                 MapInfo_Map_author = v;
 336                         else if(k == "_description")
 337                                 MapInfo_Map_description = v;
 338                         else if(k == "music")
 339                                 _MapInfo_Map_worldspawn_music = v;
 340                         else if(k == "noise")
 341                                 _MapInfo_Map_worldspawn_music = v;
 342                         else if(k == "message")
 343                         {
 344                                 i = strstrofs(v, " by ", 0);
 345                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 346                                 {
 347                                         MapInfo_Map_title = substring(v, 0, i);
 348                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 349                                 }
 350                                 else
 351                                         MapInfo_Map_title = v;
 352                         }
 353                 }
 354                 else
 355                 {
 356                         if(k == "origin")
 357                         {
 358                                 o = stov(strcat("'", v, "'"));
 359                                 mapMins.x = min(mapMins.x, o.x);
 360                                 mapMins.y = min(mapMins.y, o.y);
 361                                 mapMins.z = min(mapMins.z, o.z);
 362                                 mapMaxs.x = max(mapMaxs.x, o.x);
 363                                 mapMaxs.y = max(mapMaxs.y, o.y);
 364                                 mapMaxs.z = max(mapMaxs.z, o.z);
 365                         }
 366                         else if(k == "race_place")
 367                         {
 368                                 if(stof(v) > 0)
 369                                         spawnplaces = 1;
 370                         }
 371                         else if(k == "classname")
 372                         {
 373                                 if(v == "info_player_team1")
 374                                         ++spawnpoints;
 375                                 else if(v == "info_player_team2")
 376                                         ++spawnpoints;
 377                                 else if(v == "info_player_start")
 378                                         ++spawnpoints;
 379                                 else if(v == "info_player_deathmatch")
 380                                         ++spawnpoints;
 381                                 else if(v == "weapon_nex")
 382                                         { }
 383                                 else if(v == "weapon_railgun")
 384                                         { }
 385                                 else if(startsWith(v, "weapon_"))
 386                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 387                                 else if(startsWith(v, "turret_"))
 388                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 389                                 else if(startsWith(v, "vehicle_"))
 390                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 391                                 else if(startsWith(v, "monster_"))
 392                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 393                                 else if(v == "target_music" || v == "trigger_music")
 394                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 395                                 else
 396                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 397                         }
 398                 }
 399         }
 400         if(inWorldspawn)
 401         {
 402                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 403                 return 0;
 404         }
 405         diameter = vlen(mapMaxs - mapMins);
 406
 407         int twoBaseModes = 0;
 408         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 409         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 410         {
 411                 // we have a symmetrical map, don't add the modes without bases
 412         }
 413         else
 414         {
 415                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 416         }
 417
 418         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 419         if(!spawnplaces)
 420         {
 421                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 422                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 423         }
 424
 425         LOG_TRACE("-> diameter ",    ftos(diameter));
 426         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 427         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 428
 429         fclose(fh);
 430
 431         return r;
 432 }
 433
 434 void _MapInfo_Map_Reset()
 435 {
 436         MapInfo_Map_title = "<TITLE>";
 437         MapInfo_Map_titlestring = "<TITLE>";
 438         MapInfo_Map_description = "<DESCRIPTION>";
 439         MapInfo_Map_author = "<AUTHOR>";
 440         MapInfo_Map_supportedGametypes = 0;
 441         MapInfo_Map_supportedFeatures = 0;
 442         MapInfo_Map_flags = 0;
 443         MapInfo_Map_clientstuff = "";
 444         MapInfo_Map_fog = "";
 445         MapInfo_Map_mins = '0 0 0';
 446         MapInfo_Map_maxs = '0 0 0';
 447 }
 448
 449 string _MapInfo_GetDefault(Gametype t)
 450 {
 451         return t.m_legacydefaults;
 452 }
 453
 454 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 455 {
 456         string sa;
 457         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 458         if(!(pThisType.m_flags & pWantedType.m_flags))
 459                 return;
 460
 461         if(load_default)
 462                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 463
 464         if(!pWantedType.frags) // these modes don't use fraglimit
 465         {
 466                 cvar_set("fraglimit", "0");
 467         }
 468         else
 469         {
 470                 sa = car(s);
 471                 if(sa != "")
 472                         cvar_set("fraglimit", sa);
 473                 s = cdr(s);
 474         }
 475
 476         sa = car(s);
 477         if(sa != "")
 478                 cvar_set("timelimit", sa);
 479         s = cdr(s);
 480
 481         if(pWantedType.m_setTeams)
 482         {
 483                 sa = car(s);
 484                 if(sa != "")
 485                         pWantedType.m_setTeams(sa);
 486                 s = cdr(s);
 487         }
 488
 489         // rc = timelimit timelimit_qualification laps laps_teamplay
 490         if(pWantedType == MAPINFO_TYPE_RACE)
 491         {
 492                 cvar_set("fraglimit", "0"); // special case!
 493
 494                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 495                 cvar_set("g_race_qualifying_timelimit", sa);
 496                 s = cdr(s);
 497
 498                 sa = car(s);
 499                 if(sa != "")
 500                         if(cvar("g_race_teams") < 2)
 501                                 cvar_set("fraglimit", sa);
 502                 s = cdr(s);
 503
 504                 sa = car(s);
 505                 if(sa != "")
 506                         if(cvar("g_race_teams") >= 2)
 507                                 cvar_set("fraglimit", sa);
 508                 s = cdr(s);
 509         }
 510
 511         if(!pWantedType.frags) // these modes don't use fraglimit
 512         {
 513                 cvar_set("leadlimit", "0");
 514         }
 515         else
 516         {
 517                 sa = car(s);
 518                 if(sa != "")
 519                         cvar_set("leadlimit", sa);
 520                 s = cdr(s);
 521         }
 522 }
 523
 524 string _MapInfo_GetDefaultEx(Gametype t)
 525 {
 526         return t ? t.model2 : "";
 527 }
 528
 529 float _MapInfo_GetTeamPlayBool(Gametype t)
 530 {
 531         return t ? t.team : false;
 532 }
 533
 534 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 535 {
 536         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 537         if (!(pThisType.m_flags & pWantedType.m_flags))
 538                 return;
 539
 540         // reset all the cvars to their defaults
 541
 542         cvar_set("timelimit", cvar_defstring("timelimit"));
 543         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 544         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 545         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 546
 547         string fraglimit_normal = string_null;
 548         string fraglimit_teams = string_null;
 549
 550         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 551                 string sa = car(s);
 552                 if (sa == "") continue;
 553                 int p = strstrofs(sa, "=", 0);
 554                 if (p < 0) {
 555                         if(WARN_COND)
 556                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 557                         continue;
 558                 }
 559                 string k = substring(sa, 0, p);
 560                 string v = substring(sa, p + 1, -1);
 561                 bool handled = true;
 562                 switch (k) {
 563                         case "timelimit":
 564                         {
 565                                 cvar_set("timelimit", v);
 566                                 break;
 567                         }
 568                         case "leadlimit":
 569                         {
 570                                 cvar_set("leadlimit", v);
 571                                 break;
 572                         }
 573                         case "pointlimit":
 574                         case "fraglimit":
 575                         case "lives":
 576                         case "laplimit":
 577                         case "caplimit":
 578                         {
 579                                 fraglimit_normal = v;
 580                                 break;
 581                         }
 582                         case "teampointlimit":
 583                         case "teamlaplimit":
 584                         {
 585                                 fraglimit_teams = v;
 586                                 break;
 587                         }
 588                         default:
 589                         {
 590                             handled = false;
 591                             break;
 592                         }
 593                 }
 594                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 595                 if (!handled && WARN_COND)
 596             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 597         }
 598
 599         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 600         {
 601                 if(fraglimit_teams)
 602                         cvar_set("fraglimit", fraglimit_teams);
 603         }
 604         else
 605         {
 606                 if(fraglimit_normal)
 607                         cvar_set("fraglimit", fraglimit_normal);
 608         }
 609 }
 610
 611 Gametype MapInfo_Type_FromString(string gtype, bool dowarn, bool is_q3compat)
 612 {
 613         string replacement = "";
 614         bool do_warn = true;
 615         switch (gtype)
 616         {
 617                 case "nexball":   replacement = "nb"; break;
 618                 case "freezetag": replacement = "ft"; break;
 619                 case "keepaway":  replacement = "ka"; break;
 620                 case "invasion":  replacement = "inv"; break;
 621                 case "assault":   replacement = "as"; break;
 622                 case "race":      replacement = "rc"; break;
 623                 // quake 3 compat
 624                 case "ffa":       replacement = "dm"; do_warn = false; break;
 625                 case "cctf":
 626                 case "oneflag":   replacement = "ctf"; do_warn = false; break;
 627                 case "tourney":   replacement = "duel"; do_warn = false; break;
 628                 case "arena":     if(is_q3compat) { replacement = "ca"; do_warn = false; } break;
 629         }
 630         if (replacement != "")
 631         {
 632                 if (dowarn && WARN_COND)
 633                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, gtype, replacement);
 634                 gtype = replacement;
 635         }
 636         FOREACH(Gametypes, it.mdl == gtype, return it);
 637         return NULL;
 638 }
 639
 640 string MapInfo_Type_Description(Gametype t)
 641 {
 642         return t ? t.gametype_description : "";
 643 }
 644
 645 string MapInfo_Type_ToString(Gametype t)
 646 {
 647         return t ? t.mdl : "";
 648 }
 649
 650 string MapInfo_Type_ToText(Gametype t)
 651 {
 652         /* xgettext:no-c-format */
 653         return t ? t.message : _("@!#%'n Tuba Throwing");
 654 }
 655
 656 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 657 {
 658         string t;
 659         float o;
 660         // tabs are invalid, treat them as "empty"
 661         s = strreplace("\t", "", s);
 662
 663         t = car(s); s = cdr(s);
 664
 665         // limited support of "" and comments
 666         //   remove trailing and leading " of t
 667         if(substring(t, 0, 1) == "\"")
 668         {
 669                 if(substring(t, -1, 1) == "\"")
 670                         t = substring(t, 1, -2);
 671         }
 672
 673         //   remove leading " of s
 674         if(substring(s, 0, 1) == "\"")
 675         {
 676                 s = substring(s, 1, -1);
 677         }
 678         //   remove trailing " of s, and all that follows (cvar description)
 679         o = strstrofs(s, "\"", 0);
 680         if(o >= 0)
 681                 s = substring(s, 0, o);
 682
 683         //   remove // comments
 684         o = strstrofs(s, "//", 0);
 685         if(o >= 0)
 686                 s = substring(s, 0, o);
 687
 688         //   remove trailing spaces
 689         while(substring(s, -1, 1) == " ")
 690                 s = substring(s, 0, -2);
 691
 692         if(t == "#include")
 693         {
 694                 if(recurse > 0)
 695                 {
 696                         float fh = fopen(s, FILE_READ);
 697                         if(fh < 0)
 698                         {
 699                                 if(WARN_COND)
 700                                         LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 701                         }
 702                         else
 703                         {
 704                                 while((s = fgets(fh)))
 705                                 {
 706                                         s = strreplace("\t", "", s); // treat tabs as "empty", perform here first to ensure coments are detected
 707                                         // catch different sorts of comments
 708                                         if(s == "")                    // empty lines
 709                                                 continue;
 710                                         if(substring(s, 0, 1) == "#")  // UNIX style
 711                                                 continue;
 712                                         if(substring(s, 0, 2) == "//") // C++ style
 713                                                 continue;
 714                                         if(substring(s, 0, 1) == "_")  // q3map style
 715                                                 continue;
 716
 717                                         if(substring(s, 0, 4) == "set ")
 718                                                 s = substring(s, 4, -1);
 719                                         if(substring(s, 0, 5) == "seta ")
 720                                                 s = substring(s, 5, -1);
 721
 722                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 723                                 }
 724                                 fclose(fh);
 725                         }
 726                 }
 727                 else if(WARN_COND)
 728                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 729         }
 730         else if(t == ""
 731                 || !cvar_value_issafe(t)
 732                 || !cvar_value_issafe(s)
 733                 || matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 734         {
 735                 if (WARN_COND)
 736                         LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 737         }
 738         else if(matchacl(acl, t) <= 0)
 739         {
 740                 if (WARN_COND)
 741                         LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 742         }
 743         else
 744         {
 745                 if(type == 0) // server set
 746                 {
 747                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 748                 #if 0
 749                         if(cvar("g_campaign"))
 750                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 751                         else
 752                 #endif
 753                                 cvar_settemp(t, s);
 754                 }
 755                 else
 756                 {
 757                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 758                         MapInfo_Map_clientstuff = strcat(
 759                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 760                                         );
 761                 }
 762         }
 763 }
 764
 765 float MapInfo_isRedundant(string fn, string t)
 766 {
 767         // normalize file name
 768         fn = strreplace("_", "", fn);
 769         fn = strreplace("-", "", fn);
 770
 771         // normalize visible title
 772         t = strreplace(":", "", t);
 773         t = strreplace(" ", "", t);
 774         t = strreplace("_", "", t);
 775         t = strreplace("-", "", t);
 776         t = strreplace("'", "", t);
 777         t = strdecolorize(t);
 778
 779         // we allow the visible title to have punctuation the file name does
 780         // not, but not vice versa
 781         if(!strcasecmp(fn, t))
 782                 return true;
 783
 784         return false;
 785 }
 786
 787 bool _MapInfo_ParseArena(string arena_filename, int fh, string pFilename, Gametype pGametypeToSet, bool isdefi, bool isgenerator)
 788 {
 789         // NOTE: .arena files can hold more than 1 map's information!
 790         // to handle this, we're going to store gathered information in local variables and save it if we encounter the correct map name
 791         bool in_brackets = false; // testing a potential mapinfo section (within brackets)
 792         bool dosave = (arena_filename == strcat("scripts/", pFilename, ((isdefi) ? ".defi" : ".arena"))); // if the map is using the fallback, just accept the first found mapinfo (it's probably correct!)
 793         string stored_Map_description = "";
 794         string stored_Map_title = "";
 795         string stored_Map_author = "";
 796         int stored_supportedGametypes = 0;
 797         int stored_supportedFeatures = 0;
 798         int stored_flags = 0;
 799         string t, s;
 800         for (;;)
 801         {
 802                 if (!((s = fgets(fh))))
 803                         break;
 804
 805                 // catch different sorts of comments
 806                 if(s == "")                    // empty lines
 807                         continue;
 808                 if(substring(s, 0, 1) == "#")  // UNIX style
 809                         continue;
 810                 if(substring(s, 0, 2) == "//") // C++ style
 811                         continue;
 812                 if(substring(s, 0, 1) == "_")  // q3map style
 813                         continue;
 814                 if(strstrofs(s, "{", 0) >= 0)
 815                 {
 816                         if(in_brackets)
 817                                 return false; // edge case? already in a bracketed section!
 818                         in_brackets = true;
 819                         continue;
 820                 }
 821                 else if(!in_brackets)
 822                 {
 823                         // if we're not inside a bracket, don't process map info
 824                         continue;
 825                 }
 826                 if(strstrofs(s, "}", 0) >= 0)
 827                 {
 828                         if(!in_brackets)
 829                                 return false; // no starting bracket! let the mapinfo generation system handle it
 830                         in_brackets = false;
 831                         if(dosave)
 832                         {
 833                                 MapInfo_Map_description = stored_Map_description;
 834                                 if(stored_Map_title != "")
 835                                         MapInfo_Map_title = stored_Map_title;
 836                                 MapInfo_Map_author = stored_Map_author;
 837                                 if(isgenerator)
 838                                         MapInfo_Map_supportedGametypes = stored_supportedGametypes;
 839                                 else
 840                                 {
 841                                         FOREACH(Gametypes, it.m_flags & stored_supportedGametypes,
 842                                         {
 843                                                 _MapInfo_Map_ApplyGametype ("", pGametypeToSet, it, true);
 844                                         });
 845                                 }
 846                                 MapInfo_Map_supportedFeatures = stored_supportedFeatures;
 847                                 MapInfo_Map_flags = stored_flags;
 848                                 return true; // no need to continue through the file, we have our map!
 849                         }
 850                         else
 851                         {
 852                                 // discard any gathered locals, we're not using the correct map!
 853                                 stored_Map_description = "";
 854                                 stored_Map_title = "";
 855                                 stored_Map_author = "";
 856                                 stored_supportedGametypes = 0;
 857                                 stored_supportedFeatures = 0;
 858                                 stored_flags = 0;
 859                                 continue;
 860                         }
 861                 }
 862
 863                 s = strreplace("\t", " ", s);
 864
 865                 float p = strstrofs(s, "//", 0);
 866                 if(p >= 0)
 867                         s = substring(s, 0, p);
 868
 869                 // perform an initial trim to ensure the first argument is properly obtained
 870                 //   remove leading spaces
 871                 while(substring(s, 0, 1) == " ")
 872                         s = substring(s, 1, -1);
 873
 874                 t = car(s); s = cdr(s);
 875                 t = strtolower(t); // apparently some q3 maps use capitalized parameters
 876
 877                 //   remove trailing spaces
 878                 while(substring(t, -1, 1) == " ")
 879                         t = substring(t, 0, -2);
 880
 881                 //   remove trailing spaces
 882                 while(substring(s, -1, 1) == " ")
 883                         s = substring(s, 0, -2);
 884                 //   remove leading spaces
 885                 while(substring(s, 0, 1) == " ")
 886                         s = substring(s, 1, -1);
 887                 // limited support of ""
 888                 //   remove trailing and leading " of s
 889                 if(substring(s, 0, 1) == "\"")
 890                 {
 891                         if(substring(s, -1, 1) == "\"")
 892                                 s = substring(s, 1, -2);
 893                 }
 894                 if(t == "longname")
 895                         stored_Map_title = s;
 896                 else if(t == "author")
 897                         stored_Map_author = s;
 898                 else if(t == "type")
 899                 {
 900                         // if there is a valid gametype in this .arena file, include it in the menu
 901                         stored_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 902                         // type in quake 3 holds all the supported gametypes, so we must loop through all of them
 903                         string types = strreplace("team", "tdm ft", s); // TODO: handle support here better to include more Xonotic teamplay modes
 904                         FOREACH_WORD(types, true,
 905                         {
 906                                 Gametype f = MapInfo_Type_FromString(it, false, true);
 907                                 if(f)
 908                                         stored_supportedGametypes |= f.m_flags;
 909                         });
 910                 }
 911                 else if(t == "style" && isdefi)
 912                 {
 913                         // we have a defrag map on our hands, add CTS!
 914                         // TODO: styles
 915                         stored_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 916                 }
 917                 else if(t == "map")
 918                 {
 919                         if(strtolower(s) == strtolower(pFilename))
 920                                 dosave = true; // yay, found our map!
 921                 }
 922                 else if(t == "quote")
 923                         stored_Map_description = s;
 924                 // TODO: fraglimit
 925         }
 926
 927         // if the map wasn't found in the .arena, fall back to generated .mapinfo
 928         return false;
 929 }
 930
 931 #if defined(CSQC) || defined(MENUQC)
 932 string(string filename) whichpack = #503;
 933 #endif
 934 string _MapInfo_FindArenaFile(string pFilename, string extension)
 935 {
 936         string fallback = strcat("scripts/", pFilename, extension);
 937         if(!checkextension("DP_QC_FS_SEARCH_PACKFILE"))
 938                 return fallback;
 939         string base_pack = whichpack(strcat("maps/", pFilename, ".bsp"));
 940         if(base_pack == "") // this map isn't packaged!
 941                 return fallback;
 942
 943         int glob = search_packfile_begin(strcat("scripts/*", extension), true, true, base_pack);
 944         if(glob < 0)
 945                 return fallback;
 946         int n = search_getsize(glob);
 947         for(int j = 0; j < n; ++j)
 948         {
 949                 string file = search_getfilename(glob, j);
 950
 951                 int fh = fopen(file, FILE_READ);
 952                 if(fh < 0)
 953                         continue; // how?
 954                 for(string s; (s = fgets(fh)); )
 955                 {
 956                         int offset = strstrofs(s, "map", 0);
 957                         if(offset >= 0)
 958                         {
 959                                 if(strstrofs(strtolower(s), strcat("\"", strtolower(pFilename), "\""), offset) >= 0) // quake 3 is case insensitive
 960                                 {
 961                                         fclose(fh);
 962                                         search_end(glob);
 963                                         return file; // FOUND IT!
 964                                 }
 965                         }
 966                 }
 967                 fclose(fh);
 968         }
 969
 970         search_end(glob);
 971         return fallback; // if we get here, a valid .arena file could not be found
 972 }
 973
 974 // load info about a map by name into the MapInfo_Map_* globals
 975 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
 976 {
 977         string fn;
 978         string s, t;
 979         float fh;
 980         int f, i;
 981         float r, n;
 982         string acl;
 983
 984         acl = MAPINFO_SETTEMP_ACL_USER;
 985
 986         if(strstrofs(pFilename, "/", 0) >= 0)
 987         {
 988                 LOG_WARN("Invalid character in map name, ignored");
 989                 return 0;
 990         }
 991
 992         if(pGametypeToSet == NULL)
 993                 if(MapInfo_Cache_Retrieve(pFilename))
 994                         return 1;
 995
 996         r = 1;
 997
 998         MapInfo_Map_bspname = pFilename;
 999
1000         // default all generic fields so they have "good" values in case something fails
1001         fn = strcat("maps/", pFilename, ".mapinfo");
1002         fh = fopen(fn, FILE_READ);
1003         if(fh < 0)
1004         {
1005                 if(autocvar_g_mapinfo_arena_compat)
1006                 {
1007                         // try for .arena or .defi files if no .mapinfo exists
1008                         bool isdefi = false;
1009                         fn = _MapInfo_FindArenaFile(pFilename, ".arena");
1010                         fh = fopen(fn, FILE_READ);
1011                         if(fh < 0)
1012                         {
1013                                 isdefi = true;
1014                                 fn = _MapInfo_FindArenaFile(pFilename, ".defi");
1015                                 fh = fopen(fn, FILE_READ);
1016                         }
1017                         if(fh >= 0)
1018                         {
1019                                 _MapInfo_Map_Reset();
1020                                 if(_MapInfo_ParseArena(fn, fh, pFilename, pGametypeToSet, isdefi, false))
1021                                         goto mapinfo_handled; // skip generation
1022                         }
1023                 }
1024
1025                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
1026                 fh = fopen(fn, FILE_READ);
1027                 if(fh < 0)
1028                 {
1029                         if(!pAllowGenerate)
1030                                 return 0;
1031                         _MapInfo_Map_Reset();
1032                         r = _MapInfo_Generate(pFilename);
1033                         if(!r)
1034                                 return 0;
1035                         fh = fopen(fn, FILE_WRITE);
1036                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
1037                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
1038                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
1039                         if(_MapInfo_Map_worldspawn_music != "")
1040                         {
1041                                 if(
1042                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
1043                                         ||
1044                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
1045                                 )
1046                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
1047                                 else
1048                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
1049                         }
1050                         else
1051                         {
1052                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
1053                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
1054                                 for (;;)
1055                                 {
1056                                         i = floor(random() * n);
1057                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
1058                                                 break;
1059                                 }
1060                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
1061                         }
1062                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
1063                                 fputs(fh, "has weapons\n");
1064                         else
1065                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
1066                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
1067                                 fputs(fh, "has turrets\n");
1068                         else
1069                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
1070                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
1071                                 fputs(fh, "has vehicles\n");
1072                         else
1073                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
1074                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
1075                                 fputs(fh, "frustrating\n");
1076
1077                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
1078                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
1079                         });
1080
1081                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
1082                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
1083                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
1084                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1085                         fputs(fh, "// optional: hidden\n");
1086
1087                         fclose(fh);
1088                         r = 2;
1089                         // return r;
1090                         fh = fopen(fn, FILE_READ);
1091                         if(fh < 0)
1092                                 error("... but I just wrote it!");
1093                 }
1094
1095                 if(WARN_COND)
1096                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
1097         }
1098
1099         _MapInfo_Map_Reset();
1100         for (;;)
1101         {
1102                 if (!((s = fgets(fh))))
1103                         break;
1104
1105                 // catch different sorts of comments
1106                 if(s == "")                    // empty lines
1107                         continue;
1108                 if(substring(s, 0, 1) == "#")  // UNIX style
1109                         continue;
1110                 if(substring(s, 0, 2) == "//") // C++ style
1111                         continue;
1112                 if(substring(s, 0, 1) == "_")  // q3map style
1113                         continue;
1114
1115                 float p = strstrofs(s, "//", 0);
1116                 if(p >= 0)
1117                         s = substring(s, 0, p);
1118
1119                 t = car(s); s = cdr(s);
1120                 if(t == "title")
1121                         MapInfo_Map_title = s;
1122                 else if(t == "description")
1123                         MapInfo_Map_description = s;
1124                 else if(t == "author")
1125                         MapInfo_Map_author = s;
1126                 else if(t == "has")
1127                 {
1128                         t = car(s); // s = cdr(s);
1129                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1130                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1131                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1132                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1133                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1134                         else if(WARN_COND)
1135                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
1136                 }
1137                 else if(t == "hidden")
1138                 {
1139                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1140                 }
1141                 else if(t == "forbidden")
1142                 {
1143                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1144                 }
1145                 else if(t == "frustrating")
1146                 {
1147                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1148                 }
1149                 else if(t == "noautomaplist")
1150                 {
1151                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1152                 }
1153                 else if(t == "gameversion_min")
1154                 {
1155                         if (cvar("gameversion") < stof(s))
1156                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1157                 }
1158                 else if(t == "type")
1159                 {
1160                         t = car(s); s = cdr(s);
1161                         Gametype f = MapInfo_Type_FromString(t, true, false);
1162                         //if(WARN_COND)
1163                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
1164                         if(f)
1165                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1166                         else if(WARN_COND)
1167                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1168                 }
1169                 else if(t == "gametype")
1170                 {
1171                         t = car(s); s = cdr(s);
1172                         Gametype f = MapInfo_Type_FromString(t, true, false);
1173                         if(f)
1174                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1175                         else if(WARN_COND)
1176                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1177                 }
1178                 else if(t == "size")
1179                 {
1180                         float a, b, c, d, e;
1181                         t = car(s); s = cdr(s); a = stof(t);
1182                         t = car(s); s = cdr(s); b = stof(t);
1183                         t = car(s); s = cdr(s); c = stof(t);
1184                         t = car(s); s = cdr(s); d = stof(t);
1185                         t = car(s); s = cdr(s); e = stof(t);
1186                         if(s == "")
1187                         {
1188                                 if(WARN_COND)
1189                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1190                         }
1191                         else
1192                         {
1193                                 t = car(s); s = cdr(s); f = stof(t);
1194                                 if(s != "")
1195                                 {
1196                                         if(WARN_COND)
1197                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1198                                 }
1199                                 else
1200                                 {
1201                                         if(a >= d || b >= e || c >= f)
1202                                         {
1203                                                 if(WARN_COND)
1204                                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
1205                                         }
1206                                         else
1207                                         {
1208                                                 MapInfo_Map_mins.x = a;
1209                                                 MapInfo_Map_mins.y = b;
1210                                                 MapInfo_Map_mins.z = c;
1211                                                 MapInfo_Map_maxs.x = d;
1212                                                 MapInfo_Map_maxs.y = e;
1213                                                 MapInfo_Map_maxs.z = f;
1214                                         }
1215                                 }
1216                         }
1217                 }
1218                 else if(t == "settemp_for_type")
1219                 {
1220                         t = car(s); s = cdr(s);
1221                         bool all = t == "all";
1222                         Gametype f = NULL;
1223                         if(all || (f = MapInfo_Type_FromString(t, true, false)))
1224                         {
1225                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1226                                 {
1227                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1228                                 }
1229                         }
1230                         else
1231                         {
1232                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
1233                         }
1234                 }
1235                 else if(t == "clientsettemp_for_type")
1236                 {
1237                         t = car(s); s = cdr(s);
1238                         bool all = t == "all";
1239                         Gametype f = NULL;
1240                         if(all || (f = MapInfo_Type_FromString(t, true, false)))
1241                         {
1242                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1243                                 {
1244                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1245                                 }
1246                         }
1247                         else
1248                         {
1249                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1250                         }
1251                 }
1252                 else if(t == "fog")
1253                 {
1254                         if (!cvar_value_issafe(s))
1255                         {
1256                                 if(WARN_COND)
1257                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1258                         }
1259                         else
1260                                 MapInfo_Map_fog = s;
1261                 }
1262                 else if(t == "cdtrack")
1263                 {
1264                         t = car(s); s = cdr(s);
1265                         // We do this only if pGametypeToSet even though this
1266                         // content is theoretically game type independent,
1267                         // because MapInfo_Map_clientstuff contains otherwise
1268                         // game type dependent stuff. That way this value stays
1269                         // empty when not setting a game type to not set any
1270                         // false expectations.
1271                         if(pGametypeToSet)
1272                         {
1273                                 if (!cvar_value_issafe(t))
1274                                 {
1275                                         if(WARN_COND)
1276                                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1277                                 }
1278                                 else
1279                                         MapInfo_Map_clientstuff = strcat(
1280                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1281                                         );
1282                         }
1283                 }
1284                 else if(WARN_COND)
1285                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1286         }
1287         LABEL(mapinfo_handled)
1288         fclose(fh);
1289
1290         if(MapInfo_Map_title == "<TITLE>")
1291                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1292         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1293                 MapInfo_Map_titlestring = MapInfo_Map_title;
1294         else
1295                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1296
1297         MapInfo_Cache_Store();
1298         if(MapInfo_Map_supportedGametypes != 0)
1299                 return r;
1300         if (WARN_COND)
1301                 LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1302         return 0;
1303 }
1304 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1305 {
1306         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1307
1308         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1309
1310         if(pGametypeToSet)
1311         {
1312                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1313                 {
1314                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1315                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1316                         //return;
1317                 }
1318         }
1319
1320         return r;
1321 }
1322
1323 float MapInfo_FindName(string s)
1324 {
1325         // if there is exactly one map of prefix s, return it
1326         // if not, return the null string
1327         // note that DP sorts glob results... so I can use a binary search
1328         float l, r, m, cmp;
1329         l = 0;
1330         r = MapInfo_count;
1331         // invariants: r is behind s, l-1 is equal or before
1332         while(l != r)
1333         {
1334                 m = floor((l + r) / 2);
1335                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1336                 cmp = strcasecmp(MapInfo_FindName_match, s);
1337                 if(cmp == 0)
1338                         return m; // found and good
1339                 if(cmp < 0)
1340                         l = m + 1; // l-1 is before s
1341                 else
1342                         r = m; // behind s
1343         }
1344         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1345         MapInfo_FindName_firstResult = l;
1346         // r == l, so: l is behind s, l-1 is before
1347         // SO: if there is any, l is the one with the right prefix
1348         //     and l+1 may be one too
1349         if(l == MapInfo_count)
1350         {
1351                 MapInfo_FindName_match = string_null;
1352                 MapInfo_FindName_firstResult = -1;
1353                 return -1; // no MapInfo_FindName_match, behind last item
1354         }
1355         if(!startsWithNocase(MapInfo_FindName_match, s))
1356         {
1357                 MapInfo_FindName_match = string_null;
1358                 MapInfo_FindName_firstResult = -1;
1359                 return -1; // wrong prefix
1360         }
1361         if(l == MapInfo_count - 1)
1362                 return l; // last one, nothing can follow => unique
1363         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1364         {
1365                 MapInfo_FindName_match = string_null;
1366                 return -1; // ambigous MapInfo_FindName_match
1367         }
1368         return l;
1369 }
1370
1371 string MapInfo_FixName(string s)
1372 {
1373         MapInfo_FindName(s);
1374         return MapInfo_FindName_match;
1375 }
1376
1377 int MapInfo_CurrentFeatures()
1378 {
1379         int req = 0;
1380     // TODO: find a better way to check if weapons are required on the map
1381         if(!(cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || !cvar("g_melee_only")
1382                 || cvar("g_race") || cvar("g_cts") || cvar("g_nexball") || cvar("g_ca") || cvar("g_freezetag") || cvar("g_lms")))
1383                 req |= MAPINFO_FEATURE_WEAPONS;
1384         return req;
1385 }
1386
1387 Gametype MapInfo_CurrentGametype()
1388 {
1389         Gametype prev = MapInfo_Type_FromString(cvar_string("gamecfg"), false, false);
1390         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1391         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1392 }
1393
1394 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1395 {
1396         if(!MapInfo_Get_ByName(s, 1, NULL))
1397                 return 0;
1398         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1399                 return 0;
1400         if (gametype_only)
1401                 return 1;
1402         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1403                 return 0;
1404         return 1;
1405 }
1406
1407 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1408 {
1409         float r;
1410         r = _MapInfo_CheckMap(s, false);
1411         MapInfo_ClearTemps();
1412         return r;
1413 }
1414
1415 void MapInfo_SwitchGameType(Gametype t)
1416 {
1417         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1418 }
1419
1420 void MapInfo_LoadMap(string s, float reinit)
1421 {
1422         MapInfo_Map_supportedGametypes = 0;
1423         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1424         //if(!MapInfo_CheckMap(s))
1425         //{
1426         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1427         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1428         //}
1429
1430         LOG_INFO("Switching to map ", s);
1431
1432         cvar_settemp_restore();
1433         if(reinit)
1434                 localcmd(strcat("\nmap ", s, "\n"));
1435         else
1436                 localcmd(strcat("\nchangelevel ", s, "\n"));
1437 }
1438
1439 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1440 {
1441         string out;
1442
1443         // to make absolutely sure:
1444         MapInfo_Enumerate();
1445         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1446
1447         out = "";
1448         for(float i = 0; i < MapInfo_count; ++i)
1449                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1450         return substring(out, 1, strlen(out) - 1);
1451 }
1452
1453 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1454 {
1455         string out;
1456
1457         // to make absolutely sure:
1458         MapInfo_Enumerate();
1459         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1460
1461         out = "";
1462         for(float i = 0; i < MapInfo_count; ++i)
1463                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1464
1465         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1466
1467         return substring(out, 1, strlen(out) - 1);
1468 }
1469
1470 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1471 {
1472         MapInfo_SwitchGameType(t);
1473         cvar_set("gamecfg", t.mdl);
1474         MapInfo_LoadedGametype = t;
1475 }
1476
1477 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1478 {
1479         Gametype t = MapInfo_CurrentGametype();
1480         MapInfo_LoadMapSettings_SaveGameType(t);
1481
1482         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1483         {
1484                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1485                 {
1486                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1487                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1488                         return; // do not call Get_ByName!
1489                 }
1490
1491                 if(MapInfo_Map_supportedGametypes == 0)
1492                 {
1493                         RandomSelection_Init();
1494                         FOREACH(Gametypes, it.m_priority == 2,
1495                         {
1496                                 MapInfo_Map_supportedGametypes |= it.m_flags;
1497                                 RandomSelection_AddEnt(it, 1, 1);
1498                         });
1499                         if(RandomSelection_chosen_ent)
1500                                 t = RandomSelection_chosen_ent;
1501                         LOG_SEVEREF("Mapinfo system is not functional at all. Falling back to a preferred mode (%s).", t.mdl);
1502                         MapInfo_LoadMapSettings_SaveGameType(t);
1503                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1504                         return; // do not call Get_ByName!
1505                 }
1506
1507 #if 0
1508                 // find the lowest bit in the supported gametypes
1509                 // unnecessary now that we select one at random
1510                 int _t = 1;
1511                 while(!(MapInfo_Map_supportedGametypes & 1))
1512                 {
1513                         _t <<= 1;
1514                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1515                 }
1516 #endif
1517                 RandomSelection_Init();
1518                 Gametype t_prev = t;
1519                 FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags,
1520                 {
1521                         RandomSelection_AddEnt(it, 1, it.m_priority);
1522                 });
1523                 if(RandomSelection_chosen_ent)
1524                         t = RandomSelection_chosen_ent;
1525
1526                 // t is now a supported mode!
1527                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1528                 MapInfo_LoadMapSettings_SaveGameType(t);
1529         }
1530         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1531                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1532         }
1533         MapInfo_Get_ByName(s, 1, t);
1534 }
1535
1536 void MapInfo_ClearTemps()
1537 {
1538         MapInfo_Map_bspname = string_null;
1539         MapInfo_Map_title = string_null;
1540         MapInfo_Map_titlestring = string_null;
1541         MapInfo_Map_description = string_null;
1542         MapInfo_Map_author = string_null;
1543         MapInfo_Map_clientstuff = string_null;
1544         MapInfo_Map_supportedGametypes = 0;
1545         MapInfo_Map_supportedFeatures = 0;
1546 }
1547
1548 void MapInfo_Shutdown()
1549 {
1550         MapInfo_ClearTemps();
1551         MapInfo_Filter_Free();
1552         MapInfo_Cache_Destroy();
1553         if(_MapInfo_globopen)
1554         {
1555                 search_end(_MapInfo_globhandle);
1556                 _MapInfo_globhandle = -1;
1557                 _MapInfo_globopen = false;
1558         }
1559 }
1560
1561 int MapInfo_ForbiddenFlags()
1562 {
1563         int f = MAPINFO_FLAG_FORBIDDEN;
1564
1565 #ifdef GAMEQC
1566         if (!cvar("g_maplist_allow_hidden"))
1567 #endif
1568                 f |= MAPINFO_FLAG_HIDDEN;
1569
1570         if (!cvar("g_maplist_allow_frustrating"))
1571                 f |= MAPINFO_FLAG_FRUSTRATING;
1572
1573         return f;
1574 }
1575
1576 int MapInfo_RequiredFlags()
1577 {
1578         int f = 0;
1579
1580         if(cvar("g_maplist_allow_frustrating") > 1)
1581                 f |= MAPINFO_FLAG_FRUSTRATING;
1582
1583         return f;
1584 }