qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.sameteam = player is on same team as local client
   6 //
   7 void Draw_ShowNames()
   8 {
   9     if(!autocvar_hud_shownames)
  10         return;
  11
  12     if(self.sameteam || (!self.sameteam && autocvar_hud_shownames_enemies))
  13     {
  14         float a;
  15         a = autocvar_hud_panel_fg_alpha;
  16
  17         InterpolateOrigin_Do();
  18
  19         // draw the sprite image
  20         vector o;
  21         o = project_3d_to_2d(self.origin);
  22
  23         if not(o_z < 0 || o_x < 0 || o_y < 0 || o_x > vid_conwidth || o_y > vid_conheight)
  24         {
  25             o_z = 0;
  26
  27             vector myPos, mySize;
  28             mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_height;
  29             myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
  30
  31             vector iconpos, iconsize;
  32             vector namepos;
  33             float namesize;
  34
  35             iconpos = myPos;
  36
  37             if(autocvar_hud_shownames_status)
  38             {
  39                 if(self.sameteam)
  40                 {
  41                     iconsize = eX * 2 * mySize_y + eY * mySize_y;
  42                     // "ghost" backgrounds
  43                     drawpic_aspect_skin(iconpos, "health", '1 1 0' * iconsize_y, '0 0 0', a * 0.5, DRAWFLAG_NORMAL);
  44                     drawpic_aspect_skin(iconpos + '0.5 0 0' * iconsize_x, "armor", '1 1 0' * iconsize_y, '0 0 0', a * 0.5, DRAWFLAG_NORMAL);
  45
  46                     drawsetcliparea(0, myPos_y + iconsize_y - iconsize_y * min(1, self.healthvalue/autocvar_hud_panel_healtharmor_maxhealth), vid_conwidth, myPos_y + iconsize_y);
  47                     drawpic_aspect_skin(iconpos, "health", '1 1 0' * iconsize_y, '1 1 1', a, DRAWFLAG_NORMAL);
  48
  49                     drawsetcliparea(0, myPos_y + iconsize_y - iconsize_y * min(1, self.armorvalue/autocvar_hud_panel_healtharmor_maxarmor), vid_conwidth, myPos_y + iconsize_y);
  50                     drawpic_aspect_skin(iconpos + '0.5 0 0' * iconsize_x, "armor", '1 1 0' * iconsize_y, '1 1 1', a, DRAWFLAG_NORMAL);
  51                     drawresetcliparea();
  52                 }
  53                 else if(autocvar_hud_shownames_status == 2)
  54                 {
  55                     iconsize = eX * 2 * mySize_y + eY * mySize_y;
  56                     drawpic_aspect_skin(iconpos, "health_unknown", '1 1 0' * iconsize_y, '0 0 0', a, DRAWFLAG_NORMAL);
  57                     drawpic_aspect_skin(iconpos + '0.5 0 0' * iconsize_x, "armor_unknown", '1 1 0' * iconsize_y, '0 0 0', a, DRAWFLAG_NORMAL);
  58                 }
  59             }
  60
  61             namepos = myPos + eX * 2 * iconsize_y + eY * 0.5 * (autocvar_hud_shownames_height - autocvar_hud_shownames_fontsize);
  62             namesize = mySize_x - 2 * iconsize_y;
  63
  64             string s;
  65             s = GetPlayerName(self.the_entnum-1);
  66             s = textShortenToWidth(s, namesize, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
  67             drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
  68
  69             /* Or maybe a health bar instead?
  70              *
  71             if(self.health >= 0)
  72             {
  73                 float align;
  74                 if(self.build_finished)
  75                     align = 0.5;
  76                 else
  77                     align = 0;
  78                 drawhealthbar(o, rot * 90 * DEG2RAD, self.health, SPRITE_SIZE * t, SPRITE_HOTSPOT * t, SPRITE_HEALTHBAR_WIDTH * t, SPRITE_HEALTHBAR_HEIGHT * t, SPRITE_HEALTHBAR_MARGIN * t, SPRITE_HEALTHBAR_BORDER * t, align, self.teamradar_color, a * SPRITE_HEALTHBAR_BORDERALPHA, self.teamradar_color, a * SPRITE_HEALTHBAR_HEALTHALPHA, DRAWFLAG_NORMAL);
  79             }
  80             */
  81         }
  82     }
  83 }