qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5 #include "scoreboard.qh"
   6
   7 #include "../common/mapinfo.qh"
   8 #include "../common/util.qh"
   9
  10 #include "../dpdefs/keycodes.qh"
  11
  12
  13 int mv_num_maps;
  14
  15 float mv_active;
  16 string mv_maps[MAPVOTE_COUNT];
  17 string mv_pics[MAPVOTE_COUNT];
  18 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  19 string mv_desc[MAPVOTE_COUNT];
  20 float mv_preview[MAPVOTE_COUNT];
  21 float mv_votes[MAPVOTE_COUNT];
  22 float mv_flags[MAPVOTE_COUNT];
  23 float mv_flags_start[MAPVOTE_COUNT];
  24 entity mv_pk3list;
  25 float mv_abstain;
  26 float mv_ownvote;
  27 float mv_detail;
  28 float mv_timeout;
  29 float mv_top2_time;
  30 float mv_top2_alpha;
  31
  32 vector mv_mousepos;
  33 int mv_selection;
  34 int mv_columns;
  35 int mv_mouse_selection;
  36 int mv_selection_keyboard;
  37
  38 float gametypevote;
  39 string mapvote_chosenmap;
  40 vector gtv_text_size;
  41 vector gtv_text_size_small;
  42
  43 const int NUM_SSDIRS = 4;
  44 string ssdirs[NUM_SSDIRS];
  45 int n_ssdirs;
  46
  47 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  48 {
  49         string pre, post;
  50         pre = sprintf("%d. ", id+1);
  51         if(mv_detail)
  52         {
  53                 if(_count == 1)
  54                         post = _(" (1 vote)");
  55                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  56                         post = sprintf(_(" (%d votes)"), _count);
  57                 else
  58                         post = "";
  59         }
  60         else
  61                 post = "";
  62         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  63         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  64         return strcat(pre, map, post);
  65 }
  66
  67 vector MapVote_RGB(int id)
  68 {
  69         if(!(mv_flags[id] & GTV_AVAILABLE))
  70                 return '1 1 1';
  71         if(id == mv_ownvote)
  72                 return '0 1 0';
  73         else if (id == mv_selection)
  74                 return '1 1 0';
  75         else
  76                 return '1 1 1';
  77 }
  78
  79 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  80 {
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89
  90         // Bounding box details
  91         float rect_margin = hud_fontsize.y / 2;
  92         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  93         vector rect_size = '1 1 0';
  94         rect_size.x = tsize + rect_margin;
  95         rect_size.y = maxh + rect_margin;
  96
  97         // Highlight selected item
  98         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
  99         {
 100                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 101         }
 102
 103         // Highlight current vote
 104         vector rgb = MapVote_RGB(id);
 105         if(id == mv_ownvote)
 106         {
 107                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
 108                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 109         }
 110
 111         vector offset = pos;
 112
 113         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 114         pos.y += title_gap;
 115         maxh -= title_gap;
 116
 117         // Evaluate the image size
 118         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 119         if ( maxh < image_size.y )
 120                 image_size = '1 1 0' * maxh;
 121         image_size *= 0.8;
 122         if(pic == "")
 123                 image_size = '0 0 0';
 124         float desc_padding = gtv_text_size.x * 0.6;
 125         pos.x += image_size.x + desc_padding;
 126         tsize -= image_size.x + desc_padding;
 127
 128         // Split the description into lines
 129         entity title;
 130         title = spawn();
 131         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 132
 133         string thelabel = mv_desc[id], ts;
 134         entity last = title;
 135         entity next = world;
 136         float nlines = 0;
 137         if( thelabel != "")
 138         {
 139                 float i,n = tokenizebyseparator(thelabel, "\n");
 140                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 141                 {
 142                         getWrappedLine_remaining = argv(i);
 143                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 144                         {
 145                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 146                                 if (ts != "")
 147                                 {
 148                                         next = spawn();
 149                                         next.message = ts;
 150                                         next.origin = pos-offset;
 151                                         last.chain = next;
 152                                         last = next;
 153                                         pos.y += gtv_text_size_small.y;
 154                                         nlines++;
 155                                 }
 156                         }
 157                 }
 158         }
 159
 160         // Center the contents in the bounding box
 161         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 162         if ( maxh > 0 )
 163                 offset.y += maxh/2;
 164
 165         // Draw the title
 166         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 167
 168         // Draw the icon
 169         if(pic != "")
 170                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 171
 172         // Draw the description
 173         for ( last = title.chain; last ; )
 174         {
 175                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 176                 next = last;
 177                 last = last.chain;
 178                 remove(next);
 179         }
 180
 181         // Cleanup
 182         remove(title);
 183 }
 184
 185 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 186 {
 187         vector img_size = '0 0 0';
 188         vector rgb;
 189         string label;
 190         float text_size;
 191
 192         isize -= hud_fontsize.y; // respect the text when calculating the image size
 193
 194         rgb = MapVote_RGB(id);
 195
 196         img_size.y = isize;
 197         img_size.x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
 198
 199         pos.y = pos.y + img_size.y;
 200
 201         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 202
 203         text_size = stringwidth(label, false, hud_fontsize);
 204
 205         float theAlpha;
 206         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 207                 theAlpha = mv_top2_alpha;
 208         else
 209                 theAlpha = 1;
 210
 211         pos.x -= text_size*0.5;
 212         drawstring(pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 213
 214         pos.x = pos.x + text_size*0.5 - img_size.x*0.5;
 215         pos.y = pos.y - img_size.y;
 216
 217         pos += autocvar_scoreboard_border_thickness * '1 1 0';
 218         img_size -= (autocvar_scoreboard_border_thickness * 2) * '1 1 0';
 219         if(pic == "")
 220         {
 221                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 222         }
 223         else
 224         {
 225                 if(drawgetimagesize(pic) == '0 0 0')
 226                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 227                 else
 228                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 229         }
 230
 231         if(id == mv_ownvote)
 232                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 233         else
 234                 drawborderlines(autocvar_scoreboard_border_thickness, pos, img_size, '0 0 0', theAlpha, DRAWFLAG_NORMAL);
 235
 236         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 237                 drawfill(pos, img_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
 238 }
 239
 240 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 241 {
 242         vector rgb;
 243         float text_size;
 244         string label;
 245
 246         rgb = MapVote_RGB(id);
 247
 248         pos.y = pos.y + hud_fontsize.y;
 249
 250         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 251
 252         text_size = stringwidth(label, false, hud_fontsize);
 253
 254         pos.x -= text_size*0.5;
 255         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 256 }
 257
 258 vector MapVote_GridVec(vector gridspec, int i, int m)
 259 {
 260         int r = i % m;
 261         return
 262                 '1 0 0' * (gridspec.x * r)
 263                 +
 264                 '0 1 0' * (gridspec.y * (i - r) / m);
 265 }
 266
 267 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 268 {
 269
 270         float c, r;
 271
 272         mv_mouse_selection = -1;
 273
 274         for (r = 0; r < rows; ++r)
 275                 for (c = 0; c < columns; ++c)
 276                 {
 277                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 278                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 279                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 280                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 281                         {
 282                                 mv_mouse_selection = r * columns + c;
 283                                 break;
 284                         }
 285                 }
 286
 287         if (mv_mouse_selection >= mv_num_maps)
 288                 mv_mouse_selection = -1;
 289
 290         if (mv_abstain && mv_mouse_selection < 0)
 291                 mv_mouse_selection = mv_num_maps;
 292
 293         if ( mv_selection_keyboard )
 294                 return mv_selection;
 295
 296         return mv_mouse_selection;
 297 }
 298
 299 void MapVote_Draw()
 300 {
 301         string map;
 302         int i;
 303         float tmp;
 304         vector pos;
 305         float isize;
 306         float center;
 307         float rows;
 308         float tsize;
 309         vector dist = '0 0 0';
 310
 311         if(!mv_active)
 312                 return;
 313
 314         if (!autocvar_hud_cursormode)
 315         {
 316                 vector mpos = mv_mousepos + getmousepos();
 317                 mpos.x = bound(0, mpos.x, vid_conwidth);
 318                 mpos.y = bound(0, mpos.y, vid_conheight);
 319
 320                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 321                         mv_selection_keyboard = 0;
 322                 mv_mousepos = mpos;
 323
 324         }
 325
 326         center = (vid_conwidth - 1)/2;
 327         xmin = vid_conwidth*0.05; // 5% border must suffice
 328         xmax = vid_conwidth - xmin;
 329         ymin = 20;
 330         i = autocvar_con_chatpos; //*autocvar_con_chatsize;
 331         if(i < 0)
 332                 ymax = vid_conheight + (i - autocvar_con_chat) * autocvar_con_chatsize;
 333         if(i >= 0 || ymax < (vid_conheight*0.5))
 334                 ymax = vid_conheight - ymin;
 335
 336         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 337
 338         pos.y = ymin;
 339         pos.z = 0;
 340
 341         draw_beginBoldFont();
 342         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 343         pos.x = center - stringwidth(map, false, '12 0 0');
 344         drawstring(pos, map, '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 345         pos.y += 26;
 346
 347         if( mapvote_chosenmap != "" )
 348         {
 349                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize*1.5/2);
 350                 drawstring(pos, mapvote_chosenmap, hud_fontsize*1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
 351                 pos.y += hud_fontsize.y*2;
 352         }
 353
 354         i = ceil(max(0, mv_timeout - time));
 355         map = sprintf(_("%d seconds left"), i);
 356         pos.x = center - stringwidth(map, false, '8 0 0');
 357         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 358         pos.y += 22;
 359         pos.x = xmin;
 360         draw_endBoldFont();
 361
 362         // base for multi-column stuff...
 363         ymin = pos.y;
 364         if(mv_abstain)
 365                 mv_num_maps -= 1;
 366
 367         rows = ceil(mv_num_maps / mv_columns);
 368
 369         dist.x = (xmax - xmin) / mv_columns;
 370         dist.y = (ymax - pos.y) / rows;
 371
 372         if ( gametypevote )
 373         {
 374                 tsize = dist.x - hud_fontsize.y;
 375                 isize = dist.y;
 376                 float maxheight = (ymax - pos.y) / 3;
 377                 if ( isize > maxheight )
 378                 {
 379                         pos.x += (isize - maxheight)/2;
 380                         isize = maxheight;
 381                 }
 382                 else
 383                         dist.y += hud_fontsize.y;
 384                 pos.x = ( vid_conwidth - dist.x * mv_columns ) / 2;
 385         }
 386         else
 387         {
 388                 tsize = dist.x - 10;
 389                 isize = min(dist.y - 10, 0.75 * tsize);
 390         }
 391
 392         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 393
 394         if ( !gametypevote )
 395                 pos.x += dist.x / 2;
 396         pos.y += (dist.y - isize) / 2;
 397         ymax -= isize;
 398
 399         if (mv_top2_time)
 400                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 401
 402         void (vector, float, float, string, string, float, float) DrawItem;
 403
 404         if(gametypevote)
 405                 DrawItem = GameTypeVote_DrawGameTypeItem;
 406         else
 407                 DrawItem = MapVote_DrawMapItem;
 408
 409         for(i = 0; i < mv_num_maps; ++i)
 410         {
 411                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 412                 map = mv_maps[i];
 413                 if(mv_preview[i])
 414                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, mv_pics[i], tmp, i);
 415                 else
 416                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), isize, tsize, map, "", tmp, i);
 417         }
 418
 419         if(mv_abstain)
 420                 ++mv_num_maps;
 421
 422         if(mv_abstain && i < mv_num_maps) {
 423                 tmp = mv_votes[i];
 424                 pos.y = ymax + isize - hud_fontsize.y;
 425                 pos.x = (xmax+xmin)*0.5;
 426                 MapVote_DrawAbstain(pos, isize, xmax - xmin, tmp, i);
 427         }
 428
 429         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
 430 }
 431
 432 void Cmd_MapVote_MapDownload(float argc)
 433 {
 434         entity pak;
 435
 436         if(argc != 2 || !mv_pk3list)
 437         {
 438                 print(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 439                 return;
 440         }
 441
 442         int id = stof(argv(1));
 443         for(pak = mv_pk3list; pak; pak = pak.chain)
 444                 if(pak.sv_entnum == id)
 445                         break;
 446
 447         if(!pak || pak.sv_entnum != id) {
 448                 print(_("^1Error:^7 Couldn't find pak index.\n"));
 449                 return;
 450         }
 451
 452         if(PreviewExists(pak.message))
 453         {
 454                 mv_preview[id] = true;
 455                 return;
 456         } else {
 457                 print(_("Requesting preview...\n"));
 458                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 459         }
 460 }
 461
 462 void MapVote_CheckPK3(string pic, string pk3, int id)
 463 {
 464         entity pak;
 465         pak = spawn();
 466         pak.netname = pk3;
 467         pak.message = pic;
 468         pak.sv_entnum = id;
 469
 470         pak.chain = mv_pk3list;
 471         mv_pk3list = pak;
 472
 473         if(pk3 != "")
 474         {
 475                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 476         }
 477         else
 478         {
 479                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 480         }
 481 }
 482
 483 void MapVote_CheckPic(string pic, string pk3, int id)
 484 {
 485         // never try to retrieve a pic for the "don't care" 'map'
 486         if(mv_abstain && id == mv_num_maps - 1)
 487                 return;
 488
 489         if(PreviewExists(pic))
 490         {
 491                 mv_preview[id] = true;
 492                 return;
 493         }
 494         MapVote_CheckPK3(pic, pk3, id);
 495 }
 496
 497 void MapVote_ReadMask()
 498 {
 499         int i;
 500         if ( mv_num_maps < 24 )
 501         {
 502                 int mask, power;
 503                 if(mv_num_maps < 8)
 504                         mask = ReadByte();
 505                 else if(mv_num_maps < 16)
 506                         mask = ReadShort();
 507                 else
 508                         mask = ReadLong();
 509
 510                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 511                 {
 512                         if ( mask & power )
 513                                 mv_flags[i] |= GTV_AVAILABLE;
 514                         else
 515                                 mv_flags[i] &= ~GTV_AVAILABLE;
 516                 }
 517         }
 518         else
 519         {
 520                 for(i = 0; i < mv_num_maps; ++i )
 521                         mv_flags[i] = ReadByte();
 522         }
 523 }
 524
 525 void MapVote_ReadOption(int i)
 526 {
 527         string map = strzone(ReadString());
 528         string pk3 = strzone(ReadString());
 529         int j = bound(0, ReadByte(), n_ssdirs - 1);
 530
 531         mv_maps[i] = map;
 532         mv_pk3[i] = pk3;
 533         mv_flags[i] = GTV_AVAILABLE;
 534
 535         string pic = strzone(strcat(ssdirs[j], "/", map));
 536         mv_pics[i] = pic;
 537         mv_preview[i] = false;
 538         MapVote_CheckPic(pic, pk3, i);
 539 }
 540
 541 void GameTypeVote_ReadOption(int i)
 542 {
 543         string gt = strzone(ReadString());
 544
 545         mv_maps[i] = gt;
 546         mv_flags[i] = ReadByte();
 547
 548         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 549         if(precache_pic(mv_picpath) == "")
 550                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 551         string pic = strzone(mv_picpath);
 552         mv_pics[i] = pic;
 553         mv_preview[i] = PreviewExists(pic);
 554
 555         if ( mv_flags[i] & GTV_CUSTOM )
 556         {
 557                 string name = ReadString();
 558                 if ( strlen(name) < 1 )
 559                         name = gt;
 560                 mv_pk3[i] = strzone(name);
 561                 mv_desc[i] = strzone(ReadString());
 562         }
 563         else
 564         {
 565                 int type = MapInfo_Type_FromString(gt);
 566                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 567                 mv_desc[i] = MapInfo_Type_Description(type);
 568         }
 569 }
 570
 571 void MapVote_Init()
 572 {
 573         precache_sound ("misc/invshot.wav");
 574
 575         mv_active = 1;
 576         if(autocvar_hud_cursormode) { setcursormode(1); }
 577         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 578         mv_selection = -1;
 579         mv_selection_keyboard = 0;
 580
 581         string s;
 582         for(n_ssdirs = 0; ; ++n_ssdirs)
 583         {
 584                 s = ReadString();
 585                 if(s == "")
 586                         break;
 587                 if(n_ssdirs < NUM_SSDIRS)
 588                         ssdirs[n_ssdirs] = s;
 589         }
 590         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 591
 592         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 593         mv_abstain = ReadByte();
 594         if(mv_abstain)
 595                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 596         mv_detail = ReadByte();
 597
 598         mv_ownvote = -1;
 599         mv_timeout = ReadCoord();
 600
 601         gametypevote = ReadByte();
 602
 603         float mv_real_num_maps = mv_num_maps - mv_abstain;
 604
 605         if(gametypevote)
 606         {
 607                 mapvote_chosenmap = strzone(ReadString());
 608                 if ( gametypevote == 2 )
 609                         gametypevote = 0;
 610
 611                 gtv_text_size = hud_fontsize*1.4;
 612                 gtv_text_size_small = hud_fontsize*1.1;
 613
 614                 if (mv_real_num_maps > 8 )
 615                         mv_columns = 3;
 616                 else
 617                         mv_columns = min(2, mv_real_num_maps);
 618     }
 619     else
 620         {
 621                 if (mv_real_num_maps > 16)
 622                         mv_columns = 5;
 623                 else if (mv_real_num_maps > 9)
 624                         mv_columns = 4;
 625                 else if(mv_real_num_maps > 3)
 626                         mv_columns = 3;
 627                 else
 628                         mv_columns = mv_real_num_maps;
 629         }
 630
 631         MapVote_ReadMask();
 632         int i;
 633         for(i = 0; i < mv_num_maps; ++i )
 634                 mv_flags_start[i] = mv_flags[i];
 635
 636         // Assume mv_pk3list is world, there should only be 1 mapvote per round
 637         mv_pk3list = world; // I'm still paranoid!
 638
 639         for(i = 0; i < mv_num_maps; ++i)
 640         {
 641                 mv_votes[i] = 0;
 642
 643                 if ( gametypevote )
 644                         GameTypeVote_ReadOption(i);
 645                 else
 646                         MapVote_ReadOption(i);
 647         }
 648
 649         for(i = 0; i < n_ssdirs; ++i)
 650                 ssdirs[n_ssdirs] = string_null;
 651         n_ssdirs = 0;
 652 }
 653
 654 void MapVote_SendChoice(float index)
 655 {
 656         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 657 }
 658
 659 int MapVote_MoveLeft(int pos)
 660 {
 661         int imp;
 662         if ( pos < 0 )
 663                 imp = mv_num_maps - 1;
 664         else
 665                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 666         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 667                 imp = MapVote_MoveLeft(imp);
 668         return imp;
 669 }
 670 int MapVote_MoveRight(int pos)
 671 {
 672         int imp;
 673         if ( pos < 0 )
 674                 imp = 0;
 675         else
 676                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 677         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 678                 imp = MapVote_MoveRight(imp);
 679         return imp;
 680 }
 681 int MapVote_MoveUp(int pos)
 682 {
 683         int imp;
 684         if ( pos < 0 )
 685                 imp = mv_num_maps - 1;
 686         else
 687         {
 688                 imp = pos - mv_columns;
 689                 if ( imp < 0 )
 690                 {
 691                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 692                         if ( imp >= mv_num_maps )
 693                                 imp -= mv_columns;
 694                 }
 695         }
 696         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 697                 imp = MapVote_MoveUp(imp);
 698         return imp;
 699 }
 700 int MapVote_MoveDown(int pos)
 701 {
 702         int imp;
 703         if ( pos < 0 )
 704                 imp = 0;
 705         else
 706         {
 707                 imp = pos + mv_columns;
 708                 if ( imp >= mv_num_maps )
 709                         imp = imp % mv_columns;
 710         }
 711         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 712                 imp = MapVote_MoveDown(imp);
 713         return imp;
 714 }
 715
 716 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
 717 {
 718         float imp;
 719
 720         if (!mv_active)
 721                 return false;
 722
 723         if(bInputType == 3)
 724         {
 725                 mv_mousepos.x = nPrimary;
 726                 mv_mousepos.y = nSecondary;
 727                 mv_selection_keyboard = 0;
 728                 return true;
 729         }
 730
 731         if (bInputType != 0)
 732                 return false;
 733
 734         if ('0' <= nPrimary && nPrimary <= '9')
 735         {
 736                 imp = nPrimary - '0';
 737                 if (imp == 0) imp = 10;
 738                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 739                 return true;
 740         }
 741         switch(nPrimary)
 742         {
 743                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 744                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 745                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 746                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 747                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 748                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 749                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 750                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 751                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 752                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 753
 754                 case K_RIGHTARROW:
 755                         mv_selection_keyboard = 1;
 756                         mv_selection = MapVote_MoveRight(mv_selection);
 757                         return true;
 758                 case K_LEFTARROW:
 759                         mv_selection_keyboard = 1;
 760                         mv_selection = MapVote_MoveLeft(mv_selection);
 761                         return true;
 762                 case K_DOWNARROW:
 763                         mv_selection_keyboard = 1;
 764                         mv_selection = MapVote_MoveDown(mv_selection);
 765                         return true;
 766                 case K_UPARROW:
 767                         mv_selection_keyboard = 1;
 768                         mv_selection = MapVote_MoveUp(mv_selection);
 769                         return true;
 770                 case K_KP_ENTER:
 771                 case K_ENTER:
 772                 case K_SPACE:
 773                         if ( mv_selection_keyboard )
 774                                 MapVote_SendChoice(mv_selection);
 775                         return true;
 776         }
 777
 778         if (nPrimary == K_MOUSE1)
 779         {
 780                 mv_selection_keyboard = 0;
 781                 mv_selection = mv_mouse_selection;
 782                 if (mv_selection >= 0)
 783                 {
 784                         imp = min(mv_selection + 1, mv_num_maps);
 785                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 786                         return true;
 787                 }
 788         }
 789
 790         return false;
 791 }
 792
 793 void MapVote_UpdateMask()
 794 {
 795         MapVote_ReadMask();
 796         mv_top2_time = time;
 797 }
 798
 799 void MapVote_UpdateVotes()
 800 {
 801         int i;
 802         for(i = 0; i < mv_num_maps; ++i)
 803         {
 804                 if(mv_flags[i] & GTV_AVAILABLE)
 805                 {
 806                         if(mv_detail)
 807                                 mv_votes[i] = ReadByte();
 808                         else
 809                                 mv_votes[i] = 0;
 810                 }
 811                 else
 812                         mv_votes[i] = -1;
 813         }
 814
 815         mv_ownvote = ReadByte()-1;
 816 }
 817
 818 void Ent_MapVote()
 819 {
 820         int sf = ReadByte();
 821
 822         if(sf & 1)
 823                 MapVote_Init();
 824
 825         if(sf & 2)
 826                 MapVote_UpdateMask();
 827
 828         if(sf & 4)
 829                 MapVote_UpdateVotes();
 830 }
 831
 832 void Net_MapVote_Picture()
 833 {
 834         int type = ReadByte();
 835         mv_preview[type] = true;
 836         mv_pics[type] = strzone(ReadPicture());
 837 }