qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "casings.qh"
   5 #include "controlpoint.qh"
   6 #include "csqcmodel_hooks.qh"
   7 #include "damage.qh"
   8 #include "effects.qh"
   9 #include "generator.qh"
  10 #include "gibs.qh"
  11 #include "hook.qh"
  12 #include "hud.qh"
  13 #include "hud_config.qh"
  14 #include "laser.qh"
  15 #include "mapvoting.qh"
  16 #include "modeleffects.qh"
  17 #include "particles.qh"
  18 #include "prandom.qh"
  19 #include "scoreboard.qh"
  20 #include "shownames.qh"
  21 #include "sortlist.qh"
  22 #include "tturrets.qh"
  23 #include "tuba.qh"
  24 #include "t_items.qh"
  25 #include "wall.qh"
  26 #include "waypointsprites.qh"
  27
  28 #include "vehicles/bumblebee.qh"
  29 #include "vehicles/all.qh"
  30
  31 #include "weapons/projectile.qh"
  32
  33 #include "../common/buffs.qh"
  34 #include "../common/deathtypes.qh"
  35 #include "../common/mapinfo.qh"
  36 #include "../common/monsters/all.qh"
  37 #include "../common/nades.qh"
  38 #include "../common/net_notice.qh"
  39 #include "../common/notifications.qh"
  40 #include "../common/stats.qh"
  41 #include "../common/teams.qh"
  42
  43 #include "../common/items/all.qh"
  44
  45 #include "../common/weapons/all.qh"
  46
  47 #include "../csqcmodellib/cl_model.qh"
  48 #include "../csqcmodellib/interpolate.qh"
  49
  50 #include "../common/triggers/include.qh"
  51
  52 #include "../warpzonelib/client.qh"
  53
  54 // --------------------------------------------------------------------------
  55 // BEGIN REQUIRED CSQC FUNCTIONS
  56 //include "main.qh"
  57
  58 entity clearentity_ent;
  59 void clearentity(entity e)
  60 {
  61         if (!clearentity_ent)
  62         {
  63                 clearentity_ent = spawn();
  64                 clearentity_ent.classname = "clearentity";
  65         }
  66         int n = e.entnum;
  67         copyentity(clearentity_ent, e);
  68         e.entnum = n;
  69 }
  70
  71 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  72 void menu_show_error()
  73 {
  74         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  75 }
  76
  77 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  78 // Useful for precaching things
  79
  80 void menu_sub_null()
  81 {
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90
  91 #ifdef WATERMARK
  92         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         int i;
  96
  97         binddb = db_create();
  98         tempdb = db_create();
  99         ClientProgsDB = db_load("client.db");
 100         compressShortVector_init();
 101
 102         draw_endBoldFont();
 103         menu_visible = false;
 104         menu_show = menu_show_error;
 105         menu_action = func_null;
 106
 107         for(i = 0; i < 255; ++i)
 108                 if(getplayerkeyvalue(i, "viewentity") == "")
 109                         break;
 110         maxclients = i;
 111
 112         //registercommand("hud_configure");
 113         //registercommand("hud_save");
 114         //registercommand("menu_action");
 115
 116         ConsoleCommand_macro_init();
 117
 118         registercvar("hud_usecsqc", "1");
 119         registercvar("scoreboard_columns", "default");
 120
 121         registercvar("cl_nade_type", "3");
 122         registercvar("cl_pokenade_type", "zombie");
 123
 124         gametype = 0;
 125
 126         // hud_fields uses strunzone on the titles!
 127         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 128                 hud_title[i] = strzone("(null)");
 129
 130         Cmd_HUD_SetFields(0);
 131
 132         postinit = false;
 133
 134         calledhooks = 0;
 135
 136         teams = Sort_Spawn();
 137         players = Sort_Spawn();
 138
 139         GetTeam(NUM_SPECTATOR, true); // add specs first
 140
 141         // needs to be done so early because of the constants they create
 142         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 143         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 144         CALL_ACCUMULATED_FUNCTION(RegisterItems);
 145         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 146         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 147         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 148         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 149         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 150
 151         WaypointSprite_Load();
 152
 153         // precaches
 154         precache_model("null");
 155         precache_sound("misc/hit.wav");
 156         precache_sound("misc/typehit.wav");
 157
 158         generator_precache();
 159         Projectile_Precache();
 160         Hook_Precache();
 161         GibSplash_Precache();
 162         Casings_Precache();
 163         Vehicles_Precache();
 164         turrets_precache();
 165         Tuba_Precache();
 166         CSQCPlayer_Precache();
 167
 168         if(autocvar_cl_reticle)
 169         {
 170                 precache_pic("gfx/reticle_normal");
 171                 // weapon reticles are precached in weapon files
 172         }
 173
 174         get_mi_min_max_texcoords(1); // try the CLEVER way first
 175         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 176         shortmapname = mi_shortname;
 177
 178         if(precache_pic(minimapname) == "")
 179         {
 180                 // but maybe we have a non-clever minimap
 181                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 182                 if(precache_pic(minimapname) == "")
 183                         minimapname = ""; // FAIL
 184                 else
 185                         get_mi_min_max_texcoords(0); // load new texcoords
 186         }
 187
 188         mi_center = (mi_min + mi_max) * 0.5;
 189         mi_scale = mi_max - mi_min;
 190         minimapname = strzone(minimapname);
 191
 192         WarpZone_Init();
 193
 194         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 195         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 196 }
 197
 198 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 199 void Shutdown(void)
 200 {
 201         WarpZone_Shutdown();
 202
 203         remove(teams);
 204         remove(players);
 205         db_close(binddb);
 206         db_close(tempdb);
 207         if(autocvar_cl_db_saveasdump)
 208                 db_dump(ClientProgsDB, "client.db");
 209         else
 210                 db_save(ClientProgsDB, "client.db");
 211         db_close(ClientProgsDB);
 212
 213         if(camera_active)
 214                 cvar_set("chase_active",ftos(chase_active_backup));
 215
 216         // unset the event chasecam's chase_active
 217         if(autocvar_chase_active < 0)
 218                 cvar_set("chase_active", "0");
 219
 220         if (!isdemo())
 221         {
 222                 if (!(calledhooks & HOOK_START))
 223                         localcmd("\n_cl_hook_gamestart nop\n");
 224                 if (!(calledhooks & HOOK_END))
 225                         localcmd("\ncl_hook_gameend\n");
 226         }
 227 }
 228
 229 .float has_team;
 230 float SetTeam(entity o, int Team)
 231 {
 232         entity tm;
 233         if(teamplay)
 234         {
 235                 switch(Team)
 236                 {
 237                         case -1:
 238                         case NUM_TEAM_1:
 239                         case NUM_TEAM_2:
 240                         case NUM_TEAM_3:
 241                         case NUM_TEAM_4:
 242                                 break;
 243                         default:
 244                                 if(GetTeam(Team, false) == world)
 245                                 {
 246                                         dprintf("trying to switch to unsupported team %d\n", Team);
 247                                         Team = NUM_SPECTATOR;
 248                                 }
 249                                 break;
 250                 }
 251         }
 252         else
 253         {
 254                 switch(Team)
 255                 {
 256                         case -1:
 257                         case 0:
 258                                 break;
 259                         default:
 260                                 if(GetTeam(Team, false) == world)
 261                                 {
 262                                         dprintf("trying to switch to unsupported team %d\n", Team);
 263                                         Team = NUM_SPECTATOR;
 264                                 }
 265                                 break;
 266                 }
 267         }
 268         if(Team == -1) // leave
 269         {
 270                 if(o.has_team)
 271                 {
 272                         tm = GetTeam(o.team, false);
 273                         tm.team_size -= 1;
 274                         o.has_team = 0;
 275                         return true;
 276                 }
 277         }
 278         else
 279         {
 280                 if (!o.has_team)
 281                 {
 282                         o.team = Team;
 283                         tm = GetTeam(Team, true);
 284                         tm.team_size += 1;
 285                         o.has_team = 1;
 286                         return true;
 287                 }
 288                 else if(Team != o.team)
 289                 {
 290                         tm = GetTeam(o.team, false);
 291                         tm.team_size -= 1;
 292                         o.team = Team;
 293                         tm = GetTeam(Team, true);
 294                         tm.team_size += 1;
 295                         return true;
 296                 }
 297         }
 298         return false;
 299 }
 300
 301 void Playerchecker_Think()
 302 {
 303     int i;
 304         entity e;
 305         for(i = 0; i < maxclients; ++i)
 306         {
 307                 e = playerslots[i];
 308                 if(GetPlayerName(i) == "")
 309                 {
 310                         if(e.sort_prev)
 311                         {
 312                                 // player disconnected
 313                                 SetTeam(e, -1);
 314                                 RemovePlayer(e);
 315                                 e.sort_prev = world;
 316                                 //e.gotscores = 0;
 317                         }
 318                 }
 319                 else
 320                 {
 321                         if (!e.sort_prev)
 322                         {
 323                                 // player connected
 324                                 if (!e)
 325                                         playerslots[i] = e = spawn();
 326                                 e.sv_entnum = i;
 327                                 e.ping = 0;
 328                                 e.ping_packetloss = 0;
 329                                 e.ping_movementloss = 0;
 330                                 //e.gotscores = 0; // we might already have the scores...
 331                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 332                                 RegisterPlayer(e);
 333                                 HUD_UpdatePlayerPos(e);
 334                         }
 335                 }
 336         }
 337         self.nextthink = time + 0.2;
 338 }
 339
 340 void Porto_Init();
 341 void TrueAim_Init();
 342 void PostInit(void)
 343 {
 344         entity playerchecker;
 345         playerchecker = spawn();
 346         playerchecker.think = Playerchecker_Think;
 347         playerchecker.nextthink = time + 0.2;
 348
 349         Porto_Init();
 350         TrueAim_Init();
 351
 352         postinit = true;
 353 }
 354
 355 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 356 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 357 // All keys are in ascii.
 358 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 359 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 360 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 361 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 362 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 363 {
 364         float bSkipKey;
 365         bSkipKey = false;
 366
 367         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 368                 return true;
 369
 370         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 371                 return true;
 372
 373         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 374                 return true;
 375
 376         if(menu_visible && menu_action)
 377                 if(menu_action(bInputType, nPrimary, nSecondary))
 378                         return true;
 379
 380         return bSkipKey;
 381 }
 382
 383 // END REQUIRED CSQC FUNCTIONS
 384 // --------------------------------------------------------------------------
 385
 386 // --------------------------------------------------------------------------
 387 // BEGIN OPTIONAL CSQC FUNCTIONS
 388
 389 void Ent_RemoveEntCS()
 390 {
 391         entcs_receiver[self.sv_entnum] = world;
 392 }
 393 void Ent_ReadEntCS()
 394 {
 395     int sf;
 396         InterpolateOrigin_Undo();
 397
 398         self.classname = "entcs_receiver";
 399         sf = ReadByte();
 400
 401         if(sf & 1)
 402                 self.sv_entnum = ReadByte();
 403         if(sf & 2)
 404         {
 405                 self.origin_x = ReadShort();
 406                 self.origin_y = ReadShort();
 407                 self.origin_z = ReadShort();
 408                 setorigin(self, self.origin);
 409         }
 410         if(sf & 4)
 411         {
 412                 self.angles_y = ReadByte() * 360.0 / 256;
 413                 self.angles_x = self.angles_z = 0;
 414         }
 415         if(sf & 8)
 416                 self.healthvalue = ReadByte() * 10;
 417         if(sf & 16)
 418                 self.armorvalue = ReadByte() * 10;
 419
 420         entcs_receiver[self.sv_entnum] = self;
 421         self.entremove = Ent_RemoveEntCS;
 422         self.iflags |= IFLAG_ORIGIN;
 423
 424         InterpolateOrigin_Note();
 425 }
 426
 427 void Ent_Remove();
 428
 429 void Ent_RemovePlayerScore()
 430 {
 431         if(self.owner) {
 432                 SetTeam(self.owner, -1);
 433                 self.owner.gotscores = 0;
 434                 for(int i = 0; i < MAX_SCORE; ++i) {
 435                         self.owner.(scores[i]) = 0; // clear all scores
 436                 }
 437         }
 438 }
 439
 440 void Ent_ReadPlayerScore()
 441 {
 442         int i, n;
 443         bool isNew;
 444         entity o;
 445
 446         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 447         // (no I've never heard of M-x replace-string, sed, or anything like that)
 448         isNew = !self.owner; // workaround for DP bug
 449         n = ReadByte()-1;
 450
 451 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 452         if(!isNew && n != self.sv_entnum)
 453         {
 454                 //print("A CSQC entity changed its owner!\n");
 455                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 456                 isNew = true;
 457                 Ent_Remove();
 458                 self.enttype = ENT_CLIENT_SCORES;
 459         }
 460 #endif
 461
 462         self.sv_entnum = n;
 463
 464         if (!(playerslots[self.sv_entnum]))
 465                 playerslots[self.sv_entnum] = spawn();
 466         o = self.owner = playerslots[self.sv_entnum];
 467         o.sv_entnum = self.sv_entnum;
 468         o.gotscores = 1;
 469
 470         //if (!o.sort_prev)
 471         //      RegisterPlayer(o);
 472         //playerchecker will do this for us later, if it has not already done so
 473
 474     int sf, lf;
 475 #if MAX_SCORE <= 8
 476         sf = ReadByte();
 477         lf = ReadByte();
 478 #else
 479         sf = ReadShort();
 480         lf = ReadShort();
 481 #endif
 482     int p;
 483         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 484                 if(sf & p)
 485                 {
 486                         if(lf & p)
 487                                 o.(scores[i]) = ReadInt24_t();
 488                         else
 489                                 o.(scores[i]) = ReadChar();
 490                 }
 491
 492         if(o.sort_prev)
 493                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 494
 495         self.entremove = Ent_RemovePlayerScore;
 496 }
 497
 498 void Ent_ReadTeamScore()
 499 {
 500         int i;
 501         entity o;
 502
 503         self.team = ReadByte();
 504         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 505
 506     int sf, lf;
 507 #if MAX_TEAMSCORE <= 8
 508         sf = ReadByte();
 509         lf = ReadByte();
 510 #else
 511         sf = ReadShort();
 512         lf = ReadShort();
 513 #endif
 514         int p;
 515         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 516                 if(sf & p)
 517                 {
 518                         if(lf & p)
 519                                 o.(teamscores[i]) = ReadInt24_t();
 520                         else
 521                                 o.(teamscores[i]) = ReadChar();
 522                 }
 523
 524         HUD_UpdateTeamPos(o);
 525 }
 526
 527 void Ent_ClientData()
 528 {
 529         float newspectatee_status;
 530
 531     int f = ReadByte();
 532
 533         scoreboard_showscores_force = (f & 1);
 534
 535         if(f & 2)
 536         {
 537                 newspectatee_status = ReadByte();
 538                 if(newspectatee_status == player_localnum + 1)
 539                         newspectatee_status = -1; // observing
 540         }
 541         else
 542                 newspectatee_status = 0;
 543
 544         spectatorbutton_zoom = (f & 4);
 545
 546         if(f & 8)
 547         {
 548                 angles_held_status = 1;
 549                 angles_held.x = ReadAngle();
 550                 angles_held.y = ReadAngle();
 551                 angles_held.z = 0;
 552         }
 553         else
 554                 angles_held_status = 0;
 555
 556         if(newspectatee_status != spectatee_status)
 557         {
 558                 // clear race stuff
 559                 race_laptime = 0;
 560                 race_checkpointtime = 0;
 561         }
 562         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 563         {
 564                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 565                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 566                 )
 567                         prev_p_health = -1;
 568                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 569                         prev_health = -1;
 570         }
 571         spectatee_status = newspectatee_status;
 572
 573         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 574 }
 575
 576 void Ent_Nagger()
 577 {
 578     int i, j, b, f;
 579
 580     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 581
 582         if(!(nags & 4))
 583         {
 584                 if(vote_called_vote)
 585                         strunzone(vote_called_vote);
 586                 vote_called_vote = string_null;
 587                 vote_active = 0;
 588         }
 589         else
 590         {
 591                 vote_active = 1;
 592         }
 593
 594         if(nags & 64)
 595         {
 596                 vote_yescount = ReadByte();
 597                 vote_nocount = ReadByte();
 598                 vote_needed = ReadByte();
 599                 vote_highlighted = ReadChar();
 600         }
 601
 602         if(nags & 128)
 603         {
 604                 if(vote_called_vote)
 605                         strunzone(vote_called_vote);
 606                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 607         }
 608
 609         if(nags & 1)
 610         {
 611                 for(j = 0; j < maxclients; ++j)
 612                         if(playerslots[j])
 613                                 playerslots[j].ready = 1;
 614                 for(i = 1; i <= maxclients; i += 8)
 615                 {
 616                         f = ReadByte();
 617                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 618                                 if (!(f & b))
 619                                         if(playerslots[j])
 620                                                 playerslots[j].ready = 0;
 621                 }
 622         }
 623
 624         ready_waiting = (nags & 1);
 625         ready_waiting_for_me = (nags & 2);
 626         vote_waiting = (nags & 4);
 627         vote_waiting_for_me = (nags & 8);
 628         warmup_stage = (nags & 16);
 629 }
 630
 631 void Ent_EliminatedPlayers()
 632 {
 633     int i, j, b, f;
 634
 635     int sf = ReadByte();
 636         if(sf & 1)
 637         {
 638                 for(j = 0; j < maxclients; ++j)
 639                         if(playerslots[j])
 640                                 playerslots[j].eliminated = 1;
 641                 for(i = 1; i <= maxclients; i += 8)
 642                 {
 643                         f = ReadByte();
 644                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 645                                 if (!(f & b))
 646                                         if(playerslots[j])
 647                                                 playerslots[j].eliminated = 0;
 648                 }
 649         }
 650 }
 651
 652 void Ent_RandomSeed()
 653 {
 654         float s;
 655         prandom_debug();
 656         s = ReadShort();
 657         psrandom(s);
 658 }
 659
 660 void Ent_ReadAccuracy(void)
 661 {
 662     int f, w;
 663     int sf = ReadInt24_t();
 664         if(sf == 0)
 665         {
 666                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 667                         weapon_accuracy[w] = -1;
 668                 return;
 669         }
 670
 671         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 672         {
 673                 if(sf & f)
 674                 {
 675             int b = ReadByte();
 676                         if(b == 0)
 677                                 weapon_accuracy[w] = -1;
 678                         else if(b == 255)
 679                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 680                         else
 681                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 682                 }
 683                 if(f == 0x800000)
 684                         f = 1;
 685                 else
 686                         f *= 2;
 687         }
 688 }
 689
 690 void Spawn_Draw(void)
 691 {
 692         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 693 }
 694
 695 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 696 {
 697         float teamnum = (ReadByte() - 1);
 698         vector spn_origin;
 699         spn_origin.x = ReadShort();
 700         spn_origin.y = ReadShort();
 701         spn_origin.z = ReadShort();
 702
 703         if(is_new)
 704         {
 705                 self.origin = spn_origin;
 706                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 707                 droptofloor();
 708
 709                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 710                 {
 711                         self.mdl = "models/spawnpoint.md3";
 712                         self.colormod = Team_ColorRGB(teamnum);
 713                         precache_model(self.mdl);
 714                         setmodel(self, self.mdl);
 715                         self.drawmask = MASK_NORMAL;
 716                         //self.movetype = MOVETYPE_NOCLIP;
 717                         //self.draw = Spawn_Draw;
 718                 }*/
 719                 if(autocvar_cl_spawn_point_particles)
 720                 {
 721                         if((serverflags & SERVERFLAG_TEAMPLAY))
 722                         {
 723                                 switch(teamnum)
 724                                 {
 725                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 726                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 727                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 728                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 729                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 730                                 }
 731                         }
 732                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 733
 734                         self.draw = Spawn_Draw;
 735                 }
 736         }
 737
 738         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 739 }
 740
 741 void Ent_ReadSpawnEvent(float is_new)
 742 {
 743         // If entnum is 0, ONLY do the local spawn actions
 744         // this way the server can disable the sending of
 745         // spawn origin or such to clients if wanted.
 746         float entnum = ReadByte();
 747
 748         if(entnum)
 749         {
 750                 self.origin_x = ReadShort();
 751                 self.origin_y = ReadShort();
 752                 self.origin_z = ReadShort();
 753
 754                 if(is_new)
 755                 {
 756                         float teamnum = GetPlayerColor(entnum - 1);
 757
 758                         if(autocvar_cl_spawn_event_particles)
 759                         {
 760                                 switch(teamnum)
 761                                 {
 762                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 763                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 764                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 765                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 766                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 767                                 }
 768                         }
 769                         if(autocvar_cl_spawn_event_sound)
 770                         {
 771                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 772                         }
 773                 }
 774         }
 775
 776         // local spawn actions
 777         if(is_new && (!entnum || (entnum == player_localentnum)))
 778         {
 779                 zoomin_effect = 1;
 780                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 781
 782                 if(autocvar_cl_unpress_zoom_on_spawn)
 783                 {
 784                         localcmd("-zoom\n");
 785                         button_zoom = false;
 786                 }
 787         }
 788         HUD_Radar_Hide_Maximized();
 789         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 790 }
 791
 792 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 793 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 794 void Ent_RadarLink();
 795 void Ent_Init();
 796 void Ent_ScoresInfo();
 797 void CSQC_Ent_Update(float bIsNewEntity)
 798 {
 799         float t;
 800         float savetime;
 801         t = ReadByte();
 802
 803         if(autocvar_developer_csqcentities)
 804                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 805
 806         // set up the "time" global for received entities to be correct for interpolation purposes
 807         savetime = time;
 808         if(servertime)
 809         {
 810                 time = servertime;
 811         }
 812         else
 813         {
 814                 serverprevtime = time;
 815                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 816                 time = serverprevtime + serverdeltatime;
 817         }
 818
 819 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 820         if(self.enttype)
 821         {
 822                 if(t != self.enttype || bIsNewEntity)
 823                 {
 824                         //print("A CSQC entity changed its type!\n");
 825                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 826                         Ent_Remove();
 827                         clearentity(self);
 828                         bIsNewEntity = 1;
 829                 }
 830         }
 831         else
 832         {
 833                 if(!bIsNewEntity)
 834                 {
 835                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 836                         bIsNewEntity = 1;
 837                 }
 838         }
 839 #endif
 840         self.enttype = t;
 841         switch(t)
 842         {
 843                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 844                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 845                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 846                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 847                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 848                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 849                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 850                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 851                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 852                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 853                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 854                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 855                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 856                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 857                 case ENT_CLIENT_INIT: Ent_Init(); break;
 858                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 859                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 860                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 861                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 862                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 863                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 864                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 865                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 866                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 867                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 868                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 869                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 870                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 871                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 872                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 873                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 874                 case ENT_CLIENT_TURRET: ent_turret(); break;
 875                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 876                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
 877                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 878                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 879                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 880                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 881                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 882                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 883                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 884                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 885                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 886                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 887                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 888                 case ENT_CLIENT_DOOR: ent_door(); break;
 889                 case ENT_CLIENT_PLAT: ent_plat(); break;
 890                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 891                 case ENT_CLIENT_CORNER: ent_corner(); break;
 892                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 893                 case ENT_CLIENT_TRAIN: ent_train(); break;
 894                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 895
 896                 default:
 897                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 898                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 899                         break;
 900         }
 901
 902         time = savetime;
 903 }
 904 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 905 // used when an entity changes its type. For an entity that someone interacts
 906 // with others, make sure it can no longer do so.
 907 void Ent_Remove()
 908 {
 909         if(self.entremove)
 910                 self.entremove();
 911
 912         if(self.skeletonindex)
 913         {
 914                 skel_delete(self.skeletonindex);
 915                 self.skeletonindex = 0;
 916         }
 917
 918         if(self.snd_looping > 0)
 919         {
 920                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 921                 self.snd_looping = 0;
 922         }
 923
 924         self.enttype = 0;
 925         self.classname = "";
 926         self.draw = menu_sub_null;
 927         self.entremove = menu_sub_null;
 928         // TODO possibly set more stuff to defaults
 929 }
 930 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 931 void CSQC_Ent_Remove()
 932 {
 933         if(autocvar_developer_csqcentities)
 934                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 935
 936         if(wasfreed(self))
 937         {
 938                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 939                 return;
 940         }
 941         if(self.enttype)
 942                 Ent_Remove();
 943         remove(self);
 944 }
 945
 946 void Gamemode_Init()
 947 {
 948         if (!isdemo())
 949         {
 950                 if(!(calledhooks & HOOK_START))
 951                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 952                 calledhooks |= HOOK_START;
 953         }
 954 }
 955 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 956 void CSQC_Parse_StuffCmd(string strMessage)
 957 {
 958         if(autocvar_developer_csqcentities)
 959                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 960
 961         localcmd(strMessage);
 962 }
 963 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 964 void CSQC_Parse_Print(string strMessage)
 965 {
 966         if(autocvar_developer_csqcentities)
 967                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 968
 969         print(ColorTranslateRGB(strMessage));
 970 }
 971
 972 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 973 void CSQC_Parse_CenterPrint(string strMessage)
 974 {
 975         if(autocvar_developer_csqcentities)
 976                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 977
 978         centerprint_hud(strMessage);
 979 }
 980
 981 string notranslate_fogcmd1 = "\nfog ";
 982 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 983 void Fog_Force()
 984 {
 985         // TODO somehow thwart prvm_globalset client ...
 986
 987         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 988                 { localcmd("\nr_drawfog 0\n"); }
 989         else if(forcefog != "")
 990                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 991 }
 992
 993 void Gamemode_Init();
 994 void Ent_ScoresInfo()
 995 {
 996     int i;
 997         self.classname = "ent_client_scores_info";
 998         gametype = ReadInt24_t();
 999         HUD_ModIcons_SetFunc();
1000         for(i = 0; i < MAX_SCORE; ++i)
1001         {
1002                 if(scores_label[i])
1003                         strunzone(scores_label[i]);
1004                 scores_label[i] = strzone(ReadString());
1005                 scores_flags[i] = ReadByte();
1006         }
1007         for(i = 0; i < MAX_TEAMSCORE; ++i)
1008         {
1009                 if(teamscores_label[i])
1010                         strunzone(teamscores_label[i]);
1011                 teamscores_label[i] = strzone(ReadString());
1012                 teamscores_flags[i] = ReadByte();
1013         }
1014         HUD_InitScores();
1015         Gamemode_Init();
1016 }
1017
1018 void Ent_Init()
1019 {
1020         self.classname = "ent_client_init";
1021
1022         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1023
1024         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1025         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1026         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1027         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1028         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1029         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1030         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1031         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1032
1033         if(forcefog)
1034                 strunzone(forcefog);
1035         forcefog = strzone(ReadString());
1036
1037         armorblockpercent = ReadByte() / 255.0;
1038
1039         g_balance_mortar_bouncefactor = ReadCoord();
1040         g_balance_mortar_bouncestop = ReadCoord();
1041         g_balance_electro_secondary_bouncefactor = ReadCoord();
1042         g_balance_electro_secondary_bouncestop = ReadCoord();
1043
1044         vortex_scope = !ReadByte();
1045         rifle_scope = !ReadByte();
1046
1047         serverflags = ReadByte();
1048
1049         minelayer_maxmines = ReadByte();
1050
1051         hagar_maxrockets = ReadByte();
1052
1053         g_trueaim_minrange = ReadCoord();
1054         g_balance_porto_secondary = ReadByte();
1055
1056         if(!postinit)
1057                 PostInit();
1058 }
1059
1060 void Net_ReadRace()
1061 {
1062         float b;
1063
1064         b = ReadByte();
1065
1066         switch(b)
1067         {
1068                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1069                         race_checkpoint = ReadByte();
1070                         race_time = ReadInt24_t();
1071                         race_previousbesttime = ReadInt24_t();
1072                         if(race_previousbestname)
1073                                 strunzone(race_previousbestname);
1074                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1075
1076                         race_checkpointtime = time;
1077
1078                         if(race_checkpoint == 0 || race_checkpoint == 254)
1079                         {
1080                                 race_penaltyaccumulator = 0;
1081                                 race_laptime = time; // valid
1082                         }
1083
1084                         break;
1085
1086                 case RACE_NET_CHECKPOINT_CLEAR:
1087                         race_laptime = 0;
1088                         race_checkpointtime = 0;
1089                         break;
1090
1091                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1092                         race_laptime = ReadCoord();
1093                         race_checkpointtime = -99999;
1094                         // fall through
1095                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1096                         race_nextcheckpoint = ReadByte();
1097
1098                         race_nextbesttime = ReadInt24_t();
1099                         if(race_nextbestname)
1100                                 strunzone(race_nextbestname);
1101                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1102                         break;
1103
1104                 case RACE_NET_CHECKPOINT_HIT_RACE:
1105                         race_mycheckpoint = ReadByte();
1106                         race_mycheckpointtime = time;
1107                         race_mycheckpointdelta = ReadInt24_t();
1108                         race_mycheckpointlapsdelta = ReadByte();
1109                         if(race_mycheckpointlapsdelta >= 128)
1110                                 race_mycheckpointlapsdelta -= 256;
1111                         if(race_mycheckpointenemy)
1112                                 strunzone(race_mycheckpointenemy);
1113                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1114                         break;
1115
1116                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1117                         race_othercheckpoint = ReadByte();
1118                         race_othercheckpointtime = time;
1119                         race_othercheckpointdelta = ReadInt24_t();
1120                         race_othercheckpointlapsdelta = ReadByte();
1121                         if(race_othercheckpointlapsdelta >= 128)
1122                                 race_othercheckpointlapsdelta -= 256;
1123                         if(race_othercheckpointenemy)
1124                                 strunzone(race_othercheckpointenemy);
1125                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1126                         break;
1127
1128                 case RACE_NET_PENALTY_RACE:
1129                         race_penaltyeventtime = time;
1130                         race_penaltytime = ReadShort();
1131                         //race_penaltyaccumulator += race_penaltytime;
1132                         if(race_penaltyreason)
1133                                 strunzone(race_penaltyreason);
1134                         race_penaltyreason = strzone(ReadString());
1135                         break;
1136
1137                 case RACE_NET_PENALTY_QUALIFYING:
1138                         race_penaltyeventtime = time;
1139                         race_penaltytime = ReadShort();
1140                         race_penaltyaccumulator += race_penaltytime;
1141                         if(race_penaltyreason)
1142                                 strunzone(race_penaltyreason);
1143                         race_penaltyreason = strzone(ReadString());
1144                         break;
1145
1146                 case RACE_NET_SERVER_RECORD:
1147                         race_server_record = ReadInt24_t();
1148                         break;
1149                 case RACE_NET_SPEED_AWARD:
1150                         race_speedaward = ReadInt24_t();
1151                         if(race_speedaward_holder)
1152                                 strunzone(race_speedaward_holder);
1153                         race_speedaward_holder = strzone(ReadString());
1154                         break;
1155                 case RACE_NET_SPEED_AWARD_BEST:
1156                         race_speedaward_alltimebest = ReadInt24_t();
1157                         if(race_speedaward_alltimebest_holder)
1158                                 strunzone(race_speedaward_alltimebest_holder);
1159                         race_speedaward_alltimebest_holder = strzone(ReadString());
1160                         break;
1161                 case RACE_NET_SERVER_RANKINGS:
1162                         float prevpos, del;
1163             int pos = ReadShort();
1164                         prevpos = ReadShort();
1165                         del = ReadShort();
1166
1167                         // move other rankings out of the way
1168             int i;
1169                         if (prevpos) {
1170                                 for (i=prevpos-1;i>pos-1;--i) {
1171                                         grecordtime[i] = grecordtime[i-1];
1172                                         if(grecordholder[i])
1173                                                 strunzone(grecordholder[i]);
1174                                         grecordholder[i] = strzone(grecordholder[i-1]);
1175                                 }
1176                         } else if (del) { // a record has been deleted by the admin
1177                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1178                                         if (i == RANKINGS_CNT-1) { // clear out last record
1179                                                 grecordtime[i] = 0;
1180                                                 if (grecordholder[i])
1181                                                         strunzone(grecordholder[i]);
1182                                                 grecordholder[i] = string_null;
1183                                         }
1184                                         else {
1185                                                 grecordtime[i] = grecordtime[i+1];
1186                                                 if (grecordholder[i])
1187                                                         strunzone(grecordholder[i]);
1188                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1189                                         }
1190                                 }
1191                         } else { // player has no ranked record yet
1192                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1193                                         grecordtime[i] = grecordtime[i-1];
1194                                         if(grecordholder[i])
1195                                                 strunzone(grecordholder[i]);
1196                                         grecordholder[i] = strzone(grecordholder[i-1]);
1197                                 }
1198                         }
1199
1200                         // store new ranking
1201                         if(grecordholder[pos-1] != "")
1202                                 strunzone(grecordholder[pos-1]);
1203                         grecordholder[pos-1] = strzone(ReadString());
1204                         grecordtime[pos-1] = ReadInt24_t();
1205                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1206                                 race_myrank = pos;
1207                         break;
1208                 case RACE_NET_SERVER_STATUS:
1209                         race_status = ReadShort();
1210                         if(race_status_name)
1211                                 strunzone(race_status_name);
1212                         race_status_name = strzone(ReadString());
1213         }
1214 }
1215
1216 void Net_TeamNagger()
1217 {
1218         teamnagger = 1;
1219 }
1220
1221 void Net_ReadPingPLReport()
1222 {
1223         int e, pi, pl, ml;
1224         e = ReadByte();
1225         pi = ReadShort();
1226         pl = ReadByte();
1227         ml = ReadByte();
1228         if (!(playerslots[e]))
1229                 return;
1230         playerslots[e].ping = pi;
1231         playerslots[e].ping_packetloss = pl / 255.0;
1232         playerslots[e].ping_movementloss = ml / 255.0;
1233 }
1234
1235 void Net_WeaponComplain()
1236 {
1237         complain_weapon = ReadByte();
1238
1239         if(complain_weapon_name)
1240                 strunzone(complain_weapon_name);
1241         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1242
1243         complain_weapon_type = ReadByte();
1244
1245         complain_weapon_time = time;
1246         weapontime = time; // ping the weapon panel
1247
1248         switch(complain_weapon_type)
1249         {
1250                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1251                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1252                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1253         }
1254 }
1255
1256 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1257 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1258 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1259 float CSQC_Parse_TempEntity()
1260 {
1261         float bHandled;
1262                 bHandled  = true;
1263         // Acquire TE ID
1264         float nTEID;
1265                 nTEID = ReadByte();
1266
1267         if(autocvar_developer_csqcentities)
1268                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1269
1270                 // NOTE: Could just do return instead of break...
1271         switch(nTEID)
1272         {
1273                 case TE_CSQC_TARGET_MUSIC:
1274                         Net_TargetMusic();
1275                         bHandled = true;
1276                         break;
1277                 case TE_CSQC_PICTURE:
1278                         Net_MapVote_Picture();
1279                         bHandled = true;
1280                         break;
1281                 case TE_CSQC_RACE:
1282                         Net_ReadRace();
1283                         bHandled = true;
1284                         break;
1285                 case TE_CSQC_VORTEXBEAMPARTICLE:
1286                         Net_ReadVortexBeamParticle();
1287                         bHandled = true;
1288                         break;
1289                 case TE_CSQC_TEAMNAGGER:
1290                         Net_TeamNagger();
1291                         bHandled = true;
1292                         break;
1293                 case TE_CSQC_ARC:
1294                         Net_ReadArc();
1295                         bHandled = true;
1296                         break;
1297                 case TE_CSQC_PINGPLREPORT:
1298                         Net_ReadPingPLReport();
1299                         bHandled = true;
1300                         break;
1301                 case TE_CSQC_WEAPONCOMPLAIN:
1302                         Net_WeaponComplain();
1303                         bHandled = true;
1304                         break;
1305                 case TE_CSQC_VEHICLESETUP:
1306                         Net_VehicleSetup();
1307                         bHandled = true;
1308                         break;
1309                 case TE_CSQC_SVNOTICE:
1310                         cl_notice_read();
1311                         bHandled = true;
1312                         break;
1313                 case TE_CSQC_SHOCKWAVEPARTICLE:
1314                         Net_ReadShockwaveParticle();
1315                         bHandled = true;
1316                         break;
1317                 default:
1318                         // No special logic for this temporary entity; return 0 so the engine can handle it
1319                         bHandled = false;
1320                         break;
1321         }
1322
1323         return bHandled;
1324 }
1325
1326 string getcommandkey(string text, string command)
1327 {
1328         string keys;
1329         float n, j, k, l = 0;
1330
1331         if (!autocvar_hud_showbinds)
1332                 return text;
1333
1334         keys = db_get(binddb, command);
1335         if (keys == "")
1336         {
1337                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1338                 for(j = 0; j < n; ++j)
1339                 {
1340                         k = stof(argv(j));
1341                         if(k != -1)
1342                         {
1343                                 if ("" == keys)
1344                                         keys = keynumtostring(k);
1345                                 else
1346                                         keys = strcat(keys, ", ", keynumtostring(k));
1347
1348                                 ++l;
1349                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1350                                         break;
1351                         }
1352
1353                 }
1354                 if (keys == "")
1355                         keys = "NO_KEY";
1356                 db_put(binddb, command, keys);
1357         }
1358
1359         if (keys == "NO_KEY") {
1360                 if (autocvar_hud_showbinds > 1)
1361                         return sprintf(_("%s (not bound)"), text);
1362                 else
1363                         return text;
1364         }
1365         else if (autocvar_hud_showbinds > 1)
1366                 return sprintf("%s (%s)", text, keys);
1367         else
1368                 return keys;
1369 }