qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/quickmenu.qh>
   8 #include <client/hud/panel/scoreboard.qh>
   9 #include <client/items/items.qh>
  10 #include <client/mapvoting.qh>
  11 #include <client/mutators/_mod.qh>
  12 #include <client/shownames.qh>
  13 #include <client/view.qh>
  14 #include <client/weapons/projectile.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/effects/all.inc>
  17 #include <common/effects/all.qh>
  18 #include <common/effects/effect.qh>
  19 #include <common/effects/qc/_mod.qh>
  20 #include <common/ent_cs.qh>
  21 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/mapobjects/_mod.qh>
  25 #include <common/minigames/cl_minigames.qh>
  26 #include <common/minigames/cl_minigames_hud.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/scores.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  42 // Useful for precaching things
  43
  44 void CSQC_Init()
  45 {
  46         prvm_language = strzone(cvar_string("prvm_language"));
  47
  48 #ifdef WATERMARK
  49         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  50 #endif
  51
  52         {
  53                 int i = 0;
  54                 for ( ; i < 255; ++i)
  55                         if (getplayerkeyvalue(i, "viewentity") == "")
  56                                 break;
  57                 maxclients = i;
  58         }
  59
  60         // needs to be done so early because of the constants they create
  61         static_init();
  62         static_init_late();
  63         static_init_precache();
  64
  65         binddb = db_create();
  66         tempdb = db_create();
  67         ClientProgsDB = db_load("client.db");
  68
  69         draw_endBoldFont();
  70
  71         //registercommand("hud_configure");
  72         //registercommand("hud_save");
  73         //registercommand("menu_action");
  74
  75         ConsoleCommand_macro_init();
  76
  77         registercvar("hud_usecsqc", "1");
  78         registercvar("scoreboard_columns", "default");
  79
  80         registercvar("cl_nade_type", "3");
  81         registercvar("cl_pokenade_type", "zombie");
  82
  83         registercvar("cl_jumpspeedcap_min", "");
  84         registercvar("cl_jumpspeedcap_max", "");
  85
  86         registercvar("cl_shootfromfixedorigin", "");
  87
  88         registercvar("cl_multijump", "-1");
  89
  90         registercvar("cl_dodging", "0");
  91
  92         registercvar("cl_spawn_near_teammate", "1");
  93
  94         registercvar("cl_weapon_switch_reload", "1");
  95         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  96
  97         registercvar("cl_allow_uidranking", "1");
  98
  99         if(autocvar_cl_lockview)
 100                 cvar_set("cl_lockview", "0");
 101
 102         gametype = NULL;
 103
 104         postinit = false;
 105
 106         calledhooks = 0;
 107
 108         teams = Sort_Spawn();
 109         players = Sort_Spawn();
 110
 111         GetTeam(NUM_SPECTATOR, true); // add specs first
 112
 113         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 114                 weapon_accuracy[w] = -1;
 115
 116         // precaches
 117
 118         if(autocvar_cl_reticle)
 119         {
 120                 precache_pic("gfx/reticle_normal");
 121                 // weapon reticles are precached in weapon files
 122         }
 123
 124         {
 125                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 126                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 127                 shortmapname = mi_shortname;
 128
 129                 if (precache_pic(minimapname) == "")
 130                 {
 131                         // but maybe we have a non-clever minimap
 132                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 133                         if (precache_pic(minimapname) == "")
 134                                 minimapname = ""; // FAIL
 135                         else
 136                                 get_mi_min_max_texcoords(0); // load new texcoords
 137                 }
 138
 139                 mi_center = (mi_min + mi_max) * 0.5;
 140                 mi_scale = mi_max - mi_min;
 141                 minimapname = strzone(minimapname);
 142         }
 143
 144         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 145         LoadMenuSkinValues();
 146 }
 147
 148 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 149 void Shutdown()
 150 {
 151         WarpZone_Shutdown();
 152
 153         delete(teams);
 154         delete(players);
 155         db_close(binddb);
 156         db_close(tempdb);
 157         if(autocvar_cl_db_saveasdump)
 158                 db_dump(ClientProgsDB, "client.db");
 159         else
 160                 db_save(ClientProgsDB, "client.db");
 161         db_close(ClientProgsDB);
 162
 163         if(camera_active)
 164                 cvar_set("chase_active",ftos(chase_active_backup));
 165
 166         // unset the event chasecam's chase_active
 167         if(autocvar_chase_active < 0)
 168                 cvar_set("chase_active", "0");
 169
 170         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 171
 172         if (!isdemo())
 173         {
 174                 if (!(calledhooks & HOOK_START))
 175                         localcmd("\n_cl_hook_gamestart nop\n");
 176                 if (!(calledhooks & HOOK_END))
 177                 {
 178                         int gamecount = cvar("cl_matchcount");
 179                         localcmd("\ncl_hook_gameend\n");
 180                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 181                         // earlier versions of the game abuse the hook to set this cvar
 182                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 183                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 184                 }
 185         }
 186
 187         localcmd("\ncl_hook_shutdown\n");
 188
 189         localcmd("\n-button12\n");
 190
 191         deactivate_minigame();
 192         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 193
 194         ReplicateVars(true); // destroy
 195 }
 196
 197 void AuditLists()
 198 {
 199         entity e;
 200         entity prev;
 201
 202         prev = players;
 203         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 204         {
 205                 if(prev != e.sort_prev)
 206                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 207         }
 208
 209         prev = teams;
 210         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 211         {
 212                 if(prev != e.sort_prev)
 213                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 214         }
 215 }
 216
 217 float RegisterPlayer(entity player)
 218 {
 219         entity pl;
 220         AuditLists();
 221         for(pl = players.sort_next; pl; pl = pl.sort_next)
 222                 if(pl == player)
 223                         error("Player already registered!");
 224         player.sort_next = players.sort_next;
 225         player.sort_prev = players;
 226         if(players.sort_next)
 227                 players.sort_next.sort_prev = player;
 228         players.sort_next = player;
 229         AuditLists();
 230         return true;
 231 }
 232
 233 void RemovePlayer(entity player)
 234 {
 235         entity pl, parent;
 236         AuditLists();
 237         parent = players;
 238         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 239                 parent = pl;
 240
 241         if(!pl)
 242         {
 243                 error("Trying to remove a player which is not in the playerlist!");
 244                 return;
 245         }
 246         parent.sort_next = player.sort_next;
 247         if(player.sort_next)
 248                 player.sort_next.sort_prev = parent;
 249         AuditLists();
 250 }
 251
 252 void MoveToLast(entity e)
 253 {
 254         AuditLists();
 255         entity ent = e.sort_next;
 256         while(ent)
 257         {
 258                 SORT_SWAP(ent, e);
 259                 ent = e.sort_next;
 260         }
 261         AuditLists();
 262 }
 263
 264 float RegisterTeam(entity Team)
 265 {
 266         assert_once(Team.team, eprint(Team));
 267         entity tm;
 268         AuditLists();
 269         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 270                 if(tm == Team)
 271                         error("Team already registered!");
 272         Team.sort_next = teams.sort_next;
 273         Team.sort_prev = teams;
 274         if(teams.sort_next)
 275                 teams.sort_next.sort_prev = Team;
 276         teams.sort_next = Team;
 277         if(Team.team && Team.team != NUM_SPECTATOR)
 278                 ++team_count;
 279         AuditLists();
 280         return true;
 281 }
 282
 283 void RemoveTeam(entity Team)
 284 {
 285         entity tm, parent;
 286         AuditLists();
 287         parent = teams;
 288         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 289                 parent = tm;
 290
 291         if(!tm)
 292         {
 293                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 294                 return;
 295         }
 296         parent.sort_next = Team.sort_next;
 297         if(Team.sort_next)
 298                 Team.sort_next.sort_prev = parent;
 299         if(Team.team && Team.team != NUM_SPECTATOR)
 300                 --team_count;
 301         AuditLists();
 302 }
 303
 304 entity GetTeam(int Team, bool add)
 305 {
 306         TC(int, Team); TC(bool, add);
 307         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 308         if(teamslots[num])
 309                 return teamslots[num];
 310         if (!add)
 311                 return NULL;
 312         entity tm = new_pure(team);
 313         tm.team = Team;
 314         teamslots[num] = tm;
 315         RegisterTeam(tm);
 316         return tm;
 317 }
 318
 319 .float has_team;
 320 bool SetTeam(entity o, int Team)
 321 {
 322         TC(int, Team);
 323         //devassert_once(Team);
 324         entity tm;
 325         if(teamplay)
 326         {
 327                 switch(Team)
 328                 {
 329                         case -1:
 330                         case NUM_TEAM_1:
 331                         case NUM_TEAM_2:
 332                         case NUM_TEAM_3:
 333                         case NUM_TEAM_4:
 334                                 break;
 335                         default:
 336                                 if(GetTeam(Team, false) == NULL)
 337                                 {
 338                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 339                                         Team = NUM_SPECTATOR;
 340                                 }
 341                                 break;
 342                 }
 343         }
 344         else
 345         {
 346                 switch(Team)
 347                 {
 348                         case -1:
 349                         case 0:
 350                                 break;
 351                         default:
 352                                 if(GetTeam(Team, false) == NULL)
 353                                 {
 354                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 355                                         Team = NUM_SPECTATOR;
 356                                 }
 357                                 break;
 358                 }
 359         }
 360         if(Team == -1) // leave
 361         {
 362                 if(o.has_team)
 363                 {
 364                         tm = GetTeam(o.team, false);
 365                         tm.team_size -= 1;
 366                         o.has_team = 0;
 367                         return true;
 368                 }
 369         }
 370         else
 371         {
 372                 if (!o.has_team)
 373                 {
 374                         o.team = Team;
 375                         tm = GetTeam(Team, true);
 376                         tm.team_size += 1;
 377                         o.has_team = 1;
 378                         return true;
 379                 }
 380                 else if(Team != o.team)
 381                 {
 382                         tm = GetTeam(o.team, false);
 383                         tm.team_size -= 1;
 384                         o.team = Team;
 385                         tm = GetTeam(Team, true);
 386                         tm.team_size += 1;
 387                         return true;
 388                 }
 389         }
 390         return false;
 391 }
 392
 393 void Playerchecker_Think(entity this)
 394 {
 395         int i;
 396         entity e;
 397         for(i = 0; i < maxclients; ++i)
 398         {
 399                 e = playerslots[i];
 400                 if(entcs_GetName(i) == "")
 401                 {
 402                         if(e.sort_prev)
 403                         {
 404                                 // player disconnected
 405                                 SetTeam(e, -1);
 406                                 RemovePlayer(e);
 407                                 e.sort_prev = NULL;
 408                                 //e.gotscores = 0;
 409                         }
 410                 }
 411                 else
 412                 {
 413                         if (!e.sort_prev)
 414                         {
 415                                 // player connected
 416                                 if (!e)
 417                                 {
 418                                         playerslots[i] = e = new_pure(playerslot);
 419                                 }
 420                                 e.sv_entnum = i;
 421                                 e.ping = 0;
 422                                 e.ping_packetloss = 0;
 423                                 e.ping_movementloss = 0;
 424                                 //e.gotscores = 0; // we might already have the scores...
 425                                 int t = entcs_GetScoreTeam(i);
 426                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 427                                 RegisterPlayer(e);
 428                                 Scoreboard_UpdatePlayerPos(e);
 429                         }
 430                 }
 431         }
 432         this.nextthink = time + 0.2;
 433 }
 434
 435 void PostInit()
 436 {
 437         entity playerchecker = new_pure(playerchecker);
 438         setthink(playerchecker, Playerchecker_Think);
 439         playerchecker.nextthink = time + 0.2;
 440
 441         TrueAim_Init();
 442
 443         postinit = true;
 444 }
 445
 446 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 447 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 448 // All keys are in ascii.
 449 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 450 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 451 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 452 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 453 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 454 {
 455         TC(int, bInputType);
 456         bool override = false;
 457         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 458         if (override)
 459                 return true;
 460
 461         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 462
 463         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 464
 465         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 466
 467         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 468
 469         if(override)
 470                 return true;
 471
 472         return false;
 473 }
 474
 475 // END REQUIRED CSQC FUNCTIONS
 476 // --------------------------------------------------------------------------
 477
 478 // --------------------------------------------------------------------------
 479 // BEGIN OPTIONAL CSQC FUNCTIONS
 480
 481 void Ent_RemovePlayerScore(entity this)
 482 {
 483         if(this.owner) {
 484                 SetTeam(this.owner, -1);
 485                 this.owner.gotscores = 0;
 486                 FOREACH(Scores, true, {
 487                         this.owner.(scores(it)) = 0; // clear all scores
 488                 });
 489         }
 490 }
 491
 492 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 493 {
 494         make_pure(this);
 495         entity o;
 496
 497         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 498         // (no I've never heard of M-x replace-string, sed, or anything like that)
 499         bool isNew = !this.owner; // workaround for DP bug
 500         int n = ReadByte()-1;
 501
 502 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 503         if(!isNew && n != this.sv_entnum)
 504         {
 505                 //print("A CSQC entity changed its owner!\n");
 506                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 507                 isNew = true;
 508                 Ent_Remove(this);
 509         }
 510 #endif
 511
 512         this.sv_entnum = n;
 513
 514         o = playerslots[this.sv_entnum];
 515         if (!o)
 516         {
 517                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 518         }
 519         this.owner = o;
 520         o.sv_entnum = this.sv_entnum;
 521         o.gotscores = 1;
 522
 523         //if (!o.sort_prev)
 524         //      RegisterPlayer(o);
 525         //playerchecker will do this for us later, if it has not already done so
 526
 527         int sf = ReadShort();
 528         int lf = ReadShort();
 529         FOREACH(Scores, true, {
 530                 int p = 1 << (i % 16);
 531                 if (sf & p)
 532                 {
 533                         if (lf & p)
 534                                 o.(scores(it)) = ReadInt24_t();
 535                         else
 536                                 o.(scores(it)) = ReadChar();
 537                 }
 538         });
 539
 540         return = true;
 541
 542         if(o.sort_prev)
 543                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 544
 545         this.entremove = Ent_RemovePlayerScore;
 546 }
 547
 548 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 549 {
 550         make_pure(this);
 551         int i;
 552
 553         this.team = ReadByte();
 554         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 555
 556 #if MAX_TEAMSCORE <= 8
 557         int sf = ReadByte();
 558         int lf = ReadByte();
 559 #else
 560         int sf = ReadShort();
 561         int lf = ReadShort();
 562 #endif
 563         for(i = 0; i < MAX_TEAMSCORE; ++i)
 564                 if(sf & BIT(i))
 565                 {
 566                         if(lf & BIT(i))
 567                                 o.(teamscores(i)) = ReadInt24_t();
 568                         else
 569                                 o.(teamscores(i)) = ReadChar();
 570                 }
 571
 572         return = true;
 573
 574         Scoreboard_UpdateTeamPos(o);
 575 }
 576
 577 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 578 {
 579         make_pure(this);
 580         float newspectatee_status;
 581
 582         int f = ReadByte();
 583
 584         scoreboard_showscores_force = (f & BIT(0));
 585
 586         if(f & BIT(1))
 587         {
 588                 newspectatee_status = ReadByte();
 589                 if(newspectatee_status == player_localnum + 1)
 590                         newspectatee_status = -1; // observing
 591         }
 592         else
 593                 newspectatee_status = 0;
 594
 595         spectatorbutton_zoom = (f & BIT(2));
 596
 597         if(f & BIT(4))
 598         {
 599                 num_spectators = ReadByte();
 600
 601                 float i, slot;
 602
 603                 for(i = 0; i < MAX_SPECTATORS; ++i)
 604                         spectatorlist[i] = 0; // reset list first
 605
 606                 int limit = min(num_spectators, MAX_SPECTATORS);
 607                 for(i = 0; i < limit; ++i)
 608                 {
 609                         slot = ReadByte();
 610                         spectatorlist[i] = slot - 1;
 611                 }
 612         }
 613         else
 614         {
 615                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 616                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 617                 num_spectators = 0;
 618         }
 619
 620         return = true;
 621
 622         if(newspectatee_status != spectatee_status)
 623         {
 624                 // clear race stuff
 625                 race_laptime = 0;
 626                 race_checkpointtime = 0;
 627                 hud_dynamic_shake_factor = -1;
 628                 spectatee_status_changed_time = time;
 629         }
 630         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 631         {
 632                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 633                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 634                 )
 635                         prev_p_health = -1;
 636                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 637                         prev_health = -1;
 638         }
 639         spectatee_status = newspectatee_status;
 640
 641         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 642 }
 643
 644 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 645 {
 646         make_pure(this);
 647         int i, j, b, f;
 648
 649         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 650
 651         if(!(nags & BIT(2)))
 652         {
 653                 strfree(vote_called_vote);
 654                 vote_active = 0;
 655         }
 656         else
 657         {
 658                 vote_active = 1;
 659         }
 660
 661         if(nags & BIT(6))
 662         {
 663                 vote_yescount = ReadByte();
 664                 vote_nocount = ReadByte();
 665                 vote_needed = ReadByte();
 666                 vote_highlighted = ReadChar();
 667         }
 668
 669         if(nags & BIT(7))
 670         {
 671                 strcpy(vote_called_vote, ReadString());
 672         }
 673
 674         if(nags & 1)
 675         {
 676                 for(j = 0; j < maxclients; ++j)
 677                         if(playerslots[j])
 678                                 playerslots[j].ready = true;
 679                 for(i = 1; i <= maxclients; i += 8)
 680                 {
 681                         f = ReadByte();
 682                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 683                                 if (!(f & b))
 684                                         if(playerslots[j])
 685                                                 playerslots[j].ready = false;
 686                 }
 687         }
 688
 689         return = true;
 690
 691         ready_waiting = (nags & BIT(0));
 692         ready_waiting_for_me = (nags & BIT(1));
 693         vote_waiting = (nags & BIT(2));
 694         vote_waiting_for_me = (nags & BIT(3));
 695         warmup_stage = (nags & BIT(4));
 696 }
 697
 698 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 699 {
 700         make_pure(this);
 701         int sf = 0;
 702         serialize(byte, 0, sf);
 703         if (sf & 1) {
 704                 for (int j = 0; j < maxclients; ++j) {
 705                         if (playerslots[j]) {
 706                                 playerslots[j].eliminated = true;
 707                         }
 708                 }
 709                 for (int i = 1; i <= maxclients; i += 8) {
 710                         int f = 0;
 711                         serialize(byte, 0, f);
 712                         for (int b = 0; b < 8; ++b) {
 713                                 if (f & BIT(b)) continue;
 714                                 int j = i - 1 + b;
 715                                 if (playerslots[j]) {
 716                                         playerslots[j].eliminated = false;
 717                                 }
 718                         }
 719                 }
 720         }
 721         return true;
 722 }
 723
 724 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 725 {
 726         make_pure(this);
 727         prandom_debug();
 728         float s = ReadShort();
 729         psrandom(s);
 730         return true;
 731 }
 732
 733 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 734 {
 735         make_pure(this);
 736         int sf = ReadInt24_t();
 737         if (sf == 0) {
 738                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 739                         weapon_accuracy[w] = -1;
 740                 return true;
 741         }
 742
 743         int f = 1;
 744         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 745                 if (sf & f) {
 746                         int b = ReadByte();
 747                         if (b == 0)
 748                                 weapon_accuracy[w] = -1;
 749                         else if (b == 255)
 750                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 751                         else
 752                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 753                 }
 754                 f = (f == 0x800000) ? 1 : f * 2;
 755         }
 756         return true;
 757 }
 758
 759 void Spawn_Draw(entity this)
 760 {
 761         bool dodraw = autocvar_cl_spawn_point_particles;
 762         if(dodraw && autocvar_cl_spawn_point_dist_max)
 763         {
 764                 vector org = getpropertyvec(VF_ORIGIN);
 765                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 766         }
 767
 768         if(dodraw)
 769                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 770 }
 771
 772 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 773 {
 774         float teamnum = (ReadByte() - 1);
 775         vector spn_origin = ReadVector();
 776
 777         this.team = (teamnum + 1);
 778
 779         //if(is_new)
 780         //{
 781                 this.origin = spn_origin;
 782                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 783                 //droptofloor();
 784
 785                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 786                 {
 787                         this.mdl = "models/spawnpoint.md3";
 788                         this.colormod = Team_ColorRGB(teamnum);
 789                         precache_model(this.mdl);
 790                         setmodel(this, this.mdl);
 791                         this.drawmask = MASK_NORMAL;
 792                         //this.move_movetype = MOVETYPE_NOCLIP;
 793                         //this.draw = Spawn_Draw;
 794                         IL_PUSH(g_drawables, this);
 795                 }*/
 796                 this.draw = Spawn_Draw;
 797                 if (is_new) IL_PUSH(g_drawables, this);
 798         //}
 799
 800         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 801         return true;
 802 }
 803
 804 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 805 {
 806         // If entnum is 0, ONLY do the local spawn actions
 807         // this way the server can disable the sending of
 808         // spawn origin or such to clients if wanted.
 809         float entnum = ReadByte();
 810
 811         if(entnum)
 812         {
 813                 this.origin = ReadVector();
 814
 815                 if(is_new)
 816                 {
 817                         float teamnum = entcs_GetTeam(entnum - 1);
 818
 819                         if(autocvar_cl_spawn_event_particles)
 820                         {
 821                                 switch(teamnum)
 822                                 {
 823                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 824                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 825                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 826                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 827                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 828                                 }
 829                         }
 830                         if(autocvar_cl_spawn_event_sound)
 831                         {
 832                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 833                         }
 834                 }
 835         }
 836         return = true;
 837
 838         // local spawn actions
 839         if(is_new && (!entnum || (entnum == player_localentnum)))
 840         {
 841                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 842                 {
 843                         zoomin_effect = 1;
 844                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 845                 }
 846
 847                 if(autocvar_cl_unpress_zoom_on_spawn)
 848                 {
 849                         localcmd("-zoom\n");
 850                         button_zoom = false;
 851                 }
 852                 HUD_Radar_Hide_Maximized();
 853         }
 854         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 855 }
 856
 857 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 858 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 859 void CSQC_Ent_Update(entity this, bool isnew)
 860 {
 861         this.sourceLoc = __FILE__":"STR(__LINE__);
 862         int t = ReadByte();
 863
 864         // set up the "time" global for received entities to be correct for interpolation purposes
 865         float savetime = time;
 866         if(servertime)
 867         {
 868                 time = servertime;
 869         }
 870         else
 871         {
 872                 serverprevtime = time;
 873                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 874                 time = serverprevtime + serverdeltatime;
 875         }
 876
 877 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 878         if (this.enttype)
 879         {
 880                 if (t != this.enttype || isnew)
 881                 {
 882                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 883                         Ent_Remove(this);
 884                         clearentity(this);
 885                         isnew = true;
 886                 }
 887         }
 888         else
 889         {
 890                 if (!isnew)
 891                 {
 892                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 893                         isnew = true;
 894                 }
 895         }
 896 #endif
 897         this.enttype = t;
 898         bool done = false;
 899         FOREACH(LinkedEntities, it.m_id == t, {
 900                 if (isnew) this.classname = it.netname;
 901                 if (autocvar_developer_csqcentities)
 902             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 903                 done = it.m_read(this, NULL, isnew);
 904                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 905                 break;
 906         });
 907         time = savetime;
 908         if (!done)
 909         {
 910                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 911         }
 912 }
 913
 914 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 915 // used when an entity changes its type. For an entity that someone interacts
 916 // with others, make sure it can no longer do so.
 917 void Ent_Remove(entity this)
 918 {
 919         if(this.entremove) this.entremove(this);
 920
 921         if(this.skeletonindex)
 922         {
 923                 skel_delete(this.skeletonindex);
 924                 this.skeletonindex = 0;
 925         }
 926
 927         if(this.snd_looping > 0)
 928         {
 929                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 930                 this.snd_looping = 0;
 931         }
 932
 933         this.enttype = 0;
 934         this.classname = "";
 935         this.draw = func_null;
 936         this.entremove = func_null;
 937         // TODO possibly set more stuff to defaults
 938 }
 939 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 940 void CSQC_Ent_Remove(entity this)
 941 {
 942         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 943         if (wasfreed(this))
 944         {
 945                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 946                 return;
 947         }
 948         if (this.enttype) Ent_Remove(this);
 949         delete(this);
 950 }
 951
 952 void Gamemode_Init()
 953 {
 954         if (!isdemo())
 955         {
 956                 if(!(calledhooks & HOOK_START))
 957                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 958                 calledhooks |= HOOK_START;
 959         }
 960 }
 961 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 962 void CSQC_Parse_StuffCmd(string strMessage)
 963 {
 964         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 965         localcmd(strMessage);
 966 }
 967 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 968 void CSQC_Parse_Print(string strMessage)
 969 {
 970         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 971         print(ColorTranslateRGB(strMessage));
 972 }
 973
 974 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 975 void CSQC_Parse_CenterPrint(string strMessage)
 976 {
 977         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 978         centerprint_AddStandard(strMessage);
 979 }
 980
 981 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 982 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 983 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 984 bool CSQC_Parse_TempEntity()
 985 {
 986         // Acquire TE ID
 987         int nTEID = ReadByte();
 988
 989         FOREACH(TempEntities, it.m_id == nTEID, {
 990                 if (autocvar_developer_csqcentities)
 991                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 992                 return it.m_read(NULL, NULL, true);
 993         });
 994
 995         if (autocvar_developer_csqcentities)
 996                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 997
 998         // No special logic for this temporary entity; return 0 so the engine can handle it
 999         return false;
1000 }
1001
1002 string forcefog;
1003 void Fog_Force()
1004 {
1005         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1006                 localcmd("\nr_drawfog 0\n");
1007         else if (forcefog != "")
1008                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1009 }
1010
1011 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1012 {
1013         make_pure(this);
1014         gametype = ReadRegistered(Gametypes);
1015         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1016         HUD_ModIcons_SetFunc();
1017         FOREACH(Scores, true, {
1018                 strcpy(scores_label(it), ReadString());
1019                 scores_flags(it) = ReadByte();
1020         });
1021         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1022         {
1023                 strcpy(teamscores_label(i), ReadString());
1024                 teamscores_flags(i) = ReadByte();
1025         }
1026         return = true;
1027         Scoreboard_InitScores();
1028         Gamemode_Init();
1029 }
1030
1031 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1032 {
1033         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1034
1035         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1036         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1037         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1038         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1039         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1040         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1041         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1042         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1043
1044         strcpy(forcefog, ReadString());
1045
1046         armorblockpercent = ReadByte() / 255.0;
1047         damagepush_speedfactor = ReadByte() / 255.0;
1048
1049         serverflags = ReadByte();
1050
1051         g_trueaim_minrange = ReadCoord();
1052
1053         return = true;
1054
1055         MUTATOR_CALLHOOK(Ent_Init);
1056
1057         if (!postinit) PostInit();
1058 }
1059
1060 float GetSpeedUnitFactor(int speed_unit)
1061 {
1062         switch(speed_unit)
1063         {
1064                 default:
1065                 case 1: return 1.0;
1066                 case 2: return 0.0254;
1067                 case 3: return 0.0254 * 3.6;
1068                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1069                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1070         }
1071 }
1072
1073 string GetSpeedUnit(int speed_unit)
1074 {
1075         switch(speed_unit)
1076         {
1077                 // translator-friendly strings without the initial space
1078                 default:
1079                 case 1: return strcat(" ", _("qu/s"));
1080                 case 2: return strcat(" ", _("m/s"));
1081                 case 3: return strcat(" ", _("km/h"));
1082                 case 4: return strcat(" ", _("mph"));
1083                 case 5: return strcat(" ", _("knots"));
1084         }
1085 }
1086
1087 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1088 {
1089         int b = ReadByte();
1090
1091         switch (b)
1092         {
1093                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1094                         race_checkpoint = ReadByte();
1095                         race_time = ReadInt24_t();
1096                         race_previousbesttime = ReadInt24_t();
1097                         race_mypreviousbesttime = ReadInt24_t();
1098                         string pbestname = ReadString();
1099                         if(autocvar_cl_race_cptimes_onlyself)
1100                         {
1101                                 race_previousbesttime = race_mypreviousbesttime;
1102                                 race_mypreviousbesttime = 0;
1103                                 strcpy(race_previousbestname, "");
1104                         }
1105                         else
1106                                 strcpy(race_previousbestname, pbestname);
1107
1108                         race_checkpointtime = time;
1109
1110                         if(race_checkpoint == 0 || race_checkpoint == 254)
1111                         {
1112                                 race_penaltyaccumulator = 0;
1113                                 race_laptime = time; // valid
1114                         }
1115                         break;
1116
1117                 case RACE_NET_CHECKPOINT_CLEAR:
1118                         race_laptime = 0;
1119                         race_checkpointtime = 0;
1120                         break;
1121
1122                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1123                         race_laptime = ReadCoord();
1124                         race_checkpointtime = -99999;
1125                         // fall through
1126                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1127                         race_nextcheckpoint = ReadByte();
1128
1129                         race_nextbesttime = ReadInt24_t();
1130                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1131                                 race_mybesttime = ReadInt24_t();
1132                         string newname = ReadString();
1133                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1134                         {
1135                                 race_nextbesttime = race_mybesttime;
1136                                 race_mybesttime = 0;
1137                                 strcpy(race_nextbestname, "");
1138                         }
1139                         else
1140                                 strcpy(race_nextbestname, newname);
1141                         break;
1142
1143                 case RACE_NET_CHECKPOINT_HIT_RACE:
1144                         race_mycheckpoint = ReadByte();
1145                         race_mycheckpointtime = time;
1146                         race_mycheckpointdelta = ReadInt24_t();
1147                         race_mycheckpointlapsdelta = ReadByte();
1148                         if(race_mycheckpointlapsdelta >= 128)
1149                                 race_mycheckpointlapsdelta -= 256;
1150                         int who = ReadByte();
1151                         if(who)
1152                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1153                         else
1154                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1155                         break;
1156
1157                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1158                         race_othercheckpoint = ReadByte();
1159                         race_othercheckpointtime = time;
1160                         race_othercheckpointdelta = ReadInt24_t();
1161                         race_othercheckpointlapsdelta = ReadByte();
1162                         if(race_othercheckpointlapsdelta >= 128)
1163                                 race_othercheckpointlapsdelta -= 256;
1164                         int what = ReadByte();
1165                         if(what)
1166                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1167                         else
1168                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1169                         break;
1170
1171                 case RACE_NET_PENALTY_RACE:
1172                 case RACE_NET_PENALTY_QUALIFYING:
1173                         race_penaltyeventtime = time;
1174                         race_penaltytime = ReadShort();
1175                         string reason = ReadString();
1176                         if (reason == "missing a checkpoint")
1177                                 reason = _("missing a checkpoint");
1178                         strcpy(race_penaltyreason, reason);
1179                         if (b == RACE_NET_PENALTY_QUALIFYING)
1180                                 race_penaltyaccumulator += race_penaltytime;
1181                         break;
1182
1183                 case RACE_NET_SERVER_RECORD:
1184                         race_server_record = ReadInt24_t();
1185                         break;
1186                 case RACE_NET_SPEED_AWARD:
1187                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1188                         strcpy(race_speedaward_holder, ReadString());
1189                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1190                         break;
1191                 case RACE_NET_SPEED_AWARD_BEST:
1192                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1193                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1194                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1195                         break;
1196                 case RACE_NET_RANKINGS_CNT:
1197                         RANKINGS_DISPLAY_CNT = ReadByte();
1198                         break;
1199                 case RACE_NET_SERVER_RANKINGS:
1200                         float prevpos, del;
1201                         int pos = ReadShort();
1202                         prevpos = ReadShort();
1203                         del = ReadShort();
1204
1205                         // move other rankings out of the way
1206                         int i;
1207                         if (prevpos) {
1208                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1209                                 for (i=m-1; i>pos-1; --i) {
1210                                         grecordtime[i] = grecordtime[i-1];
1211                                         strcpy(grecordholder[i], grecordholder[i-1]);
1212                                 }
1213                         } else if (del) { // a record has been deleted by the admin
1214                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1215                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1216                                                 grecordtime[i] = 0;
1217                                                 strfree(grecordholder[i]);
1218                                         }
1219                                         else {
1220                                                 grecordtime[i] = grecordtime[i+1];
1221                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1222                                         }
1223                                 }
1224                         } else { // player has no ranked record yet
1225                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1226                                         grecordtime[i] = grecordtime[i-1];
1227                                         strcpy(grecordholder[i], grecordholder[i-1]);
1228                                 }
1229                         }
1230
1231                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1232                                 // kick off the player who fell from the last displayed position
1233                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1234                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1235                         }
1236
1237                         // store new ranking
1238                         strcpy(grecordholder[pos-1], ReadString());
1239                         grecordtime[pos-1] = ReadInt24_t();
1240                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1241                                 race_myrank = pos;
1242                         break;
1243                 case RACE_NET_SERVER_STATUS:
1244                         race_status = ReadShort();
1245                         strcpy(race_status_name, ReadString());
1246         }
1247         return true;
1248 }
1249
1250 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1251 {
1252         teamnagger = 1;
1253         return true;
1254 }
1255
1256 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1257 {
1258         int i = ReadByte();
1259         int pi = ReadShort();
1260         int pl = ReadByte();
1261         int ml = ReadByte();
1262         return = true;
1263         entity e = playerslots[i];
1264         if (!e) return;
1265         e.ping = pi;
1266         e.ping_packetloss = pl / 255.0;
1267         e.ping_movementloss = ml / 255.0;
1268 }
1269
1270 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1271 {
1272         int weapon_id = ReadByte();
1273         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1274         complain_weapon_type = ReadByte();
1275         return = true;
1276
1277         complain_weapon_time = time;
1278         weapontime = time; // ping the weapon panel
1279
1280         switch(complain_weapon_type)
1281         {
1282                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1283                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1284                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1285         }
1286 }
1287
1288 string _getcommandkey(string cmd_name, string command, bool forcename)
1289 {
1290         string keys;
1291         float n, j, k, l = 0;
1292
1293         if (!autocvar_hud_showbinds)
1294                 return cmd_name;
1295
1296         keys = db_get(binddb, command);
1297         if (keys == "")
1298         {
1299                 bool joy_active = cvar("joy_active");
1300                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1301                 for(j = 0; j < n; ++j)
1302                 {
1303                         k = stof(argv(j));
1304                         if(k != -1)
1305                         {
1306                                 string key = keynumtostring(k);
1307                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1308                                         continue;
1309
1310                                 key = translate_key(key);
1311
1312                                 if (keys == "")
1313                                         keys = key;
1314                                 else
1315                                         keys = strcat(keys, ", ", key);
1316
1317                                 ++l;
1318                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1319                                         break;
1320                         }
1321
1322                 }
1323                 if (keys == "")
1324                         keys = "NO_KEY";
1325                 db_put(binddb, command, keys);
1326         }
1327
1328         if (keys == "NO_KEY") {
1329                 if (autocvar_hud_showbinds > 1)
1330                         return sprintf(_("%s (not bound)"), cmd_name);
1331                 else
1332                         return cmd_name;
1333         }
1334         else if (autocvar_hud_showbinds > 1 || forcename)
1335                 return sprintf("%s (%s)", cmd_name, keys);
1336         else
1337                 return keys;
1338 }
1339
1340 /** engine callback */
1341 void URI_Get_Callback(int id, int status, string data)
1342 {
1343         TC(int, id); TC(int, status);
1344         if(url_URI_Get_Callback(id, status, data))
1345         {
1346                 // handled
1347         }
1348         else if (id == URI_GET_DISCARD)
1349         {
1350                 // discard
1351         }
1352         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1353         {
1354                 // sv_cmd curl
1355                 Curl_URI_Get_Callback(id, status, data);
1356         }
1357         else
1358         {
1359                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1360         }
1361 }