qcsrc/common/gamemodes/gamemode/keyhunt/sv_keyhunt.qc

   1 #include "sv_keyhunt.qh"
   2
   3 #include <server/command/vote.qh>
   4 #include <server/gamelog.qh>
   5 #include <server/g_damage.qh>
   6
   7 float autocvar_g_balance_keyhunt_damageforcescale;
   8 float autocvar_g_balance_keyhunt_delay_collect;
   9 float autocvar_g_balance_keyhunt_delay_damage_return;
  10 float autocvar_g_balance_keyhunt_delay_return;
  11 float autocvar_g_balance_keyhunt_delay_round;
  12 float autocvar_g_balance_keyhunt_delay_tracking;
  13 float autocvar_g_balance_keyhunt_return_when_unreachable;
  14 float autocvar_g_balance_keyhunt_dropvelocity;
  15 float autocvar_g_balance_keyhunt_maxdist;
  16 float autocvar_g_balance_keyhunt_protecttime;
  17
  18 int autocvar_g_balance_keyhunt_score_capture;
  19 int autocvar_g_balance_keyhunt_score_carrierfrag;
  20 int autocvar_g_balance_keyhunt_score_collect;
  21 int autocvar_g_balance_keyhunt_score_destroyed;
  22 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  23 int autocvar_g_balance_keyhunt_score_push;
  24 float autocvar_g_balance_keyhunt_throwvelocity;
  25
  26 //int autocvar_g_keyhunt_teams;
  27 int autocvar_g_keyhunt_teams_override;
  28
  29 // #define KH_PLAYER_USE_ATTACHMENT
  30 // TODO? no model exists for this
  31 // #define KH_PLAYER_USE_CARRIEDMODEL
  32
  33 #ifdef KH_PLAYER_USE_ATTACHMENT
  34 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  35 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  36 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  37 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  38 const string KH_PLAYER_ATTACHMENT_BONE = "";
  39 #else
  40 const float KH_KEY_ZSHIFT = 22;
  41 const float KH_KEY_XYDIST = 24;
  42 const float KH_KEY_XYSPEED = 45;
  43 #endif
  44 const float KH_KEY_WP_ZSHIFT = 20;
  45
  46 const vector KH_KEY_MIN = '-10 -10 -46';
  47 const vector KH_KEY_MAX = '10 10 3';
  48 const float KH_KEY_BRIGHTNESS = 2;
  49
  50 bool kh_no_radar_circles;
  51
  52 // kh_state
  53 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  54 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  55 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  56 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  57 .float siren_time;  //  time delay the siren
  58 //.float stuff_time;  //  time delay to stuffcmd a cvar
  59
  60 int kh_Team_ByID(int t)
  61 {
  62         if(t == 0) return NUM_TEAM_1;
  63         if(t == 1) return NUM_TEAM_2;
  64         if(t == 2) return NUM_TEAM_3;
  65         if(t == 3) return NUM_TEAM_4;
  66         return 0;
  67 }
  68
  69 entity kh_controller;
  70 //bool kh_tracking_enabled;
  71 int kh_teams;
  72 int kh_interferemsg_team;
  73 float kh_interferemsg_time;
  74 .entity kh_next, kh_prev; // linked list
  75 .float kh_droptime;
  76 .int kh_dropperteam;
  77 .entity kh_previous_owner;
  78 .int kh_previous_owner_playerid;
  79
  80 int kh_key_dropped, kh_key_carried;
  81
  82 int kh_Key_AllOwnedByWhichTeam();
  83
  84 const int ST_KH_CAPS = 1;
  85 void kh_ScoreRules(int teams)
  86 {
  87         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
  88         field_team(ST_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  89         field(SP_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  90         field(SP_KH_PUSHES, "pushes", 0);
  91         field(SP_KH_DESTROYS, "destroyed", SFL_LOWER_IS_BETTER);
  92         field(SP_KH_PICKUPS, "pickups", 0);
  93         field(SP_KH_KCKILLS, "kckills", 0);
  94         field(SP_KH_LOSSES, "losses", SFL_LOWER_IS_BETTER);
  95         });
  96 }
  97
  98 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
  99 {
 100         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
 101                 if(!kh_tracking_enabled)
 102                         return false;
 103
 104         return true;
 105 }
 106
 107 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 108 {
 109         if(!kh_tracking_enabled)
 110                 return false;
 111         if(!this.owner)
 112                 return true;
 113         if(!this.owner.owner)
 114                 return true;
 115         return false;  // draw only when key is not owned
 116 }
 117
 118 void kh_update_state()
 119 {
 120         entity key;
 121         int f;
 122         int s = 0;
 123         FOR_EACH_KH_KEY(key)
 124         {
 125                 if(key.owner)
 126                         f = key.team;
 127                 else
 128                         f = 30;
 129                 s |= (32 ** key.count) * f;
 130         }
 131
 132         FOREACH_CLIENT(true, { STAT(KH_KEYS, it) = s; });
 133
 134         FOR_EACH_KH_KEY(key)
 135         {
 136                 if(key.owner)
 137                         STAT(KH_KEYS, key.owner) |= (32 ** key.count) * 31;
 138         }
 139         //print(ftos((nextent(NULL)).kh_state), "\n");
 140 }
 141
 142
 143
 144
 145 var kh_Think_t kh_Controller_Thinkfunc;
 146 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 147 {
 148         kh_Controller_Thinkfunc = func;
 149         kh_controller.cnt = ceil(t);
 150         if(t == 0)
 151                 kh_controller.nextthink = time; // force
 152 }
 153 void kh_WaitForPlayers();
 154 void kh_Controller_Think(entity this)  // called a lot
 155 {
 156         if(game_stopped)
 157                 return;
 158         if(this.cnt > 0)
 159         {
 160                 if(getthink(this) != kh_WaitForPlayers)
 161                         this.cnt -= 1;
 162         }
 163         else if(this.cnt == 0)
 164         {
 165                 this.cnt -= 1;
 166                 kh_Controller_Thinkfunc();
 167         }
 168         this.nextthink = time + 1;
 169 }
 170
 171 // frags f: take from cvar * f
 172 // frags 0: no frags
 173 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 174 {
 175         string s;
 176         if(game_stopped)
 177                 return;
 178
 179         if(frags_player)
 180                 UpdateFrags(player, frags_player);
 181
 182         if(key && key.owner && frags_owner)
 183                 UpdateFrags(key.owner, frags_owner);
 184
 185         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 186                 return;
 187
 188         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 189
 190         if(key && key.owner)
 191                 s = strcat(s, ":", ftos(key.owner.playerid));
 192         else
 193                 s = strcat(s, ":0");
 194
 195         s = strcat(s, ":", ftos(frags_owner), ":");
 196
 197         if(key)
 198                 s = strcat(s, key.netname);
 199
 200         GameLogEcho(s);
 201 }
 202
 203 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 204 {
 205         if(e.tag_entity)
 206         {
 207                 makevectors(e.tag_entity.angles);
 208                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 209         }
 210         else
 211                 return e.origin;
 212 }
 213
 214 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 215 {
 216 #ifdef KH_PLAYER_USE_ATTACHMENT
 217         entity first = key.owner.kh_next;
 218         if(key == first)
 219         {
 220                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 221                 if(key.kh_next)
 222                 {
 223                         setattachment(key.kh_next, key, "");
 224                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 225                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 226                         key.kh_next.angles = '0 0 0';
 227                 }
 228                 else
 229                         setorigin(key, KH_PLAYER_ATTACHMENT);
 230                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 231         }
 232         else
 233         {
 234                 setattachment(key, key.kh_prev, "");
 235                 if(key.kh_next)
 236                         setattachment(key.kh_next, key, "");
 237                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 238                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 239                 key.angles = '0 0 0';
 240         }
 241 #else
 242         setattachment(key, key.owner, "");
 243         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 244         key.angles_y -= key.owner.angles.y;
 245 #endif
 246         key.flags = 0;
 247         if(IL_CONTAINS(g_items, key))
 248                 IL_REMOVE(g_items, key);
 249         key.solid = SOLID_NOT;
 250         set_movetype(key, MOVETYPE_NONE);
 251         key.team = key.owner.team;
 252         key.nextthink = time;
 253         key.damageforcescale = 0;
 254         key.takedamage = DAMAGE_NO;
 255         key.modelindex = kh_key_carried;
 256         navigation_dynamicgoal_unset(key);
 257 }
 258
 259 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 260 {
 261 #ifdef KH_PLAYER_USE_ATTACHMENT
 262         entity first = key.owner.kh_next;
 263         if(key == first)
 264         {
 265                 if(key.kh_next)
 266                 {
 267                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 268                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 269                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 270                 }
 271         }
 272         else
 273         {
 274                 if(key.kh_next)
 275                         setattachment(key.kh_next, key.kh_prev, "");
 276                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 277         }
 278         // in any case:
 279         setattachment(key, NULL, "");
 280         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, key.owner).z - KH_KEY_MIN_z));
 281         key.angles = key.owner.angles;
 282 #else
 283         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 284         setattachment(key, NULL, "");
 285         key.angles_y += key.owner.angles.y;
 286 #endif
 287         key.flags = FL_ITEM;
 288         if(!IL_CONTAINS(g_items, key))
 289                 IL_PUSH(g_items, key);
 290         key.solid = SOLID_TRIGGER;
 291         set_movetype(key, MOVETYPE_TOSS);
 292         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 293         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 294         key.takedamage = DAMAGE_YES;
 295         // let key.team stay
 296         key.modelindex = kh_key_dropped;
 297         navigation_dynamicgoal_set(key, key.owner);
 298         key.kh_previous_owner = key.owner;
 299         key.kh_previous_owner_playerid = key.owner.playerid;
 300 }
 301
 302 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 303 {
 304         if(key.owner == player)
 305                 return;
 306
 307         int ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 308
 309         if(key.owner)
 310         {
 311                 kh_Key_Detach(key);
 312
 313                 // remove from linked list
 314                 if(key.kh_next)
 315                         key.kh_next.kh_prev = key.kh_prev;
 316                 key.kh_prev.kh_next = key.kh_next;
 317                 key.kh_next = NULL;
 318                 key.kh_prev = NULL;
 319
 320                 if(key.owner.kh_next == NULL)
 321                 {
 322                         // No longer a key carrier
 323                         if(!kh_no_radar_circles)
 324                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 325                         WaypointSprite_DetachCarrier(key.owner);
 326                 }
 327         }
 328
 329         key.owner = player;
 330
 331         if(player)
 332         {
 333                 // insert into linked list
 334                 key.kh_next = player.kh_next;
 335                 key.kh_prev = player;
 336                 player.kh_next = key;
 337                 if(key.kh_next)
 338                         key.kh_next.kh_prev = key;
 339
 340                 kh_Key_Attach(key);
 341
 342                 if(key.kh_next == NULL)
 343                 {
 344                         // player is now a key carrier
 345                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 346                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 347                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 348                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 349                         if(player.team == NUM_TEAM_1)
 350                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 351                         else if(player.team == NUM_TEAM_2)
 352                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 353                         else if(player.team == NUM_TEAM_3)
 354                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 355                         else if(player.team == NUM_TEAM_4)
 356                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 357                         if(!kh_no_radar_circles)
 358                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 359                 }
 360         }
 361
 362         // moved that here, also update if there's no player
 363         kh_update_state();
 364
 365         key.pusher = NULL;
 366
 367         int ownerteam = kh_Key_AllOwnedByWhichTeam();
 368         if(ownerteam != ownerteam0)
 369         {
 370                 entity k;
 371                 if(ownerteam != -1)
 372                 {
 373                         kh_interferemsg_time = time + 0.2;
 374                         kh_interferemsg_team = player.team;
 375
 376                         // audit all key carrier sprites, update them to "Run here"
 377                         FOR_EACH_KH_KEY(k)
 378                         {
 379                                 if (!k.owner) continue;
 380                                 entity first = WP_Null;
 381                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 382                                 entity third = WP_Null;
 383                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 384                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 385                         }
 386                 }
 387                 else
 388                 {
 389                         kh_interferemsg_time = 0;
 390
 391                         // audit all key carrier sprites, update them to "Key Carrier"
 392                         FOR_EACH_KH_KEY(k)
 393                         {
 394                                 if (!k.owner) continue;
 395                                 entity first = WP_Null;
 396                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 397                                 entity third = WP_Null;
 398                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 399                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 400                         }
 401                 }
 402         }
 403 }
 404
 405 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 406 {
 407         if(this.owner)
 408                 return;
 409         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 410         {
 411                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 412                 return;
 413         }
 414         if(force == '0 0 0')
 415                 return;
 416         if(time > this.pushltime)
 417                 if(IS_PLAYER(attacker))
 418                         this.team = attacker.team;
 419 }
 420
 421 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 422 {
 423         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 424
 425         if(key.kh_dropperteam != player.team)
 426         {
 427                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 428                 GameRules_scoring_add(player, KH_PICKUPS, 1);
 429         }
 430         key.kh_dropperteam = 0;
 431         int realteam = kh_Team_ByID(key.count);
 432         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PICKUP), player.netname);
 433
 434         kh_Key_AssignTo(key, player); // this also updates .kh_state
 435 }
 436
 437 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 438 {
 439         if(game_stopped)
 440                 return;
 441
 442         if(this.owner) // already carried
 443                 return;
 444
 445         if(ITEM_TOUCH_NEEDKILL())
 446         {
 447                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 448                 return;
 449         }
 450
 451         if (!IS_PLAYER(toucher))
 452                 return;
 453         if(IS_DEAD(toucher))
 454                 return;
 455         if(toucher == this.enemy)
 456                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 457                         return;  // you just dropped it!
 458         kh_Key_Collect(this, toucher);
 459 }
 460
 461 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 462 {
 463         entity o = key.owner;
 464         kh_Key_AssignTo(key, NULL);
 465         if(o) // it was attached
 466                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 467         else // it was dropped
 468                 WaypointSprite_DetachCarrier(key);
 469
 470         // remove key from key list
 471         if (kh_worldkeylist == key)
 472                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 473         else
 474         {
 475                 o = kh_worldkeylist;
 476                 while (o)
 477                 {
 478                         if (o.kh_worldkeynext == key)
 479                         {
 480                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 481                                 break;
 482                         }
 483                         o = o.kh_worldkeynext;
 484                 }
 485         }
 486
 487         delete(key);
 488
 489         kh_update_state();
 490 }
 491
 492 void kh_FinishRound()  // runs when a team captures the keys
 493 {
 494         // prepare next round
 495         kh_interferemsg_time = 0;
 496         entity key;
 497
 498         kh_no_radar_circles = true;
 499         FOR_EACH_KH_KEY(key)
 500                 kh_Key_Remove(key);
 501         kh_no_radar_circles = false;
 502
 503         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 504         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 505 }
 506
 507 void nades_GiveBonus(entity player, float score);
 508
 509 void kh_WinnerTeam(int winner_team)  // runs when a team wins
 510 {
 511         // all key carriers get some points
 512         entity key;
 513         float score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 514         DistributeEvenly_Init(score, NumTeams(kh_teams));
 515         // twice the score for 3 team games, three times the score for 4 team games!
 516         // note: for a win by destroying the key, this should NOT be applied
 517         FOR_EACH_KH_KEY(key)
 518         {
 519                 float f = DistributeEvenly_Get(1);
 520                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 521                 GameRules_scoring_add_team(key.owner, KH_CAPS, 1);
 522                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 523         }
 524
 525         bool first = true;
 526         string keyowner = "";
 527         FOR_EACH_KH_KEY(key)
 528                 if(key.owner.kh_next == key)
 529                 {
 530                         if(!first)
 531                                 keyowner = strcat(keyowner, ", ");
 532                         keyowner = key.owner.netname;
 533                         first = false;
 534                 }
 535
 536         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 537         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_KEYHUNT_CAPTURE), keyowner);
 538
 539         first = true;
 540         vector firstorigin = '0 0 0', lastorigin = '0 0 0', midpoint = '0 0 0';
 541         FOR_EACH_KH_KEY(key)
 542         {
 543                 vector thisorigin = kh_AttachedOrigin(key);
 544                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 545                 midpoint += thisorigin;
 546
 547                 if(!first)
 548                 {
 549                         // TODO: this effect has been replaced due to a possible crash it causes
 550                         // see https://gitlab.com/xonotic/darkplaces/issues/123
 551                         //te_lightning2(NULL, lastorigin, thisorigin);
 552                         Send_Effect(EFFECT_TR_NEXUIZPLASMA, lastorigin, thisorigin, 1);
 553                 }
 554                 lastorigin = thisorigin;
 555                 if(first)
 556                         firstorigin = thisorigin;
 557                 first = false;
 558         }
 559         if(NumTeams(kh_teams) > 2)
 560         {
 561                 //te_lightning2(NULL, lastorigin, firstorigin); // TODO see above
 562                 Send_Effect(EFFECT_TR_NEXUIZPLASMA, lastorigin, firstorigin, 1);
 563         }
 564         midpoint = midpoint * (1 / NumTeams(kh_teams));
 565         te_customflash(midpoint, 1000, 1, Team_ColorRGB(winner_team) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 566
 567         play2all(SND(KH_CAPTURE));
 568         kh_FinishRound();
 569 }
 570
 571 void kh_LoserTeam(int loser_team, entity lostkey)  // runs when a player pushes a flag carrier off the map
 572 {
 573         float f;
 574         entity attacker = NULL;
 575         if(lostkey.pusher)
 576                 if(lostkey.pusher.team != loser_team)
 577                         if(IS_PLAYER(lostkey.pusher))
 578                                 attacker = lostkey.pusher;
 579
 580         if(attacker)
 581         {
 582                 if(lostkey.kh_previous_owner)
 583                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 584                         // don't actually GIVE him the -nn points, just log
 585                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 586                 GameRules_scoring_add(attacker, KH_PUSHES, 1);
 587                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 588         }
 589         else
 590         {
 591                 int players = 0;
 592                 float of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 593
 594                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != loser_team, { ++players; });
 595
 596                 entity key;
 597                 int keys = 0;
 598                 FOR_EACH_KH_KEY(key)
 599                         if(key.owner && key.team != loser_team)
 600                                 ++keys;
 601
 602                 if(lostkey.kh_previous_owner)
 603                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 604                         // don't actually GIVE him the -nn points, just log
 605
 606                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 607                         GameRules_scoring_add(lostkey.kh_previous_owner, KH_DESTROYS, 1);
 608
 609                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 610
 611                 FOR_EACH_KH_KEY(key)
 612                         if(key.owner && key.team != loser_team)
 613                         {
 614                                 f = DistributeEvenly_Get(of);
 615                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 616                         }
 617
 618                 int fragsleft = DistributeEvenly_Get(players);
 619
 620                 // Now distribute these among all other teams...
 621                 int j = NumTeams(kh_teams) - 1;
 622                 for(int i = 0; i < NumTeams(kh_teams); ++i)
 623                 {
 624                         int thisteam = kh_Team_ByID(i);
 625                         if(thisteam == loser_team) // bad boy, no cookie - this WILL happen
 626                                 continue;
 627
 628                         players = 0;
 629                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, { ++players; });
 630
 631                         DistributeEvenly_Init(fragsleft, j);
 632                         fragsleft = DistributeEvenly_Get(j - 1);
 633                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 634
 635                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, {
 636                                 f = DistributeEvenly_Get(1);
 637                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 638                         });
 639
 640                         --j;
 641                 }
 642         }
 643
 644         int realteam = kh_Team_ByID(lostkey.count);
 645         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(loser_team, CENTER_ROUND_TEAM_LOSS));
 646         if(attacker)
 647                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PUSHED), attacker.netname, lostkey.kh_previous_owner.netname);
 648         else
 649                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DESTROYED), lostkey.kh_previous_owner.netname);
 650
 651         play2all(SND(KH_DESTROY));
 652         te_tarexplosion(lostkey.origin);
 653
 654         kh_FinishRound();
 655 }
 656
 657 void kh_Key_Think(entity this)  // runs all the time
 658 {
 659         if(game_stopped)
 660                 return;
 661
 662         if(this.owner)
 663         {
 664 #ifndef KH_PLAYER_USE_ATTACHMENT
 665                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 666                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 667 #endif
 668         }
 669
 670         // if in nodrop or time over, end the round
 671         if(!this.owner)
 672                 if(time > this.pain_finished)
 673                         kh_LoserTeam(this.team, this);
 674
 675         if(this.owner)
 676         if(kh_Key_AllOwnedByWhichTeam() != -1)
 677         {
 678                 if(this.siren_time < time)
 679                 {
 680                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 681                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 682                 }
 683
 684                 entity key;
 685                 vector p = this.owner.origin;
 686                 FOR_EACH_KH_KEY(key)
 687                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 688                                 goto not_winning;
 689                 kh_WinnerTeam(this.team);
 690 LABEL(not_winning)
 691         }
 692
 693         if(kh_interferemsg_time && time > kh_interferemsg_time)
 694         {
 695                 kh_interferemsg_time = 0;
 696                 FOREACH_CLIENT(IS_PLAYER(it), {
 697                         if(it.team == kh_interferemsg_team)
 698                         {
 699                                 if(it.kh_next)
 700                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 701                                 else
 702                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 703                         }
 704                         else
 705                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 706                 });
 707         }
 708
 709         this.nextthink = time + 0.05;
 710 }
 711
 712 void key_reset(entity this)
 713 {
 714         kh_Key_AssignTo(this, NULL);
 715         kh_Key_Remove(this);
 716 }
 717
 718 const string STR_ITEM_KH_KEY = "item_kh_key";
 719 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 720 {
 721         entity key = spawn();
 722         key.count = i;
 723         key.classname = STR_ITEM_KH_KEY;
 724         settouch(key, kh_Key_Touch);
 725         setthink(key, kh_Key_Think);
 726         key.nextthink = time;
 727         key.items = IT_KEY1 | IT_KEY2;
 728         key.cnt = _angle;
 729         key.angles = '0 360 0' * random();
 730         key.event_damage = kh_Key_Damage;
 731         key.takedamage = DAMAGE_YES;
 732         key.damagedbytriggers = autocvar_g_balance_keyhunt_return_when_unreachable;
 733         key.damagedbycontents = autocvar_g_balance_keyhunt_return_when_unreachable;
 734         key.modelindex = kh_key_dropped;
 735         key.model = "key";
 736         key.kh_dropperteam = 0;
 737         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 738         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 739         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 740         key.reset = key_reset;
 741         navigation_dynamicgoal_init(key, false);
 742
 743         switch(initial_owner.team)
 744         {
 745                 case NUM_TEAM_1:
 746                         key.netname = "^1red key";
 747                         break;
 748                 case NUM_TEAM_2:
 749                         key.netname = "^4blue key";
 750                         break;
 751                 case NUM_TEAM_3:
 752                         key.netname = "^3yellow key";
 753                         break;
 754                 case NUM_TEAM_4:
 755                         key.netname = "^6pink key";
 756                         break;
 757                 default:
 758                         key.netname = "NETGIER key";
 759                         break;
 760         }
 761
 762         // link into key list
 763         key.kh_worldkeynext = kh_worldkeylist;
 764         kh_worldkeylist = key;
 765
 766         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 767
 768         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 769         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 770
 771         kh_Key_AssignTo(key, initial_owner);
 772 }
 773
 774 // -1 when no team completely owns all keys yet
 775 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 776 {
 777         entity key;
 778         int teem = -1;
 779         int keys = NumTeams(kh_teams);
 780         FOR_EACH_KH_KEY(key)
 781         {
 782                 if(!key.owner)
 783                         return -1;
 784                 if(teem == -1)
 785                         teem = key.team;
 786                 else if(teem != key.team)
 787                         return -1;
 788                 --keys;
 789         }
 790         if(keys != 0)
 791                 return -1;
 792         return teem;
 793 }
 794
 795 void kh_Key_DropOne(entity key)
 796 {
 797         // prevent collecting this one for some time
 798         entity player = key.owner;
 799
 800         key.kh_droptime = time;
 801         key.enemy = player;
 802
 803         kh_Scores_Event(player, key, "dropkey", 0, 0);
 804         GameRules_scoring_add(player, KH_LOSSES, 1);
 805         int realteam = kh_Team_ByID(key.count);
 806         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DROP), player.netname);
 807
 808         kh_Key_AssignTo(key, NULL);
 809         makevectors(player.v_angle);
 810         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 811         key.pusher = NULL;
 812         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 813         key.kh_dropperteam = key.team;
 814
 815         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 816 }
 817
 818 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 819 {
 820         if(player.kh_next)
 821         {
 822                 entity mypusher = NULL;
 823                 if(player.pusher)
 824                         if(time < player.pushltime)
 825                                 mypusher = player.pusher;
 826
 827                 entity key;
 828                 while((key = player.kh_next))
 829                 {
 830                         kh_Scores_Event(player, key, "losekey", 0, 0);
 831                         GameRules_scoring_add(player, KH_LOSSES, 1);
 832                         int realteam = kh_Team_ByID(key.count);
 833                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_LOST), player.netname);
 834                         kh_Key_AssignTo(key, NULL);
 835                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 836                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 837                         key.pusher = mypusher;
 838                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 839                         if(suicide)
 840                                 key.kh_dropperteam = player.team;
 841                 }
 842                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 843         }
 844 }
 845
 846 int kh_GetMissingTeams()
 847 {
 848         int missing_teams = 0;
 849         for(int i = 0; i < NumTeams(kh_teams); ++i)
 850         {
 851                 int teem = kh_Team_ByID(i);
 852                 int players = 0;
 853                 FOREACH_CLIENT(IS_PLAYER(it), {
 854                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 855                                 ++players;
 856                 });
 857                 if (!players)
 858                         missing_teams |= (2 ** i);
 859         }
 860         return missing_teams;
 861 }
 862
 863 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 864 {
 865         static int prev_missing_teams_mask;
 866         if(time < game_starttime)
 867         {
 868                 if (prev_missing_teams_mask > 0)
 869                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 870                 prev_missing_teams_mask = -1;
 871                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 872                 return;
 873         }
 874
 875         int missing_teams_mask = kh_GetMissingTeams();
 876         if(!missing_teams_mask)
 877         {
 878                 if(prev_missing_teams_mask > 0)
 879                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 880                 prev_missing_teams_mask = -1;
 881                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 882                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 883         }
 884         else
 885         {
 886                 if(player_count == 0)
 887                 {
 888                         if(prev_missing_teams_mask > 0)
 889                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 890                         prev_missing_teams_mask = -1;
 891                 }
 892                 else
 893                 {
 894                         if(prev_missing_teams_mask != missing_teams_mask)
 895                         {
 896                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 897                                 prev_missing_teams_mask = missing_teams_mask;
 898                         }
 899                 }
 900                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 901         }
 902 }
 903
 904 void kh_EnableTrackingDevice()  // runs after each round
 905 {
 906         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 907         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 908
 909         kh_tracking_enabled = true;
 910 }
 911
 912 void kh_StartRound()  // runs at the start of each round
 913 {
 914         if(time < game_starttime)
 915         {
 916                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 917                 return;
 918         }
 919
 920         if(kh_GetMissingTeams())
 921         {
 922                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 923                 return;
 924         }
 925
 926         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 927         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 928
 929         for(int i = 0; i < NumTeams(kh_teams); ++i)
 930         {
 931                 int teem = kh_Team_ByID(i);
 932                 int players = 0;
 933                 entity my_player = NULL;
 934                 FOREACH_CLIENT(IS_PLAYER(it), {
 935                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 936                         {
 937                                 ++players;
 938                                 if(random() * players <= 1)
 939                                         my_player = it;
 940                         }
 941                 });
 942                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 943         }
 944
 945         kh_tracking_enabled = false;
 946         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 947         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 948 }
 949
 950 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 951 {
 952         if(attacker == targ)
 953                 return f;
 954
 955         if(targ.kh_next)
 956         {
 957                 if(attacker.team == targ.team)
 958                 {
 959                         int nk = 0;
 960                         for(entity k = targ.kh_next; k != NULL; k = k.kh_next)
 961                                 ++nk;
 962                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 963                 }
 964                 else
 965                 {
 966                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 967                         GameRules_scoring_add(attacker, KH_KCKILLS, 1);
 968                         // the frag gets added later
 969                 }
 970         }
 971
 972         return f;
 973 }
 974
 975 void kh_Initialize()  // sets up th KH environment
 976 {
 977         // setup variables
 978         kh_teams = autocvar_g_keyhunt_teams_override;
 979         if(kh_teams < 2)
 980                 kh_teams = cvar("g_keyhunt_teams"); // read the cvar directly as it gets written earlier in the same frame
 981         kh_teams = BITS(bound(2, kh_teams, 4));
 982
 983         // make a KH entity for controlling the game
 984         kh_controller = spawn();
 985         setthink(kh_controller, kh_Controller_Think);
 986         kh_Controller_SetThink(0, kh_WaitForPlayers);
 987
 988         setmodel(kh_controller, MDL_KH_KEY);
 989         kh_key_dropped = kh_controller.modelindex;
 990         /*
 991         dprint(vtos(kh_controller.mins));
 992         dprint(vtos(kh_controller.maxs));
 993         dprint("\n");
 994         */
 995 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 996         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
 997         kh_key_carried = kh_controller.modelindex;
 998 #else
 999         kh_key_carried = kh_key_dropped;
1000 #endif
1001
1002         kh_controller.model = "";
1003         kh_controller.modelindex = 0;
1004
1005         kh_ScoreRules(kh_teams);
1006 }
1007
1008 void kh_finalize()
1009 {
1010         // to be called before intermission
1011         kh_FinishRound();
1012         delete(kh_controller);
1013         kh_controller = NULL;
1014 }
1015
1016 // legacy bot role
1017
1018 void(entity this) havocbot_role_kh_carrier;
1019 void(entity this) havocbot_role_kh_defense;
1020 void(entity this) havocbot_role_kh_offense;
1021 void(entity this) havocbot_role_kh_freelancer;
1022
1023
1024 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1025 {
1026         entity head;
1027         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1028         {
1029                 if(head.owner == this)
1030                         continue;
1031                 if(!kh_tracking_enabled)
1032                 {
1033                         // if it's carried by our team we know about it
1034                         // otherwise we have to see it to know about it
1035                         if(!head.owner || head.team != this.team)
1036                         {
1037                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1038                                 if (trace_fraction < 1 && trace_ent != head)
1039                                         continue; // skip what I can't see
1040                         }
1041                 }
1042                 if(!head.owner)
1043                         navigation_routerating(this, head, ratingscale_dropped * 10000, 100000);
1044                 else if(head.team == this.team)
1045                         navigation_routerating(this, head.owner, ratingscale_team * 10000, 100000);
1046                 else
1047                         navigation_routerating(this, head.owner, ratingscale_enemy * 10000, 100000);
1048         }
1049
1050         havocbot_goalrating_items(this, 80000, this.origin, 10000);
1051 }
1052
1053 void havocbot_role_kh_carrier(entity this)
1054 {
1055         if(IS_DEAD(this))
1056                 return;
1057
1058         if (!(this.kh_next))
1059         {
1060                 LOG_TRACE("changing role to freelancer");
1061                 this.havocbot_role = havocbot_role_kh_freelancer;
1062                 this.havocbot_role_timeout = 0;
1063                 return;
1064         }
1065
1066         if (navigation_goalrating_timeout(this))
1067         {
1068                 navigation_goalrating_start(this);
1069
1070                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1071                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // bring home
1072                 else
1073                         havocbot_goalrating_kh(this, 4, 4, 0.5); // play defensively
1074
1075                 navigation_goalrating_end(this);
1076
1077                 navigation_goalrating_timeout_set(this);
1078         }
1079 }
1080
1081 void havocbot_role_kh_defense(entity this)
1082 {
1083         if(IS_DEAD(this))
1084                 return;
1085
1086         if (this.kh_next)
1087         {
1088                 LOG_TRACE("changing role to carrier");
1089                 this.havocbot_role = havocbot_role_kh_carrier;
1090                 this.havocbot_role_timeout = 0;
1091                 return;
1092         }
1093
1094         if (!this.havocbot_role_timeout)
1095                 this.havocbot_role_timeout = time + random() * 10 + 20;
1096         if (time > this.havocbot_role_timeout)
1097         {
1098                 LOG_TRACE("changing role to freelancer");
1099                 this.havocbot_role = havocbot_role_kh_freelancer;
1100                 this.havocbot_role_timeout = 0;
1101                 return;
1102         }
1103
1104         if (navigation_goalrating_timeout(this))
1105         {
1106                 float key_owner_team;
1107                 navigation_goalrating_start(this);
1108
1109                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1110                 if(key_owner_team == this.team)
1111                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend key carriers
1112                 else if(key_owner_team == -1)
1113                         havocbot_goalrating_kh(this, 4, 1, 0.05); // play defensively
1114                 else
1115                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1116
1117                 navigation_goalrating_end(this);
1118
1119                 navigation_goalrating_timeout_set(this);
1120         }
1121 }
1122
1123 void havocbot_role_kh_offense(entity this)
1124 {
1125         if(IS_DEAD(this))
1126                 return;
1127
1128         if (this.kh_next)
1129         {
1130                 LOG_TRACE("changing role to carrier");
1131                 this.havocbot_role = havocbot_role_kh_carrier;
1132                 this.havocbot_role_timeout = 0;
1133                 return;
1134         }
1135
1136         if (!this.havocbot_role_timeout)
1137                 this.havocbot_role_timeout = time + random() * 10 + 20;
1138         if (time > this.havocbot_role_timeout)
1139         {
1140                 LOG_TRACE("changing role to freelancer");
1141                 this.havocbot_role = havocbot_role_kh_freelancer;
1142                 this.havocbot_role_timeout = 0;
1143                 return;
1144         }
1145
1146         if (navigation_goalrating_timeout(this))
1147         {
1148                 float key_owner_team;
1149
1150                 navigation_goalrating_start(this);
1151
1152                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1153                 if(key_owner_team == this.team)
1154                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1155                 else if(key_owner_team == -1)
1156                         havocbot_goalrating_kh(this, 0.1, 1, 2); // play offensively
1157                 else
1158                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK! EMERGENCY!
1159
1160                 navigation_goalrating_end(this);
1161
1162                 navigation_goalrating_timeout_set(this);
1163         }
1164 }
1165
1166 void havocbot_role_kh_freelancer(entity this)
1167 {
1168         if(IS_DEAD(this))
1169                 return;
1170
1171         if (this.kh_next)
1172         {
1173                 LOG_TRACE("changing role to carrier");
1174                 this.havocbot_role = havocbot_role_kh_carrier;
1175                 this.havocbot_role_timeout = 0;
1176                 return;
1177         }
1178
1179         if (!this.havocbot_role_timeout)
1180                 this.havocbot_role_timeout = time + random() * 10 + 10;
1181         if (time > this.havocbot_role_timeout)
1182         {
1183                 if (random() < 0.5)
1184                 {
1185                         LOG_TRACE("changing role to offense");
1186                         this.havocbot_role = havocbot_role_kh_offense;
1187                 }
1188                 else
1189                 {
1190                         LOG_TRACE("changing role to defense");
1191                         this.havocbot_role = havocbot_role_kh_defense;
1192                 }
1193                 this.havocbot_role_timeout = 0;
1194                 return;
1195         }
1196
1197         if (navigation_goalrating_timeout(this))
1198         {
1199                 navigation_goalrating_start(this);
1200
1201                 int key_owner_team = kh_Key_AllOwnedByWhichTeam();
1202                 if(key_owner_team == this.team)
1203                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1204                 else if(key_owner_team == -1)
1205                         havocbot_goalrating_kh(this, 1, 10, 2); // prefer dropped keys
1206                 else
1207                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1208
1209                 navigation_goalrating_end(this);
1210
1211                 navigation_goalrating_timeout_set(this);
1212         }
1213 }
1214
1215
1216 // register this as a mutator
1217
1218 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1219 {
1220         entity player = M_ARGV(0, entity);
1221
1222         kh_Key_DropAll(player, true);
1223 }
1224
1225 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1226 {
1227         entity player = M_ARGV(0, entity);
1228
1229         kh_Key_DropAll(player, true);
1230 }
1231
1232 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1233 {
1234         entity frag_attacker = M_ARGV(1, entity);
1235         entity frag_target = M_ARGV(2, entity);
1236
1237         if(frag_target == frag_attacker)
1238                 kh_Key_DropAll(frag_target, true);
1239         else if(IS_PLAYER(frag_attacker))
1240                 kh_Key_DropAll(frag_target, false);
1241         else
1242                 kh_Key_DropAll(frag_target, true);
1243 }
1244
1245 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1246 {
1247         entity frag_attacker = M_ARGV(0, entity);
1248         entity frag_target = M_ARGV(1, entity);
1249         float frag_score = M_ARGV(2, float);
1250         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1251 }
1252
1253 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1254 {
1255         kh_finalize();
1256 }
1257
1258 MUTATOR_HOOKFUNCTION(kh, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1259 {
1260         M_ARGV(0, float) = kh_teams;
1261         return true;
1262 }
1263
1264 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1265 {
1266         entity spectatee = M_ARGV(0, entity);
1267         entity client = M_ARGV(1, entity);
1268
1269         STAT(KH_KEYS, client) = STAT(KH_KEYS, spectatee);
1270 }
1271
1272 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1273 {
1274         entity player = M_ARGV(0, entity);
1275
1276         if(MUTATOR_RETURNVALUE == 0)
1277         {
1278                 entity k = player.kh_next;
1279                 if(k)
1280                 {
1281                         kh_Key_DropOne(k);
1282                         return true;
1283                 }
1284         }
1285 }
1286
1287 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1288 {
1289     entity bot = M_ARGV(0, entity);
1290
1291         if(IS_DEAD(bot))
1292                 return true;
1293
1294         float r = random() * 3;
1295         if (r < 1)
1296                 bot.havocbot_role = havocbot_role_kh_offense;
1297         else if (r < 2)
1298                 bot.havocbot_role = havocbot_role_kh_defense;
1299         else
1300                 bot.havocbot_role = havocbot_role_kh_freelancer;
1301
1302         return true;
1303 }
1304
1305 MUTATOR_HOOKFUNCTION(kh, LogDeath_AppendItemCodes)
1306 {
1307         entity player = M_ARGV(0, entity);
1308         if(player.kh_next)
1309                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "K"); // item codes
1310 }
1311
1312 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1313 {
1314         entity frag_target = M_ARGV(0, entity);
1315
1316         kh_Key_DropAll(frag_target, false);
1317 }
1318
1319 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1320 {
1321         kh_WaitForPlayers(); // takes care of killing the "missing teams" message
1322 }