qcsrc/common/gamemodes/gamemode/onslaught/sv_onslaught.qc

   1 #include "sv_onslaught.qh"
   2 #include "sv_controlpoint.qh"
   3 #include "sv_generator.qh"
   4
   5 bool g_onslaught;
   6
   7 float autocvar_g_onslaught_teleport_wait;
   8 bool autocvar_g_onslaught_spawn_at_controlpoints;
   9 bool autocvar_g_onslaught_spawn_at_generator;
  10 float autocvar_g_onslaught_cp_proxydecap;
  11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
  12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
  13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
  14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
  15 float autocvar_g_onslaught_spawn_at_generator_chance;
  16 float autocvar_g_onslaught_spawn_at_generator_random;
  17 float autocvar_g_onslaught_cp_buildhealth;
  18 float autocvar_g_onslaught_cp_buildtime;
  19 float autocvar_g_onslaught_cp_health;
  20 float autocvar_g_onslaught_cp_regen;
  21 float autocvar_g_onslaught_gen_health;
  22 float autocvar_g_onslaught_shield_force = 100;
  23 float autocvar_g_onslaught_allow_vehicle_touch;
  24 float autocvar_g_onslaught_round_timelimit;
  25 float autocvar_g_onslaught_warmup;
  26 float autocvar_g_onslaught_teleport_radius;
  27 float autocvar_g_onslaught_spawn_choose;
  28 float autocvar_g_onslaught_click_radius;
  29
  30 void FixSize(entity e);
  31 entity cam;
  32
  33 // =======================
  34 // CaptureShield Functions
  35 // =======================
  36
  37 bool clientcamera_send(entity this, entity to, int sf)
  38 {
  39         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
  40
  41         WriteCoord(MSG_ENTITY, this.origin_x);
  42         WriteCoord(MSG_ENTITY, this.origin_y);
  43         WriteCoord(MSG_ENTITY, this.origin_z);
  44
  45         WriteAngle(MSG_ENTITY, this.angles_x);
  46         WriteAngle(MSG_ENTITY, this.angles_y);
  47         WriteAngle(MSG_ENTITY, this.angles_z);
  48
  49         return true;
  50 }
  51
  52 bool ons_CaptureShield_Customize(entity this, entity client)
  53 {
  54         entity e = WaypointSprite_getviewentity(client);
  55
  56         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
  57         if(SAME_TEAM(this, e)) { return false; }
  58
  59         return true;
  60 }
  61
  62 void ons_CaptureShield_Touch(entity this, entity toucher)
  63 {
  64         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
  65         if(!IS_PLAYER(toucher)) { return; }
  66         if(SAME_TEAM(toucher, this)) { return; }
  67
  68         vector mymid = (this.absmin + this.absmax) * 0.5;
  69         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
  70
  71         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
  72
  73         if(IS_REAL_CLIENT(toucher))
  74         {
  75                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
  76
  77                 if(this.enemy.classname == "onslaught_generator")
  78                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
  79                 else
  80                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
  81         }
  82 }
  83
  84 void ons_CaptureShield_Reset(entity this)
  85 {
  86         this.colormap = this.enemy.colormap;
  87         this.team = this.enemy.team;
  88 }
  89
  90 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
  91 {
  92         entity shield = new(ons_captureshield);
  93         IL_PUSH(g_onsshields, shield);
  94
  95         shield.enemy = generator;
  96         shield.team = generator.team;
  97         shield.colormap = generator.colormap;
  98         shield.reset = ons_CaptureShield_Reset;
  99         settouch(shield, ons_CaptureShield_Touch);
 100         setcefc(shield, ons_CaptureShield_Customize);
 101         shield.effects = EF_ADDITIVE;
 102         set_movetype(shield, MOVETYPE_NOCLIP);
 103         shield.solid = SOLID_TRIGGER;
 104         shield.avelocity = '7 0 11';
 105         shield.scale = 1;
 106         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
 107
 108         precache_model(shield.model);
 109         setorigin(shield, generator.origin);
 110         _setmodel(shield, shield.model);
 111         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 112 }
 113
 114
 115 // ==========
 116 // Junk Pile
 117 // ==========
 118
 119 void setmodel_fixsize(entity e, Model m)
 120 {
 121         setmodel(e, m);
 122         FixSize(e);
 123 }
 124
 125 void onslaught_updatelinks()
 126 {
 127         entity l;
 128         // first check if the game has ended
 129         LOG_DEBUG("--- updatelinks ---");
 130         // mark generators as being shielded and networked
 131         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 132         {
 133                 if (l.iscaptured)
 134                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
 135                 else
 136                         LOG_DEBUG(etos(l), " (generator) is destroyed");
 137                 l.islinked = l.iscaptured;
 138                 l.isshielded = l.iscaptured;
 139                 l.sprite.SendFlags |= 16;
 140         }
 141         // mark points as shielded and not networked
 142         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 143         {
 144                 l.islinked = false;
 145                 l.isshielded = true;
 146                 int i;
 147                 for(i = 0; i < 17; ++i) { l.isgenneighbor[i] = false; l.iscpneighbor[i] = false; }
 148                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
 149                 l.sprite.SendFlags |= 16;
 150         }
 151         // flow power outward from the generators through the network
 152         bool stop = false;
 153         while (!stop)
 154         {
 155                 stop = true;
 156                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 157                 {
 158                         // if both points are captured by the same team, and only one of
 159                         // them is powered, mark the other one as powered as well
 160                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
 161                                 if (l.enemy.islinked != l.goalentity.islinked)
 162                                         if(SAME_TEAM(l.enemy, l.goalentity))
 163                                         {
 164                                                 if (!l.goalentity.islinked)
 165                                                 {
 166                                                         stop = false;
 167                                                         l.goalentity.islinked = true;
 168                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
 169                                                 }
 170                                                 else if (!l.enemy.islinked)
 171                                                 {
 172                                                         stop = false;
 173                                                         l.enemy.islinked = true;
 174                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
 175                                                 }
 176                                         }
 177                 }
 178         }
 179         // now that we know which points are powered we can mark their neighbors
 180         // as unshielded if team differs
 181         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 182         {
 183                 if (l.goalentity.islinked)
 184                 {
 185                         if(DIFF_TEAM(l.goalentity, l.enemy))
 186                         {
 187                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
 188                                 l.enemy.isshielded = false;
 189                         }
 190                         if(l.goalentity.classname == "onslaught_generator")
 191                                 l.enemy.isgenneighbor[l.goalentity.team] = true;
 192                         else
 193                                 l.enemy.iscpneighbor[l.goalentity.team] = true;
 194                 }
 195                 if (l.enemy.islinked)
 196                 {
 197                         if(DIFF_TEAM(l.goalentity, l.enemy))
 198                         {
 199                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
 200                                 l.goalentity.isshielded = false;
 201                         }
 202                         if(l.enemy.classname == "onslaught_generator")
 203                                 l.goalentity.isgenneighbor[l.enemy.team] = true;
 204                         else
 205                                 l.goalentity.iscpneighbor[l.enemy.team] = true;
 206                 }
 207         }
 208         // now update the generators
 209         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 210         {
 211                 if (l.isshielded)
 212                 {
 213                         LOG_DEBUG(etos(l), " (generator) is shielded");
 214                         l.takedamage = DAMAGE_NO;
 215                         if(l.bot_attack)
 216                                 IL_REMOVE(g_bot_targets, l);
 217                         l.bot_attack = false;
 218                 }
 219                 else
 220                 {
 221                         LOG_DEBUG(etos(l), " (generator) is not shielded");
 222                         l.takedamage = DAMAGE_AIM;
 223                         if(!l.bot_attack)
 224                                 IL_PUSH(g_bot_targets, l);
 225                         l.bot_attack = true;
 226                 }
 227
 228                 ons_Generator_UpdateSprite(l);
 229         }
 230         // now update the takedamage and alpha variables on control point icons
 231         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 232         {
 233                 if (l.isshielded)
 234                 {
 235                         LOG_DEBUG(etos(l), " (point) is shielded");
 236                         if (l.goalentity)
 237                         {
 238                                 l.goalentity.takedamage = DAMAGE_NO;
 239                                 if(l.goalentity.bot_attack)
 240                                         IL_REMOVE(g_bot_targets, l.goalentity);
 241                                 l.goalentity.bot_attack = false;
 242                         }
 243                 }
 244                 else
 245                 {
 246                         LOG_DEBUG(etos(l), " (point) is not shielded");
 247                         if (l.goalentity)
 248                         {
 249                                 l.goalentity.takedamage = DAMAGE_AIM;
 250                                 if(!l.goalentity.bot_attack)
 251                                         IL_PUSH(g_bot_targets, l.goalentity);
 252                                 l.goalentity.bot_attack = true;
 253                         }
 254                 }
 255                 ons_ControlPoint_UpdateSprite(l);
 256         }
 257         IL_EACH(g_onsshields, true,
 258         {
 259                 it.team = it.enemy.team;
 260                 it.colormap = it.enemy.colormap;
 261         });
 262 }
 263
 264
 265 // ===================
 266 // Main Link Functions
 267 // ===================
 268
 269 bool ons_Link_Send(entity this, entity to, int sendflags)
 270 {
 271         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 272         WriteByte(MSG_ENTITY, sendflags);
 273         if(sendflags & 1)
 274         {
 275                 WriteCoord(MSG_ENTITY, this.goalentity.origin_x);
 276                 WriteCoord(MSG_ENTITY, this.goalentity.origin_y);
 277                 WriteCoord(MSG_ENTITY, this.goalentity.origin_z);
 278         }
 279         if(sendflags & 2)
 280         {
 281                 WriteCoord(MSG_ENTITY, this.enemy.origin_x);
 282                 WriteCoord(MSG_ENTITY, this.enemy.origin_y);
 283                 WriteCoord(MSG_ENTITY, this.enemy.origin_z);
 284         }
 285         if(sendflags & 4)
 286         {
 287                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
 288         }
 289         return true;
 290 }
 291
 292 void ons_Link_CheckUpdate(entity this)
 293 {
 294         // TODO check if the two sides have moved (currently they won't move anyway)
 295         float cc = 0, cc1 = 0, cc2 = 0;
 296
 297         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
 298         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
 299
 300         cc = cc1 + cc2;
 301
 302         if(cc != this.clientcolors)
 303         {
 304                 this.clientcolors = cc;
 305                 this.SendFlags |= 4;
 306         }
 307
 308         this.nextthink = time;
 309 }
 310
 311 void ons_DelayedLinkSetup(entity this)
 312 {
 313         this.goalentity = find(NULL, targetname, this.target);
 314         this.enemy = find(NULL, targetname, this.target2);
 315         if(!this.goalentity) { objerror(this, "can not find target\n"); }
 316         if(!this.enemy) { objerror(this, "can not find target2\n"); }
 317
 318         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
 319         this.SendFlags |= 3;
 320         setthink(this, ons_Link_CheckUpdate);
 321         this.nextthink = time;
 322 }
 323
 324
 325 // =============================
 326 // Main Control Point Functions
 327 // =============================
 328
 329 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
 330 {
 331         if(cp.isgenneighbor[teamnumber]) { return 2; }
 332         if(cp.iscpneighbor[teamnumber]) { return 1; }
 333
 334         return 0;
 335 }
 336
 337 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
 338         // -2: SAME TEAM, attackable by enemy!
 339         // -1: SAME TEAM!
 340         // 0: off limits
 341         // 1: attack it
 342         // 2: touch it
 343         // 3: attack it (HIGH PRIO)
 344         // 4: touch it (HIGH PRIO)
 345 {
 346         int a;
 347
 348         if(cp.isshielded)
 349         {
 350                 return 0;
 351         }
 352         else if(cp.goalentity)
 353         {
 354                 // if there's already an icon built, nothing happens
 355                 if(cp.team == teamnumber)
 356                 {
 357                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 358                         if(a) // attackable by enemy?
 359                                 return -2; // EMERGENCY!
 360                         return -1;
 361                 }
 362                 // we know it can be linked, so no need to check
 363                 // but...
 364                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 365                 if(a == 2) // near our generator?
 366                         return 3; // EMERGENCY!
 367                 return 1;
 368         }
 369         else
 370         {
 371                 // free point
 372                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
 373                 {
 374                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
 375                         if(a == 2)
 376                                 return 4; // GET THIS ONE NOW!
 377                         else
 378                                 return 2; // TOUCH ME
 379                 }
 380         }
 381         return 0;
 382 }
 383
 384 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 385 {
 386         if(damage <= 0) { return; }
 387
 388         if (this.owner.isshielded)
 389         {
 390                 // this is protected by a shield, so ignore the damage
 391                 if (time > this.pain_finished)
 392                         if (IS_PLAYER(attacker))
 393                         {
 394                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 395                                 this.pain_finished = time + 1;
 396                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
 397                         }
 398
 399                 return;
 400         }
 401
 402         if(IS_PLAYER(attacker))
 403         if(time - ons_notification_time[this.team] > 10)
 404         {
 405                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
 406                 ons_notification_time[this.team] = time;
 407         }
 408
 409         this.health = this.health - damage;
 410         if(this.owner.iscaptured)
 411                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 412         else
 413                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - this.health) / (this.count / ONS_CP_THINKRATE));
 414         this.pain_finished = time + 1;
 415         // particles on every hit
 416         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
 417         //sound on every hit
 418         if (random() < 0.5)
 419                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
 420         else
 421                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
 422
 423         if (this.health < 0)
 424         {
 425                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
 426                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 427                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
 428
 429                 PlayerScore_Add(attacker, SP_ONS_TAKES, 1);
 430                 PlayerScore_Add(attacker, SP_SCORE, 10);
 431
 432                 this.owner.goalentity = NULL;
 433                 this.owner.islinked = false;
 434                 this.owner.iscaptured = false;
 435                 this.owner.team = 0;
 436                 this.owner.colormap = 1024;
 437
 438                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
 439
 440                 onslaught_updatelinks();
 441
 442                 // Use targets now (somebody make sure this is in the right place..)
 443                 SUB_UseTargets(this.owner, this, NULL);
 444
 445                 this.owner.waslinked = this.owner.islinked;
 446                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
 447                         setmodel_fixsize(this.owner, MDL_ONS_CP_PAD1);
 448                 //setsize(this, '-32 -32 0', '32 32 8');
 449
 450                 delete(this);
 451         }
 452
 453         this.SendFlags |= CPSF_STATUS;
 454 }
 455
 456 void ons_ControlPoint_Icon_Think(entity this)
 457 {
 458         this.nextthink = time + ONS_CP_THINKRATE;
 459
 460         if(autocvar_g_onslaught_cp_proxydecap)
 461         {
 462                 int _enemy_count = 0;
 463                 int _friendly_count = 0;
 464
 465                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
 466                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
 467                         {
 468                                 if(SAME_TEAM(it, this))
 469                                         ++_friendly_count;
 470                                 else
 471                                         ++_enemy_count;
 472                         }
 473                 });
 474
 475                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 476                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 477
 478                 this.health = bound(0, this.health + (_friendly_count - _enemy_count), this.max_health);
 479                 this.SendFlags |= CPSF_STATUS;
 480                 if(this.health <= 0)
 481                 {
 482                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, this.origin, '0 0 0');
 483                         return;
 484                 }
 485         }
 486
 487         if (time > this.pain_finished + 5)
 488         {
 489                 if(this.health < this.max_health)
 490                 {
 491                         this.health = this.health + this.count;
 492                         if (this.health >= this.max_health)
 493                                 this.health = this.max_health;
 494                         WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 495                 }
 496         }
 497
 498         if(this.owner.islinked != this.owner.waslinked)
 499         {
 500                 // unteam the spawnpoint if needed
 501                 int t = this.owner.team;
 502                 if(!this.owner.islinked)
 503                         this.owner.team = 0;
 504
 505                 SUB_UseTargets(this.owner, this, NULL);
 506
 507                 this.owner.team = t;
 508
 509                 this.owner.waslinked = this.owner.islinked;
 510         }
 511
 512         // damaged fx
 513         if(random() < 0.6 - this.health / this.max_health)
 514         {
 515                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
 516
 517                 if(random() > 0.8)
 518                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
 519                 else if (random() > 0.5)
 520                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
 521         }
 522 }
 523
 524 void ons_ControlPoint_Icon_BuildThink(entity this)
 525 {
 526         int a;
 527
 528         this.nextthink = time + ONS_CP_THINKRATE;
 529
 530         // only do this if there is power
 531         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
 532         if(!a)
 533                 return;
 534
 535         this.health = this.health + this.count;
 536
 537         this.SendFlags |= CPSF_STATUS;
 538
 539         if (this.health >= this.max_health)
 540         {
 541                 this.health = this.max_health;
 542                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
 543                 setthink(this, ons_ControlPoint_Icon_Think);
 544                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
 545                 this.owner.iscaptured = true;
 546                 this.solid = SOLID_BBOX;
 547
 548                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
 549
 550                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
 551                 WaypointSprite_UpdateHealth(this.owner.sprite, this.health);
 552
 553                 if(IS_PLAYER(this.owner.ons_toucher))
 554                 {
 555                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
 556                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE), this.owner.message);
 557                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
 558                         PlayerScore_Add(this.owner.ons_toucher, SP_ONS_CAPS, 1);
 559                         PlayerTeamScore_AddScore(this.owner.ons_toucher, 10);
 560                 }
 561
 562                 this.owner.ons_toucher = NULL;
 563
 564                 onslaught_updatelinks();
 565
 566                 // Use targets now (somebody make sure this is in the right place..)
 567                 SUB_UseTargets(this.owner, this, NULL);
 568
 569                 this.SendFlags |= CPSF_SETUP;
 570         }
 571         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
 572                 setmodel_fixsize(this.owner, MDL_ONS_CP_PAD2);
 573
 574         if(random() < 0.9 - this.health / this.max_health)
 575                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
 576 }
 577
 578 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
 579
 580 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
 581 {
 582         entity e = new(onslaught_controlpoint_icon);
 583
 584         setsize(e, CPICON_MIN, CPICON_MAX);
 585         setorigin(e, cp.origin + CPICON_OFFSET);
 586
 587         e.owner = cp;
 588         e.max_health = autocvar_g_onslaught_cp_health;
 589         e.health = autocvar_g_onslaught_cp_buildhealth;
 590         e.solid = SOLID_NOT;
 591         e.takedamage = DAMAGE_AIM;
 592         e.bot_attack = true;
 593         IL_PUSH(g_bot_targets, e);
 594         e.event_damage = ons_ControlPoint_Icon_Damage;
 595         e.team = player.team;
 596         e.colormap = 1024 + (e.team - 1) * 17;
 597         e.count = (e.max_health - e.health) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
 598
 599         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
 600
 601         cp.goalentity = e;
 602         cp.team = e.team;
 603         cp.colormap = e.colormap;
 604
 605         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
 606
 607         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - e.health) / (e.count / ONS_CP_THINKRATE));
 608         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
 609         cp.sprite.SendFlags |= 16;
 610
 611         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
 612 }
 613
 614 entity ons_ControlPoint_Waypoint(entity e)
 615 {
 616         if(e.team)
 617         {
 618                 int a = ons_ControlPoint_Attackable(e, e.team);
 619
 620                 if(a == -2) { return WP_OnsCPDefend; } // defend now
 621                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
 622                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
 623         }
 624         else
 625                 return WP_OnsCP;
 626
 627         return WP_Null;
 628 }
 629
 630 void ons_ControlPoint_UpdateSprite(entity e)
 631 {
 632         entity s1 = ons_ControlPoint_Waypoint(e);
 633         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 634
 635         bool sh;
 636         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
 637
 638         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
 639         {
 640                 if(e.iscaptured) // don't mess up build bars!
 641                 {
 642                         if(sh)
 643                         {
 644                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
 645                         }
 646                         else
 647                         {
 648                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
 649                                 WaypointSprite_UpdateHealth(e.sprite, e.goalentity.health);
 650                         }
 651                 }
 652                 if(e.lastshielded)
 653                 {
 654                         if(e.team)
 655                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
 656                         else
 657                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 658                 }
 659                 else
 660                 {
 661                         if(e.team)
 662                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
 663                         else
 664                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 665                 }
 666                 WaypointSprite_Ping(e.sprite);
 667
 668                 e.lastteam = e.team + 2;
 669                 e.lastshielded = sh;
 670                 e.lastcaptured = e.iscaptured;
 671         }
 672 }
 673
 674 void ons_ControlPoint_Touch(entity this, entity toucher)
 675 {
 676         int attackable;
 677
 678         if(IS_VEHICLE(toucher) && toucher.owner)
 679         if(autocvar_g_onslaught_allow_vehicle_touch)
 680                 toucher = toucher.owner;
 681         else
 682                 return;
 683
 684         if(!IS_PLAYER(toucher)) { return; }
 685         if(STAT(FROZEN, toucher)) { return; }
 686         if(IS_DEAD(toucher)) { return; }
 687
 688         if ( SAME_TEAM(this,toucher) )
 689         if ( this.iscaptured )
 690         {
 691                 if(time <= toucher.teleport_antispam)
 692                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
 693                 else
 694                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
 695         }
 696
 697         attackable = ons_ControlPoint_Attackable(this, toucher.team);
 698         if(attackable != 2 && attackable != 4)
 699                 return;
 700         // we've verified that this player has a legitimate claim to this point,
 701         // so start building the captured point icon (which only captures this
 702         // point if it successfully builds without being destroyed first)
 703         ons_ControlPoint_Icon_Spawn(this, toucher);
 704
 705         this.ons_toucher = toucher;
 706
 707         onslaught_updatelinks();
 708 }
 709
 710 void ons_ControlPoint_Think(entity this)
 711 {
 712         this.nextthink = time + ONS_CP_THINKRATE;
 713         CSQCMODEL_AUTOUPDATE(this);
 714 }
 715
 716 void ons_ControlPoint_Reset(entity this)
 717 {
 718         if(this.goalentity)
 719                 delete(this.goalentity);
 720
 721         this.goalentity = NULL;
 722         this.team = 0;
 723         this.colormap = 1024;
 724         this.iscaptured = false;
 725         this.islinked = false;
 726         this.isshielded = true;
 727         setthink(this, ons_ControlPoint_Think);
 728         this.ons_toucher = NULL;
 729         this.nextthink = time + ONS_CP_THINKRATE;
 730         setmodel_fixsize(this, MDL_ONS_CP_PAD1);
 731
 732         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 733         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 734
 735         onslaught_updatelinks();
 736
 737         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
 738
 739         CSQCMODEL_AUTOUPDATE(this);
 740 }
 741
 742 void ons_DelayedControlPoint_Setup(entity this)
 743 {
 744         onslaught_updatelinks();
 745
 746         // captureshield setup
 747         ons_CaptureShield_Spawn(this, false);
 748
 749         CSQCMODEL_AUTOINIT(this);
 750 }
 751
 752 void ons_ControlPoint_Setup(entity cp)
 753 {
 754         // main setup
 755         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
 756         ons_worldcplist = cp;
 757
 758         cp.netname = "Control point";
 759         cp.team = 0;
 760         cp.solid = SOLID_BBOX;
 761         set_movetype(cp, MOVETYPE_NONE);
 762         settouch(cp, ons_ControlPoint_Touch);
 763         setthink(cp, ons_ControlPoint_Think);
 764         cp.nextthink = time + ONS_CP_THINKRATE;
 765         cp.reset = ons_ControlPoint_Reset;
 766         cp.colormap = 1024;
 767         cp.iscaptured = false;
 768         cp.islinked = false;
 769         cp.isshielded = true;
 770
 771         if(cp.message == "") { cp.message = "a"; }
 772
 773         // appearence
 774         setmodel_fixsize(cp, MDL_ONS_CP_PAD1);
 775
 776         // control point placement
 777         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
 778         {
 779                 cp.noalign = true;
 780                 set_movetype(cp, MOVETYPE_NONE);
 781         }
 782         else // drop to floor, automatically find a platform and set that as spawn origin
 783         {
 784                 setorigin(cp, cp.origin + '0 0 20');
 785                 cp.noalign = false;
 786                 droptofloor(cp);
 787                 set_movetype(cp, MOVETYPE_TOSS);
 788         }
 789
 790         // waypointsprites
 791         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
 792         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
 793
 794         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
 795 }
 796
 797
 798 // =========================
 799 // Main Generator Functions
 800 // =========================
 801
 802 entity ons_Generator_Waypoint(entity e)
 803 {
 804         if (e.isshielded)
 805                 return WP_OnsGenShielded;
 806         return WP_OnsGen;
 807 }
 808
 809 void ons_Generator_UpdateSprite(entity e)
 810 {
 811         entity s1 = ons_Generator_Waypoint(e);
 812         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 813
 814         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 815         {
 816                 e.lastteam = e.team + 2;
 817                 e.lastshielded = e.isshielded;
 818                 if(e.lastshielded)
 819                 {
 820                         if(e.team)
 821                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
 822                         else
 823                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 824                 }
 825                 else
 826                 {
 827                         if(e.team)
 828                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
 829                         else
 830                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 831                 }
 832                 WaypointSprite_Ping(e.sprite);
 833         }
 834 }
 835
 836 void ons_camSetup(entity this)
 837 {
 838         vector dir;
 839         vector ang = '0 0 0';
 840         vector best_ang = '0 0 0';
 841         float best_trace_fraction = 0;
 842         while(ang.y < 360)
 843         {
 844                 dir = eX * cos(ang.y * DEG2RAD) + eY * sin(ang.y * DEG2RAD);
 845                 dir *= 500;
 846                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
 847                 if(trace_fraction > best_trace_fraction)
 848                 {
 849                         best_trace_fraction = trace_fraction;
 850                         best_ang = ang;
 851                         if(trace_fraction == 1)
 852                                 break;
 853                 }
 854                 ang.y += 90;
 855                 if(ang.y == 360)
 856                         ang.y = 45;
 857         }
 858         cam.origin = this.origin;
 859         setorigin(cam, cam.origin);
 860         cam.angles = best_ang;
 861         Net_LinkEntity(cam, false, 0, clientcamera_send);
 862
 863         FOREACH_CLIENT(true, it.clientcamera = cam;);
 864
 865         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
 866         WriteAngle(MSG_ALL, cam.angles_x);
 867         WriteAngle(MSG_ALL, cam.angles_y);
 868         WriteAngle(MSG_ALL, cam.angles_z);
 869 }
 870
 871 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 872 {
 873         if(damage <= 0) { return; }
 874         if(warmup_stage || gameover) { return; }
 875         if(!round_handler_IsRoundStarted()) { return; }
 876
 877         if (attacker != this)
 878         {
 879                 if (this.isshielded)
 880                 {
 881                         // generator is protected by a shield, so ignore the damage
 882                         if (time > this.pain_finished)
 883                                 if (IS_PLAYER(attacker))
 884                                 {
 885                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 886                                         attacker.typehitsound += 1;
 887                                         this.pain_finished = time + 1;
 888                                 }
 889                         return;
 890                 }
 891                 if (time > this.pain_finished)
 892                 {
 893                         this.pain_finished = time + 10;
 894                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
 895                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
 896                 }
 897         }
 898         this.health = this.health - damage;
 899         WaypointSprite_UpdateHealth(this.sprite, this.health);
 900         // choose an animation frame based on health
 901         this.frame = 10 * bound(0, (1 - this.health / this.max_health), 1);
 902         // see if the generator is still functional, or dying
 903         if (this.health > 0)
 904         {
 905                 this.lasthealth = this.health;
 906         }
 907         else
 908         {
 909                 if (attacker == this)
 910                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
 911                 else
 912                 {
 913                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
 914                         PlayerScore_Add(attacker, SP_SCORE, 100);
 915                 }
 916                 this.iscaptured = false;
 917                 this.islinked = false;
 918                 this.isshielded = false;
 919                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
 920                 this.event_damage = func_null; // won't do anything if hurt
 921                 this.count = 0; // reset counter
 922                 setthink(this, func_null);
 923                 this.nextthink = 0;
 924                 //this.think(); // do the first explosion now
 925
 926                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 927                 WaypointSprite_Ping(this.sprite);
 928                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
 929
 930                 onslaught_updatelinks();
 931
 932                 ons_camSetup(this);
 933         }
 934
 935         // Throw some flaming gibs on damage, more damage = more chance for gib
 936         if(random() < damage/220)
 937         {
 938                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 939         }
 940         else
 941         {
 942                 // particles on every hit
 943                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
 944
 945                 //sound on every hit
 946                 if (random() < 0.5)
 947                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
 948                 else
 949                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
 950         }
 951
 952         this.SendFlags |= GSF_STATUS;
 953 }
 954
 955 void ons_GeneratorThink(entity this)
 956 {
 957         this.nextthink = time + GEN_THINKRATE;
 958         if (!gameover)
 959         {
 960                 if(!this.isshielded && this.wait < time)
 961                 {
 962                         this.wait = time + 5;
 963                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 964                                 if(SAME_TEAM(it, this))
 965                                 {
 966                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
 967                                         soundto(MSG_ONE, it, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE);    // FIXME: unique sound?
 968                                 }
 969                                 else
 970                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
 971                         });
 972                 }
 973         }
 974 }
 975
 976 void ons_GeneratorReset(entity this)
 977 {
 978         this.team = this.team_saved;
 979         this.lasthealth = this.max_health = this.health = autocvar_g_onslaught_gen_health;
 980         this.takedamage = DAMAGE_AIM;
 981         this.bot_attack = true;
 982         IL_PUSH(g_bot_targets, this);
 983         this.iscaptured = true;
 984         this.islinked = true;
 985         this.isshielded = true;
 986         this.event_damage = ons_GeneratorDamage;
 987         setthink(this, ons_GeneratorThink);
 988         this.nextthink = time + GEN_THINKRATE;
 989
 990         Net_LinkEntity(this, false, 0, generator_send);
 991
 992         this.SendFlags = GSF_SETUP; // just incase
 993         this.SendFlags |= GSF_STATUS;
 994
 995         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
 996         WaypointSprite_UpdateHealth(this.sprite, this.health);
 997         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 998
 999         onslaught_updatelinks();
1000 }
1001
1002 void ons_DelayedGeneratorSetup(entity this)
1003 {
1004         // bot waypoints
1005         waypoint_spawnforitem_force(this, this.origin);
1006         this.nearestwaypointtimeout = 0; // activate waypointing again
1007         this.bot_basewaypoint = this.nearestwaypoint;
1008
1009         // captureshield setup
1010         ons_CaptureShield_Spawn(this, true);
1011
1012         onslaught_updatelinks();
1013
1014         Net_LinkEntity(this, false, 0, generator_send);
1015 }
1016
1017
1018 void onslaught_generator_touch(entity this, entity toucher)
1019 {
1020         if ( IS_PLAYER(toucher) )
1021         if ( SAME_TEAM(this,toucher) )
1022         if ( this.iscaptured )
1023         {
1024                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1025         }
1026 }
1027
1028 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1029 {
1030         // declarations
1031         int teamnumber = gen.team;
1032
1033         // main setup
1034         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1035         ons_worldgeneratorlist = gen;
1036
1037         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1038         gen.classname = "onslaught_generator";
1039         gen.solid = SOLID_BBOX;
1040         gen.team_saved = teamnumber;
1041         set_movetype(gen, MOVETYPE_NONE);
1042         gen.lasthealth = gen.max_health = gen.health = autocvar_g_onslaught_gen_health;
1043         gen.takedamage = DAMAGE_AIM;
1044         gen.bot_attack = true;
1045         IL_PUSH(g_bot_targets, gen);
1046         gen.event_damage = ons_GeneratorDamage;
1047         gen.reset = ons_GeneratorReset;
1048         setthink(gen, ons_GeneratorThink);
1049         gen.nextthink = time + GEN_THINKRATE;
1050         gen.iscaptured = true;
1051         gen.islinked = true;
1052         gen.isshielded = true;
1053         settouch(gen, onslaught_generator_touch);
1054
1055         // appearence
1056         // model handled by CSQC
1057         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1058         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1059         gen.colormap = 1024 + (teamnumber - 1) * 17;
1060
1061         // generator placement
1062         droptofloor(gen);
1063
1064         // waypointsprites
1065         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1066         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1067         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1068         WaypointSprite_UpdateHealth(gen.sprite, gen.health);
1069
1070         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1071 }
1072
1073
1074 // ===============
1075 //  Round Handler
1076 // ===============
1077
1078 int total_generators;
1079 void Onslaught_count_generators()
1080 {
1081         entity e;
1082         total_generators = redowned = blueowned = yellowowned = pinkowned = 0;
1083         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1084         {
1085                 ++total_generators;
1086                 redowned += (e.team == NUM_TEAM_1 && e.health > 0);
1087                 blueowned += (e.team == NUM_TEAM_2 && e.health > 0);
1088                 yellowowned += (e.team == NUM_TEAM_3 && e.health > 0);
1089                 pinkowned += (e.team == NUM_TEAM_4 && e.health > 0);
1090         }
1091 }
1092
1093 int Onslaught_GetWinnerTeam()
1094 {
1095         int winner_team = 0;
1096         if(redowned > 0)
1097                 winner_team = NUM_TEAM_1;
1098         if(blueowned > 0)
1099         {
1100                 if(winner_team) return 0;
1101                 winner_team = NUM_TEAM_2;
1102         }
1103         if(yellowowned > 0)
1104         {
1105                 if(winner_team) return 0;
1106                 winner_team = NUM_TEAM_3;
1107         }
1108         if(pinkowned > 0)
1109         {
1110                 if(winner_team) return 0;
1111                 winner_team = NUM_TEAM_4;
1112         }
1113         if(winner_team)
1114                 return winner_team;
1115         return -1; // no generators left?
1116 }
1117
1118 void nades_Clear(entity e);
1119
1120 #define ONS_OWNED_GENERATORS() ((redowned > 0) + (blueowned > 0) + (yellowowned > 0) + (pinkowned > 0))
1121 #define ONS_OWNED_GENERATORS_OK() (ONS_OWNED_GENERATORS() > 1)
1122 bool Onslaught_CheckWinner()
1123 {
1124         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1125         {
1126                 ons_stalemate = true;
1127
1128                 if (!wpforenemy_announced)
1129                 {
1130                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1131                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1132
1133                         wpforenemy_announced = true;
1134                 }
1135
1136                 entity tmp_entity; // temporary entity
1137                 float d;
1138                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1139                 {
1140                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1141                         // control points reduce the overtime duration.
1142                         d = 1;
1143                         entity e;
1144                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1145                         {
1146                                 if(DIFF_TEAM(e, tmp_entity))
1147                                 if(e.islinked)
1148                                         d = d + 1;
1149                         }
1150
1151                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1152                                 d = d * tmp_entity.max_health;
1153                         else
1154                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1155
1156                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, tmp_entity.origin, '0 0 0');
1157
1158                         tmp_entity.sprite.SendFlags |= 16;
1159
1160                         tmp_entity.ons_overtime_damagedelay = time + 1;
1161                 }
1162         }
1163         else { wpforenemy_announced = false; ons_stalemate = false; }
1164
1165         Onslaught_count_generators();
1166
1167         if(ONS_OWNED_GENERATORS_OK())
1168                 return 0;
1169
1170         int winner_team = Onslaught_GetWinnerTeam();
1171
1172         if(winner_team > 0)
1173         {
1174                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1175                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1176                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1177         }
1178         else if(winner_team == -1)
1179         {
1180                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1181                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1182         }
1183
1184         ons_stalemate = false;
1185
1186         play2all(SND(CTF_CAPTURE(winner_team)));
1187
1188         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1189
1190         FOREACH_CLIENT(IS_PLAYER(it), {
1191                 STAT(ROUNDLOST, it) = true;
1192                 it.player_blocked = true;
1193
1194                 nades_Clear(it);
1195         });
1196
1197         return 1;
1198 }
1199
1200 bool Onslaught_CheckPlayers()
1201 {
1202         return 1;
1203 }
1204
1205 void Onslaught_RoundStart()
1206 {
1207         entity tmp_entity;
1208         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1209
1210         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1211                 tmp_entity.sprite.SendFlags |= 16;
1212
1213         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1214                 tmp_entity.sprite.SendFlags |= 16;
1215 }
1216
1217
1218 // ================
1219 // Bot player logic
1220 // ================
1221
1222 // NOTE: LEGACY CODE, needs to be re-written!
1223
1224 void havocbot_goalrating_ons_offenseitems(entity this, float ratingscale, vector org, float sradius)
1225 {
1226         bool needarmor = false, needweapons = false;
1227
1228         // Needs armor/health?
1229         if(this.health<100)
1230                 needarmor = true;
1231
1232         // Needs weapons?
1233         int c = 0;
1234         FOREACH(Weapons, it != WEP_Null, {
1235                 if(this.weapons & (it.m_wepset))
1236                 if(++c >= 4)
1237                         break;
1238         });
1239
1240         if(c<4)
1241                 needweapons = true;
1242
1243         if(!needweapons && !needarmor)
1244                 return;
1245
1246         LOG_DEBUG(this.netname, " needs weapons ", ftos(needweapons));
1247         LOG_DEBUG(this.netname, " needs armor ", ftos(needarmor));
1248
1249         // See what is around
1250         IL_EACH(g_items, it.bot_pickup,
1251         {
1252                 // gather health and armor only
1253                 if (it.solid)
1254                 if ( ((it.health || it.armorvalue) && needarmor) || (it.weapons && needweapons ) )
1255                 if (vdist(it.origin - org, <, sradius))
1256                 {
1257                         int t = it.bot_pickupevalfunc(this, it);
1258                         if (t > 0)
1259                                 navigation_routerating(this, it, t * ratingscale, 500);
1260                 }
1261         });
1262 }
1263
1264 void havocbot_role_ons_setrole(entity this, int role)
1265 {
1266         LOG_DEBUG(this.netname," switched to ");
1267         switch(role)
1268         {
1269                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1270                         LOG_DEBUG("defense");
1271                         this.havocbot_role = havocbot_role_ons_defense;
1272                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_DEFENSE;
1273                         this.havocbot_role_timeout = 0;
1274                         break;
1275                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1276                         LOG_DEBUG("assistant");
1277                         this.havocbot_role = havocbot_role_ons_assistant;
1278                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_ASSISTANT;
1279                         this.havocbot_role_timeout = 0;
1280                         break;
1281                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1282                         LOG_DEBUG("offense");
1283                         this.havocbot_role = havocbot_role_ons_offense;
1284                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_OFFENSE;
1285                         this.havocbot_role_timeout = 0;
1286                         break;
1287         }
1288         LOG_DEBUG("");
1289 }
1290
1291 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1292 {
1293         entity cp, cp1, cp2, best, wp;
1294         float radius, bestvalue;
1295         int c;
1296         bool found;
1297
1298         // Filter control points
1299         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1300         {
1301                 cp2.wpcost = c = 0;
1302                 cp2.wpconsidered = false;
1303
1304                 if(cp2.isshielded)
1305                         continue;
1306
1307                 // Ignore owned controlpoints
1308                 if(!(cp2.isgenneighbor[this.team] || cp2.iscpneighbor[this.team]))
1309                         continue;
1310
1311                 // Count team mates interested in this control point
1312                 // (easier and cleaner than keeping counters per cp and teams)
1313                 FOREACH_CLIENT(IS_PLAYER(it), {
1314                         if(SAME_TEAM(it, this))
1315                         if(it.havocbot_role_flags & HAVOCBOT_ONS_ROLE_OFFENSE)
1316                         if(it.havocbot_ons_target == cp2)
1317                                 ++c;
1318                 });
1319
1320                 // NOTE: probably decrease the cost of attackable control points
1321                 cp2.wpcost = c;
1322                 cp2.wpconsidered = true;
1323         }
1324
1325         // We'll consider only the best case
1326         bestvalue = 99999999999;
1327         cp = NULL;
1328         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1329         {
1330                 if (!cp1.wpconsidered)
1331                         continue;
1332
1333                 if(cp1.wpcost<bestvalue)
1334                 {
1335                         bestvalue = cp1.wpcost;
1336                         cp = cp1;
1337                         this.havocbot_ons_target = cp1;
1338                 }
1339         }
1340
1341         if (!cp)
1342                 return;
1343
1344         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1345
1346         if(cp.goalentity)
1347         {
1348                 // Should be attacked
1349                 // Rate waypoints near it
1350                 found = false;
1351                 best = NULL;
1352                 bestvalue = 99999999999;
1353                 for(radius=0; radius<1000 && !found; radius+=500)
1354                 {
1355                         for(wp=findradius(cp.origin,radius); wp; wp=wp.chain)
1356                         {
1357                                 if(!(wp.wpflags & WAYPOINTFLAG_GENERATED))
1358                                 if(wp.classname=="waypoint")
1359                                 if(checkpvs(wp.origin,cp))
1360                                 {
1361                                         found = true;
1362                                         if(wp.cnt<bestvalue)
1363                                         {
1364                                                 best = wp;
1365                                                 bestvalue = wp.cnt;
1366                                         }
1367                                 }
1368                         }
1369                 }
1370
1371                 if(best)
1372                 {
1373                         navigation_routerating(this, best, ratingscale, 10000);
1374                         best.cnt += 1;
1375
1376                         this.havocbot_attack_time = 0;
1377                         if(checkpvs(this.view_ofs,cp))
1378                         if(checkpvs(this.view_ofs,best))
1379                                 this.havocbot_attack_time = time + 2;
1380                 }
1381                 else
1382                 {
1383                         navigation_routerating(this, cp, ratingscale, 10000);
1384                 }
1385                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1386         }
1387         else
1388         {
1389                 // Should be touched
1390                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1391                 found = false;
1392
1393                 // Look for auto generated waypoint
1394                 if (!bot_waypoints_for_items)
1395                 for (wp = findradius(cp.origin,100); wp; wp = wp.chain)
1396                 {
1397                         if(wp.classname=="waypoint")
1398                         {
1399                                 navigation_routerating(this, wp, ratingscale, 10000);
1400                                 found = true;
1401                         }
1402                 }
1403
1404                 // Nothing found, rate the controlpoint itself
1405                 if (!found)
1406                         navigation_routerating(this, cp, ratingscale, 10000);
1407         }
1408 }
1409
1410 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1411 {
1412         entity g, wp, bestwp;
1413         bool found;
1414         int best;
1415
1416         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1417         {
1418                 if(SAME_TEAM(g, this) || g.isshielded)
1419                         continue;
1420
1421                 // Should be attacked
1422                 // Rate waypoints near it
1423                 found = false;
1424                 bestwp = NULL;
1425                 best = 99999999999;
1426
1427                 for(wp=findradius(g.origin,400); wp; wp=wp.chain)
1428                 {
1429                         if(wp.classname=="waypoint")
1430                         if(checkpvs(wp.origin,g))
1431                         {
1432                                 found = true;
1433                                 if(wp.cnt<best)
1434                                 {
1435                                         bestwp = wp;
1436                                         best = wp.cnt;
1437                                 }
1438                         }
1439                 }
1440
1441                 if(bestwp)
1442                 {
1443                         LOG_DEBUG("waypoints found around generator");
1444                         navigation_routerating(this, bestwp, ratingscale, 10000);
1445                         bestwp.cnt += 1;
1446
1447                         this.havocbot_attack_time = 0;
1448                         if(checkpvs(this.view_ofs,g))
1449                         if(checkpvs(this.view_ofs,bestwp))
1450                                 this.havocbot_attack_time = time + 5;
1451
1452                         return true;
1453                 }
1454                 else
1455                 {
1456                         LOG_DEBUG("generator found without waypoints around");
1457                         // if there aren't waypoints near the generator go straight to it
1458                         navigation_routerating(this, g, ratingscale, 10000);
1459                         this.havocbot_attack_time = 0;
1460                         return true;
1461                 }
1462         }
1463         return false;
1464 }
1465
1466 void havocbot_role_ons_offense(entity this)
1467 {
1468         if(IS_DEAD(this))
1469         {
1470                 this.havocbot_attack_time = 0;
1471                 havocbot_ons_reset_role(this);
1472                 return;
1473         }
1474
1475         // Set the role timeout if necessary
1476         if (!this.havocbot_role_timeout)
1477                 this.havocbot_role_timeout = time + 120;
1478
1479         if (time > this.havocbot_role_timeout)
1480         {
1481                 havocbot_ons_reset_role(this);
1482                 return;
1483         }
1484
1485         if(this.havocbot_attack_time>time)
1486                 return;
1487
1488         if (this.bot_strategytime < time)
1489         {
1490                 navigation_goalrating_start(this);
1491                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1492                 if(!havocbot_goalrating_ons_generator_attack(this, 20000))
1493                         havocbot_goalrating_ons_controlpoints_attack(this, 20000);
1494                 havocbot_goalrating_ons_offenseitems(this, 10000, this.origin, 10000);
1495                 navigation_goalrating_end(this);
1496
1497                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1498         }
1499 }
1500
1501 void havocbot_role_ons_assistant(entity this)
1502 {
1503         havocbot_ons_reset_role(this);
1504 }
1505
1506 void havocbot_role_ons_defense(entity this)
1507 {
1508         havocbot_ons_reset_role(this);
1509 }
1510
1511 void havocbot_ons_reset_role(entity this)
1512 {
1513         if(IS_DEAD(this))
1514                 return;
1515
1516         this.havocbot_ons_target = NULL;
1517
1518         // TODO: Defend control points or generator if necessary
1519
1520         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1521 }
1522
1523
1524 /*
1525  * Find control point or generator owned by the same team self which is nearest to pos
1526  * if max_dist is positive, only control points within this range will be considered
1527  */
1528 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1529 {
1530         entity closest_target = NULL;
1531         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1532         {
1533                 if(SAME_TEAM(cp, this))
1534                 if(cp.iscaptured)
1535                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1536                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1537                         closest_target = cp;
1538         }
1539         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1540         {
1541                 if(SAME_TEAM(gen, this))
1542                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1543                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1544                         closest_target = gen;
1545         }
1546
1547         return closest_target;
1548 }
1549
1550 /*
1551  * Find control point or generator owned by the same team self which is nearest to pos
1552  * if max_dist is positive, only control points within this range will be considered
1553  * This function only check distances on the XY plane, disregarding Z
1554  */
1555 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1556 {
1557         entity closest_target = NULL;
1558         vector delta;
1559         float smallest_distance = 0, distance;
1560
1561         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1562         {
1563                 delta = cp.origin - pos;
1564                 delta_z = 0;
1565                 distance = vlen(delta);
1566
1567                 if(SAME_TEAM(cp, this))
1568                 if(cp.iscaptured)
1569                 if(max_dist <= 0 || distance <= max_dist)
1570                 if(closest_target == NULL || distance <= smallest_distance )
1571                 {
1572                         closest_target = cp;
1573                         smallest_distance = distance;
1574                 }
1575         }
1576         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1577         {
1578                 delta = gen.origin - pos;
1579                 delta_z = 0;
1580                 distance = vlen(delta);
1581
1582                 if(SAME_TEAM(gen, this))
1583                 if(max_dist <= 0 || distance <= max_dist)
1584                 if(closest_target == NULL || distance <= smallest_distance )
1585                 {
1586                         closest_target = gen;
1587                         smallest_distance = distance;
1588                 }
1589         }
1590
1591         return closest_target;
1592 }
1593 /**
1594  * find the number of control points and generators in the same team as this
1595  */
1596 int ons_Count_SelfControlPoints(entity this)
1597 {
1598         int n = 0;
1599         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1600         {
1601                 if(SAME_TEAM(cp, this))
1602                 if(cp.iscaptured)
1603                         n++;
1604         }
1605         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1606         {
1607                 if(SAME_TEAM(gen, this))
1608                         n++;
1609         }
1610         return n;
1611 }
1612
1613 /**
1614  * Teleport player to a random position near tele_target
1615  * if tele_effects is true, teleport sound+particles are created
1616  * return false on failure
1617  */
1618 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1619 {
1620         if ( !tele_target )
1621                 return false;
1622
1623         int i;
1624         vector loc;
1625         float theta;
1626         // narrow the range for each iteration to increase chances that a spawnpoint
1627         // can be found even if there's little room around the control point
1628         float iteration_scale = 1;
1629         for(i = 0; i < 16; ++i)
1630         {
1631                 iteration_scale -= i / 16;
1632                 theta = random() * 2 * M_PI;
1633                 loc_y = sin(theta);
1634                 loc_x = cos(theta);
1635                 loc_z = 0;
1636                 loc *= random() * range * iteration_scale;
1637
1638                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1639
1640                 tracebox(loc, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), loc, MOVE_NORMAL, player);
1641                 if(trace_fraction == 1.0 && !trace_startsolid)
1642                 {
1643                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1644                         if(trace_fraction == 1.0 && !trace_startsolid)
1645                         {
1646                                 if ( tele_effects )
1647                                 {
1648                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1649                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1650                                 }
1651                                 setorigin(player, loc);
1652                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1653                                 makevectors(player.angles);
1654                                 player.fixangle = true;
1655                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1656
1657                                 if ( tele_effects )
1658                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1659                                 return true;
1660                         }
1661                 }
1662         }
1663
1664         return false;
1665 }
1666
1667 // ==============
1668 // Hook Functions
1669 // ==============
1670
1671 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1672 {
1673         FOREACH_CLIENT(IS_PLAYER(it), {
1674                 STAT(ROUNDLOST, it) = false;
1675                 it.ons_deathloc = '0 0 0';
1676                 PutClientInServer(it);
1677                 it.clientcamera = it;
1678         });
1679         return false;
1680 }
1681
1682 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1683 {
1684         entity player = M_ARGV(0, entity);
1685
1686         player.ons_deathloc = '0 0 0';
1687 }
1688
1689 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1690 {
1691         entity player = M_ARGV(0, entity);
1692
1693         player.ons_deathloc = '0 0 0';
1694 }
1695
1696 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1697 {
1698         entity player = M_ARGV(0, entity);
1699
1700         if(!round_handler_IsRoundStarted())
1701         {
1702                 player.player_blocked = true;
1703                 return false;
1704         }
1705
1706         entity l;
1707         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1708         {
1709                 l.sprite.SendFlags |= 16;
1710         }
1711         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1712         {
1713                 l.sprite.SendFlags |= 16;
1714         }
1715
1716         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1717
1718         if ( autocvar_g_onslaught_spawn_choose )
1719         if ( player.ons_spawn_by )
1720         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1721         {
1722                 player.ons_spawn_by = NULL;
1723                 return false;
1724         }
1725
1726         if(autocvar_g_onslaught_spawn_at_controlpoints)
1727         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1728         {
1729                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1730                 entity tmp_entity, closest_target = NULL;
1731                 vector spawn_loc = player.ons_deathloc;
1732
1733                 // new joining player or round reset, don't bother checking
1734                 if(spawn_loc == '0 0 0') { return false; }
1735
1736                 if(random_target) { RandomSelection_Init(); }
1737
1738                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1739                 {
1740                         if(SAME_TEAM(tmp_entity, player))
1741                         if(random_target)
1742                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1743                         else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1744                                 closest_target = tmp_entity;
1745                 }
1746
1747                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1748
1749                 if(closest_target)
1750                 {
1751                         float i;
1752                         vector loc;
1753                         float iteration_scale = 1;
1754                         for(i = 0; i < 10; ++i)
1755                         {
1756                                 iteration_scale -= i / 10;
1757                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1758                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1759                                 tracebox(loc, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), loc, MOVE_NORMAL, player);
1760                                 if(trace_fraction == 1.0 && !trace_startsolid)
1761                                 {
1762                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1763                                         if(trace_fraction == 1.0 && !trace_startsolid)
1764                                         {
1765                                                 setorigin(player, loc);
1766                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1767                                                 return false;
1768                                         }
1769                                 }
1770                         }
1771                 }
1772         }
1773
1774         if(autocvar_g_onslaught_spawn_at_generator)
1775         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1776         {
1777                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1778                 entity tmp_entity, closest_target = NULL;
1779                 vector spawn_loc = player.ons_deathloc;
1780
1781                 // new joining player or round reset, don't bother checking
1782                 if(spawn_loc == '0 0 0') { return false; }
1783
1784                 if(random_target) { RandomSelection_Init(); }
1785
1786                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1787                 {
1788                         if(random_target)
1789                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1790                         else
1791                         {
1792                                 if(SAME_TEAM(tmp_entity, player))
1793                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1794                                         closest_target = tmp_entity;
1795                         }
1796                 }
1797
1798                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1799
1800                 if(closest_target)
1801                 {
1802                         float i;
1803                         vector loc;
1804                         float iteration_scale = 1;
1805                         for(i = 0; i < 10; ++i)
1806                         {
1807                                 iteration_scale -= i / 10;
1808                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1809                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1810                                 tracebox(loc, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), loc, MOVE_NORMAL, player);
1811                                 if(trace_fraction == 1.0 && !trace_startsolid)
1812                                 {
1813                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1814                                         if(trace_fraction == 1.0 && !trace_startsolid)
1815                                         {
1816                                                 setorigin(player, loc);
1817                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1818                                                 return false;
1819                                         }
1820                                 }
1821                         }
1822                 }
1823         }
1824
1825         return false;
1826 }
1827
1828 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1829 {
1830         entity frag_target = M_ARGV(2, entity);
1831
1832         frag_target.ons_deathloc = frag_target.origin;
1833         entity l;
1834         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1835         {
1836                 l.sprite.SendFlags |= 16;
1837         }
1838         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1839         {
1840                 l.sprite.SendFlags |= 16;
1841         }
1842
1843         if ( autocvar_g_onslaught_spawn_choose )
1844         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1845                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1846
1847         return false;
1848 }
1849
1850 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1851 {
1852         entity mon = M_ARGV(0, entity);
1853
1854         entity e = find(NULL, targetname, mon.target);
1855         if (e != NULL)
1856                 mon.team = e.team;
1857 }
1858
1859 void ons_MonsterSpawn_Delayed(entity this)
1860 {
1861         entity own = this.owner;
1862
1863         if(!own) { delete(this); return; }
1864
1865         if(own.targetname)
1866         {
1867                 entity e = find(NULL, target, own.targetname);
1868                 if(e != NULL)
1869                 {
1870                         own.team = e.team;
1871
1872                         own.use(own, e, NULL);
1873                 }
1874         }
1875
1876         delete(this);
1877 }
1878
1879 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1880 {
1881         entity mon = M_ARGV(0, entity);
1882
1883         entity e = spawn();
1884         e.owner = mon;
1885         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1886 }
1887
1888 void ons_TurretSpawn_Delayed(entity this)
1889 {
1890         entity own = this.owner;
1891
1892         if(!own) { delete(this); return; }
1893
1894         if(own.targetname)
1895         {
1896                 entity e = find(NULL, target, own.targetname);
1897                 if(e != NULL)
1898                 {
1899                         own.team = e.team;
1900                         own.active = ACTIVE_NOT;
1901
1902                         own.use(own, e, NULL);
1903                 }
1904         }
1905
1906         delete(this);
1907 }
1908
1909 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1910 {
1911         entity turret = M_ARGV(0, entity);
1912
1913         entity e = spawn();
1914         e.owner = turret;
1915         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1916
1917         return false;
1918 }
1919
1920 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1921 {
1922         entity bot = M_ARGV(0, entity);
1923
1924         havocbot_ons_reset_role(bot);
1925         return true;
1926 }
1927
1928 MUTATOR_HOOKFUNCTION(ons, CheckAllowedTeams)
1929 {
1930         // onslaught is special
1931         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1932         {
1933                 switch(tmp_entity.team)
1934                 {
1935                         case NUM_TEAM_1: c1 = 0; break;
1936                         case NUM_TEAM_2: c2 = 0; break;
1937                         case NUM_TEAM_3: c3 = 0; break;
1938                         case NUM_TEAM_4: c4 = 0; break;
1939                 }
1940         }
1941
1942         return true;
1943 }
1944
1945 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1946 {
1947         entity spectatee = M_ARGV(0, entity);
1948         entity client = M_ARGV(1, entity);
1949
1950         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1951 }
1952
1953 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1954 {
1955         if(MUTATOR_RETURNVALUE) // command was already handled?
1956                 return false;
1957
1958         entity player = M_ARGV(0, entity);
1959         string cmd_name = M_ARGV(1, string);
1960         int cmd_argc = M_ARGV(2, int);
1961
1962         if ( cmd_name == "ons_spawn" )
1963         {
1964                 vector pos = player.origin;
1965                 if(cmd_argc > 1)
1966                         pos_x = stof(argv(1));
1967                 if(cmd_argc > 2)
1968                         pos_y = stof(argv(2));
1969                 if(cmd_argc > 3)
1970                         pos_z = stof(argv(3));
1971
1972                 if ( IS_PLAYER(player) )
1973                 {
1974                         if ( !STAT(FROZEN, player) )
1975                         {
1976                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1977
1978                                 if ( !source_point && player.health > 0 )
1979                                 {
1980                                         sprint(player, "\nYou need to be next to a control point\n");
1981                                         return true;
1982                                 }
1983
1984
1985                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1986
1987                                 if ( closest_target == NULL )
1988                                 {
1989                                         sprint(player, "\nNo control point found\n");
1990                                         return true;
1991                                 }
1992
1993                                 if ( player.health <= 0 )
1994                                 {
1995                                         player.ons_spawn_by = closest_target;
1996                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
1997                                 }
1998                                 else
1999                                 {
2000                                         if ( source_point == closest_target )
2001                                         {
2002                                                 sprint(player, "\nTeleporting to the same point\n");
2003                                                 return true;
2004                                         }
2005
2006                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
2007                                                 sprint(player, "\nUnable to teleport there\n");
2008                                 }
2009
2010                                 return true;
2011                         }
2012
2013                         sprint(player, "\nNo teleportation for you\n");
2014                 }
2015
2016                 return true;
2017         }
2018         return false;
2019 }
2020
2021 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2022 {
2023         if(MUTATOR_RETURNVALUE || gameover) { return false; }
2024
2025         entity player = M_ARGV(0, entity);
2026
2027         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2028         {
2029                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2030                 if ( source_point )
2031                 {
2032                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2033                         return true;
2034                 }
2035         }
2036 }
2037
2038 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2039 {
2040         entity frag_victim = M_ARGV(0, entity);
2041
2042         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2043                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2044 }
2045
2046 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2047 {
2048     entity wp = M_ARGV(0, entity);
2049     entity to = M_ARGV(1, entity);
2050     int sf = M_ARGV(2, int);
2051     int wp_flag = M_ARGV(3, int);
2052
2053         if(sf & 16)
2054         {
2055                 if(wp.owner.classname == "onslaught_controlpoint")
2056                 {
2057                         entity wp_owner = wp.owner;
2058                         entity e = WaypointSprite_getviewentity(to);
2059                         if(SAME_TEAM(e, wp_owner) && wp_owner.goalentity.health >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2060                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2061                 }
2062                 if(wp.owner.classname == "onslaught_generator")
2063                 {
2064                         entity wp_owner = wp.owner;
2065                         if(wp_owner.isshielded && wp_owner.health >= wp_owner.max_health) { wp_flag |= 2; }
2066                         if(wp_owner.health <= 0) { wp_flag |= 2; }
2067                 }
2068         }
2069
2070         M_ARGV(3, int) = wp_flag;
2071 }
2072
2073 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2074 {
2075         entity turret_target = M_ARGV(1, entity);
2076
2077         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2078         {
2079                 M_ARGV(3, float) = -3;
2080                 return true;
2081         }
2082
2083         return false;
2084 }
2085
2086 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2087 {
2088     entity turret = M_ARGV(0, entity);
2089
2090         // ONS uses somewhat backwards linking.
2091         if(turret.target)
2092         {
2093                 entity e = find(NULL, targetname, turret.target);
2094                 if (e != NULL)
2095                         turret.team = e.team;
2096         }
2097
2098         if(turret.team != turret.tur_head.team)
2099                 turret_respawn(turret);
2100 }
2101
2102
2103 // ==========
2104 // Spawnfuncs
2105 // ==========
2106
2107 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2108   Link between control points.
2109
2110   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2111
2112 keys:
2113 "target" - first control point.
2114 "target2" - second control point.
2115  */
2116 spawnfunc(onslaught_link)
2117 {
2118         if(!g_onslaught) { delete(this); return; }
2119
2120         if (this.target == "" || this.target2 == "")
2121                 objerror(this, "target and target2 must be set\n");
2122
2123         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2124         ons_worldlinklist = this;
2125
2126         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2127         Net_LinkEntity(this, false, 0, ons_Link_Send);
2128 }
2129
2130 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2131   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2132
2133   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2134
2135 keys:
2136 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2137 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2138 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2139  */
2140
2141 spawnfunc(onslaught_controlpoint)
2142 {
2143         if(!g_onslaught) { delete(this); return; }
2144
2145         ons_ControlPoint_Setup(this);
2146 }
2147
2148 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2149   Base generator.
2150
2151   spawnfunc_onslaught_link entities can target this.
2152
2153 keys:
2154 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2155 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2156  */
2157 spawnfunc(onslaught_generator)
2158 {
2159         if(!g_onslaught) { delete(this); return; }
2160         if(!this.team) { objerror(this, "team must be set"); }
2161
2162         ons_GeneratorSetup(this);
2163 }
2164
2165 // scoreboard setup
2166 void ons_ScoreRules()
2167 {
2168         CheckAllowedTeams(NULL);
2169         int teams = 0;
2170         if(c1 >= 0) teams |= BIT(0);
2171         if(c2 >= 0) teams |= BIT(1);
2172         if(c3 >= 0) teams |= BIT(2);
2173         if(c4 >= 0) teams |= BIT(3);
2174         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, 0, true);
2175         ScoreInfo_SetLabel_TeamScore  (ST_ONS_CAPS,     "destroyed", SFL_SORT_PRIO_PRIMARY);
2176         ScoreInfo_SetLabel_PlayerScore(SP_ONS_CAPS,    "caps",      SFL_SORT_PRIO_SECONDARY);
2177         ScoreInfo_SetLabel_PlayerScore(SP_ONS_TAKES,    "takes",     0);
2178         ScoreRules_basics_end();
2179 }
2180
2181 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2182 {
2183         ons_ScoreRules();
2184
2185         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2186         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2187 }
2188
2189 void ons_Initialize()
2190 {
2191         g_onslaught = true;
2192         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2193
2194         cam = new(objective_camera);
2195
2196         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2197 }