qcsrc/common/gamemodes/gamemode/freezetag/sv_freezetag.qc

   1 #include "sv_freezetag.qh"
   2
   3 #include <server/elimination.qh>
   4 #include <server/resources.qh>
   5
   6 float autocvar_g_freezetag_frozen_maxtime;
   7 float autocvar_g_freezetag_revive_clearspeed;
   8 float autocvar_g_freezetag_round_timelimit;
   9 //int autocvar_g_freezetag_teams;
  10 int autocvar_g_freezetag_teams_override;
  11 float autocvar_g_freezetag_warmup;
  12
  13 float autocvar_g_ft_start_health = 100;
  14 float autocvar_g_ft_start_armor = 100;
  15 float autocvar_g_ft_start_ammo_shells = 60;
  16 float autocvar_g_ft_start_ammo_nails = 320;
  17 float autocvar_g_ft_start_ammo_rockets = 160;
  18 float autocvar_g_ft_start_ammo_cells = 180;
  19 float autocvar_g_ft_start_ammo_plasma = 180;
  20 float autocvar_g_ft_start_ammo_fuel = 0;
  21
  22 void freezetag_count_alive_players()
  23 {
  24         total_players = 0;
  25         for (int i = 1; i <= NUM_TEAMS; ++i)
  26         {
  27                 Team_SetNumberOfAlivePlayers(Team_GetTeamFromIndex(i), 0);
  28         }
  29         FOREACH_CLIENT(IS_PLAYER(it) && Entity_HasValidTeam(it),
  30         {
  31                 ++total_players;
  32                 if (GetResource(it, RES_HEALTH) < 1 || STAT(FROZEN, it) == FROZEN_NORMAL)
  33                 {
  34                         continue;
  35                 }
  36                 entity team_ = Entity_GetTeam(it);
  37                 int num_alive = Team_GetNumberOfAlivePlayers(team_);
  38                 ++num_alive;
  39                 Team_SetNumberOfAlivePlayers(team_, num_alive);
  40         });
  41         FOREACH_CLIENT(IS_REAL_CLIENT(it),
  42         {
  43                 STAT(REDALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(
  44                         1));
  45                 STAT(BLUEALIVE, it) = Team_GetNumberOfAlivePlayers(
  46                         Team_GetTeamFromIndex(2));
  47                 STAT(YELLOWALIVE, it) = Team_GetNumberOfAlivePlayers(
  48                         Team_GetTeamFromIndex(3));
  49                 STAT(PINKALIVE, it) = Team_GetNumberOfAlivePlayers(
  50                         Team_GetTeamFromIndex(4));
  51         });
  52
  53         eliminatedPlayers.SendFlags |= 1;
  54 }
  55
  56 bool freezetag_CheckTeams()
  57 {
  58         static float prev_missing_teams_mask;
  59         if (Team_GetNumberOfAliveTeams() == NumTeams(freezetag_teams))
  60         {
  61                 if(prev_missing_teams_mask > 0)
  62                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  63                 prev_missing_teams_mask = -1;
  64                 return true;
  65         }
  66         if(total_players == 0)
  67         {
  68                 if(prev_missing_teams_mask > 0)
  69                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  70                 prev_missing_teams_mask = -1;
  71                 return false;
  72         }
  73         int missing_teams_mask = 0;
  74         for (int i = 1; i <= NUM_TEAMS; ++i)
  75         {
  76                 if ((freezetag_teams & Team_IndexToBit(i)) &&
  77                         (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) == 0))
  78                 {
  79                         missing_teams_mask |= Team_IndexToBit(i);
  80                 }
  81         }
  82         if(prev_missing_teams_mask != missing_teams_mask)
  83         {
  84                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
  85                 prev_missing_teams_mask = missing_teams_mask;
  86         }
  87         return false;
  88 }
  89
  90 int freezetag_getWinnerTeam()
  91 {
  92         int winner_team = 0;
  93         if (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(1)) >= 1)
  94         {
  95                 winner_team = NUM_TEAM_1;
  96         }
  97         for (int i = 2; i <= NUM_TEAMS; ++i)
  98         {
  99                 if (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) >= 1)
 100                 {
 101                         if (winner_team != 0)
 102                         {
 103                                 return 0;
 104                         }
 105                         winner_team = Team_IndexToTeam(i);
 106                 }
 107         }
 108         if (winner_team)
 109         {
 110                 return winner_team;
 111         }
 112         return -1; // no player left
 113 }
 114
 115 void nades_Clear(entity);
 116 void nades_GiveBonus(entity player, float score);
 117
 118 bool freezetag_CheckWinner()
 119 {
 120         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 121         {
 122                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
 123                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
 124                 FOREACH_CLIENT(IS_PLAYER(it), {
 125                         it.freezetag_frozen_timeout = 0;
 126                         it.freezetag_revive_time = 0;
 127                         nades_Clear(it);
 128                 });
 129                 game_stopped = true;
 130                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 131                 return true;
 132         }
 133
 134         if (Team_GetNumberOfAliveTeams() > 1)
 135         {
 136                 return false;
 137         }
 138
 139         int winner_team = freezetag_getWinnerTeam();
 140         if(winner_team > 0)
 141         {
 142                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 143                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 144                 TeamScore_AddToTeam(winner_team, ST_FT_ROUNDS, +1);
 145         }
 146         else if(winner_team == -1)
 147         {
 148                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
 149                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
 150         }
 151
 152         FOREACH_CLIENT(IS_PLAYER(it), {
 153                 it.freezetag_frozen_timeout = 0;
 154                 it.freezetag_revive_time = 0;
 155                 nades_Clear(it);
 156         });
 157
 158         game_stopped = true;
 159         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 160         return true;
 161 }
 162
 163 entity freezetag_LastPlayerForTeam(entity this)
 164 {
 165         entity last_pl = NULL;
 166         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 167                 if (STAT(FROZEN, it) != FROZEN_NORMAL && GetResource(it, RES_HEALTH) >= 1)
 168                 {
 169                         if (!last_pl)
 170                                 last_pl = it;
 171                         else
 172                                 return NULL;
 173                 }
 174         });
 175         return last_pl;
 176 }
 177
 178 void freezetag_LastPlayerForTeam_Notify(entity this)
 179 {
 180         if(round_handler_IsActive())
 181         if(round_handler_IsRoundStarted())
 182         {
 183                 entity pl = freezetag_LastPlayerForTeam(this);
 184                 if(pl)
 185                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 186         }
 187 }
 188
 189 void freezetag_Add_Score(entity targ, entity attacker)
 190 {
 191         if(attacker == targ)
 192         {
 193                 // you froze your own dumb self
 194                 // counted as "suicide" already
 195                 GameRules_scoring_add(targ, SCORE, -1);
 196         }
 197         else if(IS_PLAYER(attacker))
 198         {
 199                 // got frozen by an enemy
 200                 // counted as "kill" and "death" already
 201                 GameRules_scoring_add(targ, SCORE, -1);
 202                 GameRules_scoring_add(attacker, SCORE, +1);
 203         }
 204         // else nothing - got frozen by the game type rules themselves
 205 }
 206
 207 // to be called when the player is frozen by freezetag (on death, spectator join etc), gives the score
 208 void freezetag_Freeze(entity targ, entity attacker)
 209 {
 210         if(STAT(FROZEN, targ))
 211                 return;
 212
 213         targ.freezetag_frozen_time = time;
 214         if (autocvar_g_freezetag_revive_auto && autocvar_g_freezetag_frozen_maxtime > 0)
 215                 targ.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 216
 217         Freeze(targ, 0, FROZEN_NORMAL, true);
 218
 219         freezetag_count_alive_players();
 220
 221         freezetag_Add_Score(targ, attacker);
 222 }
 223
 224 bool freezetag_isEliminated(entity e)
 225 {
 226         if(IS_PLAYER(e) && (STAT(FROZEN, e) == FROZEN_NORMAL || IS_DEAD(e)))
 227                 return true;
 228         return false;
 229 }
 230
 231
 232 // ================
 233 // Bot player logic
 234 // ================
 235
 236 void(entity this) havocbot_role_ft_freeing;
 237 void(entity this) havocbot_role_ft_offense;
 238
 239 void havocbot_goalrating_ft_freeplayers(entity this, float ratingscale, vector org, float sradius)
 240 {
 241         entity best_pl = NULL;
 242         float best_dist2 = FLOAT_MAX;
 243         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 244                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
 245                 {
 246                         if(vdist(it.origin - org, >, sradius))
 247                                 continue;
 248                         navigation_routerating(this, it, ratingscale, 2000);
 249                 }
 250                 else if (best_dist2
 251                         && GetResource(it, RES_HEALTH) < GetResource(this, RES_HEALTH) + 30
 252                         && vlen2(it.origin - org) < best_dist2)
 253                 {
 254                         // If teamate is not frozen still seek them out as fight better
 255                         // in a group.
 256                         best_dist2 = vlen2(it.origin - org);
 257                         if (best_dist2 < 700 ** 2)
 258                         {
 259                                 best_pl = NULL;
 260                                 best_dist2 = 0; // already close to a teammate
 261                         }
 262                         else
 263                                 best_pl = it;
 264                 }
 265         });
 266         if (best_pl)
 267                 navigation_routerating(this, best_pl, ratingscale / 2, 2000);
 268 }
 269
 270 void havocbot_role_ft_offense(entity this)
 271 {
 272         if(IS_DEAD(this))
 273                 return;
 274
 275         if (!this.havocbot_role_timeout)
 276                 this.havocbot_role_timeout = time + random() * 10 + 20;
 277
 278         // Count how many players on team are unfrozen.
 279         int unfrozen = 0;
 280         FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, this) && STAT(FROZEN, it) != FROZEN_NORMAL, {
 281                 unfrozen++;
 282         });
 283
 284         // If only one left on team or if role has timed out then start trying to free players.
 285         if ((!unfrozen && STAT(FROZEN, this) != FROZEN_NORMAL) || time > this.havocbot_role_timeout)
 286         {
 287                 LOG_TRACE("changing role to freeing");
 288                 this.havocbot_role = havocbot_role_ft_freeing;
 289                 this.havocbot_role_timeout = 0;
 290                 return;
 291         }
 292
 293         if (navigation_goalrating_timeout(this))
 294         {
 295                 navigation_goalrating_start(this);
 296                 havocbot_goalrating_items(this, 12000, this.origin, 10000);
 297                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 298                 havocbot_goalrating_ft_freeplayers(this, 9000, this.origin, 10000);
 299                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 300                 navigation_goalrating_end(this);
 301
 302                 navigation_goalrating_timeout_set(this);
 303         }
 304 }
 305
 306 void havocbot_role_ft_freeing(entity this)
 307 {
 308         if(IS_DEAD(this))
 309                 return;
 310
 311         if (!this.havocbot_role_timeout)
 312                 this.havocbot_role_timeout = time + random() * 10 + 20;
 313
 314         if (time > this.havocbot_role_timeout)
 315         {
 316                 LOG_TRACE("changing role to offense");
 317                 this.havocbot_role = havocbot_role_ft_offense;
 318                 this.havocbot_role_timeout = 0;
 319                 return;
 320         }
 321
 322         if (navigation_goalrating_timeout(this))
 323         {
 324                 navigation_goalrating_start(this);
 325                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 326                 havocbot_goalrating_enemyplayers(this, 5000, this.origin, 10000);
 327                 havocbot_goalrating_ft_freeplayers(this, 20000, this.origin, 10000);
 328                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 329                 navigation_goalrating_end(this);
 330
 331                 navigation_goalrating_timeout_set(this);
 332         }
 333 }
 334
 335
 336 // ==============
 337 // Hook Functions
 338 // ==============
 339
 340 void ft_RemovePlayer(entity this)
 341 {
 342         if (STAT(FROZEN, this) != FROZEN_NORMAL)
 343                 freezetag_LastPlayerForTeam_Notify(this);
 344         Unfreeze(this, false);
 345
 346         SetResourceExplicit(this, RES_HEALTH, 0); // neccessary to correctly count alive players
 347         freezetag_count_alive_players();
 348 }
 349
 350 MUTATOR_HOOKFUNCTION(ft, ClientDisconnect)
 351 {
 352         entity player = M_ARGV(0, entity);
 353
 354         ft_RemovePlayer(player);
 355         return true;
 356 }
 357
 358 MUTATOR_HOOKFUNCTION(ft, MakePlayerObserver)
 359 {
 360         entity player = M_ARGV(0, entity);
 361
 362         ft_RemovePlayer(player);
 363 }
 364
 365 MUTATOR_HOOKFUNCTION(ft, PlayerDies)
 366 {
 367         entity frag_attacker = M_ARGV(1, entity);
 368         entity frag_target = M_ARGV(2, entity);
 369         float frag_deathtype = M_ARGV(3, float);
 370
 371         if(round_handler_IsActive())
 372         if(round_handler_CountdownRunning())
 373         {
 374                 if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 375                         Unfreeze(frag_target, true);
 376                 freezetag_count_alive_players();
 377                 frag_target.respawn_time = time;
 378                 frag_target.respawn_flags |= RESPAWN_FORCE;
 379                 return true;
 380         }
 381
 382         frag_target.respawn_time = time + 1;
 383         frag_target.respawn_flags |= RESPAWN_FORCE;
 384
 385         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 386         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 387         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 388                 || frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
 389         {
 390                 // let the player die, he will be automatically frozen when he respawns
 391                 if (STAT(FROZEN, frag_target) != FROZEN_NORMAL)
 392                 {
 393                         freezetag_Add_Score(frag_target, frag_attacker);
 394                         freezetag_count_alive_players();
 395                         freezetag_LastPlayerForTeam_Notify(frag_target);
 396                         frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
 397                 }
 398                 else
 399                 {
 400                         float t = frag_target.freezetag_frozen_timeout;
 401                         float t2 = frag_target.freezetag_frozen_time;
 402                         Unfreeze(frag_target, false); // remove ice
 403                         // keep timeout value so it can be restored when player will be refrozen on respawn
 404                         // NOTE this can't be exactly -2 since game starts from time 2
 405                         frag_target.freezetag_frozen_timeout = -t;
 406                         frag_target.freezetag_frozen_time = t2;
 407                 }
 408                 return true;
 409         }
 410
 411         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 412                 return true;
 413
 414         freezetag_Freeze(frag_target, frag_attacker);
 415         freezetag_LastPlayerForTeam_Notify(frag_target);
 416
 417         if(frag_attacker == frag_target || frag_attacker == NULL)
 418         {
 419                 if(IS_PLAYER(frag_target))
 420                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 421                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 422         }
 423         else
 424         {
 425                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 426         }
 427
 428         return true;
 429 }
 430
 431 MUTATOR_HOOKFUNCTION(ft, PlayerSpawn)
 432 {
 433         entity player = M_ARGV(0, entity);
 434
 435         if(player.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 436                 return true; // do nothing, round is starting right now
 437
 438         if(player.freezetag_frozen_timeout <= -2) // player was dead
 439         {
 440                 float t = player.freezetag_frozen_timeout;
 441                 float t2 = player.freezetag_frozen_time;
 442                 freezetag_Freeze(player, NULL);
 443                 if (t < -2)
 444                 {
 445                         player.freezetag_frozen_timeout = -t;
 446                         player.freezetag_frozen_time = t2;
 447                 }
 448                 return true;
 449         }
 450
 451         freezetag_count_alive_players();
 452
 453         if(round_handler_IsActive())
 454         if(round_handler_IsRoundStarted())
 455         {
 456                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 457                 freezetag_Freeze(player, NULL);
 458         }
 459
 460         return true;
 461 }
 462
 463 MUTATOR_HOOKFUNCTION(ft, reset_map_players)
 464 {
 465         FOREACH_CLIENT(IS_PLAYER(it), {
 466                 CS(it).killcount = 0;
 467                 it.freezetag_revive_time = 0;
 468                 it.freezetag_frozen_timeout = -1;
 469                 PutClientInServer(it);
 470                 it.freezetag_frozen_timeout = 0;
 471         });
 472         freezetag_count_alive_players();
 473         return true;
 474 }
 475
 476 MUTATOR_HOOKFUNCTION(ft, GiveFragsForKill, CBC_ORDER_FIRST)
 477 {
 478         M_ARGV(2, float) = 0; // no frags counted in Freeze Tag
 479         return true;
 480 }
 481
 482 MUTATOR_HOOKFUNCTION(ft, Unfreeze)
 483 {
 484         entity targ = M_ARGV(0, entity);
 485         targ.freezetag_frozen_time = 0;
 486         targ.freezetag_frozen_timeout = 0;
 487 }
 488
 489 MUTATOR_HOOKFUNCTION(ft, Damage_Calculate)
 490 {
 491         entity frag_attacker = M_ARGV(1, entity);
 492         entity frag_target = M_ARGV(2, entity);
 493         //float frag_deathtype = M_ARGV(3, float);
 494         //float frag_damage = M_ARGV(4, float);
 495         vector frag_force = M_ARGV(6, vector);
 496
 497         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto_reducible
 498                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto)
 499         {
 500                 float t = 0;
 501                 if ((autocvar_g_freezetag_revive_auto_reducible < 0 || DIFF_TEAM(frag_attacker, frag_target))
 502                         && frag_target.freezetag_frozen_timeout > time)
 503                 {
 504                         if (fabs(autocvar_g_freezetag_revive_auto_reducible) == 1)
 505                         {
 506                                 float maxforce = autocvar_g_freezetag_revive_auto_reducible_maxforce;
 507                                 t = vlen(frag_force);
 508                                 // limit hit force considered at once, e.g when you have the Strength
 509                                 // powerup but also with weapons that fire multiple projectiles at once (crylink)
 510                                 if (frag_target.freezetag_frozen_force + t > maxforce)
 511                                 {
 512                                         t = max(0, maxforce - frag_target.freezetag_frozen_force);
 513                                         frag_target.freezetag_frozen_force = maxforce;
 514                                 }
 515                                 else
 516                                         frag_target.freezetag_frozen_force += t;
 517                                 t *= autocvar_g_freezetag_revive_auto_reducible_forcefactor;
 518                         }
 519                         frag_target.freezetag_frozen_timeout -= t;
 520                         if (frag_target.freezetag_frozen_timeout < time)
 521                                 frag_target.freezetag_frozen_timeout = time;
 522                 }
 523         }
 524 }
 525
 526 #ifdef IN_REVIVING_RANGE
 527         #undef IN_REVIVING_RANGE
 528 #endif
 529
 530 #define IN_REVIVING_RANGE(player, it, revive_extra_size) \
 531         (it != player && !IS_DEAD(it) && SAME_TEAM(it, player) \
 532         && boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
 533
 534 MUTATOR_HOOKFUNCTION(ft, PlayerPreThink, CBC_ORDER_FIRST)
 535 {
 536         if(game_stopped)
 537                 return true;
 538
 539         if(round_handler_IsActive())
 540         if(!round_handler_IsRoundStarted())
 541                 return true;
 542
 543         entity player = M_ARGV(0, entity);
 544         //if (STAT(FROZEN, player) == FROZEN_NORMAL)
 545         //if(player.freezetag_frozen_timeout > 0 && time < player.freezetag_frozen_timeout)
 546                 //player.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (player.freezetag_frozen_timeout - time) / (player.freezetag_frozen_timeout - player.freezetag_frozen_time);
 547
 548         player.freezetag_frozen_force = 0;
 549
 550         if (!(frametime && IS_PLAYER(player)))
 551                 return true;
 552
 553         entity revivers_last = NULL;
 554         entity revivers_first = NULL;
 555
 556         bool player_is_reviving = false;
 557         int n = 0;
 558         vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 559         FOREACH_CLIENT(IS_PLAYER(it), {
 560                 // check if player is reviving anyone
 561                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
 562                 {
 563                         if ((STAT(FROZEN, player) == FROZEN_NORMAL))
 564                                 continue;
 565                         if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
 566                                 continue;
 567                         player_is_reviving = true;
 568                         break;
 569                 }
 570
 571                 if (!(STAT(FROZEN, player) == FROZEN_NORMAL))
 572                         continue; // both player and it are NOT frozen
 573                 if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
 574                         continue;
 575
 576                 // found a teammate that is reviving player
 577                 if (autocvar_g_freezetag_revive_time_to_score > 0 && STAT(FROZEN, player) == FROZEN_NORMAL)
 578                 {
 579                         it.freezetag_revive_time += frametime / autocvar_g_freezetag_revive_time_to_score;
 580                         while (it.freezetag_revive_time > 1)
 581                         {
 582                                 GameRules_scoring_add(it, SCORE, +1);
 583                                 it.freezetag_revive_time -= 1;
 584                         }
 585                 }
 586                 if (revivers_last)
 587                         revivers_last.chain = it;
 588                 revivers_last = it;
 589                 if (!revivers_first)
 590                         revivers_first = it;
 591                 ++n;
 592         });
 593         if (revivers_last)
 594                 revivers_last.chain = NULL;
 595
 596         // allow normal revival during automatic revival
 597         // (if we wouldn't allow it then freezetag_frozen_timeout should be checked too in the previous loop)
 598         //if (STAT(FROZEN, player) == FROZEN_NORMAL) // redundant check
 599         if (!n && player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
 600                 n = -1;
 601
 602         float base_progress = 0;
 603         if  (STAT(FROZEN, player) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto
 604                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto_progress)
 605         {
 606                 // NOTE if auto-revival is in progress, manual revive speed is reduced so that it always takes the same amount of time
 607                 base_progress = bound(0, (1 - (player.freezetag_frozen_timeout - time) / autocvar_g_freezetag_frozen_maxtime), 1);
 608         }
 609
 610         if (!n) // no teammate nearby
 611         {
 612                 float clearspeed = autocvar_g_freezetag_revive_clearspeed;
 613                 if (STAT(FROZEN, player) == FROZEN_NORMAL)
 614                 {
 615                         if (autocvar_g_freezetag_revive_time_to_score > 0)
 616                         {
 617                                 if (STAT(REVIVE_PROGRESS, player) > base_progress)
 618                                 {
 619                                         // reduce auto-revival time based on manual revival progress
 620                                         base_progress = STAT(REVIVE_PROGRESS, player);
 621                                         player.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime * (1 - STAT(REVIVE_PROGRESS, player));
 622                                 }
 623                                 // don't clear revive progress, it would allow stacking points
 624                                 // by entering and exiting the revival zone many times
 625                                 STAT(REVIVE_PROGRESS, player) = base_progress;
 626                         }
 627                         else
 628                                 STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) - frametime * clearspeed * (1 - base_progress), 1);
 629                 }
 630                 else if (!STAT(FROZEN, player) && !player_is_reviving)
 631                         STAT(REVIVE_PROGRESS, player) = base_progress; // thawing nobody
 632         }
 633         else if (STAT(FROZEN, player) == FROZEN_NORMAL) // OK, there is at least one teammate reviving us
 634         {
 635                 float spd = autocvar_g_freezetag_revive_speed_t2s;
 636                 if (autocvar_g_freezetag_revive_time_to_score <= 0)
 637                         spd = autocvar_g_freezetag_revive_speed * (1 - base_progress);
 638                 STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) + frametime * max(1/60, spd), 1);
 639
 640                 if(STAT(REVIVE_PROGRESS, player) >= 1)
 641                 {
 642                         float frozen_time = time - player.freezetag_frozen_time;
 643                         Unfreeze(player, false);
 644                         SetResourceExplicit(player, RES_HEALTH, ((warmup_stage) ? warmup_start_health : start_health));
 645                         player.spawnshieldtime = time + autocvar_g_freezetag_revive_spawnshield;
 646                         freezetag_count_alive_players();
 647
 648                         if(n == -1)
 649                         {
 650                                 if(autocvar_sv_eventlog)
 651                                         GameLogEcho(strcat(":ft:autorevival:", ftos(player.playerid)));
 652                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, frozen_time);
 653                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, player.netname, frozen_time);
 654                                 return true;
 655                         }
 656
 657                         // EVERY team mate nearby gets a point (even if multiple!)
 658                         for(entity it = revivers_first; it; it = it.chain)
 659                         {
 660                                 GameRules_scoring_add(it, FREEZETAG_REVIVALS, +1);
 661                                 if (autocvar_g_freezetag_revive_time_to_score <= 0)
 662                                         GameRules_scoring_add(it, SCORE, +1);
 663                                 nades_GiveBonus(it, autocvar_g_nades_bonus_score_low);
 664                         }
 665
 666                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, revivers_first.netname);
 667                         Send_Notification(NOTIF_ONE, revivers_first, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
 668                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED, player.netname, revivers_first.netname);
 669                         if(autocvar_sv_eventlog)
 670                         {
 671                                 string revivers = "";
 672                                 for(entity it = revivers_first; it; it = it.chain)
 673                                         revivers = strcat(revivers, ftos(it.playerid), ",");
 674                                 revivers = substring(revivers, 0, strlen(revivers) - 1);
 675                                 GameLogEcho(strcat(":ft:revival:", ftos(player.playerid), ":", revivers));
 676                         }
 677                 }
 678
 679                 for(entity it = revivers_first; it; it = it.chain)
 680                         STAT(REVIVE_PROGRESS, it) = STAT(REVIVE_PROGRESS, player);
 681         }
 682
 683         if (STAT(FROZEN, player) == FROZEN_NORMAL)
 684         {
 685                 entity player_wp = player.waypointsprite_attached;
 686                 if (n > 0 || (n == 0 && STAT(REVIVE_PROGRESS, player) > 0.95))
 687                 {
 688                         WaypointSprite_UpdateSprites(player_wp, WP_Reviving, WP_Null, WP_Null);
 689                         WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_REVIVING_COLOR);
 690                 }
 691                 else
 692                 {
 693                         WaypointSprite_UpdateSprites(player_wp, WP_Frozen, WP_Null, WP_Null);
 694                         WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_FROZEN_COLOR);
 695                 }
 696
 697                 WaypointSprite_UpdateMaxHealth(player_wp, 1);
 698                 WaypointSprite_UpdateHealth(player_wp, STAT(REVIVE_PROGRESS, player));
 699         }
 700
 701         return true;
 702 }
 703
 704 MUTATOR_HOOKFUNCTION(ft, SetStartItems)
 705 {
 706         start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
 707         if(!cvar("g_use_ammunition"))
 708                 start_items |= IT_UNLIMITED_AMMO;
 709
 710         start_health       = warmup_start_health       = autocvar_g_ft_start_health;
 711         start_armorvalue   = warmup_start_armorvalue   = autocvar_g_ft_start_armor;
 712         start_ammo_shells  = warmup_start_ammo_shells  = autocvar_g_ft_start_ammo_shells;
 713         start_ammo_nails   = warmup_start_ammo_nails   = autocvar_g_ft_start_ammo_nails;
 714         start_ammo_rockets = warmup_start_ammo_rockets = autocvar_g_ft_start_ammo_rockets;
 715         start_ammo_cells   = warmup_start_ammo_cells   = autocvar_g_ft_start_ammo_cells;
 716         start_ammo_plasma  = warmup_start_ammo_plasma  = autocvar_g_ft_start_ammo_plasma;
 717         start_ammo_fuel    = warmup_start_ammo_fuel    = autocvar_g_ft_start_ammo_fuel;
 718 }
 719
 720 MUTATOR_HOOKFUNCTION(ft, HavocBot_ChooseRole)
 721 {
 722         entity bot = M_ARGV(0, entity);
 723
 724         if (!IS_DEAD(bot))
 725         {
 726                 if (random() < 0.5)
 727                         bot.havocbot_role = havocbot_role_ft_freeing;
 728                 else
 729                         bot.havocbot_role = havocbot_role_ft_offense;
 730         }
 731
 732         // if bots spawn all at once assign them a more appropriated role after a while
 733         if (time < CS(bot).jointime + 1)
 734                 bot.havocbot_role_timeout = time + 10 + random() * 10;
 735
 736         return true;
 737 }
 738
 739 MUTATOR_HOOKFUNCTION(ft, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 740 {
 741         M_ARGV(0, float) = freezetag_teams;
 742         return true;
 743 }
 744
 745 MUTATOR_HOOKFUNCTION(ft, SetWeaponArena)
 746 {
 747         if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
 748                 M_ARGV(0, string) = autocvar_g_freezetag_weaponarena;
 749 }
 750
 751 MUTATOR_HOOKFUNCTION(ft, FragCenterMessage)
 752 {
 753         entity frag_attacker = M_ARGV(0, entity);
 754         entity frag_target = M_ARGV(1, entity);
 755         //float frag_deathtype = M_ARGV(2, float);
 756         int kill_count_to_attacker = M_ARGV(3, int);
 757         int kill_count_to_target = M_ARGV(4, int);
 758
 759         if(STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 760                 return; // target was already frozen, so this is just pushing them off the cliff
 761
 762         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CHOICE, CHOICE_FRAG_FREEZE, frag_target.netname, kill_count_to_attacker, (IS_BOT_CLIENT(frag_target) ? -1 : CS(frag_target).ping));
 763         Send_Notification(NOTIF_ONE, frag_target, MSG_CHOICE, CHOICE_FRAGGED_FREEZE, frag_attacker.netname, kill_count_to_target,
 764                 GetResource(frag_attacker, RES_HEALTH), GetResource(frag_attacker, RES_ARMOR), (IS_BOT_CLIENT(frag_attacker) ? -1 : CS(frag_attacker).ping));
 765
 766         return true;
 767 }
 768
 769 MUTATOR_HOOKFUNCTION(ft, SV_ParseServerCommand)
 770 {
 771         string cmd_name = M_ARGV(0, string);
 772         if (cmd_name == "shuffleteams")
 773                 shuffleteams_on_reset_map = !(round_handler_IsActive() && !round_handler_IsRoundStarted());
 774         return false;
 775 }
 776
 777 MUTATOR_HOOKFUNCTION(ft, Scores_CountFragsRemaining)
 778 {
 779         // announce remaining frags
 780         return true;
 781 }
 782
 783 void freezetag_Initialize()
 784 {
 785         freezetag_teams = autocvar_g_freezetag_teams_override;
 786         if(freezetag_teams < 2)
 787                 freezetag_teams = cvar("g_freezetag_teams"); // read the cvar directly as it gets written earlier in the same frame
 788
 789         freezetag_teams = BITS(bound(2, freezetag_teams, 4));
 790         GameRules_scoring(freezetag_teams, SFL_SORT_PRIO_PRIMARY, 0, {
 791                 field_team(ST_FT_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
 792                 field(SP_FREEZETAG_REVIVALS, "revivals", 0);
 793         });
 794
 795         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 796         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 797
 798         EliminatedPlayers_Init(freezetag_isEliminated);
 799 }