qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "defs.qh"
   6 #include "hud/_mod.qh"
   7 #include "hud/panel/scoreboard.qh"
   8
   9 #include <common/mapinfo.qh>
  10
  11
  12 int mv_num_maps;
  13
  14 string mv_maps[MAPVOTE_COUNT];
  15 string mv_pics[MAPVOTE_COUNT];
  16 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  17 string mv_desc[MAPVOTE_COUNT];
  18 float mv_preview[MAPVOTE_COUNT];
  19 float mv_votes[MAPVOTE_COUNT];
  20 float mv_flags[MAPVOTE_COUNT];
  21 float mv_flags_start[MAPVOTE_COUNT];
  22 entity mv_pk3list;
  23 float mv_abstain;
  24 float mv_ownvote;
  25 float mv_detail;
  26 float mv_timeout;
  27 float mv_top2_time;
  28 float mv_top2_alpha;
  29
  30 int mv_selection;
  31 int mv_columns;
  32 int mv_mouse_selection;
  33 int mv_selection_keyboard;
  34
  35 float gametypevote;
  36 string mapvote_chosenmap;
  37 vector gtv_text_size;
  38 vector gtv_text_size_small;
  39
  40 const int NUM_SSDIRS = 4;
  41 string ssdirs[NUM_SSDIRS];
  42 int n_ssdirs;
  43
  44 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  45 {
  46     TC(int, id);
  47         string pre, post;
  48         pre = sprintf("%d. ", id+1);
  49         if(mv_detail)
  50         {
  51                 if(_count == 1)
  52                         post = _(" (1 vote)");
  53                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  54                         post = sprintf(_(" (%d votes)"), _count);
  55                 else
  56                         post = "";
  57         }
  58         else
  59                 post = "";
  60         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  61         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  62         return strcat(pre, map, post);
  63 }
  64
  65 vector MapVote_RGB(int id)
  66 {
  67     TC(int, id);
  68         if(!(mv_flags[id] & GTV_AVAILABLE))
  69                 return '1 1 1';
  70         if(id == mv_ownvote)
  71                 return '0 1 0';
  72         else if (id == mv_selection)
  73                 return '1 1 0';
  74         else
  75                 return '1 1 1';
  76 }
  77
  78 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  79 {
  80     TC(int, id);
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89         alpha *= panel_fg_alpha;
  90
  91         // Bounding box details
  92         float rect_margin = hud_fontsize.y / 2;
  93
  94         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  95         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  96         maxh -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  97         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  98
  99         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 100         vector rect_size = '1 1 0';
 101         rect_size.x = tsize + rect_margin;
 102         rect_size.y = maxh + rect_margin;
 103
 104         // Highlight selected item
 105         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 106         {
 107                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 108         }
 109
 110         // Highlight current vote
 111         vector rgb = MapVote_RGB(id);
 112         if(id == mv_ownvote)
 113         {
 114                 drawfill(rect_pos, rect_size, rgb, 0.1 * alpha, DRAWFLAG_NORMAL);
 115                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 116         }
 117
 118         vector offset = pos;
 119
 120         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 121         pos.y += title_gap;
 122         maxh -= title_gap;
 123
 124         // Evaluate the image size
 125         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 126         if ( maxh < image_size.y )
 127                 image_size = '1 1 0' * maxh;
 128         image_size *= 0.8;
 129         float desc_padding = gtv_text_size.x * 0.6;
 130         pos.x += image_size.x + desc_padding;
 131         tsize -= image_size.x + desc_padding;
 132
 133         // Split the description into lines
 134         entity title;
 135         title = spawn();
 136         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 137
 138         string thelabel = mv_desc[id], ts;
 139         entity last = title;
 140         entity next = NULL;
 141         float nlines = 0;
 142         if( thelabel != "")
 143         {
 144                 float i,n = tokenizebyseparator(thelabel, "\n");
 145                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 146                 {
 147                         getWrappedLine_remaining = argv(i);
 148                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 149                         {
 150                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 151                                 if (ts != "")
 152                                 {
 153                                         next = spawn();
 154                                         next.message = ts;
 155                                         next.origin = pos-offset;
 156                                         last.chain = next;
 157                                         last = next;
 158                                         pos.y += gtv_text_size_small.y;
 159                                         nlines++;
 160                                 }
 161                         }
 162                 }
 163         }
 164
 165         // Center the contents in the bounding box
 166         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 167         if ( maxh > 0 )
 168                 offset.y += maxh/2;
 169
 170         // Draw the title
 171         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 172
 173         // Draw the icon
 174         if(pic != "")
 175                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 176
 177         // Draw the description
 178         for ( last = title.chain; last ; )
 179         {
 180                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 181                 next = last;
 182                 last = last.chain;
 183                 delete(next);
 184         }
 185
 186         // Cleanup
 187         delete(title);
 188 }
 189
 190 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 191 {
 192     TC(int, id);
 193         vector img_size = '0 0 0';
 194         string label;
 195         float text_size;
 196
 197         float rect_margin = hud_fontsize.y / 2;
 198
 199         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 200         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 201         isize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 202         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 203
 204         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 205         vector rect_size = '1 1 0';
 206         rect_size.x = tsize + rect_margin;
 207         rect_size.y = isize + rect_margin;
 208
 209         float img_ar = 4/3;
 210         img_size.x = min(tsize, isize * img_ar);
 211         img_size.y = img_size.x / img_ar;
 212         img_size.y -= hud_fontsize.y;
 213         img_size.x = img_size.y * img_ar;
 214
 215         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 216
 217         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 218
 219         text_size = stringwidth(label, false, hud_fontsize);
 220
 221         float save_rect_sizex = rect_size.x;
 222         rect_size.x = max(img_size.x, text_size) + rect_margin;
 223         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 224
 225         vector text_pos = '0 0 0';
 226         text_pos.x = pos.x + (tsize - text_size) / 2;
 227         text_pos.y = pos.y + img_size.y;
 228
 229         pos.x += (tsize - img_size.x) / 2;
 230
 231         float theAlpha;
 232         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 233                 theAlpha = mv_top2_alpha;
 234         else
 235                 theAlpha = 1;
 236         theAlpha *= panel_fg_alpha;
 237
 238         // Highlight selected item
 239         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 240                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 241
 242         // Highlight current vote
 243         vector rgb = MapVote_RGB(id);
 244         if(id == mv_ownvote)
 245         {
 246                 drawfill(rect_pos, rect_size, rgb, 0.1 * theAlpha, DRAWFLAG_NORMAL);
 247                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 248         }
 249
 250         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 251
 252         if(pic == "")
 253         {
 254                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 255         }
 256         else
 257         {
 258                 if(drawgetimagesize(pic) == '0 0 0')
 259                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 260                 else
 261                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 262         }
 263 }
 264
 265 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 266 {
 267     TC(int, id);
 268         vector rgb;
 269         float text_size;
 270         string label;
 271
 272         rgb = MapVote_RGB(id);
 273
 274         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 275
 276         text_size = stringwidth(label, false, hud_fontsize);
 277
 278         pos.x -= text_size*0.5;
 279         drawstring(pos, label, hud_fontsize, rgb, panel_fg_alpha, DRAWFLAG_NORMAL);
 280 }
 281
 282 vector MapVote_GridVec(vector gridspec, int i, int m)
 283 {
 284     TC(int, i); TC(int, m);
 285         int r = i % m;
 286         return
 287                 '1 0 0' * (gridspec.x * r)
 288                 +
 289                 '0 1 0' * (gridspec.y * (i - r) / m);
 290 }
 291
 292 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 293 {
 294
 295         float c, r;
 296
 297         mv_mouse_selection = -1;
 298
 299         for (r = 0; r < rows; ++r)
 300                 for (c = 0; c < columns; ++c)
 301                 {
 302                         if (mousepos.x >= topleft.x + cellsize.x *  c &&
 303                                 mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 304                                 mousepos.y >= topleft.y + cellsize.y *  r &&
 305                                 mousepos.y <= topleft.y + cellsize.y * (r + 1))
 306                         {
 307                                 mv_mouse_selection = r * columns + c;
 308                                 break;
 309                         }
 310                 }
 311
 312         if (mv_mouse_selection >= mv_num_maps)
 313                 mv_mouse_selection = -1;
 314
 315         if (mv_abstain && mv_mouse_selection < 0)
 316                 mv_mouse_selection = mv_num_maps;
 317
 318         if ( mv_selection_keyboard )
 319                 return mv_selection;
 320
 321         return mv_mouse_selection;
 322 }
 323
 324 void MapVote_Draw()
 325 {
 326         string map;
 327         int i;
 328         float tmp;
 329         vector pos;
 330         float center;
 331         float rows;
 332         vector dist = '0 0 0';
 333
 334         //if(intermission != 2) return;
 335         if(!mv_active)
 336                 return;
 337
 338         HUD_Panel_LoadCvars();
 339
 340         if (!autocvar_hud_cursormode)
 341         {
 342                 vector mpos = mousepos;
 343                 update_mousepos();
 344                 if (mpos.x != mousepos.x || mpos.y != mousepos.y)
 345                         mv_selection_keyboard = 0;
 346         }
 347
 348         center = (vid_conwidth - 1)/2;
 349         xmin = vid_conwidth * 0.08;
 350         xmax = vid_conwidth - xmin;
 351         ymin = 20;
 352         ymax = vid_conheight - ymin;
 353
 354         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 355                 ymin += chat_sizey;
 356         else
 357                 ymax -= chat_sizey;
 358
 359         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 360
 361         pos.y = ymin;
 362         pos.z = 0;
 363
 364         HUD_Scale_Disable();
 365         draw_beginBoldFont();
 366
 367         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 368         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 369         drawstring(pos, map, hud_fontsize * 2, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 370         pos.y += hud_fontsize.y * 2;
 371
 372         if( mapvote_chosenmap != "" )
 373         {
 374                 pos.y += hud_fontsize.y * 0.25;
 375                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 376                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 377                 pos.y += hud_fontsize.y * 1.5;
 378         }
 379         pos.y += hud_fontsize.y * 0.5;
 380
 381         draw_endBoldFont();
 382
 383         i = ceil(max(0, mv_timeout - time));
 384         map = sprintf(_("%d seconds left"), i);
 385         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 386         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', panel_fg_alpha, DRAWFLAG_NORMAL);
 387         pos.y += hud_fontsize.y * 1.5;
 388         pos.y += hud_fontsize.y * 0.5;
 389
 390         // base for multi-column stuff...
 391         pos.y += hud_fontsize.y;
 392         pos.x = xmin;
 393         ymin = pos.y;
 394         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 395         if(mv_abstain)
 396         {
 397                 mv_num_maps -= 1;
 398                 ymax -= abstain_spacing;
 399         }
 400
 401         // higher than the image itself ratio for mapvote items to reserve space for long map names
 402         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 403         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, vec2(xmax - xmin, ymax - ymin), item_aspect);
 404         mv_columns = table_size.x;
 405         rows = table_size.y;
 406
 407         dist.x = (xmax - xmin) / mv_columns;
 408         dist.y = (ymax - pos.y) / rows;
 409
 410         // reduce size of too wide items
 411         tmp = vid_conwidth / 3; // max width
 412         if(dist.x > tmp)
 413         {
 414                 dist.x = tmp;
 415                 dist.y = min(dist.y, dist.x / item_aspect);
 416         }
 417         tmp = vid_conheight / 3; // max height
 418         if(dist.y > tmp)
 419         {
 420                 dist.y = tmp;
 421                 dist.x = min(dist.x, dist.y * item_aspect);
 422         }
 423
 424         // reduce size to fix aspect ratio
 425         if(dist.x / dist.y > item_aspect)
 426                 dist.x = dist.y * item_aspect;
 427         else
 428                 dist.y = dist.x / item_aspect;
 429
 430         // adjust table pos and size according to the new size
 431         float offset;
 432         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 433         xmin = pos.x += offset;
 434         xmax -= offset;
 435         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 436         ymax -= 2 * offset;
 437
 438         // override panel_pos and panel_size
 439         panel_pos.x = pos.x;
 440         panel_pos.y = pos.y;
 441         panel_size.x = xmax - xmin;
 442         panel_size.y = ymax - ymin;
 443         HUD_Panel_DrawBg();
 444
 445         if(panel_bg_padding)
 446         {
 447                 // FIXME item AR gets slightly changed here...
 448                 // it's rather hard to avoid it at this point
 449                 dist.x -= 2 * panel_bg_padding / mv_columns;
 450                 dist.y -= 2 * panel_bg_padding / rows;
 451                 xmin = pos.x += panel_bg_padding;
 452                 ymin = pos.y += panel_bg_padding;
 453                 xmax -= 2 * panel_bg_padding;
 454                 ymax -= 2 * panel_bg_padding;
 455         }
 456
 457         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 458
 459         if (mv_top2_time)
 460                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 461
 462         void (vector, float, float, string, string, float, float) DrawItem;
 463
 464         if(gametypevote)
 465                 DrawItem = GameTypeVote_DrawGameTypeItem;
 466         else
 467                 DrawItem = MapVote_DrawMapItem;
 468
 469         for(i = 0; i < mv_num_maps; ++i)
 470         {
 471                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 472                 map = mv_maps[i];
 473                 if(mv_preview[i])
 474                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 475                 else
 476                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 477         }
 478
 479         if(mv_abstain)
 480                 ++mv_num_maps;
 481
 482         if(mv_abstain && i < mv_num_maps) {
 483                 tmp = mv_votes[i];
 484                 pos.y = ymax + abstain_spacing;
 485                 pos.x = (xmax+xmin)*0.5;
 486                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 487         }
 488
 489         draw_cursor_normal(mousepos, '1 1 1', panel_fg_alpha);
 490 }
 491
 492 void Cmd_MapVote_MapDownload(int argc)
 493 {
 494     TC(int, argc);
 495         entity pak;
 496
 497         if(argc != 2 || !mv_pk3list)
 498         {
 499                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!"));
 500                 return;
 501         }
 502
 503         int id = stof(argv(1));
 504         for(pak = mv_pk3list; pak; pak = pak.chain)
 505                 if(pak.sv_entnum == id)
 506                         break;
 507
 508         if(!pak || pak.sv_entnum != id) {
 509                 LOG_INFO(_("^1Error:^7 Couldn't find pak index."));
 510                 return;
 511         }
 512
 513         if(PreviewExists(pak.message))
 514         {
 515                 mv_preview[id] = true;
 516                 return;
 517         } else {
 518                 LOG_INFO(_("Requesting preview..."));
 519                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 520         }
 521 }
 522
 523 void MapVote_CheckPK3(string pic, string pk3, int id)
 524 {
 525     TC(int, id);
 526         entity pak;
 527         pak = spawn();
 528         pak.netname = pk3;
 529         pak.message = pic;
 530         pak.sv_entnum = id;
 531
 532         pak.chain = mv_pk3list;
 533         mv_pk3list = pak;
 534
 535         if(pk3 != "")
 536         {
 537                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 538         }
 539         else
 540         {
 541                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 542         }
 543 }
 544
 545 void MapVote_CheckPic(string pic, string pk3, int id)
 546 {
 547     TC(int, id);
 548         // never try to retrieve a pic for the "don't care" 'map'
 549         if(mv_abstain && id == mv_num_maps - 1)
 550                 return;
 551
 552         if(PreviewExists(pic))
 553         {
 554                 mv_preview[id] = true;
 555                 return;
 556         }
 557         MapVote_CheckPK3(pic, pk3, id);
 558 }
 559
 560 void MapVote_ReadMask()
 561 {
 562         int i;
 563         if ( mv_num_maps < 24 )
 564         {
 565                 int mask;
 566                 if(mv_num_maps < 8)
 567                         mask = ReadByte();
 568                 else if(mv_num_maps < 16)
 569                         mask = ReadShort();
 570                 else
 571                         mask = ReadLong();
 572
 573                 for(i = 0; i < mv_num_maps; ++i)
 574                 {
 575                         if (mask & BIT(i))
 576                                 mv_flags[i] |= GTV_AVAILABLE;
 577                         else
 578                                 mv_flags[i] &= ~GTV_AVAILABLE;
 579                 }
 580         }
 581         else
 582         {
 583                 for(i = 0; i < mv_num_maps; ++i )
 584                         mv_flags[i] = ReadByte();
 585         }
 586 }
 587
 588 void MapVote_ReadOption(int i)
 589 {
 590     TC(int, i);
 591         string map = strzone(ReadString());
 592         string pk3 = strzone(ReadString());
 593         int j = bound(0, ReadByte(), n_ssdirs - 1);
 594
 595         mv_maps[i] = map;
 596         mv_pk3[i] = pk3;
 597         mv_flags[i] = GTV_AVAILABLE;
 598
 599         string pic = strzone(strcat(ssdirs[j], "/", map));
 600         mv_pics[i] = pic;
 601         mv_preview[i] = false;
 602         MapVote_CheckPic(pic, pk3, i);
 603 }
 604
 605 void GameTypeVote_ReadOption(int i)
 606 {
 607     TC(int, i);
 608         string gt = strzone(ReadString());
 609
 610         mv_maps[i] = gt;
 611         mv_flags[i] = ReadByte();
 612
 613         string basetype = "";
 614
 615         if ( mv_flags[i] & GTV_CUSTOM )
 616         {
 617                 string name = ReadString();
 618                 if ( strlen(name) < 1 )
 619                         name = gt;
 620                 mv_pk3[i] = strzone(name);
 621                 mv_desc[i] = strzone(ReadString());
 622                 basetype = strzone(ReadString());
 623         }
 624         else
 625         {
 626                 Gametype type = MapInfo_Type_FromString(gt);
 627                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 628                 mv_desc[i] = MapInfo_Type_Description(type);
 629         }
 630
 631         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 632         if(precache_pic(mv_picpath) == "")
 633         {
 634                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 635                 if(precache_pic(mv_picpath) == "")
 636                 {
 637                         mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, basetype);
 638                         if(precache_pic(mv_picpath) == "")
 639                         {
 640                                 mv_picpath = strcat("gfx/menu/default/gametype_", basetype);
 641                         }
 642                 }
 643         }
 644         string pic = strzone(mv_picpath);
 645         mv_pics[i] = pic;
 646         mv_preview[i] = PreviewExists(pic);
 647 }
 648
 649 void MapVote_Init()
 650 {
 651         mv_active = 1;
 652         if(autocvar_hud_cursormode) setcursormode(1);
 653         else mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 654         mv_selection = -1;
 655         mv_selection_keyboard = 0;
 656
 657         string s;
 658         for(n_ssdirs = 0; ; ++n_ssdirs)
 659         {
 660                 s = ReadString();
 661                 if(s == "")
 662                         break;
 663                 if(n_ssdirs < NUM_SSDIRS)
 664                         ssdirs[n_ssdirs] = s;
 665         }
 666         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 667
 668         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 669         mv_abstain = ReadByte();
 670         if(mv_abstain)
 671                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 672         mv_detail = ReadByte();
 673
 674         mv_ownvote = -1;
 675         mv_timeout = ReadCoord();
 676
 677         gametypevote = ReadByte();
 678
 679         if(gametypevote)
 680         {
 681                 mapvote_chosenmap = strzone(ReadString());
 682                 if ( gametypevote == 2 )
 683                         gametypevote = 0;
 684
 685                 gtv_text_size = hud_fontsize*1.4;
 686                 gtv_text_size_small = hud_fontsize*1.1;
 687         }
 688
 689         MapVote_ReadMask();
 690         int i;
 691         for(i = 0; i < mv_num_maps; ++i )
 692                 mv_flags_start[i] = mv_flags[i];
 693
 694         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 695         mv_pk3list = NULL; // I'm still paranoid!
 696
 697         for(i = 0; i < mv_num_maps; ++i)
 698         {
 699                 mv_votes[i] = 0;
 700
 701                 if ( gametypevote )
 702                         GameTypeVote_ReadOption(i);
 703                 else
 704                         MapVote_ReadOption(i);
 705         }
 706
 707         for(i = 0; i < n_ssdirs; ++i)
 708                 ssdirs[n_ssdirs] = string_null;
 709         n_ssdirs = 0;
 710 }
 711
 712 void MapVote_SendChoice(int index)
 713 {
 714     TC(int, index);
 715         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 716 }
 717
 718 int MapVote_MoveLeft(int pos)
 719 {
 720     TC(int, pos);
 721         int imp;
 722         if ( pos < 0 )
 723                 imp = mv_num_maps - 1;
 724         else
 725                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 726         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 727                 imp = MapVote_MoveLeft(imp);
 728         return imp;
 729 }
 730 int MapVote_MoveRight(int pos)
 731 {
 732     TC(int, pos);
 733         int imp;
 734         if ( pos < 0 )
 735                 imp = 0;
 736         else
 737                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 738         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 739                 imp = MapVote_MoveRight(imp);
 740         return imp;
 741 }
 742 int MapVote_MoveUp(int pos)
 743 {
 744     TC(int, pos);
 745         int imp;
 746         if ( pos < 0 )
 747                 imp = mv_num_maps - 1;
 748         else
 749         {
 750                 imp = pos - mv_columns;
 751                 if ( imp < 0 )
 752                 {
 753                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 754                         if ( imp >= mv_num_maps )
 755                                 imp -= mv_columns;
 756                 }
 757         }
 758         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 759                 imp = MapVote_MoveUp(imp);
 760         return imp;
 761 }
 762 int MapVote_MoveDown(int pos)
 763 {
 764     TC(int, pos);
 765         int imp;
 766         if ( pos < 0 )
 767                 imp = 0;
 768         else
 769         {
 770                 imp = pos + mv_columns;
 771                 if ( imp >= mv_num_maps )
 772                         imp = imp % mv_columns;
 773         }
 774         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 775                 imp = MapVote_MoveDown(imp);
 776         return imp;
 777 }
 778
 779 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
 780 {
 781     TC(int, bInputType);
 782         float imp;
 783
 784         if (!mv_active)
 785                 return false;
 786
 787         if(bInputType == 3)
 788         {
 789                 mousepos.x = nPrimary;
 790                 mousepos.y = nSecondary;
 791                 mv_selection_keyboard = 0;
 792                 return true;
 793         }
 794
 795         if (bInputType != 0)
 796                 return false;
 797
 798         if ('0' <= nPrimary && nPrimary <= '9')
 799         {
 800                 imp = nPrimary - '0';
 801                 if (imp == 0) imp = 10;
 802                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 803                 return true;
 804         }
 805         switch(nPrimary)
 806         {
 807                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 808                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 809                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 810                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 811                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 812                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 813                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 814                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 815                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 816                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 817
 818                 case K_RIGHTARROW:
 819                         mv_selection_keyboard = 1;
 820                         mv_selection = MapVote_MoveRight(mv_selection);
 821                         return true;
 822                 case K_LEFTARROW:
 823                         mv_selection_keyboard = 1;
 824                         mv_selection = MapVote_MoveLeft(mv_selection);
 825                         return true;
 826                 case K_DOWNARROW:
 827                         mv_selection_keyboard = 1;
 828                         mv_selection = MapVote_MoveDown(mv_selection);
 829                         return true;
 830                 case K_UPARROW:
 831                         mv_selection_keyboard = 1;
 832                         mv_selection = MapVote_MoveUp(mv_selection);
 833                         return true;
 834                 case K_KP_ENTER:
 835                 case K_ENTER:
 836                 case K_SPACE:
 837                         if ( mv_selection_keyboard )
 838                                 MapVote_SendChoice(mv_selection);
 839                         return true;
 840         }
 841
 842         if (nPrimary == K_MOUSE1)
 843         {
 844                 mv_selection_keyboard = 0;
 845                 mv_selection = mv_mouse_selection;
 846                 if (mv_selection >= 0)
 847                 {
 848                         imp = min(mv_selection + 1, mv_num_maps);
 849                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 850                         return true;
 851                 }
 852         }
 853
 854         return false;
 855 }
 856
 857 void MapVote_UpdateMask()
 858 {
 859         MapVote_ReadMask();
 860         mv_top2_time = time;
 861 }
 862
 863 void MapVote_UpdateVotes()
 864 {
 865         int i;
 866         for(i = 0; i < mv_num_maps; ++i)
 867         {
 868                 if(mv_flags[i] & GTV_AVAILABLE)
 869                 {
 870                         if(mv_detail)
 871                                 mv_votes[i] = ReadByte();
 872                         else
 873                                 mv_votes[i] = 0;
 874                 }
 875                 else
 876                         mv_votes[i] = -1;
 877         }
 878
 879         mv_ownvote = ReadByte()-1;
 880 }
 881
 882 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
 883 {
 884         make_pure(this);
 885         int sf = ReadByte();
 886         return = true;
 887
 888         if(sf & 1)
 889                 MapVote_Init();
 890
 891         if(sf & 2)
 892                 MapVote_UpdateMask();
 893
 894         if(sf & 4)
 895                 MapVote_UpdateVotes();
 896 }
 897
 898 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
 899 {
 900         Net_MapVote_Picture();
 901         return true;
 902 }
 903
 904 void Net_MapVote_Picture()
 905 {
 906         int type = ReadByte();
 907         mv_preview[type] = true;
 908         mv_pics[type] = strzone(ReadPicture());
 909 }