qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/_all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void calc_followmodel_ofs(entity view)
 118 {
 119         if(cl_followmodel_time == time)
 120                 return; // cl_followmodel_ofs already calculated for this frame
 121
 122         float frac;
 123         vector gunorg = '0 0 0';
 124         static vector vel_average;
 125         static vector gunorg_prev = '0 0 0';
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 .string name_last;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = this.alpha;
 292         static bool wasinvehicle;
 293         bool invehicle = player_localentnum > maxclients;
 294         if (invehicle) a = -1;
 295         else if (wasinvehicle) a = 1;
 296         wasinvehicle = invehicle;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 309                 e.glowmod = g;
 310                 e.csqcmodel_effects = fx;
 311                 CSQCModel_Effects_Apply(e);
 312         }
 313         {
 314                 string name = wep.mdl;
 315                 bool swap = name != this.name_last;
 316                 // if (swap)
 317                 {
 318                         this.name_last = name;
 319                         CL_WeaponEntity_SetModel(this, name, swap);
 320                         this.viewmodel_origin = this.origin;
 321                         this.viewmodel_angles = this.angles;
 322                 }
 323                 anim_update(this);
 324                 if (!this.animstate_override && !this.animstate_looping)
 325                         anim_set(this, this.anim_idle, true, false, false);
 326         }
 327         float f = 0; // 0..1; 0: fully active
 328         float rate = STAT(WEAPONRATEFACTOR);
 329         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 330         if (eta <= 0) f = this.weapon_eta_last;
 331         else switch (this.state)
 332         {
 333                 case WS_RAISE:
 334                 {
 335                         f = eta / max(eta, this.weapon_switchdelay);
 336                         break;
 337                 }
 338                 case WS_DROP:
 339                 {
 340                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_CLEAR:
 344                 {
 345                         f = 1;
 346                         break;
 347                 }
 348         }
 349         this.weapon_eta_last = f;
 350         this.origin = this.viewmodel_origin;
 351         this.angles = this.viewmodel_angles;
 352         this.angles_x = (-90 * f * f);
 353         viewmodel_animate(this);
 354         setorigin(this, this.origin);
 355 }
 356
 357 STATIC_INIT(viewmodel) {
 358     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 359         viewmodels[slot] = new(viewmodel);
 360 }
 361
 362 void Porto_Draw(entity this);
 363 STATIC_INIT(Porto)
 364 {
 365         entity e = new_pure(porto);
 366         e.draw = Porto_Draw;
 367         IL_PUSH(g_drawables, e);
 368         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 369 }
 370
 371 const int polyline_length = 16;
 372 .vector polyline[polyline_length];
 373 void Porto_Draw(entity this)
 374 {
 375         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 376         {
 377                 entity wepent = viewmodels[slot];
 378
 379                 if (wepent.activeweapon != WEP_PORTO) continue;
 380                 if (spectatee_status) continue;
 381                 if (WEP_CVAR(porto, secondary)) continue;
 382                 if (intermission == 1) continue;
 383                 if (intermission == 2) continue;
 384                 if (STAT(HEALTH) <= 0) continue;
 385
 386                 vector pos = view_origin;
 387                 vector dir = view_forward;
 388                 if (wepent.angles_held_status)
 389                 {
 390                         makevectors(wepent.angles_held);
 391                         dir = v_forward;
 392                 }
 393
 394                 wepent.polyline[0] = pos;
 395
 396                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 397                 int n = 1 + 2;  // 2 lines == 3 points
 398                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 399                 {
 400                         traceline(pos, pos + 65536 * dir, true, this);
 401                         dir = reflect(dir, trace_plane_normal);
 402                         pos = trace_endpos;
 403                         wepent.polyline[++idx] = pos;
 404                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 405                         {
 406                                 n += 1;
 407                                 continue;
 408                         }
 409                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 410                         {
 411                                 n = max(2, idx);
 412                                 break;
 413                         }
 414                         // check size
 415                         {
 416                                 vector ang = vectoangles2(trace_plane_normal, dir);
 417                                 ang.x = -ang.x;
 418                                 makevectors(ang);
 419                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 420                                 {
 421                                         n = max(2, idx);
 422                                         break;
 423                                 }
 424                         }
 425                         portal_number += 1;
 426                         if (portal_number >= portal_max) break;
 427                         if (portal_number == 1) portal1_idx = idx;
 428                 }
 429                 for (int idx = 0; idx < n - 1; ++idx)
 430                 {
 431                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 432                         if (idx == 0) p -= view_up * 16;  // line from player
 433                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 434                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 435                 }
 436         }
 437 }
 438
 439 float drawtime;
 440 float avgspeed;
 441 vector GetCurrentFov(float fov)
 442 {
 443         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 444         float velocityzoom, curspeed;
 445         vector v;
 446
 447         zoomsensitivity = autocvar_cl_zoomsensitivity;
 448         zoomfactor = autocvar_cl_zoomfactor;
 449         if(zoomfactor < 1 || zoomfactor > 30)
 450                 zoomfactor = 2.5;
 451         zoomspeed = autocvar_cl_zoomspeed;
 452         if(zoomspeed >= 0)
 453         if(zoomspeed < 0.5 || zoomspeed > 16)
 454                         zoomspeed = 3.5;
 455
 456         zoomdir = button_zoom;
 457
 458         if(hud == HUD_NORMAL && !spectatee_status)
 459         {
 460                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 461                 {
 462                         entity wepent = viewmodels[slot];
 463                         if(wepent.switchweapon == wepent.activeweapon)
 464                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 465                                 zoomdir += button_attack2;
 466                 }
 467         }
 468         if(spectatee_status > 0 || isdemo())
 469         {
 470                 if(spectatorbutton_zoom)
 471                 {
 472                         if(zoomdir)
 473                                 zoomdir = 0;
 474                         else
 475                                 zoomdir = 1;
 476                 }
 477                 // fteqcc failed twice here already, don't optimize this
 478         }
 479
 480         if(zoomdir) { zoomin_effect = 0; }
 481
 482         if(camera_active)
 483         {
 484                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 485         }
 486         else if(autocvar_cl_spawnzoom && zoomin_effect)
 487         {
 488                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 489
 490                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 491                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 492                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 493         }
 494         else
 495         {
 496                 if(zoomspeed < 0) // instant zoom
 497                 {
 498                         if(zoomdir)
 499                                 current_viewzoom = 1 / zoomfactor;
 500                         else
 501                                 current_viewzoom = 1;
 502                 }
 503                 else
 504                 {
 505                         if(zoomdir)
 506                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 507                         else
 508                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 509                 }
 510         }
 511
 512         if(almost_equals(current_viewzoom, 1))
 513                 current_zoomfraction = 0;
 514         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 515                 current_zoomfraction = 1;
 516         else
 517                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 518
 519         if(zoomsensitivity < 1)
 520                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 521         else
 522                 setsensitivityscale(1);
 523
 524         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 525         {
 526                 if(intermission) { curspeed = 0; }
 527                 else
 528                 {
 529
 530                         makevectors(view_angles);
 531                         v = pmove_vel;
 532                         if(csqcplayer)
 533                                 v = csqcplayer.velocity;
 534
 535                         switch(autocvar_cl_velocityzoom_type)
 536                         {
 537                                 case 3: curspeed = max(0, v_forward * v); break;
 538                                 case 2: curspeed = (v_forward * v); break;
 539                                 case 1: default: curspeed = vlen(v); break;
 540                         }
 541                 }
 542
 543                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 544                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 545                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 546
 547                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 548         }
 549         else
 550                 velocityzoom = 1;
 551
 552         float frustumx, frustumy, fovx, fovy;
 553         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 554         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 555         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 556         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 557
 558         return '1 0 0' * fovx + '0 1 0' * fovy;
 559 }
 560
 561 vector GetViewLocationFOV(float fov)
 562 {
 563         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 564         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 565         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 566         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 567         return '1 0 0' * fovx + '0 1 0' * fovy;
 568 }
 569
 570 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 571 {
 572         float fovx, fovy;
 573         float width = (ov_worldmax.x - ov_worldmin.x);
 574         float height = (ov_worldmax.y - ov_worldmin.y);
 575         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 576         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 577         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 578         return '1 0 0' * fovx + '0 1 0' * fovy;
 579 }
 580
 581 // this function must match W_SetupShot!
 582 float zoomscript_caught;
 583
 584 vector wcross_origin;
 585 float wcross_scale_prev, wcross_alpha_prev;
 586 vector wcross_color_prev;
 587 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 588 vector wcross_color_goal_prev;
 589 float wcross_changedonetime;
 590
 591 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 592 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 593 float wcross_name_changestarttime, wcross_name_changedonetime;
 594 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 595
 596 float wcross_ring_prev;
 597
 598 entity trueaim;
 599 entity trueaim_rifle;
 600
 601 const float SHOTTYPE_HITTEAM = 1;
 602 const float SHOTTYPE_HITOBSTRUCTION = 2;
 603 const float SHOTTYPE_HITWORLD = 3;
 604 const float SHOTTYPE_HITENEMY = 4;
 605
 606 void TrueAim_Init()
 607 {
 608         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 609         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 610 }
 611
 612 float EnemyHitCheck()
 613 {
 614         float t, n;
 615         wcross_origin = project_3d_to_2d(trace_endpos);
 616         wcross_origin.z = 0;
 617         if(trace_ent)
 618                 n = trace_ent.entnum;
 619         else
 620                 n = trace_networkentity;
 621         if(n < 1)
 622                 return SHOTTYPE_HITWORLD;
 623         if(n > maxclients)
 624                 return SHOTTYPE_HITWORLD;
 625         t = entcs_GetTeam(n - 1);
 626         if(teamplay)
 627                 if(t == myteam)
 628                         return SHOTTYPE_HITTEAM;
 629         if(t == NUM_SPECTATOR)
 630                 return SHOTTYPE_HITWORLD;
 631         return SHOTTYPE_HITENEMY;
 632 }
 633
 634 float TrueAimCheck(entity wepent)
 635 {
 636         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 637         vector vecs, trueaimpoint, w_shotorg;
 638         vector mi, ma, dv;
 639         float shottype;
 640         entity ta;
 641         float mv;
 642
 643         mi = ma = '0 0 0';
 644         ta = trueaim;
 645         mv = MOVE_NOMONSTERS;
 646
 647         switch(wepent.activeweapon) // WEAPONTODO
 648         {
 649                 case WEP_TUBA: // no aim
 650                 case WEP_PORTO: // shoots from eye
 651                 case WEP_NEXBALL: // shoots from eye
 652                 case WEP_HOOK: // no trueaim
 653                 case WEP_MORTAR: // toss curve
 654                         return SHOTTYPE_HITWORLD;
 655                 case WEP_VORTEX:
 656                 case WEP_VAPORIZER:
 657                         mv = MOVE_NORMAL;
 658                         break;
 659                 case WEP_RIFLE:
 660                         ta = trueaim_rifle;
 661                         mv = MOVE_NORMAL;
 662                         if(zoomscript_caught)
 663                         {
 664                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 665                                 return EnemyHitCheck();
 666                         }
 667                         break;
 668                 case WEP_DEVASTATOR: // projectile has a size!
 669                         mi = '-3 -3 -3';
 670                         ma = '3 3 3';
 671                         break;
 672                 case WEP_FIREBALL: // projectile has a size!
 673                         mi = '-16 -16 -16';
 674                         ma = '16 16 16';
 675                         break;
 676                 case WEP_SEEKER: // projectile has a size!
 677                         mi = '-2 -2 -2';
 678                         ma = '2 2 2';
 679                         break;
 680                 case WEP_ELECTRO: // projectile has a size!
 681                         mi = '0 0 -3';
 682                         ma = '0 0 -3';
 683                         break;
 684         }
 685
 686         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 687
 688         vecs = decompressShotOrigin(STAT(SHOTORG));
 689
 690         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 691         trueaimpoint = trace_endpos;
 692
 693         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 694                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 695
 696         if(vecs.x > 0)
 697                 vecs.y = -vecs.y;
 698         else
 699                 vecs = '0 0 0';
 700
 701         dv = view_right * vecs.y + view_up * vecs.z;
 702         w_shotorg = traceorigin + dv;
 703
 704         // now move the vecs forward as much as requested if possible
 705         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 706         w_shotorg = trace_endpos - view_forward * nudge;
 707
 708         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 709         shottype = EnemyHitCheck();
 710         if(shottype != SHOTTYPE_HITWORLD)
 711                 return shottype;
 712
 713 #if 0
 714         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 715         // or rather, I know why, but see no fix
 716         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 717                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 718                 return SHOTTYPE_HITOBSTRUCTION;
 719 #endif
 720
 721         return SHOTTYPE_HITWORLD;
 722 }
 723
 724 void PostInit();
 725 void CSQC_Demo_Camera();
 726 float camera_mode;
 727 const float CAMERA_FREE = 1;
 728 const float CAMERA_CHASE = 2;
 729 float reticle_type;
 730 string NextFrameCommand;
 731
 732 vector freeze_org, freeze_ang;
 733 entity nightvision_noise, nightvision_noise2;
 734
 735 const float MAX_TIME_DIFF = 5;
 736 float pickup_crosshair_time, pickup_crosshair_size;
 737 float hitindication_crosshair_size;
 738 float use_vortex_chargepool;
 739
 740 float myhealth, myhealth_prev;
 741 float myhealth_flash;
 742
 743 float old_blurradius, old_bluralpha;
 744 float old_sharpen_intensity;
 745
 746 vector myhealth_gentlergb;
 747
 748 float contentavgalpha, liquidalpha_prev;
 749 vector liquidcolor_prev;
 750
 751 float eventchase_current_distance;
 752 float eventchase_running;
 753 bool WantEventchase(entity this)
 754 {
 755         if(autocvar_cl_orthoview)
 756                 return false;
 757         if(intermission)
 758                 return true;
 759         if(this.viewloc)
 760                 return true;
 761         if(spectatee_status >= 0)
 762         {
 763                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 764                         return true;
 765                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 766                         return true;
 767                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 768                 {
 769                         if(autocvar_cl_eventchase_death == 2)
 770                         {
 771                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 772                                 if(this.velocity == '0 0 0' || eventchase_running)
 773                                         return true;
 774                         }
 775                         else return true;
 776                 }
 777         }
 778         return false;
 779 }
 780
 781 void HUD_Crosshair_Vehicle(entity this)
 782 {
 783         if(hud != HUD_BUMBLEBEE_GUN)
 784         {
 785                 Vehicle info = Vehicles_from(hud);
 786                 info.vr_crosshair(info, this);
 787         }
 788 }
 789
 790 vector damage_blurpostprocess, content_blurpostprocess;
 791
 792 float unaccounted_damage = 0;
 793 void UpdateDamage()
 794 {
 795         // accumulate damage with each stat update
 796         static float damage_total_prev = 0;
 797         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 798         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 799         damage_total_prev = damage_total;
 800
 801         static float damage_dealt_time_prev = 0;
 802         float damage_dealt_time = STAT(HIT_TIME);
 803         if (damage_dealt_time != damage_dealt_time_prev)
 804         {
 805                 unaccounted_damage += unaccounted_damage_new;
 806                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 807         }
 808         damage_dealt_time_prev = damage_dealt_time;
 809
 810         // prevent hitsound when switching spectatee
 811         static float spectatee_status_prev = 0;
 812         if (spectatee_status != spectatee_status_prev)
 813                 unaccounted_damage = 0;
 814         spectatee_status_prev = spectatee_status;
 815 }
 816
 817 void HitSound()
 818 {
 819         // varying sound pitch
 820
 821         bool have_arc = false;
 822         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 823         {
 824                 entity wepent = viewmodels[slot];
 825
 826                 if(wepent.activeweapon == WEP_ARC)
 827                         have_arc = true;
 828         }
 829
 830         static float hitsound_time_prev = 0;
 831         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 832         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 833         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 834         {
 835                 if (autocvar_cl_hitsound && unaccounted_damage)
 836                 {
 837                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 838                         float a = autocvar_cl_hitsound_max_pitch;
 839                         float b = autocvar_cl_hitsound_min_pitch;
 840                         float c = autocvar_cl_hitsound_nom_damage;
 841                         float x = unaccounted_damage;
 842                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 843
 844                         // if sound variation is disabled, set pitch_shift to 1
 845                         if (autocvar_cl_hitsound == 1)
 846                                 pitch_shift = 1;
 847
 848                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 849                         if (autocvar_cl_hitsound == 3)
 850                         {
 851                                 float mirror_value = (a-b)/2 + b;
 852                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 853                         }
 854
 855                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 856
 857                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 858                         // todo: normalize sound pressure levels? seems unnecessary
 859
 860                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 861                 }
 862                 unaccounted_damage = 0;
 863                 hitsound_time_prev = time;
 864         }
 865
 866         static float typehit_time_prev = 0;
 867         float typehit_time = STAT(TYPEHIT_TIME);
 868         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 869         {
 870                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 871                 typehit_time_prev = typehit_time;
 872         }
 873 }
 874
 875 vector crosshair_getcolor(entity this, float health_stat)
 876 {
 877         static float rainbow_last_flicker;
 878         static vector rainbow_prev_color;
 879         vector wcross_color = '0 0 0';
 880         switch(autocvar_crosshair_color_special)
 881         {
 882                 case 1: // crosshair_color_per_weapon
 883                 {
 884                         if(this != WEP_Null && hud == HUD_NORMAL)
 885                         {
 886                                 wcross_color = this.wpcolor;
 887                                 break;
 888                         }
 889                         else { goto normalcolor; }
 890                 }
 891
 892                 case 2: // crosshair_color_by_health
 893                 {
 894                         float x = health_stat;
 895
 896                         //x = red
 897                         //y = green
 898                         //z = blue
 899
 900                         wcross_color.z = 0;
 901
 902                         if(x > 200)
 903                         {
 904                                 wcross_color.x = 0;
 905                                 wcross_color.y = 1;
 906                         }
 907                         else if(x > 150)
 908                         {
 909                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 910                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 911                         }
 912                         else if(x > 100)
 913                         {
 914                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 915                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 916                                 wcross_color.z = 1 - (x-100)*0.02;
 917                         }
 918                         else if(x > 50)
 919                         {
 920                                 wcross_color.x = 1;
 921                                 wcross_color.y = 1;
 922                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 923                         }
 924                         else if(x > 20)
 925                         {
 926                                 wcross_color.x = 1;
 927                                 wcross_color.y = (x-20)*90/27/100;
 928                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 929                         }
 930                         else
 931                         {
 932                                 wcross_color.x = 1;
 933                                 wcross_color.y = 0;
 934                         }
 935                         break;
 936                 }
 937
 938                 case 3: // crosshair_color_rainbow
 939                 {
 940                         if(time >= rainbow_last_flicker)
 941                         {
 942                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 943                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 944                         }
 945                         wcross_color = rainbow_prev_color;
 946                         break;
 947                 }
 948 LABEL(normalcolor)
 949                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 950         }
 951
 952         return wcross_color;
 953 }
 954
 955 void HUD_Crosshair(entity this)
 956 {
 957         float f, i, j;
 958         vector v;
 959         if(!scoreboard_active && !camera_active && intermission != 2 &&
 960                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 961                 !HUD_MinigameMenu_IsOpened() )
 962         {
 963                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 964                         return;
 965
 966                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 967                         return;
 968
 969                 if (hud != HUD_NORMAL)
 970                 {
 971                         HUD_Crosshair_Vehicle(this);
 972                         return;
 973                 }
 974
 975                 string wcross_style;
 976                 float wcross_alpha, wcross_resolution;
 977                 wcross_style = autocvar_crosshair;
 978                 if (wcross_style == "0")
 979                         return;
 980                 wcross_resolution = autocvar_crosshair_size;
 981                 if (wcross_resolution == 0)
 982                         return;
 983                 wcross_alpha = autocvar_crosshair_alpha;
 984                 if (wcross_alpha == 0)
 985                         return;
 986
 987                 // TrueAim check
 988                 float shottype;
 989
 990                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 991                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 992                 wcross_origin.z = 0;
 993                 if(autocvar_crosshair_hittest)
 994                 {
 995                         vector wcross_oldorigin;
 996                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 997                         wcross_oldorigin = wcross_origin;
 998                         shottype = TrueAimCheck(thiswep);
 999                         if(shottype == SHOTTYPE_HITWORLD)
1000                         {
1001                                 v = wcross_origin - wcross_oldorigin;
1002                                 v.x /= vid_conwidth;
1003                                 v.y /= vid_conheight;
1004                                 if(vdist(v, >, 0.01))
1005                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1006                         }
1007                         if(!autocvar_crosshair_hittest_showimpact)
1008                                 wcross_origin = wcross_oldorigin;
1009                 }
1010                 else
1011                         shottype = SHOTTYPE_HITWORLD;
1012
1013                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1014                 string wcross_name = "";
1015                 float wcross_scale, wcross_blur;
1016
1017         entity e = WEP_Null;
1018                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1019                 {
1020                         entity wepent = viewmodels[0]; // TODO: unhardcode
1021                         e = wepent.switchingweapon;
1022                         if(e)
1023                         {
1024                                 if(autocvar_crosshair_per_weapon)
1025                                 {
1026                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1027                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1028                                         //if (wcross_resolution == 0)
1029                                                 //return;
1030
1031                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1032                                         wcross_resolution *= e.w_crosshair_size;
1033                                         wcross_name = e.w_crosshair;
1034                                 }
1035                         }
1036                 }
1037
1038                 if(wcross_name == "")
1039                         wcross_name = strcat("gfx/crosshair", wcross_style);
1040
1041                 // MAIN CROSSHAIR COLOR DECISION
1042                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1043
1044                 if(autocvar_crosshair_effect_scalefade)
1045                 {
1046                         wcross_scale = wcross_resolution;
1047                         wcross_resolution = 1;
1048                 }
1049                 else
1050                 {
1051                         wcross_scale = 1;
1052                 }
1053
1054                 if(autocvar_crosshair_pickup)
1055                 {
1056                         float stat_pickup_time = STAT(LAST_PICKUP);
1057
1058                         if(pickup_crosshair_time < stat_pickup_time)
1059                         {
1060                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1061                                         pickup_crosshair_size = 1;
1062
1063                                 pickup_crosshair_time = stat_pickup_time;
1064                         }
1065
1066                         if(pickup_crosshair_size > 0)
1067                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1068                         else
1069                                 pickup_crosshair_size = 0;
1070
1071                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1072                 }
1073
1074                 // todo: make crosshair hit indication dependent on damage dealt
1075                 if(autocvar_crosshair_hitindication)
1076                 {
1077                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1078
1079                         if(unaccounted_damage)
1080                         {
1081                                 hitindication_crosshair_size = 1;
1082                         }
1083
1084                         if(hitindication_crosshair_size > 0)
1085                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1086                         else
1087                                 hitindication_crosshair_size = 0;
1088
1089                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1090                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1091                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1092                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1093                 }
1094
1095                 if(shottype == SHOTTYPE_HITENEMY)
1096                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1097                 if(shottype == SHOTTYPE_HITTEAM)
1098                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1099
1100                 f = fabs(autocvar_crosshair_effect_time);
1101                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1102                 {
1103                         wcross_changedonetime = time + f;
1104                 }
1105                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1106                 {
1107                         wcross_name_changestarttime = time;
1108                         wcross_name_changedonetime = time + f;
1109                         if(wcross_name_goal_prev_prev)
1110                                 strunzone(wcross_name_goal_prev_prev);
1111                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1112                         wcross_name_goal_prev = strzone(wcross_name);
1113                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1114                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1115                         wcross_resolution_goal_prev = wcross_resolution;
1116                 }
1117
1118                 wcross_scale_goal_prev = wcross_scale;
1119                 wcross_alpha_goal_prev = wcross_alpha;
1120                 wcross_color_goal_prev = wcross_color;
1121
1122                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1123                 {
1124                         wcross_blur = 1;
1125                         wcross_alpha *= 0.75;
1126                 }
1127                 else
1128                         wcross_blur = 0;
1129                 // *_prev is at time-frametime
1130                 // * is at wcross_changedonetime+f
1131                 // what do we have at time?
1132                 if(time < wcross_changedonetime)
1133                 {
1134                         f = frametime / (wcross_changedonetime - time + frametime);
1135                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1136                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1137                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1138                 }
1139
1140                 wcross_scale_prev = wcross_scale;
1141                 wcross_alpha_prev = wcross_alpha;
1142                 wcross_color_prev = wcross_color;
1143
1144                 MUTATOR_CALLHOOK(UpdateCrosshair);
1145
1146                 wcross_scale *= 1 - autocvar__menu_alpha;
1147                 wcross_alpha *= 1 - autocvar__menu_alpha;
1148                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1149
1150                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1151                 {
1152                         // crosshair rings for weapon stats
1153                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1154                         {
1155                                 // declarations and stats
1156                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1157                                 string ring_image = string_null, ring_inner_image = string_null;
1158                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1159
1160                                 ring_scale = autocvar_crosshair_ring_size;
1161
1162                                 float weapon_clipload, weapon_clipsize;
1163                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1164                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1165
1166                                 float vortex_charge, vortex_chargepool;
1167                                 vortex_charge = STAT(VORTEX_CHARGE);
1168                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1169
1170                                 float arc_heat = STAT(ARC_HEAT);
1171
1172                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1173                                         vortex_charge_movingavg = vortex_charge;
1174
1175                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1176
1177                                 // handle the values
1178                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1179                                 {
1180                                         if (vortex_chargepool || use_vortex_chargepool) {
1181                                                 use_vortex_chargepool = 1;
1182                                                 ring_inner_value = vortex_chargepool;
1183                                         } else {
1184                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1185                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1186                                         }
1187
1188                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1189                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1190                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1191
1192                                         // draw the outer ring to show the current charge of the weapon
1193                                         ring_value = vortex_charge;
1194                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1195                                         ring_rgb = wcross_color;
1196                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1197                                 }
1198                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1199                                 {
1200                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1201                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1202                                         ring_rgb = wcross_color;
1203                                         ring_image = "gfx/crosshair_ring.tga";
1204                                 }
1205                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1206                                 {
1207                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1208                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1209                                         ring_rgb = wcross_color;
1210                                         ring_image = "gfx/crosshair_ring.tga";
1211                                 }
1212                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1213                                 {
1214                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1215                                         ring_scale = autocvar_crosshair_ring_reload_size;
1216                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1217                                         ring_rgb = wcross_color;
1218
1219                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1220                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1221                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1222                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1223                                         else
1224                                                 ring_image = "gfx/crosshair_ring.tga";
1225                                 }
1226                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1227                                 {
1228                                         ring_value = arc_heat;
1229                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1230                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1231                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1232                                         ring_image = "gfx/crosshair_ring.tga";
1233                                 }
1234
1235                                 // if in weapon switch animation, fade ring out/in
1236                                 if(autocvar_crosshair_effect_time > 0)
1237                                 {
1238                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1239                                         if (f >= 1)
1240                                         {
1241                                                 wcross_ring_prev = ((ring_image) ? true : false);
1242                                         }
1243
1244                                         if(wcross_ring_prev)
1245                                         {
1246                                                 if(f < 1)
1247                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1248                                         }
1249                                         else
1250                                         {
1251                                                 if(f < 1)
1252                                                         ring_alpha *= bound(0, f, 1);
1253                                         }
1254                                 }
1255
1256                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1257                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1258
1259                                 if (ring_value)
1260                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1261                         }
1262
1263 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1264                         MACRO_BEGIN { \
1265                                 if(wcross_blur > 0) \
1266                                 { \
1267                                         for(i = -2; i <= 2; ++i) \
1268                                         for(j = -2; j <= 2; ++j) \
1269                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1270                                 } \
1271                                 else \
1272                                 { \
1273                                         M(0,0,sz,wcross_name,wcross_alpha); \
1274                                 } \
1275                         } MACRO_END
1276
1277 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1278                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1279
1280 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1281                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1282
1283                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1284                         {
1285                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1286                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1287                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1288                                 f = 1 - f;
1289                         }
1290                         else
1291                         {
1292                                 f = 1;
1293                         }
1294                         wcross_name_alpha_goal_prev = f;
1295
1296                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1297                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1298
1299                         if(autocvar_crosshair_dot)
1300                         {
1301                                 vector wcross_color_old;
1302                                 wcross_color_old = wcross_color;
1303
1304                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1305                                         wcross_color = stov(autocvar_crosshair_dot_color);
1306
1307                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1308                                 // FIXME why don't we use wcross_alpha here?
1309                                 wcross_color = wcross_color_old;
1310                         }
1311                 }
1312         }
1313         else
1314         {
1315                 wcross_scale_prev = 0;
1316                 wcross_alpha_prev = 0;
1317                 wcross_scale_goal_prev = 0;
1318                 wcross_alpha_goal_prev = 0;
1319                 wcross_changedonetime = 0;
1320                 if(wcross_name_goal_prev)
1321                         strunzone(wcross_name_goal_prev);
1322                 wcross_name_goal_prev = string_null;
1323                 if(wcross_name_goal_prev_prev)
1324                         strunzone(wcross_name_goal_prev_prev);
1325                 wcross_name_goal_prev_prev = string_null;
1326                 wcross_name_changestarttime = 0;
1327                 wcross_name_changedonetime = 0;
1328                 wcross_name_alpha_goal_prev = 0;
1329                 wcross_name_alpha_goal_prev_prev = 0;
1330                 wcross_resolution_goal_prev = 0;
1331                 wcross_resolution_goal_prev_prev = 0;
1332         }
1333 }
1334
1335 void HUD_Draw(entity this)
1336 {
1337         // if we don't know gametype and scores yet avoid drawing the scoreboard
1338         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1339         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1340         // cl_deathscoreboard would show the scoreboard and so on
1341         if(!gametype)
1342                 return;
1343
1344         if(!intermission)
1345         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1346         {
1347                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1348         }
1349         else if(STAT(FROZEN))
1350         {
1351                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1352         }
1353         if(!intermission)
1354         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1355         {
1356                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1357                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1358         }
1359         else if(STAT(CAPTURE_PROGRESS))
1360         {
1361                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1362                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1363         }
1364         else if(STAT(REVIVE_PROGRESS))
1365         {
1366                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1367                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1368         }
1369
1370         if(autocvar_r_letterbox == 0)
1371                 if(autocvar_viewsize < 120)
1372                 {
1373                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1374                                 Accuracy_LoadLevels();
1375
1376                         HUD_Main();
1377                         HUD_Scale_Disable();
1378                 }
1379
1380         // crosshair goes VERY LAST
1381         UpdateDamage();
1382         HUD_Crosshair(this);
1383         HitSound();
1384 }
1385
1386 bool ov_enabled;
1387 float oldr_nearclip;
1388 float oldr_farclip_base;
1389 float oldr_farclip_world;
1390 float oldr_novis;
1391 float oldr_useportalculling;
1392 float oldr_useinfinitefarclip;
1393
1394 void cl_notice_run();
1395
1396 float prev_myteam;
1397 int lasthud;
1398 float vh_notice_time;
1399 void WaypointSprite_Load();
1400 void CSQC_UpdateView(entity this, float w, float h)
1401 {
1402     TC(int, w); TC(int, h);
1403         entity e;
1404         float fov;
1405         float f;
1406         vector vf_size, vf_min;
1407         float a;
1408
1409         execute_next_frame();
1410
1411         ++framecount;
1412
1413         stats_get();
1414         hud = STAT(HUD);
1415
1416         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1417                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1418
1419         lasthud = hud;
1420
1421         HUD_Scale_Disable();
1422
1423         if(autocvar__hud_showbinds_reload) // menu can set this one
1424         {
1425                 db_close(binddb);
1426                 binddb = db_create();
1427                 cvar_set("_hud_showbinds_reload", "0");
1428         }
1429
1430         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1431                 view_quality = getproperty(VF_MINFPS_QUALITY);
1432         else
1433                 view_quality = 1;
1434
1435         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1436         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1437
1438         vf_size = getpropertyvec(VF_SIZE);
1439         vf_min = getpropertyvec(VF_MIN);
1440         vid_width = vf_size.x;
1441         vid_height = vf_size.y;
1442
1443         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1444         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1445
1446         WaypointSprite_Load();
1447
1448         CSQCPlayer_SetCamera();
1449
1450         if(player_localentnum <= maxclients) // is it a client?
1451                 current_player = player_localentnum - 1;
1452         else // then player_localentnum is the vehicle I'm driving
1453                 current_player = player_localnum;
1454         myteam = entcs_GetTeam(current_player);
1455
1456         if(myteam != prev_myteam)
1457         {
1458                 myteamcolors = colormapPaletteColor(myteam, 1);
1459                 FOREACH(hud_panels, true, it.update_time = time);
1460                 prev_myteam = myteam;
1461         }
1462
1463         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1464
1465         float is_dead = (STAT(HEALTH) <= 0);
1466
1467         // FIXME do we need this hack?
1468         if(isdemo())
1469         {
1470                 // in demos, input_buttons do not work
1471                 button_zoom = (autocvar__togglezoom == "-");
1472         }
1473         else if(button_zoom
1474                 && autocvar_cl_unpress_zoom_on_death
1475                 && (spectatee_status >= 0)
1476                 && (is_dead || intermission))
1477         {
1478                 // no zoom while dead or in intermission please
1479                 localcmd("-zoom\n");
1480                 button_zoom = false;
1481         }
1482
1483         // event chase camera
1484         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1485         {
1486                 if(STAT(CAMERA_SPECTATOR))
1487                 {
1488                         if(spectatee_status > 0)
1489                         {
1490                                 if(!autocvar_chase_active)
1491                                 {
1492                                         cvar_set("chase_active", "-2");
1493                                         goto skip_eventchase_death;
1494                                 }
1495                         }
1496                         else if(autocvar_chase_active == -2)
1497                                 cvar_set("chase_active", "0");
1498
1499                         if(autocvar_chase_active == -2)
1500                                 goto skip_eventchase_death;
1501                 }
1502                 else if(autocvar_chase_active == -2)
1503                         cvar_set("chase_active", "0");
1504
1505                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1506
1507                 float vehicle_viewdist = 0;
1508                 vector vehicle_viewofs = '0 0 0';
1509
1510                 if(vehicle_chase)
1511                 {
1512                         if(hud != HUD_BUMBLEBEE_GUN)
1513                         {
1514                                 Vehicle info = Vehicles_from(hud);
1515                                 vehicle_viewdist = info.height;
1516                                 vehicle_viewofs = info.view_ofs;
1517                         }
1518                 }
1519
1520                 if(WantEventchase(this))
1521                 {
1522                         vector current_view_origin_override = '0 0 0';
1523                         vector view_offset_override = '0 0 0';
1524                         float chase_distance_override = 0;
1525                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1526                         if(custom_eventchase)
1527                         {
1528                                 current_view_origin_override = M_ARGV(0, vector);
1529                                 view_offset_override = M_ARGV(1, vector);
1530                                 chase_distance_override = M_ARGV(0, float);
1531                         }
1532                         eventchase_running = true;
1533
1534                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1535                         if(!local_player)
1536                                 local_player = this; // fall back!
1537
1538                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1539                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1540                         if (custom_eventchase)
1541                                 current_view_origin = current_view_origin_override;
1542
1543                         // detect maximum viewoffset and use it
1544                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1545                         if(vehicle_chase)
1546                         {
1547                                 if(vehicle_viewofs)
1548                                         view_offset = vehicle_viewofs;
1549                                 else
1550                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1551                         }
1552                         if (custom_eventchase)
1553                                 view_offset = view_offset_override;
1554
1555                         if(view_offset)
1556                         {
1557                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1558                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1559                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1560                         }
1561
1562                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1563                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1564                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1565                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1566
1567                         // make the camera smooth back
1568                         float chase_distance = autocvar_cl_eventchase_distance;
1569                         if(vehicle_chase)
1570                         {
1571                                 if(vehicle_viewofs)
1572                                         chase_distance = vehicle_viewdist;
1573                                 else
1574                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1575                         }
1576                         if (custom_eventchase)
1577                                 chase_distance = chase_distance_override;
1578
1579                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1580                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1581                         else if(eventchase_current_distance != chase_distance)
1582                                 eventchase_current_distance = chase_distance;
1583
1584                         makevectors(view_angles);
1585
1586                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1587                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1588
1589                         // If the boxtrace fails, revert back to line tracing.
1590                         if(!local_player.viewloc)
1591                         if(trace_startsolid)
1592                         {
1593                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1594                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1595                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1596                         }
1597                         else { setproperty(VF_ORIGIN, trace_endpos); }
1598
1599                         if(!local_player.viewloc)
1600                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1601                 }
1602                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1603                 {
1604                         eventchase_running = false;
1605                         cvar_set("chase_active", "0");
1606                         eventchase_current_distance = 0; // start from 0 next time
1607                 }
1608         }
1609         // workaround for camera stuck between player's legs when using chase_active 1
1610         // because the engine stops updating the chase_active camera when the game ends
1611         else if(intermission)
1612         {
1613                 cvar_settemp("chase_active", "-1");
1614                 eventchase_current_distance = 0;
1615         }
1616
1617         LABEL(skip_eventchase_death);
1618
1619         // do lockview after event chase camera so that it still applies whenever necessary.
1620         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1621         {
1622                 setproperty(VF_ORIGIN, freeze_org);
1623                 setproperty(VF_ANGLES, freeze_ang);
1624         }
1625         else
1626         {
1627                 freeze_org = getpropertyvec(VF_ORIGIN);
1628                 freeze_ang = getpropertyvec(VF_ANGLES);
1629         }
1630
1631         WarpZone_FixView();
1632         //WarpZone_FixPMove();
1633
1634         vector ov_org = '0 0 0';
1635         vector ov_mid = '0 0 0';
1636         vector ov_worldmin = '0 0 0';
1637         vector ov_worldmax = '0 0 0';
1638         if(autocvar_cl_orthoview)
1639         {
1640                 ov_worldmin = mi_picmin;
1641                 ov_worldmax = mi_picmax;
1642
1643                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1644                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1645                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1646
1647                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1648                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1649
1650                 float ov_nearest = vlen(ov_org - vec3(
1651                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1652                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1653                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1654                 ));
1655
1656                 float ov_furthest = 0;
1657                 float dist = 0;
1658
1659                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1660                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1661                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1662                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1663                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1664                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1665                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1666                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1667
1668                 if(!ov_enabled)
1669                 {
1670                         oldr_nearclip = cvar("r_nearclip");
1671                         oldr_farclip_base = cvar("r_farclip_base");
1672                         oldr_farclip_world = cvar("r_farclip_world");
1673                         oldr_novis = cvar("r_novis");
1674                         oldr_useportalculling = cvar("r_useportalculling");
1675                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1676                 }
1677
1678                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1679                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1680                 cvar_settemp("r_farclip_world", "0");
1681                 cvar_settemp("r_novis", "1");
1682                 cvar_settemp("r_useportalculling", "0");
1683                 cvar_settemp("r_useinfinitefarclip", "0");
1684
1685                 setproperty(VF_ORIGIN, ov_org);
1686                 setproperty(VF_ANGLES, '90 0 0');
1687
1688                 ov_enabled = true;
1689
1690                 #if 0
1691                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1692                         vtos(ov_org),
1693                         vtos(getpropertyvec(VF_ANGLES)),
1694                         ov_distance,
1695                         ov_nearest,
1696                         ov_furthest);
1697                 #endif
1698         }
1699         else
1700         {
1701                 if(ov_enabled)
1702                 {
1703                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1704                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1705                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1706                         cvar_set("r_novis", ftos(oldr_novis));
1707                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1708                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1709                 }
1710                 ov_enabled = false;
1711         }
1712
1713         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1714         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1715         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1716                 viewmodel_draw(viewmodels[slot]);
1717
1718         // Render the Scene
1719         view_origin = getpropertyvec(VF_ORIGIN);
1720         view_angles = getpropertyvec(VF_ANGLES);
1721         makevectors(view_angles);
1722         view_forward = v_forward;
1723         view_right = v_right;
1724         view_up = v_up;
1725
1726 #ifdef BLURTEST
1727         if(time > blurtest_time0 && time < blurtest_time1)
1728         {
1729                 float r, t;
1730
1731                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1732                 r = t * blurtest_radius;
1733                 f = 1 / pow(t, blurtest_power) - 1;
1734
1735                 cvar_set("r_glsl_postprocess", "1");
1736                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1737         }
1738         else
1739         {
1740                 cvar_set("r_glsl_postprocess", "0");
1741                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1742         }
1743 #endif
1744
1745         TargetMusic_Advance();
1746         Fog_Force();
1747
1748         if(drawtime == 0)
1749                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1750         else
1751                 drawframetime = bound(0.000001, time - drawtime, 1);
1752         drawtime = time;
1753
1754         // watch for gametype changes here...
1755         // in ParseStuffCMD the cmd isn't executed yet :/
1756         // might even be better to add the gametype to TE_CSQC_INIT...?
1757         if(!postinit)
1758                 PostInit();
1759
1760         if(intermission && !gameover_time)
1761                 gameover_time = time;
1762
1763         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1764         {
1765                 if(calledhooks & HOOK_START)
1766                 {
1767                         localcmd("\ncl_hook_gameend\n");
1768                         calledhooks |= HOOK_END;
1769                 }
1770         }
1771
1772         Announcer();
1773
1774         fov = autocvar_fov;
1775         if(fov <= 59.5)
1776         {
1777                 if(!zoomscript_caught)
1778                 {
1779                         localcmd("+button9\n");
1780                         zoomscript_caught = 1;
1781                 }
1782         }
1783         else
1784         {
1785                 if(zoomscript_caught)
1786                 {
1787                         localcmd("-button9\n");
1788                         zoomscript_caught = 0;
1789                 }
1790         }
1791
1792         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1793
1794         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1795         {
1796                 entity wepent = viewmodels[slot];
1797
1798                 if(wepent.last_switchweapon != wepent.switchweapon)
1799                 {
1800                         weapontime = time;
1801                         wepent.last_switchweapon = wepent.switchweapon;
1802                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1803                         {
1804                                 localcmd("-zoom\n");
1805                                 button_zoom = false;
1806                         }
1807                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1808                         {
1809                                 localcmd("-fire\n");
1810                                 localcmd("-fire2\n");
1811                                 button_attack2 = false;
1812                         }
1813                 }
1814                 if(wepent.last_activeweapon != wepent.activeweapon)
1815                 {
1816                         wepent.last_activeweapon = wepent.activeweapon;
1817
1818                         e = wepent.activeweapon;
1819                         if(e.netname != "")
1820                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1821                         else if(slot == 0)
1822                                 localcmd("\ncl_hook_activeweapon none\n");
1823                 }
1824         }
1825
1826         // ALWAYS Clear Current Scene First
1827         clearscene();
1828
1829         setproperty(VF_ORIGIN, view_origin);
1830         setproperty(VF_ANGLES, view_angles);
1831
1832         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1833         setproperty(VF_SIZE, vf_size);
1834         setproperty(VF_MIN, vf_min);
1835
1836         // Assign Standard Viewflags
1837         // Draw the World (and sky)
1838         setproperty(VF_DRAWWORLD, 1);
1839
1840         // Set the console size vars
1841         vid_conwidth = autocvar_vid_conwidth;
1842         vid_conheight = autocvar_vid_conheight;
1843         vid_pixelheight = autocvar_vid_pixelheight;
1844
1845         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1846         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1847         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1848
1849         if(camera_active) // Camera for demo playback
1850         {
1851                 if(autocvar_camera_enable)
1852                         CSQC_Demo_Camera();
1853                 else
1854                 {
1855                         cvar_set("chase_active", ftos(chase_active_backup));
1856                         cvar_set("cl_demo_mousegrab", "0");
1857                         camera_active = false;
1858                 }
1859         }
1860         else
1861         {
1862 #ifdef CAMERATEST
1863                 if(autocvar_camera_enable)
1864 #else
1865                 if(autocvar_camera_enable && isdemo())
1866 #endif
1867                 {
1868                         // Enable required Darkplaces cvars
1869                         chase_active_backup = autocvar_chase_active;
1870                         cvar_set("chase_active", "2");
1871                         cvar_set("cl_demo_mousegrab", "1");
1872                         camera_active = true;
1873                         camera_mode = false;
1874                 }
1875         }
1876
1877         // Draw the Crosshair
1878         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1879
1880         // Draw the Engine Status Bar (the default Quake HUD)
1881         setproperty(VF_DRAWENGINESBAR, 0);
1882
1883         // Update the mouse position
1884         /*
1885            mousepos_x = vid_conwidth;
1886            mousepos_y = vid_conheight;
1887            mousepos = mousepos*0.5 + getmousepos();
1888          */
1889
1890         IL_EACH(g_drawables, it.draw, it.draw(it));
1891
1892         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1893         renderscene();
1894
1895         // now switch to 2D drawing mode by calling a 2D drawing function
1896         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1897         // next R_RenderScene call
1898         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1899
1900         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1901         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1902         {
1903                 // apply night vision effect
1904                 vector tc_00, tc_01, tc_10, tc_11;
1905                 vector rgb = '0 0 0';
1906
1907                 if(!nightvision_noise)
1908                 {
1909                         nightvision_noise = new(nightvision_noise);
1910                 }
1911                 if(!nightvision_noise2)
1912                 {
1913                         nightvision_noise2 = new(nightvision_noise2);
1914                 }
1915
1916                 // color tint in yellow
1917                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1918
1919                 // draw BG
1920                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1921                 rgb = '1 1 1';
1922                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1923                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1924                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1925                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1926                 tc_11 = tc_01 + tc_10 - tc_00;
1927                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1928                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1929                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1930                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1931                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1932                 R_EndPolygon();
1933
1934                 // draw FG
1935                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1936                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1937                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1938                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1939                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1940                 tc_11 = tc_01 + tc_10 - tc_00;
1941                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1942                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1943                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1944                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1945                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1946                 R_EndPolygon();
1947         }
1948
1949         if(autocvar_cl_reticle)
1950         {
1951                 string reticle_image = "";
1952                 bool wep_zoomed = false;
1953                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1954                 {
1955                         entity wepe = viewmodels[slot];
1956                         Weapon wep = wepe.activeweapon;
1957                         if(wep != WEP_Null && wep.wr_zoom)
1958                         {
1959                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1960                                 if(wep.w_reticle && wep.w_reticle != "")
1961                                         reticle_image = wep.w_reticle;
1962                                 wep_zoomed += do_zoom;
1963                         }
1964                 }
1965                 // Draw the aiming reticle for weapons that use it
1966                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1967                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1968                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1969                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1970                 {
1971                         // no zoom reticle while dead
1972                         reticle_type = 0;
1973                 }
1974                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1975                 {
1976                         if(reticle_image && reticle_image != "") { reticle_type = 2; }
1977                         else { reticle_type = 0; }
1978                 }
1979                 else if(button_zoom || zoomscript_caught)
1980                 {
1981                         // normal zoom
1982                         reticle_type = 1;
1983                 }
1984
1985                 if(reticle_type)
1986                 {
1987                         if(autocvar_cl_reticle_stretch)
1988                         {
1989                                 reticle_size.x = vid_conwidth;
1990                                 reticle_size.y = vid_conheight;
1991                                 reticle_pos.x = 0;
1992                                 reticle_pos.y = 0;
1993                         }
1994                         else
1995                         {
1996                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1997                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1998                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1999                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2000                         }
2001
2002                         if(zoomscript_caught)
2003                                 f = 1;
2004                         else
2005                                 f = current_zoomfraction;
2006
2007                         if(f)
2008                         {
2009                                 switch(reticle_type)
2010                                 {
2011                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2012                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2013                                 }
2014                         }
2015                 }
2016         }
2017         else
2018         {
2019                 if(reticle_type != 0) { reticle_type = 0; }
2020         }
2021
2022
2023         // improved polyblend
2024         if(autocvar_hud_contents)
2025         {
2026                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2027                 vector liquidcolor;
2028
2029                 switch(pointcontents(view_origin))
2030                 {
2031                         case CONTENT_WATER:
2032                                 liquidalpha = autocvar_hud_contents_water_alpha;
2033                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2034                                 incontent = 1;
2035                                 break;
2036
2037                         case CONTENT_LAVA:
2038                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2039                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2040                                 incontent = 1;
2041                                 break;
2042
2043                         case CONTENT_SLIME:
2044                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2045                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2046                                 incontent = 1;
2047                                 break;
2048
2049                         default:
2050                                 liquidalpha = 0;
2051                                 liquidcolor = '0 0 0';
2052                                 incontent = 0;
2053                                 break;
2054                 }
2055
2056                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2057                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2058                         contentfadetime = autocvar_hud_contents_fadeintime;
2059                         liquidalpha_prev = liquidalpha;
2060                         liquidcolor_prev = liquidcolor;
2061                 }
2062                 else
2063                         contentfadetime = autocvar_hud_contents_fadeouttime;
2064
2065                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2066                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2067
2068                 if(contentavgalpha)
2069                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2070
2071                 if(autocvar_hud_postprocessing)
2072                 {
2073                         if(autocvar_hud_contents_blur && contentavgalpha)
2074                         {
2075                                 content_blurpostprocess.x = 1;
2076                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2077                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2078                         }
2079                         else
2080                         {
2081                                 content_blurpostprocess.x = 0;
2082                                 content_blurpostprocess.y = 0;
2083                                 content_blurpostprocess.z = 0;
2084                         }
2085                 }
2086         }
2087
2088         if(autocvar_hud_damage && !STAT(FROZEN))
2089         {
2090                 splash_size.x = max(vid_conwidth, vid_conheight);
2091                 splash_size.y = max(vid_conwidth, vid_conheight);
2092                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2093                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2094
2095                 float myhealth_flash_temp;
2096                 myhealth = STAT(HEALTH);
2097
2098                 // fade out
2099                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2100                 // add new damage
2101                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2102
2103                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2104                 pain_threshold = autocvar_hud_damage_pain_threshold;
2105                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2106                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2107
2108                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2109                 {
2110                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2111                 }
2112
2113                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2114
2115                 if(myhealth_prev < 1)
2116                 {
2117                         if(myhealth >= 1)
2118                         {
2119                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2120                                 myhealth_flash_temp = 0;
2121                         }
2122                         else
2123                         {
2124                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2125                         }
2126                 }
2127
2128                 if(spectatee_status == -1 || intermission)
2129                 {
2130                         myhealth_flash = 0; // observing, or match ended
2131                         myhealth_flash_temp = 0;
2132                 }
2133
2134                 myhealth_prev = myhealth;
2135
2136                 // IDEA: change damage color/picture based on player model for robot/alien species?
2137                 // pro: matches model better
2138                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2139                 // maybe different reddish pics?
2140                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2141                 {
2142                         if(autocvar_cl_gentle_damage == 2)
2143                         {
2144                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2145                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2146                         }
2147                         else
2148                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2149
2150                         if(myhealth_flash_temp > 0)
2151                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2152                 }
2153                 else if(myhealth_flash_temp > 0)
2154                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2155
2156                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2157                 {
2158                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2159                         {
2160                                 damage_blurpostprocess.x = 1;
2161                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2162                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2163                         }
2164                         else
2165                         {
2166                                 damage_blurpostprocess.x = 0;
2167                                 damage_blurpostprocess.y = 0;
2168                                 damage_blurpostprocess.z = 0;
2169                         }
2170                 }
2171         }
2172
2173         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2174         float e2 = (autocvar_hud_powerup != 0);
2175         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2176         {
2177                 // enable or disable rendering types if they are used or not
2178                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2179                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2180
2181                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2182                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2183                 {
2184                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2185                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2186                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2187                         {
2188                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2189                                 old_blurradius = blurradius;
2190                                 old_bluralpha = bluralpha;
2191                         }
2192                 }
2193                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2194                 {
2195                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2196                         old_blurradius = 0;
2197                         old_bluralpha = 0;
2198                 }
2199
2200                 // edge detection postprocess handling done second (used by hud_powerup)
2201                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2202                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2203                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2204
2205                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2206
2207                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2208                 {
2209                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2210                         {
2211                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2212                                 old_sharpen_intensity = sharpen_intensity;
2213                         }
2214                 }
2215                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2216                 {
2217                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2218                         old_sharpen_intensity = 0;
2219                 }
2220
2221                 if(cvar("r_glsl_postprocess") == 0)
2222                         cvar_set("r_glsl_postprocess", "2");
2223         }
2224         else if(cvar("r_glsl_postprocess") == 2)
2225                 cvar_set("r_glsl_postprocess", "0");
2226
2227         /*if(gametype == MAPINFO_TYPE_CTF)
2228           {
2229           ctf_view();
2230           } else */
2231
2232         // draw 2D entities
2233         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2234         Draw_ShowNames_All();
2235         Debug_Draw();
2236
2237         scoreboard_active = Scoreboard_WouldDraw();
2238
2239         HUD_Draw(this); // this parameter for deep vehicle function
2240
2241         if(NextFrameCommand)
2242         {
2243                 localcmd("\n", NextFrameCommand, "\n");
2244                 NextFrameCommand = string_null;
2245         }
2246
2247         // we must do this check AFTER a frame was rendered, or it won't work
2248         if(cs_project_is_b0rked == 0)
2249         {
2250                 string w0, h0;
2251                 w0 = ftos(autocvar_vid_conwidth);
2252                 h0 = ftos(autocvar_vid_conheight);
2253                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2254                 //setproperty(VF_FOV, '90 90 0');
2255                 setproperty(VF_ORIGIN, '0 0 0');
2256                 setproperty(VF_ANGLES, '0 0 0');
2257                 setproperty(VF_PERSPECTIVE, 1);
2258                 makevectors('0 0 0');
2259                 vector v1, v2;
2260                 cvar_set("vid_conwidth", "800");
2261                 cvar_set("vid_conheight", "600");
2262                 v1 = cs_project(v_forward);
2263                 cvar_set("vid_conwidth", "640");
2264                 cvar_set("vid_conheight", "480");
2265                 v2 = cs_project(v_forward);
2266                 if(v1 == v2)
2267                         cs_project_is_b0rked = 1;
2268                 else
2269                         cs_project_is_b0rked = -1;
2270                 cvar_set("vid_conwidth", w0);
2271                 cvar_set("vid_conheight", h0);
2272         }
2273
2274         if(autocvar__hud_configure)
2275                 HUD_Panel_Mouse();
2276         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2277                 HUD_Minigame_Mouse();
2278         else if(QuickMenu_IsOpened())
2279                 QuickMenu_Mouse();
2280         else
2281                 HUD_Radar_Mouse();
2282
2283         cl_notice_run();
2284         unpause_update();
2285         Net_Flush();
2286
2287         // let's reset the view back to normal for the end
2288         setproperty(VF_MIN, '0 0 0');
2289         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2290
2291         IL_ENDFRAME();
2292 }
2293
2294
2295 // following vectors must be global to allow seamless switching between camera modes
2296 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2297 void CSQC_Demo_Camera()
2298 {
2299         float speed, attenuation, dimensions;
2300         vector tmp, delta;
2301
2302         if( autocvar_camera_reset || !camera_mode )
2303         {
2304                 camera_offset = '0 0 0';
2305                 current_angles = '0 0 0';
2306                 camera_direction = '0 0 0';
2307                 camera_offset.z += 30;
2308                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2309                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2310                 current_origin = view_origin;
2311                 current_camera_offset  = camera_offset;
2312                 cvar_set("camera_reset", "0");
2313                 camera_mode = CAMERA_CHASE;
2314         }
2315
2316         // Camera angles
2317         if( camera_roll )
2318                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2319
2320         if(autocvar_camera_look_player)
2321         {
2322                 vector dir;
2323                 float n;
2324
2325                 dir = normalize(view_origin - current_position);
2326                 n = mouse_angles.z;
2327                 mouse_angles = vectoangles(dir);
2328                 mouse_angles.x = mouse_angles.x * -1;
2329                 mouse_angles.z = n;
2330         }
2331         else
2332         {
2333                 tmp = getmousepos() * 0.1;
2334                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2335                 {
2336                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2337                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2338                 }
2339         }
2340
2341         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2342         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2343         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2344         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2345
2346         // Fix difference when angles don't have the same sign
2347         delta = '0 0 0';
2348         if(mouse_angles.y < -60 && current_angles.y > 60)
2349                 delta = '0 360 0';
2350         if(mouse_angles.y > 60 && current_angles.y < -60)
2351                 delta = '0 -360 0';
2352
2353         if(autocvar_camera_look_player)
2354                 attenuation = autocvar_camera_look_attenuation;
2355         else
2356                 attenuation = autocvar_camera_speed_attenuation;
2357
2358         attenuation = 1 / max(1, attenuation);
2359         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2360
2361         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2362         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2363         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2364         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2365
2366         // Camera position
2367         tmp = '0 0 0';
2368         dimensions = 0;
2369
2370         if( camera_direction.x )
2371         {
2372                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2373                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2374                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2375                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2376                 ++dimensions;
2377         }
2378
2379         if( camera_direction.y )
2380         {
2381                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2382                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2383                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2384                 ++dimensions;
2385         }
2386
2387         if( camera_direction.z )
2388         {
2389                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2390                 ++dimensions;
2391         }
2392
2393         if(autocvar_camera_free)
2394                 speed = autocvar_camera_speed_free;
2395         else
2396                 speed = autocvar_camera_speed_chase;
2397
2398         if(dimensions)
2399         {
2400                 speed = speed * sqrt(1 / dimensions);
2401                 camera_offset += tmp * speed;
2402         }
2403
2404         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2405
2406         // Camera modes
2407         if( autocvar_camera_free )
2408         {
2409                 if ( camera_mode == CAMERA_CHASE )
2410                 {
2411                         current_camera_offset = current_origin + current_camera_offset;
2412                         camera_offset = current_origin + camera_offset;
2413                 }
2414
2415                 camera_mode = CAMERA_FREE;
2416                 current_position = current_camera_offset;
2417         }
2418         else
2419         {
2420                 if ( camera_mode == CAMERA_FREE )
2421                 {
2422                         current_origin = view_origin;
2423                         camera_offset = camera_offset - current_origin;
2424                         current_camera_offset = current_camera_offset - current_origin;
2425                 }
2426
2427                 camera_mode = CAMERA_CHASE;
2428
2429                 if(autocvar_camera_chase_smoothly)
2430                         current_origin += (view_origin - current_origin) * attenuation;
2431                 else
2432                         current_origin = view_origin;
2433
2434                 current_position = current_origin + current_camera_offset;
2435         }
2436
2437         setproperty(VF_ANGLES, current_angles);
2438         setproperty(VF_ORIGIN, current_position);
2439 }