qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha = 1;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward, right, up;
 137                 MAKE_VECTORS(view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward, right, up;
 163                 MAKE_VECTORS(view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         int wepskin = this.m_skin;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.skin = wepskin;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         if(a >= 0)
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 float showfps_prevfps;
 369 float showfps_prevfps_time;
 370 int showfps_framecounter;
 371
 372 void fpscounter_update()
 373 {
 374         if(!STAT(SHOWFPS))
 375                 return;
 376
 377         float currentTime = gettime(GETTIME_REALTIME);
 378         showfps_framecounter += 1;
 379         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 380         {
 381                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 382                 showfps_framecounter = 0;
 383                 showfps_prevfps_time = currentTime;
 384
 385                 int channel = MSG_C2S;
 386                 WriteHeader(channel, fpsreport);
 387                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 388         }
 389 }
 390
 391 STATIC_INIT(fpscounter_init)
 392 {
 393         float currentTime = gettime(GETTIME_REALTIME);
 394         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 395 }
 396
 397 float avgspeed;
 398 vector GetCurrentFov(float fov)
 399 {
 400         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 401         float velocityzoom, curspeed;
 402         vector v;
 403
 404         zoomsensitivity = autocvar_cl_zoomsensitivity;
 405         zoomfactor = autocvar_cl_zoomfactor;
 406         if(zoomfactor < 1 || zoomfactor > 30)
 407                 zoomfactor = 2.5;
 408         zoomspeed = autocvar_cl_zoomspeed;
 409         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 410                 zoomspeed = 3.5;
 411
 412         zoomdir = button_zoom;
 413
 414         if(hud == HUD_NORMAL && !spectatee_status)
 415         {
 416                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 417                 {
 418                         entity wepent = viewmodels[slot];
 419                         if(wepent.switchweapon != wepent.activeweapon)
 420                                 continue;
 421                         Weapon wep = wepent.activeweapon;
 422                         if(wep != WEP_Null && wep.wr_zoomdir)
 423                         {
 424                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 425                                 zoomdir += do_zoom;
 426                         }
 427                 }
 428         }
 429         if(spectatee_status > 0 || isdemo())
 430         {
 431                 if(spectatorbutton_zoom)
 432                 {
 433                         if(zoomdir)
 434                                 zoomdir = 0;
 435                         else
 436                                 zoomdir = 1;
 437                 }
 438                 // fteqcc failed twice here already, don't optimize this
 439         }
 440
 441         if(zoomdir) { zoomin_effect = 0; }
 442
 443         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 444         {
 445                 current_viewzoom = 1;
 446         }
 447         else if (camera_active)
 448         {
 449                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 450         }
 451         else if(autocvar_cl_spawnzoom && zoomin_effect)
 452         {
 453                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 454
 455                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 456                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 457                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 458         }
 459         else
 460         {
 461                 if(zoomspeed < 0) // instant zoom
 462                 {
 463                         if(zoomdir)
 464                                 current_viewzoom = 1 / zoomfactor;
 465                         else
 466                                 current_viewzoom = 1;
 467                 }
 468                 else
 469                 {
 470                         if(zoomdir)
 471                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 472                         else
 473                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 474                 }
 475         }
 476
 477         if(almost_equals(current_viewzoom, 1))
 478                 current_zoomfraction = 0;
 479         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 480                 current_zoomfraction = 1;
 481         else
 482                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 483
 484         if(zoomsensitivity < 1)
 485                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 486         else
 487                 setsensitivityscale(1);
 488
 489         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 490         {
 491                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 492                         curspeed = 0;
 493                 else
 494                 {
 495                         vector forward, right, up;
 496                         MAKE_VECTORS(view_angles, forward, right, up);
 497                         v = pmove_vel;
 498                         if(csqcplayer)
 499                                 v = csqcplayer.velocity;
 500
 501                         switch(autocvar_cl_velocityzoom_type)
 502                         {
 503                                 case 3: curspeed = max(0, forward * v); break;
 504                                 case 2: curspeed = (forward * v); break;
 505                                 case 1: default: curspeed = vlen(v); break;
 506                         }
 507                 }
 508
 509                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 510                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 511                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 512
 513                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 514         }
 515         else
 516                 velocityzoom = 1;
 517
 518         float frustumx, frustumy, fovx, fovy;
 519         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 520         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 521         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 522         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 523
 524         return '1 0 0' * fovx + '0 1 0' * fovy;
 525 }
 526
 527 vector GetViewLocationFOV(float fov)
 528 {
 529         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 530         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 531         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 532         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 533         return '1 0 0' * fovx + '0 1 0' * fovy;
 534 }
 535
 536 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 537 {
 538         float fovx, fovy;
 539         float width = (ov_worldmax.x - ov_worldmin.x);
 540         float height = (ov_worldmax.y - ov_worldmin.y);
 541         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 542         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 543         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 544         return '1 0 0' * fovx + '0 1 0' * fovy;
 545 }
 546
 547 // this function must match W_SetupShot!
 548 float zoomscript_caught;
 549
 550 bool minigame_wasactive;
 551
 552 vector wcross_origin;
 553 float wcross_scale_prev, wcross_alpha_prev;
 554 vector wcross_color_prev;
 555 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 556 vector wcross_color_goal_prev;
 557 float wcross_changedonetime;
 558
 559 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 560 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 561 float wcross_name_changestarttime, wcross_name_changedonetime;
 562 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 563
 564 float wcross_ring_prev;
 565
 566 entity trueaim;
 567 entity trueaim_rifle;
 568
 569 const float SHOTTYPE_HITTEAM = 1;
 570 const float SHOTTYPE_HITOBSTRUCTION = 2;
 571 const float SHOTTYPE_HITWORLD = 3;
 572 const float SHOTTYPE_HITENEMY = 4;
 573
 574 void TrueAim_Init()
 575 {
 576         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 577         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 578 }
 579
 580 float EnemyHitCheck()
 581 {
 582         float t, n;
 583         wcross_origin = project_3d_to_2d(trace_endpos);
 584         wcross_origin.z = 0;
 585         if(trace_ent)
 586                 n = trace_ent.entnum;
 587         else
 588                 n = trace_networkentity;
 589         if(n < 1)
 590                 return SHOTTYPE_HITWORLD;
 591         if(n > maxclients)
 592                 return SHOTTYPE_HITWORLD;
 593         t = entcs_GetTeam(n - 1);
 594         if(teamplay)
 595                 if(t == myteam)
 596                         return SHOTTYPE_HITTEAM;
 597         if(t == NUM_SPECTATOR)
 598                 return SHOTTYPE_HITWORLD;
 599         return SHOTTYPE_HITENEMY;
 600 }
 601
 602 float TrueAimCheck(entity wepent)
 603 {
 604         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
 605                 return SHOTTYPE_HITWORLD;
 606
 607         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 608         vector vecs, trueaimpoint, w_shotorg;
 609         vector mi, ma, dv;
 610         float shottype;
 611         entity ta;
 612         float mv;
 613
 614         mi = ma = '0 0 0';
 615         ta = trueaim;
 616         mv = MOVE_NOMONSTERS;
 617
 618         switch(wepent.activeweapon) // WEAPONTODO
 619         {
 620                 case WEP_VORTEX:
 621                 case WEP_OVERKILL_NEX:
 622                 case WEP_VAPORIZER:
 623                         mv = MOVE_NORMAL;
 624                         break;
 625                 case WEP_RIFLE:
 626                         ta = trueaim_rifle;
 627                         mv = MOVE_NORMAL;
 628                         if(zoomscript_caught)
 629                         {
 630                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 631                                 return EnemyHitCheck();
 632                         }
 633                         break;
 634                 case WEP_DEVASTATOR: // projectile has a size!
 635                         mi = '-3 -3 -3';
 636                         ma = '3 3 3';
 637                         break;
 638                 case WEP_FIREBALL: // projectile has a size!
 639                         mi = '-16 -16 -16';
 640                         ma = '16 16 16';
 641                         break;
 642                 case WEP_SEEKER: // projectile has a size!
 643                         mi = '-2 -2 -2';
 644                         ma = '2 2 2';
 645                         break;
 646                 case WEP_ELECTRO: // projectile has a size!
 647                         mi = '0 0 -3';
 648                         ma = '0 0 -3';
 649                         break;
 650         }
 651
 652         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 653
 654         vecs = decompressShotOrigin(STAT(SHOTORG));
 655
 656         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 657         trueaimpoint = trace_endpos;
 658         // move trueaimpoint a little bit forward to make the final tracebox reliable
 659         // since it sometimes doesn't reach a teammate by a hair
 660         trueaimpoint += view_forward;
 661
 662         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 663                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 664
 665         if(vecs.x > 0)
 666                 vecs.y = -vecs.y;
 667         else
 668                 vecs = '0 0 0';
 669
 670         dv = view_right * vecs.y + view_up * vecs.z;
 671         w_shotorg = traceorigin + dv;
 672
 673         // now move the vecs forward as much as requested if possible
 674         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 675         w_shotorg = trace_endpos - view_forward * nudge;
 676
 677         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 678         shottype = EnemyHitCheck();
 679         if(shottype != SHOTTYPE_HITWORLD)
 680                 return shottype;
 681
 682 #if 0
 683         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 684         // or rather, I know why, but see no fix
 685         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 686                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 687                 return SHOTTYPE_HITOBSTRUCTION;
 688 #endif
 689
 690         return SHOTTYPE_HITWORLD;
 691 }
 692
 693 float camera_mode;
 694 const float CAMERA_FREE = 1;
 695 const float CAMERA_CHASE = 2;
 696 float reticle_type;
 697 string NextFrameCommand;
 698
 699 vector freeze_org, freeze_ang;
 700 entity nightvision_noise, nightvision_noise2;
 701
 702 const float MAX_TIME_DIFF = 5;
 703 float pickup_crosshair_time, pickup_crosshair_size;
 704 float hitindication_crosshair_size;
 705 float use_vortex_chargepool;
 706
 707 float myhealth, myhealth_prev;
 708 float myhealth_flash;
 709
 710 float old_blurradius, old_bluralpha;
 711 float old_sharpen_intensity;
 712
 713 vector myhealth_gentlergb;
 714
 715 float contentavgalpha, liquidalpha_prev;
 716 vector liquidcolor_prev;
 717
 718 float eventchase_current_distance;
 719 float eventchase_running;
 720 int WantEventchase(entity this, bool want_vehiclechase)
 721 {
 722         if(autocvar_cl_orthoview)
 723                 return 0;
 724         if(STAT(GAME_STOPPED) || intermission)
 725                 return 1;
 726         if(this.viewloc)
 727                 return 1;
 728         if(spectatee_status >= 0)
 729         {
 730                 if(want_vehiclechase)
 731                         return 1;
 732                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 733                         return 1;
 734                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 735                         return 1;
 736                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 737                 {
 738                         if(autocvar_cl_eventchase_death == 2)
 739                         {
 740                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 741                                 if(this.velocity == '0 0 0' || eventchase_running)
 742                                         return 1;
 743                         }
 744                         else return 1;
 745                 }
 746                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 747                 {
 748                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 749                                 return 1;
 750                         else if (eventchase_running)
 751                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 752                 }
 753         }
 754         return 0;
 755 }
 756
 757 void View_EventChase(entity this)
 758 {
 759         // event chase camera
 760         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 761         {
 762                 if(STAT(CAMERA_SPECTATOR))
 763                 {
 764                         if(spectatee_status > 0)
 765                         {
 766                                 if(!autocvar_chase_active)
 767                                 {
 768                                         cvar_set("chase_active", "-2");
 769                                         return;
 770                                 }
 771                         }
 772                         else if(autocvar_chase_active == -2)
 773                                 cvar_set("chase_active", "0");
 774
 775                         if(autocvar_chase_active == -2)
 776                                 return;
 777                 }
 778                 else if(autocvar_chase_active == -2)
 779                         cvar_set("chase_active", "0");
 780
 781                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
 782
 783                 float vehicle_viewdist = 0;
 784                 vector vehicle_viewofs = '0 0 0';
 785
 786                 if(vehicle_chase)
 787                 {
 788                         if(hud != HUD_BUMBLEBEE_GUN)
 789                         {
 790                                 Vehicle info = Vehicles_from(hud);
 791                                 vehicle_viewdist = info.height;
 792                                 vehicle_viewofs = info.view_ofs;
 793                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
 794                                         vehicle_chase = false;
 795                         }
 796                         else
 797                                 vehicle_chase = false;
 798                 }
 799
 800                 int eventchase = WantEventchase(this, vehicle_chase);
 801                 if (eventchase)
 802                 {
 803                         vector current_view_origin_override = '0 0 0';
 804                         vector view_offset_override = '0 0 0';
 805                         float chase_distance_override = 0;
 806                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
 807                         if(custom_eventchase)
 808                         {
 809                                 current_view_origin_override = M_ARGV(0, vector);
 810                                 view_offset_override = M_ARGV(1, vector);
 811                                 chase_distance_override = M_ARGV(0, float);
 812                         }
 813                         eventchase_running = true;
 814
 815                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 816                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 817                         if (custom_eventchase)
 818                                 current_view_origin = current_view_origin_override;
 819
 820                         // detect maximum viewoffset and use it
 821                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 822                         if(vehicle_chase)
 823                         {
 824                                 if(vehicle_viewofs)
 825                                         view_offset = vehicle_viewofs;
 826                                 else
 827                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
 828                         }
 829                         if (custom_eventchase)
 830                                 view_offset = view_offset_override;
 831
 832                         if(view_offset)
 833                         {
 834                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
 835                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 836                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
 837                         }
 838
 839                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 840                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 841                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 842                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 843
 844                         // make the camera smooth back
 845                         float chase_distance = autocvar_cl_eventchase_distance;
 846                         if(vehicle_chase)
 847                         {
 848                                 if(vehicle_viewofs)
 849                                         chase_distance = vehicle_viewdist;
 850                                 else
 851                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
 852                         }
 853                         if (custom_eventchase)
 854                                 chase_distance = chase_distance_override;
 855
 856                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 857                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 858                         else if(eventchase_current_distance != chase_distance)
 859                                 eventchase_current_distance = chase_distance;
 860
 861                         vector forward, right, up;
 862                         MAKE_VECTORS(view_angles, forward, right, up);
 863
 864                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 865                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
 866
 867                         // If the boxtrace fails, revert back to line tracing.
 868                         if(!this.viewloc)
 869                         if(trace_startsolid)
 870                         {
 871                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 872                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
 873                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
 874                         }
 875                         else { setproperty(VF_ORIGIN, trace_endpos); }
 876
 877                         if(!this.viewloc)
 878                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 879                 }
 880
 881                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 882                 {
 883                         eventchase_running = false;
 884                         cvar_set("chase_active", "0");
 885                         eventchase_current_distance = 0; // start from 0 next time
 886                 }
 887         }
 888         // workaround for camera stuck between player's legs when using chase_active 1
 889         // because the engine stops updating the chase_active camera when the game ends
 890         else if(intermission)
 891         {
 892                 cvar_settemp("chase_active", "-1");
 893                 eventchase_current_distance = 0;
 894         }
 895 }
 896
 897 void HUD_Crosshair_Vehicle(entity this)
 898 {
 899         if(hud != HUD_BUMBLEBEE_GUN)
 900         {
 901                 Vehicle info = Vehicles_from(hud);
 902                 info.vr_crosshair(info, this);
 903         }
 904 }
 905
 906 vector damage_blurpostprocess, content_blurpostprocess;
 907
 908 float unaccounted_damage = 0;
 909 void UpdateDamage()
 910 {
 911         // accumulate damage with each stat update
 912         static float damage_total_prev = 0;
 913         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 914         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 915         damage_total_prev = damage_total;
 916
 917         static float damage_dealt_time_prev = 0;
 918         float damage_dealt_time = STAT(HIT_TIME);
 919         if (damage_dealt_time != damage_dealt_time_prev)
 920         {
 921                 unaccounted_damage += unaccounted_damage_new;
 922                 //LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 923         }
 924         damage_dealt_time_prev = damage_dealt_time;
 925
 926         // prevent hitsound when switching spectatee
 927         static float spectatee_status_prev = 0;
 928         if (spectatee_status != spectatee_status_prev)
 929                 unaccounted_damage = 0;
 930         spectatee_status_prev = spectatee_status;
 931 }
 932
 933 void HitSound()
 934 {
 935         // varying sound pitch
 936
 937         bool have_arc = false;
 938         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 939         {
 940                 entity wepent = viewmodels[slot];
 941
 942                 if(wepent.activeweapon == WEP_ARC)
 943                         have_arc = true;
 944         }
 945
 946         static float hitsound_time_prev = 0;
 947         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 948         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 949         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 950         {
 951                 if (autocvar_cl_hitsound && unaccounted_damage)
 952                 {
 953                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 954                         float a = autocvar_cl_hitsound_max_pitch;
 955                         float b = autocvar_cl_hitsound_min_pitch;
 956                         float c = autocvar_cl_hitsound_nom_damage;
 957                         float d = unaccounted_damage;
 958                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 959
 960                         // if sound variation is disabled, set pitch_shift to 1
 961                         if (autocvar_cl_hitsound == 1)
 962                                 pitch_shift = 1;
 963
 964                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 965                         if (autocvar_cl_hitsound == 3)
 966                         {
 967                                 float mirror_value = (a-b)/2 + b;
 968                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 969                         }
 970
 971                         //LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 972
 973                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 974                         // todo: normalize sound pressure levels? seems unnecessary
 975
 976                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 977                 }
 978                 unaccounted_damage = 0;
 979                 hitsound_time_prev = time;
 980         }
 981
 982         static float typehit_time_prev = 0;
 983         float typehit_time = STAT(TYPEHIT_TIME);
 984         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 985         {
 986                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 987                 typehit_time_prev = typehit_time;
 988         }
 989
 990         static float kill_time_prev = 0;
 991         float kill_time = STAT(KILL_TIME);
 992         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 993         {
 994                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 995                 kill_time_prev = kill_time;
 996         }
 997 }
 998
 999 vector crosshair_getcolor(entity this, float health_stat)
1000 {
1001         static float rainbow_last_flicker;
1002         static vector rainbow_prev_color;
1003         vector wcross_color = '0 0 0';
1004         switch(autocvar_crosshair_color_special)
1005         {
1006                 case 1: // crosshair_color_per_weapon
1007                 {
1008                         if(this != WEP_Null && hud == HUD_NORMAL)
1009                         {
1010                                 wcross_color = this.wpcolor;
1011                                 break;
1012                         }
1013                         else { goto normalcolor; }
1014                 }
1015
1016                 case 2: // crosshair_color_by_health
1017                 {
1018                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
1019                         float hp = floor(v.x + 1);
1020
1021                         //x = red
1022                         //y = green
1023                         //z = blue
1024
1025                         wcross_color.z = 0;
1026
1027                         if(hp > 200)
1028                         {
1029                                 wcross_color.x = 0;
1030                                 wcross_color.y = 1;
1031                         }
1032                         else if(hp > 150)
1033                         {
1034                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
1035                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
1036                         }
1037                         else if(hp > 100)
1038                         {
1039                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
1040                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
1041                                 wcross_color.z = 1 - (hp-100)*0.02;
1042                         }
1043                         else if(hp > 50)
1044                         {
1045                                 wcross_color.x = 1;
1046                                 wcross_color.y = 1;
1047                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
1048                         }
1049                         else if(hp > 20)
1050                         {
1051                                 wcross_color.x = 1;
1052                                 wcross_color.y = (hp-20)*90/27/100;
1053                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
1054                         }
1055                         else
1056                         {
1057                                 wcross_color.x = 1;
1058                                 wcross_color.y = 0;
1059                         }
1060                         break;
1061                 }
1062
1063                 case 3: // crosshair_color_rainbow
1064                 {
1065                         if(time >= rainbow_last_flicker)
1066                         {
1067                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1068                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1069                         }
1070                         wcross_color = rainbow_prev_color;
1071                         break;
1072                 }
1073 LABEL(normalcolor)
1074                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1075         }
1076
1077         return wcross_color;
1078 }
1079
1080 void HUD_Crosshair(entity this)
1081 {
1082         float f, i, j;
1083         vector v;
1084         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1085                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1086                 !HUD_MinigameMenu_IsOpened() )
1087         {
1088                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1089                         return;
1090
1091                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1092                         return;
1093
1094                 if (hud != HUD_NORMAL)
1095                 {
1096                         HUD_Crosshair_Vehicle(this);
1097                         return;
1098                 }
1099
1100                 string wcross_style;
1101                 float wcross_alpha, wcross_resolution;
1102                 wcross_style = autocvar_crosshair;
1103                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1104                         wcross_style = autocvar_crosshair_2d;
1105                 if (wcross_style == "0")
1106                         return;
1107                 wcross_resolution = autocvar_crosshair_size;
1108                 if (wcross_resolution == 0)
1109                         return;
1110                 wcross_alpha = autocvar_crosshair_alpha;
1111                 if (wcross_alpha == 0)
1112                         return;
1113
1114                 // TrueAim check
1115                 float shottype;
1116
1117                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1118                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1119                         wcross_origin = viewloc_mousepos;
1120                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
1121                 {
1122                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
1123                         if(csqcplayer && autocvar_crosshair_chase_playeralpha && autocvar_crosshair_chase_playeralpha < 1)
1124                         {
1125                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
1126                                 float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
1127                                 if(trace_ent == csqcplayer && STAT(HEALTH) > 0)
1128                                         csqcplayer.alpha = min(autocvar_crosshair_chase_playeralpha, myalpha);
1129                                 else
1130                                         csqcplayer.alpha = csqcplayer.m_alpha;
1131                         }
1132                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
1133                         wcross_origin = project_3d_to_2d(trace_endpos);
1134                 }
1135                 else
1136                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1137                 wcross_origin.z = 0;
1138                 if(autocvar_crosshair_hittest)
1139                 {
1140                         vector wcross_oldorigin;
1141                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1142                         wcross_oldorigin = wcross_origin;
1143                         shottype = TrueAimCheck(thiswep);
1144                         if(shottype == SHOTTYPE_HITWORLD)
1145                         {
1146                                 v = wcross_origin - wcross_oldorigin;
1147                                 v.x /= vid_conwidth;
1148                                 v.y /= vid_conheight;
1149                                 if(vdist(v, >, 0.01))
1150                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1151                         }
1152                         if(!autocvar_crosshair_hittest_showimpact)
1153                                 wcross_origin = wcross_oldorigin;
1154                 }
1155                 else
1156                         shottype = SHOTTYPE_HITWORLD;
1157
1158                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1159                 string wcross_name = "";
1160                 float wcross_scale, wcross_blur;
1161
1162         entity e = WEP_Null;
1163                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1164                 {
1165                         entity wepent = viewmodels[0]; // TODO: unhardcode
1166                         e = wepent.switchingweapon;
1167                         if(e)
1168                         {
1169                                 if(autocvar_crosshair_per_weapon)
1170                                 {
1171                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1172                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1173                                         //if (wcross_resolution == 0)
1174                                                 //return;
1175
1176                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1177                                         wcross_resolution *= e.w_crosshair_size;
1178                                         wcross_name = e.w_crosshair;
1179                                 }
1180                         }
1181                 }
1182
1183                 if(wcross_name == "")
1184                         wcross_name = strcat("gfx/crosshair", wcross_style);
1185
1186                 // MAIN CROSSHAIR COLOR DECISION
1187                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1188
1189                 if(autocvar_crosshair_effect_scalefade)
1190                 {
1191                         wcross_scale = wcross_resolution;
1192                         wcross_resolution = 1;
1193                 }
1194                 else
1195                 {
1196                         wcross_scale = 1;
1197                 }
1198
1199                 if(autocvar_crosshair_pickup)
1200                 {
1201                         float stat_pickup_time = STAT(LAST_PICKUP);
1202
1203                         if(pickup_crosshair_time < stat_pickup_time)
1204                         {
1205                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1206                                         pickup_crosshair_size = 1;
1207
1208                                 pickup_crosshair_time = stat_pickup_time;
1209                         }
1210
1211                         if(pickup_crosshair_size > 0)
1212                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1213                         else
1214                                 pickup_crosshair_size = 0;
1215
1216                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1217                 }
1218
1219                 // todo: make crosshair hit indication dependent on damage dealt
1220                 if(autocvar_crosshair_hitindication)
1221                 {
1222                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1223
1224                         if(unaccounted_damage)
1225                         {
1226                                 hitindication_crosshair_size = 1;
1227                         }
1228
1229                         if(hitindication_crosshair_size > 0)
1230                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1231                         else
1232                                 hitindication_crosshair_size = 0;
1233
1234                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1235                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1236                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1237                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1238                 }
1239
1240                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
1241                 // just show for teammates to give a sign that they're an invalid target
1242                 //if(shottype == SHOTTYPE_HITENEMY)
1243                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1244                 if(shottype == SHOTTYPE_HITTEAM)
1245                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1246
1247                 f = fabs(autocvar_crosshair_effect_time);
1248                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1249                 {
1250                         wcross_changedonetime = time + f;
1251                 }
1252                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1253                 {
1254                         wcross_name_changestarttime = time;
1255                         wcross_name_changedonetime = time + f;
1256                         if(wcross_name_goal_prev_prev)
1257                                 strunzone(wcross_name_goal_prev_prev);
1258                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1259                         wcross_name_goal_prev = strzone(wcross_name);
1260                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1261                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1262                         wcross_resolution_goal_prev = wcross_resolution;
1263                 }
1264
1265                 wcross_scale_goal_prev = wcross_scale;
1266                 wcross_alpha_goal_prev = wcross_alpha;
1267                 wcross_color_goal_prev = wcross_color;
1268
1269                 if(spectatee_status == 0 && (shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active)))
1270                 {
1271                         wcross_blur = 1;
1272                         wcross_alpha *= 0.75;
1273                 }
1274                 else
1275                         wcross_blur = 0;
1276                 // *_prev is at time-frametime
1277                 // * is at wcross_changedonetime+f
1278                 // what do we have at time?
1279                 if(time < wcross_changedonetime)
1280                 {
1281                         f = frametime / (wcross_changedonetime - time + frametime);
1282                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1283                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1284                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1285                 }
1286
1287                 wcross_scale_prev = wcross_scale;
1288                 wcross_alpha_prev = wcross_alpha;
1289                 wcross_color_prev = wcross_color;
1290
1291                 MUTATOR_CALLHOOK(UpdateCrosshair);
1292
1293                 wcross_scale *= 1 - autocvar__menu_alpha;
1294                 wcross_alpha *= 1 - autocvar__menu_alpha;
1295                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1296
1297                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1298                 {
1299                         // crosshair rings for weapon stats
1300                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1301                         {
1302                                 // declarations and stats
1303                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1304                                 string ring_image = string_null, ring_inner_image = string_null;
1305                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1306
1307                                 ring_scale = autocvar_crosshair_ring_size;
1308
1309                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1310
1311                                 int weapon_clipload = wepent.clip_load;
1312                                 int weapon_clipsize = wepent.clip_size;
1313
1314                                 float arc_heat = wepent.arc_heat_percent;
1315                                 float vcharge = wepent.vortex_charge;
1316                                 float vchargepool = wepent.vortex_chargepool_ammo;
1317                                 float oknex_charge_ = wepent.oknex_charge;
1318                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1319
1320                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1321                                         vortex_charge_movingavg = vcharge;
1322
1323                                 // handle the values
1324                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1325                                 {
1326                                         if (vchargepool || use_vortex_chargepool) {
1327                                                 use_vortex_chargepool = 1;
1328                                                 ring_inner_value = vchargepool;
1329                                         } else {
1330                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1331                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1332                                         }
1333
1334                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1335                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1336                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1337
1338                                         // draw the outer ring to show the current charge of the weapon
1339                                         ring_value = vcharge;
1340                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1341                                         ring_rgb = wcross_color;
1342                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1343                                 }
1344                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1345                                 {
1346                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1347                                                 use_vortex_chargepool = 1;
1348                                                 ring_inner_value = oknex_chargepool_;
1349                                         } else {
1350                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1351                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1352                                         }
1353
1354                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1355                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1356                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1357
1358                                         // draw the outer ring to show the current charge of the weapon
1359                                         ring_value = oknex_charge_;
1360                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1361                                         ring_rgb = wcross_color;
1362                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1363                                 }
1364                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1365                                 {
1366                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1367                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1368                                         ring_rgb = wcross_color;
1369                                         ring_image = "gfx/crosshair_ring.tga";
1370                                 }
1371                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1372                                 {
1373                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1374                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1375                                         ring_rgb = wcross_color;
1376                                         ring_image = "gfx/crosshair_ring.tga";
1377                                 }
1378                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1379                                 {
1380                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1381                                         ring_scale = autocvar_crosshair_ring_reload_size;
1382                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1383                                         ring_rgb = wcross_color;
1384
1385                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1386                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1387                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1388                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1389                                         else
1390                                                 ring_image = "gfx/crosshair_ring.tga";
1391                                 }
1392                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1393                                 {
1394                                         ring_value = arc_heat;
1395                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1396                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1397                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1398                                         ring_image = "gfx/crosshair_ring.tga";
1399                                 }
1400
1401                                 // if in weapon switch animation, fade ring out/in
1402                                 if(autocvar_crosshair_effect_time > 0)
1403                                 {
1404                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1405                                         if (f >= 1)
1406                                         {
1407                                                 wcross_ring_prev = ((ring_image) ? true : false);
1408                                         }
1409
1410                                         if(wcross_ring_prev)
1411                                         {
1412                                                 if(f < 1)
1413                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1414                                         }
1415                                         else
1416                                         {
1417                                                 if(f < 1)
1418                                                         ring_alpha *= bound(0, f, 1);
1419                                         }
1420                                 }
1421
1422                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1423                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1424
1425                                 if (ring_value)
1426                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1427                         }
1428
1429 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1430                         MACRO_BEGIN \
1431                                 vector scaled_sz = sz * wcross_size; \
1432                                 if(wcross_blur > 0) \
1433                                 { \
1434                                         for(i = -2; i <= 2; ++i) \
1435                                         for(j = -2; j <= 2; ++j) \
1436                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1437                                 } \
1438                                 else \
1439                                 { \
1440                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1441                                 } \
1442                         MACRO_END
1443
1444 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1445                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1446
1447 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1448                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1449
1450                         vector wcross_origin_save = wcross_origin;
1451                         wcross_origin += autocvar_crosshair_offset * wcross_scale;
1452                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1453                         {
1454                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1455                                 vector wcross_size_save = wcross_size;
1456                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1457                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1458                                 wcross_size = wcross_size_save;
1459                                 f = 1 - f;
1460                         }
1461                         else
1462                         {
1463                                 f = 1;
1464                         }
1465                         wcross_name_alpha_goal_prev = f;
1466
1467                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1468                         wcross_origin = wcross_origin_save;
1469
1470                         if(autocvar_crosshair_dot)
1471                         {
1472                                 vector wcross_color_old;
1473                                 wcross_color_old = wcross_color;
1474
1475                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1476                                         wcross_color = stov(autocvar_crosshair_dot_color);
1477
1478                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1479                                 // FIXME why don't we use wcross_alpha here?
1480                                 wcross_color = wcross_color_old;
1481                         }
1482                 }
1483         }
1484         else
1485         {
1486                 wcross_scale_prev = 0;
1487                 wcross_alpha_prev = 0;
1488                 wcross_scale_goal_prev = 0;
1489                 wcross_alpha_goal_prev = 0;
1490                 wcross_changedonetime = 0;
1491                 strfree(wcross_name_goal_prev);
1492                 strfree(wcross_name_goal_prev_prev);
1493                 wcross_name_changestarttime = 0;
1494                 wcross_name_changedonetime = 0;
1495                 wcross_name_alpha_goal_prev = 0;
1496                 wcross_name_alpha_goal_prev_prev = 0;
1497                 wcross_resolution_goal_prev = 0;
1498                 wcross_resolution_goal_prev_prev = 0;
1499         }
1500 }
1501
1502 const int MAX_SPECIALCOMMAND = 15;
1503 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1504 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1505 const float SPECIALCOMMAND_SPEED = 150;
1506 const float SPECIALCOMMAND_TURNSPEED = 2;
1507 const float SPECIALCOMMAND_SIZE = 0.025;
1508 const float SPECIALCOMMAND_CHANCE = 0.35;
1509 float sc_spawntime, sc_changetime;
1510 vector sc_color = '1 1 1';
1511 void SpecialCommand()
1512 {
1513         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1514                 return;
1515
1516         if(time >= sc_changetime)
1517         {
1518                 sc_changetime = time + 1;
1519                 sc_color = randomvec() * 1.5;
1520                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1521                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1522                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1523         }
1524         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1525
1526         if(!precache_pic("gfx/smile"))
1527                 return; // damn party poopers
1528
1529         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1530         {
1531                 vector slot = specialcommand_slots[j];
1532                 if(slot.y)
1533                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1534                 //if(slot.z)
1535                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1536                 if(slot.y >= vid_conheight)
1537                         slot = '0 0 0';
1538
1539                 if(slot == '0 0 0')
1540                 {
1541                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1542                         {
1543                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1544                                 slot.y = 1; // start it off 0 so we can use it
1545                                 slot.z = floor(random() * Weapons_MAX);
1546                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1547                                 vector newcolor = randomvec() * 2;
1548                                 newcolor.x = bound(0.4, newcolor.x, 1);
1549                                 newcolor.y = bound(0.4, newcolor.y, 1);
1550                                 newcolor.z = bound(0.4, newcolor.z, 1);
1551                                 specialcommand_colors[j] = newcolor;
1552                         }
1553                 }
1554                 else
1555                 {
1556                         vector splash_size = '0 0 0';
1557                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1558                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1559                         entity wep = Weapons_from(slot.z);
1560                         if(wep == WEP_Null)
1561                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1562                         else
1563                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1564                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1565                 }
1566
1567                 specialcommand_slots[j] = slot;
1568         }
1569 }
1570
1571 void HUD_Draw(entity this)
1572 {
1573         // if we don't know gametype and scores yet avoid drawing the scoreboard
1574         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1575         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1576         // cl_deathscoreboard would show the scoreboard and so on
1577         if(!gametype)
1578                 return;
1579
1580         Hud_Dynamic_Frame();
1581
1582         if(!intermission)
1583         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1584         {
1585                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1586         }
1587         else if(STAT(FROZEN))
1588         {
1589                 vector col = '0.25 0.90 1';
1590                 if(STAT(REVIVE_PROGRESS))
1591                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1592                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1593         }
1594
1595         HUD_Scale_Enable();
1596         if(!intermission)
1597         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1598         {
1599                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1600                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1601                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1602         }
1603         else if(STAT(CAPTURE_PROGRESS))
1604         {
1605                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1606                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1607         }
1608         else if(STAT(REVIVE_PROGRESS))
1609         {
1610                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1611                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1612         }
1613         HUD_Scale_Disable();
1614
1615         if(autocvar_r_letterbox == 0)
1616                 if(autocvar_viewsize < 120)
1617                 {
1618                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1619                                 Accuracy_LoadLevels();
1620
1621                         HUD_Main();
1622                         HUD_Scale_Disable();
1623                 }
1624
1625         // crosshair goes VERY LAST
1626         SpecialCommand();
1627         UpdateDamage();
1628         HUD_Crosshair(this);
1629         HitSound();
1630 }
1631
1632 void ViewLocation_Mouse()
1633 {
1634         if(spectatee_status)
1635                 return; // don't draw it as spectator!
1636
1637         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1638         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1639         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1640
1641         //float cursor_alpha = 1 - autocvar__menu_alpha;
1642         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1643 }
1644
1645 void HUD_Cursor_Show()
1646 {
1647         float cursor_alpha = 1 - autocvar__menu_alpha;
1648         if(cursor_type == CURSOR_NORMAL)
1649                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1650         else if(cursor_type == CURSOR_MOVE)
1651                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1652         else if(cursor_type == CURSOR_RESIZE)
1653                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1654         else if(cursor_type == CURSOR_RESIZE2)
1655                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1656 }
1657
1658 void HUD_Mouse(entity player)
1659 {
1660         if(autocvar__menu_alpha == 1)
1661                 return;
1662
1663         if(!cursor_active)
1664         {
1665                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1666                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1667                 return;
1668         }
1669
1670         if (cursor_active == -1) // starting to display the cursor
1671         {
1672                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1673                 // in the first frame mousepos is the mouse position of the last time
1674                 // the cursor was displayed, thus we ignore it to avoid a glictch
1675                 cursor_active = 1;
1676                 return;
1677         }
1678
1679         if(!autocvar_hud_cursormode)
1680                 update_mousepos();
1681
1682         if(autocvar__hud_configure)
1683                 HUD_Panel_Mouse();
1684         else
1685         {
1686                 if (HUD_MinigameMenu_IsOpened())
1687                         HUD_Minigame_Mouse();
1688                 if (QuickMenu_IsOpened())
1689                         QuickMenu_Mouse();
1690                 if (HUD_Radar_Clickable())
1691                         HUD_Radar_Mouse();
1692         }
1693
1694         prevMouseClicked = mouseClicked;
1695
1696         HUD_Cursor_Show();
1697 }
1698
1699 void View_NightVision()
1700 {
1701         if(!(autocvar_r_fakelight >= 2 || autocvar_r_fullbright) || (serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1702                 return;
1703
1704         // apply night vision effect
1705         vector tc_00, tc_01, tc_10, tc_11;
1706         vector rgb = '0 0 0';
1707         float a;
1708
1709         if(!nightvision_noise)
1710         {
1711                 nightvision_noise = new(nightvision_noise);
1712         }
1713         if(!nightvision_noise2)
1714         {
1715                 nightvision_noise2 = new(nightvision_noise2);
1716         }
1717
1718         // color tint in yellow
1719         drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1720
1721         // draw BG
1722         a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1723         rgb = '1 1 1';
1724         tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1725         tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1726         tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1727         //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1728         tc_11 = tc_01 + tc_10 - tc_00;
1729         R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE, true);
1730         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1731         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1732         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1733         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1734         R_EndPolygon();
1735
1736         // draw FG
1737         a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1738         rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1739         tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1740         tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1741         tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1742         tc_11 = tc_01 + tc_10 - tc_00;
1743         R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE, true);
1744         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1745         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1746         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1747         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1748         R_EndPolygon();
1749 }
1750
1751 void DrawReticle(entity this)
1752 {
1753         if(!autocvar_cl_reticle || MUTATOR_CALLHOOK(DrawReticle))
1754         {
1755                 reticle_type = 0;
1756                 return;
1757         }
1758
1759         float is_dead = (STAT(HEALTH) <= 0);
1760         string reticle_image = string_null;
1761         bool wep_zoomed = false;
1762         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1763         {
1764                 entity wepe = viewmodels[slot];
1765                 Weapon wep = wepe.activeweapon;
1766                 if(wep != WEP_Null && wep.wr_zoom)
1767                 {
1768                         bool do_zoom = wep.wr_zoom(wep, NULL);
1769                         if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
1770                                 reticle_image = wep.w_reticle;
1771                         wep_zoomed += do_zoom;
1772                 }
1773         }
1774         // Draw the aiming reticle for weapons that use it
1775         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1776         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1777         // the view to go back to normal, so reticle_type would become 0 as we fade out)
1778         if(spectatee_status || is_dead || hud != HUD_NORMAL || this.viewloc)
1779         {
1780                 // no zoom reticle while dead
1781                 reticle_type = 0;
1782         }
1783         else if(wep_zoomed && autocvar_cl_reticle_weapon)
1784         {
1785                 if(reticle_image) { reticle_type = 2; }
1786                 else { reticle_type = 0; }
1787         }
1788         else if(button_zoom || zoomscript_caught)
1789         {
1790                 // normal zoom
1791                 reticle_type = 1;
1792         }
1793
1794         if(reticle_type)
1795         {
1796                 vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1797                 if(autocvar_cl_reticle_stretch)
1798                 {
1799                         reticle_size.x = vid_conwidth;
1800                         reticle_size.y = vid_conheight;
1801                         reticle_pos.x = 0;
1802                         reticle_pos.y = 0;
1803                 }
1804                 else
1805                 {
1806                         reticle_size.x = max(vid_conwidth, vid_conheight);
1807                         reticle_size.y = max(vid_conwidth, vid_conheight);
1808                         reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1809                         reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1810                 }
1811
1812                 float f = (zoomscript_caught) ? 1 : current_zoomfraction;
1813
1814                 if(f)
1815                 {
1816                         switch(reticle_type)
1817                         {
1818                                 case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1819                                 case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1820                         }
1821                 }
1822         }
1823 }
1824
1825 // visual overlay while in liquids
1826 // provides some effects to the postprocessing function
1827 void HUD_Contents()
1828 {
1829         if(!autocvar_hud_contents || MUTATOR_CALLHOOK(HUD_Contents))
1830                 return;
1831
1832         // improved polyblend
1833         float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1834         vector liquidcolor;
1835
1836         switch(pointcontents(view_origin))
1837         {
1838                 case CONTENT_WATER:
1839                         liquidalpha = autocvar_hud_contents_water_alpha;
1840                         liquidcolor = stov(autocvar_hud_contents_water_color);
1841                         incontent = 1;
1842                         break;
1843
1844                 case CONTENT_LAVA:
1845                         liquidalpha = autocvar_hud_contents_lava_alpha;
1846                         liquidcolor = stov(autocvar_hud_contents_lava_color);
1847                         incontent = 1;
1848                         break;
1849
1850                 case CONTENT_SLIME:
1851                         liquidalpha = autocvar_hud_contents_slime_alpha;
1852                         liquidcolor = stov(autocvar_hud_contents_slime_color);
1853                         incontent = 1;
1854                         break;
1855
1856                 default:
1857                         liquidalpha = 0;
1858                         liquidcolor = '0 0 0';
1859                         incontent = 0;
1860                         break;
1861         }
1862
1863         if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1864         { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1865                 contentfadetime = autocvar_hud_contents_fadeintime;
1866                 liquidalpha_prev = liquidalpha;
1867                 liquidcolor_prev = liquidcolor;
1868         }
1869         else
1870                 contentfadetime = autocvar_hud_contents_fadeouttime;
1871
1872         contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1873         contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1874
1875         if(contentavgalpha)
1876                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1877
1878         if(autocvar_hud_postprocessing)
1879         {
1880                 if(autocvar_hud_contents_blur && contentavgalpha)
1881                 {
1882                         content_blurpostprocess.x = 1;
1883                         content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1884                         content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1885                 }
1886                 else
1887                 {
1888                         content_blurpostprocess.x = 0;
1889                         content_blurpostprocess.y = 0;
1890                         content_blurpostprocess.z = 0;
1891                 }
1892         }
1893 }
1894
1895 // visual pain effects on the screen
1896 // provides some effects to the postprocessing function
1897 void HUD_Damage()
1898 {
1899         if(!autocvar_hud_damage || STAT(FROZEN))
1900                 return;
1901
1902         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1903         splash_size.x = max(vid_conwidth, vid_conheight);
1904         splash_size.y = max(vid_conwidth, vid_conheight);
1905         splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1906         splash_pos.y = (vid_conheight - splash_size.y) / 2;
1907
1908         float myhealth_flash_temp;
1909         myhealth = STAT(HEALTH);
1910
1911         // fade out
1912         myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1913         // add new damage
1914         myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1915
1916         float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1917         pain_threshold = autocvar_hud_damage_pain_threshold;
1918         pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1919         pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1920
1921         if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1922         {
1923                 pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1924         }
1925
1926         myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1927
1928         if(myhealth_prev < 1)
1929         {
1930                 if(myhealth >= 1)
1931                 {
1932                         myhealth_flash = 0; // just spawned, clear the flash immediately
1933                         myhealth_flash_temp = 0;
1934                 }
1935                 else
1936                 {
1937                         myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1938                 }
1939         }
1940
1941         if(spectatee_status == -1 || intermission)
1942         {
1943                 myhealth_flash = 0; // observing, or match ended
1944                 myhealth_flash_temp = 0;
1945         }
1946
1947         myhealth_prev = myhealth;
1948
1949         // IDEA: change damage color/picture based on player model for robot/alien species?
1950         // pro: matches model better
1951         // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1952         // maybe different reddish pics?
1953         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1954         {
1955                 if(autocvar_cl_gentle_damage == 2)
1956                 {
1957                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1958                                 myhealth_gentlergb = randomvec();
1959                 }
1960                 else
1961                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1962
1963                 if(myhealth_flash_temp > 0)
1964                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1965         }
1966         else if(myhealth_flash_temp > 0)
1967                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1968
1969         if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1970         {
1971                 if(autocvar_hud_damage_blur && myhealth_flash_temp)
1972                 {
1973                         damage_blurpostprocess.x = 1;
1974                         damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1975                         damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1976                 }
1977                 else
1978                 {
1979                         damage_blurpostprocess.x = 0;
1980                         damage_blurpostprocess.y = 0;
1981                         damage_blurpostprocess.z = 0;
1982                 }
1983         }
1984 }
1985
1986 void View_PostProcessing()
1987 {
1988         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1989         float e2 = (autocvar_hud_powerup != 0);
1990         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1991         {
1992                 // enable or disable rendering types if they are used or not
1993                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1994                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1995
1996                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1997                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1998                 {
1999                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2000                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2001                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2002                         {
2003                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2004                                 old_blurradius = blurradius;
2005                                 old_bluralpha = bluralpha;
2006                         }
2007                 }
2008                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2009                 {
2010                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2011                         old_blurradius = 0;
2012                         old_bluralpha = 0;
2013                 }
2014
2015                 // edge detection postprocess handling done second (used by hud_powerup)
2016                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2017                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2018                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2019
2020                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2021
2022                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2023                 {
2024                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2025                         {
2026                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2027                                 old_sharpen_intensity = sharpen_intensity;
2028                         }
2029                 }
2030                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2031                 {
2032                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2033                         old_sharpen_intensity = 0;
2034                 }
2035
2036                 if(cvar("r_glsl_postprocess") == 0)
2037                         cvar_set("r_glsl_postprocess", "2");
2038         }
2039         else if(cvar("r_glsl_postprocess") == 2)
2040                 cvar_set("r_glsl_postprocess", "0");
2041 }
2042
2043 void View_Lock()
2044 {
2045         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
2046         {
2047                 setproperty(VF_ORIGIN, freeze_org);
2048                 setproperty(VF_ANGLES, freeze_ang);
2049         }
2050         else
2051         {
2052                 freeze_org = getpropertyvec(VF_ORIGIN);
2053                 freeze_ang = getpropertyvec(VF_ANGLES);
2054         }
2055 }
2056
2057 void View_DemoCamera()
2058 {
2059         if(camera_active) // Camera for demo playback
2060         {
2061                 if(autocvar_camera_enable)
2062                         CSQC_Demo_Camera();
2063                 else
2064                 {
2065                         cvar_set("chase_active", ftos(chase_active_backup));
2066                         cvar_set("cl_demo_mousegrab", "0");
2067                         camera_active = false;
2068                 }
2069         }
2070         else
2071         {
2072 #ifdef CAMERATEST
2073                 if(autocvar_camera_enable)
2074 #else
2075                 if(autocvar_camera_enable && isdemo())
2076 #endif
2077                 {
2078                         // Enable required Darkplaces cvars
2079                         chase_active_backup = autocvar_chase_active;
2080                         cvar_set("chase_active", "2");
2081                         cvar_set("cl_demo_mousegrab", "1");
2082                         camera_active = true;
2083                         camera_mode = false;
2084                 }
2085         }
2086 }
2087
2088 #ifdef BLURTEST
2089 void View_BlurTest()
2090 {
2091         if(time > blurtest_time0 && time < blurtest_time1)
2092         {
2093                 float t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
2094                 float r = t * blurtest_radius;
2095                 float f = 1 / (t ** blurtest_power) - 1;
2096
2097                 cvar_set("r_glsl_postprocess", "1");
2098                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
2099         }
2100         else
2101         {
2102                 cvar_set("r_glsl_postprocess", "0");
2103                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2104         }
2105 }
2106 #endif
2107
2108 void View_CheckButtonStatus()
2109 {
2110         float is_dead = (STAT(HEALTH) <= 0);
2111
2112         // FIXME do we need this hack?
2113         if(isdemo())
2114         {
2115                 // in demos, input_buttons do not work
2116                 button_zoom = (autocvar__togglezoom == "-");
2117         }
2118         else if(button_zoom
2119                 && autocvar_cl_unpress_zoom_on_death
2120                 && (spectatee_status >= 0)
2121                 && (is_dead || intermission))
2122         {
2123                 // no zoom while dead or in intermission please
2124                 localcmd("-zoom\n");
2125                 button_zoom = false;
2126         }
2127
2128         if(autocvar_fov <= 59.5)
2129         {
2130                 if(!zoomscript_caught)
2131                 {
2132                         localcmd("+button9\n");
2133                         zoomscript_caught = 1;
2134                 }
2135         }
2136         else
2137         {
2138                 if(zoomscript_caught)
2139                 {
2140                         localcmd("-button9\n");
2141                         zoomscript_caught = 0;
2142                 }
2143         }
2144
2145         if(active_minigame && HUD_MinigameMenu_IsOpened())
2146         {
2147                 if(!minigame_wasactive)
2148                 {
2149                         localcmd("+button12\n");
2150                         minigame_wasactive = true;
2151                 }
2152         }
2153         else if(minigame_wasactive)
2154         {
2155                 localcmd("-button12\n");
2156                 minigame_wasactive = false;
2157         }
2158
2159         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2160         {
2161                 entity wepent = viewmodels[slot];
2162
2163                 if(wepent.last_switchweapon != wepent.switchweapon)
2164                 {
2165                         weapontime = time;
2166                         wepent.last_switchweapon = wepent.switchweapon;
2167                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
2168                         {
2169                                 localcmd("-zoom\n");
2170                                 button_zoom = false;
2171                         }
2172                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
2173                         {
2174                                 localcmd("-fire\n");
2175                                 localcmd("-fire2\n");
2176                                 button_attack2 = false;
2177                         }
2178                 }
2179                 if(wepent.last_activeweapon != wepent.activeweapon)
2180                 {
2181                         wepent.last_activeweapon = wepent.activeweapon;
2182
2183                         entity e = wepent.activeweapon;
2184                         if(e.netname != "")
2185                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2186                         else if(slot == 0)
2187                                 localcmd("\ncl_hook_activeweapon none\n");
2188                 }
2189         }
2190 }
2191
2192 bool ov_enabled;
2193 float oldr_nearclip;
2194 float oldr_farclip_base;
2195 float oldr_farclip_world;
2196 float oldr_novis;
2197 float oldr_useportalculling;
2198 float oldr_useinfinitefarclip;
2199 vector ov_org = '0 0 0';
2200 vector ov_mid = '0 0 0';
2201 vector ov_worldmin = '0 0 0';
2202 vector ov_worldmax = '0 0 0';
2203
2204 void View_Ortho()
2205 {
2206         ov_org = '0 0 0';
2207         ov_mid = '0 0 0';
2208         ov_worldmin = '0 0 0';
2209         ov_worldmax = '0 0 0';
2210         if(autocvar_cl_orthoview)
2211         {
2212                 ov_worldmin = mi_picmin;
2213                 ov_worldmax = mi_picmax;
2214
2215                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
2216                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
2217                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
2218
2219                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
2220                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
2221
2222                 float ov_nearest = vlen(ov_org - vec3(
2223                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
2224                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
2225                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
2226                 ));
2227
2228                 float ov_furthest = 0;
2229                 float dist = 0;
2230
2231                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2232                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2233                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2234                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2235                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2236                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2237                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2238                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2239
2240                 if(!ov_enabled)
2241                 {
2242                         oldr_nearclip = cvar("r_nearclip");
2243                         oldr_farclip_base = cvar("r_farclip_base");
2244                         oldr_farclip_world = cvar("r_farclip_world");
2245                         oldr_novis = cvar("r_novis");
2246                         oldr_useportalculling = cvar("r_useportalculling");
2247                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
2248                 }
2249
2250                 cvar_settemp("r_nearclip", ftos(ov_nearest));
2251                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
2252                 cvar_settemp("r_farclip_world", "0");
2253                 cvar_settemp("r_novis", "1");
2254                 cvar_settemp("r_useportalculling", "0");
2255                 cvar_settemp("r_useinfinitefarclip", "0");
2256
2257                 setproperty(VF_ORIGIN, ov_org);
2258                 setproperty(VF_ANGLES, '90 0 0');
2259
2260                 ov_enabled = true;
2261
2262                 #if 0
2263                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
2264                         vtos(ov_org),
2265                         vtos(getpropertyvec(VF_ANGLES)),
2266                         ov_distance,
2267                         ov_nearest,
2268                         ov_furthest);
2269                 #endif
2270         }
2271         else
2272         {
2273                 if(ov_enabled)
2274                 {
2275                         cvar_set("r_nearclip", ftos(oldr_nearclip));
2276                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
2277                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
2278                         cvar_set("r_novis", ftos(oldr_novis));
2279                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
2280                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
2281                 }
2282                 ov_enabled = false;
2283         }
2284 }
2285
2286 void View_UpdateFov()
2287 {
2288         vector fov;
2289         if(autocvar_cl_orthoview)
2290                 fov = GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org);
2291         else if(csqcplayer.viewloc)
2292                 fov = GetViewLocationFOV(110); // enforce 110 fov, so things don't look odd
2293         else
2294                 fov = GetCurrentFov(autocvar_fov);
2295
2296         setproperty(VF_FOV, fov);
2297 }
2298
2299 void CSQC_UpdateView(entity this, float w, float h)
2300 {
2301         TC(int, w); TC(int, h);
2302
2303         execute_next_frame();
2304
2305         ++framecount;
2306
2307         stats_get();
2308         hud = STAT(HUD);
2309
2310         ReplicateVars(false);
2311         if (ReplicateVars_NOT_SENDING())
2312                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
2313
2314         HUD_Scale_Disable();
2315
2316         if(autocvar__hud_showbinds_reload) // menu can set this one
2317         {
2318                 db_close(binddb);
2319                 binddb = db_create();
2320                 cvar_set("_hud_showbinds_reload", "0");
2321         }
2322
2323         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
2324                 view_quality = getproperty(VF_MINFPS_QUALITY);
2325         else
2326                 view_quality = 1;
2327
2328         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
2329         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
2330
2331         vector vf_size = getpropertyvec(VF_SIZE);
2332         vector vf_min = getpropertyvec(VF_MIN);
2333         vid_width = vf_size.x;
2334         vid_height = vf_size.y;
2335
2336         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
2337
2338         WaypointSprite_Load();
2339
2340         CSQCPlayer_SetCamera();
2341
2342         if(player_localentnum <= maxclients) // is it a client?
2343                 current_player = player_localentnum - 1;
2344         else // then player_localentnum is the vehicle I'm driving
2345                 current_player = player_localnum;
2346         myteam = entcs_GetTeam(current_player);
2347
2348         // abused multiple places below
2349         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
2350         if(!local_player)
2351                 local_player = this; // fall back!
2352
2353         View_EventChase(local_player);
2354
2355         // do lockview after event chase camera so that it still applies whenever necessary.
2356         View_Lock();
2357
2358         WarpZone_FixView();
2359         //WarpZone_FixPMove();
2360
2361         View_Ortho();
2362
2363         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
2364         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
2365         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2366                 viewmodel_draw(viewmodels[slot]);
2367
2368         // Render the Scene
2369         view_origin = getpropertyvec(VF_ORIGIN);
2370         view_angles = getpropertyvec(VF_ANGLES);
2371         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
2372
2373 #ifdef BLURTEST
2374         View_BlurTest();
2375 #endif
2376
2377         TargetMusic_Advance();
2378         Fog_Force();
2379         fpscounter_update();
2380
2381         if(drawtime == 0)
2382                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
2383         else
2384                 drawframetime = bound(0.000001, time - drawtime, 1);
2385         drawtime = time;
2386
2387         // watch for gametype changes here...
2388         // in ParseStuffCMD the cmd isn't executed yet :/
2389         // might even be better to add the gametype to TE_CSQC_INIT...?
2390         if(!postinit)
2391                 PostInit();
2392
2393         if(intermission && !intermission_time)
2394                 intermission_time = time;
2395
2396         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
2397         {
2398                 if(calledhooks & HOOK_START)
2399                 {
2400                         localcmd("\ncl_hook_gameend\n");
2401                         calledhooks |= HOOK_END;
2402                 }
2403         }
2404
2405         Announcer();
2406
2407         View_CheckButtonStatus();
2408
2409         ColorTranslateMode = autocvar_cl_stripcolorcodes;
2410
2411         // ALWAYS Clear Current Scene First
2412         clearscene();
2413
2414         setproperty(VF_ORIGIN, view_origin);
2415         setproperty(VF_ANGLES, view_angles);
2416
2417         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2418         setproperty(VF_SIZE, vf_size);
2419         setproperty(VF_MIN, vf_min);
2420
2421         // Assign Standard Viewflags
2422         // Draw the World (and sky)
2423         setproperty(VF_DRAWWORLD, 1);
2424
2425         // Set the console size vars
2426         vid_conwidth = autocvar_vid_conwidth;
2427         vid_conheight = autocvar_vid_conheight;
2428         vid_pixelheight = autocvar_vid_pixelheight;
2429
2430         View_UpdateFov();
2431
2432         View_DemoCamera();
2433
2434         // Draw the Crosshair
2435         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2436
2437         // Draw the Engine Status Bar (the default Quake HUD)
2438         setproperty(VF_DRAWENGINESBAR, 0);
2439
2440         // Update the mouse position
2441         /*
2442            mousepos_x = vid_conwidth;
2443            mousepos_y = vid_conheight;
2444            mousepos = mousepos*0.5 + getmousepos();
2445          */
2446
2447         IL_EACH(g_drawables, it.draw, it.draw(it));
2448
2449         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2450         renderscene();
2451
2452         // Now the the scene has been rendered, begin with the 2D drawing functions
2453
2454         View_NightVision();
2455         DrawReticle(local_player);
2456         HUD_Contents();
2457         HUD_Damage();
2458         View_PostProcessing();
2459
2460         // draw 2D entities
2461         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2462         Draw_ShowNames_All();
2463 #if ENABLE_DEBUGDRAW
2464         Debug_Draw();
2465 #endif
2466
2467         scoreboard_active = Scoreboard_WouldDraw();
2468
2469         HUD_Draw(this); // this parameter for deep vehicle function
2470
2471         if(NextFrameCommand)
2472         {
2473                 localcmd("\n", NextFrameCommand, "\n");
2474                 NextFrameCommand = string_null;
2475         }
2476
2477         // we must do this check AFTER a frame was rendered, or it won't work
2478         if(cs_project_is_b0rked == 0)
2479         {
2480                 string w0, h0;
2481                 w0 = ftos(autocvar_vid_conwidth);
2482                 h0 = ftos(autocvar_vid_conheight);
2483                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2484                 //setproperty(VF_FOV, '90 90 0');
2485                 setproperty(VF_ORIGIN, '0 0 0');
2486                 setproperty(VF_ANGLES, '0 0 0');
2487                 setproperty(VF_PERSPECTIVE, 1);
2488                 vector forward, right, up;
2489                 MAKE_VECTORS('0 0 0', forward, right, up);
2490                 vector v1, v2;
2491                 cvar_set("vid_conwidth", "800");
2492                 cvar_set("vid_conheight", "600");
2493                 v1 = cs_project(forward);
2494                 cvar_set("vid_conwidth", "640");
2495                 cvar_set("vid_conheight", "480");
2496                 v2 = cs_project(forward);
2497                 if(v1 == v2)
2498                         cs_project_is_b0rked = 1;
2499                 else
2500                         cs_project_is_b0rked = -1;
2501                 cvar_set("vid_conwidth", w0);
2502                 cvar_set("vid_conheight", h0);
2503         }
2504
2505         HUD_Mouse(local_player);
2506
2507         cl_notice_run();
2508         unpause_update();
2509         Net_Flush();
2510
2511         // let's reset the view back to normal for the end
2512         setproperty(VF_MIN, '0 0 0');
2513         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2514
2515         IL_ENDFRAME();
2516 }
2517
2518
2519 // following vectors must be global to allow seamless switching between camera modes
2520 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2521 void CSQC_Demo_Camera()
2522 {
2523         float speed, attenuation, dimensions;
2524         vector tmp, delta;
2525
2526         if( autocvar_camera_reset || !camera_mode )
2527         {
2528                 camera_offset = '0 0 0';
2529                 current_angles = '0 0 0';
2530                 camera_direction = '0 0 0';
2531                 camera_offset.z += 30;
2532                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2533                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2534                 current_origin = view_origin;
2535                 current_camera_offset  = camera_offset;
2536                 cvar_set("camera_reset", "0");
2537                 camera_mode = CAMERA_CHASE;
2538         }
2539
2540         // Camera angles
2541         if( camera_roll )
2542                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2543
2544         if(autocvar_camera_look_player)
2545         {
2546                 vector dir;
2547                 float n;
2548
2549                 dir = normalize(view_origin - current_position);
2550                 n = mouse_angles.z;
2551                 mouse_angles = vectoangles(dir);
2552                 mouse_angles.x = mouse_angles.x * -1;
2553                 mouse_angles.z = n;
2554         }
2555         else
2556         {
2557                 tmp = getmousepos() * 0.1;
2558                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2559                 {
2560                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2561                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2562                 }
2563         }
2564
2565         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2566         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2567         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2568         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2569
2570         // Fix difference when angles don't have the same sign
2571         delta = '0 0 0';
2572         if(mouse_angles.y < -60 && current_angles.y > 60)
2573                 delta = '0 360 0';
2574         if(mouse_angles.y > 60 && current_angles.y < -60)
2575                 delta = '0 -360 0';
2576
2577         if(autocvar_camera_look_player)
2578                 attenuation = autocvar_camera_look_attenuation;
2579         else
2580                 attenuation = autocvar_camera_speed_attenuation;
2581
2582         attenuation = 1 / max(1, attenuation);
2583         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2584
2585         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2586         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2587         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2588         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2589
2590         // Camera position
2591         tmp = '0 0 0';
2592         dimensions = 0;
2593
2594         if( camera_direction.x )
2595         {
2596                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2597                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2598                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2599                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2600                 ++dimensions;
2601         }
2602
2603         if( camera_direction.y )
2604         {
2605                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2606                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2607                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2608                 ++dimensions;
2609         }
2610
2611         if( camera_direction.z )
2612         {
2613                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2614                 ++dimensions;
2615         }
2616
2617         if(autocvar_camera_free)
2618                 speed = autocvar_camera_speed_free;
2619         else
2620                 speed = autocvar_camera_speed_chase;
2621
2622         if(dimensions)
2623         {
2624                 speed = speed * sqrt(1 / dimensions);
2625                 camera_offset += tmp * speed;
2626         }
2627
2628         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2629
2630         // Camera modes
2631         if( autocvar_camera_free )
2632         {
2633                 if ( camera_mode == CAMERA_CHASE )
2634                 {
2635                         current_camera_offset = current_origin + current_camera_offset;
2636                         camera_offset = current_origin + camera_offset;
2637                 }
2638
2639                 camera_mode = CAMERA_FREE;
2640                 current_position = current_camera_offset;
2641         }
2642         else
2643         {
2644                 if ( camera_mode == CAMERA_FREE )
2645                 {
2646                         current_origin = view_origin;
2647                         camera_offset = camera_offset - current_origin;
2648                         current_camera_offset = current_camera_offset - current_origin;
2649                 }
2650
2651                 camera_mode = CAMERA_CHASE;
2652
2653                 if(autocvar_camera_chase_smoothly)
2654                         current_origin += (view_origin - current_origin) * attenuation;
2655                 else
2656                         current_origin = view_origin;
2657
2658                 current_position = current_origin + current_camera_offset;
2659         }
2660
2661         setproperty(VF_ANGLES, current_angles);
2662         setproperty(VF_ORIGIN, current_position);
2663 }