qcsrc/common/gamemodes/gamemode/cts/sv_cts.qc

   1 #include "sv_cts.qh"
   2
   3 #include <server/race.qh>
   4 #include <server/g_world.qh>
   5 #include <server/gamelog.qh>
   6 #include <server/items/spawning.qh>
   7
   8 float autocvar_g_cts_finish_kill_delay;
   9 bool autocvar_g_cts_selfdamage;
  10 bool autocvar_g_cts_removeprojectiles;
  11
  12 // legacy bot roles
  13 .float race_checkpoint;
  14 void havocbot_role_cts(entity this)
  15 {
  16         if(IS_DEAD(this))
  17                 return;
  18
  19         if (navigation_goalrating_timeout(this))
  20         {
  21                 navigation_goalrating_start(this);
  22
  23                 bool raw_touch_check = true;
  24                 int cp = this.race_checkpoint;
  25
  26                 LABEL(search_racecheckpoints)
  27                 IL_EACH(g_racecheckpoints, true,
  28                 {
  29                         if(it.cnt == cp || cp == -1)
  30                         {
  31                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
  32                                 // e.g. checkpoint in front of Stormkeep's warpzone
  33                                 // the same workaround is applied in Race game mode
  34                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
  35                                 {
  36                                         cp = race_NextCheckpoint(cp);
  37                                         raw_touch_check = false;
  38                                         goto search_racecheckpoints;
  39                                 }
  40                                 navigation_routerating(this, it, 1000000, 5000);
  41                         }
  42                 });
  43
  44                 navigation_goalrating_end(this);
  45
  46                 navigation_goalrating_timeout_set(this);
  47         }
  48 }
  49
  50 void cts_ScoreRules()
  51 {
  52     GameRules_score_enabled(false);
  53     GameRules_scoring(0, 0, 0, {
  54         if (g_race_qualifying) {
  55             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  56         } else {
  57             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  58             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  59             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  60         }
  61     });
  62 }
  63
  64 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  65 {
  66         if(autocvar_sv_eventlog)
  67                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  68 }
  69
  70 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
  71 {
  72         entity player = M_ARGV(0, entity);
  73         float dt = M_ARGV(1, float);
  74
  75         player.race_movetime_frac += dt;
  76         float f = floor(player.race_movetime_frac);
  77         player.race_movetime_frac -= f;
  78         player.race_movetime_count += f;
  79         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
  80
  81         if(IS_PLAYER(player))
  82         {
  83                 if (player.race_penalty)
  84                         if (time > player.race_penalty)
  85                                 player.race_penalty = 0;
  86                 if(player.race_penalty)
  87                 {
  88                         player.velocity = '0 0 0';
  89                         set_movetype(player, MOVETYPE_NONE);
  90                         player.disableclientprediction = 2;
  91                 }
  92         }
  93
  94         // force kbd movement for fairness
  95         float wishspeed;
  96         vector wishvel;
  97
  98         // if record times matter
  99         // ensure nothing EVIL is being done (i.e. div0_evade)
 100         // this hinders joystick users though
 101         // but it still gives SOME analog control
 102         wishvel.x = fabs(CS(player).movement.x);
 103         wishvel.y = fabs(CS(player).movement.y);
 104         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 105         {
 106                 wishvel.z = 0;
 107                 wishspeed = vlen(wishvel);
 108                 if(wishvel.x >= 2 * wishvel.y)
 109                 {
 110                         // pure X motion
 111                         if(CS(player).movement.x > 0)
 112                                 CS(player).movement_x = wishspeed;
 113                         else
 114                                 CS(player).movement_x = -wishspeed;
 115                         CS(player).movement_y = 0;
 116                 }
 117                 else if(wishvel.y >= 2 * wishvel.x)
 118                 {
 119                         // pure Y motion
 120                         CS(player).movement_x = 0;
 121                         if(CS(player).movement.y > 0)
 122                                 CS(player).movement_y = wishspeed;
 123                         else
 124                                 CS(player).movement_y = -wishspeed;
 125                 }
 126                 else
 127                 {
 128                         // diagonal
 129                         if(CS(player).movement.x > 0)
 130                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 131                         else
 132                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 133                         if(CS(player).movement.y > 0)
 134                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 135                         else
 136                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 137                 }
 138         }
 139 }
 140
 141 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
 142 {
 143         float s;
 144
 145         Score_NicePrint(NULL);
 146
 147         race_ClearRecords();
 148         PlayerScore_Sort(race_place, 0, 1, 0);
 149
 150         FOREACH_CLIENT(true, {
 151                 if(it.race_place)
 152                 {
 153                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 154                         if(!s)
 155                                 it.race_place = 0;
 156                 }
 157                 cts_EventLog(ftos(it.race_place), it);
 158         });
 159
 160         if(g_race_qualifying == 2)
 161         {
 162                 g_race_qualifying = 0;
 163                 independent_players = 0;
 164                 cvar_set("fraglimit", ftos(race_fraglimit));
 165                 cvar_set("leadlimit", ftos(race_leadlimit));
 166                 cvar_set("timelimit", ftos(race_timelimit));
 167                 cts_ScoreRules();
 168         }
 169 }
 170
 171 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
 172 {
 173         entity player = M_ARGV(0, entity);
 174
 175         race_PreparePlayer(player);
 176         player.race_checkpoint = -1;
 177
 178         if(IS_REAL_CLIENT(player))
 179         {
 180                 string rr = CTS_RECORD;
 181
 182                 msg_entity = player;
 183                 race_send_recordtime(MSG_ONE);
 184                 race_send_speedaward(MSG_ONE);
 185
 186                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 187                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 188                 race_send_speedaward_alltimebest(MSG_ONE);
 189
 190                 float i;
 191                 int m = min(RANKINGS_CNT, autocvar_g_cts_send_rankings_cnt);
 192                 race_send_rankings_cnt(MSG_ONE);
 193                 for (i = 1; i <= m; ++i)
 194                 {
 195                         race_SendRankings(i, 0, 0, MSG_ONE);
 196                 }
 197         }
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(cts, AbortSpeedrun)
 201 {
 202         entity player = M_ARGV(0, entity);
 203
 204         if(autocvar_g_allow_checkpoints)
 205                 race_PreparePlayer(player); // nice try
 206 }
 207
 208 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
 209 {
 210         entity player = M_ARGV(0, entity);
 211
 212         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 213                 player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 214         else
 215                 player.frags = FRAGS_SPECTATOR;
 216
 217         race_PreparePlayer(player);
 218         player.race_checkpoint = -1;
 219 }
 220
 221 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
 222 {
 223         entity player = M_ARGV(0, entity);
 224         entity spawn_spot = M_ARGV(1, entity);
 225
 226         if(spawn_spot.target == "")
 227                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 228                 race_PreparePlayer(player);
 229
 230         // if we need to respawn, do it right
 231         player.race_respawn_checkpoint = player.race_checkpoint;
 232         player.race_respawn_spotref = spawn_spot;
 233
 234         player.race_place = 0;
 235 }
 236
 237 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
 238 {
 239         entity player = M_ARGV(0, entity);
 240
 241         if(IS_PLAYER(player))
 242         if(!game_stopped)
 243         {
 244                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 245                         race_PreparePlayer(player);
 246                 else // respawn
 247                         race_RetractPlayer(player);
 248
 249                 race_AbandonRaceCheck(player);
 250         }
 251 }
 252
 253 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
 254 {
 255         entity frag_target = M_ARGV(2, entity);
 256
 257         frag_target.respawn_flags |= RESPAWN_FORCE;
 258         race_AbandonRaceCheck(frag_target);
 259
 260         if(autocvar_g_cts_removeprojectiles)
 261         {
 262                 IL_EACH(g_projectiles, it.owner == frag_target && (it.flags & FL_PROJECTILE),
 263                 {
 264                         delete(it);
 265                 });
 266         }
 267 }
 268
 269 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
 270 {
 271         entity bot = M_ARGV(0, entity);
 272
 273         bot.havocbot_role = havocbot_role_cts;
 274         return true;
 275 }
 276
 277 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
 278 {
 279         entity player = M_ARGV(0, entity);
 280
 281         if(CS(player).cvar_cl_allow_uidtracking == 1 && CS(player).cvar_cl_allow_uid2name == 1)
 282         {
 283                 if (!player.stored_netname)
 284                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 285                 if(player.stored_netname != player.netname)
 286                 {
 287                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 288                         strcpy(player.stored_netname, player.netname);
 289                 }
 290         }
 291
 292         if (!IS_OBSERVER(player))
 293         {
 294                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 295                 {
 296                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 297                         speedaward_holder = player.netname;
 298                         speedaward_uid = player.crypto_idfp;
 299                         speedaward_lastupdate = time;
 300                 }
 301                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 302                 {
 303                         string rr = CTS_RECORD;
 304                         race_send_speedaward(MSG_ALL);
 305                         speedaward_lastsent = speedaward_speed;
 306                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 307                         {
 308                                 speedaward_alltimebest = speedaward_speed;
 309                                 speedaward_alltimebest_holder = speedaward_holder;
 310                                 speedaward_alltimebest_uid = speedaward_uid;
 311                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 312                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 313                                 race_send_speedaward_alltimebest(MSG_ALL);
 314                         }
 315                 }
 316         }
 317 }
 318
 319 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
 320 {
 321         // no weapon dropping in CTS
 322         return true;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(cts, FilterItem)
 326 {
 327         entity item = M_ARGV(0, entity);
 328
 329         if (Item_IsLoot(item))
 330         {
 331                 return true;
 332         }
 333 }
 334
 335 MUTATOR_HOOKFUNCTION(cts, Damage_Calculate)
 336 {
 337         entity frag_attacker = M_ARGV(1, entity);
 338         entity frag_target = M_ARGV(2, entity);
 339         float frag_deathtype = M_ARGV(3, float);
 340         float frag_damage = M_ARGV(4, float);
 341
 342         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
 343         if(!autocvar_g_cts_selfdamage)
 344         {
 345                 frag_damage = 0;
 346                 M_ARGV(4, float) = frag_damage;
 347         }
 348 }
 349
 350 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
 351 {
 352         return true; // in CTS, you don't lose score by observing
 353 }
 354
 355 MUTATOR_HOOKFUNCTION(cts, GetRecords)
 356 {
 357         int record_page = M_ARGV(0, int);
 358         string ret_string = M_ARGV(1, string);
 359
 360         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 361         {
 362                 if(MapInfo_Get_ByID(i))
 363                 {
 364                         float r = race_readTime(MapInfo_Map_bspname, 1);
 365
 366                         if(!r)
 367                                 continue;
 368
 369                         string h = race_readName(MapInfo_Map_bspname, 1);
 370                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 371                 }
 372         }
 373
 374         M_ARGV(1, string) = ret_string;
 375 }
 376
 377 MUTATOR_HOOKFUNCTION(cts, ClientKill)
 378 {
 379         M_ARGV(1, float) = 0; // kill delay
 380 }
 381
 382 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
 383 {
 384         entity player = M_ARGV(0, entity);
 385
 386         // useful to prevent cheating by running back to the start line and starting out with more speed
 387         if(autocvar_g_cts_finish_kill_delay)
 388                 ClientKill_Silent(player, autocvar_g_cts_finish_kill_delay);
 389 }
 390
 391 MUTATOR_HOOKFUNCTION(cts, HideTeamNagger)
 392 {
 393         return true; // doesn't work so well (but isn't cts a teamless mode?)
 394 }
 395
 396 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
 397 {
 398         entity player = M_ARGV(0, entity);
 399
 400         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 401 }
 402
 403 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
 404 {
 405         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
 406         M_ARGV(3, bool) = true; // want mutator blocked
 407         return true;
 408 }
 409
 410 MUTATOR_HOOKFUNCTION(cts, ForbidDropCurrentWeapon)
 411 {
 412         return true;
 413 }
 414
 415 void cts_Initialize()
 416 {
 417         cts_ScoreRules();
 418 }