qcsrc/common/gamemodes/gamemode/cts/sv_cts.qc

   1 #include "sv_cts.qh"
   2
   3 #include <server/client.qh>
   4 #include <server/race.qh>
   5 #include <server/world.qh>
   6 #include <server/gamelog.qh>
   7 #include <server/intermission.qh>
   8 #include <server/items/spawning.qh>
   9 #include <server/weapons/common.qh>
  10 #include <common/mapobjects/triggers.qh>
  11
  12 float autocvar_g_cts_finish_kill_delay;
  13 bool autocvar_g_cts_selfdamage;
  14 bool autocvar_g_cts_removeprojectiles;
  15
  16 // legacy bot roles
  17 .float race_checkpoint;
  18 .float race_oldcheckpoint;
  19 .bool startspeed_recorded;
  20 .float startspeed;
  21 void havocbot_role_cts(entity this)
  22 {
  23         if(IS_DEAD(this))
  24                 return;
  25
  26         if (navigation_goalrating_timeout(this))
  27         {
  28                 navigation_goalrating_start(this);
  29
  30                 bool raw_touch_check = true;
  31                 int cp = this.race_checkpoint;
  32
  33                 LABEL(search_racecheckpoints)
  34                 IL_EACH(g_racecheckpoints, true,
  35                 {
  36                         if(it.cnt == cp || cp == -1)
  37                         {
  38                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
  39                                 // e.g. checkpoint in front of Stormkeep's warpzone
  40                                 // the same workaround is applied in Race game mode
  41                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
  42                                 {
  43                                         cp = race_NextCheckpoint(cp);
  44                                         raw_touch_check = false;
  45                                         goto search_racecheckpoints;
  46                                 }
  47                                 navigation_routerating(this, it, 1000000, 5000);
  48                         }
  49                 });
  50
  51                 navigation_goalrating_end(this);
  52
  53                 navigation_goalrating_timeout_set(this);
  54         }
  55 }
  56
  57 void cts_ScoreRules()
  58 {
  59     GameRules_score_enabled(false);
  60     GameRules_scoring(0, 0, 0, {
  61         if (g_race_qualifying) {
  62             field(SP_CTS_STRAFE, "strafe", 0);
  63             field(SP_CTS_STARTSPEED, "startspeed", 0);
  64             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  65         } else {
  66             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  67             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  68             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  69         }
  70     });
  71 }
  72
  73 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  74 {
  75         if(autocvar_sv_eventlog)
  76                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  77 }
  78
  79 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
  80 {
  81         entity player = M_ARGV(0, entity);
  82         float dt = M_ARGV(1, float);
  83
  84         player.race_movetime_frac += dt;
  85         float f = floor(player.race_movetime_frac);
  86         player.race_movetime_frac -= f;
  87         player.race_movetime_count += f;
  88         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
  89
  90         if(IS_PLAYER(player))
  91         {
  92                 if (player.race_penalty)
  93                         if (time > player.race_penalty)
  94                                 player.race_penalty = 0;
  95                 if(player.race_penalty)
  96                 {
  97                         player.velocity = '0 0 0';
  98                         set_movetype(player, MOVETYPE_NONE);
  99                         player.disableclientprediction = 2;
 100                 }
 101         }
 102
 103         // force kbd movement for fairness
 104         float wishspeed;
 105         vector wishvel;
 106
 107         // if record times matter
 108         // ensure nothing EVIL is being done (i.e. div0_evade)
 109         // this hinders joystick users though
 110         // but it still gives SOME analog control
 111         wishvel.x = fabs(CS(player).movement.x);
 112         wishvel.y = fabs(CS(player).movement.y);
 113         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 114         {
 115                 wishvel.z = 0;
 116                 wishspeed = vlen(wishvel);
 117                 if(wishvel.x >= 2 * wishvel.y)
 118                 {
 119                         // pure X motion
 120                         if(CS(player).movement.x > 0)
 121                                 CS(player).movement_x = wishspeed;
 122                         else
 123                                 CS(player).movement_x = -wishspeed;
 124                         CS(player).movement_y = 0;
 125                 }
 126                 else if(wishvel.y >= 2 * wishvel.x)
 127                 {
 128                         // pure Y motion
 129                         CS(player).movement_x = 0;
 130                         if(CS(player).movement.y > 0)
 131                                 CS(player).movement_y = wishspeed;
 132                         else
 133                                 CS(player).movement_y = -wishspeed;
 134                 }
 135                 else
 136                 {
 137                         // diagonal
 138                         if(CS(player).movement.x > 0)
 139                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 140                         else
 141                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 142                         if(CS(player).movement.y > 0)
 143                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 144                         else
 145                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 146                 }
 147         }
 148         player.strafe_efficiency_sum += calculate_strafe_efficiency(player, CS(player).movement);
 149         if(!player.race_started) player.startspeed_recorded = false;
 150         if(player.race_started && !player.startspeed_recorded && player.race_checkpoint != 0 && player.race_oldcheckpoint == 0)
 151         {
 152                 float new_startspeed = vlen(vec2(player.velocity));
 153                 player.startspeed_recorded = true;
 154                 if(new_startspeed > player.startspeed)
 155                 {
 156                         player.startspeed = new_startspeed;
 157                         PlayerScore_Set(player, SP_CTS_STARTSPEED, player.startspeed * 100);
 158                 }
 159         }
 160         player.race_oldcheckpoint = player.race_checkpoint;
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
 164 {
 165         float s;
 166
 167         Score_NicePrint(NULL);
 168
 169         race_ClearRecords();
 170         PlayerScore_Sort(race_place, 0, true, false);
 171
 172         FOREACH_CLIENT(true, {
 173                 it.strafe_efficiency_best = -2;
 174                 PlayerScore_Set(it, SP_CTS_STRAFE, -20000);
 175                 it.startspeed_recorded = false;
 176                 it.race_oldcheckpoint = 0;
 177                 PlayerScore_Set(it, SP_CTS_STARTSPEED, -1);
 178
 179                 if(it.race_place)
 180                 {
 181                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 182                         if(!s)
 183                                 it.race_place = 0;
 184                 }
 185                 cts_EventLog(ftos(it.race_place), it);
 186         });
 187
 188         if(g_race_qualifying == 2)
 189         {
 190                 g_race_qualifying = 0;
 191                 independent_players = 0;
 192                 cvar_set("fraglimit", ftos(race_fraglimit));
 193                 cvar_set("leadlimit", ftos(race_leadlimit));
 194                 cvar_set("timelimit", ftos(race_timelimit));
 195                 cts_ScoreRules();
 196         }
 197 }
 198
 199 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
 200 {
 201         entity player = M_ARGV(0, entity);
 202
 203         race_PreparePlayer(player);
 204         player.race_checkpoint = -1;
 205         player.strafe_efficiency_sum = player.strafe_efficiency_tics = 0;
 206         player.strafe_efficiency_best = -2;
 207         PlayerScore_Set(player, SP_CTS_STRAFE, -20000);
 208         player.startspeed_recorded = false;
 209         player.race_oldcheckpoint = 0;
 210         PlayerScore_Set(player, SP_CTS_STARTSPEED, -1);
 211
 212         race_SendAll(player, false);
 213 }
 214
 215 MUTATOR_HOOKFUNCTION(cts, AbortSpeedrun)
 216 {
 217         entity player = M_ARGV(0, entity);
 218
 219         if(autocvar_g_allow_checkpoints)
 220                 race_PreparePlayer(player); // nice try
 221 }
 222
 223 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
 224 {
 225         entity player = M_ARGV(0, entity);
 226
 227         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 228                 player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 229         else
 230                 player.frags = FRAGS_SPECTATOR;
 231
 232         race_PreparePlayer(player);
 233         player.race_checkpoint = -1;
 234 }
 235
 236 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
 237 {
 238         entity player = M_ARGV(0, entity);
 239         entity spawn_spot = M_ARGV(1, entity);
 240
 241         if(spawn_spot.target == "")
 242                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 243                 race_PreparePlayer(player);
 244
 245         // if we need to respawn, do it right
 246         player.race_respawn_checkpoint = player.race_checkpoint;
 247         player.race_respawn_spotref = spawn_spot;
 248
 249         player.race_place = 0;
 250 }
 251
 252 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
 253 {
 254         entity player = M_ARGV(0, entity);
 255
 256         if(IS_PLAYER(player))
 257         if(!game_stopped)
 258         {
 259                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 260                         race_PreparePlayer(player);
 261                 else // respawn
 262                         race_RetractPlayer(player);
 263
 264                 race_AbandonRaceCheck(player);
 265         }
 266 }
 267
 268 MUTATOR_HOOKFUNCTION(cts, PlayerDamaged)
 269 {
 270         int frag_deathtype = M_ARGV(5, int);
 271         if (frag_deathtype == DEATH_KILL.m_id)
 272                 return true; // forbid logging damage
 273 }
 274
 275 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
 276 {
 277         entity frag_target = M_ARGV(2, entity);
 278
 279         frag_target.respawn_flags |= RESPAWN_FORCE;
 280         race_AbandonRaceCheck(frag_target);
 281
 282         frag_target.strafe_efficiency_sum = frag_target.strafe_efficiency_tics = 0;
 283         frag_target.startspeed_recorded = false;
 284
 285         if(autocvar_g_cts_removeprojectiles)
 286         {
 287                 IL_EACH(g_projectiles, it.owner == frag_target && (it.flags & FL_PROJECTILE),
 288                 {
 289                         delete(it);
 290                 });
 291         }
 292 }
 293
 294 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
 295 {
 296         entity bot = M_ARGV(0, entity);
 297
 298         bot.havocbot_role = havocbot_role_cts;
 299         return true;
 300 }
 301
 302 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
 303 {
 304         entity player = M_ARGV(0, entity);
 305
 306         race_checkAndWriteName(player);
 307         race_SpeedAwardFrame(player);
 308 }
 309
 310 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
 311 {
 312         // no weapon dropping in CTS
 313         return true;
 314 }
 315
 316 MUTATOR_HOOKFUNCTION(cts, FilterItem)
 317 {
 318         entity item = M_ARGV(0, entity);
 319
 320         if (Item_IsLoot(item))
 321         {
 322                 return true;
 323         }
 324 }
 325
 326 MUTATOR_HOOKFUNCTION(cts, Damage_Calculate)
 327 {
 328         entity frag_attacker = M_ARGV(1, entity);
 329         entity frag_target = M_ARGV(2, entity);
 330         float frag_deathtype = M_ARGV(3, float);
 331         float frag_damage = M_ARGV(4, float);
 332
 333         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
 334         if(!autocvar_g_cts_selfdamage)
 335         {
 336                 frag_damage = 0;
 337                 M_ARGV(4, float) = frag_damage;
 338         }
 339 }
 340
 341 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
 342 {
 343         return true; // in CTS, you don't lose score by observing
 344 }
 345
 346 MUTATOR_HOOKFUNCTION(cts, GetRecords)
 347 {
 348         int record_page = M_ARGV(0, int);
 349         string ret_string = M_ARGV(1, string);
 350
 351         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 352         {
 353                 if(MapInfo_Get_ByID(i))
 354                 {
 355                         float r = race_readTime(MapInfo_Map_bspname, 1);
 356
 357                         if(!r)
 358                                 continue;
 359
 360                         string h = race_readName(MapInfo_Map_bspname, 1);
 361                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 362                 }
 363         }
 364
 365         M_ARGV(1, string) = ret_string;
 366 }
 367
 368 MUTATOR_HOOKFUNCTION(cts, ClientKill)
 369 {
 370         M_ARGV(1, float) = 0; // kill delay
 371 }
 372
 373 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
 374 {
 375         entity player = M_ARGV(0, entity);
 376         float strafe_efficiency_average = player.strafe_efficiency_sum / player.strafe_efficiency_tics;
 377
 378         if(player.strafe_efficiency_best < strafe_efficiency_average)
 379         {
 380                 player.strafe_efficiency_best = strafe_efficiency_average;
 381                 PlayerScore_Set(player, SP_CTS_STRAFE, player.strafe_efficiency_best * 10000);
 382         }
 383
 384         // useful to prevent cheating by running back to the start line and starting out with more speed
 385         if(autocvar_g_cts_finish_kill_delay)
 386                 ClientKill_Silent(player, autocvar_g_cts_finish_kill_delay);
 387 }
 388
 389 MUTATOR_HOOKFUNCTION(cts, HideTeamNagger)
 390 {
 391         return true; // doesn't work so well (but isn't cts a teamless mode?)
 392 }
 393
 394 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
 395 {
 396         entity player = M_ARGV(0, entity);
 397
 398         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 399 }
 400
 401 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
 402 {
 403         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
 404         M_ARGV(3, bool) = true; // want mutator blocked
 405         return true;
 406 }
 407
 408 MUTATOR_HOOKFUNCTION(cts, ForbidDropCurrentWeapon)
 409 {
 410         return true;
 411 }
 412
 413 void cts_Initialize()
 414 {
 415         record_type = CTS_RECORD;
 416         cts_ScoreRules();
 417 }