qcsrc/common/gamemodes/gamemode/tka/sv_tka.qc

   1 #include "sv_tka.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 .entity ballcarried;
   6
   7 int autocvar_g_tka_ballcarrier_effects;
   8 float autocvar_g_tka_ballcarrier_damage;
   9 float autocvar_g_tka_ballcarrier_force;
  10 float autocvar_g_tka_ballcarrier_highspeed;
  11 float autocvar_g_tka_ballcarrier_selfdamage;
  12 float autocvar_g_tka_ballcarrier_selfforce;
  13 float autocvar_g_tka_noncarrier_damage;
  14 float autocvar_g_tka_noncarrier_force;
  15 float autocvar_g_tka_noncarrier_selfdamage;
  16 float autocvar_g_tka_noncarrier_selfforce;
  17 bool autocvar_g_tka_noncarrier_warn;
  18 int autocvar_g_tka_score_bckill;
  19 int autocvar_g_tka_score_killac;
  20 bool autocvar_g_tka_score_team;
  21 int autocvar_g_tka_score_timepoints;
  22 float autocvar_g_tka_score_timeinterval;
  23 float autocvar_g_tkaball_damageforcescale;
  24 int autocvar_g_tkaball_effects;
  25 float autocvar_g_tkaball_respawntime;
  26 int autocvar_g_tkaball_trail_color;
  27
  28 bool tka_ballcarrier_waypointsprite_visible_for_player(entity this, entity player, entity view) // runs on waypoints which are attached to ballcarriers, updates once per frame
  29 {
  30         if(view.ballcarried)
  31                 if(IS_SPEC(player))
  32                         return false; // we don't want spectators of the ballcarrier to see the attached waypoint on the top of their screen
  33
  34         // TODO: Make the ballcarrier lack a waypointsprite whenever they have the invisibility powerup
  35
  36         return true;
  37 }
  38
  39 void tka_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  40 {
  41         if(autocvar_sv_eventlog)
  42                 GameLogEcho(strcat(":tka:", mode, ((actor != NULL) ? (strcat(":", ftos(actor.team), ":", ftos(actor.playerid))) : "")));
  43 }
  44
  45 void tka_TouchEvent(entity this, entity toucher);
  46 void tka_RespawnBall(entity this) // runs whenever the ball needs to be relocated
  47 {
  48         if(game_stopped) return;
  49         vector oldballorigin = this.origin;
  50
  51         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
  52                 setorigin(this, SelectSpawnPoint(this, true).origin);
  53
  54         set_movetype(this, MOVETYPE_BOUNCE);
  55         this.velocity = '0 0 200';
  56         this.angles = '0 0 0';
  57         this.effects = autocvar_g_tkaball_effects;
  58         settouch(this, tka_TouchEvent);
  59         setthink(this, tka_RespawnBall);
  60         this.nextthink = time + autocvar_g_tkaball_respawntime;
  61         navigation_dynamicgoal_set(this, NULL);
  62
  63         Send_Effect(EFFECT_ELECTRO_COMBO, oldballorigin, '0 0 0', 1);
  64         Send_Effect(EFFECT_ELECTRO_COMBO, this.origin, '0 0 0', 1);
  65
  66         WaypointSprite_Spawn(WP_KaBall, 0, 0, this, '0 0 64', NULL, this.team, this, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
  67         WaypointSprite_Ping(this.waypointsprite_attachedforcarrier);
  68
  69         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
  70 }
  71
  72 void tka_TimeScoring(entity this)
  73 {
  74         if(this.owner.ballcarried)
  75         { // add points for holding the ball after a certain amount of time
  76                 if(autocvar_g_tka_score_timepoints)
  77                         GameRules_scoring_add_team(this.owner, SCORE, autocvar_g_tka_score_timepoints);
  78
  79                 GameRules_scoring_add(this.owner, TKA_BCTIME, (autocvar_g_tka_score_timeinterval / 1)); // interval is divided by 1 so that time always shows "seconds"
  80                 this.nextthink = time + autocvar_g_tka_score_timeinterval;
  81         }
  82 }
  83
  84 void tka_TouchEvent(entity this, entity toucher) // runs any time that the ball comes in contact with something
  85 {
  86         if (!this || game_stopped)
  87                 return;
  88
  89         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  90         { // The ball fell off the map, respawn it since players can't get to it
  91                 tka_RespawnBall(this);
  92                 return;
  93         }
  94         if(toucher.ballcarried) { return; }
  95         if(IS_DEAD(toucher)) { return; }
  96         if(STAT(FROZEN, toucher)) { return; }
  97         if (!IS_PLAYER(toucher))
  98         {  // The ball just touched an object, most likely the world
  99                 Send_Effect(EFFECT_BALL_SPARKS, this.origin, '0 0 0', 1);
 100                 sound(this, CH_TRIGGER, SND_KA_TOUCH, VOL_BASE, ATTEN_NORM);
 101                 return;
 102         }
 103         else if(this.wait > time) { return; }
 104
 105         // attach the ball to the player
 106         this.owner = toucher;
 107         toucher.ballcarried = this;
 108         GameRules_scoring_vip(toucher, true);
 109         setattachment(this, toucher, "");
 110         setorigin(this, '0 0 0');
 111
 112         // make the ball invisible/unable to do anything/set up time scoring
 113         this.velocity = '0 0 0';
 114         set_movetype(this, MOVETYPE_NONE);
 115         this.effects |= EF_NODRAW;
 116         settouch(this, func_null);
 117         setthink(this, tka_TimeScoring);
 118         this.nextthink = time + autocvar_g_tka_score_timeinterval;
 119         this.takedamage = DAMAGE_NO;
 120         navigation_dynamicgoal_unset(this);
 121
 122         // apply effects to player
 123         toucher.glow_color = autocvar_g_tkaball_trail_color;
 124         toucher.glow_trail = true;
 125         toucher.effects |= autocvar_g_tka_ballcarrier_effects;
 126
 127         // messages and sounds
 128         tka_EventLog("pickup", toucher);
 129         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_PICKUP, toucher.netname);
 130         Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP, toucher.netname);
 131         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_KEEPAWAY_PICKUP_SELF);
 132         sound(this.owner, CH_TRIGGER, SND_KA_PICKEDUP, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 133
 134         // scoring
 135         GameRules_scoring_add(toucher, TKA_PICKUPS, 1);
 136
 137         // waypoints
 138         WaypointSprite_AttachCarrier(WP_Null, toucher, RADARICON_FLAGCARRIER);
 139         toucher.waypointsprite_attachedforcarrier.colormod = colormapPaletteColor(toucher.team - 1, 0);
 140         toucher.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = tka_ballcarrier_waypointsprite_visible_for_player;
 141         WaypointSprite_UpdateRule(toucher.waypointsprite_attachedforcarrier, toucher.team, SPRITERULE_TEAMPLAY);
 142         if(toucher.team == NUM_TEAM_1)
 143                 WaypointSprite_UpdateSprites(toucher.waypointsprite_attachedforcarrier, WP_TkaBallCarrierRed, WP_KaBallCarrier, WP_TkaBallCarrierRed);
 144         else if(toucher.team == NUM_TEAM_2)
 145                 WaypointSprite_UpdateSprites(toucher.waypointsprite_attachedforcarrier, WP_TkaBallCarrierBlue, WP_KaBallCarrier, WP_TkaBallCarrierBlue);
 146         else if(toucher.team == NUM_TEAM_3)
 147                 WaypointSprite_UpdateSprites(toucher.waypointsprite_attachedforcarrier, WP_TkaBallCarrierYellow, WP_KaBallCarrier, WP_TkaBallCarrierYellow);
 148         else if(toucher.team == NUM_TEAM_4)
 149                 WaypointSprite_UpdateSprites(toucher.waypointsprite_attachedforcarrier, WP_TkaBallCarrierPink, WP_KaBallCarrier, WP_TkaBallCarrierPink);
 150         WaypointSprite_Ping(toucher.waypointsprite_attachedforcarrier);
 151         WaypointSprite_Kill(this.waypointsprite_attachedforcarrier);
 152 }
 153
 154 void tka_PlayerReset(entity player)
 155 {
 156         player.ballcarried = NULL;
 157         GameRules_scoring_vip(player, false);
 158         WaypointSprite_Kill(player.waypointsprite_attachedforcarrier);
 159
 160         // reset the player effects
 161         player.glow_trail = false;
 162         player.effects &= ~autocvar_g_tka_ballcarrier_effects;
 163 }
 164
 165 void tka_DropEvent(entity player) // runs any time that a player is supposed to lose the ball
 166 {
 167         entity ball;
 168         ball = player.ballcarried;
 169
 170         if(!ball) { return; }
 171
 172         // reset the ball
 173         setattachment(ball, NULL, "");
 174         set_movetype(ball, MOVETYPE_BOUNCE);
 175         ball.wait = time + 1;
 176         settouch(ball, tka_TouchEvent);
 177         setthink(ball, tka_RespawnBall);
 178         ball.nextthink = time + autocvar_g_tkaball_respawntime;
 179         ball.takedamage = DAMAGE_YES;
 180         ball.effects &= ~EF_NODRAW;
 181         setorigin(ball, player.origin + '0 0 10');
 182         ball.velocity = '0 0 200' + '0 100 0'*crandom() + '100 0 0'*crandom();
 183         ball.owner = NULL;
 184         navigation_dynamicgoal_set(ball, player);
 185
 186         // messages and sounds
 187         tka_EventLog("dropped", player);
 188         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_KEEPAWAY_DROPPED, player.netname);
 189         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEEPAWAY_DROPPED, player.netname);
 190         sound(NULL, CH_TRIGGER, SND_KA_DROPPED, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 191
 192         // waypoints
 193         WaypointSprite_Spawn(WP_KaBall, 0, 0, ball, '0 0 64', NULL, ball.team, ball, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER);
 194         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 195         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 196
 197         tka_PlayerReset(player);
 198 }
 199
 200 .bool pushable;
 201
 202 MODEL(TKA_BALL, "models/orbs/orbblue.md3");
 203
 204 void tka_RemoveBalls()
 205 {
 206         IL_EACH(g_tkaballs, true,
 207         {
 208                 if (it.owner) // it was attached
 209                         tka_PlayerReset(it.owner);
 210                 else
 211                         WaypointSprite_DetachCarrier(it);
 212                 delete(it);
 213         });
 214 }
 215
 216 void tka_SpawnBalls()
 217 {
 218         int i = 0;
 219         do // never allow less than 1 ball to spawn
 220         {
 221                 entity e = new(keepawayball);
 222                 setmodel(e, MDL_TKA_BALL);
 223                 setsize(e, '-16 -16 -20', '16 16 20'); // 20 20 20 was too big, player is only 16 16 24... gotta cheat with the Z (20) axis so that the particle isn't cut off
 224                 e.damageforcescale = autocvar_g_tkaball_damageforcescale;
 225                 e.takedamage = DAMAGE_YES;
 226                 e.solid = SOLID_TRIGGER;
 227                 set_movetype(e, MOVETYPE_BOUNCE);
 228                 e.glow_color = autocvar_g_tkaball_trail_color;
 229                 e.glow_trail = true;
 230                 e.flags = FL_ITEM;
 231                 IL_PUSH(g_items, e);
 232                 e.pushable = true;
 233                 settouch(e, tka_TouchEvent);
 234                 e.owner = NULL;
 235                 IL_PUSH(g_tkaballs, e);
 236                 navigation_dynamicgoal_init(e, false);
 237
 238                 tka_RespawnBall(e);
 239
 240                 ++i;
 241         }
 242         while (i < TKA_BALL_COUNT);
 243 }
 244
 245 void tka_Handler_CheckBall(entity this)
 246 {
 247         if(time < game_starttime)
 248         {
 249                 if (!IL_EMPTY(g_tkaballs))
 250                         tka_RemoveBalls();
 251         }
 252         else
 253         {
 254                 if (IL_EMPTY(g_tkaballs))
 255                         tka_SpawnBalls();
 256         }
 257
 258         this.nextthink = time;
 259 }
 260
 261
 262 // ================
 263 // Bot player logic
 264 // ================
 265
 266 void havocbot_goalrating_tkaball(entity this, float ratingscale, vector org)
 267 {
 268         entity ball = NULL, ball_carried = NULL;
 269
 270         // stops at last ball, prefers ball without carrier
 271         IL_EACH(g_tkaballs, it.owner != this && DIFF_TEAM(ball.owner, this),
 272         {
 273                 if(it.owner)
 274                         ball_carried = it.owner;
 275                 else
 276                         ball = it;
 277         });
 278
 279         if (ball)
 280                 navigation_routerating(this, ball, ratingscale, 2000);
 281         else if(ball_carried)
 282                 navigation_routerating(this, ball_carried, ratingscale, 2000);
 283 }
 284
 285 void havocbot_role_tka_carrier(entity this)
 286 {
 287         if (IS_DEAD(this))
 288                 return;
 289
 290         if (navigation_goalrating_timeout(this))
 291         {
 292                 navigation_goalrating_start(this);
 293                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 294                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 295                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 296                 navigation_goalrating_end(this);
 297
 298                 navigation_goalrating_timeout_set(this);
 299         }
 300
 301         if (!this.ballcarried)
 302         {
 303                 this.havocbot_role = havocbot_role_tka_collector;
 304                 navigation_goalrating_timeout_expire(this, 2);
 305         }
 306 }
 307
 308 void havocbot_role_tka_collector(entity this)
 309 {
 310         if (IS_DEAD(this))
 311                 return;
 312
 313         if (navigation_goalrating_timeout(this))
 314         {
 315                 navigation_goalrating_start(this);
 316                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 317                 havocbot_goalrating_enemyplayers(this, 500, this.origin, 10000);
 318                 havocbot_goalrating_tkaball(this, 8000, this.origin);
 319                 navigation_goalrating_end(this);
 320
 321                 navigation_goalrating_timeout_set(this);
 322         }
 323
 324         if (this.ballcarried)
 325         {
 326                 this.havocbot_role = havocbot_role_tka_carrier;
 327                 navigation_goalrating_timeout_expire(this, 2);
 328         }
 329 }
 330
 331
 332 // ==============
 333 // Hook Functions
 334 // ==============
 335
 336 MUTATOR_HOOKFUNCTION(tka, PlayerDies)
 337 {
 338         entity frag_attacker = M_ARGV(1, entity);
 339         entity frag_target = M_ARGV(2, entity);
 340
 341         if(frag_attacker != frag_target && IS_PLAYER(frag_attacker) && DIFF_TEAM(frag_attacker, frag_target))
 342         {
 343                 bool team_has_ball = false;
 344                 IL_EACH(g_tkaballs, it.owner != frag_attacker && SAME_TEAM(it.owner, frag_attacker),
 345                 {
 346                         team_has_ball = true;
 347                         break;
 348                 });
 349                 if(frag_target.ballcarried) { // add to amount of times killing carrier
 350                         GameRules_scoring_add(frag_attacker, TKA_CARRIERKILLS, 1);
 351                         if(autocvar_g_tka_score_bckill) // add bckills to the score
 352                                 GameRules_scoring_add_team(frag_attacker, SCORE, autocvar_g_tka_score_bckill);
 353                 }
 354                 else if(!frag_attacker.ballcarried && !(autocvar_g_tka_score_team && team_has_ball))
 355                 {
 356                         if(autocvar_g_tka_noncarrier_warn)
 357                                 Send_Notification(NOTIF_ONE_ONLY, frag_attacker, MSG_CENTER, CENTER_KEEPAWAY_WARN);
 358                 }
 359
 360                 if(frag_attacker.ballcarried || (autocvar_g_tka_score_team && team_has_ball)) // add to amount of kills while ballcarrier (or if team scoring is enabled)
 361                         GameRules_scoring_add_team(frag_attacker, SCORE, autocvar_g_tka_score_killac);
 362         }
 363
 364         if(frag_target.ballcarried) { tka_DropEvent(frag_target); } // a player with the ball has died, drop it
 365 }
 366
 367 MUTATOR_HOOKFUNCTION(tka, GiveFragsForKill)
 368 {
 369         M_ARGV(2, float) = 0; // no frags counted in keepaway
 370         return true; // you deceptive little bugger ;3 This needs to be true in order for this function to even count.
 371 }
 372
 373 MUTATOR_HOOKFUNCTION(tka, Scores_CountFragsRemaining)
 374 {
 375         // announce remaining frags, but only when timed scoring is off
 376         return !autocvar_g_tka_score_timepoints;
 377 }
 378
 379 MUTATOR_HOOKFUNCTION(tka, PlayerPreThink)
 380 {
 381         entity player = M_ARGV(0, entity);
 382
 383         // clear the item used for the ball in keepaway
 384         STAT(TKA_BALLSTATUS, player) = 0;
 385
 386         // if the player has the ball, make sure they have the item for it (Used for HUD primarily)
 387         if(player.ballcarried)
 388                 STAT(TKA_BALLSTATUS, player) |= TKA_BALL_CARRYING;
 389
 390         IL_EACH(g_tkaballs, true,
 391         {
 392                 if(!it.owner)
 393                         STAT(TKA_BALLSTATUS, player) |= TKA_BALL_DROPPED;
 394                 else
 395                 {
 396                         // TODO: teamless carrier?
 397                         switch(it.owner.team)
 398                         {
 399                                 case NUM_TEAM_1: STAT(TKA_BALLSTATUS, player) |= TKA_BALL_TAKEN_RED; break;
 400                                 case NUM_TEAM_2: STAT(TKA_BALLSTATUS, player) |= TKA_BALL_TAKEN_BLUE; break;
 401                                 case NUM_TEAM_3: STAT(TKA_BALLSTATUS, player) |= TKA_BALL_TAKEN_YELLOW; break;
 402                                 case NUM_TEAM_4: STAT(TKA_BALLSTATUS, player) |= TKA_BALL_TAKEN_PINK; break;
 403                         }
 404                 }
 405         });
 406 }
 407
 408 MUTATOR_HOOKFUNCTION(tka, PlayerUseKey)
 409 {
 410         entity player = M_ARGV(0, entity);
 411
 412         if(MUTATOR_RETURNVALUE == 0)
 413         if(player.ballcarried)
 414         {
 415                 tka_DropEvent(player);
 416                 return true;
 417         }
 418 }
 419
 420 MUTATOR_HOOKFUNCTION(tka, Damage_Calculate) // for changing damage and force values that are applied to players
 421 {
 422         entity frag_attacker = M_ARGV(1, entity);
 423         entity frag_target = M_ARGV(2, entity);
 424         float frag_damage = M_ARGV(4, float);
 425         vector frag_force = M_ARGV(6, vector);
 426
 427         // as a gamemode rule, only apply scaling to player versus player combat
 428         if(!IS_PLAYER(frag_attacker) || !IS_PLAYER(frag_target))
 429                 return;
 430
 431         if(frag_attacker.ballcarried) // if the attacker is a ballcarrier
 432         {
 433                 if(frag_target == frag_attacker) // damage done to yourself
 434                 {
 435                         frag_damage *= autocvar_g_tka_ballcarrier_selfdamage;
 436                         frag_force *= autocvar_g_tka_ballcarrier_selfforce;
 437                 }
 438                 else // damage done to other ballcarriers
 439                 {
 440                         frag_damage *= autocvar_g_tka_ballcarrier_damage;
 441                         frag_force *= autocvar_g_tka_ballcarrier_force;
 442                 }
 443         }
 444         else // if the attacker is a noncarrier
 445         {
 446                 if(frag_target == frag_attacker) // damage done to yourself
 447                 {
 448                         frag_damage *= autocvar_g_tka_noncarrier_selfdamage;
 449                         frag_force *= autocvar_g_tka_noncarrier_selfforce;
 450                 }
 451                 else // damage done to other noncarriers
 452                 {
 453                         frag_damage *= autocvar_g_tka_noncarrier_damage;
 454                         frag_force *= autocvar_g_tka_noncarrier_force;
 455                 }
 456         }
 457
 458         M_ARGV(4, float) = frag_damage;
 459         M_ARGV(6, vector) = frag_force;
 460 }
 461
 462 MUTATOR_HOOKFUNCTION(tka, ClientDisconnect)
 463 {
 464         entity player = M_ARGV(0, entity);
 465
 466         if(player.ballcarried) { tka_DropEvent(player); } // a player with the ball has left the match, drop it
 467 }
 468
 469 MUTATOR_HOOKFUNCTION(tka, MakePlayerObserver)
 470 {
 471         entity player = M_ARGV(0, entity);
 472
 473         if(player.ballcarried) { tka_DropEvent(player); } // a player with the ball has left the match, drop it
 474 }
 475
 476 MUTATOR_HOOKFUNCTION(tka, PlayerPowerups)
 477 {
 478         entity player = M_ARGV(0, entity);
 479
 480         // In the future this hook is supposed to allow me to do some extra stuff with waypointsprites and invisibility powerup
 481         // So bare with me until I can fix a certain bug with tka_ballcarrier_waypointsprite_visible_for_player()
 482
 483         player.effects &= ~autocvar_g_tka_ballcarrier_effects;
 484
 485         if(player.ballcarried)
 486                 player.effects |= autocvar_g_tka_ballcarrier_effects;
 487 }
 488
 489
 490 MUTATOR_HOOKFUNCTION(tka, PlayerPhysics_UpdateStats)
 491 {
 492         entity player = M_ARGV(0, entity);
 493         // these automatically reset, no need to worry
 494
 495         if(player.ballcarried)
 496                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_tka_ballcarrier_highspeed;
 497 }
 498
 499 MUTATOR_HOOKFUNCTION(tka, BotShouldAttack)
 500 {
 501         entity bot = M_ARGV(0, entity);
 502         entity targ = M_ARGV(1, entity);
 503
 504         // if neither player has ball then don't attack unless the ball is on the ground
 505         bool have_held_ball = false, team_has_ball = false;
 506         IL_EACH(g_tkaballs, it.owner,
 507         {
 508                 have_held_ball = true;
 509                 if(SAME_TEAM(bot, it.owner))
 510                         team_has_ball = true;
 511         });
 512
 513         if(!targ.ballcarried && !bot.ballcarried && have_held_ball && !(autocvar_g_tka_score_team && team_has_ball))
 514                 return true;
 515 }
 516
 517 MUTATOR_HOOKFUNCTION(tka, HavocBot_ChooseRole)
 518 {
 519         entity bot = M_ARGV(0, entity);
 520
 521         if (bot.ballcarried)
 522                 bot.havocbot_role = havocbot_role_tka_carrier;
 523         else
 524                 bot.havocbot_role = havocbot_role_tka_collector;
 525         return true;
 526 }
 527
 528 MUTATOR_HOOKFUNCTION(tka, DropSpecialItems)
 529 {
 530         entity frag_target = M_ARGV(0, entity);
 531
 532         if(frag_target.ballcarried)
 533                 tka_DropEvent(frag_target);
 534 }
 535
 536 MUTATOR_HOOKFUNCTION(tka, SpectateCopy)
 537 {
 538         entity spectatee = M_ARGV(0, entity);
 539         entity client = M_ARGV(1, entity);
 540
 541         STAT(TKA_BALLSTATUS, client) = STAT(TKA_BALLSTATUS, spectatee);
 542 }
 543
 544 MUTATOR_HOOKFUNCTION(tka, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 545 {
 546         M_ARGV(0, float) = tka_teams;
 547         return true;
 548 }
 549
 550 void tka_Initialize()
 551 {
 552         tka_teams = autocvar_g_tka_teams_override;
 553         if(tka_teams < 2)
 554                 tka_teams = cvar("g_tka_teams"); // read the cvar directly as it gets written earlier in the same frame
 555         tka_teams = BITS(bound(2, tka_teams, 4));
 556         GameRules_scoring(tka_teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
 557                 field(SP_TKA_PICKUPS, "pickups", 0);
 558                 field(SP_TKA_CARRIERKILLS, "bckills", 0);
 559                 field(SP_TKA_BCTIME, "bctime", SFL_SORT_PRIO_SECONDARY);
 560         });
 561
 562         g_tkaballs = IL_NEW();
 563         entity tka_Handler = new_pure(tka_Handler);
 564         setthink(tka_Handler, tka_Handler_CheckBall);
 565         InitializeEntity(tka_Handler, tka_Handler_CheckBall, INITPRIO_GAMETYPE);
 566 }