qcsrc/common/mapinfo.qc

   1 // generic string stuff
   2
   3 float _MapInfo_Cache_Active;
   4 float _MapInfo_Cache_DB_NameToIndex;
   5 float _MapInfo_Cache_Buf_IndexToMapData;
   6
   7 void MapInfo_Cache_Destroy()
   8 {
   9         if(!_MapInfo_Cache_Active)
  10                 return;
  11
  12         db_close(_MapInfo_Cache_DB_NameToIndex);
  13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  14         _MapInfo_Cache_Active = 0;
  15 }
  16
  17 void MapInfo_Cache_Create()
  18 {
  19         MapInfo_Cache_Destroy();
  20         _MapInfo_Cache_DB_NameToIndex = db_create();
  21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  22         _MapInfo_Cache_Active = 1;
  23 }
  24
  25 void MapInfo_Cache_Invalidate()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         MapInfo_Cache_Create();
  31 }
  32
  33 void MapInfo_Cache_Store()
  34 {
  35         float i;
  36         string s;
  37         if(!_MapInfo_Cache_Active)
  38                 return;
  39
  40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  41         if(s == "")
  42         {
  43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  45         }
  46         else
  47                 i = stof(s);
  48
  49         // now store all the stuff
  50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  57         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  58 }
  59
  60 float MapInfo_Cache_Retrieve(string map)
  61 {
  62         float i;
  63         string s;
  64         if(!_MapInfo_Cache_Active)
  65                 return 0;
  66
  67         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  68         if(s == "")
  69                 return 0;
  70         i = stof(s);
  71
  72         // now retrieve all the stuff
  73         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  74         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  75         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  76         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  77         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  78         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  79         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  80         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  81
  82         return 1;
  83 }
  84
  85 // GLOB HANDLING (for all BSP files)
  86 float _MapInfo_globopen;
  87 float _MapInfo_globcount;
  88 float _MapInfo_globhandle;
  89 string _MapInfo_GlobItem(float i)
  90 {
  91         string s;
  92         if(!_MapInfo_globopen)
  93                 return string_null;
  94         s = search_getfilename(_MapInfo_globhandle, i);
  95         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  96 }
  97
  98 void MapInfo_Enumerate()
  99 {
 100         if(_MapInfo_globopen)
 101         {
 102                 search_end(_MapInfo_globhandle);
 103                 _MapInfo_globopen = 0;
 104         }
 105         MapInfo_Cache_Invalidate();
 106         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 107         if(_MapInfo_globhandle >= 0)
 108         {
 109                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 110                 _MapInfo_globopen = 1;
 111         }
 112         else
 113                 _MapInfo_globcount = 0;
 114 }
 115
 116 // filter the info by game type mask (updates MapInfo_count)
 117 //
 118 float _MapInfo_filtered;
 119 float _MapInfo_filtered_allocated;
 120 float MapInfo_FilterList_Lookup(float i)
 121 {
 122         return stof(bufstr_get(_MapInfo_filtered, i));
 123 }
 124
 125 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 126 {
 127         string h;
 128         h = bufstr_get(_MapInfo_filtered, i);
 129         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 130         bufstr_set(_MapInfo_filtered, j, h);
 131 }
 132
 133 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 134 {
 135         string a, b;
 136         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 137         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 138         return strcasecmp(a, b);
 139 }
 140
 141 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 142 {
 143         float i, j;
 144         if (!_MapInfo_filtered_allocated)
 145         {
 146                 _MapInfo_filtered_allocated = 1;
 147                 _MapInfo_filtered = buf_create();
 148         }
 149         MapInfo_count = 0;
 150         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 151         {
 152                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 153                         if(pAbortOnGenerate)
 154                         {
 155                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 156                                 MapInfo_progress = i / _MapInfo_globcount;
 157                                 return 0;
 158                         }
 159                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 160                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 161                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 162                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 163                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 164         }
 165         MapInfo_count = j + 1;
 166         MapInfo_ClearTemps();
 167
 168         // sometimes the glob isn't sorted nicely, so fix it here...
 169         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
 170
 171         return 1;
 172 }
 173
 174 void MapInfo_Filter_Free()
 175 {
 176         if(_MapInfo_filtered_allocated)
 177         {
 178                 buf_del(_MapInfo_filtered);
 179                 _MapInfo_filtered_allocated = 0;
 180         }
 181 }
 182
 183 // load info about the i-th map into the MapInfo_Map_* globals
 184 string MapInfo_BSPName_ByID(float i)
 185 {
 186         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 187 }
 188
 189 string unquote(string s)
 190 {
 191         float i, j, l;
 192         l = strlen(s);
 193         j = -1;
 194         for(i = 0; i < l; ++i)
 195         {
 196                 string ch;
 197                 ch = substring(s, i, 1);
 198                 if(ch != " ") if(ch != "\"")
 199                 {
 200                         for(j = strlen(s) - i - 1; j > 0; --j)
 201                         {
 202                                 ch = substring(s, i+j, 1);
 203                                 if(ch != " ") if(ch != "\"")
 204                                         return substring(s, i, j+1);
 205                         }
 206                         return substring(s, i, 1);
 207                 }
 208         }
 209         return "";
 210 }
 211
 212 float MapInfo_Get_ByID(float i)
 213 {
 214         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 215                 return 1;
 216         return 0;
 217 }
 218
 219 string _MapInfo_Map_worldspawn_music;
 220
 221 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 222 {
 223         string fn;
 224         float fh;
 225         string s, k, v;
 226         vector o;
 227         float i;
 228         float inWorldspawn;
 229         float r;
 230         float twoBaseModes;
 231         float diameter, spawnpoints;
 232         float spawnplaces;
 233
 234         vector mapMins, mapMaxs;
 235
 236         r = 1;
 237         fn = strcat("maps/", pFilename, ".ent");
 238         fh = fopen(fn, FILE_READ);
 239         if(fh < 0)
 240         {
 241                 r = 2;
 242                 fn = strcat("maps/", pFilename, ".bsp");
 243                 fh = fopen(fn, FILE_READ);
 244         }
 245         if(fh < 0)
 246                 return 0;
 247         print("Analyzing ", fn, " to generate initial mapinfo\n");
 248
 249         inWorldspawn = 2;
 250         MapInfo_Map_flags = 0;
 251         MapInfo_Map_supportedGametypes = 0;
 252         spawnpoints = 0;
 253         spawnplaces = 0;
 254         _MapInfo_Map_worldspawn_music = "";
 255         mapMins = '0 0 0';
 256         mapMaxs = '0 0 0';
 257
 258         for(;;)
 259         {
 260                 if (!((s = fgets(fh))))
 261                         break;
 262                 if(inWorldspawn == 1)
 263                         if(startsWith(s, "}"))
 264                                 inWorldspawn = 0;
 265                 k = unquote(car(s));
 266                 v = unquote(cdr(s));
 267                 if(inWorldspawn)
 268                 {
 269                         if(k == "classname" && v == "worldspawn")
 270                                 inWorldspawn = 1;
 271                         else if(k == "author")
 272                                 MapInfo_Map_author = v;
 273                         else if(k == "_description")
 274                                 MapInfo_Map_description = v;
 275                         else if(k == "music")
 276                                 _MapInfo_Map_worldspawn_music = v;
 277                         else if(k == "noise")
 278                                 _MapInfo_Map_worldspawn_music = v;
 279                         else if(k == "message")
 280                         {
 281                                 i = strstrofs(v, " by ", 0);
 282                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 283                                 {
 284                                         MapInfo_Map_title = substring(v, 0, i);
 285                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 286                                 }
 287                                 else
 288                                         MapInfo_Map_title = v;
 289                         }
 290                 }
 291                 else
 292                 {
 293                         if(k == "origin")
 294                         {
 295                                 o = stov(strcat("'", v, "'"));
 296                                 mapMins_x = min(mapMins_x, o_x);
 297                                 mapMins_y = min(mapMins_y, o_y);
 298                                 mapMins_z = min(mapMins_z, o_z);
 299                                 mapMaxs_x = max(mapMaxs_x, o_x);
 300                                 mapMaxs_y = max(mapMaxs_y, o_y);
 301                                 mapMaxs_z = max(mapMaxs_z, o_z);
 302                         }
 303                         else if(k == "race_place")
 304                         {
 305                                 if(stof(v) > 0)
 306                                         spawnplaces = 1;
 307                         }
 308                         else if(k == "classname")
 309                         {
 310                                 if(v == "dom_controlpoint")
 311                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 312                                 else if(v == "item_flag_team2")
 313                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 314                                 else if(v == "team_CTF_blueflag")
 315                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 316                                 else if(v == "invasion_spawnpoint")
 317                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_INVASION;
 318                                 else if(v == "target_assault_roundend")
 319                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 320                                 else if(v == "onslaught_generator")
 321                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 322                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 323                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 324                                 else if(v == "info_player_team1")
 325                                         ++spawnpoints;
 326                                 else if(v == "info_player_team2")
 327                                         ++spawnpoints;
 328                                 else if(v == "info_player_start")
 329                                         ++spawnpoints;
 330                                 else if(v == "info_player_deathmatch")
 331                                         ++spawnpoints;
 332                                 else if(v == "trigger_race_checkpoint")
 333                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 334                                 else if(v == "target_startTimer")
 335                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 336                                 else if(v == "weapon_nex")
 337                                         { }
 338                                 else if(v == "weapon_railgun")
 339                                         { }
 340                                 else if(startsWith(v, "weapon_"))
 341                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 342                                 else if(startsWith(v, "turret_"))
 343                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 344                                 else if(startsWith(v, "vehicle_"))
 345                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 346                                 else if(v == "target_music" || v == "trigger_music")
 347                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 348                         }
 349                 }
 350         }
 351         if(inWorldspawn)
 352         {
 353                 print(fn, " ended still in worldspawn, BUG\n");
 354                 return 0;
 355         }
 356         diameter = vlen(mapMaxs - mapMins);
 357
 358         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
 359         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 360         {
 361                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 362                 // as the map is too symmetric for them.
 363         }
 364         else
 365         {
 366                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 367                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 368                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEEPAWAY;                // Keepaway always works
 369
 370                 if(spawnpoints >= 8  && diameter > 4096) {
 371                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 372                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_FREEZETAG;
 373                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
 374                 }
 375                 if(spawnpoints >= 12 && diameter > 5120)
 376                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 377         }
 378
 379         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
 380         if(!spawnplaces)
 381         {
 382                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE;
 383                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
 384         }
 385
 386         dprint("-> diameter ",    ftos(diameter));
 387         dprint(";  spawnpoints ", ftos(spawnpoints));
 388         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 389
 390         fclose(fh);
 391
 392         return r;
 393 }
 394
 395 void _MapInfo_Map_Reset()
 396 {
 397         MapInfo_Map_title = "<TITLE>";
 398         MapInfo_Map_titlestring = "<TITLE>";
 399         MapInfo_Map_description = "<DESCRIPTION>";
 400         MapInfo_Map_author = "<AUTHOR>";
 401         MapInfo_Map_supportedGametypes = 0;
 402         MapInfo_Map_supportedFeatures = 0;
 403         MapInfo_Map_flags = 0;
 404         MapInfo_Map_clientstuff = "";
 405         MapInfo_Map_fog = "";
 406         MapInfo_Map_mins = '0 0 0';
 407         MapInfo_Map_maxs = '0 0 0';
 408 }
 409
 410 string _MapInfo_GetDefault(float t)
 411 {
 412         switch(t)
 413         {
 414                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
 415                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
 416                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
 417                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
 418                 case MAPINFO_TYPE_LMS:             return "9 20 0";
 419                 case MAPINFO_TYPE_CA:              return "10 20 0";
 420                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
 421                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
 422                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
 423                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
 424                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
 425                 case MAPINFO_TYPE_CTS:             return "20 0 0";
 426                 case MAPINFO_TYPE_FREEZETAG:       return "10 20 0";
 427                 // NOTE: DO NOT ADD ANY MORE GAME TYPES HERE
 428                 // THIS IS JUST LEGACY SUPPORT FOR NEXUIZ MAPS
 429                 // ONLY ADD NEW STUFF TO _MapInfo_GetDefaultEx
 430                 // THIS FUNCTION WILL EVENTUALLY BE REMOVED
 431                 default:                           return "";
 432         }
 433 }
 434
 435 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
 436 {
 437         string sa;
 438         MapInfo_Map_supportedGametypes |= pThisType;
 439         if(!(pThisType & pWantedType))
 440                 return;
 441
 442         if(load_default)
 443                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
 444
 445         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 446         {
 447                 cvar_set("fraglimit", "0");
 448         }
 449         else
 450         {
 451                 sa = car(s);
 452                 if(sa != "")
 453                         cvar_set("fraglimit", sa);
 454                 s = cdr(s);
 455         }
 456
 457         sa = car(s);
 458         if(sa != "")
 459                 cvar_set("timelimit", sa);
 460         s = cdr(s);
 461
 462         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 463         {
 464                 sa = car(s);
 465                 if(sa != "")
 466                         cvar_set("g_tdm_teams", sa);
 467                 s = cdr(s);
 468         }
 469
 470         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 471         {
 472                 sa = car(s);
 473                 if(sa != "")
 474                         cvar_set("g_keyhunt_teams", sa);
 475                 s = cdr(s);
 476         }
 477
 478         if(pWantedType == MAPINFO_TYPE_CA)
 479         {
 480                 sa = car(s);
 481                 if(sa != "")
 482                         cvar_set("g_ca_teams", sa);
 483                 s = cdr(s);
 484         }
 485
 486         if(pWantedType == MAPINFO_TYPE_FREEZETAG)
 487         {
 488                 sa = car(s);
 489                 if(sa != "")
 490                         cvar_set("g_freezetag_teams", sa);
 491                 s = cdr(s);
 492         }
 493
 494         if(pWantedType == MAPINFO_TYPE_CTF)
 495         {
 496                 sa = car(s);
 497                 if(sa != "")
 498                         cvar_set("fraglimit", sa);
 499                 s = cdr(s);
 500         }
 501
 502         /* keepaway wuz here
 503         if(pWantedType == MAPINFO_TYPE_KEEPAWAY)
 504         {
 505                 sa = car(s);
 506                 if(sa != "")
 507                         cvar_set("fraglimit", sa);
 508                 s = cdr(s);
 509         }
 510         */
 511
 512         // rc = timelimit timelimit_qualification laps laps_teamplay
 513         if(pWantedType == MAPINFO_TYPE_RACE)
 514         {
 515                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 516                 cvar_set("g_race_qualifying_timelimit", sa);
 517                 s = cdr(s);
 518
 519                 sa = car(s);
 520                 if(sa != "")
 521                         if(cvar("g_race_teams") < 2)
 522                                 cvar_set("fraglimit", sa);
 523                 s = cdr(s);
 524
 525                 sa = car(s);
 526                 if(sa != "")
 527                         if(cvar("g_race_teams") >= 2)
 528                                 cvar_set("fraglimit", sa);
 529                 s = cdr(s);
 530         }
 531
 532         if(pWantedType == MAPINFO_TYPE_CTS)
 533         {
 534                 sa = car(s);
 535
 536                 // this is the skill of the map
 537                 // not parsed by anything yet
 538                 // for map databases
 539                 //if(sa != "")
 540                 //      cvar_set("fraglimit", sa);
 541
 542                 s = cdr(s);
 543         }
 544
 545         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
 546         {
 547                 cvar_set("leadlimit", "0");
 548         }
 549         else
 550         {
 551                 sa = car(s);
 552                 if(sa != "")
 553                         cvar_set("leadlimit", sa);
 554                 s = cdr(s);
 555         }
 556 }
 557
 558 string _MapInfo_GetDefaultEx(float t)
 559 {
 560         entity e;
 561         for(e = MapInfo_Type_first; e; e = e.enemy)
 562                 if(t == e.items)
 563                         return e.model2;
 564         return "";
 565 }
 566
 567 float _MapInfo_GetTeamPlayBool(float t)
 568 {
 569         entity e;
 570         for(e = MapInfo_Type_first; e; e = e.enemy)
 571                 if(t == e.items)
 572                         return e.team;
 573         return FALSE;
 574 }
 575
 576 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
 577 {
 578         string sa, k, v;
 579         float p;
 580         string fraglimit_normal;
 581         string fraglimit_teams;
 582
 583         MapInfo_Map_supportedGametypes |= pThisType;
 584         if(!(pThisType & pWantedType))
 585                 return;
 586
 587         // reset all the cvars to their defaults
 588
 589         cvar_set("timelimit", cvar_defstring("timelimit"));
 590         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 591         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 592         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 593         cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 594         cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 595         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 596         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 597         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 598
 599         fraglimit_normal = string_null;
 600         fraglimit_teams = string_null;
 601
 602         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
 603         while(s != "")
 604         {
 605                 sa = car(s);
 606                 s = cdr(s);
 607
 608                 if(sa == "")
 609                         continue;
 610
 611                 p = strstrofs(sa, "=", 0);
 612                 if(p < 0)
 613                 {
 614                         k = "timelimit";
 615                         v = s;
 616                 }
 617                 else
 618                 {
 619                         k = substring(sa, 0, p);
 620                         v = substring(sa, p+1, -1);
 621                 }
 622
 623                 if(k == "timelimit")
 624                 {
 625                         cvar_set("timelimit", v);
 626                 }
 627                 else if(k == "leadlimit")
 628                 {
 629                         cvar_set("leadlimit", v);
 630                 }
 631                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit" || k == "caplimit")
 632                 {
 633                         fraglimit_normal = v;
 634                 }
 635                 else if(k == "teampointlimit" || k == "teamlaplimit")
 636                 {
 637                         fraglimit_teams = v;
 638                 }
 639                 else if(k == "teams")
 640                 {
 641                         cvar_set("g_tdm_teams", v);
 642                         cvar_set("g_ca_teams", v);
 643                         cvar_set("g_freezetag_teams", v);
 644                         cvar_set("g_keyhunt_teams", v);
 645                         cvar_set("g_domination_default_teams", v);
 646                 }
 647                 else if(k == "qualifying_timelimit")
 648                 {
 649                         cvar_set("g_race_qualifying_timelimit", v);
 650                 }
 651                 else if(k == "skill")
 652                 {
 653                         // ignore
 654                 }
 655                 else
 656                 {
 657                         print("Invalid gametype key in mapinfo: ", k, "\n");
 658                 }
 659         }
 660
 661         if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 662         {
 663                 if(fraglimit_teams)
 664                         cvar_set("fraglimit", fraglimit_teams);
 665         }
 666         else
 667         {
 668                 if(fraglimit_normal)
 669                         cvar_set("fraglimit", fraglimit_normal);
 670         }
 671 }
 672
 673 float MapInfo_Type_FromString(string t)
 674 {
 675         entity e;
 676         if(t == "nexball")
 677         {
 678                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 679                 t = "nb";
 680                 print("'. Should use '", t, "'.\n");
 681         }
 682         if(t == "freezetag")
 683         {
 684                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 685                 t = "ft";
 686                 print("'. Should use '", t, "'.\n");
 687         }
 688         if(t == "keepaway")
 689         {
 690                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 691                 t = "ka";
 692                 print("'. Should use '", t, "'.\n");
 693         }
 694         if(t == "invasion")
 695         {
 696                 print("MapInfo_Type_FromString (probably ", MapInfo_Map_bspname, "): using deprecated name '", t);
 697                 t = "inv";
 698                 print("'. Should use '", t, "'.\n");
 699         }
 700         if(t == "all")
 701                 return MAPINFO_TYPE_ALL;
 702         for(e = MapInfo_Type_first; e; e = e.enemy)
 703                 if(t == e.mdl)
 704                         return e.items;
 705         return 0;
 706 }
 707
 708 string MapInfo_Type_ToString(float t)
 709 {
 710         entity e;
 711         if(t == MAPINFO_TYPE_ALL)
 712                 return "all";
 713         for(e = MapInfo_Type_first; e; e = e.enemy)
 714                 if(t == e.items)
 715                         return e.mdl;
 716         return "";
 717 }
 718
 719 string MapInfo_Type_ToText(float t)
 720 {
 721         entity e;
 722         for(e = MapInfo_Type_first; e; e = e.enemy)
 723                 if(t == e.items)
 724                         return e.message;
 725         /* xgettext:no-c-format */
 726         return _("@!#%'n Tuba Throwing");
 727 }
 728
 729 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 730 {
 731         string t;
 732         float fh, o;
 733         t = car(s); s = cdr(s);
 734
 735         // limited support of "" and comments
 736         //   remove trailing and leading " of t
 737         if(substring(t, 0, 1) == "\"")
 738         {
 739                 if(substring(t, -1, 1) == "\"")
 740                         t = substring(t, 1, -2);
 741         }
 742
 743         //   remove leading " of s
 744         if(substring(s, 0, 1) == "\"")
 745         {
 746                 s = substring(s, 1, -1);
 747         }
 748         //   remove trailing " of s, and all that follows (cvar description)
 749         o = strstrofs(s, "\"", 0);
 750         if(o >= 0)
 751                 s = substring(s, 0, o);
 752
 753         //   remove // comments
 754         o = strstrofs(s, "//", 0);
 755         if(o >= 0)
 756                 s = substring(s, 0, o);
 757
 758         //   remove trailing spaces
 759         while(substring(s, -1, 1) == " ")
 760                 s = substring(s, 0, -2);
 761
 762         if(t == "#include")
 763         {
 764                 if(recurse > 0)
 765                 {
 766                         fh = fopen(s, FILE_READ);
 767                         if(fh < 0)
 768                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
 769                         else
 770                         {
 771                                 for(;;)
 772                                 {
 773                                         if (!((s = fgets(fh))))
 774                                                 break;
 775
 776                                         // catch different sorts of comments
 777                                         if(s == "")                    // empty lines
 778                                                 continue;
 779                                         if(substring(s, 0, 1) == "#")  // UNIX style
 780                                                 continue;
 781                                         if(substring(s, 0, 2) == "//") // C++ style
 782                                                 continue;
 783                                         if(substring(s, 0, 1) == "_")  // q3map style
 784                                                 continue;
 785
 786                                         if(substring(s, 0, 4) == "set ")
 787                                                 s = substring(s, 4, -1);
 788                                         if(substring(s, 0, 5) == "seta ")
 789                                                 s = substring(s, 5, -1);
 790
 791                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 792                                 }
 793                                 fclose(fh);
 794                         }
 795                 }
 796                 else
 797                         print("Map ", pFilename, " uses too many levels of inclusion\n");
 798         }
 799         else if(t == "")
 800                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 801         else if (!cvar_value_issafe(t))
 802                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 803         else if (!cvar_value_issafe(s))
 804                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 805         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 806                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 807         else if(matchacl(acl, t) <= 0)
 808                 print("Map ", pFilename, " contains a denied setting, ignored\n");
 809         else
 810         {
 811                 if(type == 0) // server set
 812                 {
 813                         dprint("Applying temporary setting ", t, " := ", s, "\n");
 814                         if(cvar("g_campaign"))
 815                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 816                         else
 817                                 cvar_settemp(t, s);
 818                 }
 819                 else
 820                 {
 821                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
 822                         MapInfo_Map_clientstuff = strcat(
 823                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 824                                         );
 825                 }
 826         }
 827 }
 828
 829 float MapInfo_isRedundant(string fn, string t)
 830 {
 831         // normalize file name
 832         fn = strreplace("_", "-", fn);
 833
 834         // normalize visible title
 835         t = strreplace(": ", "-", t);
 836         t = strreplace(":", "-", t);
 837         t = strreplace(" ", "-", t);
 838         t = strreplace("_", "-", t);
 839         t = strreplace("'", "-", t);
 840
 841         if(!strcasecmp(fn, t))
 842                 return TRUE;
 843
 844         // we allow the visible title to have punctuation the file name does
 845         // not, but not vice versa
 846         t = strreplace("-", "", t);
 847
 848         if(!strcasecmp(fn, t))
 849                 return TRUE;
 850
 851         return FALSE;
 852 }
 853
 854 // load info about a map by name into the MapInfo_Map_* globals
 855 float MapInfo_Get_ByName_NoFallbacks(string pFilename, float pAllowGenerate, float pGametypeToSet)
 856 {
 857         string fn;
 858         string s, t;
 859         float fh;
 860         float r, f, n, i, p;
 861         string acl;
 862
 863         acl = MAPINFO_SETTEMP_ACL_USER;
 864
 865         if(strstrofs(pFilename, "/", 0) >= 0)
 866         {
 867                 print("Invalid character in map name, ignored\n");
 868                 return 0;
 869         }
 870
 871         if(pGametypeToSet == 0)
 872                 if(MapInfo_Cache_Retrieve(pFilename))
 873                         return 1;
 874
 875         r = 1;
 876
 877         MapInfo_Map_bspname = pFilename;
 878
 879         // default all generic fields so they have "good" values in case something fails
 880         fn = strcat("maps/", pFilename, ".mapinfo");
 881         fh = fopen(fn, FILE_READ);
 882         if(fh < 0)
 883         {
 884                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 885                 fh = fopen(fn, FILE_READ);
 886                 if(fh < 0)
 887                 {
 888                         if(!pAllowGenerate)
 889                                 return 0;
 890                         _MapInfo_Map_Reset();
 891                         r = _MapInfo_Generate(pFilename);
 892                         if(!r)
 893                                 return 0;
 894                         fh = fopen(fn, FILE_WRITE);
 895                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 896                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 897                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 898                         if(_MapInfo_Map_worldspawn_music != "")
 899                         {
 900                                 if(
 901                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 902                                         ||
 903                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 904                                 )
 905                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 906                                 else
 907                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 908                         }
 909                         else
 910                         {
 911                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 912                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 913                                 for(;;)
 914                                 {
 915                                         i = floor(random() * n);
 916                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 917                                                 break;
 918                                 }
 919                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 920                         }
 921                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 922                                 fputs(fh, "has weapons\n");
 923                         else
 924                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 925                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 926                                 fputs(fh, "has turrets\n");
 927                         else
 928                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 929                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 930                                 fputs(fh, "has vehicles\n");
 931                         else
 932                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 933                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 934                                 fputs(fh, "frustrating\n");
 935
 936                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
 937                                 if(MapInfo_Map_supportedGametypes & i)
 938                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
 939
 940                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 941                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 942
 943                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 944                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 945                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 946                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 947                         fputs(fh, "// optional: hidden\n");
 948
 949                         fclose(fh);
 950                         r = 2;
 951                         // return r;
 952                         fh = fopen(fn, FILE_READ);
 953                         if(fh < 0)
 954                                 error("... but I just wrote it!");
 955                 }
 956
 957                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
 958         }
 959
 960         _MapInfo_Map_Reset();
 961         for(;;)
 962         {
 963                 if (!((s = fgets(fh))))
 964                         break;
 965
 966                 // catch different sorts of comments
 967                 if(s == "")                    // empty lines
 968                         continue;
 969                 if(substring(s, 0, 1) == "#")  // UNIX style
 970                         continue;
 971                 if(substring(s, 0, 2) == "//") // C++ style
 972                         continue;
 973                 if(substring(s, 0, 1) == "_")  // q3map style
 974                         continue;
 975
 976                 p = strstrofs(s, "//", 0);
 977                 if(p >= 0)
 978                         s = substring(s, 0, p);
 979
 980                 t = car(s); s = cdr(s);
 981                 if(t == "title")
 982                         MapInfo_Map_title = s;
 983                 else if(t == "description")
 984                         MapInfo_Map_description = s;
 985                 else if(t == "author")
 986                         MapInfo_Map_author = s;
 987                 else if(t == "has")
 988                 {
 989                         t = car(s); // s = cdr(s);
 990                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 991                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 992                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 993                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 994                         else
 995                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 996                 }
 997                 else if(t == "hidden")
 998                 {
 999                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1000                 }
1001                 else if(t == "forbidden")
1002                 {
1003                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1004                 }
1005                 else if(t == "frustrating")
1006                 {
1007                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1008                 }
1009                 else if(t == "noautomaplist")
1010                 {
1011                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1012                 }
1013                 else if(t == "type")
1014                 {
1015                         t = car(s); s = cdr(s);
1016                         f = MapInfo_Type_FromString(t);
1017                         print("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.\n");
1018                         if(f)
1019                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
1020                         else
1021                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1022                 }
1023                 else if(t == "gametype")
1024                 {
1025                         t = car(s); s = cdr(s);
1026                         f = MapInfo_Type_FromString(t);
1027                         if(f)
1028                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1029                         else
1030                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
1031                 }
1032                 else if(t == "size")
1033                 {
1034                         float a, b, c, d, e;
1035                         t = car(s); s = cdr(s); a = stof(t);
1036                         t = car(s); s = cdr(s); b = stof(t);
1037                         t = car(s); s = cdr(s); c = stof(t);
1038                         t = car(s); s = cdr(s); d = stof(t);
1039                         t = car(s); s = cdr(s); e = stof(t);
1040                         if(s == "")
1041                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1042                         else
1043                         {
1044                                 t = car(s); s = cdr(s); f = stof(t);
1045                                 if(s != "")
1046                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1047                                 else
1048                                 {
1049                                         if(a >= d || b >= e || c >= f)
1050                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
1051                                         else
1052                                         {
1053                                                 MapInfo_Map_mins_x = a;
1054                                                 MapInfo_Map_mins_y = b;
1055                                                 MapInfo_Map_mins_z = c;
1056                                                 MapInfo_Map_maxs_x = d;
1057                                                 MapInfo_Map_maxs_y = e;
1058                                                 MapInfo_Map_maxs_z = f;
1059                                         }
1060                                 }
1061                         }
1062                 }
1063                 else if(t == "settemp_for_type")
1064                 {
1065                         t = car(s); s = cdr(s);
1066                         if((f = MapInfo_Type_FromString(t)))
1067                         {
1068                                 if(f & pGametypeToSet)
1069                                 {
1070                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1071                                 }
1072                         }
1073                         else
1074                         {
1075                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
1076                         }
1077                 }
1078                 else if(t == "clientsettemp_for_type")
1079                 {
1080                         t = car(s); s = cdr(s);
1081                         if((f = MapInfo_Type_FromString(t)))
1082                         {
1083                                 if(f & pGametypeToSet)
1084                                 {
1085                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1086                                 }
1087                         }
1088                         else
1089                         {
1090                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1091                         }
1092                 }
1093                 else if(t == "fog")
1094                 {
1095                         if (!cvar_value_issafe(s))
1096                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1097                         else
1098                                 MapInfo_Map_fog = s;
1099                 }
1100                 else if(t == "cdtrack")
1101                 {
1102                         t = car(s); s = cdr(s);
1103                         if(pGametypeToSet) // FIXME is this check right here?
1104                         {
1105                                 if (!cvar_value_issafe(t))
1106                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1107                                 else
1108                                         MapInfo_Map_clientstuff = strcat(
1109                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1110                                         );
1111                         }
1112                 }
1113                 else
1114                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1115         }
1116         fclose(fh);
1117
1118         if(MapInfo_Map_title == "<TITLE>")
1119                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1120         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1121                 MapInfo_Map_titlestring = MapInfo_Map_title;
1122         else
1123                 MapInfo_Map_titlestring = sprintf(_("%s: %s"), MapInfo_Map_bspname, MapInfo_Map_title);
1124
1125         MapInfo_Cache_Store();
1126         if(MapInfo_Map_supportedGametypes != 0)
1127                 return r;
1128         dprint("Map ", pFilename, " supports no game types, ignored\n");
1129         return 0;
1130 }
1131 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
1132 {
1133         float r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1134
1135         if(cvar("g_tdm_on_dm_maps"))
1136         {
1137                 // if this is set, all DM maps support TDM too
1138                 if (!(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH))
1139                         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)
1140                                 _MapInfo_Map_ApplyGametypeEx ("", pGametypeToSet, MAPINFO_TYPE_TEAM_DEATHMATCH);
1141         }
1142
1143         if(pGametypeToSet)
1144         {
1145                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1146                 {
1147                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1148                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1149                         //return;
1150                 }
1151         }
1152
1153         return r;
1154 }
1155
1156 float MapInfo_FindName(string s)
1157 {
1158         // if there is exactly one map of prefix s, return it
1159         // if not, return the null string
1160         // note that DP sorts glob results... so I can use a binary search
1161         float l, r, m, cmp;
1162         l = 0;
1163         r = MapInfo_count;
1164         // invariants: r is behind s, l-1 is equal or before
1165         while(l != r)
1166         {
1167                 m = floor((l + r) / 2);
1168                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1169                 cmp = strcasecmp(MapInfo_FindName_match, s);
1170                 if(cmp == 0)
1171                         return m; // found and good
1172                 if(cmp < 0)
1173                         l = m + 1; // l-1 is before s
1174                 else
1175                         r = m; // behind s
1176         }
1177         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1178         MapInfo_FindName_firstResult = l;
1179         // r == l, so: l is behind s, l-1 is before
1180         // SO: if there is any, l is the one with the right prefix
1181         //     and l+1 may be one too
1182         if(l == MapInfo_count)
1183         {
1184                 MapInfo_FindName_match = string_null;
1185                 MapInfo_FindName_firstResult = -1;
1186                 return -1; // no MapInfo_FindName_match, behind last item
1187         }
1188         if(!startsWithNocase(MapInfo_FindName_match, s))
1189         {
1190                 MapInfo_FindName_match = string_null;
1191                 MapInfo_FindName_firstResult = -1;
1192                 return -1; // wrong prefix
1193         }
1194         if(l == MapInfo_count - 1)
1195                 return l; // last one, nothing can follow => unique
1196         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1197         {
1198                 MapInfo_FindName_match = string_null;
1199                 return -1; // ambigous MapInfo_FindName_match
1200         }
1201         return l;
1202 }
1203
1204 string MapInfo_FixName(string s)
1205 {
1206         MapInfo_FindName(s);
1207         return MapInfo_FindName_match;
1208 }
1209
1210 float MapInfo_CurrentFeatures()
1211 {
1212         float req;
1213         req = 0;
1214         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1215                 req |= MAPINFO_FEATURE_WEAPONS;
1216         return req;
1217 }
1218
1219 float MapInfo_CurrentGametype()
1220 {
1221         float prev;
1222         entity e;
1223         prev = cvar("gamecfg");
1224         for(e = MapInfo_Type_first; e; e = e.enemy)
1225                 if(cvar(e.netname))
1226                         if(prev != e.items)
1227                                 return e.items;
1228         if(prev)
1229                 return prev;
1230         return MAPINFO_TYPE_DEATHMATCH;
1231 }
1232
1233 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1234 {
1235         if(!MapInfo_Get_ByName(s, 1, 0))
1236                 return 0;
1237         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1238                 return 0;
1239         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1240                 return 0;
1241         return 1;
1242 }
1243
1244 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1245 {
1246         float r;
1247         r = _MapInfo_CheckMap(s);
1248         MapInfo_ClearTemps();
1249         return r;
1250 }
1251
1252 void MapInfo_SwitchGameType(float t)
1253 {
1254         entity e;
1255         for(e = MapInfo_Type_first; e; e = e.enemy)
1256                 cvar_set(e.netname, (t == e.items) ? "1" : "0");
1257 }
1258
1259 void MapInfo_LoadMap(string s, float reinit)
1260 {
1261         MapInfo_Map_supportedGametypes = 0;
1262         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1263         //if(!MapInfo_CheckMap(s))
1264         //{
1265         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1266         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1267         //}
1268
1269         cvar_settemp_restore();
1270         if(reinit)
1271                 localcmd(strcat("\nmap ", s, "\n"));
1272         else
1273                 localcmd(strcat("\nchangelevel ", s, "\n"));
1274 }
1275
1276 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1277 {
1278         string out;
1279         float i;
1280
1281         // to make absolutely sure:
1282         MapInfo_Enumerate();
1283         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1284
1285         out = "";
1286         for(i = 0; i < MapInfo_count; ++i)
1287                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1288         return substring(out, 1, strlen(out) - 1);
1289 }
1290
1291 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1292 {
1293         string out;
1294         float i;
1295
1296         // to make absolutely sure:
1297         MapInfo_Enumerate();
1298         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1299
1300         out = "";
1301         for(i = 0; i < MapInfo_count; ++i)
1302                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1303
1304         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1305
1306         return substring(out, 1, strlen(out) - 1);
1307 }
1308
1309 void MapInfo_LoadMapSettings_SaveGameType(float t)
1310 {
1311         MapInfo_SwitchGameType(t);
1312         cvar_set("gamecfg", ftos(t));
1313         MapInfo_LoadedGametype = t;
1314 }
1315
1316 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1317 {
1318         float t;
1319
1320         t = MapInfo_CurrentGametype();
1321         MapInfo_LoadMapSettings_SaveGameType(t);
1322
1323         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1324         {
1325                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1326                 {
1327                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1328                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1329                         return; // do not call Get_ByName!
1330                 }
1331
1332                 if(MapInfo_Map_supportedGametypes == 0)
1333                 {
1334                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1335                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1336                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1337                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1338                         return; // do not call Get_ByName!
1339                 }
1340
1341                 t = 1;
1342                 while(!(MapInfo_Map_supportedGametypes & 1))
1343                 {
1344                         t *= 2;
1345                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1346                 }
1347
1348                 // t is now a supported mode!
1349                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1350                 MapInfo_LoadMapSettings_SaveGameType(t);
1351         }
1352         MapInfo_Get_ByName(s, 1, t);
1353 }
1354
1355 void MapInfo_ClearTemps()
1356 {
1357         MapInfo_Map_bspname = string_null;
1358         MapInfo_Map_title = string_null;
1359         MapInfo_Map_titlestring = string_null;
1360         MapInfo_Map_description = string_null;
1361         MapInfo_Map_author = string_null;
1362         MapInfo_Map_clientstuff = string_null;
1363         MapInfo_Map_supportedGametypes = 0;
1364         MapInfo_Map_supportedFeatures = 0;
1365 }
1366
1367 void MapInfo_Shutdown()
1368 {
1369         MapInfo_ClearTemps();
1370         MapInfo_Filter_Free();
1371         MapInfo_Cache_Destroy();
1372         if(_MapInfo_globopen)
1373         {
1374                 search_end(_MapInfo_globhandle);
1375                 _MapInfo_globhandle = -1;
1376                 _MapInfo_globopen = FALSE;
1377         }
1378 }
1379
1380 float MapInfo_ForbiddenFlags()
1381 {
1382         float f;
1383         f = MAPINFO_FLAG_FORBIDDEN;
1384
1385 #ifndef MENUQC
1386         if (!cvar("g_maplist_allow_hidden"))
1387 #endif
1388                 f |= MAPINFO_FLAG_HIDDEN;
1389
1390         if (!cvar("g_maplist_allow_frustrating"))
1391                 f |= MAPINFO_FLAG_FRUSTRATING;
1392
1393         return f;
1394 }
1395
1396 float MapInfo_RequiredFlags()
1397 {
1398         float f;
1399         f = 0;
1400
1401         if(cvar("g_maplist_allow_frustrating") > 1)
1402                 f |= MAPINFO_FLAG_FRUSTRATING;
1403
1404         return f;
1405 }