qcsrc/client/view.qc

   1 #include "_all.qh"
   2
   3 #include "announcer.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "mapvoting.qh"
   8 #include "noise.qh"
   9 #include "scoreboard.qh"
  10 #include "shownames.qh"
  11 #include "vehicles/all.qh"
  12 #include "waypointsprites.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/nades.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20 #include "../common/util.qh"
  21
  22 #include "../common/weapons/all.qh"
  23
  24 #include "../csqcmodellib/cl_player.qh"
  25
  26 #include "../warpzonelib/client.qh"
  27 #include "../warpzonelib/common.qh"
  28 #include "../warpzonelib/mathlib.qh"
  29
  30 entity porto;
  31 vector polyline[16];
  32 void Porto_Draw()
  33 {
  34         vector p, dir, ang, q, nextdir;
  35         float portal_number, portal1_idx;
  36
  37         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  38                 return;
  39         if(g_balance_porto_secondary)
  40                 return;
  41         if(intermission == 1)
  42                 return;
  43         if(intermission == 2)
  44                 return;
  45         if (getstati(STAT_HEALTH) <= 0)
  46                 return;
  47
  48         dir = view_forward;
  49
  50         if(angles_held_status)
  51         {
  52                 makevectors(angles_held);
  53                 dir = v_forward;
  54         }
  55
  56         p = view_origin;
  57
  58         polyline[0] = p;
  59         int idx = 1;
  60         portal_number = 0;
  61         nextdir = dir;
  62
  63         for (;;)
  64         {
  65                 dir = nextdir;
  66                 traceline(p, p + 65536 * dir, true, porto);
  67                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  68                         return;
  69                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  70                 p = trace_endpos;
  71                 polyline[idx] = p;
  72                 ++idx;
  73                 if(idx >= 16)
  74                         return;
  75                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  76                         continue;
  77                 ++portal_number;
  78                 ang = vectoangles2(trace_plane_normal, dir);
  79                 ang.x = -ang.x;
  80                 makevectors(ang);
  81                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  82                         return;
  83                 if(portal_number == 1)
  84                 {
  85                         portal1_idx = idx;
  86                         if(portal_number >= 2)
  87                                 break;
  88                 }
  89         }
  90
  91         while(idx >= 2)
  92         {
  93                 p = polyline[idx-2];
  94                 q = polyline[idx-1];
  95                 if(idx == 2)
  96                         p = p - view_up * 16;
  97                 if(idx-1 >= portal1_idx)
  98                 {
  99                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 100                 }
 101                 else
 102                 {
 103                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 104                 }
 105                 --idx;
 106         }
 107 }
 108
 109 void Porto_Init()
 110 {
 111         porto = spawn();
 112         porto.classname = "porto";
 113         porto.draw = Porto_Draw;
 114         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 115 }
 116
 117 float drawtime;
 118 float avgspeed;
 119 vector GetCurrentFov(float fov)
 120 {
 121         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 122         float velocityzoom, curspeed;
 123         vector v;
 124
 125         zoomsensitivity = autocvar_cl_zoomsensitivity;
 126         zoomfactor = autocvar_cl_zoomfactor;
 127         if(zoomfactor < 1 || zoomfactor > 16)
 128                 zoomfactor = 2.5;
 129         zoomspeed = autocvar_cl_zoomspeed;
 130         if(zoomspeed >= 0)
 131         if(zoomspeed < 0.5 || zoomspeed > 16)
 132                         zoomspeed = 3.5;
 133
 134         zoomdir = button_zoom;
 135         if(hud == HUD_NORMAL)
 136         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 137                 zoomdir += button_attack2;
 138         if(spectatee_status > 0 || isdemo())
 139         {
 140                 if(spectatorbutton_zoom)
 141                 {
 142                         if(zoomdir)
 143                                 zoomdir = 0;
 144                         else
 145                                 zoomdir = 1;
 146                 }
 147                 // fteqcc failed twice here already, don't optimize this
 148         }
 149
 150         if(zoomdir) { zoomin_effect = 0; }
 151
 152         if(camera_active)
 153         {
 154                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 155         }
 156         else if(autocvar_cl_spawnzoom && zoomin_effect)
 157         {
 158                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 159
 160                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 161                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 162                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 163         }
 164         else
 165         {
 166                 if(zoomspeed < 0) // instant zoom
 167                 {
 168                         if(zoomdir)
 169                                 current_viewzoom = 1 / zoomfactor;
 170                         else
 171                                 current_viewzoom = 1;
 172                 }
 173                 else
 174                 {
 175                         if(zoomdir)
 176                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 177                         else
 178                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 179                 }
 180         }
 181
 182         if(almost_equals(current_viewzoom, 1))
 183                 current_zoomfraction = 0;
 184         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 185                 current_zoomfraction = 1;
 186         else
 187                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 188
 189         if(zoomsensitivity < 1)
 190                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 191         else
 192                 setsensitivityscale(1);
 193
 194         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 195         {
 196                 if(intermission) { curspeed = 0; }
 197                 else
 198                 {
 199
 200                         makevectors(view_angles);
 201                         v = pmove_vel;
 202                         if(csqcplayer)
 203                                 v = csqcplayer.velocity;
 204
 205                         switch(autocvar_cl_velocityzoom_type)
 206                         {
 207                                 case 3: curspeed = max(0, v_forward * v); break;
 208                                 case 2: curspeed = (v_forward * v); break;
 209                                 case 1: default: curspeed = vlen(v); break;
 210                         }
 211                 }
 212
 213                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 214                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 215                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 216
 217                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 218         }
 219         else
 220                 velocityzoom = 1;
 221
 222         float frustumx, frustumy, fovx, fovy;
 223         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 224         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 225         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 226         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 227
 228         return '1 0 0' * fovx + '0 1 0' * fovy;
 229 }
 230
 231 vector GetViewLocationFOV(float fov)
 232 {
 233         float frustumx, frustumy, fovx, fovy;
 234         frustumy = tan(fov * M_PI / 360.0) * 0.75;
 235         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 236         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 237         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 238         return '1 0 0' * fovx + '0 1 0' * fovy;
 239 }
 240
 241 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 242 {
 243         float fovx, fovy;
 244         float width = (ov_worldmax.x - ov_worldmin.x);
 245         float height = (ov_worldmax.y - ov_worldmin.y);
 246         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 247         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 248         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 249         return '1 0 0' * fovx + '0 1 0' * fovy;
 250 }
 251
 252 // this function must match W_SetupShot!
 253 float zoomscript_caught;
 254
 255 vector wcross_origin;
 256 float wcross_scale_prev, wcross_alpha_prev;
 257 vector wcross_color_prev;
 258 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 259 vector wcross_color_goal_prev;
 260 float wcross_changedonetime;
 261
 262 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 263 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 264 float wcross_name_changestarttime, wcross_name_changedonetime;
 265 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 266
 267 float wcross_ring_prev;
 268
 269 entity trueaim;
 270 entity trueaim_rifle;
 271
 272 const float SHOTTYPE_HITTEAM = 1;
 273 const float SHOTTYPE_HITOBSTRUCTION = 2;
 274 const float SHOTTYPE_HITWORLD = 3;
 275 const float SHOTTYPE_HITENEMY = 4;
 276
 277 void TrueAim_Init()
 278 {
 279         trueaim = spawn();
 280         trueaim.classname = "trueaim";
 281         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 282         trueaim_rifle = spawn();
 283         trueaim_rifle.classname = "trueaim_rifle";
 284         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 285 }
 286
 287 float EnemyHitCheck()
 288 {
 289         float t, n;
 290         wcross_origin = project_3d_to_2d(trace_endpos);
 291         wcross_origin.z = 0;
 292         if(trace_ent)
 293                 n = trace_ent.entnum;
 294         else
 295                 n = trace_networkentity;
 296         if(n < 1)
 297                 return SHOTTYPE_HITWORLD;
 298         if(n > maxclients)
 299                 return SHOTTYPE_HITWORLD;
 300         t = GetPlayerColor(n - 1);
 301         if(teamplay)
 302                 if(t == myteam)
 303                         return SHOTTYPE_HITTEAM;
 304         if(t == NUM_SPECTATOR)
 305                 return SHOTTYPE_HITWORLD;
 306         return SHOTTYPE_HITENEMY;
 307 }
 308
 309 float TrueAimCheck()
 310 {
 311         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 312         vector vecs, trueaimpoint, w_shotorg;
 313         vector mi, ma, dv;
 314         float shottype;
 315         entity ta;
 316         float mv;
 317
 318         mi = ma = '0 0 0';
 319         ta = trueaim;
 320         mv = MOVE_NOMONSTERS;
 321
 322         switch(activeweapon) // WEAPONTODO
 323         {
 324                 case WEP_TUBA: // no aim
 325                 case WEP_PORTO: // shoots from eye
 326                 case WEP_HOOK: // no trueaim
 327                 case WEP_MORTAR: // toss curve
 328                         return SHOTTYPE_HITWORLD;
 329                 case WEP_VORTEX:
 330                 case WEP_VAPORIZER:
 331                         mv = MOVE_NORMAL;
 332                         break;
 333                 case WEP_RIFLE:
 334                         ta = trueaim_rifle;
 335                         mv = MOVE_NORMAL;
 336                         if(zoomscript_caught)
 337                         {
 338                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 339                                 return EnemyHitCheck();
 340                         }
 341                         break;
 342                 case WEP_DEVASTATOR: // projectile has a size!
 343                         mi = '-3 -3 -3';
 344                         ma = '3 3 3';
 345                         break;
 346                 case WEP_FIREBALL: // projectile has a size!
 347                         mi = '-16 -16 -16';
 348                         ma = '16 16 16';
 349                         break;
 350                 case WEP_SEEKER: // projectile has a size!
 351                         mi = '-2 -2 -2';
 352                         ma = '2 2 2';
 353                         break;
 354                 case WEP_ELECTRO: // projectile has a size!
 355                         mi = '0 0 -3';
 356                         ma = '0 0 -3';
 357                         break;
 358         }
 359
 360         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 361
 362         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 363
 364         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 365         trueaimpoint = trace_endpos;
 366
 367         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 368                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 369
 370         if(vecs.x > 0)
 371                 vecs.y = -vecs.y;
 372         else
 373                 vecs = '0 0 0';
 374
 375         dv = view_right * vecs.y + view_up * vecs.z;
 376         w_shotorg = traceorigin + dv;
 377
 378         // now move the vecs forward as much as requested if possible
 379         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 380         w_shotorg = trace_endpos - view_forward * nudge;
 381
 382         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 383         shottype = EnemyHitCheck();
 384         if(shottype != SHOTTYPE_HITWORLD)
 385                 return shottype;
 386
 387 #if 0
 388         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 389         // or rather, I know why, but see no fix
 390         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 391                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 392                 return SHOTTYPE_HITOBSTRUCTION;
 393 #endif
 394
 395         return SHOTTYPE_HITWORLD;
 396 }
 397
 398 void CSQC_common_hud(void);
 399
 400 void PostInit(void);
 401 void CSQC_Demo_Camera();
 402 float HUD_WouldDrawScoreboard();
 403 float camera_mode;
 404 const float CAMERA_FREE = 1;
 405 const float CAMERA_CHASE = 2;
 406 float reticle_type;
 407 string reticle_image;
 408 string NextFrameCommand;
 409 void CSQC_SPIDER_HUD();
 410 void CSQC_RAPTOR_HUD();
 411
 412 vector freeze_org, freeze_ang;
 413 entity nightvision_noise, nightvision_noise2;
 414
 415 const float MAX_TIME_DIFF = 5;
 416 float pickup_crosshair_time, pickup_crosshair_size;
 417 float hitindication_crosshair_size;
 418 float use_vortex_chargepool;
 419
 420 float myhealth, myhealth_prev;
 421 float myhealth_flash;
 422
 423 float old_blurradius, old_bluralpha;
 424 float old_sharpen_intensity;
 425
 426 vector myhealth_gentlergb;
 427
 428 float contentavgalpha, liquidalpha_prev;
 429 vector liquidcolor_prev;
 430
 431 float eventchase_current_distance;
 432 float eventchase_running;
 433 bool WantEventchase()
 434 {
 435         if(autocvar_cl_orthoview)
 436                 return false;
 437         if(intermission)
 438                 return true;
 439         if(self.viewloc)
 440                 return true;
 441         if(spectatee_status >= 0)
 442         {
 443                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 444                         return true;
 445                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 446                 {
 447                         if(autocvar_cl_eventchase_death == 2)
 448                         {
 449                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 450                                 if(self.velocity == '0 0 0' || eventchase_running)
 451                                         return true;
 452                         }
 453                         else return true;
 454                 }
 455         }
 456         return false;
 457 }
 458
 459 vector damage_blurpostprocess, content_blurpostprocess;
 460
 461 float checkfail[16];
 462
 463 float unaccounted_damage = 0;
 464 void UpdateDamage()
 465 {
 466         // accumulate damage with each stat update
 467         static float damage_total_prev = 0;
 468         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 469         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 470         damage_total_prev = damage_total;
 471
 472         static float damage_dealt_time_prev = 0;
 473         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 474         if (damage_dealt_time != damage_dealt_time_prev)
 475         {
 476                 unaccounted_damage += unaccounted_damage_new;
 477                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 478         }
 479         damage_dealt_time_prev = damage_dealt_time;
 480
 481         // prevent hitsound when switching spectatee
 482         static float spectatee_status_prev = 0;
 483         if (spectatee_status != spectatee_status_prev)
 484                 unaccounted_damage = 0;
 485         spectatee_status_prev = spectatee_status;
 486 }
 487
 488 void UpdateHitsound()
 489 {
 490         // varying sound pitch
 491
 492         static float hitsound_time_prev = 0;
 493         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 494         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 495         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 496         {
 497                 if (autocvar_cl_hitsound && unaccounted_damage)
 498                 {
 499                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 500                         float a = autocvar_cl_hitsound_max_pitch;
 501                         float b = autocvar_cl_hitsound_min_pitch;
 502                         float c = autocvar_cl_hitsound_nom_damage;
 503                         float x = unaccounted_damage;
 504                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 505
 506                         // if sound variation is disabled, set pitch_shift to 1
 507                         if (autocvar_cl_hitsound == 1)
 508                                 pitch_shift = 1;
 509
 510                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 511                         if (autocvar_cl_hitsound == 3)
 512                         {
 513                                 float mirror_value = (a-b)/2 + b;
 514                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 515                         }
 516
 517                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 518
 519                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 520                         // todo: normalize sound pressure levels? seems unnecessary
 521
 522                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 523                 }
 524                 unaccounted_damage = 0;
 525                 hitsound_time_prev = time;
 526         }
 527
 528         static float typehit_time_prev = 0;
 529         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 530         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 531         {
 532                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 533                 typehit_time_prev = typehit_time;
 534         }
 535 }
 536
 537 void UpdateCrosshair()
 538 {
 539         static float rainbow_last_flicker;
 540     static vector rainbow_prev_color;
 541         entity e = self;
 542         float f, i, j;
 543         vector v;
 544         if(getstati(STAT_FROZEN))
 545                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 546         else if (getstatf(STAT_HEALING_ORB)>time)
 547                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 548         if(!intermission)
 549         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 550         {
 551                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 552                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 553         }
 554         else if(getstatf(STAT_REVIVE_PROGRESS))
 555         {
 556                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 557                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 558         }
 559
 560         if(autocvar_r_letterbox == 0)
 561                 if(autocvar_viewsize < 120)
 562                         CSQC_common_hud();
 563
 564         // crosshair goes VERY LAST
 565         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc)
 566         {
 567                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 568                         return;
 569
 570                 string wcross_style;
 571                 float wcross_alpha, wcross_resolution;
 572                 wcross_style = autocvar_crosshair;
 573                 if (wcross_style == "0")
 574                         return;
 575                 wcross_resolution = autocvar_crosshair_size;
 576                 if (wcross_resolution == 0)
 577                         return;
 578                 wcross_alpha = autocvar_crosshair_alpha;
 579                 if (wcross_alpha == 0)
 580                         return;
 581
 582                 // TrueAim check
 583                 float shottype;
 584
 585                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 586                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 587                 wcross_origin.z = 0;
 588                 if(autocvar_crosshair_hittest)
 589                 {
 590                         vector wcross_oldorigin;
 591                         wcross_oldorigin = wcross_origin;
 592                         shottype = TrueAimCheck();
 593                         if(shottype == SHOTTYPE_HITWORLD)
 594                         {
 595                                 v = wcross_origin - wcross_oldorigin;
 596                                 v.x /= vid_conwidth;
 597                                 v.y /= vid_conheight;
 598                                 if(vlen(v) > 0.01)
 599                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 600                         }
 601                         if(!autocvar_crosshair_hittest_showimpact)
 602                                 wcross_origin = wcross_oldorigin;
 603                 }
 604                 else
 605                         shottype = SHOTTYPE_HITWORLD;
 606
 607                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 608                 string wcross_name = "";
 609                 float wcross_scale, wcross_blur;
 610
 611                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 612                 {
 613                         e = get_weaponinfo(switchingweapon);
 614                         if(e)
 615                         {
 616                                 if(autocvar_crosshair_per_weapon)
 617                                 {
 618                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 619                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 620                                         //if (wcross_resolution == 0)
 621                                                 //return;
 622
 623                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 624                                         wcross_resolution *= e.w_crosshair_size;
 625                                         wcross_name = e.w_crosshair;
 626                                 }
 627                         }
 628                 }
 629
 630                 if(wcross_name == "")
 631                         wcross_name = strcat("gfx/crosshair", wcross_style);
 632
 633                 // MAIN CROSSHAIR COLOR DECISION
 634                 switch(autocvar_crosshair_color_special)
 635                 {
 636                         case 1: // crosshair_color_per_weapon
 637                         {
 638                                 if(e)
 639                                 {
 640                                         wcross_color = e.wpcolor;
 641                                         break;
 642                                 }
 643                                 else { goto normalcolor; }
 644                         }
 645
 646                         case 2: // crosshair_color_by_health
 647                         {
 648                                 float x = getstati(STAT_HEALTH);
 649
 650                                 //x = red
 651                                 //y = green
 652                                 //z = blue
 653
 654                                 wcross_color.z = 0;
 655
 656                                 if(x > 200)
 657                                 {
 658                                         wcross_color.x = 0;
 659                                         wcross_color.y = 1;
 660                                 }
 661                                 else if(x > 150)
 662                                 {
 663                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 664                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 665                                 }
 666                                 else if(x > 100)
 667                                 {
 668                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 669                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 670                                         wcross_color.z = 1 - (x-100)*0.02;
 671                                 }
 672                                 else if(x > 50)
 673                                 {
 674                                         wcross_color.x = 1;
 675                                         wcross_color.y = 1;
 676                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 677                                 }
 678                                 else if(x > 20)
 679                                 {
 680                                         wcross_color.x = 1;
 681                                         wcross_color.y = (x-20)*90/27/100;
 682                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 683                                 }
 684                                 else
 685                                 {
 686                                         wcross_color.x = 1;
 687                                         wcross_color.y = 0;
 688                                 }
 689                                 break;
 690                         }
 691
 692                         case 3: // crosshair_color_rainbow
 693                         {
 694                                 if(time >= rainbow_last_flicker)
 695                                 {
 696                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 697                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 698                                 }
 699                                 wcross_color = rainbow_prev_color;
 700                                 break;
 701                         }
 702                         :normalcolor
 703                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 704                 }
 705
 706                 if(autocvar_crosshair_effect_scalefade)
 707                 {
 708                         wcross_scale = wcross_resolution;
 709                         wcross_resolution = 1;
 710                 }
 711                 else
 712                 {
 713                         wcross_scale = 1;
 714                 }
 715
 716                 if(autocvar_crosshair_pickup)
 717                 {
 718                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 719
 720                         if(pickup_crosshair_time < stat_pickup_time)
 721                         {
 722                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 723                                         pickup_crosshair_size = 1;
 724
 725                                 pickup_crosshair_time = stat_pickup_time;
 726                         }
 727
 728                         if(pickup_crosshair_size > 0)
 729                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 730                         else
 731                                 pickup_crosshair_size = 0;
 732
 733                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 734                 }
 735
 736                 // todo: make crosshair hit indication dependent on damage dealt
 737                 if(autocvar_crosshair_hitindication)
 738                 {
 739                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 740
 741                         if(unaccounted_damage)
 742                         {
 743                                 hitindication_crosshair_size = 1;
 744                         }
 745
 746                         if(hitindication_crosshair_size > 0)
 747                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 748                         else
 749                                 hitindication_crosshair_size = 0;
 750
 751                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 752                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 753                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 754                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 755                 }
 756
 757                 if(shottype == SHOTTYPE_HITENEMY)
 758                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 759                 if(shottype == SHOTTYPE_HITTEAM)
 760                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 761
 762                 f = fabs(autocvar_crosshair_effect_time);
 763                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 764                 {
 765                         wcross_changedonetime = time + f;
 766                 }
 767                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 768                 {
 769                         wcross_name_changestarttime = time;
 770                         wcross_name_changedonetime = time + f;
 771                         if(wcross_name_goal_prev_prev)
 772                                 strunzone(wcross_name_goal_prev_prev);
 773                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 774                         wcross_name_goal_prev = strzone(wcross_name);
 775                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 776                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 777                         wcross_resolution_goal_prev = wcross_resolution;
 778                 }
 779
 780                 wcross_scale_goal_prev = wcross_scale;
 781                 wcross_alpha_goal_prev = wcross_alpha;
 782                 wcross_color_goal_prev = wcross_color;
 783
 784                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 785                 {
 786                         wcross_blur = 1;
 787                         wcross_alpha *= 0.75;
 788                 }
 789                 else
 790                         wcross_blur = 0;
 791                 // *_prev is at time-frametime
 792                 // * is at wcross_changedonetime+f
 793                 // what do we have at time?
 794                 if(time < wcross_changedonetime)
 795                 {
 796                         f = frametime / (wcross_changedonetime - time + frametime);
 797                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 798                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 799                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 800                 }
 801
 802                 wcross_scale_prev = wcross_scale;
 803                 wcross_alpha_prev = wcross_alpha;
 804                 wcross_color_prev = wcross_color;
 805
 806                 wcross_scale *= 1 - autocvar__menu_alpha;
 807                 wcross_alpha *= 1 - autocvar__menu_alpha;
 808                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 809
 810                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 811                 {
 812                         // crosshair rings for weapon stats
 813                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 814                         {
 815                                 // declarations and stats
 816                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 817                                 string ring_image = string_null, ring_inner_image = string_null;
 818                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 819
 820                                 ring_scale = autocvar_crosshair_ring_size;
 821
 822                                 float weapon_clipload, weapon_clipsize;
 823                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 824                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 825
 826                                 float ok_ammo_charge, ok_ammo_chargepool;
 827                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 828                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 829
 830                                 float vortex_charge, vortex_chargepool;
 831                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 832                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 833
 834                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 835
 836                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 837                                         vortex_charge_movingavg = vortex_charge;
 838
 839
 840                                 // handle the values
 841                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 842                                 {
 843                                         if (vortex_chargepool || use_vortex_chargepool) {
 844                                                 use_vortex_chargepool = 1;
 845                                                 ring_inner_value = vortex_chargepool;
 846                                         } else {
 847                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 848                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 849                                         }
 850
 851                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 852                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 853                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 854
 855                                         // draw the outer ring to show the current charge of the weapon
 856                                         ring_value = vortex_charge;
 857                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 858                                         ring_rgb = wcross_color;
 859                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 860                                 }
 861                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 862                                 {
 863                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 864                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 865                                         ring_rgb = wcross_color;
 866                                         ring_image = "gfx/crosshair_ring.tga";
 867                                 }
 868                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 869                                 {
 870                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 871                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 872                                         ring_rgb = wcross_color;
 873                                         ring_image = "gfx/crosshair_ring.tga";
 874                                 }
 875                                 else if (ok_ammo_charge)
 876                                 {
 877                                         ring_value = ok_ammo_chargepool;
 878                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 879                                         ring_rgb = wcross_color;
 880                                         ring_image = "gfx/crosshair_ring.tga";
 881                                 }
 882                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 883                                 {
 884                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 885                                         ring_scale = autocvar_crosshair_ring_reload_size;
 886                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 887                                         ring_rgb = wcross_color;
 888
 889                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 890                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 891                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 892                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 893                                         else
 894                                                 ring_image = "gfx/crosshair_ring.tga";
 895                                 }
 896                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
 897                                 {
 898                                         ring_value = arc_heat;
 899                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 900                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 901                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 902                                         ring_image = "gfx/crosshair_ring.tga";
 903                                 }
 904
 905                                 // if in weapon switch animation, fade ring out/in
 906                                 if(autocvar_crosshair_effect_time > 0)
 907                                 {
 908                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 909                                         if (f >= 1)
 910                                         {
 911                                                 wcross_ring_prev = ((ring_image) ? true : false);
 912                                         }
 913
 914                                         if(wcross_ring_prev)
 915                                         {
 916                                                 if(f < 1)
 917                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 918                                         }
 919                                         else
 920                                         {
 921                                                 if(f < 1)
 922                                                         ring_alpha *= bound(0, f, 1);
 923                                         }
 924                                 }
 925
 926                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 927                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 928
 929                                 if (ring_value)
 930                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 931                         }
 932
 933 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 934                         do \
 935                         { \
 936                                 if(wcross_blur > 0) \
 937                                 { \
 938                                         for(i = -2; i <= 2; ++i) \
 939                                         for(j = -2; j <= 2; ++j) \
 940                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 941                                 } \
 942                                 else \
 943                                 { \
 944                                         M(0,0,sz,wcross_name,wcross_alpha); \
 945                                 } \
 946                         } \
 947                         while(0)
 948
 949 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 950                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 951
 952 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 953                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 954
 955                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 956                         {
 957                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 958                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 959                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 960                                 f = 1 - f;
 961                         }
 962                         else
 963                         {
 964                                 f = 1;
 965                         }
 966                         wcross_name_alpha_goal_prev = f;
 967
 968                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 969                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 970
 971                         if(autocvar_crosshair_dot)
 972                         {
 973                                 vector wcross_color_old;
 974                                 wcross_color_old = wcross_color;
 975
 976                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 977                                         wcross_color = stov(autocvar_crosshair_dot_color);
 978
 979                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 980                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 981                                 wcross_color = wcross_color_old;
 982                         }
 983                 }
 984         }
 985         else
 986         {
 987                 wcross_scale_prev = 0;
 988                 wcross_alpha_prev = 0;
 989                 wcross_scale_goal_prev = 0;
 990                 wcross_alpha_goal_prev = 0;
 991                 wcross_changedonetime = 0;
 992                 if(wcross_name_goal_prev)
 993                         strunzone(wcross_name_goal_prev);
 994                 wcross_name_goal_prev = string_null;
 995                 if(wcross_name_goal_prev_prev)
 996                         strunzone(wcross_name_goal_prev_prev);
 997                 wcross_name_goal_prev_prev = string_null;
 998                 wcross_name_changestarttime = 0;
 999                 wcross_name_changedonetime = 0;
1000                 wcross_name_alpha_goal_prev = 0;
1001                 wcross_name_alpha_goal_prev_prev = 0;
1002                 wcross_resolution_goal_prev = 0;
1003                 wcross_resolution_goal_prev_prev = 0;
1004         }
1005 }
1006
1007 const int BUTTON_3 = 4;
1008 const int BUTTON_4 = 8;
1009 float cl_notice_run();
1010 float prev_myteam;
1011 void CSQC_UpdateView(float w, float h)
1012 {
1013         entity e;
1014         float fov;
1015         float f;
1016         int i;
1017         vector vf_size, vf_min;
1018         float a;
1019
1020         execute_next_frame();
1021
1022         ++framecount;
1023
1024         hud = getstati(STAT_HUD);
1025
1026         if(autocvar__hud_showbinds_reload) // menu can set this one
1027         {
1028                 db_close(binddb);
1029                 binddb = db_create();
1030                 cvar_set("_hud_showbinds_reload", "0");
1031         }
1032
1033         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1034                 view_quality = getproperty(VF_MINFPS_QUALITY);
1035         else
1036                 view_quality = 1;
1037
1038         button_attack2 = (input_buttons & BUTTON_3);
1039         button_zoom = (input_buttons & BUTTON_4);
1040
1041 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1042         float checkfailv = (func)(parm);                                                                                \
1043         if (checkfailv != (val)) {                                                                                      \
1044                 if (!checkfail[(flag)])                                                                                     \
1045                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1046                 checkfail[(flag)] = 1;                                                                                      \
1047         }                                                                                                               \
1048 } while(0)
1049         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1050         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1051         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1052         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1053         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1054         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1055         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1056
1057         vf_size = getpropertyvec(VF_SIZE);
1058         vf_min = getpropertyvec(VF_MIN);
1059         vid_width = vf_size.x;
1060         vid_height = vf_size.y;
1061
1062         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1063         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1064
1065         WaypointSprite_Load();
1066
1067         CSQCPlayer_SetCamera();
1068
1069         myteam = GetPlayerColor(player_localentnum - 1);
1070
1071         if(myteam != prev_myteam)
1072         {
1073                 myteamcolors = colormapPaletteColor(myteam, 1);
1074                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1075                         hud_panel[i].update_time = time;
1076                 prev_myteam = myteam;
1077         }
1078
1079         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1080
1081         float is_dead = (getstati(STAT_HEALTH) <= 0);
1082
1083         // FIXME do we need this hack?
1084         if(isdemo())
1085         {
1086                 // in demos, input_buttons do not work
1087                 button_zoom = (autocvar__togglezoom == "-");
1088         }
1089         else if(button_zoom
1090                 && autocvar_cl_unpress_zoom_on_death
1091                 && (spectatee_status >= 0)
1092                 && (is_dead || intermission))
1093         {
1094                 // no zoom while dead or in intermission please
1095                 localcmd("-zoom\n");
1096                 button_zoom = false;
1097         }
1098
1099         // event chase camera
1100         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1101         {
1102                 if(WantEventchase())
1103                 {
1104                         eventchase_running = true;
1105
1106                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1107                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1108
1109                         // detect maximum viewoffset and use it
1110                         if(autocvar_cl_eventchase_viewoffset)
1111                         {
1112                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1113                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1114                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1115                         }
1116
1117                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1118                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1119                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1120                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1121
1122                         // make the camera smooth back
1123                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1124                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1125                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1126                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1127
1128                         makevectors(view_angles);
1129
1130                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1131                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1132
1133                         // If the boxtrace fails, revert back to line tracing.
1134                         if(!self.viewloc)
1135                         if(trace_startsolid)
1136                         {
1137                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1138                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1139                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1140                         }
1141                         else { setproperty(VF_ORIGIN, trace_endpos); }
1142
1143                         if(!self.viewloc)
1144                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1145                 }
1146                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1147                 {
1148                         eventchase_running = false;
1149                         cvar_set("chase_active", "0");
1150                         eventchase_current_distance = 0; // start from 0 next time
1151                 }
1152         }
1153         // workaround for camera stuck between player's legs when using chase_active 1
1154         // because the engine stops updating the chase_active camera when the game ends
1155         else if(intermission)
1156         {
1157                 cvar_settemp("chase_active", "-1");
1158                 eventchase_current_distance = 0;
1159         }
1160
1161         // do lockview after event chase camera so that it still applies whenever necessary.
1162         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1163         {
1164                 setproperty(VF_ORIGIN, freeze_org);
1165                 setproperty(VF_ANGLES, freeze_ang);
1166         }
1167         else
1168         {
1169                 freeze_org = getpropertyvec(VF_ORIGIN);
1170                 freeze_ang = getpropertyvec(VF_ANGLES);
1171         }
1172
1173         WarpZone_FixView();
1174         //WarpZone_FixPMove();
1175
1176         vector ov_org = '0 0 0';
1177         vector ov_mid = '0 0 0';
1178         vector ov_worldmin = '0 0 0';
1179         vector ov_worldmax = '0 0 0';
1180         if(autocvar_cl_orthoview)
1181         {
1182                 ov_worldmin = mi_picmin;
1183                 ov_worldmax = mi_picmax;
1184
1185                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1186                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1187                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1188
1189                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1190                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1191
1192                 float ov_nearest = vlen(ov_org - vec3(
1193                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1194                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1195                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1196                 ));
1197
1198                 float ov_furthest = 0;
1199                 float dist = 0;
1200
1201                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1202                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1203                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1204                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1205                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1206                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1207                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1208                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1209
1210                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1211                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1212                 cvar_settemp("r_farclip_world", "0");
1213                 cvar_settemp("r_novis", "1");
1214                 cvar_settemp("r_useportalculling", "0");
1215                 cvar_settemp("r_useinfinitefarclip", "0");
1216
1217                 setproperty(VF_ORIGIN, ov_org);
1218                 setproperty(VF_ANGLES, '90 0 0');
1219
1220                 #if 0
1221                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1222                         vtos(ov_org),
1223                         vtos(getpropertyvec(VF_ANGLES)),
1224                         ov_distance,
1225                         ov_nearest,
1226                         ov_furthest);
1227                 #endif
1228         }
1229
1230         // Render the Scene
1231         view_origin = getpropertyvec(VF_ORIGIN);
1232         view_angles = getpropertyvec(VF_ANGLES);
1233         makevectors(view_angles);
1234         view_forward = v_forward;
1235         view_right = v_right;
1236         view_up = v_up;
1237
1238 #ifdef BLURTEST
1239         if(time > blurtest_time0 && time < blurtest_time1)
1240         {
1241                 float r, t;
1242
1243                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1244                 r = t * blurtest_radius;
1245                 f = 1 / pow(t, blurtest_power) - 1;
1246
1247                 cvar_set("r_glsl_postprocess", "1");
1248                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1249         }
1250         else
1251         {
1252                 cvar_set("r_glsl_postprocess", "0");
1253                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1254         }
1255 #endif
1256
1257         TargetMusic_Advance();
1258         Fog_Force();
1259
1260         if(drawtime == 0)
1261                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1262         else
1263                 drawframetime = bound(0.000001, time - drawtime, 1);
1264         drawtime = time;
1265
1266         // watch for gametype changes here...
1267         // in ParseStuffCMD the cmd isn't executed yet :/
1268         // might even be better to add the gametype to TE_CSQC_INIT...?
1269         if(!postinit)
1270                 PostInit();
1271
1272         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1273         {
1274                 if(calledhooks & HOOK_START)
1275                 {
1276                         localcmd("\ncl_hook_gameend\n");
1277                         calledhooks |= HOOK_END;
1278                 }
1279         }
1280
1281         Announcer();
1282
1283         fov = autocvar_fov;
1284         if(fov <= 59.5)
1285         {
1286                 if(!zoomscript_caught)
1287                 {
1288                         localcmd("+button9\n");
1289                         zoomscript_caught = 1;
1290                 }
1291         }
1292         else
1293         {
1294                 if(zoomscript_caught)
1295                 {
1296                         localcmd("-button9\n");
1297                         zoomscript_caught = 0;
1298                 }
1299         }
1300
1301         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1302
1303         // next WANTED weapon (for HUD)
1304         switchweapon = getstati(STAT_SWITCHWEAPON);
1305
1306         // currently switching-to weapon (for crosshair)
1307         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1308
1309         // actually active weapon (for zoom)
1310         activeweapon = getstati(STAT_ACTIVEWEAPON);
1311
1312         f = (serverflags & SERVERFLAG_TEAMPLAY);
1313         if(f != teamplay)
1314         {
1315                 teamplay = f;
1316                 HUD_InitScores();
1317         }
1318
1319         if(last_switchweapon != switchweapon)
1320         {
1321                 weapontime = time;
1322                 last_switchweapon = switchweapon;
1323                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1324                 {
1325                         localcmd("-zoom\n");
1326                         button_zoom = false;
1327                 }
1328                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1329                 {
1330                         localcmd("-fire\n");
1331                         localcmd("-fire2\n");
1332                         button_attack2 = false;
1333                 }
1334         }
1335         if(last_activeweapon != activeweapon)
1336         {
1337                 last_activeweapon = activeweapon;
1338
1339                 e = get_weaponinfo(activeweapon);
1340                 if(e.netname != "")
1341                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1342                 else
1343                         localcmd("\ncl_hook_activeweapon none\n");
1344         }
1345
1346         // ALWAYS Clear Current Scene First
1347         clearscene();
1348
1349         setproperty(VF_ORIGIN, view_origin);
1350         setproperty(VF_ANGLES, view_angles);
1351
1352         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1353         setproperty(VF_SIZE, vf_size);
1354         setproperty(VF_MIN, vf_min);
1355
1356         // Assign Standard Viewflags
1357         // Draw the World (and sky)
1358         setproperty(VF_DRAWWORLD, 1);
1359
1360         // Set the console size vars
1361         vid_conwidth = autocvar_vid_conwidth;
1362         vid_conheight = autocvar_vid_conheight;
1363         vid_pixelheight = autocvar_vid_pixelheight;
1364
1365         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1366         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1367         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1368
1369         // Camera for demo playback
1370         if(camera_active)
1371         {
1372                 if(autocvar_camera_enable)
1373                         CSQC_Demo_Camera();
1374                 else
1375                 {
1376                         cvar_set("chase_active", ftos(chase_active_backup));
1377                         cvar_set("cl_demo_mousegrab", "0");
1378                         camera_active = false;
1379                 }
1380         }
1381         else
1382         {
1383 #ifdef CAMERATEST
1384                 if(autocvar_camera_enable)
1385 #else
1386                 if(autocvar_camera_enable && isdemo())
1387 #endif
1388                 {
1389                         // Enable required Darkplaces cvars
1390                         chase_active_backup = autocvar_chase_active;
1391                         cvar_set("chase_active", "2");
1392                         cvar_set("cl_demo_mousegrab", "1");
1393                         camera_active = true;
1394                         camera_mode = false;
1395                 }
1396         }
1397
1398         // Draw the Crosshair
1399         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1400
1401         // Draw the Engine Status Bar (the default Quake HUD)
1402         setproperty(VF_DRAWENGINESBAR, 0);
1403
1404         // Update the mouse position
1405         /*
1406            mousepos_x = vid_conwidth;
1407            mousepos_y = vid_conheight;
1408            mousepos = mousepos*0.5 + getmousepos();
1409          */
1410
1411         e = self;
1412         for(self = world; (self = nextent(self)); )
1413                 if(self.draw)
1414                         self.draw();
1415         self = e;
1416
1417         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1418         renderscene();
1419
1420         // now switch to 2D drawing mode by calling a 2D drawing function
1421         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1422         // next R_RenderScene call
1423         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1424
1425         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1426         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1427         {
1428                 // apply night vision effect
1429                 vector tc_00, tc_01, tc_10, tc_11;
1430                 vector rgb = '0 0 0';
1431
1432                 if(!nightvision_noise)
1433                 {
1434                         nightvision_noise = spawn();
1435                         nightvision_noise.classname = "nightvision_noise";
1436                 }
1437                 if(!nightvision_noise2)
1438                 {
1439                         nightvision_noise2 = spawn();
1440                         nightvision_noise2.classname = "nightvision_noise2";
1441                 }
1442
1443                 // color tint in yellow
1444                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1445
1446                 // draw BG
1447                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1448                 rgb = '1 1 1';
1449                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1450                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1451                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1452                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1453                 tc_11 = tc_01 + tc_10 - tc_00;
1454                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1455                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1456                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1457                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1458                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1459                 R_EndPolygon();
1460
1461                 // draw FG
1462                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1463                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1464                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1465                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1466                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1467                 tc_11 = tc_01 + tc_10 - tc_00;
1468                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1469                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1470                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1471                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1472                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1473                 R_EndPolygon();
1474         }
1475
1476         if(autocvar_cl_reticle)
1477         {
1478                 // Draw the aiming reticle for weapons that use it
1479                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1480                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1481                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1482                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1483                 {
1484                         // no zoom reticle while dead
1485                         reticle_type = 0;
1486                 }
1487                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1488                 {
1489                         if(reticle_image != "") { reticle_type = 2; }
1490                         else { reticle_type = 0; }
1491                 }
1492                 else if(button_zoom || zoomscript_caught)
1493                 {
1494                         // normal zoom
1495                         reticle_type = 1;
1496                 }
1497
1498                 if(reticle_type)
1499                 {
1500                         if(autocvar_cl_reticle_stretch)
1501                         {
1502                                 reticle_size.x = vid_conwidth;
1503                                 reticle_size.y = vid_conheight;
1504                                 reticle_pos.x = 0;
1505                                 reticle_pos.y = 0;
1506                         }
1507                         else
1508                         {
1509                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1510                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1511                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1512                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1513                         }
1514
1515                         if(zoomscript_caught)
1516                                 f = 1;
1517                         else
1518                                 f = current_zoomfraction;
1519
1520                         if(f)
1521                         {
1522                                 switch(reticle_type)
1523                                 {
1524                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1525                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1526                                 }
1527                         }
1528                 }
1529         }
1530         else
1531         {
1532                 if(reticle_type != 0) { reticle_type = 0; }
1533         }
1534
1535
1536         // improved polyblend
1537         if(autocvar_hud_contents)
1538         {
1539                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1540                 vector liquidcolor;
1541
1542                 switch(pointcontents(view_origin))
1543                 {
1544                         case CONTENT_WATER:
1545                                 liquidalpha = autocvar_hud_contents_water_alpha;
1546                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1547                                 incontent = 1;
1548                                 break;
1549
1550                         case CONTENT_LAVA:
1551                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1552                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1553                                 incontent = 1;
1554                                 break;
1555
1556                         case CONTENT_SLIME:
1557                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1558                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1559                                 incontent = 1;
1560                                 break;
1561
1562                         default:
1563                                 liquidalpha = 0;
1564                                 liquidcolor = '0 0 0';
1565                                 incontent = 0;
1566                                 break;
1567                 }
1568
1569                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1570                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1571                         contentfadetime = autocvar_hud_contents_fadeintime;
1572                         liquidalpha_prev = liquidalpha;
1573                         liquidcolor_prev = liquidcolor;
1574                 }
1575                 else
1576                         contentfadetime = autocvar_hud_contents_fadeouttime;
1577
1578                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1579                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1580
1581                 if(contentavgalpha)
1582                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1583
1584                 if(autocvar_hud_postprocessing)
1585                 {
1586                         if(autocvar_hud_contents_blur && contentavgalpha)
1587                         {
1588                                 content_blurpostprocess.x = 1;
1589                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1590                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1591                         }
1592                         else
1593                         {
1594                                 content_blurpostprocess.x = 0;
1595                                 content_blurpostprocess.y = 0;
1596                                 content_blurpostprocess.z = 0;
1597                         }
1598                 }
1599         }
1600
1601         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1602         {
1603                 splash_size.x = max(vid_conwidth, vid_conheight);
1604                 splash_size.y = max(vid_conwidth, vid_conheight);
1605                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1606                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1607
1608                 float myhealth_flash_temp;
1609                 myhealth = getstati(STAT_HEALTH);
1610
1611                 // fade out
1612                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1613                 // add new damage
1614                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1615
1616                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1617                 pain_threshold = autocvar_hud_damage_pain_threshold;
1618                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1619                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1620
1621                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1622                 {
1623                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1624                 }
1625
1626                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1627
1628                 if(myhealth_prev < 1)
1629                 {
1630                         if(myhealth >= 1)
1631                         {
1632                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1633                                 myhealth_flash_temp = 0;
1634                         }
1635                         else
1636                         {
1637                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1638                         }
1639                 }
1640
1641                 if(spectatee_status == -1 || intermission)
1642                 {
1643                         myhealth_flash = 0; // observing, or match ended
1644                         myhealth_flash_temp = 0;
1645                 }
1646
1647                 myhealth_prev = myhealth;
1648
1649                 // IDEA: change damage color/picture based on player model for robot/alien species?
1650                 // pro: matches model better
1651                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1652                 // maybe different reddish pics?
1653                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1654                 {
1655                         if(autocvar_cl_gentle_damage == 2)
1656                         {
1657                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1658                                 {
1659                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1660                                 }
1661                         }
1662                         else
1663                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1664
1665                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1666                 }
1667                 else
1668                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1669
1670                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1671                 {
1672                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1673                         {
1674                                 damage_blurpostprocess.x = 1;
1675                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1676                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1677                         }
1678                         else
1679                         {
1680                                 damage_blurpostprocess.x = 0;
1681                                 damage_blurpostprocess.y = 0;
1682                                 damage_blurpostprocess.z = 0;
1683                         }
1684                 }
1685         }
1686
1687         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1688         float e2 = (autocvar_hud_powerup != 0);
1689         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1690         {
1691                 // enable or disable rendering types if they are used or not
1692                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1693                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1694
1695                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1696                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1697                 {
1698                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1699                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1700                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1701                         {
1702                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1703                                 old_blurradius = blurradius;
1704                                 old_bluralpha = bluralpha;
1705                         }
1706                 }
1707                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1708                 {
1709                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1710                         old_blurradius = 0;
1711                         old_bluralpha = 0;
1712                 }
1713
1714                 // edge detection postprocess handling done second (used by hud_powerup)
1715                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1716                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1717                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1718
1719                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1720
1721                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1722                 {
1723                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1724                         {
1725                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1726                                 old_sharpen_intensity = sharpen_intensity;
1727                         }
1728                 }
1729                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1730                 {
1731                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1732                         old_sharpen_intensity = 0;
1733                 }
1734
1735                 if(cvar("r_glsl_postprocess") == 0)
1736                         cvar_set("r_glsl_postprocess", "2");
1737         }
1738         else if(cvar("r_glsl_postprocess") == 2)
1739                 cvar_set("r_glsl_postprocess", "0");
1740
1741         if(menu_visible)
1742                 menu_show();
1743
1744         /*if(gametype == MAPINFO_TYPE_CTF)
1745           {
1746           ctf_view();
1747           } else */
1748
1749         // draw 2D entities
1750         e = self;
1751         for(self = world; (self = nextent(self)); )
1752                 if(self.draw2d)
1753                         self.draw2d();
1754         self = e;
1755         Draw_ShowNames_All();
1756
1757         scoreboard_active = HUD_WouldDrawScoreboard();
1758
1759         UpdateDamage();
1760         UpdateCrosshair();
1761         UpdateHitsound();
1762
1763         if(NextFrameCommand)
1764         {
1765                 localcmd("\n", NextFrameCommand, "\n");
1766                 NextFrameCommand = string_null;
1767         }
1768
1769         // we must do this check AFTER a frame was rendered, or it won't work
1770         if(cs_project_is_b0rked == 0)
1771         {
1772                 string w0, h0;
1773                 w0 = ftos(autocvar_vid_conwidth);
1774                 h0 = ftos(autocvar_vid_conheight);
1775                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1776                 //setproperty(VF_FOV, '90 90 0');
1777                 setproperty(VF_ORIGIN, '0 0 0');
1778                 setproperty(VF_ANGLES, '0 0 0');
1779                 setproperty(VF_PERSPECTIVE, 1);
1780                 makevectors('0 0 0');
1781                 vector v1, v2;
1782                 cvar_set("vid_conwidth", "800");
1783                 cvar_set("vid_conheight", "600");
1784                 v1 = cs_project(v_forward);
1785                 cvar_set("vid_conwidth", "640");
1786                 cvar_set("vid_conheight", "480");
1787                 v2 = cs_project(v_forward);
1788                 if(v1 == v2)
1789                         cs_project_is_b0rked = 1;
1790                 else
1791                         cs_project_is_b0rked = -1;
1792                 cvar_set("vid_conwidth", w0);
1793                 cvar_set("vid_conheight", h0);
1794         }
1795
1796         if(autocvar__hud_configure)
1797                 HUD_Panel_Mouse();
1798
1799     if(hud && !intermission)
1800     {
1801         if(hud == HUD_SPIDERBOT)
1802             CSQC_SPIDER_HUD();
1803         else if(hud == HUD_WAKIZASHI)
1804             CSQC_WAKIZASHI_HUD();
1805         else if(hud == HUD_RAPTOR)
1806             CSQC_RAPTOR_HUD();
1807         else if(hud == HUD_BUMBLEBEE)
1808             CSQC_BUMBLE_HUD();
1809         else if(hud == HUD_BUMBLEBEE_GUN)
1810             CSQC_BUMBLE_GUN_HUD();
1811     }
1812
1813         cl_notice_run();
1814
1815         // let's reset the view back to normal for the end
1816         setproperty(VF_MIN, '0 0 0');
1817         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1818 }
1819
1820
1821 void CSQC_common_hud(void)
1822 {
1823         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1824                 Accuracy_LoadLevels();
1825
1826         HUD_Main(); // always run these functions for alpha checks
1827         HUD_DrawScoreboard();
1828
1829         if (scoreboard_active) // scoreboard/accuracy
1830                 HUD_Reset();
1831         else if (intermission == 2) // map voting screen
1832         {
1833                 MapVote_Draw();
1834                 HUD_Reset();
1835         }
1836 }
1837
1838
1839 // following vectors must be global to allow seamless switching between camera modes
1840 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1841 void CSQC_Demo_Camera()
1842 {
1843         float speed, attenuation, dimensions;
1844         vector tmp, delta;
1845
1846         if( autocvar_camera_reset || !camera_mode )
1847         {
1848                 camera_offset = '0 0 0';
1849                 current_angles = '0 0 0';
1850                 camera_direction = '0 0 0';
1851                 camera_offset.z += 30;
1852                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1853                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1854                 current_origin = view_origin;
1855                 current_camera_offset  = camera_offset;
1856                 cvar_set("camera_reset", "0");
1857                 camera_mode = CAMERA_CHASE;
1858         }
1859
1860         // Camera angles
1861         if( camera_roll )
1862                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1863
1864         if(autocvar_camera_look_player)
1865         {
1866                 vector dir;
1867                 float n;
1868
1869                 dir = normalize(view_origin - current_position);
1870                 n = mouse_angles.z;
1871                 mouse_angles = vectoangles(dir);
1872                 mouse_angles.x = mouse_angles.x * -1;
1873                 mouse_angles.z = n;
1874         }
1875         else
1876         {
1877                 tmp = getmousepos() * 0.1;
1878                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1879                 {
1880                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1881                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1882                 }
1883         }
1884
1885         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1886         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1887         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1888         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1889
1890         // Fix difference when angles don't have the same sign
1891         delta = '0 0 0';
1892         if(mouse_angles.y < -60 && current_angles.y > 60)
1893                 delta = '0 360 0';
1894         if(mouse_angles.y > 60 && current_angles.y < -60)
1895                 delta = '0 -360 0';
1896
1897         if(autocvar_camera_look_player)
1898                 attenuation = autocvar_camera_look_attenuation;
1899         else
1900                 attenuation = autocvar_camera_speed_attenuation;
1901
1902         attenuation = 1 / max(1, attenuation);
1903         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1904
1905         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1906         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1907         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1908         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1909
1910         // Camera position
1911         tmp = '0 0 0';
1912         dimensions = 0;
1913
1914         if( camera_direction.x )
1915         {
1916                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1917                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1918                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1919                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1920                 ++dimensions;
1921         }
1922
1923         if( camera_direction.y )
1924         {
1925                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1926                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1927                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1928                 ++dimensions;
1929         }
1930
1931         if( camera_direction.z )
1932         {
1933                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1934                 ++dimensions;
1935         }
1936
1937         if(autocvar_camera_free)
1938                 speed = autocvar_camera_speed_free;
1939         else
1940                 speed = autocvar_camera_speed_chase;
1941
1942         if(dimensions)
1943         {
1944                 speed = speed * sqrt(1 / dimensions);
1945                 camera_offset += tmp * speed;
1946         }
1947
1948         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1949
1950         // Camera modes
1951         if( autocvar_camera_free )
1952         {
1953                 if ( camera_mode == CAMERA_CHASE )
1954                 {
1955                         current_camera_offset = current_origin + current_camera_offset;
1956                         camera_offset = current_origin + camera_offset;
1957                 }
1958
1959                 camera_mode = CAMERA_FREE;
1960                 current_position = current_camera_offset;
1961         }
1962         else
1963         {
1964                 if ( camera_mode == CAMERA_FREE )
1965                 {
1966                         current_origin = view_origin;
1967                         camera_offset = camera_offset - current_origin;
1968                         current_camera_offset = current_camera_offset - current_origin;
1969                 }
1970
1971                 camera_mode = CAMERA_CHASE;
1972
1973                 if(autocvar_camera_chase_smoothly)
1974                         current_origin += (view_origin - current_origin) * attenuation;
1975                 else
1976                         current_origin = view_origin;
1977
1978                 current_position = current_origin + current_camera_offset;
1979         }
1980
1981         setproperty(VF_ANGLES, current_angles);
1982         setproperty(VF_ORIGIN, current_position);
1983 }