qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3         #include <common/util.qh>
   4         #include <common/weapons/_all.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7         #include <common/util.qh>
   8         #include <common/monsters/_mod.qh>
   9 #endif
  10
  11 int autocvar_g_mapinfo_q3compat = 1;
  12
  13 #ifdef MENUQC
  14 #define WARN_COND false
  15 #else
  16 bool autocvar_g_mapinfo_ignore_warnings;
  17 #define WARN_COND (!autocvar_g_mapinfo_ignore_warnings && MapInfo_Map_bspname == mi_shortname)
  18 #endif
  19
  20 // generic string stuff
  21
  22 int _MapInfo_Cache_Active;
  23 int _MapInfo_Cache_DB_NameToIndex;
  24 int _MapInfo_Cache_Buf_IndexToMapData;
  25
  26 void MapInfo_Cache_Destroy()
  27 {
  28         if(!_MapInfo_Cache_Active)
  29                 return;
  30
  31         db_close(_MapInfo_Cache_DB_NameToIndex);
  32         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  33         _MapInfo_Cache_Active = 0;
  34 }
  35
  36 void MapInfo_Cache_Create()
  37 {
  38         MapInfo_Cache_Destroy();
  39         _MapInfo_Cache_DB_NameToIndex = db_create();
  40         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  41         _MapInfo_Cache_Active = 1;
  42 }
  43
  44 void MapInfo_Cache_Invalidate()
  45 {
  46         if(!_MapInfo_Cache_Active)
  47                 return;
  48
  49         MapInfo_Cache_Create();
  50 }
  51
  52 void MapInfo_Cache_Store()
  53 {
  54         float i;
  55         string s;
  56         if(!_MapInfo_Cache_Active)
  57                 return;
  58
  59         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  60         if(s == "")
  61         {
  62                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  63                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  64         }
  65         else
  66                 i = stof(s);
  67
  68         // now store all the stuff
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  75         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  76         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  77 }
  78
  79 float MapInfo_Cache_Retrieve(string map)
  80 {
  81         float i;
  82         string s;
  83         if(!_MapInfo_Cache_Active)
  84                 return 0;
  85
  86         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  87         if(s == "")
  88                 return 0;
  89         i = stof(s);
  90
  91         // now retrieve all the stuff
  92         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  93         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  94         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  95         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  96         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  97         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  98         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  99         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 100
 101         return 1;
 102 }
 103
 104 // GLOB HANDLING (for all BSP files)
 105 float _MapInfo_globopen;
 106 float _MapInfo_globcount;
 107 float _MapInfo_globhandle;
 108 string _MapInfo_GlobItem(float i)
 109 {
 110         string s;
 111         if(!_MapInfo_globopen)
 112                 return string_null;
 113         s = search_getfilename(_MapInfo_globhandle, i);
 114         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 115 }
 116
 117 void MapInfo_Enumerate()
 118 {
 119         if(_MapInfo_globopen)
 120         {
 121                 search_end(_MapInfo_globhandle);
 122                 _MapInfo_globopen = 0;
 123         }
 124         MapInfo_Cache_Invalidate();
 125         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 126         if(_MapInfo_globhandle >= 0)
 127         {
 128                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 129                 _MapInfo_globopen = 1;
 130         }
 131         else
 132                 _MapInfo_globcount = 0;
 133 }
 134
 135 // filter the info by game type mask (updates MapInfo_count)
 136 //
 137 float _MapInfo_filtered;
 138 float _MapInfo_filtered_allocated;
 139 float MapInfo_FilterList_Lookup(float i)
 140 {
 141         return stof(bufstr_get(_MapInfo_filtered, i));
 142 }
 143
 144 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 145 {
 146         string h;
 147         h = bufstr_get(_MapInfo_filtered, i);
 148         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 149         bufstr_set(_MapInfo_filtered, j, h);
 150 }
 151
 152 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 153 {
 154         string a, b;
 155         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 156         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 157         return strcasecmp(a, b);
 158 }
 159
 160 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 161 {
 162         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 163 }
 164 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 165 {
 166         float i, j;
 167         if (!_MapInfo_filtered_allocated)
 168         {
 169                 _MapInfo_filtered_allocated = 1;
 170                 _MapInfo_filtered = buf_create();
 171         }
 172         MapInfo_count = 0;
 173         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 174         {
 175                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 176                         if(pAbortOnGenerate)
 177                         {
 178                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 179                                 MapInfo_progress = i / _MapInfo_globcount;
 180                                 return 0;
 181                         }
 182                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 183                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 184                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 185                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 186                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 187         }
 188         MapInfo_count = j + 1;
 189         MapInfo_ClearTemps();
 190
 191         // sometimes the glob isn't sorted nicely, so fix it here...
 192         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 193
 194         return 1;
 195 }
 196 void MapInfo_FilterString(string sf)
 197 {
 198         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 199         float i, j;
 200         string title;
 201
 202         for(i = 0, j = -1; i < MapInfo_count; ++i)
 203         {
 204                 if (MapInfo_Get_ByID(i))
 205                 {
 206                         // prepare for keyword filter
 207                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 208                                 title = MapInfo_Map_title;
 209                         else
 210                                 title = MapInfo_Map_bspname;
 211                         // keyword filter
 212                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 213                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 214                 }
 215         }
 216         MapInfo_count = j + 1;
 217         MapInfo_ClearTemps();
 218
 219         // sometimes the glob isn't sorted nicely, so fix it here...
 220         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 221 }
 222
 223 void MapInfo_Filter_Free()
 224 {
 225         if(_MapInfo_filtered_allocated)
 226         {
 227                 buf_del(_MapInfo_filtered);
 228                 _MapInfo_filtered_allocated = 0;
 229         }
 230 }
 231
 232 // load info about the i-th map into the MapInfo_Map_* globals
 233 string MapInfo_BSPName_ByID(float i)
 234 {
 235         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 236 }
 237
 238 string unquote(string s)
 239 {
 240         float l = strlen(s);
 241         for(float i = 0; i < l; ++i)
 242         {
 243                 string ch = substring(s, i, 1);
 244                 if((ch != " ") && (ch != "\""))
 245                 {
 246                         for(float j = l - i - 1; j > 0; --j)
 247                         {
 248                                 ch = substring(s, i+j, 1);
 249                                 if(ch != " ") if(ch != "\"")
 250                                         return substring(s, i, j+1);
 251                         }
 252                         return substring(s, i, 1);
 253                 }
 254         }
 255         return "";
 256 }
 257
 258 bool MapInfo_Get_ByID(int i)
 259 {
 260         return MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL) ? true : false;
 261 }
 262
 263 string _MapInfo_Map_worldspawn_music;
 264
 265 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 266 {
 267         string fn;
 268         float fh;
 269         string s, k, v;
 270         vector o;
 271         float i;
 272         float inWorldspawn;
 273         float r;
 274         float diameter, spawnpoints;
 275         float spawnplaces;
 276
 277         vector mapMins, mapMaxs;
 278
 279         r = 1;
 280         fn = strcat("maps/", pFilename, ".ent");
 281         fh = fopen(fn, FILE_READ);
 282         if(fh < 0)
 283         {
 284                 r = 2;
 285                 fn = strcat("maps/", pFilename, ".bsp");
 286                 fh = fopen(fn, FILE_READ);
 287         }
 288         if(fh < 0)
 289                 return 0;
 290         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
 291
 292         inWorldspawn = 2;
 293         MapInfo_Map_flags = 0;
 294         MapInfo_Map_supportedGametypes = 0;
 295         spawnpoints = 0;
 296         spawnplaces = 0;
 297         _MapInfo_Map_worldspawn_music = "";
 298         mapMins = '0 0 0';
 299         mapMaxs = '0 0 0';
 300
 301         if(autocvar_g_mapinfo_q3compat == 2) // generate mapinfo using arena data
 302         {
 303                 // try for .arena or .defi files, as they may have more accurate information
 304                 bool isdefi = false;
 305                 float arena_fh = -1;
 306                 string arena_fn = _MapInfo_FindArenaFile(pFilename, ".arena");
 307                 if(arena_fn != "")
 308                         arena_fh = fopen(arena_fn, FILE_READ);
 309                 if(arena_fh < 0)
 310                 {
 311                         isdefi = true;
 312                         arena_fn = _MapInfo_FindArenaFile(pFilename, ".defi");
 313                         if(arena_fn != "")
 314                                 arena_fh = fopen(arena_fn, FILE_READ);
 315                 }
 316                 if(arena_fh >= 0)
 317                 {
 318                         _MapInfo_ParseArena(arena_fn, arena_fh, pFilename, NULL, isdefi, true);
 319                         fclose(arena_fh);
 320                 }
 321         }
 322
 323         for (;;)
 324         {
 325                 if (!((s = fgets(fh))))
 326                         break;
 327                 if(inWorldspawn == 1)
 328                         if(startsWith(s, "}"))
 329                                 inWorldspawn = 0;
 330                 k = unquote(car(s));
 331                 v = unquote(cdr(s));
 332                 if(inWorldspawn)
 333                 {
 334                         if(k == "classname" && v == "worldspawn")
 335                                 inWorldspawn = 1;
 336                         else if(k == "author")
 337                                 MapInfo_Map_author = v;
 338                         else if(k == "_description")
 339                                 MapInfo_Map_description = v;
 340                         else if(k == "music")
 341                                 _MapInfo_Map_worldspawn_music = v;
 342                         else if(k == "noise")
 343                                 _MapInfo_Map_worldspawn_music = v;
 344                         else if(k == "message")
 345                         {
 346                                 i = strstrofs(v, " by ", 0);
 347                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 348                                 {
 349                                         MapInfo_Map_title = substring(v, 0, i);
 350                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 351                                 }
 352                                 else
 353                                         MapInfo_Map_title = v;
 354                         }
 355                 }
 356                 else
 357                 {
 358                         if(k == "origin")
 359                         {
 360                                 o = stov(strcat("'", v, "'"));
 361                                 mapMins.x = min(mapMins.x, o.x);
 362                                 mapMins.y = min(mapMins.y, o.y);
 363                                 mapMins.z = min(mapMins.z, o.z);
 364                                 mapMaxs.x = max(mapMaxs.x, o.x);
 365                                 mapMaxs.y = max(mapMaxs.y, o.y);
 366                                 mapMaxs.z = max(mapMaxs.z, o.z);
 367                         }
 368                         else if(k == "race_place")
 369                         {
 370                                 if(stof(v) > 0)
 371                                         spawnplaces = 1;
 372                         }
 373                         else if(k == "classname")
 374                         {
 375                                 if(v == "info_player_team1")
 376                                         ++spawnpoints;
 377                                 else if(v == "info_player_team2")
 378                                         ++spawnpoints;
 379                                 else if(v == "info_player_start")
 380                                         ++spawnpoints;
 381                                 else if(v == "info_player_deathmatch")
 382                                         ++spawnpoints;
 383                                 else if(v == "weapon_nex")
 384                                         { }
 385                                 else if(v == "weapon_railgun")
 386                                         { }
 387                                 else if(startsWith(v, "weapon_"))
 388                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 389                                 else if(startsWith(v, "turret_"))
 390                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 391                                 else if(startsWith(v, "vehicle_"))
 392                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 393                                 else if(startsWith(v, "monster_"))
 394                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 395                                 else if(v == "target_music" || v == "trigger_music")
 396                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 397                                 else
 398                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 399                         }
 400                 }
 401         }
 402         if(inWorldspawn)
 403         {
 404                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 405                 return 0;
 406         }
 407         diameter = vlen(mapMaxs - mapMins);
 408
 409         int twoBaseModes = 0;
 410         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 411         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 412         {
 413                 // we have a symmetrical map, don't add the modes without bases
 414         }
 415         else
 416         {
 417                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 418         }
 419
 420         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 421         if(!spawnplaces)
 422         {
 423                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 424                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 425         }
 426
 427         LOG_TRACE("-> diameter ",    ftos(diameter));
 428         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 429         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 430
 431         fclose(fh);
 432
 433         return r;
 434 }
 435
 436 void _MapInfo_Map_Reset()
 437 {
 438         MapInfo_Map_title = "<TITLE>";
 439         MapInfo_Map_titlestring = "<TITLE>";
 440         MapInfo_Map_description = "<DESCRIPTION>";
 441         MapInfo_Map_author = "<AUTHOR>";
 442         MapInfo_Map_supportedGametypes = 0;
 443         MapInfo_Map_supportedFeatures = 0;
 444         MapInfo_Map_flags = 0;
 445         MapInfo_Map_clientstuff = "";
 446         MapInfo_Map_fog = "";
 447         MapInfo_Map_mins = '0 0 0';
 448         MapInfo_Map_maxs = '0 0 0';
 449 }
 450
 451 string _MapInfo_GetDefault(Gametype t)
 452 {
 453         return t.m_legacydefaults;
 454 }
 455
 456 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 457 {
 458         string sa;
 459         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 460         if(!(pThisType.m_flags & pWantedType.m_flags))
 461                 return;
 462
 463         if(load_default)
 464                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 465
 466         if(!pWantedType.frags) // these modes don't use fraglimit
 467         {
 468                 cvar_set("fraglimit", "0");
 469         }
 470         else
 471         {
 472                 sa = car(s);
 473                 if(sa != "")
 474                         cvar_set("fraglimit", sa);
 475                 s = cdr(s);
 476         }
 477
 478         sa = car(s);
 479         if(sa != "")
 480                 cvar_set("timelimit", sa);
 481         s = cdr(s);
 482
 483         if(pWantedType.m_setTeams)
 484         {
 485                 sa = car(s);
 486                 if(sa != "")
 487                         pWantedType.m_setTeams(sa);
 488                 s = cdr(s);
 489         }
 490
 491         // rc = timelimit timelimit_qualification laps laps_teamplay
 492         if(pWantedType == MAPINFO_TYPE_RACE)
 493         {
 494                 cvar_set("fraglimit", "0"); // special case!
 495
 496                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 497                 cvar_set("g_race_qualifying_timelimit", sa);
 498                 s = cdr(s);
 499
 500                 sa = car(s);
 501                 if(sa != "")
 502                         if(cvar("g_race_teams") < 2)
 503                                 cvar_set("fraglimit", sa);
 504                 s = cdr(s);
 505
 506                 sa = car(s);
 507                 if(sa != "")
 508                         if(cvar("g_race_teams") >= 2)
 509                                 cvar_set("fraglimit", sa);
 510                 s = cdr(s);
 511         }
 512
 513         if(!pWantedType.frags) // these modes don't use fraglimit
 514         {
 515                 cvar_set("leadlimit", "0");
 516         }
 517         else
 518         {
 519                 sa = car(s);
 520                 if(sa != "")
 521                         cvar_set("leadlimit", sa);
 522                 s = cdr(s);
 523         }
 524 }
 525
 526 string _MapInfo_GetDefaultEx(Gametype t)
 527 {
 528         return t ? t.model2 : "";
 529 }
 530
 531 float _MapInfo_GetTeamPlayBool(Gametype t)
 532 {
 533         return t ? t.team : false;
 534 }
 535
 536 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 537 {
 538         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 539         if (!(pThisType.m_flags & pWantedType.m_flags))
 540                 return;
 541
 542         // reset all the cvars to their defaults
 543
 544         cvar_set("timelimit", cvar_defstring("timelimit"));
 545         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 546         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 547         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 548
 549         string fraglimit_normal = string_null;
 550         string fraglimit_teams = string_null;
 551
 552         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 553                 string sa = car(s);
 554                 if (sa == "") continue;
 555                 int p = strstrofs(sa, "=", 0);
 556                 if (p < 0) {
 557                         if(WARN_COND)
 558                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 559                         continue;
 560                 }
 561                 string k = substring(sa, 0, p);
 562                 string v = substring(sa, p + 1, -1);
 563                 bool handled = true;
 564                 switch (k) {
 565                         case "timelimit":
 566                         {
 567                                 cvar_set("timelimit", v);
 568                                 break;
 569                         }
 570                         case "leadlimit":
 571                         {
 572                                 cvar_set("leadlimit", v);
 573                                 break;
 574                         }
 575                         case "pointlimit":
 576                         case "fraglimit":
 577                         case "lives":
 578                         case "laplimit":
 579                         case "caplimit":
 580                         {
 581                                 fraglimit_normal = v;
 582                                 break;
 583                         }
 584                         case "teampointlimit":
 585                         case "teamlaplimit":
 586                         {
 587                                 fraglimit_teams = v;
 588                                 break;
 589                         }
 590                         default:
 591                         {
 592                             handled = false;
 593                             break;
 594                         }
 595                 }
 596                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 597                 if (!handled && WARN_COND)
 598             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 599         }
 600
 601         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 602         {
 603                 if(fraglimit_teams)
 604                         cvar_set("fraglimit", fraglimit_teams);
 605         }
 606         else
 607         {
 608                 if(fraglimit_normal)
 609                         cvar_set("fraglimit", fraglimit_normal);
 610         }
 611 }
 612
 613 Gametype MapInfo_Type_FromString(string gtype, bool dowarn, bool is_q3compat)
 614 {
 615         string replacement = "";
 616         bool do_warn = true;
 617         switch (gtype)
 618         {
 619                 case "nexball":   replacement = "nb"; break;
 620                 case "freezetag": replacement = "ft"; break;
 621                 case "keepaway":  replacement = "ka"; break;
 622                 case "invasion":  replacement = "inv"; break;
 623                 case "assault":   replacement = "as"; break;
 624                 case "race":      replacement = "rc"; break;
 625                 // quake 3 compat
 626                 case "ffa":       replacement = "dm"; do_warn = false; break;
 627                 case "cctf":
 628                 case "oneflag":   replacement = "ctf"; do_warn = false; break;
 629                 case "tournament":
 630                 case "tourney":   replacement = "duel"; do_warn = false; break;
 631                 case "arena":     if(is_q3compat) { replacement = "ca"; do_warn = false; } break;
 632         }
 633         if (replacement != "")
 634         {
 635                 if (dowarn && WARN_COND)
 636                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, gtype, replacement);
 637                 gtype = replacement;
 638         }
 639         FOREACH(Gametypes, it.mdl == gtype, return it);
 640         return NULL;
 641 }
 642
 643 string MapInfo_Type_Description(Gametype t)
 644 {
 645         return t ? t.gametype_description : "";
 646 }
 647
 648 string MapInfo_Type_ToString(Gametype t)
 649 {
 650         return t ? t.mdl : "";
 651 }
 652
 653 string MapInfo_Type_ToText(Gametype t)
 654 {
 655         /* xgettext:no-c-format */
 656         return t ? t.message : _("@!#%'n Tuba Throwing");
 657 }
 658
 659 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 660 {
 661         string t;
 662         float o;
 663         // tabs are invalid, treat them as "empty"
 664         s = strreplace("\t", "", s);
 665
 666         t = car(s); s = cdr(s);
 667
 668         // limited support of "" and comments
 669         //   remove trailing and leading " of t
 670         if(substring(t, 0, 1) == "\"")
 671         {
 672                 if(substring(t, -1, 1) == "\"")
 673                         t = substring(t, 1, -2);
 674         }
 675
 676         //   remove leading " of s
 677         if(substring(s, 0, 1) == "\"")
 678         {
 679                 s = substring(s, 1, -1);
 680         }
 681         //   remove trailing " of s, and all that follows (cvar description)
 682         o = strstrofs(s, "\"", 0);
 683         if(o >= 0)
 684                 s = substring(s, 0, o);
 685
 686         //   remove // comments
 687         o = strstrofs(s, "//", 0);
 688         if(o >= 0)
 689                 s = substring(s, 0, o);
 690
 691         //   remove trailing spaces
 692         while(substring(s, -1, 1) == " ")
 693                 s = substring(s, 0, -2);
 694
 695         if(t == "#include")
 696         {
 697                 if(recurse > 0)
 698                 {
 699                         float fh = fopen(s, FILE_READ);
 700                         if(fh < 0)
 701                         {
 702                                 if(WARN_COND)
 703                                         LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 704                         }
 705                         else
 706                         {
 707                                 while((s = fgets(fh)))
 708                                 {
 709                                         s = strreplace("\t", "", s); // treat tabs as "empty", perform here first to ensure coments are detected
 710                                         // catch different sorts of comments
 711                                         if(s == "")                    // empty lines
 712                                                 continue;
 713                                         if(substring(s, 0, 1) == "#")  // UNIX style
 714                                                 continue;
 715                                         if(substring(s, 0, 2) == "//") // C++ style
 716                                                 continue;
 717                                         if(substring(s, 0, 1) == "_")  // q3map style
 718                                                 continue;
 719
 720                                         if(substring(s, 0, 4) == "set ")
 721                                                 s = substring(s, 4, -1);
 722                                         if(substring(s, 0, 5) == "seta ")
 723                                                 s = substring(s, 5, -1);
 724
 725                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 726                                 }
 727                                 fclose(fh);
 728                         }
 729                 }
 730                 else if(WARN_COND)
 731                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 732         }
 733         else if(t == ""
 734                 || !cvar_value_issafe(t)
 735                 || !cvar_value_issafe(s)
 736                 || matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 737         {
 738                 if (WARN_COND)
 739                         LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 740         }
 741         else if(matchacl(acl, t) <= 0)
 742         {
 743                 if (WARN_COND)
 744                         LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 745         }
 746         else
 747         {
 748                 if(type == 0) // server set
 749                 {
 750                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 751                 #if 0
 752                         if(cvar("g_campaign"))
 753                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 754                         else
 755                 #endif
 756                                 cvar_settemp(t, s);
 757                 }
 758                 else
 759                 {
 760                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 761                         MapInfo_Map_clientstuff = strcat(
 762                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 763                                         );
 764                 }
 765         }
 766 }
 767
 768 float MapInfo_isRedundant(string fn, string t)
 769 {
 770         // normalize file name
 771         fn = strreplace("_", "", fn);
 772         fn = strreplace("-", "", fn);
 773
 774         // normalize visible title
 775         t = strreplace(":", "", t);
 776         t = strreplace(" ", "", t);
 777         t = strreplace("_", "", t);
 778         t = strreplace("-", "", t);
 779         t = strreplace("'", "", t);
 780         t = strdecolorize(t);
 781
 782         // we allow the visible title to have punctuation the file name does
 783         // not, but not vice versa
 784         if(!strcasecmp(fn, t))
 785                 return true;
 786
 787         return false;
 788 }
 789
 790 bool _MapInfo_ParseArena(string arena_filename, int fh, string pFilename, Gametype pGametypeToSet, bool isdefi, bool isgenerator)
 791 {
 792         // NOTE: .arena files can hold more than 1 map's information!
 793         // to handle this, we're going to store gathered information in local variables and save it if we encounter the correct map name
 794         bool in_brackets = false; // testing a potential mapinfo section (within brackets)
 795         bool dosave = false;
 796         string stored_Map_description = "";
 797         string stored_Map_title = "";
 798         string stored_Map_author = "";
 799         int stored_supportedGametypes = 0;
 800         int stored_supportedFeatures = 0;
 801         int stored_flags = 0;
 802         string t, s;
 803         for (;;)
 804         {
 805                 if (!((s = fgets(fh))))
 806                         break;
 807
 808                 // catch different sorts of comments
 809                 if(s == "")                    // empty lines
 810                         continue;
 811                 if(substring(s, 0, 2) == "//") // C++ style
 812                         continue;
 813                 if(strstrofs(s, "{", 0) >= 0)
 814                 {
 815                         if(in_brackets)
 816                                 return false; // edge case? already in a bracketed section!
 817                         in_brackets = true;
 818                         continue;
 819                 }
 820                 else if(!in_brackets)
 821                 {
 822                         // if we're not inside a bracket, don't process map info
 823                         continue;
 824                 }
 825                 if(strstrofs(s, "}", 0) >= 0)
 826                 {
 827                         if(!in_brackets)
 828                                 return false; // no starting bracket! let the mapinfo generation system handle it
 829                         in_brackets = false;
 830                         if(dosave)
 831                         {
 832                                 MapInfo_Map_description = stored_Map_description;
 833                                 if(stored_Map_title != "")
 834                                         MapInfo_Map_title = stored_Map_title;
 835                                 MapInfo_Map_author = stored_Map_author;
 836                                 if(isgenerator)
 837                                         MapInfo_Map_supportedGametypes = stored_supportedGametypes;
 838                                 else
 839                                 {
 840                                         FOREACH(Gametypes, it.m_flags & stored_supportedGametypes,
 841                                         {
 842                                                 _MapInfo_Map_ApplyGametype ("", pGametypeToSet, it, true);
 843                                         });
 844                                 }
 845                                 MapInfo_Map_supportedFeatures = stored_supportedFeatures;
 846                                 MapInfo_Map_flags = stored_flags;
 847                                 return true; // no need to continue through the file, we have our map!
 848                         }
 849                         else
 850                         {
 851                                 // discard any gathered locals, we're not using the correct map!
 852                                 stored_Map_description = "";
 853                                 stored_Map_title = "";
 854                                 stored_Map_author = "";
 855                                 stored_supportedGametypes = 0;
 856                                 stored_supportedFeatures = 0;
 857                                 stored_flags = 0;
 858                                 continue;
 859                         }
 860                 }
 861
 862                 s = strreplace("\t", " ", s);
 863
 864                 float p = strstrofs(s, "//", 0);
 865                 if(p >= 0)
 866                         s = substring(s, 0, p);
 867
 868                 // perform an initial trim to ensure the first argument is properly obtained
 869                 //   remove leading spaces
 870                 while(substring(s, 0, 1) == " ")
 871                         s = substring(s, 1, -1);
 872
 873                 t = car(s); s = cdr(s);
 874                 t = strtolower(t); // apparently some q3 maps use capitalized parameters
 875
 876                 //   remove trailing spaces
 877                 while(substring(t, -1, 1) == " ")
 878                         t = substring(t, 0, -2);
 879
 880                 //   remove trailing spaces
 881                 while(substring(s, -1, 1) == " ")
 882                         s = substring(s, 0, -2);
 883                 //   remove leading spaces
 884                 while(substring(s, 0, 1) == " ")
 885                         s = substring(s, 1, -1);
 886                 // limited support of ""
 887                 //   remove trailing and leading " of s
 888                 if(substring(s, 0, 1) == "\"")
 889                 {
 890                         if(substring(s, -1, 1) == "\"")
 891                                 s = substring(s, 1, -2);
 892                 }
 893                 if(t == "longname")
 894                         stored_Map_title = s;
 895                 else if(t == "author")
 896                         stored_Map_author = s;
 897                 else if(t == "type")
 898                 {
 899                         // if there is a valid gametype in this .arena file, include it in the menu
 900                         stored_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 901                         // type in quake 3 holds all the supported gametypes, so we must loop through all of them
 902                         // TODO: handle support here better to include more Xonotic teamplay modes
 903                         string types = strreplace("team", "tdm ft", s);
 904                         if(strstrofs(s, "tournament", 0) < 0 && strstrofs(s, "tdm", 0) >= 0) // larger team map, support additional gamemodes!
 905                                 types = cons(types, "ca kh");
 906                         FOREACH_WORD(types, true,
 907                         {
 908                                 Gametype f = MapInfo_Type_FromString(it, false, true);
 909                                 if(f)
 910                                         stored_supportedGametypes |= f.m_flags;
 911                         });
 912                 }
 913                 else if(t == "style" && isdefi)
 914                 {
 915                         // we have a defrag map on our hands, add CTS!
 916                         // TODO: styles
 917                         stored_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 918                 }
 919                 else if(t == "map")
 920                 {
 921                         if(strtolower(s) == strtolower(pFilename))
 922                                 dosave = true; // yay, found our map!
 923                 }
 924                 else if(t == "quote")
 925                         stored_Map_description = s;
 926                 // TODO: fraglimit
 927         }
 928
 929         // if the map wasn't found in the .arena, fall back to generated .mapinfo
 930         return false;
 931 }
 932
 933 #if defined(CSQC) || defined(MENUQC)
 934 string(string filename) whichpack = #503;
 935 #endif
 936 string _MapInfo_CheckArenaFile(string pFilename, string pMapname)
 937 {
 938         // returns the file name if valid, otherwise returns ""
 939         // a string is returned to optimise the use cases where a filename is also returned
 940         int fh = fopen(pFilename, FILE_READ);
 941         if(fh < 0)
 942                 return "";
 943         for(string s; (s = fgets(fh)); )
 944         {
 945                 s = strreplace("\t", "", s);
 946                 if(s == "")
 947                         continue;
 948                 while(substring(s, 0, 1) == " ")
 949                         s = substring(s, 1, -1);
 950                 if(substring(s, 0, 2) == "//")
 951                         continue;
 952                 int offset = strstrofs(s, "map", 0);
 953                 if(offset >= 0)
 954                 {
 955                         if(strstrofs(strtolower(s), strcat("\"", strtolower(pMapname), "\""), offset) >= 0) // quake 3 is case insensitive
 956                         {
 957                                 fclose(fh);
 958                                 return pFilename; // FOUND IT!
 959                         }
 960                 }
 961         }
 962         fclose(fh);
 963         return ""; // file did not contain a "map" field matching our map name
 964 }
 965
 966 string _MapInfo_FindArenaFile(string pFilename, string extension)
 967 {
 968         string fallback = strcat("scripts/", pFilename, extension);
 969         if(!checkextension("DP_QC_FS_SEARCH_PACKFILE"))
 970                 return _MapInfo_CheckArenaFile(fallback, pFilename);
 971         string base_pack = whichpack(strcat("maps/", pFilename, ".bsp"));
 972         if(base_pack == "") // this map isn't packaged!
 973                 return _MapInfo_CheckArenaFile(fallback, pFilename);
 974
 975         int glob = search_packfile_begin(strcat("scripts/*", extension), true, true, base_pack);
 976         if(glob < 0)
 977                 return _MapInfo_CheckArenaFile(fallback, pFilename);
 978         int n = search_getsize(glob);
 979         for(int j = 0; j < n; ++j)
 980         {
 981                 string file = search_getfilename(glob, j);
 982                 if(_MapInfo_CheckArenaFile(file, pFilename) != "")
 983                 {
 984                         search_end(glob);
 985                         return file;
 986                 }
 987         }
 988
 989         search_end(glob);
 990         return ""; // if we get here, a valid .arena file could not be found
 991 }
 992
 993 // load info about a map by name into the MapInfo_Map_* globals
 994 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
 995 {
 996         string fn;
 997         string s, t;
 998         float fh;
 999         int f, i;
1000         float r, n;
1001         string acl;
1002
1003         acl = MAPINFO_SETTEMP_ACL_USER;
1004
1005         if(strstrofs(pFilename, "/", 0) >= 0)
1006         {
1007                 LOG_WARN("Invalid character in map name, ignored");
1008                 return 0;
1009         }
1010
1011         if(pGametypeToSet == NULL)
1012                 if(MapInfo_Cache_Retrieve(pFilename))
1013                         return 1;
1014
1015         r = 1;
1016
1017         MapInfo_Map_bspname = pFilename;
1018
1019         // default all generic fields so they have "good" values in case something fails
1020         fn = strcat("maps/", pFilename, ".mapinfo");
1021         fh = fopen(fn, FILE_READ);
1022         if(fh < 0)
1023         {
1024                 if(autocvar_g_mapinfo_q3compat == 1) // use arena data instead of generating a mapinfo file
1025                 {
1026                         bool isdefi = false;
1027                         fn = _MapInfo_FindArenaFile(pFilename, ".arena");
1028                         if(fn != "")
1029                                 fh = fopen(fn, FILE_READ);
1030                         if(fh < 0)
1031                         {
1032                                 isdefi = true;
1033                                 fn = _MapInfo_FindArenaFile(pFilename, ".defi");
1034                                 if(fn != "")
1035                                         fh = fopen(fn, FILE_READ);
1036                         }
1037                         if(fh >= 0)
1038                         {
1039                                 _MapInfo_Map_Reset();
1040                                 if(_MapInfo_ParseArena(fn, fh, pFilename, pGametypeToSet, isdefi, false))
1041                                         goto mapinfo_handled; // skip generation
1042                         }
1043                 }
1044
1045                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
1046                 fh = fopen(fn, FILE_READ);
1047                 if(fh < 0)
1048                 {
1049                         if(!pAllowGenerate)
1050                                 return 0;
1051                         _MapInfo_Map_Reset();
1052                         r = _MapInfo_Generate(pFilename);
1053                         if(!r)
1054                                 return 0;
1055                         fh = fopen(fn, FILE_WRITE);
1056                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
1057                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
1058                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
1059                         if(_MapInfo_Map_worldspawn_music != "")
1060                         {
1061                                 if(strcasecmp(substring(_MapInfo_Map_worldspawn_music, -4, 4), ".wav") == 0 || strcasecmp(substring(_MapInfo_Map_worldspawn_music, -4, 4), ".ogg") == 0)
1062                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, -4), "\n"));
1063                                 else
1064                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
1065                         }
1066                         else
1067                         {
1068                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
1069                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
1070                                 for (;;)
1071                                 {
1072                                         i = floor(random() * n);
1073                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
1074                                                 break;
1075                                 }
1076                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
1077                         }
1078                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
1079                                 fputs(fh, "has weapons\n");
1080                         else
1081                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
1082                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
1083                                 fputs(fh, "has turrets\n");
1084                         else
1085                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
1086                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
1087                                 fputs(fh, "has vehicles\n");
1088                         else
1089                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
1090                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
1091                                 fputs(fh, "frustrating\n");
1092
1093                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
1094                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
1095                         });
1096
1097                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
1098                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
1099                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
1100                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
1101                         fputs(fh, "// optional: hidden\n");
1102
1103                         fclose(fh);
1104                         r = 2;
1105                         // return r;
1106                         fh = fopen(fn, FILE_READ);
1107                         if(fh < 0)
1108                                 error("... but I just wrote it!");
1109                 }
1110
1111                 if(WARN_COND)
1112                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
1113         }
1114
1115         _MapInfo_Map_Reset();
1116         for (;;)
1117         {
1118                 if (!((s = fgets(fh))))
1119                         break;
1120
1121                 // catch different sorts of comments
1122                 if(s == "")                    // empty lines
1123                         continue;
1124                 if(substring(s, 0, 1) == "#")  // UNIX style
1125                         continue;
1126                 if(substring(s, 0, 2) == "//") // C++ style
1127                         continue;
1128                 if(substring(s, 0, 1) == "_")  // q3map style
1129                         continue;
1130
1131                 float p = strstrofs(s, "//", 0);
1132                 if(p >= 0)
1133                         s = substring(s, 0, p);
1134
1135                 t = car(s); s = cdr(s);
1136                 if(t == "title")
1137                         MapInfo_Map_title = s;
1138                 else if(t == "description")
1139                         MapInfo_Map_description = s;
1140                 else if(t == "author")
1141                         MapInfo_Map_author = s;
1142                 else if(t == "has")
1143                 {
1144                         t = car(s); // s = cdr(s);
1145                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1146                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
1147                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
1148                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
1149                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
1150                         else if(WARN_COND)
1151                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
1152                 }
1153                 else if(t == "hidden")
1154                 {
1155                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
1156                 }
1157                 else if(t == "forbidden")
1158                 {
1159                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
1160                 }
1161                 else if(t == "frustrating")
1162                 {
1163                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
1164                 }
1165                 else if(t == "noautomaplist")
1166                 {
1167                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1168                 }
1169                 else if(t == "gameversion_min")
1170                 {
1171                         if (cvar("gameversion") < stof(s))
1172                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
1173                 }
1174                 else if(t == "type")
1175                 {
1176                         t = car(s); s = cdr(s);
1177                         Gametype f = MapInfo_Type_FromString(t, true, false);
1178                         //if(WARN_COND)
1179                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
1180                         if(f)
1181                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
1182                         else if(WARN_COND)
1183                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1184                 }
1185                 else if(t == "gametype")
1186                 {
1187                         t = car(s); s = cdr(s);
1188                         Gametype f = MapInfo_Type_FromString(t, true, false);
1189                         if(f)
1190                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
1191                         else if(WARN_COND)
1192                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
1193                 }
1194                 else if(t == "size")
1195                 {
1196                         float a, b, c, d, e;
1197                         t = car(s); s = cdr(s); a = stof(t);
1198                         t = car(s); s = cdr(s); b = stof(t);
1199                         t = car(s); s = cdr(s); c = stof(t);
1200                         t = car(s); s = cdr(s); d = stof(t);
1201                         t = car(s); s = cdr(s); e = stof(t);
1202                         if(s == "")
1203                         {
1204                                 if(WARN_COND)
1205                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1206                         }
1207                         else
1208                         {
1209                                 t = car(s); s = cdr(s); f = stof(t);
1210                                 if(s != "")
1211                                 {
1212                                         if(WARN_COND)
1213                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
1214                                 }
1215                                 else
1216                                 {
1217                                         if(a >= d || b >= e || c >= f)
1218                                         {
1219                                                 if(WARN_COND)
1220                                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
1221                                         }
1222                                         else
1223                                         {
1224                                                 MapInfo_Map_mins.x = a;
1225                                                 MapInfo_Map_mins.y = b;
1226                                                 MapInfo_Map_mins.z = c;
1227                                                 MapInfo_Map_maxs.x = d;
1228                                                 MapInfo_Map_maxs.y = e;
1229                                                 MapInfo_Map_maxs.z = f;
1230                                         }
1231                                 }
1232                         }
1233                 }
1234                 else if(t == "settemp_for_type")
1235                 {
1236                         t = car(s); s = cdr(s);
1237                         bool all = t == "all";
1238                         Gametype f = NULL;
1239                         if(all || (f = MapInfo_Type_FromString(t, true, false)))
1240                         {
1241                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1242                                 {
1243                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
1244                                 }
1245                         }
1246                         else
1247                         {
1248                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
1249                         }
1250                 }
1251                 else if(t == "clientsettemp_for_type")
1252                 {
1253                         t = car(s); s = cdr(s);
1254                         bool all = t == "all";
1255                         Gametype f = NULL;
1256                         if(all || (f = MapInfo_Type_FromString(t, true, false)))
1257                         {
1258                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1259                                 {
1260                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1261                                 }
1262                         }
1263                         else
1264                         {
1265                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1266                         }
1267                 }
1268                 else if(t == "fog")
1269                 {
1270                         if (!cvar_value_issafe(s))
1271                         {
1272                                 if(WARN_COND)
1273                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1274                         }
1275                         else
1276                                 MapInfo_Map_fog = s;
1277                 }
1278                 else if(t == "cdtrack")
1279                 {
1280                         t = car(s); s = cdr(s);
1281                         // We do this only if pGametypeToSet even though this
1282                         // content is theoretically game type independent,
1283                         // because MapInfo_Map_clientstuff contains otherwise
1284                         // game type dependent stuff. That way this value stays
1285                         // empty when not setting a game type to not set any
1286                         // false expectations.
1287                         if(pGametypeToSet)
1288                         {
1289                                 if (!cvar_value_issafe(t))
1290                                 {
1291                                         if(WARN_COND)
1292                                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1293                                 }
1294                                 else
1295                                         MapInfo_Map_clientstuff = strcat(
1296                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1297                                         );
1298                         }
1299                 }
1300                 else if(WARN_COND)
1301                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1302         }
1303         LABEL(mapinfo_handled)
1304         fclose(fh);
1305
1306         if(MapInfo_Map_title == "<TITLE>")
1307                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1308         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1309                 MapInfo_Map_titlestring = MapInfo_Map_title;
1310         else
1311                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1312
1313         MapInfo_Cache_Store();
1314         if(MapInfo_Map_supportedGametypes != 0)
1315                 return r;
1316         if (WARN_COND)
1317                 LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1318         return 0;
1319 }
1320 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1321 {
1322         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1323
1324         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1325
1326         if(pGametypeToSet)
1327         {
1328                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1329                 {
1330                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1331                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1332                         //return;
1333                 }
1334         }
1335
1336         return r;
1337 }
1338
1339 float MapInfo_FindName(string s)
1340 {
1341         // if there is exactly one map of prefix s, return it
1342         // if not, return the null string
1343         // note that DP sorts glob results... so I can use a binary search
1344         float l, r, m, cmp;
1345         l = 0;
1346         r = MapInfo_count;
1347         // invariants: r is behind s, l-1 is equal or before
1348         while(l != r)
1349         {
1350                 m = floor((l + r) / 2);
1351                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1352                 cmp = strcasecmp(MapInfo_FindName_match, s);
1353                 if(cmp == 0)
1354                         return m; // found and good
1355                 if(cmp < 0)
1356                         l = m + 1; // l-1 is before s
1357                 else
1358                         r = m; // behind s
1359         }
1360         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1361         MapInfo_FindName_firstResult = l;
1362         // r == l, so: l is behind s, l-1 is before
1363         // SO: if there is any, l is the one with the right prefix
1364         //     and l+1 may be one too
1365         if(l == MapInfo_count)
1366         {
1367                 MapInfo_FindName_match = string_null;
1368                 MapInfo_FindName_firstResult = -1;
1369                 return -1; // no MapInfo_FindName_match, behind last item
1370         }
1371         if(!startsWithNocase(MapInfo_FindName_match, s))
1372         {
1373                 MapInfo_FindName_match = string_null;
1374                 MapInfo_FindName_firstResult = -1;
1375                 return -1; // wrong prefix
1376         }
1377         if(l == MapInfo_count - 1)
1378                 return l; // last one, nothing can follow => unique
1379         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1380         {
1381                 MapInfo_FindName_match = string_null;
1382                 return -1; // ambigous MapInfo_FindName_match
1383         }
1384         return l;
1385 }
1386
1387 string MapInfo_FixName(string s)
1388 {
1389         MapInfo_FindName(s);
1390         return MapInfo_FindName_match;
1391 }
1392
1393 int MapInfo_CurrentFeatures()
1394 {
1395         int req = 0;
1396     // TODO: find a better way to check if weapons are required on the map
1397         if(!(cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || !cvar("g_melee_only")
1398                 || cvar("g_race") || cvar("g_cts") || cvar("g_nexball") || cvar("g_ca") || cvar("g_freezetag") || cvar("g_lms")))
1399                 req |= MAPINFO_FEATURE_WEAPONS;
1400         return req;
1401 }
1402
1403 Gametype MapInfo_CurrentGametype()
1404 {
1405         Gametype prev = MapInfo_Type_FromString(cvar_string("gamecfg"), false, false);
1406         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1407         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1408 }
1409
1410 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1411 {
1412         if(!MapInfo_Get_ByName(s, 1, NULL))
1413                 return 0;
1414         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1415                 return 0;
1416         if (gametype_only)
1417                 return 1;
1418         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1419                 return 0;
1420         return 1;
1421 }
1422
1423 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1424 {
1425         float r;
1426         r = _MapInfo_CheckMap(s, false);
1427         MapInfo_ClearTemps();
1428         return r;
1429 }
1430
1431 void MapInfo_SwitchGameType(Gametype t)
1432 {
1433         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1434 }
1435
1436 void MapInfo_LoadMap(string s, float reinit)
1437 {
1438         MapInfo_Map_supportedGametypes = 0;
1439         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1440         //if(!MapInfo_CheckMap(s))
1441         //{
1442         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1443         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1444         //}
1445
1446         LOG_INFO("Switching to map ", s);
1447
1448         cvar_settemp_restore();
1449         if(reinit)
1450                 localcmd(strcat("\nmap ", s, "\n"));
1451         else
1452                 localcmd(strcat("\nchangelevel ", s, "\n"));
1453 }
1454
1455 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1456 {
1457         string out;
1458
1459         // to make absolutely sure:
1460         MapInfo_Enumerate();
1461         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1462
1463         out = "";
1464         for(float i = 0; i < MapInfo_count; ++i)
1465                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1466         return substring(out, 1, strlen(out) - 1);
1467 }
1468
1469 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1470 {
1471         string out;
1472
1473         // to make absolutely sure:
1474         MapInfo_Enumerate();
1475         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1476
1477         out = "";
1478         for(float i = 0; i < MapInfo_count; ++i)
1479                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1480
1481         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1482
1483         return substring(out, 1, strlen(out) - 1);
1484 }
1485
1486 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1487 {
1488         MapInfo_SwitchGameType(t);
1489         cvar_set("gamecfg", t.mdl);
1490         MapInfo_LoadedGametype = t;
1491 }
1492
1493 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1494 {
1495         Gametype t = MapInfo_CurrentGametype();
1496         MapInfo_LoadMapSettings_SaveGameType(t);
1497
1498         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1499         {
1500                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1501                 {
1502                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1503                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1504                         return; // do not call Get_ByName!
1505                 }
1506
1507                 if(MapInfo_Map_supportedGametypes == 0)
1508                 {
1509                         RandomSelection_Init();
1510                         FOREACH(Gametypes, it.m_priority == 2,
1511                         {
1512                                 MapInfo_Map_supportedGametypes |= it.m_flags;
1513                                 RandomSelection_AddEnt(it, 1, 1);
1514                         });
1515                         if(RandomSelection_chosen_ent)
1516                                 t = RandomSelection_chosen_ent;
1517                         LOG_SEVEREF("Mapinfo system is not functional at all. Falling back to a preferred mode (%s).", t.mdl);
1518                         MapInfo_LoadMapSettings_SaveGameType(t);
1519                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1520                         return; // do not call Get_ByName!
1521                 }
1522
1523 #if 0
1524                 // find the lowest bit in the supported gametypes
1525                 // unnecessary now that we select one at random
1526                 int _t = 1;
1527                 while(!(MapInfo_Map_supportedGametypes & 1))
1528                 {
1529                         _t <<= 1;
1530                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1531                 }
1532 #endif
1533                 RandomSelection_Init();
1534                 Gametype t_prev = t;
1535                 FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags,
1536                 {
1537                         RandomSelection_AddEnt(it, 1, it.m_priority);
1538                 });
1539                 if(RandomSelection_chosen_ent)
1540                         t = RandomSelection_chosen_ent;
1541
1542                 // t is now a supported mode!
1543                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1544                 MapInfo_LoadMapSettings_SaveGameType(t);
1545         }
1546         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1547                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1548         }
1549         MapInfo_Get_ByName(s, 1, t);
1550 }
1551
1552 void MapInfo_ClearTemps()
1553 {
1554         MapInfo_Map_bspname = string_null;
1555         MapInfo_Map_title = string_null;
1556         MapInfo_Map_titlestring = string_null;
1557         MapInfo_Map_description = string_null;
1558         MapInfo_Map_author = string_null;
1559         MapInfo_Map_clientstuff = string_null;
1560         MapInfo_Map_supportedGametypes = 0;
1561         MapInfo_Map_supportedFeatures = 0;
1562 }
1563
1564 void MapInfo_Shutdown()
1565 {
1566         MapInfo_ClearTemps();
1567         MapInfo_Filter_Free();
1568         MapInfo_Cache_Destroy();
1569         if(_MapInfo_globopen)
1570         {
1571                 search_end(_MapInfo_globhandle);
1572                 _MapInfo_globhandle = -1;
1573                 _MapInfo_globopen = false;
1574         }
1575 }
1576
1577 int MapInfo_ForbiddenFlags()
1578 {
1579         int f = MAPINFO_FLAG_FORBIDDEN;
1580
1581 #ifdef GAMEQC
1582         if (!cvar("g_maplist_allow_hidden"))
1583 #endif
1584                 f |= MAPINFO_FLAG_HIDDEN;
1585
1586         if (!cvar("g_maplist_allow_frustrating"))
1587                 f |= MAPINFO_FLAG_FRUSTRATING;
1588
1589         return f;
1590 }
1591
1592 int MapInfo_RequiredFlags()
1593 {
1594         int f = 0;
1595
1596         if(cvar("g_maplist_allow_frustrating") > 1)
1597                 f |= MAPINFO_FLAG_FRUSTRATING;
1598
1599         return f;
1600 }