qcsrc/common/gamemodes/gamemode/clanarena/sv_clanarena.qc

   1 #include "sv_clanarena.qh"
   2
   3 float autocvar_g_ca_damage2score = 100;
   4 bool autocvar_g_ca_spectate_enemies;
   5
   6 float autocvar_g_ca_start_health = 200;
   7 float autocvar_g_ca_start_armor = 200;
   8 float autocvar_g_ca_start_ammo_shells = 60;
   9 float autocvar_g_ca_start_ammo_nails = 320;
  10 float autocvar_g_ca_start_ammo_rockets = 160;
  11 float autocvar_g_ca_start_ammo_cells = 180;
  12 float autocvar_g_ca_start_ammo_plasma = 180;
  13 float autocvar_g_ca_start_ammo_fuel = 0;
  14
  15 .float ca_damage_counter;
  16
  17 void CA_count_alive_players()
  18 {
  19         total_players = 0;
  20         for (int i = 1; i <= NUM_TEAMS; ++i)
  21         {
  22                 Team_SetNumberOfAlivePlayers(Team_GetTeamFromIndex(i), 0);
  23         }
  24         FOREACH_CLIENT(IS_PLAYER(it) && Entity_HasValidTeam(it),
  25         {
  26                 ++total_players;
  27                 if (IS_DEAD(it))
  28                 {
  29                         continue;
  30                 }
  31                 entity team_ = Entity_GetTeam(it);
  32                 int num_alive = Team_GetNumberOfAlivePlayers(team_);
  33                 ++num_alive;
  34                 Team_SetNumberOfAlivePlayers(team_, num_alive);
  35         });
  36         FOREACH_CLIENT(IS_REAL_CLIENT(it),
  37         {
  38                 STAT(REDALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(1));
  39                 STAT(BLUEALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(2));
  40                 STAT(YELLOWALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(3));
  41                 STAT(PINKALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(4));
  42         });
  43 }
  44
  45 void nades_Clear(entity player);
  46
  47 float CA_CheckWinner()
  48 {
  49         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  50         {
  51                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
  52                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
  53                 FOREACH_CLIENT(IS_PLAYER(it), { nades_Clear(it); });
  54
  55                 allowed_to_spawn = false;
  56                 game_stopped = true;
  57                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  58                 return 1;
  59         }
  60
  61         CA_count_alive_players();
  62         int winner_team = Team_GetWinnerAliveTeam();
  63         if (!winner_team)
  64                 return 0;
  65
  66         if(winner_team > 0)
  67         {
  68                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
  69                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
  70                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
  71         }
  72         else if(winner_team == -1)
  73         {
  74                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
  75                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
  76         }
  77
  78         allowed_to_spawn = false;
  79         game_stopped = true;
  80         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  81
  82         FOREACH_CLIENT(IS_PLAYER(it), { nades_Clear(it); });
  83
  84         return 1;
  85 }
  86
  87 void CA_RoundStart()
  88 {
  89         allowed_to_spawn = boolean(warmup_stage);
  90 }
  91
  92 bool CA_CheckTeams()
  93 {
  94         static int prev_missing_teams_mask;
  95         allowed_to_spawn = true;
  96         CA_count_alive_players();
  97         if (Team_GetNumberOfAliveTeams() == NumTeams(ca_teams))
  98         {
  99                 if(prev_missing_teams_mask > 0)
 100                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 101                 prev_missing_teams_mask = -1;
 102                 return true;
 103         }
 104         if(total_players == 0)
 105         {
 106                 if(prev_missing_teams_mask > 0)
 107                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 108                 prev_missing_teams_mask = -1;
 109                 return false;
 110         }
 111         int missing_teams_mask = 0;
 112         for (int i = 1; i <= NUM_TEAMS; ++i)
 113         {
 114                 if ((ca_teams & Team_IndexToBit(i)) &&
 115                         (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) == 0))
 116                 {
 117                         missing_teams_mask |= Team_IndexToBit(i);
 118                 }
 119         }
 120         if(prev_missing_teams_mask != missing_teams_mask)
 121         {
 122                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 123                 prev_missing_teams_mask = missing_teams_mask;
 124         }
 125         return false;
 126 }
 127
 128 bool ca_isEliminated(entity e)
 129 {
 130         if(INGAME_JOINED(e) && (IS_DEAD(e) || e.frags == FRAGS_PLAYER_OUT_OF_GAME))
 131                 return true;
 132         if(INGAME_JOINING(e))
 133                 return true;
 134         return false;
 135 }
 136
 137 /** Returns next available player to spectate if g_ca_spectate_enemies == 0 */
 138 entity CA_SpectateNext(entity player, entity start)
 139 {
 140         if (SAME_TEAM(start, player)) return start;
 141         // continue from current player
 142         for (entity e = start; (e = find(e, classname, STR_PLAYER)); )
 143         {
 144                 if (SAME_TEAM(player, e)) return e;
 145         }
 146         // restart from the beginning
 147         for (entity e = NULL; (e = find(e, classname, STR_PLAYER)); )
 148         {
 149                 if (SAME_TEAM(player, e)) return e;
 150         }
 151         return start;
 152 }
 153
 154
 155 MUTATOR_HOOKFUNCTION(ca, PlayerSpawn)
 156 {
 157         entity player = M_ARGV(0, entity);
 158
 159         INGAME_STATUS_SET(player, INGAME_STATUS_JOINED);
 160         if (time <= game_starttime) // reset on game restart, not on round start
 161                 player.ca_damage_counter = autocvar_g_ca_damage2score / 2; // for rounding purposes
 162         if (!warmup_stage)
 163                 eliminatedPlayers.SendFlags |= 1;
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(ca, ForbidSpawn)
 167 {
 168         entity player = M_ARGV(0, entity);
 169
 170         // spectators / observers that weren't playing can join; they are
 171         // immediately forced to observe in the PutClientInServer hook
 172         // this way they are put in a team and can play in the next round
 173         if (!allowed_to_spawn && INGAME(player))
 174                 return true;
 175         return false;
 176 }
 177
 178 MUTATOR_HOOKFUNCTION(ca, PutClientInServer)
 179 {
 180         entity player = M_ARGV(0, entity);
 181
 182         if (!allowed_to_spawn && IS_PLAYER(player)) // this is true even when player is trying to join
 183         {
 184                 TRANSMUTE(Observer, player);
 185                 if (CS(player).jointime != time && !INGAME(player)) // not when connecting
 186                 {
 187                         INGAME_STATUS_SET(player, INGAME_STATUS_JOINING);
 188                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_JOIN_LATE);
 189                 }
 190         }
 191 }
 192
 193 MUTATOR_HOOKFUNCTION(ca, reset_map_players)
 194 {
 195         FOREACH_CLIENT(true, {
 196                 CS(it).killcount = 0;
 197                 if (!INGAME(it) && IS_BOT_CLIENT(it))
 198                 {
 199                         it.team = -1;
 200                         INGAME_STATUS_SET(it, INGAME_STATUS_JOINED);
 201                 }
 202                 if (INGAME(it))
 203                 {
 204                         TRANSMUTE(Player, it);
 205                         INGAME_STATUS_SET(it, INGAME_STATUS_JOINED);
 206                         PutClientInServer(it);
 207                 }
 208         });
 209         return true;
 210 }
 211
 212 MUTATOR_HOOKFUNCTION(ca, reset_map_global)
 213 {
 214         allowed_to_spawn = true;
 215         return true;
 216 }
 217
 218 MUTATOR_HOOKFUNCTION(ca, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 219 {
 220         M_ARGV(0, float) = ca_teams;
 221         return true;
 222 }
 223
 224 entity ca_LastPlayerForTeam(entity this)
 225 {
 226         entity last_pl = NULL;
 227         FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 228                 if (!IS_DEAD(it) && SAME_TEAM(this, it))
 229                 {
 230                         if (!last_pl)
 231                                 last_pl = it;
 232                         else
 233                                 return NULL;
 234                 }
 235         });
 236         return last_pl;
 237 }
 238
 239 void ca_LastPlayerForTeam_Notify(entity this)
 240 {
 241         if (!warmup_stage && round_handler_IsActive() && round_handler_IsRoundStarted())
 242         {
 243                 entity pl = ca_LastPlayerForTeam(this);
 244                 if (pl)
 245                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 246         }
 247 }
 248
 249 MUTATOR_HOOKFUNCTION(ca, PlayerDies)
 250 {
 251         entity frag_target = M_ARGV(2, entity);
 252
 253         ca_LastPlayerForTeam_Notify(frag_target);
 254         if (!allowed_to_spawn)
 255         {
 256                 frag_target.respawn_flags = RESPAWN_SILENT;
 257                 // prevent unwanted sudden rejoin as spectator and movement of spectator camera
 258                 frag_target.respawn_time = time + 2;
 259         }
 260         frag_target.respawn_flags |= RESPAWN_FORCE;
 261         if (!warmup_stage)
 262                 eliminatedPlayers.SendFlags |= 1;
 263         return true;
 264 }
 265
 266 MUTATOR_HOOKFUNCTION(ca, ClientConnect)
 267 {
 268         entity player = M_ARGV(0, entity);
 269         player.ca_damage_counter = autocvar_g_ca_damage2score / 2; // for rounding purposes
 270 }
 271
 272 MUTATOR_HOOKFUNCTION(ca, ClientDisconnect)
 273 {
 274         entity player = M_ARGV(0, entity);
 275
 276         if (IS_PLAYER(player) && !IS_DEAD(player))
 277                 ca_LastPlayerForTeam_Notify(player);
 278         return true;
 279 }
 280
 281 MUTATOR_HOOKFUNCTION(ca, MakePlayerObserver)
 282 {
 283         entity player = M_ARGV(0, entity);
 284
 285         bool is_forced = M_ARGV(1, bool);
 286         if (is_forced && INGAME(player))
 287                 INGAME_STATUS_CLEAR(player);
 288
 289         if (IS_PLAYER(player) && !IS_DEAD(player))
 290                 ca_LastPlayerForTeam_Notify(player);
 291         if (player.killindicator_teamchange == -2) // player wants to spectate
 292         {
 293                 entcs_update_players(player);
 294                 INGAME_STATUS_CLEAR(player);
 295         }
 296         if (INGAME(player))
 297                 player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 298         if (!warmup_stage)
 299                 eliminatedPlayers.SendFlags |= 1;
 300         if (!INGAME(player))
 301                 return false;  // allow team reset
 302         return true;  // prevent team reset
 303 }
 304
 305 MUTATOR_HOOKFUNCTION(ca, ForbidThrowCurrentWeapon)
 306 {
 307         return true;
 308 }
 309
 310 MUTATOR_HOOKFUNCTION(ca, GiveFragsForKill, CBC_ORDER_FIRST)
 311 {
 312         M_ARGV(2, float) = 0; // score will be given to the winner team when the round ends
 313         return true;
 314 }
 315
 316 MUTATOR_HOOKFUNCTION(ca, SetStartItems)
 317 {
 318         start_items       &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
 319         if(!cvar("g_use_ammunition"))
 320                 start_items |= IT_UNLIMITED_AMMO;
 321
 322         start_health       = warmup_start_health       = autocvar_g_ca_start_health;
 323         start_armorvalue   = warmup_start_armorvalue   = autocvar_g_ca_start_armor;
 324         start_ammo_shells  = warmup_start_ammo_shells  = autocvar_g_ca_start_ammo_shells;
 325         start_ammo_nails   = warmup_start_ammo_nails   = autocvar_g_ca_start_ammo_nails;
 326         start_ammo_rockets = warmup_start_ammo_rockets = autocvar_g_ca_start_ammo_rockets;
 327         start_ammo_cells   = warmup_start_ammo_cells   = autocvar_g_ca_start_ammo_cells;
 328         start_ammo_plasma  = warmup_start_ammo_plasma  = autocvar_g_ca_start_ammo_plasma;
 329         start_ammo_fuel    = warmup_start_ammo_fuel    = autocvar_g_ca_start_ammo_fuel;
 330 }
 331
 332 MUTATOR_HOOKFUNCTION(ca, Damage_Calculate)
 333 {
 334         entity frag_attacker = M_ARGV(1, entity);
 335         entity frag_target = M_ARGV(2, entity);
 336         float frag_deathtype = M_ARGV(3, float);
 337         float frag_damage = M_ARGV(4, float);
 338         float frag_mirrordamage = M_ARGV(5, float);
 339
 340         if (IS_PLAYER(frag_target))
 341         if (!IS_DEAD(frag_target))
 342         if (frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL.m_id)
 343                 frag_damage = 0;
 344
 345         frag_mirrordamage = 0;
 346
 347         M_ARGV(4, float) = frag_damage;
 348         M_ARGV(5, float) = frag_mirrordamage;
 349 }
 350
 351 MUTATOR_HOOKFUNCTION(ca, FilterItem)
 352 {
 353         entity item = M_ARGV(0, entity);
 354
 355         if (autocvar_g_powerups <= 0)
 356         if (item.itemdef.instanceOfPowerup)
 357                 return true;
 358
 359         if (autocvar_g_pickup_items <= 0)
 360                 return true;
 361 }
 362
 363 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_SplitHealthArmor)
 364 {
 365         if (time < game_starttime || (round_handler_IsActive() && !round_handler_IsRoundStarted()))
 366                 return;
 367
 368         entity frag_attacker = M_ARGV(1, entity);
 369         entity frag_target = M_ARGV(2, entity);
 370         float frag_deathtype = M_ARGV(6, float);
 371         float frag_damage = M_ARGV(7, float);
 372         float damage_take = bound(0, M_ARGV(4, float), GetResource(frag_target, RES_HEALTH));
 373         float damage_save = bound(0, M_ARGV(5, float), GetResource(frag_target, RES_ARMOR));
 374
 375         float excess = max(0, frag_damage - damage_take - damage_save);
 376
 377         if (autocvar_g_ca_damage2score <= 0 || frag_damage - excess == 0) return;
 378
 379         entity scorer = NULL;
 380         float scorer_damage = 0;
 381
 382         if (IS_PLAYER(frag_attacker))
 383         {
 384                 if (DIFF_TEAM(frag_target, frag_attacker))
 385                         scorer_damage = frag_damage - excess;
 386                 else // friendly fire
 387                         scorer_damage = -(frag_damage - excess);
 388
 389                 scorer = frag_attacker;
 390         }
 391         else
 392         {
 393                 //handle (environmental hazard) suiciding, check first if player has a registered attacker who most likely pushed them there to avoid punishing pushed players as pushers are already rewarded
 394                 //deathtypes:
 395                 //kill = suicide, drown = drown in water/liquid, hurttrigger = out of the map void or hurt triggers inside maps like electric sparks
 396                 //camp = campcheck, lava = lava, slime = slime
 397                 //team change / rebalance suicides are currently not included
 398                 if (frag_deathtype == DEATH_KILL.m_id ||
 399                         frag_deathtype == DEATH_DROWN.m_id ||
 400                         frag_deathtype == DEATH_HURTTRIGGER.m_id ||
 401                         frag_deathtype == DEATH_CAMP.m_id ||
 402                         frag_deathtype == DEATH_LAVA.m_id ||
 403                         frag_deathtype == DEATH_SLIME.m_id ||
 404                         frag_deathtype == DEATH_SWAMP.m_id)
 405                 {
 406                         scorer_damage = -(frag_damage - excess);
 407                         scorer = frag_target;
 408                 }
 409         }
 410
 411         if (scorer)
 412         {
 413                 scorer.ca_damage_counter += scorer_damage;
 414                 if (fabs(scorer.ca_damage_counter) < autocvar_g_ca_damage2score)
 415                         return;
 416                 // NOTE: here we are actually rounding since ca_damage_counter is
 417                 // initialized on player spawn to half autocvar_g_ca_damage2score
 418                 // Also note that this code works for subtracting score too
 419                 int points = floor(scorer.ca_damage_counter / autocvar_g_ca_damage2score);
 420                 GameRules_scoring_add(scorer, SCORE, points);
 421
 422                 scorer.ca_damage_counter -= points * autocvar_g_ca_damage2score;
 423         }
 424 }
 425
 426 MUTATOR_HOOKFUNCTION(ca, CalculateRespawnTime)
 427 {
 428         // no respawn calculations needed, player is forced to spectate anyway
 429         return true;
 430 }
 431
 432 MUTATOR_HOOKFUNCTION(ca, PlayerRegen)
 433 {
 434         // no regeneration in CA
 435         return true;
 436 }
 437
 438 MUTATOR_HOOKFUNCTION(ca, Scores_CountFragsRemaining)
 439 {
 440         // announce remaining frags
 441         return true;
 442 }
 443
 444 MUTATOR_HOOKFUNCTION(ca, SpectateSet)
 445 {
 446         entity client = M_ARGV(0, entity);
 447         entity targ = M_ARGV(1, entity);
 448
 449         if (!autocvar_g_ca_spectate_enemies && INGAME(client))
 450         if (DIFF_TEAM(targ, client))
 451                 return true;
 452 }
 453
 454 MUTATOR_HOOKFUNCTION(ca, SpectateNext)
 455 {
 456         entity client = M_ARGV(0, entity);
 457
 458         if (!autocvar_g_ca_spectate_enemies && INGAME(client)
 459                 && Team_GetNumberOfAlivePlayers(Entity_GetTeam(client)))
 460         {
 461                 entity targ = M_ARGV(1, entity);
 462                 M_ARGV(1, entity) = CA_SpectateNext(client, targ);
 463                 return true;
 464         }
 465 }
 466
 467 MUTATOR_HOOKFUNCTION(ca, SpectatePrev)
 468 {
 469         entity client = M_ARGV(0, entity);
 470         entity targ = M_ARGV(1, entity);
 471         entity first = M_ARGV(2, entity);
 472
 473         if (!autocvar_g_ca_spectate_enemies && INGAME(client)
 474                 && Team_GetNumberOfAlivePlayers(Entity_GetTeam(client)))
 475         {
 476                 do { targ = targ.chain; }
 477                 while(targ && DIFF_TEAM(targ, client));
 478
 479                 if (!targ)
 480                 {
 481                         for (targ = first; targ && DIFF_TEAM(targ, client); targ = targ.chain);
 482
 483                         if (targ == client.enemy)
 484                                 return MUT_SPECPREV_RETURN;
 485                 }
 486         }
 487         else
 488                 return MUT_SPECPREV_CONTINUE;
 489
 490         M_ARGV(1, entity) = targ;
 491
 492         return MUT_SPECPREV_FOUND;
 493 }
 494
 495 MUTATOR_HOOKFUNCTION(ca, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 496 {
 497         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 498                 if (IS_PLAYER(it) || INGAME_JOINED(it))
 499                         ++M_ARGV(0, int);
 500                 ++M_ARGV(1, int);
 501         });
 502         return true;
 503 }
 504
 505 MUTATOR_HOOKFUNCTION(ca, ClientCommand_Spectate)
 506 {
 507         entity player = M_ARGV(0, entity);
 508
 509         if (INGAME(player))
 510         {
 511                 // they're going to spec, we can do other checks
 512                 if (autocvar_sv_spectate && (IS_SPEC(player) || IS_OBSERVER(player)))
 513                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_LEAVE);
 514                 return MUT_SPECCMD_FORCE;
 515         }
 516
 517         return MUT_SPECCMD_CONTINUE;
 518 }
 519
 520 MUTATOR_HOOKFUNCTION(ca, HideTeamNagger)
 521 {
 522         return true; // doesn't work well with the whole spectator as player thing
 523 }
 524
 525 MUTATOR_HOOKFUNCTION(ca, SetWeaponArena)
 526 {
 527         if (M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
 528                 M_ARGV(0, string) = autocvar_g_ca_weaponarena;
 529 }
 530
 531 MUTATOR_HOOKFUNCTION(ca, SV_ParseServerCommand)
 532 {
 533         string cmd_name = M_ARGV(0, string);
 534         if (cmd_name == "shuffleteams")
 535                 shuffleteams_on_reset_map = !allowed_to_spawn;
 536         return false;
 537 }