qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.sameteam = player is on same team as local client
   6 // self.fadedelay = time to wait before name tag starts fading in for enemies
   7 // self.pointtime = last time you pointed at this player
   8 // self.csqcmodel_isdead = value of csqcmodel_isdead to know when the player is dead or not
   9
  10 const float SHOWNAMES_FADESPEED = 4;
  11 const float SHOWNAMES_FADEDELAY = 0.4;
  12 void Draw_ShowNames(entity ent)
  13 {
  14         if(!autocvar_hud_shownames)
  15                 return;
  16
  17 #ifdef COMPAT_XON050_ENGINE
  18         if((ent.sv_entnum == player_localentnum) || (ent.sv_entnum == spectatee_status)) // ent is me or person i'm spectating
  19 #else
  20         if(ent.sv_entnum == player_localentnum) // ent is me or person i'm spectating
  21 #endif
  22                 if not (autocvar_hud_shownames_self && autocvar_chase_active)
  23                         return;
  24
  25         makevectors(view_angles);
  26
  27         if(ent.sameteam || (!ent.sameteam && autocvar_hud_shownames_enemies))
  28         {
  29                 ent.origin_z += autocvar_hud_shownames_offset;
  30
  31                 float hit;
  32                 if(ent.sameteam && !autocvar_hud_shownames_crosshairdistance)
  33                 {
  34                         hit = 1;
  35                 }
  36                 else
  37                 {
  38                         traceline(view_origin, ent.origin, MOVE_NORMAL, ent);
  39                         if(trace_fraction < 1 && (trace_networkentity != ent.sv_entnum && trace_ent.entnum != ent.sv_entnum))
  40                                 hit = 0;
  41                         else
  42                                 hit = 1;
  43                 }
  44
  45                 // handle tag fading
  46                 float overlap = FALSE, onscreen, crosshairdistance;
  47                 vector o, eo;
  48
  49                 o = project_3d_to_2d(ent.origin);
  50
  51                 if(autocvar_hud_shownames_antioverlap)
  52                 {
  53                         // fade tag out if another tag that is closer to you overlaps
  54                         entity e;
  55                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  56                         {
  57                                 if(e == ent)
  58                                         continue;
  59                                 eo = project_3d_to_2d(e.origin);
  60                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  61                                 {
  62                                         eo_z = 0;
  63                                         if(vlen((eX * o_x + eY * o_y) - eo) < autocvar_hud_shownames_antioverlap_distance && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  64                                         {
  65                                                 overlap = TRUE;
  66                                                 break;
  67                                         }
  68                                 }
  69                         }
  70                 }
  71
  72                 onscreen = (o_z >= 0 && o_x >= 0 && o_y >= 0 && o_x <= vid_conwidth && o_y <= vid_conheight);
  73                 crosshairdistance = sqrt( pow(o_x - vid_conwidth/2, 2) + pow(o_y - vid_conheight/2, 2) );
  74
  75                 if(autocvar_hud_shownames_crosshairdistance)
  76                 {
  77                         if(autocvar_hud_shownames_crosshairdistance > crosshairdistance)
  78                                 ent.pointtime = time;
  79
  80                         if not(ent.pointtime + autocvar_hud_shownames_crosshairdistance_time > time)
  81                                 overlap = TRUE;
  82                         else
  83                                 overlap = (autocvar_hud_shownames_crosshairdistance_antioverlap ? overlap : FALSE); // override what antioverlap says unless allowed by cvar.
  84                 }
  85
  86                 if(!ent.fadedelay)
  87                         ent.fadedelay = time + SHOWNAMES_FADEDELAY;
  88
  89                 if(!ent.sameteam && (!onscreen || !hit)) // out of view, fade out
  90                 {
  91                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  92                         ent.fadedelay = 0; // reset fade in delay, enemy has left the view
  93                 }
  94                 else if(ent.csqcmodel_isdead) // dead player, fade out slowly
  95                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  96                 else if(overlap) // tag overlap detected, fade out
  97                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  98                 else if(ent.sameteam) // fade in for team mates
  99                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
 100                 else if(time > ent.fadedelay) // fade in for enemies
 101                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
 102
 103                 if(!ent.alpha)
 104                         return;
 105
 106                 float dist;
 107                 dist = vlen(ent.origin - view_origin);
 108
 109                 float a;
 110                 a = autocvar_hud_shownames_alpha;
 111                 a *= ent.alpha;
 112                 if(autocvar_hud_shownames_maxdistance)
 113                 {
 114                         if(dist >= autocvar_hud_shownames_maxdistance)
 115                                 return;
 116                         a *= ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
 117                 }
 118
 119                 if(!a)
 120                         return;
 121
 122                 float resize;
 123                 resize = 1;
 124                 if(autocvar_hud_shownames_resize) // limit resize so its never smaller than 0.5... gets unreadable
 125                         resize = 0.5 + 0.5 * ((autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance) - max(0, dist - autocvar_hud_shownames_mindistance)) / (autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance);
 126
 127                 // draw the sprite image
 128                 if(o_z >= 0)
 129                 {
 130                         o_z = 0;
 131
 132                         vector myPos, mySize;
 133                         mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
 134                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
 135
 136                         // size scaling
 137                         mySize_x *= resize;
 138                         mySize_y *= resize;
 139
 140                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 141                         myPos_y += (mySize_y / resize - mySize_y);
 142
 143                         vector namepos; // this is where the origin of the string
 144                         float namewidth;
 145
 146                         namepos = myPos;
 147                         namewidth = mySize_x;
 148
 149                         if(autocvar_hud_shownames_status && teamplay)
 150                         {
 151                                 if(ent.sameteam)
 152                                 {
 153                                         if(ent.healthvalue > 0)
 154                                         {
 155                                                 HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.healthvalue/autocvar_hud_panel_healtharmor_maxhealth, 0, 1, '1 0 0', a, DRAWFLAG_NORMAL);
 156
 157                                                 if(ent.armorvalue > 0)
 158                                                         HUD_Panel_DrawProgressBar(namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize + eX * 0.5 * mySize_x, eX * 0.5 * mySize_x + eY * resize * autocvar_hud_shownames_statusbar_height, "nametag_statusbar", ent.armorvalue/autocvar_hud_panel_healtharmor_maxarmor, 0, 0, '0 1 0', a, DRAWFLAG_NORMAL);
 159                                         }
 160                                 }
 161                         }
 162
 163                         string s;
 164                         s = GetPlayerName(ent.sv_entnum-1);
 165                         if((autocvar_hud_shownames_decolorize == 1 && teamplay) || autocvar_hud_shownames_decolorize == 2)
 166                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 167
 168                         drawfontscale = '1 1 0' * resize;
 169                         s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
 170
 171                         float width;
 172                         width = stringwidth(s, TRUE, '1 1 0' * autocvar_hud_shownames_fontsize);
 173
 174                         if (width != namewidth)
 175                                 namepos_x += (namewidth - width) / 2;
 176                         drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
 177                         drawfontscale = '1 1 0';
 178                 }
 179         }
 180 }
 181
 182 entity shownames_ent[255];
 183 void Draw_ShowNames_All()
 184 {
 185         float i;
 186         for(i = 0; i < maxclients; ++i)
 187         {
 188                 float t;
 189                 t = GetPlayerColor(i);
 190                 if(t == FL_SPECTATOR)
 191                         continue;
 192
 193                 entity e;
 194                 e = shownames_ent[i];
 195                 if(!e)
 196                 {
 197                         e = spawn();
 198                         e.classname = "shownames_tag";
 199                         e.sv_entnum = i+1;
 200                         shownames_ent[i] = e;
 201                 }
 202
 203                 entity entcs;
 204                 entcs = entcs_receiver[i];
 205                 if(entcs)
 206                 {
 207                         e.healthvalue = entcs.healthvalue;
 208                         e.armorvalue = entcs.armorvalue;
 209                         e.sameteam = 1; /* (teamplay && (t == myteam)); */
 210                 }
 211                 else
 212                 {
 213                         e.healthvalue = 2342;
 214                         e.armorvalue = 0;
 215                         e.sameteam = 0;
 216                 }
 217
 218                 setorigin(e, getplayerorigin(i));
 219                 if(e.origin == GETPLAYERORIGIN_ERROR)
 220                         continue;
 221
 222                 e.csqcmodel_isdead = getplayerisdead(i);
 223
 224                 Draw_ShowNames(e);
 225         }
 226 }