qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/mutators/mutator/overkill/okvortex.qh>
  30 #include <common/viewloc.qh>
  31 #include <common/minigames/cl_minigames.qh>
  32 #include <common/minigames/cl_minigames_hud.qh>
  33
  34 #include <lib/csqcmodel/cl_player.qh>
  35 #include <lib/csqcmodel/cl_model.qh>
  36 #include "csqcmodel_hooks.qh"
  37
  38 #include <lib/warpzone/client.qh>
  39 #include <lib/warpzone/common.qh>
  40
  41 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  42
  43 float autocvar_cl_viewmodel_scale;
  44
  45 bool autocvar_cl_bobmodel;
  46 float autocvar_cl_bobmodel_speed;
  47 float autocvar_cl_bobmodel_side;
  48 float autocvar_cl_bobmodel_up;
  49
  50 float autocvar_cl_followmodel;
  51 float autocvar_cl_followmodel_speed = 0.3;
  52 float autocvar_cl_followmodel_limit = 135;
  53 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  54 float autocvar_cl_followmodel_highpass = 0.05;
  55 float autocvar_cl_followmodel_lowpass = 0.03;
  56 bool autocvar_cl_followmodel_velocity_absolute;
  57
  58 float autocvar_cl_leanmodel;
  59 float autocvar_cl_leanmodel_speed = 0.3;
  60 float autocvar_cl_leanmodel_limit = 30;
  61 float autocvar_cl_leanmodel_highpass1 = 0.2;
  62 float autocvar_cl_leanmodel_highpass = 0.2;
  63 float autocvar_cl_leanmodel_lowpass = 0.05;
  64
  65 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  66 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  67 { \
  68         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  69 } MACRO_END
  70
  71 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  72 { \
  73         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  74         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  75 } MACRO_END
  76
  77 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  78 { \
  79         float __f = 0; lowpass(value, frac, ref_store, __f); \
  80         ret = (value) - __f; \
  81 } MACRO_END
  82
  83 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  84 { \
  85         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  86         ret = (value) - __f; \
  87 } MACRO_END
  88
  89 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  90 { \
  91         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  92         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  93 } MACRO_END
  94
  95 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  96 { \
  97         highpass(value.x, frac, ref_store.x, ref_out.x); \
  98         highpass(value.y, frac, ref_store.y, ref_out.y); \
  99 } MACRO_END
 100
 101 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 102 { \
 103         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 104         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 105 } MACRO_END
 106
 107 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 108 { \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 } MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115 { \
 116         highpass(value.x, frac, ref_store.x, ref_out.x); \
 117         highpass(value.y, frac, ref_store.y, ref_out.y); \
 118         highpass(value.z, frac, ref_store.z, ref_out.z); \
 119 } MACRO_END
 120
 121 void calc_followmodel_ofs(entity view)
 122 {
 123         if(cl_followmodel_time == time)
 124                 return; // cl_followmodel_ofs already calculated for this frame
 125
 126         float frac;
 127         vector gunorg = '0 0 0';
 128         static vector vel_average;
 129         static vector gunorg_adjustment_highpass;
 130         static vector gunorg_adjustment_lowpass;
 131
 132         vector vel;
 133         if (autocvar_cl_followmodel_velocity_absolute)
 134                 vel = view.velocity;
 135         else
 136         {
 137                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 138                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 139                 vel.x = view.velocity * forward;
 140                 vel.y = view.velocity * right * -1;
 141                 vel.z = view.velocity * up;
 142         }
 143
 144         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 145         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 146         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 147
 148         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 149         lowpass3(vel, frac, vel_average, gunorg);
 150
 151         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 152
 153         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 154         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 155         frac = avg_factor(autocvar_cl_followmodel_highpass);
 156         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 157         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 158         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 159
 160         if (autocvar_cl_followmodel_velocity_absolute)
 161         {
 162                 vector fixed_gunorg;
 163                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 164                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 165                 fixed_gunorg.x = gunorg * forward;
 166                 fixed_gunorg.y = gunorg * right * -1;
 167                 fixed_gunorg.z = gunorg * up;
 168                 gunorg = fixed_gunorg;
 169         }
 170
 171         cl_followmodel_ofs = gunorg;
 172         cl_followmodel_time = time;
 173 }
 174
 175 vector leanmodel_ofs(entity view)
 176 {
 177         float frac;
 178         vector gunangles = '0 0 0';
 179         static vector gunangles_prev = '0 0 0';
 180         static vector gunangles_highpass = '0 0 0';
 181         static vector gunangles_adjustment_highpass;
 182         static vector gunangles_adjustment_lowpass;
 183
 184         if (view.csqcmodel_teleported)
 185                 gunangles_prev = view_angles;
 186
 187         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 188         gunangles_highpass += gunangles_prev;
 189         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 190         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 191         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 192         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 193         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 194         gunangles_prev = view_angles;
 195         gunangles_highpass -= gunangles_prev;
 196
 197         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 198         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 199
 200         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 201         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 202         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 203         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 204         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 205
 206         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 207
 208         return gunangles;
 209 }
 210
 211 vector bobmodel_ofs(entity view)
 212 {
 213         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 214         static bool oldonground;
 215         static float hitgroundtime;
 216         if (clonground)
 217         {
 218                 float f = time; // cl.movecmd[0].time
 219                 if (!oldonground)
 220                         hitgroundtime = f;
 221         }
 222         oldonground = clonground;
 223
 224         // calculate for swinging gun model
 225         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 226         vector gunorg = '0 0 0';
 227         static float bobmodel_scale = 0;
 228         static float time_ofs = 0; // makes the effect always restart in the same way
 229         if (clonground)
 230         {
 231                 if (time - hitgroundtime > 0.05)
 232                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 233         }
 234         else
 235                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 236
 237         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 238         if (bobmodel_scale && xyspeed)
 239         {
 240                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 241                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 242                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 243                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 244         }
 245         else
 246                 time_ofs = time;
 247
 248         return gunorg;
 249 }
 250
 251 void viewmodel_animate(entity this)
 252 {
 253         if (autocvar_chase_active) return;
 254         if (STAT(HEALTH) <= 0) return;
 255
 256         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 257
 258         if (autocvar_cl_followmodel)
 259         {
 260                 calc_followmodel_ofs(view);
 261                 this.origin += cl_followmodel_ofs;
 262         }
 263
 264         if (autocvar_cl_leanmodel)
 265                 this.angles += leanmodel_ofs(view);
 266
 267         // vertical view bobbing code
 268         // TODO: cl_bob
 269
 270         // horizontal view bobbing code
 271         // TODO: cl_bob2
 272
 273         // fall bobbing code
 274         // causes the view to swing down and back up when touching the ground
 275         // TODO: cl_bobfall
 276
 277         // gun model bobbing code
 278         if (autocvar_cl_bobmodel)
 279                 this.origin += bobmodel_ofs(view);
 280 }
 281
 282 .vector viewmodel_origin, viewmodel_angles;
 283 .float weapon_nextthink;
 284 .float weapon_eta_last;
 285 .float weapon_switchdelay;
 286
 287 .string name_last;
 288
 289 void viewmodel_draw(entity this)
 290 {
 291         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 292                 return;
 293         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 294         float a = this.alpha;
 295         static bool wasinvehicle;
 296         bool invehicle = player_localentnum > maxclients;
 297         if (invehicle) a = -1;
 298         else if (wasinvehicle) a = 1;
 299         wasinvehicle = invehicle;
 300         Weapon wep = this.activeweapon;
 301         int c = entcs_GetClientColors(current_player);
 302         vector g = weaponentity_glowmod(wep, NULL, c, this);
 303         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 304         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 305                 | EF_NODEPTHTEST)
 306                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 307         for (entity e = this; e; e = e.weaponchild)
 308         {
 309                 e.drawmask = mask;
 310                 e.alpha = a;
 311                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 312                 e.glowmod = g;
 313                 e.csqcmodel_effects = fx;
 314                 CSQCModel_Effects_Apply(e);
 315         }
 316         {
 317                 string name = wep.mdl;
 318                 string newname = wep.wr_viewmodel(wep, this);
 319                 if(newname)
 320                         name = newname;
 321                 bool swap = name != this.name_last;
 322                 // if (swap)
 323                 {
 324                         this.name_last = name;
 325                         CL_WeaponEntity_SetModel(this, name, swap);
 326                         this.viewmodel_origin = this.origin;
 327                         this.viewmodel_angles = this.angles;
 328                 }
 329                 anim_update(this);
 330                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 331                         anim_set(this, this.anim_idle, true, false, false);
 332         }
 333         float f = 0; // 0..1; 0: fully active
 334         float rate = STAT(WEAPONRATEFACTOR);
 335         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 336         if (eta <= 0) f = this.weapon_eta_last;
 337         else switch (this.state)
 338         {
 339                 case WS_RAISE:
 340                 {
 341                         f = eta / max(eta, this.weapon_switchdelay);
 342                         break;
 343                 }
 344                 case WS_DROP:
 345                 {
 346                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_CLEAR:
 350                 {
 351                         f = 1;
 352                         break;
 353                 }
 354         }
 355         this.weapon_eta_last = f;
 356         this.origin = this.viewmodel_origin;
 357         this.angles = this.viewmodel_angles;
 358         this.angles_x = (-90 * f * f);
 359         viewmodel_animate(this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 void Porto_Draw(entity this);
 369 STATIC_INIT(Porto)
 370 {
 371         entity e = new_pure(porto);
 372         e.draw = Porto_Draw;
 373         IL_PUSH(g_drawables, e);
 374         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 375 }
 376
 377 const int polyline_length = 16;
 378 .vector polyline[polyline_length];
 379 void Porto_Draw(entity this)
 380 {
 381         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 382         {
 383                 entity wepent = viewmodels[slot];
 384
 385                 if (wepent.activeweapon != WEP_PORTO) continue;
 386                 if (spectatee_status) continue;
 387                 if (WEP_CVAR(porto, secondary)) continue;
 388                 if (intermission == 1) continue;
 389                 if (intermission == 2) continue;
 390                 if (STAT(HEALTH) <= 0) continue;
 391
 392                 vector pos = view_origin;
 393                 vector dir = view_forward;
 394                 if (wepent.angles_held_status)
 395                 {
 396                         makevectors(wepent.angles_held);
 397                         dir = v_forward;
 398                 }
 399
 400                 wepent.polyline[0] = pos;
 401
 402                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 403                 int n = 1 + 2;  // 2 lines == 3 points
 404                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 405                 {
 406                         traceline(pos, pos + 65536 * dir, true, this);
 407                         dir = reflect(dir, trace_plane_normal);
 408                         pos = trace_endpos;
 409                         wepent.polyline[++idx] = pos;
 410                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 411                         {
 412                                 n += 1;
 413                                 continue;
 414                         }
 415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 416                         {
 417                                 n = max(2, idx);
 418                                 break;
 419                         }
 420                         // check size
 421                         {
 422                                 vector ang = vectoangles2(trace_plane_normal, dir);
 423                                 ang.x = -ang.x;
 424                                 makevectors(ang);
 425                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 426                                 {
 427                                         n = max(2, idx);
 428                                         break;
 429                                 }
 430                         }
 431                         portal_number += 1;
 432                         if (portal_number >= portal_max) break;
 433                         if (portal_number == 1) portal1_idx = idx;
 434                 }
 435                 for (int idx = 0; idx < n - 1; ++idx)
 436                 {
 437                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 438                         if (idx == 0) p -= view_up * 16;  // line from player
 439                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 440                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 441                 }
 442         }
 443 }
 444
 445 float drawtime;
 446 float avgspeed;
 447 vector GetCurrentFov(float fov)
 448 {
 449         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 450         float velocityzoom, curspeed;
 451         vector v;
 452
 453         zoomsensitivity = autocvar_cl_zoomsensitivity;
 454         zoomfactor = autocvar_cl_zoomfactor;
 455         if(zoomfactor < 1 || zoomfactor > 30)
 456                 zoomfactor = 2.5;
 457         zoomspeed = autocvar_cl_zoomspeed;
 458         if(zoomspeed >= 0)
 459         if(zoomspeed < 0.5 || zoomspeed > 16)
 460                         zoomspeed = 3.5;
 461
 462         zoomdir = button_zoom;
 463
 464         if(hud == HUD_NORMAL && !spectatee_status)
 465         {
 466                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 467                 {
 468                         entity wepent = viewmodels[slot];
 469                         if(wepent.switchweapon == wepent.activeweapon)
 470                         if(((wepent.activeweapon == WEP_VORTEX || wepent.activeweapon == WEP_OVERKILL_VORTEX) && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 471                                 zoomdir += button_attack2;
 472                 }
 473         }
 474         if(spectatee_status > 0 || isdemo())
 475         {
 476                 if(spectatorbutton_zoom)
 477                 {
 478                         if(zoomdir)
 479                                 zoomdir = 0;
 480                         else
 481                                 zoomdir = 1;
 482                 }
 483                 // fteqcc failed twice here already, don't optimize this
 484         }
 485
 486         if(zoomdir) { zoomin_effect = 0; }
 487
 488         if(camera_active)
 489         {
 490                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 491         }
 492         else if(autocvar_cl_spawnzoom && zoomin_effect)
 493         {
 494                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 495
 496                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 497                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 498                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 499         }
 500         else
 501         {
 502                 if(zoomspeed < 0) // instant zoom
 503                 {
 504                         if(zoomdir)
 505                                 current_viewzoom = 1 / zoomfactor;
 506                         else
 507                                 current_viewzoom = 1;
 508                 }
 509                 else
 510                 {
 511                         if(zoomdir)
 512                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 513                         else
 514                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 515                 }
 516         }
 517
 518         if(almost_equals(current_viewzoom, 1))
 519                 current_zoomfraction = 0;
 520         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 521                 current_zoomfraction = 1;
 522         else
 523                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 524
 525         if(zoomsensitivity < 1)
 526                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 527         else
 528                 setsensitivityscale(1);
 529
 530         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 531         {
 532                 if(intermission) { curspeed = 0; }
 533                 else
 534                 {
 535
 536                         makevectors(view_angles);
 537                         v = pmove_vel;
 538                         if(csqcplayer)
 539                                 v = csqcplayer.velocity;
 540
 541                         switch(autocvar_cl_velocityzoom_type)
 542                         {
 543                                 case 3: curspeed = max(0, v_forward * v); break;
 544                                 case 2: curspeed = (v_forward * v); break;
 545                                 case 1: default: curspeed = vlen(v); break;
 546                         }
 547                 }
 548
 549                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 550                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 551                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 552
 553                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 554         }
 555         else
 556                 velocityzoom = 1;
 557
 558         float frustumx, frustumy, fovx, fovy;
 559         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 560         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 561         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 562         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 563
 564         return '1 0 0' * fovx + '0 1 0' * fovy;
 565 }
 566
 567 vector GetViewLocationFOV(float fov)
 568 {
 569         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 570         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 571         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 572         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 573         return '1 0 0' * fovx + '0 1 0' * fovy;
 574 }
 575
 576 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 577 {
 578         float fovx, fovy;
 579         float width = (ov_worldmax.x - ov_worldmin.x);
 580         float height = (ov_worldmax.y - ov_worldmin.y);
 581         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 582         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 583         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 584         return '1 0 0' * fovx + '0 1 0' * fovy;
 585 }
 586
 587 // this function must match W_SetupShot!
 588 float zoomscript_caught;
 589
 590 vector wcross_origin;
 591 float wcross_scale_prev, wcross_alpha_prev;
 592 vector wcross_color_prev;
 593 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 594 vector wcross_color_goal_prev;
 595 float wcross_changedonetime;
 596
 597 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 598 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 599 float wcross_name_changestarttime, wcross_name_changedonetime;
 600 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 601
 602 float wcross_ring_prev;
 603
 604 entity trueaim;
 605 entity trueaim_rifle;
 606
 607 const float SHOTTYPE_HITTEAM = 1;
 608 const float SHOTTYPE_HITOBSTRUCTION = 2;
 609 const float SHOTTYPE_HITWORLD = 3;
 610 const float SHOTTYPE_HITENEMY = 4;
 611
 612 void TrueAim_Init()
 613 {
 614         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 615         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 616 }
 617
 618 float EnemyHitCheck()
 619 {
 620         float t, n;
 621         wcross_origin = project_3d_to_2d(trace_endpos);
 622         wcross_origin.z = 0;
 623         if(trace_ent)
 624                 n = trace_ent.entnum;
 625         else
 626                 n = trace_networkentity;
 627         if(n < 1)
 628                 return SHOTTYPE_HITWORLD;
 629         if(n > maxclients)
 630                 return SHOTTYPE_HITWORLD;
 631         t = entcs_GetTeam(n - 1);
 632         if(teamplay)
 633                 if(t == myteam)
 634                         return SHOTTYPE_HITTEAM;
 635         if(t == NUM_SPECTATOR)
 636                 return SHOTTYPE_HITWORLD;
 637         return SHOTTYPE_HITENEMY;
 638 }
 639
 640 float TrueAimCheck(entity wepent)
 641 {
 642         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 643         vector vecs, trueaimpoint, w_shotorg;
 644         vector mi, ma, dv;
 645         float shottype;
 646         entity ta;
 647         float mv;
 648
 649         mi = ma = '0 0 0';
 650         ta = trueaim;
 651         mv = MOVE_NOMONSTERS;
 652
 653         switch(wepent.activeweapon) // WEAPONTODO
 654         {
 655                 case WEP_TUBA: // no aim
 656                 case WEP_PORTO: // shoots from eye
 657                 case WEP_NEXBALL: // shoots from eye
 658                 case WEP_HOOK: // no trueaim
 659                 case WEP_MORTAR: // toss curve
 660                         return SHOTTYPE_HITWORLD;
 661                 case WEP_VORTEX:
 662                 case WEP_OVERKILL_VORTEX:
 663                 case WEP_VAPORIZER:
 664                         mv = MOVE_NORMAL;
 665                         break;
 666                 case WEP_RIFLE:
 667                         ta = trueaim_rifle;
 668                         mv = MOVE_NORMAL;
 669                         if(zoomscript_caught)
 670                         {
 671                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 672                                 return EnemyHitCheck();
 673                         }
 674                         break;
 675                 case WEP_DEVASTATOR: // projectile has a size!
 676                         mi = '-3 -3 -3';
 677                         ma = '3 3 3';
 678                         break;
 679                 case WEP_FIREBALL: // projectile has a size!
 680                         mi = '-16 -16 -16';
 681                         ma = '16 16 16';
 682                         break;
 683                 case WEP_SEEKER: // projectile has a size!
 684                         mi = '-2 -2 -2';
 685                         ma = '2 2 2';
 686                         break;
 687                 case WEP_ELECTRO: // projectile has a size!
 688                         mi = '0 0 -3';
 689                         ma = '0 0 -3';
 690                         break;
 691         }
 692
 693         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 694
 695         vecs = decompressShotOrigin(STAT(SHOTORG));
 696
 697         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 698         trueaimpoint = trace_endpos;
 699
 700         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 701                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 702
 703         if(vecs.x > 0)
 704                 vecs.y = -vecs.y;
 705         else
 706                 vecs = '0 0 0';
 707
 708         dv = view_right * vecs.y + view_up * vecs.z;
 709         w_shotorg = traceorigin + dv;
 710
 711         // now move the vecs forward as much as requested if possible
 712         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 713         w_shotorg = trace_endpos - view_forward * nudge;
 714
 715         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 716         shottype = EnemyHitCheck();
 717         if(shottype != SHOTTYPE_HITWORLD)
 718                 return shottype;
 719
 720 #if 0
 721         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 722         // or rather, I know why, but see no fix
 723         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 724                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 725                 return SHOTTYPE_HITOBSTRUCTION;
 726 #endif
 727
 728         return SHOTTYPE_HITWORLD;
 729 }
 730
 731 void PostInit();
 732 void CSQC_Demo_Camera();
 733 float camera_mode;
 734 const float CAMERA_FREE = 1;
 735 const float CAMERA_CHASE = 2;
 736 float reticle_type;
 737 string NextFrameCommand;
 738
 739 vector freeze_org, freeze_ang;
 740 entity nightvision_noise, nightvision_noise2;
 741
 742 const float MAX_TIME_DIFF = 5;
 743 float pickup_crosshair_time, pickup_crosshair_size;
 744 float hitindication_crosshair_size;
 745 float use_vortex_chargepool;
 746
 747 float myhealth, myhealth_prev;
 748 float myhealth_flash;
 749
 750 float old_blurradius, old_bluralpha;
 751 float old_sharpen_intensity;
 752
 753 vector myhealth_gentlergb;
 754
 755 float contentavgalpha, liquidalpha_prev;
 756 vector liquidcolor_prev;
 757
 758 float eventchase_current_distance;
 759 float eventchase_running;
 760 bool WantEventchase(entity this)
 761 {
 762         if(autocvar_cl_orthoview)
 763                 return false;
 764         if(STAT(GAME_STOPPED) || intermission)
 765                 return true;
 766         if(this.viewloc)
 767                 return true;
 768         if(spectatee_status >= 0)
 769         {
 770                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 771                         return true;
 772                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 773                         return true;
 774                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 775                 {
 776                         if(autocvar_cl_eventchase_death == 2)
 777                         {
 778                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 779                                 if(this.velocity == '0 0 0' || eventchase_running)
 780                                         return true;
 781                         }
 782                         else return true;
 783                 }
 784         }
 785         return false;
 786 }
 787
 788 void HUD_Crosshair_Vehicle(entity this)
 789 {
 790         if(hud != HUD_BUMBLEBEE_GUN)
 791         {
 792                 Vehicle info = Vehicles_from(hud);
 793                 info.vr_crosshair(info, this);
 794         }
 795 }
 796
 797 vector damage_blurpostprocess, content_blurpostprocess;
 798
 799 float unaccounted_damage = 0;
 800 void UpdateDamage()
 801 {
 802         // accumulate damage with each stat update
 803         static float damage_total_prev = 0;
 804         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 805         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 806         damage_total_prev = damage_total;
 807
 808         static float damage_dealt_time_prev = 0;
 809         float damage_dealt_time = STAT(HIT_TIME);
 810         if (damage_dealt_time != damage_dealt_time_prev)
 811         {
 812                 unaccounted_damage += unaccounted_damage_new;
 813                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 814         }
 815         damage_dealt_time_prev = damage_dealt_time;
 816
 817         // prevent hitsound when switching spectatee
 818         static float spectatee_status_prev = 0;
 819         if (spectatee_status != spectatee_status_prev)
 820                 unaccounted_damage = 0;
 821         spectatee_status_prev = spectatee_status;
 822 }
 823
 824 void HitSound()
 825 {
 826         // varying sound pitch
 827
 828         bool have_arc = false;
 829         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 830         {
 831                 entity wepent = viewmodels[slot];
 832
 833                 if(wepent.activeweapon == WEP_ARC)
 834                         have_arc = true;
 835         }
 836
 837         static float hitsound_time_prev = 0;
 838         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 839         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 840         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 841         {
 842                 if (autocvar_cl_hitsound && unaccounted_damage)
 843                 {
 844                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 845                         float a = autocvar_cl_hitsound_max_pitch;
 846                         float b = autocvar_cl_hitsound_min_pitch;
 847                         float c = autocvar_cl_hitsound_nom_damage;
 848                         float d = unaccounted_damage;
 849                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 850
 851                         // if sound variation is disabled, set pitch_shift to 1
 852                         if (autocvar_cl_hitsound == 1)
 853                                 pitch_shift = 1;
 854
 855                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 856                         if (autocvar_cl_hitsound == 3)
 857                         {
 858                                 float mirror_value = (a-b)/2 + b;
 859                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 860                         }
 861
 862                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 863
 864                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 865                         // todo: normalize sound pressure levels? seems unnecessary
 866
 867                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 868                 }
 869                 unaccounted_damage = 0;
 870                 hitsound_time_prev = time;
 871         }
 872
 873         static float typehit_time_prev = 0;
 874         float typehit_time = STAT(TYPEHIT_TIME);
 875         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 876         {
 877                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 878                 typehit_time_prev = typehit_time;
 879         }
 880 }
 881
 882 vector crosshair_getcolor(entity this, float health_stat)
 883 {
 884         static float rainbow_last_flicker;
 885         static vector rainbow_prev_color;
 886         vector wcross_color = '0 0 0';
 887         switch(autocvar_crosshair_color_special)
 888         {
 889                 case 1: // crosshair_color_per_weapon
 890                 {
 891                         if(this != WEP_Null && hud == HUD_NORMAL)
 892                         {
 893                                 wcross_color = this.wpcolor;
 894                                 break;
 895                         }
 896                         else { goto normalcolor; }
 897                 }
 898
 899                 case 2: // crosshair_color_by_health
 900                 {
 901                         float hp = health_stat;
 902
 903                         //x = red
 904                         //y = green
 905                         //z = blue
 906
 907                         wcross_color.z = 0;
 908
 909                         if(hp > 200)
 910                         {
 911                                 wcross_color.x = 0;
 912                                 wcross_color.y = 1;
 913                         }
 914                         else if(hp > 150)
 915                         {
 916                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 917                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 918                         }
 919                         else if(hp > 100)
 920                         {
 921                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 922                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 923                                 wcross_color.z = 1 - (hp-100)*0.02;
 924                         }
 925                         else if(hp > 50)
 926                         {
 927                                 wcross_color.x = 1;
 928                                 wcross_color.y = 1;
 929                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 930                         }
 931                         else if(hp > 20)
 932                         {
 933                                 wcross_color.x = 1;
 934                                 wcross_color.y = (hp-20)*90/27/100;
 935                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 936                         }
 937                         else
 938                         {
 939                                 wcross_color.x = 1;
 940                                 wcross_color.y = 0;
 941                         }
 942                         break;
 943                 }
 944
 945                 case 3: // crosshair_color_rainbow
 946                 {
 947                         if(time >= rainbow_last_flicker)
 948                         {
 949                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 950                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 951                         }
 952                         wcross_color = rainbow_prev_color;
 953                         break;
 954                 }
 955 LABEL(normalcolor)
 956                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 957         }
 958
 959         return wcross_color;
 960 }
 961
 962 void HUD_Crosshair(entity this)
 963 {
 964         float f, i, j;
 965         vector v;
 966         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 967                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 968                 !HUD_MinigameMenu_IsOpened() )
 969         {
 970                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 971                         return;
 972
 973                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 974                         return;
 975
 976                 if (hud != HUD_NORMAL)
 977                 {
 978                         HUD_Crosshair_Vehicle(this);
 979                         return;
 980                 }
 981
 982                 string wcross_style;
 983                 float wcross_alpha, wcross_resolution;
 984                 wcross_style = autocvar_crosshair;
 985                 if (wcross_style == "0")
 986                         return;
 987                 wcross_resolution = autocvar_crosshair_size;
 988                 if (wcross_resolution == 0)
 989                         return;
 990                 wcross_alpha = autocvar_crosshair_alpha;
 991                 if (wcross_alpha == 0)
 992                         return;
 993
 994                 // TrueAim check
 995                 float shottype;
 996
 997                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 998                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 999                 wcross_origin.z = 0;
1000                 if(autocvar_crosshair_hittest)
1001                 {
1002                         vector wcross_oldorigin;
1003                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1004                         wcross_oldorigin = wcross_origin;
1005                         shottype = TrueAimCheck(thiswep);
1006                         if(shottype == SHOTTYPE_HITWORLD)
1007                         {
1008                                 v = wcross_origin - wcross_oldorigin;
1009                                 v.x /= vid_conwidth;
1010                                 v.y /= vid_conheight;
1011                                 if(vdist(v, >, 0.01))
1012                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1013                         }
1014                         if(!autocvar_crosshair_hittest_showimpact)
1015                                 wcross_origin = wcross_oldorigin;
1016                 }
1017                 else
1018                         shottype = SHOTTYPE_HITWORLD;
1019
1020                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1021                 string wcross_name = "";
1022                 float wcross_scale, wcross_blur;
1023
1024         entity e = WEP_Null;
1025                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1026                 {
1027                         entity wepent = viewmodels[0]; // TODO: unhardcode
1028                         e = wepent.switchingweapon;
1029                         if(e)
1030                         {
1031                                 if(autocvar_crosshair_per_weapon)
1032                                 {
1033                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1034                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1035                                         //if (wcross_resolution == 0)
1036                                                 //return;
1037
1038                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1039                                         wcross_resolution *= e.w_crosshair_size;
1040                                         wcross_name = e.w_crosshair;
1041                                 }
1042                         }
1043                 }
1044
1045                 if(wcross_name == "")
1046                         wcross_name = strcat("gfx/crosshair", wcross_style);
1047
1048                 // MAIN CROSSHAIR COLOR DECISION
1049                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1050
1051                 if(autocvar_crosshair_effect_scalefade)
1052                 {
1053                         wcross_scale = wcross_resolution;
1054                         wcross_resolution = 1;
1055                 }
1056                 else
1057                 {
1058                         wcross_scale = 1;
1059                 }
1060
1061                 if(autocvar_crosshair_pickup)
1062                 {
1063                         float stat_pickup_time = STAT(LAST_PICKUP);
1064
1065                         if(pickup_crosshair_time < stat_pickup_time)
1066                         {
1067                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1068                                         pickup_crosshair_size = 1;
1069
1070                                 pickup_crosshair_time = stat_pickup_time;
1071                         }
1072
1073                         if(pickup_crosshair_size > 0)
1074                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1075                         else
1076                                 pickup_crosshair_size = 0;
1077
1078                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1079                 }
1080
1081                 // todo: make crosshair hit indication dependent on damage dealt
1082                 if(autocvar_crosshair_hitindication)
1083                 {
1084                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1085
1086                         if(unaccounted_damage)
1087                         {
1088                                 hitindication_crosshair_size = 1;
1089                         }
1090
1091                         if(hitindication_crosshair_size > 0)
1092                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1093                         else
1094                                 hitindication_crosshair_size = 0;
1095
1096                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1097                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1098                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1099                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1100                 }
1101
1102                 if(shottype == SHOTTYPE_HITENEMY)
1103                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1104                 if(shottype == SHOTTYPE_HITTEAM)
1105                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1106
1107                 f = fabs(autocvar_crosshair_effect_time);
1108                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1109                 {
1110                         wcross_changedonetime = time + f;
1111                 }
1112                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1113                 {
1114                         wcross_name_changestarttime = time;
1115                         wcross_name_changedonetime = time + f;
1116                         if(wcross_name_goal_prev_prev)
1117                                 strunzone(wcross_name_goal_prev_prev);
1118                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1119                         wcross_name_goal_prev = strzone(wcross_name);
1120                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1121                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1122                         wcross_resolution_goal_prev = wcross_resolution;
1123                 }
1124
1125                 wcross_scale_goal_prev = wcross_scale;
1126                 wcross_alpha_goal_prev = wcross_alpha;
1127                 wcross_color_goal_prev = wcross_color;
1128
1129                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1130                 {
1131                         wcross_blur = 1;
1132                         wcross_alpha *= 0.75;
1133                 }
1134                 else
1135                         wcross_blur = 0;
1136                 // *_prev is at time-frametime
1137                 // * is at wcross_changedonetime+f
1138                 // what do we have at time?
1139                 if(time < wcross_changedonetime)
1140                 {
1141                         f = frametime / (wcross_changedonetime - time + frametime);
1142                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1143                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1144                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1145                 }
1146
1147                 wcross_scale_prev = wcross_scale;
1148                 wcross_alpha_prev = wcross_alpha;
1149                 wcross_color_prev = wcross_color;
1150
1151                 MUTATOR_CALLHOOK(UpdateCrosshair);
1152
1153                 wcross_scale *= 1 - autocvar__menu_alpha;
1154                 wcross_alpha *= 1 - autocvar__menu_alpha;
1155                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1156
1157                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1158                 {
1159                         // crosshair rings for weapon stats
1160                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1161                         {
1162                                 // declarations and stats
1163                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1164                                 string ring_image = string_null, ring_inner_image = string_null;
1165                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1166
1167                                 ring_scale = autocvar_crosshair_ring_size;
1168
1169                                 float weapon_clipload, weapon_clipsize;
1170                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1171                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1172
1173                                 float vortex_charge, vortex_chargepool;
1174                                 vortex_charge = STAT(VORTEX_CHARGE);
1175                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1176
1177                                 float arc_heat = STAT(ARC_HEAT);
1178
1179                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1180                                         vortex_charge_movingavg = vortex_charge;
1181
1182                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1183
1184                                 // handle the values
1185                                 if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_VORTEX || wepent.activeweapon == WEP_OVERKILL_VORTEX) && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1186                                 {
1187                                         if (vortex_chargepool || use_vortex_chargepool) {
1188                                                 use_vortex_chargepool = 1;
1189                                                 ring_inner_value = vortex_chargepool;
1190                                         } else {
1191                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1192                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1193                                         }
1194
1195                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1196                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1197                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1198
1199                                         // draw the outer ring to show the current charge of the weapon
1200                                         ring_value = vortex_charge;
1201                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1202                                         ring_rgb = wcross_color;
1203                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1204                                 }
1205                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1206                                 {
1207                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1208                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1209                                         ring_rgb = wcross_color;
1210                                         ring_image = "gfx/crosshair_ring.tga";
1211                                 }
1212                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1213                                 {
1214                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1215                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1216                                         ring_rgb = wcross_color;
1217                                         ring_image = "gfx/crosshair_ring.tga";
1218                                 }
1219                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1220                                 {
1221                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1222                                         ring_scale = autocvar_crosshair_ring_reload_size;
1223                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1224                                         ring_rgb = wcross_color;
1225
1226                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1227                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1228                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1229                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1230                                         else
1231                                                 ring_image = "gfx/crosshair_ring.tga";
1232                                 }
1233                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1234                                 {
1235                                         ring_value = arc_heat;
1236                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1237                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1238                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1239                                         ring_image = "gfx/crosshair_ring.tga";
1240                                 }
1241
1242                                 // if in weapon switch animation, fade ring out/in
1243                                 if(autocvar_crosshair_effect_time > 0)
1244                                 {
1245                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1246                                         if (f >= 1)
1247                                         {
1248                                                 wcross_ring_prev = ((ring_image) ? true : false);
1249                                         }
1250
1251                                         if(wcross_ring_prev)
1252                                         {
1253                                                 if(f < 1)
1254                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1255                                         }
1256                                         else
1257                                         {
1258                                                 if(f < 1)
1259                                                         ring_alpha *= bound(0, f, 1);
1260                                         }
1261                                 }
1262
1263                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1264                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1265
1266                                 if (ring_value)
1267                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1268                         }
1269
1270 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1271                         MACRO_BEGIN { \
1272                                 if(wcross_blur > 0) \
1273                                 { \
1274                                         for(i = -2; i <= 2; ++i) \
1275                                         for(j = -2; j <= 2; ++j) \
1276                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1277                                 } \
1278                                 else \
1279                                 { \
1280                                         M(0,0,sz,wcross_name,wcross_alpha); \
1281                                 } \
1282                         } MACRO_END
1283
1284 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1285                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1286
1287 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1288                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1289
1290                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1291                         {
1292                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1293                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1294                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1295                                 f = 1 - f;
1296                         }
1297                         else
1298                         {
1299                                 f = 1;
1300                         }
1301                         wcross_name_alpha_goal_prev = f;
1302
1303                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1304                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1305
1306                         if(autocvar_crosshair_dot)
1307                         {
1308                                 vector wcross_color_old;
1309                                 wcross_color_old = wcross_color;
1310
1311                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1312                                         wcross_color = stov(autocvar_crosshair_dot_color);
1313
1314                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1315                                 // FIXME why don't we use wcross_alpha here?
1316                                 wcross_color = wcross_color_old;
1317                         }
1318                 }
1319         }
1320         else
1321         {
1322                 wcross_scale_prev = 0;
1323                 wcross_alpha_prev = 0;
1324                 wcross_scale_goal_prev = 0;
1325                 wcross_alpha_goal_prev = 0;
1326                 wcross_changedonetime = 0;
1327                 if(wcross_name_goal_prev)
1328                         strunzone(wcross_name_goal_prev);
1329                 wcross_name_goal_prev = string_null;
1330                 if(wcross_name_goal_prev_prev)
1331                         strunzone(wcross_name_goal_prev_prev);
1332                 wcross_name_goal_prev_prev = string_null;
1333                 wcross_name_changestarttime = 0;
1334                 wcross_name_changedonetime = 0;
1335                 wcross_name_alpha_goal_prev = 0;
1336                 wcross_name_alpha_goal_prev_prev = 0;
1337                 wcross_resolution_goal_prev = 0;
1338                 wcross_resolution_goal_prev_prev = 0;
1339         }
1340 }
1341
1342 void HUD_Draw(entity this)
1343 {
1344         // if we don't know gametype and scores yet avoid drawing the scoreboard
1345         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1346         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1347         // cl_deathscoreboard would show the scoreboard and so on
1348         if(!gametype)
1349                 return;
1350
1351         if(!intermission)
1352         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1353         {
1354                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1355         }
1356         else if(STAT(FROZEN))
1357         {
1358                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1359         }
1360         if(!intermission)
1361         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1362         {
1363                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1364                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1365         }
1366         else if(STAT(CAPTURE_PROGRESS))
1367         {
1368                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1369                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1370         }
1371         else if(STAT(REVIVE_PROGRESS))
1372         {
1373                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1374                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1375         }
1376
1377         if(autocvar_r_letterbox == 0)
1378                 if(autocvar_viewsize < 120)
1379                 {
1380                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1381                                 Accuracy_LoadLevels();
1382
1383                         HUD_Main();
1384                         HUD_Scale_Disable();
1385                 }
1386
1387         // crosshair goes VERY LAST
1388         UpdateDamage();
1389         HUD_Crosshair(this);
1390         HitSound();
1391 }
1392
1393 bool ov_enabled;
1394 float oldr_nearclip;
1395 float oldr_farclip_base;
1396 float oldr_farclip_world;
1397 float oldr_novis;
1398 float oldr_useportalculling;
1399 float oldr_useinfinitefarclip;
1400
1401 void cl_notice_run();
1402
1403 float prev_myteam;
1404 int lasthud;
1405 float vh_notice_time;
1406 void WaypointSprite_Load();
1407 void CSQC_UpdateView(entity this, float w, float h)
1408 {
1409     TC(int, w); TC(int, h);
1410         entity e;
1411         float fov;
1412         float f;
1413         vector vf_size, vf_min;
1414         float a;
1415
1416         execute_next_frame();
1417
1418         ++framecount;
1419
1420         stats_get();
1421         hud = STAT(HUD);
1422
1423         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1424                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1425
1426         lasthud = hud;
1427
1428         HUD_Scale_Disable();
1429
1430         if(autocvar__hud_showbinds_reload) // menu can set this one
1431         {
1432                 db_close(binddb);
1433                 binddb = db_create();
1434                 cvar_set("_hud_showbinds_reload", "0");
1435         }
1436
1437         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1438                 view_quality = getproperty(VF_MINFPS_QUALITY);
1439         else
1440                 view_quality = 1;
1441
1442         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1443         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1444
1445         vf_size = getpropertyvec(VF_SIZE);
1446         vf_min = getpropertyvec(VF_MIN);
1447         vid_width = vf_size.x;
1448         vid_height = vf_size.y;
1449
1450         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1451         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1452
1453         WaypointSprite_Load();
1454
1455         CSQCPlayer_SetCamera();
1456
1457         if(player_localentnum <= maxclients) // is it a client?
1458                 current_player = player_localentnum - 1;
1459         else // then player_localentnum is the vehicle I'm driving
1460                 current_player = player_localnum;
1461         myteam = entcs_GetTeam(current_player);
1462
1463         if(myteam != prev_myteam)
1464         {
1465                 myteamcolors = colormapPaletteColor(myteam, 1);
1466                 FOREACH(hud_panels, true, it.update_time = time);
1467                 prev_myteam = myteam;
1468         }
1469
1470         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1471
1472         float is_dead = (STAT(HEALTH) <= 0);
1473
1474         // FIXME do we need this hack?
1475         if(isdemo())
1476         {
1477                 // in demos, input_buttons do not work
1478                 button_zoom = (autocvar__togglezoom == "-");
1479         }
1480         else if(button_zoom
1481                 && autocvar_cl_unpress_zoom_on_death
1482                 && (spectatee_status >= 0)
1483                 && (is_dead || intermission))
1484         {
1485                 // no zoom while dead or in intermission please
1486                 localcmd("-zoom\n");
1487                 button_zoom = false;
1488         }
1489
1490         // event chase camera
1491         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1492         {
1493                 if(STAT(CAMERA_SPECTATOR))
1494                 {
1495                         if(spectatee_status > 0)
1496                         {
1497                                 if(!autocvar_chase_active)
1498                                 {
1499                                         cvar_set("chase_active", "-2");
1500                                         goto skip_eventchase_death;
1501                                 }
1502                         }
1503                         else if(autocvar_chase_active == -2)
1504                                 cvar_set("chase_active", "0");
1505
1506                         if(autocvar_chase_active == -2)
1507                                 goto skip_eventchase_death;
1508                 }
1509                 else if(autocvar_chase_active == -2)
1510                         cvar_set("chase_active", "0");
1511
1512                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1513
1514                 float vehicle_viewdist = 0;
1515                 vector vehicle_viewofs = '0 0 0';
1516
1517                 if(vehicle_chase)
1518                 {
1519                         if(hud != HUD_BUMBLEBEE_GUN)
1520                         {
1521                                 Vehicle info = Vehicles_from(hud);
1522                                 vehicle_viewdist = info.height;
1523                                 vehicle_viewofs = info.view_ofs;
1524                         }
1525                 }
1526
1527                 if(WantEventchase(this))
1528                 {
1529                         vector current_view_origin_override = '0 0 0';
1530                         vector view_offset_override = '0 0 0';
1531                         float chase_distance_override = 0;
1532                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1533                         if(custom_eventchase)
1534                         {
1535                                 current_view_origin_override = M_ARGV(0, vector);
1536                                 view_offset_override = M_ARGV(1, vector);
1537                                 chase_distance_override = M_ARGV(0, float);
1538                         }
1539                         eventchase_running = true;
1540
1541                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1542                         if(!local_player)
1543                                 local_player = this; // fall back!
1544
1545                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1546                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1547                         if (custom_eventchase)
1548                                 current_view_origin = current_view_origin_override;
1549
1550                         // detect maximum viewoffset and use it
1551                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1552                         if(vehicle_chase)
1553                         {
1554                                 if(vehicle_viewofs)
1555                                         view_offset = vehicle_viewofs;
1556                                 else
1557                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1558                         }
1559                         if (custom_eventchase)
1560                                 view_offset = view_offset_override;
1561
1562                         if(view_offset)
1563                         {
1564                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1565                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1566                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1567                         }
1568
1569                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1570                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1571                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1572                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1573
1574                         // make the camera smooth back
1575                         float chase_distance = autocvar_cl_eventchase_distance;
1576                         if(vehicle_chase)
1577                         {
1578                                 if(vehicle_viewofs)
1579                                         chase_distance = vehicle_viewdist;
1580                                 else
1581                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1582                         }
1583                         if (custom_eventchase)
1584                                 chase_distance = chase_distance_override;
1585
1586                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1587                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1588                         else if(eventchase_current_distance != chase_distance)
1589                                 eventchase_current_distance = chase_distance;
1590
1591                         makevectors(view_angles);
1592
1593                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1594                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1595
1596                         // If the boxtrace fails, revert back to line tracing.
1597                         if(!local_player.viewloc)
1598                         if(trace_startsolid)
1599                         {
1600                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1601                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1602                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1603                         }
1604                         else { setproperty(VF_ORIGIN, trace_endpos); }
1605
1606                         if(!local_player.viewloc)
1607                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1608                 }
1609                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1610                 {
1611                         eventchase_running = false;
1612                         cvar_set("chase_active", "0");
1613                         eventchase_current_distance = 0; // start from 0 next time
1614                 }
1615         }
1616         // workaround for camera stuck between player's legs when using chase_active 1
1617         // because the engine stops updating the chase_active camera when the game ends
1618         else if(intermission)
1619         {
1620                 cvar_settemp("chase_active", "-1");
1621                 eventchase_current_distance = 0;
1622         }
1623
1624         LABEL(skip_eventchase_death);
1625
1626         // do lockview after event chase camera so that it still applies whenever necessary.
1627         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1628         {
1629                 setproperty(VF_ORIGIN, freeze_org);
1630                 setproperty(VF_ANGLES, freeze_ang);
1631         }
1632         else
1633         {
1634                 freeze_org = getpropertyvec(VF_ORIGIN);
1635                 freeze_ang = getpropertyvec(VF_ANGLES);
1636         }
1637
1638         WarpZone_FixView();
1639         //WarpZone_FixPMove();
1640
1641         vector ov_org = '0 0 0';
1642         vector ov_mid = '0 0 0';
1643         vector ov_worldmin = '0 0 0';
1644         vector ov_worldmax = '0 0 0';
1645         if(autocvar_cl_orthoview)
1646         {
1647                 ov_worldmin = mi_picmin;
1648                 ov_worldmax = mi_picmax;
1649
1650                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1651                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1652                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1653
1654                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1655                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1656
1657                 float ov_nearest = vlen(ov_org - vec3(
1658                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1659                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1660                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1661                 ));
1662
1663                 float ov_furthest = 0;
1664                 float dist = 0;
1665
1666                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1667                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1668                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1669                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1670                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1671                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1672                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1673                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1674
1675                 if(!ov_enabled)
1676                 {
1677                         oldr_nearclip = cvar("r_nearclip");
1678                         oldr_farclip_base = cvar("r_farclip_base");
1679                         oldr_farclip_world = cvar("r_farclip_world");
1680                         oldr_novis = cvar("r_novis");
1681                         oldr_useportalculling = cvar("r_useportalculling");
1682                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1683                 }
1684
1685                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1686                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1687                 cvar_settemp("r_farclip_world", "0");
1688                 cvar_settemp("r_novis", "1");
1689                 cvar_settemp("r_useportalculling", "0");
1690                 cvar_settemp("r_useinfinitefarclip", "0");
1691
1692                 setproperty(VF_ORIGIN, ov_org);
1693                 setproperty(VF_ANGLES, '90 0 0');
1694
1695                 ov_enabled = true;
1696
1697                 #if 0
1698                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1699                         vtos(ov_org),
1700                         vtos(getpropertyvec(VF_ANGLES)),
1701                         ov_distance,
1702                         ov_nearest,
1703                         ov_furthest);
1704                 #endif
1705         }
1706         else
1707         {
1708                 if(ov_enabled)
1709                 {
1710                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1711                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1712                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1713                         cvar_set("r_novis", ftos(oldr_novis));
1714                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1715                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1716                 }
1717                 ov_enabled = false;
1718         }
1719
1720         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1721         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1722         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1723                 viewmodel_draw(viewmodels[slot]);
1724
1725         // Render the Scene
1726         view_origin = getpropertyvec(VF_ORIGIN);
1727         view_angles = getpropertyvec(VF_ANGLES);
1728         makevectors(view_angles);
1729         view_forward = v_forward;
1730         view_right = v_right;
1731         view_up = v_up;
1732
1733 #ifdef BLURTEST
1734         if(time > blurtest_time0 && time < blurtest_time1)
1735         {
1736                 float r, t;
1737
1738                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1739                 r = t * blurtest_radius;
1740                 f = 1 / (t ** blurtest_power) - 1;
1741
1742                 cvar_set("r_glsl_postprocess", "1");
1743                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1744         }
1745         else
1746         {
1747                 cvar_set("r_glsl_postprocess", "0");
1748                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1749         }
1750 #endif
1751
1752         TargetMusic_Advance();
1753         Fog_Force();
1754
1755         if(drawtime == 0)
1756                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1757         else
1758                 drawframetime = bound(0.000001, time - drawtime, 1);
1759         drawtime = time;
1760
1761         // watch for gametype changes here...
1762         // in ParseStuffCMD the cmd isn't executed yet :/
1763         // might even be better to add the gametype to TE_CSQC_INIT...?
1764         if(!postinit)
1765                 PostInit();
1766
1767         if(intermission && !intermission_time)
1768                 intermission_time = time;
1769
1770         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1771         {
1772                 if(calledhooks & HOOK_START)
1773                 {
1774                         localcmd("\ncl_hook_gameend\n");
1775                         calledhooks |= HOOK_END;
1776                 }
1777         }
1778
1779         Announcer();
1780
1781         fov = autocvar_fov;
1782         if(fov <= 59.5)
1783         {
1784                 if(!zoomscript_caught)
1785                 {
1786                         localcmd("+button9\n");
1787                         zoomscript_caught = 1;
1788                 }
1789         }
1790         else
1791         {
1792                 if(zoomscript_caught)
1793                 {
1794                         localcmd("-button9\n");
1795                         zoomscript_caught = 0;
1796                 }
1797         }
1798
1799         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1800
1801         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1802         {
1803                 entity wepent = viewmodels[slot];
1804
1805                 if(wepent.last_switchweapon != wepent.switchweapon)
1806                 {
1807                         weapontime = time;
1808                         wepent.last_switchweapon = wepent.switchweapon;
1809                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1810                         {
1811                                 localcmd("-zoom\n");
1812                                 button_zoom = false;
1813                         }
1814                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1815                         {
1816                                 localcmd("-fire\n");
1817                                 localcmd("-fire2\n");
1818                                 button_attack2 = false;
1819                         }
1820                 }
1821                 if(wepent.last_activeweapon != wepent.activeweapon)
1822                 {
1823                         wepent.last_activeweapon = wepent.activeweapon;
1824
1825                         e = wepent.activeweapon;
1826                         if(e.netname != "")
1827                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1828                         else if(slot == 0)
1829                                 localcmd("\ncl_hook_activeweapon none\n");
1830                 }
1831         }
1832
1833         // ALWAYS Clear Current Scene First
1834         clearscene();
1835
1836         setproperty(VF_ORIGIN, view_origin);
1837         setproperty(VF_ANGLES, view_angles);
1838
1839         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1840         setproperty(VF_SIZE, vf_size);
1841         setproperty(VF_MIN, vf_min);
1842
1843         // Assign Standard Viewflags
1844         // Draw the World (and sky)
1845         setproperty(VF_DRAWWORLD, 1);
1846
1847         // Set the console size vars
1848         vid_conwidth = autocvar_vid_conwidth;
1849         vid_conheight = autocvar_vid_conheight;
1850         vid_pixelheight = autocvar_vid_pixelheight;
1851
1852         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1853         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1854         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1855
1856         if(camera_active) // Camera for demo playback
1857         {
1858                 if(autocvar_camera_enable)
1859                         CSQC_Demo_Camera();
1860                 else
1861                 {
1862                         cvar_set("chase_active", ftos(chase_active_backup));
1863                         cvar_set("cl_demo_mousegrab", "0");
1864                         camera_active = false;
1865                 }
1866         }
1867         else
1868         {
1869 #ifdef CAMERATEST
1870                 if(autocvar_camera_enable)
1871 #else
1872                 if(autocvar_camera_enable && isdemo())
1873 #endif
1874                 {
1875                         // Enable required Darkplaces cvars
1876                         chase_active_backup = autocvar_chase_active;
1877                         cvar_set("chase_active", "2");
1878                         cvar_set("cl_demo_mousegrab", "1");
1879                         camera_active = true;
1880                         camera_mode = false;
1881                 }
1882         }
1883
1884         // Draw the Crosshair
1885         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1886
1887         // Draw the Engine Status Bar (the default Quake HUD)
1888         setproperty(VF_DRAWENGINESBAR, 0);
1889
1890         // Update the mouse position
1891         /*
1892            mousepos_x = vid_conwidth;
1893            mousepos_y = vid_conheight;
1894            mousepos = mousepos*0.5 + getmousepos();
1895          */
1896
1897         IL_EACH(g_drawables, it.draw, it.draw(it));
1898
1899         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1900         renderscene();
1901
1902         // now switch to 2D drawing mode by calling a 2D drawing function
1903         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1904         // next R_RenderScene call
1905         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1906
1907         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1908         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1909         {
1910                 // apply night vision effect
1911                 vector tc_00, tc_01, tc_10, tc_11;
1912                 vector rgb = '0 0 0';
1913
1914                 if(!nightvision_noise)
1915                 {
1916                         nightvision_noise = new(nightvision_noise);
1917                 }
1918                 if(!nightvision_noise2)
1919                 {
1920                         nightvision_noise2 = new(nightvision_noise2);
1921                 }
1922
1923                 // color tint in yellow
1924                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1925
1926                 // draw BG
1927                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1928                 rgb = '1 1 1';
1929                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1930                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1931                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1932                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1933                 tc_11 = tc_01 + tc_10 - tc_00;
1934                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1935                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1936                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1937                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1938                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1939                 R_EndPolygon();
1940
1941                 // draw FG
1942                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1943                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1944                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1945                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1946                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1947                 tc_11 = tc_01 + tc_10 - tc_00;
1948                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1949                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1950                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1951                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1952                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1953                 R_EndPolygon();
1954         }
1955
1956         if(autocvar_cl_reticle)
1957         {
1958                 string reticle_image = string_null;
1959                 bool wep_zoomed = false;
1960                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1961                 {
1962                         entity wepe = viewmodels[slot];
1963                         Weapon wep = wepe.activeweapon;
1964                         if(wep != WEP_Null && wep.wr_zoom)
1965                         {
1966                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1967                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
1968                                         reticle_image = wep.w_reticle;
1969                                 wep_zoomed += do_zoom;
1970                         }
1971                 }
1972                 // Draw the aiming reticle for weapons that use it
1973                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1974                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1975                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1976                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1977                 {
1978                         // no zoom reticle while dead
1979                         reticle_type = 0;
1980                 }
1981                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1982                 {
1983                         if(reticle_image) { reticle_type = 2; }
1984                         else { reticle_type = 0; }
1985                 }
1986                 else if(button_zoom || zoomscript_caught)
1987                 {
1988                         // normal zoom
1989                         reticle_type = 1;
1990                 }
1991
1992                 if(reticle_type)
1993                 {
1994                         if(autocvar_cl_reticle_stretch)
1995                         {
1996                                 reticle_size.x = vid_conwidth;
1997                                 reticle_size.y = vid_conheight;
1998                                 reticle_pos.x = 0;
1999                                 reticle_pos.y = 0;
2000                         }
2001                         else
2002                         {
2003                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2004                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2005                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2006                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2007                         }
2008
2009                         if(zoomscript_caught)
2010                                 f = 1;
2011                         else
2012                                 f = current_zoomfraction;
2013
2014                         if(f)
2015                         {
2016                                 switch(reticle_type)
2017                                 {
2018                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2019                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2020                                 }
2021                         }
2022                 }
2023         }
2024         else
2025         {
2026                 if(reticle_type != 0) { reticle_type = 0; }
2027         }
2028
2029
2030         // improved polyblend
2031         if(autocvar_hud_contents)
2032         {
2033                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2034                 vector liquidcolor;
2035
2036                 switch(pointcontents(view_origin))
2037                 {
2038                         case CONTENT_WATER:
2039                                 liquidalpha = autocvar_hud_contents_water_alpha;
2040                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2041                                 incontent = 1;
2042                                 break;
2043
2044                         case CONTENT_LAVA:
2045                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2046                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2047                                 incontent = 1;
2048                                 break;
2049
2050                         case CONTENT_SLIME:
2051                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2052                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2053                                 incontent = 1;
2054                                 break;
2055
2056                         default:
2057                                 liquidalpha = 0;
2058                                 liquidcolor = '0 0 0';
2059                                 incontent = 0;
2060                                 break;
2061                 }
2062
2063                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2064                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2065                         contentfadetime = autocvar_hud_contents_fadeintime;
2066                         liquidalpha_prev = liquidalpha;
2067                         liquidcolor_prev = liquidcolor;
2068                 }
2069                 else
2070                         contentfadetime = autocvar_hud_contents_fadeouttime;
2071
2072                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2073                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2074
2075                 if(contentavgalpha)
2076                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2077
2078                 if(autocvar_hud_postprocessing)
2079                 {
2080                         if(autocvar_hud_contents_blur && contentavgalpha)
2081                         {
2082                                 content_blurpostprocess.x = 1;
2083                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2084                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2085                         }
2086                         else
2087                         {
2088                                 content_blurpostprocess.x = 0;
2089                                 content_blurpostprocess.y = 0;
2090                                 content_blurpostprocess.z = 0;
2091                         }
2092                 }
2093         }
2094
2095         if(autocvar_hud_damage && !STAT(FROZEN))
2096         {
2097                 splash_size.x = max(vid_conwidth, vid_conheight);
2098                 splash_size.y = max(vid_conwidth, vid_conheight);
2099                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2100                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2101
2102                 float myhealth_flash_temp;
2103                 myhealth = STAT(HEALTH);
2104
2105                 // fade out
2106                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2107                 // add new damage
2108                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2109
2110                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2111                 pain_threshold = autocvar_hud_damage_pain_threshold;
2112                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2113                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2114
2115                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2116                 {
2117                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2118                 }
2119
2120                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2121
2122                 if(myhealth_prev < 1)
2123                 {
2124                         if(myhealth >= 1)
2125                         {
2126                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2127                                 myhealth_flash_temp = 0;
2128                         }
2129                         else
2130                         {
2131                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2132                         }
2133                 }
2134
2135                 if(spectatee_status == -1 || intermission)
2136                 {
2137                         myhealth_flash = 0; // observing, or match ended
2138                         myhealth_flash_temp = 0;
2139                 }
2140
2141                 myhealth_prev = myhealth;
2142
2143                 // IDEA: change damage color/picture based on player model for robot/alien species?
2144                 // pro: matches model better
2145                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2146                 // maybe different reddish pics?
2147                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2148                 {
2149                         if(autocvar_cl_gentle_damage == 2)
2150                         {
2151                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2152                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2153                         }
2154                         else
2155                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2156
2157                         if(myhealth_flash_temp > 0)
2158                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2159                 }
2160                 else if(myhealth_flash_temp > 0)
2161                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2162
2163                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2164                 {
2165                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2166                         {
2167                                 damage_blurpostprocess.x = 1;
2168                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2169                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2170                         }
2171                         else
2172                         {
2173                                 damage_blurpostprocess.x = 0;
2174                                 damage_blurpostprocess.y = 0;
2175                                 damage_blurpostprocess.z = 0;
2176                         }
2177                 }
2178         }
2179
2180         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2181         float e2 = (autocvar_hud_powerup != 0);
2182         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2183         {
2184                 // enable or disable rendering types if they are used or not
2185                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2186                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2187
2188                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2189                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2190                 {
2191                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2192                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2193                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2194                         {
2195                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2196                                 old_blurradius = blurradius;
2197                                 old_bluralpha = bluralpha;
2198                         }
2199                 }
2200                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2201                 {
2202                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2203                         old_blurradius = 0;
2204                         old_bluralpha = 0;
2205                 }
2206
2207                 // edge detection postprocess handling done second (used by hud_powerup)
2208                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2209                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2210                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2211
2212                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2213
2214                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2215                 {
2216                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2217                         {
2218                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2219                                 old_sharpen_intensity = sharpen_intensity;
2220                         }
2221                 }
2222                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2223                 {
2224                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2225                         old_sharpen_intensity = 0;
2226                 }
2227
2228                 if(cvar("r_glsl_postprocess") == 0)
2229                         cvar_set("r_glsl_postprocess", "2");
2230         }
2231         else if(cvar("r_glsl_postprocess") == 2)
2232                 cvar_set("r_glsl_postprocess", "0");
2233
2234         /*if(gametype == MAPINFO_TYPE_CTF)
2235           {
2236           ctf_view();
2237           } else */
2238
2239         // draw 2D entities
2240         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2241         Draw_ShowNames_All();
2242         Debug_Draw();
2243
2244         scoreboard_active = Scoreboard_WouldDraw();
2245
2246         HUD_Draw(this); // this parameter for deep vehicle function
2247
2248         if(NextFrameCommand)
2249         {
2250                 localcmd("\n", NextFrameCommand, "\n");
2251                 NextFrameCommand = string_null;
2252         }
2253
2254         // we must do this check AFTER a frame was rendered, or it won't work
2255         if(cs_project_is_b0rked == 0)
2256         {
2257                 string w0, h0;
2258                 w0 = ftos(autocvar_vid_conwidth);
2259                 h0 = ftos(autocvar_vid_conheight);
2260                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2261                 //setproperty(VF_FOV, '90 90 0');
2262                 setproperty(VF_ORIGIN, '0 0 0');
2263                 setproperty(VF_ANGLES, '0 0 0');
2264                 setproperty(VF_PERSPECTIVE, 1);
2265                 makevectors('0 0 0');
2266                 vector v1, v2;
2267                 cvar_set("vid_conwidth", "800");
2268                 cvar_set("vid_conheight", "600");
2269                 v1 = cs_project(v_forward);
2270                 cvar_set("vid_conwidth", "640");
2271                 cvar_set("vid_conheight", "480");
2272                 v2 = cs_project(v_forward);
2273                 if(v1 == v2)
2274                         cs_project_is_b0rked = 1;
2275                 else
2276                         cs_project_is_b0rked = -1;
2277                 cvar_set("vid_conwidth", w0);
2278                 cvar_set("vid_conheight", h0);
2279         }
2280
2281         if(autocvar__hud_configure)
2282                 HUD_Panel_Mouse();
2283         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2284                 HUD_Minigame_Mouse();
2285         else if(QuickMenu_IsOpened())
2286                 QuickMenu_Mouse();
2287         else
2288                 HUD_Radar_Mouse();
2289
2290         cl_notice_run();
2291         unpause_update();
2292         Net_Flush();
2293
2294         // let's reset the view back to normal for the end
2295         setproperty(VF_MIN, '0 0 0');
2296         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2297
2298         IL_ENDFRAME();
2299 }
2300
2301
2302 // following vectors must be global to allow seamless switching between camera modes
2303 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2304 void CSQC_Demo_Camera()
2305 {
2306         float speed, attenuation, dimensions;
2307         vector tmp, delta;
2308
2309         if( autocvar_camera_reset || !camera_mode )
2310         {
2311                 camera_offset = '0 0 0';
2312                 current_angles = '0 0 0';
2313                 camera_direction = '0 0 0';
2314                 camera_offset.z += 30;
2315                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2316                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2317                 current_origin = view_origin;
2318                 current_camera_offset  = camera_offset;
2319                 cvar_set("camera_reset", "0");
2320                 camera_mode = CAMERA_CHASE;
2321         }
2322
2323         // Camera angles
2324         if( camera_roll )
2325                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2326
2327         if(autocvar_camera_look_player)
2328         {
2329                 vector dir;
2330                 float n;
2331
2332                 dir = normalize(view_origin - current_position);
2333                 n = mouse_angles.z;
2334                 mouse_angles = vectoangles(dir);
2335                 mouse_angles.x = mouse_angles.x * -1;
2336                 mouse_angles.z = n;
2337         }
2338         else
2339         {
2340                 tmp = getmousepos() * 0.1;
2341                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2342                 {
2343                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2344                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2345                 }
2346         }
2347
2348         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2349         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2350         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2351         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2352
2353         // Fix difference when angles don't have the same sign
2354         delta = '0 0 0';
2355         if(mouse_angles.y < -60 && current_angles.y > 60)
2356                 delta = '0 360 0';
2357         if(mouse_angles.y > 60 && current_angles.y < -60)
2358                 delta = '0 -360 0';
2359
2360         if(autocvar_camera_look_player)
2361                 attenuation = autocvar_camera_look_attenuation;
2362         else
2363                 attenuation = autocvar_camera_speed_attenuation;
2364
2365         attenuation = 1 / max(1, attenuation);
2366         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2367
2368         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2369         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2370         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2371         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2372
2373         // Camera position
2374         tmp = '0 0 0';
2375         dimensions = 0;
2376
2377         if( camera_direction.x )
2378         {
2379                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2380                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2381                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2382                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2383                 ++dimensions;
2384         }
2385
2386         if( camera_direction.y )
2387         {
2388                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2389                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2390                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2391                 ++dimensions;
2392         }
2393
2394         if( camera_direction.z )
2395         {
2396                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2397                 ++dimensions;
2398         }
2399
2400         if(autocvar_camera_free)
2401                 speed = autocvar_camera_speed_free;
2402         else
2403                 speed = autocvar_camera_speed_chase;
2404
2405         if(dimensions)
2406         {
2407                 speed = speed * sqrt(1 / dimensions);
2408                 camera_offset += tmp * speed;
2409         }
2410
2411         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2412
2413         // Camera modes
2414         if( autocvar_camera_free )
2415         {
2416                 if ( camera_mode == CAMERA_CHASE )
2417                 {
2418                         current_camera_offset = current_origin + current_camera_offset;
2419                         camera_offset = current_origin + camera_offset;
2420                 }
2421
2422                 camera_mode = CAMERA_FREE;
2423                 current_position = current_camera_offset;
2424         }
2425         else
2426         {
2427                 if ( camera_mode == CAMERA_FREE )
2428                 {
2429                         current_origin = view_origin;
2430                         camera_offset = camera_offset - current_origin;
2431                         current_camera_offset = current_camera_offset - current_origin;
2432                 }
2433
2434                 camera_mode = CAMERA_CHASE;
2435
2436                 if(autocvar_camera_chase_smoothly)
2437                         current_origin += (view_origin - current_origin) * attenuation;
2438                 else
2439                         current_origin = view_origin;
2440
2441                 current_position = current_origin + current_camera_offset;
2442         }
2443
2444         setproperty(VF_ANGLES, current_angles);
2445         setproperty(VF_ORIGIN, current_position);
2446 }