qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "defs.qh"
   6 #include "hud/_mod.qh"
   7 #include "hud/panel/scoreboard.qh"
   8
   9 #include <common/mapinfo.qh>
  10
  11 // MapVote (#21)
  12
  13 void MapVote_Draw_Export(int fh)
  14 {
  15         // allow saving cvars that aesthetically change the panel into hud skin files
  16         HUD_Write_Cvar("hud_panel_mapvote_highlight_border");
  17 }
  18
  19 int mv_num_maps;
  20
  21 string mv_maps[MAPVOTE_COUNT];
  22 string mv_pics[MAPVOTE_COUNT];
  23 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  24 string mv_desc[MAPVOTE_COUNT];
  25 float mv_preview[MAPVOTE_COUNT];
  26 float mv_votes[MAPVOTE_COUNT];
  27 float mv_flags[MAPVOTE_COUNT];
  28 float mv_flags_start[MAPVOTE_COUNT];
  29 entity mv_pk3list;
  30 float mv_abstain;
  31 float mv_ownvote;
  32 float mv_detail;
  33 float mv_timeout;
  34 float mv_top2_time;
  35 float mv_top2_alpha;
  36
  37 int mv_selection;
  38 int mv_columns;
  39 int mv_mouse_selection;
  40 int mv_selection_keyboard;
  41
  42 float gametypevote;
  43 string mapvote_chosenmap;
  44 vector gtv_text_size;
  45 vector gtv_text_size_small;
  46
  47 const int NUM_SSDIRS = 4;
  48 string ssdirs[NUM_SSDIRS];
  49 int n_ssdirs;
  50
  51 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  52 {
  53         TC(int, id);
  54         string pre, post;
  55         pre = sprintf("%d. ", id+1);
  56         if(mv_detail)
  57         {
  58                 if(_count == 1)
  59                         post = _(" (1 vote)");
  60                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  61                         post = sprintf(_(" (%d votes)"), _count);
  62                 else
  63                         post = "";
  64         }
  65         else
  66                 post = "";
  67         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  68         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  69         return strcat(pre, map, post);
  70 }
  71
  72 vector MapVote_RGB(int id)
  73 {
  74         TC(int, id);
  75         if(!(mv_flags[id] & GTV_AVAILABLE))
  76                 return '1 1 1';
  77         if(id == mv_ownvote)
  78                 return '0 1 0';
  79         else if (id == mv_selection)
  80                 return '1 1 0';
  81         else
  82                 return '1 1 1';
  83 }
  84
  85 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  86 {
  87         TC(int, id);
  88         // Find the correct alpha
  89         float alpha;
  90         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  91                 alpha = 0.2; // The gametype isn't supported by the map
  92         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  93                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  94         else
  95                 alpha = 1; // Normal, full alpha
  96         alpha *= panel_fg_alpha;
  97
  98         // Bounding box details
  99         float rect_margin = hud_fontsize.y / 2;
 100
 101         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 102         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 103         maxh -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 104         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 105
 106         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 107         vector rect_size = '1 1 0';
 108         rect_size.x = tsize + rect_margin;
 109         rect_size.y = maxh + rect_margin;
 110
 111         // Highlight selected item
 112         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 113         {
 114                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 115         }
 116
 117         // Highlight current vote
 118         vector rgb = MapVote_RGB(id);
 119         if(id == mv_ownvote)
 120         {
 121                 drawfill(rect_pos, rect_size, rgb, 0.1 * alpha, DRAWFLAG_NORMAL);
 122                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 123         }
 124
 125         vector offset = pos;
 126
 127         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 128         pos.y += title_gap;
 129         maxh -= title_gap;
 130
 131         // Evaluate the image size
 132         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 133         if ( maxh < image_size.y )
 134                 image_size = '1 1 0' * maxh;
 135         image_size *= 0.8;
 136         float desc_padding = gtv_text_size.x * 0.6;
 137         pos.x += image_size.x + desc_padding;
 138         tsize -= image_size.x + desc_padding;
 139
 140         // Split the description into lines
 141         entity title;
 142         title = spawn();
 143         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 144
 145         string thelabel = mv_desc[id], ts;
 146         entity last = title;
 147         entity next = NULL;
 148         float nlines = 0;
 149         if( thelabel != "")
 150         {
 151                 float i,n = tokenizebyseparator(thelabel, "\n");
 152                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 153                 {
 154                         getWrappedLine_remaining = argv(i);
 155                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 156                         {
 157                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 158                                 if (ts != "")
 159                                 {
 160                                         next = spawn();
 161                                         next.message = ts;
 162                                         next.origin = pos-offset;
 163                                         last.chain = next;
 164                                         last = next;
 165                                         pos.y += gtv_text_size_small.y;
 166                                         nlines++;
 167                                 }
 168                         }
 169                 }
 170         }
 171
 172         // Center the contents in the bounding box
 173         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 174         if ( maxh > 0 )
 175                 offset.y += maxh/2;
 176
 177         // Draw the title
 178         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 179
 180         // Draw the icon
 181         if(pic != "")
 182                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 183
 184         // Draw the description
 185         for ( last = title.chain; last ; )
 186         {
 187                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 188                 next = last;
 189                 last = last.chain;
 190                 delete(next);
 191         }
 192
 193         // Cleanup
 194         delete(title);
 195 }
 196
 197 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 198 {
 199         TC(int, id);
 200         vector img_size = '0 0 0';
 201         string label;
 202         float text_size;
 203
 204         float rect_margin = hud_fontsize.y / 2;
 205
 206         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 207         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 208         isize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 209         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 210
 211         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 212         vector rect_size = '1 1 0';
 213         rect_size.x = tsize + rect_margin;
 214         rect_size.y = isize + rect_margin;
 215
 216         float img_ar = 4/3;
 217         img_size.x = min(tsize, isize * img_ar);
 218         img_size.y = img_size.x / img_ar;
 219         img_size.y -= hud_fontsize.y;
 220         img_size.x = img_size.y * img_ar;
 221
 222         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 223
 224         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 225
 226         text_size = stringwidth(label, false, hud_fontsize);
 227
 228         float save_rect_sizex = rect_size.x;
 229         rect_size.x = max(img_size.x, text_size) + rect_margin;
 230         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 231
 232         vector text_pos = '0 0 0';
 233         text_pos.x = pos.x + (tsize - text_size) / 2;
 234         text_pos.y = pos.y + img_size.y;
 235
 236         pos.x += (tsize - img_size.x) / 2;
 237
 238         float theAlpha;
 239         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 240                 theAlpha = mv_top2_alpha;
 241         else
 242                 theAlpha = 1;
 243         theAlpha *= panel_fg_alpha;
 244
 245         // Highlight selected item
 246         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 247                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 248
 249         // Highlight current vote
 250         vector rgb = MapVote_RGB(id);
 251         if(id == mv_ownvote)
 252         {
 253                 drawfill(rect_pos, rect_size, rgb, 0.1 * theAlpha, DRAWFLAG_NORMAL);
 254                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 255         }
 256
 257         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 258
 259         if(pic == "")
 260         {
 261                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 262         }
 263         else
 264         {
 265                 if(drawgetimagesize(pic) == '0 0 0')
 266                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 267                 else
 268                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 269         }
 270 }
 271
 272 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 273 {
 274         TC(int, id);
 275         vector rgb;
 276         float text_size;
 277         string label;
 278
 279         rgb = MapVote_RGB(id);
 280
 281         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 282
 283         text_size = stringwidth(label, false, hud_fontsize);
 284
 285         pos.x -= text_size*0.5;
 286         drawstring(pos, label, hud_fontsize, rgb, panel_fg_alpha, DRAWFLAG_NORMAL);
 287 }
 288
 289 vector MapVote_GridVec(vector gridspec, int i, int m)
 290 {
 291         TC(int, i); TC(int, m);
 292         int r = i % m;
 293         return
 294                 '1 0 0' * (gridspec.x * r)
 295                 +
 296                 '0 1 0' * (gridspec.y * (i - r) / m);
 297 }
 298
 299 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 300 {
 301
 302         float c, r;
 303
 304         mv_mouse_selection = -1;
 305
 306         for (r = 0; r < rows; ++r)
 307                 for (c = 0; c < columns; ++c)
 308                 {
 309                         if (mousepos.x >= topleft.x + cellsize.x *  c &&
 310                                 mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 311                                 mousepos.y >= topleft.y + cellsize.y *  r &&
 312                                 mousepos.y <= topleft.y + cellsize.y * (r + 1))
 313                         {
 314                                 mv_mouse_selection = r * columns + c;
 315                                 break;
 316                         }
 317                 }
 318
 319         if (mv_mouse_selection >= mv_num_maps)
 320                 mv_mouse_selection = -1;
 321
 322         if (mv_abstain && mv_mouse_selection < 0)
 323                 mv_mouse_selection = mv_num_maps;
 324
 325         if ( mv_selection_keyboard )
 326                 return mv_selection;
 327
 328         return mv_mouse_selection;
 329 }
 330
 331 vector prev_mousepos;
 332 // draws map vote or gametype vote
 333 void MapVote_Draw()
 334 {
 335         string map;
 336         int i;
 337         float tmp;
 338         vector pos;
 339         float center;
 340         float rows;
 341         vector dist = '0 0 0';
 342
 343         //if(intermission != 2) return;
 344         if(!mv_active)
 345                 return;
 346
 347         HUD_Panel_LoadCvars();
 348
 349         if (!autocvar_hud_cursormode)
 350         {
 351                 if (mousepos.x != prev_mousepos.x || mousepos.y != prev_mousepos.y)
 352                 {
 353                         mv_selection_keyboard = 0;
 354                         prev_mousepos = mousepos;
 355                 }
 356         }
 357
 358         center = (vid_conwidth - 1)/2;
 359         xmin = vid_conwidth * 0.08;
 360         xmax = vid_conwidth - xmin;
 361         ymin = 20;
 362         ymax = vid_conheight - ymin;
 363
 364         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 365                 ymin += chat_sizey;
 366         else
 367                 ymax -= chat_sizey;
 368
 369         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 370         if (gametypevote)
 371         {
 372                 gtv_text_size = hud_fontsize * 1.4;
 373                 gtv_text_size_small = hud_fontsize * 1.1;
 374         }
 375
 376         pos.y = ymin;
 377         pos.z = 0;
 378
 379         HUD_Scale_Disable();
 380         draw_beginBoldFont();
 381
 382         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 383         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 384         drawstring(pos, map, hud_fontsize * 2, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 385         pos.y += hud_fontsize.y * 2;
 386
 387         if( mapvote_chosenmap != "" )
 388         {
 389                 pos.y += hud_fontsize.y * 0.25;
 390                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 391                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 392                 pos.y += hud_fontsize.y * 1.5;
 393         }
 394         pos.y += hud_fontsize.y * 0.5;
 395
 396         draw_endBoldFont();
 397
 398         i = ceil(max(0, mv_timeout - time));
 399         map = sprintf(_("%d seconds left"), i);
 400         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 401         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', panel_fg_alpha, DRAWFLAG_NORMAL);
 402         pos.y += hud_fontsize.y * 1.5;
 403         pos.y += hud_fontsize.y * 0.5;
 404
 405         // base for multi-column stuff...
 406         pos.y += hud_fontsize.y;
 407         pos.x = xmin;
 408         ymin = pos.y;
 409         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 410         if(mv_abstain)
 411         {
 412                 mv_num_maps -= 1;
 413                 ymax -= abstain_spacing;
 414         }
 415
 416         // higher than the image itself ratio for mapvote items to reserve space for long map names
 417         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 418         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, vec2(xmax - xmin, ymax - ymin), item_aspect);
 419         mv_columns = table_size.x;
 420         rows = table_size.y;
 421
 422         dist.x = (xmax - xmin) / mv_columns;
 423         dist.y = (ymax - pos.y) / rows;
 424
 425         // reduce size of too wide items
 426         tmp = vid_conwidth / 3; // max width
 427         if(dist.x > tmp)
 428         {
 429                 dist.x = tmp;
 430                 dist.y = min(dist.y, dist.x / item_aspect);
 431         }
 432         tmp = vid_conheight / 3; // max height
 433         if(dist.y > tmp)
 434         {
 435                 dist.y = tmp;
 436                 dist.x = min(dist.x, dist.y * item_aspect);
 437         }
 438
 439         // reduce size to fix aspect ratio
 440         if(dist.x / dist.y > item_aspect)
 441                 dist.x = dist.y * item_aspect;
 442         else
 443                 dist.y = dist.x / item_aspect;
 444
 445         // adjust table pos and size according to the new size
 446         float offset;
 447         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 448         xmin = pos.x += offset;
 449         xmax -= offset;
 450         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 451         ymax -= 2 * offset;
 452
 453         // override panel_pos and panel_size
 454         panel_pos.x = pos.x;
 455         panel_pos.y = pos.y;
 456         panel_size.x = xmax - xmin;
 457         panel_size.y = ymax - ymin;
 458         HUD_Panel_DrawBg();
 459
 460         if(panel_bg_padding)
 461         {
 462                 // FIXME item AR gets slightly changed here...
 463                 // it's rather hard to avoid it at this point
 464                 dist.x -= 2 * panel_bg_padding / mv_columns;
 465                 dist.y -= 2 * panel_bg_padding / rows;
 466                 xmin = pos.x += panel_bg_padding;
 467                 ymin = pos.y += panel_bg_padding;
 468                 xmax -= 2 * panel_bg_padding;
 469                 ymax -= 2 * panel_bg_padding;
 470         }
 471
 472         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 473
 474         if (mv_top2_time)
 475                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time) ** 2);
 476
 477         void (vector, float, float, string, string, float, float) DrawItem;
 478
 479         if(gametypevote)
 480                 DrawItem = GameTypeVote_DrawGameTypeItem;
 481         else
 482                 DrawItem = MapVote_DrawMapItem;
 483
 484         for(i = 0; i < mv_num_maps; ++i)
 485         {
 486                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 487                 map = mv_maps[i];
 488                 if(mv_preview[i])
 489                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 490                 else
 491                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 492         }
 493
 494         if(mv_abstain)
 495                 ++mv_num_maps;
 496
 497         if(mv_abstain && i < mv_num_maps) {
 498                 tmp = mv_votes[i];
 499                 pos.y = ymax + abstain_spacing;
 500                 pos.x = (xmax+xmin)*0.5;
 501                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 502         }
 503 }
 504
 505 void Cmd_MapVote_MapDownload(int argc)
 506 {
 507         TC(int, argc);
 508         entity pak;
 509
 510         if(argc != 2 || !mv_pk3list)
 511         {
 512                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!"));
 513                 return;
 514         }
 515
 516         int id = stof(argv(1));
 517         for(pak = mv_pk3list; pak; pak = pak.chain)
 518                 if(pak.sv_entnum == id)
 519                         break;
 520
 521         if(!pak || pak.sv_entnum != id) {
 522                 LOG_INFO(_("^1Error:^7 Couldn't find pak index."));
 523                 return;
 524         }
 525
 526         if(PreviewExists(pak.message))
 527         {
 528                 mv_preview[id] = true;
 529                 return;
 530         } else {
 531                 LOG_INFO(_("Requesting preview..."));
 532                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 533         }
 534 }
 535
 536 void MapVote_CheckPK3(string pic, string pk3, int id)
 537 {
 538         TC(int, id);
 539         entity pak;
 540         pak = spawn();
 541         pak.netname = pk3;
 542         pak.message = pic;
 543         pak.sv_entnum = id;
 544
 545         pak.chain = mv_pk3list;
 546         mv_pk3list = pak;
 547
 548         if(pk3 != "")
 549         {
 550                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 551         }
 552         else
 553         {
 554                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 555         }
 556 }
 557
 558 void MapVote_CheckPic(string pic, string pk3, int id)
 559 {
 560         TC(int, id);
 561         // never try to retrieve a pic for the "don't care" 'map'
 562         if(mv_abstain && id == mv_num_maps - 1)
 563                 return;
 564
 565         if(PreviewExists(pic))
 566         {
 567                 mv_preview[id] = true;
 568                 return;
 569         }
 570         MapVote_CheckPK3(pic, pk3, id);
 571 }
 572
 573 void MapVote_ReadMask()
 574 {
 575         int i;
 576         if ( mv_num_maps < 24 )
 577         {
 578                 int mask;
 579                 if(mv_num_maps < 8)
 580                         mask = ReadByte();
 581                 else if(mv_num_maps < 16)
 582                         mask = ReadShort();
 583                 else
 584                         mask = ReadLong();
 585
 586                 for(i = 0; i < mv_num_maps; ++i)
 587                 {
 588                         if (mask & BIT(i))
 589                                 mv_flags[i] |= GTV_AVAILABLE;
 590                         else
 591                                 mv_flags[i] &= ~GTV_AVAILABLE;
 592                 }
 593         }
 594         else
 595         {
 596                 for(i = 0; i < mv_num_maps; ++i )
 597                         mv_flags[i] = ReadByte();
 598         }
 599 }
 600
 601 void MapVote_ReadOption(int i)
 602 {
 603         TC(int, i);
 604         string map = strzone(ReadString());
 605         string pk3 = strzone(ReadString());
 606         int j = bound(0, ReadByte(), n_ssdirs - 1);
 607
 608         mv_maps[i] = map;
 609         mv_pk3[i] = pk3;
 610         mv_flags[i] = GTV_AVAILABLE;
 611
 612         string pic = strzone(strcat(ssdirs[j], "/", map));
 613         mv_pics[i] = pic;
 614         mv_preview[i] = false;
 615         MapVote_CheckPic(pic, pk3, i);
 616 }
 617
 618 void GameTypeVote_ReadOption(int i)
 619 {
 620         TC(int, i);
 621         string gt = strzone(ReadString());
 622
 623         mv_maps[i] = gt;
 624         mv_flags[i] = ReadByte();
 625
 626         string basetype = "";
 627
 628         if ( mv_flags[i] & GTV_CUSTOM )
 629         {
 630                 string name = ReadString();
 631                 if ( strlen(name) < 1 )
 632                         name = gt;
 633                 mv_pk3[i] = strzone(name);
 634                 mv_desc[i] = strzone(ReadString());
 635                 basetype = strzone(ReadString());
 636         }
 637         else
 638         {
 639                 Gametype type = MapInfo_Type_FromString(gt);
 640                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 641                 mv_desc[i] = MapInfo_Type_Description(type);
 642         }
 643
 644         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 645         if(precache_pic(mv_picpath) == "")
 646         {
 647                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 648                 if(precache_pic(mv_picpath) == "")
 649                 {
 650                         mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, basetype);
 651                         if(precache_pic(mv_picpath) == "")
 652                         {
 653                                 mv_picpath = strcat("gfx/menu/default/gametype_", basetype);
 654                         }
 655                 }
 656         }
 657         string pic = strzone(mv_picpath);
 658         mv_pics[i] = pic;
 659         mv_preview[i] = PreviewExists(pic);
 660 }
 661
 662 void MapVote_Init()
 663 {
 664         mv_active = 1;
 665         if(!autocvar_hud_cursormode) mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 666         mv_selection = -1;
 667         mv_selection_keyboard = 0;
 668
 669         string s;
 670         for(n_ssdirs = 0; ; ++n_ssdirs)
 671         {
 672                 s = ReadString();
 673                 if(s == "")
 674                         break;
 675                 if(n_ssdirs < NUM_SSDIRS)
 676                         ssdirs[n_ssdirs] = s;
 677         }
 678         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 679
 680         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 681         mv_abstain = ReadByte();
 682         if(mv_abstain)
 683                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 684         mv_detail = ReadByte();
 685
 686         mv_ownvote = -1;
 687         mv_timeout = ReadCoord();
 688
 689         gametypevote = ReadByte();
 690
 691         if(gametypevote)
 692         {
 693                 mapvote_chosenmap = strzone(ReadString());
 694                 if ( gametypevote == 2 )
 695                         gametypevote = 0;
 696         }
 697
 698         MapVote_ReadMask();
 699         int i;
 700         for(i = 0; i < mv_num_maps; ++i )
 701                 mv_flags_start[i] = mv_flags[i];
 702
 703         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 704         mv_pk3list = NULL; // I'm still paranoid!
 705
 706         for(i = 0; i < mv_num_maps; ++i)
 707         {
 708                 mv_votes[i] = 0;
 709
 710                 if ( gametypevote )
 711                         GameTypeVote_ReadOption(i);
 712                 else
 713                         MapVote_ReadOption(i);
 714         }
 715
 716         for(i = 0; i < n_ssdirs; ++i)
 717                 ssdirs[n_ssdirs] = string_null;
 718         n_ssdirs = 0;
 719 }
 720
 721 void MapVote_SendChoice(int index)
 722 {
 723         TC(int, index);
 724         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 725 }
 726
 727 int MapVote_MoveLeft(int pos)
 728 {
 729         TC(int, pos);
 730         int imp;
 731         if ( pos < 0 )
 732                 imp = mv_num_maps - 1;
 733         else
 734                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 735         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 736                 imp = MapVote_MoveLeft(imp);
 737         return imp;
 738 }
 739 int MapVote_MoveRight(int pos)
 740 {
 741         TC(int, pos);
 742         int imp;
 743         if ( pos < 0 )
 744                 imp = 0;
 745         else
 746                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 747         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 748                 imp = MapVote_MoveRight(imp);
 749         return imp;
 750 }
 751 int MapVote_MoveUp(int pos)
 752 {
 753         TC(int, pos);
 754         int imp;
 755         if ( pos < 0 )
 756                 imp = mv_num_maps - 1;
 757         else
 758         {
 759                 imp = pos - mv_columns;
 760                 if ( imp < 0 )
 761                 {
 762                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 763                         if ( imp >= mv_num_maps )
 764                                 imp -= mv_columns;
 765                 }
 766         }
 767         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 768                 imp = MapVote_MoveUp(imp);
 769         return imp;
 770 }
 771 int MapVote_MoveDown(int pos)
 772 {
 773         TC(int, pos);
 774         int imp;
 775         if ( pos < 0 )
 776                 imp = 0;
 777         else
 778         {
 779                 imp = pos + mv_columns;
 780                 if ( imp >= mv_num_maps )
 781                         imp = imp % mv_columns;
 782         }
 783         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 784                 imp = MapVote_MoveDown(imp);
 785         return imp;
 786 }
 787
 788 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
 789 {
 790         TC(int, bInputType);
 791
 792         static int first_digit = 0;
 793         if (!mv_active)
 794                 return false;
 795
 796         if(bInputType == 3)
 797         {
 798                 mousepos.x = nPrimary;
 799                 mousepos.y = nSecondary;
 800                 mv_selection_keyboard = 0;
 801                 return true;
 802         }
 803
 804         if (bInputType == 0)
 805         {
 806                 if (nPrimary == K_ALT) hudShiftState |= S_ALT;
 807                 if (nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 808                 if (nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 809         }
 810         else if (bInputType == 1)
 811         {
 812                 if (nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 813                 if (nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 814                 if (nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 815
 816                 if (nPrimary == K_CTRL)
 817                         first_digit = 0;
 818         }
 819
 820         if (bInputType != 0)
 821                 return false;
 822
 823         int imp = 0;
 824         switch(nPrimary)
 825         {
 826                 case K_RIGHTARROW:
 827                         mv_selection_keyboard = 1;
 828                         mv_selection = MapVote_MoveRight(mv_selection);
 829                         return true;
 830                 case K_LEFTARROW:
 831                         mv_selection_keyboard = 1;
 832                         mv_selection = MapVote_MoveLeft(mv_selection);
 833                         return true;
 834                 case K_DOWNARROW:
 835                         mv_selection_keyboard = 1;
 836                         mv_selection = MapVote_MoveDown(mv_selection);
 837                         return true;
 838                 case K_UPARROW:
 839                         mv_selection_keyboard = 1;
 840                         mv_selection = MapVote_MoveUp(mv_selection);
 841                         return true;
 842                 case K_KP_ENTER:
 843                 case K_ENTER:
 844                 case K_SPACE:
 845                         if ( mv_selection_keyboard )
 846                                 MapVote_SendChoice(mv_selection);
 847                         return true;
 848                 case '1': case K_KP_1: imp = 1; break;
 849                 case '2': case K_KP_2: imp = 2; break;
 850                 case '3': case K_KP_3: imp = 3; break;
 851                 case '4': case K_KP_4: imp = 4; break;
 852                 case '5': case K_KP_5: imp = 5; break;
 853                 case '6': case K_KP_6: imp = 6; break;
 854                 case '7': case K_KP_7: imp = 7; break;
 855                 case '8': case K_KP_8: imp = 8; break;
 856                 case '9': case K_KP_9: imp = 9; break;
 857                 case '0': case K_KP_0: imp = 10; break;
 858         }
 859
 860         if (imp && hudShiftState & S_CTRL)
 861         {
 862                 if (!first_digit)
 863                 {
 864                         first_digit = imp % 10;
 865                         return true;
 866                 }
 867                 else
 868                         imp = first_digit * 10 + (imp % 10);
 869         }
 870
 871         if (nPrimary == K_MOUSE1)
 872         {
 873                 mv_selection_keyboard = 0;
 874                 mv_selection = mv_mouse_selection;
 875                 if (mv_selection >= 0)
 876                         imp = min(mv_selection + 1, mv_num_maps);
 877         }
 878
 879         if (imp)
 880         {
 881                 if (imp <= mv_num_maps)
 882                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 883                 return true;
 884         }
 885
 886         return false;
 887 }
 888
 889 void MapVote_UpdateMask()
 890 {
 891         MapVote_ReadMask();
 892         mv_top2_time = time;
 893 }
 894
 895 void MapVote_UpdateVotes()
 896 {
 897         int i;
 898         for(i = 0; i < mv_num_maps; ++i)
 899         {
 900                 if(mv_flags[i] & GTV_AVAILABLE)
 901                 {
 902                         if(mv_detail)
 903                                 mv_votes[i] = ReadByte();
 904                         else
 905                                 mv_votes[i] = 0;
 906                 }
 907                 else
 908                         mv_votes[i] = -1;
 909         }
 910
 911         mv_ownvote = ReadByte()-1;
 912 }
 913
 914 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
 915 {
 916         make_pure(this);
 917         int sf = ReadByte();
 918         return = true;
 919
 920         if(sf & 1)
 921                 MapVote_Init();
 922
 923         if(sf & 2)
 924                 MapVote_UpdateMask();
 925
 926         if(sf & 4)
 927                 MapVote_UpdateVotes();
 928 }
 929
 930 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
 931 {
 932         Net_MapVote_Picture();
 933         return true;
 934 }
 935
 936 void Net_MapVote_Picture()
 937 {
 938         int type = ReadByte();
 939         mv_preview[type] = true;
 940         mv_pics[type] = strzone(ReadPicture());
 941 }