qcsrc/client/main.qc

   1 #include "mapvoting.qh"
   2 #include "modeleffects.qh"
   3 #include "particles.qh"
   4 #include "scoreboard.qh"
   5 #include "shownames.qh"
   6 #include "target_music.qh"
   7 #include "tturrets.qh"
   8 #include "tuba.qh"
   9 #include "wall.qh"
  10 #include "waypointsprites.qh"
  11
  12 #include "vehicles/vehicles.qh"
  13
  14 #include "../server/vehicles/bumblebee.qh"
  15
  16 #include "../common/net_notice.qh"
  17
  18 #include "../common/monsters/monsters.qh"
  19
  20 #include "../warpzonelib/client.qh"
  21
  22 // --------------------------------------------------------------------------
  23 // BEGIN REQUIRED CSQC FUNCTIONS
  24 //include "main.qh"
  25
  26 entity clearentity_ent;
  27 void clearentity(entity e)
  28 {
  29         if (!clearentity_ent)
  30         {
  31                 clearentity_ent = spawn();
  32                 clearentity_ent.classname = "clearentity";
  33         }
  34         int n = e.entnum;
  35         copyentity(clearentity_ent, e);
  36         e.entnum = n;
  37 }
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40 void menu_show_error()
  41 {
  42         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  43 }
  44
  45 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  46 // Useful for precaching things
  47
  48 void menu_sub_null()
  49 {
  50 }
  51
  52 string forcefog;
  53 void WaypointSprite_Load();
  54 void ConsoleCommand_macro_init();
  55 void CSQC_Init(void)
  56 {
  57         prvm_language = cvar_string("prvm_language");
  58
  59 #ifdef WATERMARK
  60         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  61 #endif
  62
  63         int i;
  64
  65         binddb = db_create();
  66         tempdb = db_create();
  67         ClientProgsDB = db_load("client.db");
  68         compressShortVector_init();
  69
  70         draw_endBoldFont();
  71         menu_visible = false;
  72         menu_show = menu_show_error;
  73         menu_action = func_null;
  74
  75         for(i = 0; i < 255; ++i)
  76                 if(getplayerkeyvalue(i, "viewentity") == "")
  77                         break;
  78         maxclients = i;
  79
  80         //registercommand("hud_configure");
  81         //registercommand("hud_save");
  82         //registercommand("menu_action");
  83
  84         ConsoleCommand_macro_init();
  85
  86         registercvar("hud_usecsqc", "1");
  87         registercvar("scoreboard_columns", "default");
  88
  89         registercvar("cl_nade_type", "3");
  90         registercvar("cl_pokenade_type", "zombie");
  91
  92         gametype = 0;
  93
  94         // hud_fields uses strunzone on the titles!
  95         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  96                 hud_title[i] = strzone("(null)");
  97
  98         Cmd_HUD_SetFields(0);
  99
 100         postinit = false;
 101
 102         calledhooks = 0;
 103
 104         teams = Sort_Spawn();
 105         players = Sort_Spawn();
 106
 107         GetTeam(NUM_SPECTATOR, true); // add specs first
 108
 109         // needs to be done so early because of the constants they create
 110         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 111         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
 112         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 113         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 114         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 115         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 116         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
 117
 118         initialize_minigames();
 119
 120         WaypointSprite_Load();
 121
 122         // precaches
 123         precache_model("null");
 124         precache_sound("misc/hit.wav");
 125         precache_sound("misc/typehit.wav");
 126
 127         Projectile_Precache();
 128         Hook_Precache();
 129         GibSplash_Precache();
 130         Casings_Precache();
 131         Vehicles_Precache();
 132         turrets_precache();
 133         Tuba_Precache();
 134         CSQCPlayer_Precache();
 135
 136         if(autocvar_cl_reticle)
 137         {
 138                 precache_pic("gfx/reticle_normal");
 139                 // weapon reticles are precached in weapon files
 140         }
 141
 142         get_mi_min_max_texcoords(1); // try the CLEVER way first
 143         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 144         shortmapname = mi_shortname;
 145
 146         if(precache_pic(minimapname) == "")
 147         {
 148                 // but maybe we have a non-clever minimap
 149                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 150                 if(precache_pic(minimapname) == "")
 151                         minimapname = ""; // FAIL
 152                 else
 153                         get_mi_min_max_texcoords(0); // load new texcoords
 154         }
 155
 156         mi_center = (mi_min + mi_max) * 0.5;
 157         mi_scale = mi_max - mi_min;
 158         minimapname = strzone(minimapname);
 159
 160         WarpZone_Init();
 161
 162         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 163         hud_configure_prev = -1;
 164
 165         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 166 }
 167
 168 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 169 void Shutdown(void)
 170 {
 171         WarpZone_Shutdown();
 172
 173         remove(teams);
 174         remove(players);
 175         db_close(binddb);
 176         db_close(tempdb);
 177         if(autocvar_cl_db_saveasdump)
 178                 db_dump(ClientProgsDB, "client.db");
 179         else
 180                 db_save(ClientProgsDB, "client.db");
 181         db_close(ClientProgsDB);
 182
 183         if(camera_active)
 184                 cvar_set("chase_active",ftos(chase_active_backup));
 185
 186         // unset the event chasecam's chase_active
 187         if(autocvar_chase_active < 0)
 188                 cvar_set("chase_active", "0");
 189
 190         if (!isdemo())
 191         {
 192                 if (!(calledhooks & HOOK_START))
 193                         localcmd("\n_cl_hook_gamestart nop\n");
 194                 if (!(calledhooks & HOOK_END))
 195                         localcmd("\ncl_hook_gameend\n");
 196         }
 197
 198         deactivate_minigame();
 199         HUD_MinigameMenu_Close();
 200 }
 201
 202 .float has_team;
 203 float SetTeam(entity o, int Team)
 204 {
 205         entity tm;
 206         if(teamplay)
 207         {
 208                 switch(Team)
 209                 {
 210                         case -1:
 211                         case NUM_TEAM_1:
 212                         case NUM_TEAM_2:
 213                         case NUM_TEAM_3:
 214                         case NUM_TEAM_4:
 215                                 break;
 216                         default:
 217                                 if(GetTeam(Team, false) == world)
 218                                 {
 219                                         dprintf("trying to switch to unsupported team %d\n", Team);
 220                                         Team = NUM_SPECTATOR;
 221                                 }
 222                                 break;
 223                 }
 224         }
 225         else
 226         {
 227                 switch(Team)
 228                 {
 229                         case -1:
 230                         case 0:
 231                                 break;
 232                         default:
 233                                 if(GetTeam(Team, false) == world)
 234                                 {
 235                                         dprintf("trying to switch to unsupported team %d\n", Team);
 236                                         Team = NUM_SPECTATOR;
 237                                 }
 238                                 break;
 239                 }
 240         }
 241         if(Team == -1) // leave
 242         {
 243                 if(o.has_team)
 244                 {
 245                         tm = GetTeam(o.team, false);
 246                         tm.team_size -= 1;
 247                         o.has_team = 0;
 248                         return true;
 249                 }
 250         }
 251         else
 252         {
 253                 if (!o.has_team)
 254                 {
 255                         o.team = Team;
 256                         tm = GetTeam(Team, true);
 257                         tm.team_size += 1;
 258                         o.has_team = 1;
 259                         return true;
 260                 }
 261                 else if(Team != o.team)
 262                 {
 263                         tm = GetTeam(o.team, false);
 264                         tm.team_size -= 1;
 265                         o.team = Team;
 266                         tm = GetTeam(Team, true);
 267                         tm.team_size += 1;
 268                         return true;
 269                 }
 270         }
 271         return false;
 272 }
 273
 274 void Playerchecker_Think()
 275 {
 276     int i;
 277         entity e;
 278         for(i = 0; i < maxclients; ++i)
 279         {
 280                 e = playerslots[i];
 281                 if(GetPlayerName(i) == "")
 282                 {
 283                         if(e.sort_prev)
 284                         {
 285                                 // player disconnected
 286                                 SetTeam(e, -1);
 287                                 RemovePlayer(e);
 288                                 e.sort_prev = world;
 289                                 //e.gotscores = 0;
 290                         }
 291                 }
 292                 else
 293                 {
 294                         if (!e.sort_prev)
 295                         {
 296                                 // player connected
 297                                 if (!e)
 298                                         playerslots[i] = e = spawn();
 299                                 e.sv_entnum = i;
 300                                 e.ping = 0;
 301                                 e.ping_packetloss = 0;
 302                                 e.ping_movementloss = 0;
 303                                 //e.gotscores = 0; // we might already have the scores...
 304                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 305                                 RegisterPlayer(e);
 306                                 HUD_UpdatePlayerPos(e);
 307                         }
 308                 }
 309         }
 310         self.nextthink = time + 0.2;
 311 }
 312
 313 void Porto_Init();
 314 void TrueAim_Init();
 315 void PostInit(void)
 316 {
 317         entity playerchecker;
 318         playerchecker = spawn();
 319         playerchecker.think = Playerchecker_Think;
 320         playerchecker.nextthink = time + 0.2;
 321
 322         Porto_Init();
 323         TrueAim_Init();
 324
 325         postinit = true;
 326 }
 327
 328 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 329 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 330 // All keys are in ascii.
 331 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 332 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 333 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 334 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 335 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 336 {
 337         float bSkipKey;
 338         bSkipKey = false;
 339
 340         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 341                 return true;
 342
 343         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 344                 return true;
 345
 346         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 347                 return true;
 348
 349         if(menu_visible && menu_action)
 350                 if(menu_action(bInputType, nPrimary, nSecondary))
 351                         return true;
 352
 353         return bSkipKey;
 354 }
 355
 356 // END REQUIRED CSQC FUNCTIONS
 357 // --------------------------------------------------------------------------
 358
 359 // --------------------------------------------------------------------------
 360 // BEGIN OPTIONAL CSQC FUNCTIONS
 361 void Ent_RemoveEntCS()
 362 {
 363         entcs_receiver[self.sv_entnum] = world;
 364 }
 365 void Ent_ReadEntCS()
 366 {
 367     int sf;
 368         InterpolateOrigin_Undo();
 369
 370         self.classname = "entcs_receiver";
 371         sf = ReadByte();
 372
 373         if(sf & 1)
 374                 self.sv_entnum = ReadByte();
 375         if(sf & 2)
 376         {
 377                 self.origin_x = ReadShort();
 378                 self.origin_y = ReadShort();
 379                 self.origin_z = ReadShort();
 380                 setorigin(self, self.origin);
 381         }
 382         if(sf & 4)
 383         {
 384                 self.angles_y = ReadByte() * 360.0 / 256;
 385                 self.angles_x = self.angles_z = 0;
 386         }
 387         if(sf & 8)
 388                 self.healthvalue = ReadByte() * 10;
 389         if(sf & 16)
 390                 self.armorvalue = ReadByte() * 10;
 391
 392         entcs_receiver[self.sv_entnum] = self;
 393         self.entremove = Ent_RemoveEntCS;
 394         self.iflags |= IFLAG_ORIGIN;
 395
 396         InterpolateOrigin_Note();
 397 }
 398
 399 void Ent_Remove();
 400
 401 void Ent_RemovePlayerScore()
 402 {
 403         if(self.owner) {
 404                 SetTeam(self.owner, -1);
 405                 self.owner.gotscores = 0;
 406                 for(int i = 0; i < MAX_SCORE; ++i) {
 407                         self.owner.(scores[i]) = 0; // clear all scores
 408                 }
 409         }
 410 }
 411
 412 void Ent_ReadPlayerScore()
 413 {
 414         int i, n;
 415         bool isNew;
 416         entity o;
 417
 418         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 419         // (no I've never heard of M-x replace-string, sed, or anything like that)
 420         isNew = !self.owner; // workaround for DP bug
 421         n = ReadByte()-1;
 422
 423 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 424         if(!isNew && n != self.sv_entnum)
 425         {
 426                 //print("A CSQC entity changed its owner!\n");
 427                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 428                 isNew = true;
 429                 Ent_Remove();
 430                 self.enttype = ENT_CLIENT_SCORES;
 431         }
 432 #endif
 433
 434         self.sv_entnum = n;
 435
 436         if (!(playerslots[self.sv_entnum]))
 437                 playerslots[self.sv_entnum] = spawn();
 438         o = self.owner = playerslots[self.sv_entnum];
 439         o.sv_entnum = self.sv_entnum;
 440         o.gotscores = 1;
 441
 442         //if (!o.sort_prev)
 443         //      RegisterPlayer(o);
 444         //playerchecker will do this for us later, if it has not already done so
 445
 446     int sf, lf;
 447 #if MAX_SCORE <= 8
 448         sf = ReadByte();
 449         lf = ReadByte();
 450 #else
 451         sf = ReadShort();
 452         lf = ReadShort();
 453 #endif
 454     int p;
 455         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 456                 if(sf & p)
 457                 {
 458                         if(lf & p)
 459                                 o.(scores[i]) = ReadInt24_t();
 460                         else
 461                                 o.(scores[i]) = ReadChar();
 462                 }
 463
 464         if(o.sort_prev)
 465                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 466
 467         self.entremove = Ent_RemovePlayerScore;
 468 }
 469
 470 void Ent_ReadTeamScore()
 471 {
 472         int i;
 473         entity o;
 474
 475         self.team = ReadByte();
 476         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 477
 478     int sf, lf;
 479 #if MAX_TEAMSCORE <= 8
 480         sf = ReadByte();
 481         lf = ReadByte();
 482 #else
 483         sf = ReadShort();
 484         lf = ReadShort();
 485 #endif
 486         int p;
 487         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 488                 if(sf & p)
 489                 {
 490                         if(lf & p)
 491                                 o.(teamscores[i]) = ReadInt24_t();
 492                         else
 493                                 o.(teamscores[i]) = ReadChar();
 494                 }
 495
 496         HUD_UpdateTeamPos(o);
 497 }
 498
 499 void Ent_ClientData()
 500 {
 501         float newspectatee_status;
 502
 503     int f = ReadByte();
 504
 505         scoreboard_showscores_force = (f & 1);
 506
 507         if(f & 2)
 508         {
 509                 newspectatee_status = ReadByte();
 510                 if(newspectatee_status == player_localnum + 1)
 511                         newspectatee_status = -1; // observing
 512         }
 513         else
 514                 newspectatee_status = 0;
 515
 516         spectatorbutton_zoom = (f & 4);
 517
 518         if(f & 8)
 519         {
 520                 angles_held_status = 1;
 521                 angles_held.x = ReadAngle();
 522                 angles_held.y = ReadAngle();
 523                 angles_held.z = 0;
 524         }
 525         else
 526                 angles_held_status = 0;
 527
 528         if(newspectatee_status != spectatee_status)
 529         {
 530                 // clear race stuff
 531                 race_laptime = 0;
 532                 race_checkpointtime = 0;
 533         }
 534         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 535         {
 536                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 537                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 538                 )
 539                         prev_p_health = -1;
 540                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 541                         prev_health = -1;
 542         }
 543         spectatee_status = newspectatee_status;
 544
 545         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 546 }
 547
 548 void Ent_Nagger()
 549 {
 550     int i, j, b, f;
 551
 552     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 553
 554         if(!(nags & 4))
 555         {
 556                 if(vote_called_vote)
 557                         strunzone(vote_called_vote);
 558                 vote_called_vote = string_null;
 559                 vote_active = 0;
 560         }
 561         else
 562         {
 563                 vote_active = 1;
 564         }
 565
 566         if(nags & 64)
 567         {
 568                 vote_yescount = ReadByte();
 569                 vote_nocount = ReadByte();
 570                 vote_needed = ReadByte();
 571                 vote_highlighted = ReadChar();
 572         }
 573
 574         if(nags & 128)
 575         {
 576                 if(vote_called_vote)
 577                         strunzone(vote_called_vote);
 578                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 579         }
 580
 581         if(nags & 1)
 582         {
 583                 for(j = 0; j < maxclients; ++j)
 584                         if(playerslots[j])
 585                                 playerslots[j].ready = 1;
 586                 for(i = 1; i <= maxclients; i += 8)
 587                 {
 588                         f = ReadByte();
 589                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 590                                 if (!(f & b))
 591                                         if(playerslots[j])
 592                                                 playerslots[j].ready = 0;
 593                 }
 594         }
 595
 596         ready_waiting = (nags & 1);
 597         ready_waiting_for_me = (nags & 2);
 598         vote_waiting = (nags & 4);
 599         vote_waiting_for_me = (nags & 8);
 600         warmup_stage = (nags & 16);
 601 }
 602
 603 void Ent_EliminatedPlayers()
 604 {
 605     int i, j, b, f;
 606
 607     int sf = ReadByte();
 608         if(sf & 1)
 609         {
 610                 for(j = 0; j < maxclients; ++j)
 611                         if(playerslots[j])
 612                                 playerslots[j].eliminated = 1;
 613                 for(i = 1; i <= maxclients; i += 8)
 614                 {
 615                         f = ReadByte();
 616                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 617                                 if (!(f & b))
 618                                         if(playerslots[j])
 619                                                 playerslots[j].eliminated = 0;
 620                 }
 621         }
 622 }
 623
 624 void Ent_RandomSeed()
 625 {
 626         float s;
 627         prandom_debug();
 628         s = ReadShort();
 629         psrandom(s);
 630 }
 631
 632 void Ent_ReadAccuracy(void)
 633 {
 634     int f, w;
 635     int sf = ReadInt24_t();
 636         if(sf == 0)
 637         {
 638                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 639                         weapon_accuracy[w] = -1;
 640                 return;
 641         }
 642
 643         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 644         {
 645                 if(sf & f)
 646                 {
 647             int b = ReadByte();
 648                         if(b == 0)
 649                                 weapon_accuracy[w] = -1;
 650                         else if(b == 255)
 651                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 652                         else
 653                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 654                 }
 655                 if(f == 0x800000)
 656                         f = 1;
 657                 else
 658                         f *= 2;
 659         }
 660 }
 661
 662 void Spawn_Draw(void)
 663 {
 664         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 665 }
 666
 667 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 668 {
 669         float teamnum = (ReadByte() - 1);
 670         vector spn_origin;
 671         spn_origin.x = ReadShort();
 672         spn_origin.y = ReadShort();
 673         spn_origin.z = ReadShort();
 674
 675         if(is_new)
 676         {
 677                 self.origin = spn_origin;
 678                 setsize(self, PL_MIN, PL_MAX);
 679                 droptofloor();
 680
 681                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 682                 {
 683                         self.mdl = "models/spawnpoint.md3";
 684                         self.colormod = Team_ColorRGB(teamnum);
 685                         precache_model(self.mdl);
 686                         setmodel(self, self.mdl);
 687                         self.drawmask = MASK_NORMAL;
 688                         //self.movetype = MOVETYPE_NOCLIP;
 689                         //self.draw = Spawn_Draw;
 690                 }*/
 691                 if(autocvar_cl_spawn_point_particles)
 692                 {
 693                         if((serverflags & SERVERFLAG_TEAMPLAY))
 694                         {
 695                                 switch(teamnum)
 696                                 {
 697                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 698                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 699                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 700                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 701                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 702                                 }
 703                         }
 704                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 705
 706                         self.draw = Spawn_Draw;
 707                 }
 708         }
 709
 710         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 711 }
 712
 713 void Ent_ReadSpawnEvent(float is_new)
 714 {
 715         // If entnum is 0, ONLY do the local spawn actions
 716         // this way the server can disable the sending of
 717         // spawn origin or such to clients if wanted.
 718         float entnum = ReadByte();
 719
 720         if(entnum)
 721         {
 722                 self.origin_x = ReadShort();
 723                 self.origin_y = ReadShort();
 724                 self.origin_z = ReadShort();
 725
 726                 if(is_new)
 727                 {
 728                         float teamnum = GetPlayerColor(entnum - 1);
 729
 730                         if(autocvar_cl_spawn_event_particles)
 731                         {
 732                                 switch(teamnum)
 733                                 {
 734                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 735                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 736                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 737                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 738                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 739                                 }
 740                         }
 741                         if(autocvar_cl_spawn_event_sound)
 742                         {
 743                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 744                         }
 745                 }
 746         }
 747
 748         // local spawn actions
 749         if(is_new && (!entnum || (entnum == player_localentnum)))
 750         {
 751                 zoomin_effect = 1;
 752                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 753
 754                 if(autocvar_cl_unpress_zoom_on_spawn)
 755                 {
 756                         localcmd("-zoom\n");
 757                         button_zoom = false;
 758                 }
 759         }
 760
 761         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 762 }
 763
 764 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 765 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 766 void Ent_RadarLink();
 767 void Ent_Init();
 768 void Ent_ScoresInfo();
 769 void CSQC_Ent_Update(float bIsNewEntity)
 770 {
 771         float t;
 772         float savetime;
 773         t = ReadByte();
 774
 775         if(autocvar_developer_csqcentities)
 776                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 777
 778         // set up the "time" global for received entities to be correct for interpolation purposes
 779         savetime = time;
 780         if(servertime)
 781         {
 782                 time = servertime;
 783         }
 784         else
 785         {
 786                 serverprevtime = time;
 787                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 788                 time = serverprevtime + serverdeltatime;
 789         }
 790
 791 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 792         if(self.enttype)
 793         {
 794                 if(t != self.enttype || bIsNewEntity)
 795                 {
 796                         //print("A CSQC entity changed its type!\n");
 797                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 798                         Ent_Remove();
 799                         clearentity(self);
 800                         bIsNewEntity = 1;
 801                 }
 802         }
 803         else
 804         {
 805                 if(!bIsNewEntity)
 806                 {
 807                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 808                         bIsNewEntity = 1;
 809                 }
 810         }
 811 #endif
 812         self.enttype = t;
 813         switch(t)
 814         {
 815                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 816                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 817                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 818                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 819                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 820                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 821                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 822                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 823                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 824                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 825                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 826                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 827                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 828                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 829                 case ENT_CLIENT_INIT: Ent_Init(); break;
 830                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 831                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 832                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 833                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 834                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 835                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 836                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 837                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 838                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 839                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 840                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 841                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 842                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 843                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 844                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 845                 case ENT_CLIENT_TURRET: ent_turret(); break;
 846                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 847                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 848                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 849                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 850                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 851                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 852                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 853                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 854
 855                 default:
 856                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 857                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 858                         break;
 859         }
 860
 861         time = savetime;
 862 }
 863 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 864 // used when an entity changes its type. For an entity that someone interacts
 865 // with others, make sure it can no longer do so.
 866 void Ent_Remove()
 867 {
 868         if(self.entremove)
 869                 self.entremove();
 870
 871         if(self.skeletonindex)
 872         {
 873                 skel_delete(self.skeletonindex);
 874                 self.skeletonindex = 0;
 875         }
 876
 877         if(self.snd_looping > 0)
 878         {
 879                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 880                 self.snd_looping = 0;
 881         }
 882
 883         self.enttype = 0;
 884         self.classname = "";
 885         self.draw = menu_sub_null;
 886         self.entremove = menu_sub_null;
 887         // TODO possibly set more stuff to defaults
 888 }
 889 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 890 void CSQC_Ent_Remove()
 891 {
 892         if(autocvar_developer_csqcentities)
 893                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 894
 895         if(wasfreed(self))
 896         {
 897                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 898                 return;
 899         }
 900         if(self.enttype)
 901                 Ent_Remove();
 902         remove(self);
 903 }
 904
 905 void Gamemode_Init()
 906 {
 907         if (!isdemo())
 908         {
 909                 if(!(calledhooks & HOOK_START))
 910                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 911                 calledhooks |= HOOK_START;
 912         }
 913 }
 914 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 915 void CSQC_Parse_StuffCmd(string strMessage)
 916 {
 917         if(autocvar_developer_csqcentities)
 918                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 919
 920         localcmd(strMessage);
 921 }
 922 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 923 void CSQC_Parse_Print(string strMessage)
 924 {
 925         if(autocvar_developer_csqcentities)
 926                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 927
 928         print(ColorTranslateRGB(strMessage));
 929 }
 930
 931 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 932 void CSQC_Parse_CenterPrint(string strMessage)
 933 {
 934         if(autocvar_developer_csqcentities)
 935                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 936
 937         centerprint_hud(strMessage);
 938 }
 939
 940 string notranslate_fogcmd1 = "\nfog ";
 941 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 942 void Fog_Force()
 943 {
 944         // TODO somehow thwart prvm_globalset client ...
 945
 946         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 947                 { localcmd("\nr_drawfog 0\n"); }
 948         else if(forcefog != "")
 949                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 950 }
 951
 952 void Gamemode_Init();
 953 void Ent_ScoresInfo()
 954 {
 955     int i;
 956         self.classname = "ent_client_scores_info";
 957         gametype = ReadInt24_t();
 958         HUD_ModIcons_SetFunc();
 959         for(i = 0; i < MAX_SCORE; ++i)
 960         {
 961                 if(scores_label[i])
 962                         strunzone(scores_label[i]);
 963                 scores_label[i] = strzone(ReadString());
 964                 scores_flags[i] = ReadByte();
 965         }
 966         for(i = 0; i < MAX_TEAMSCORE; ++i)
 967         {
 968                 if(teamscores_label[i])
 969                         strunzone(teamscores_label[i]);
 970                 teamscores_label[i] = strzone(ReadString());
 971                 teamscores_flags[i] = ReadByte();
 972         }
 973         HUD_InitScores();
 974         Gamemode_Init();
 975 }
 976
 977 void Ent_Init()
 978 {
 979         self.classname = "ent_client_init";
 980
 981         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 982
 983         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 984         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 985         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 986         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 987         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 988         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 989         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 990         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 991
 992         if(forcefog)
 993                 strunzone(forcefog);
 994         forcefog = strzone(ReadString());
 995
 996         armorblockpercent = ReadByte() / 255.0;
 997
 998         g_balance_mortar_bouncefactor = ReadCoord();
 999         g_balance_mortar_bouncestop = ReadCoord();
1000         g_balance_electro_secondary_bouncefactor = ReadCoord();
1001         g_balance_electro_secondary_bouncestop = ReadCoord();
1002
1003         vortex_scope = !ReadByte();
1004         rifle_scope = !ReadByte();
1005
1006         serverflags = ReadByte();
1007
1008         minelayer_maxmines = ReadByte();
1009
1010         hagar_maxrockets = ReadByte();
1011
1012         g_trueaim_minrange = ReadCoord();
1013         g_balance_porto_secondary = ReadByte();
1014
1015         if(!postinit)
1016                 PostInit();
1017 }
1018
1019 void Net_ReadRace()
1020 {
1021         float b;
1022
1023         b = ReadByte();
1024
1025         switch(b)
1026         {
1027                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1028                         race_checkpoint = ReadByte();
1029                         race_time = ReadInt24_t();
1030                         race_previousbesttime = ReadInt24_t();
1031                         if(race_previousbestname)
1032                                 strunzone(race_previousbestname);
1033                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1034
1035                         race_checkpointtime = time;
1036
1037                         if(race_checkpoint == 0 || race_checkpoint == 254)
1038                         {
1039                                 race_penaltyaccumulator = 0;
1040                                 race_laptime = time; // valid
1041                         }
1042
1043                         break;
1044
1045                 case RACE_NET_CHECKPOINT_CLEAR:
1046                         race_laptime = 0;
1047                         race_checkpointtime = 0;
1048                         break;
1049
1050                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1051                         race_laptime = ReadCoord();
1052                         race_checkpointtime = -99999;
1053                         // fall through
1054                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1055                         race_nextcheckpoint = ReadByte();
1056
1057                         race_nextbesttime = ReadInt24_t();
1058                         if(race_nextbestname)
1059                                 strunzone(race_nextbestname);
1060                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1061                         break;
1062
1063                 case RACE_NET_CHECKPOINT_HIT_RACE:
1064                         race_mycheckpoint = ReadByte();
1065                         race_mycheckpointtime = time;
1066                         race_mycheckpointdelta = ReadInt24_t();
1067                         race_mycheckpointlapsdelta = ReadByte();
1068                         if(race_mycheckpointlapsdelta >= 128)
1069                                 race_mycheckpointlapsdelta -= 256;
1070                         if(race_mycheckpointenemy)
1071                                 strunzone(race_mycheckpointenemy);
1072                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1073                         break;
1074
1075                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1076                         race_othercheckpoint = ReadByte();
1077                         race_othercheckpointtime = time;
1078                         race_othercheckpointdelta = ReadInt24_t();
1079                         race_othercheckpointlapsdelta = ReadByte();
1080                         if(race_othercheckpointlapsdelta >= 128)
1081                                 race_othercheckpointlapsdelta -= 256;
1082                         if(race_othercheckpointenemy)
1083                                 strunzone(race_othercheckpointenemy);
1084                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1085                         break;
1086
1087                 case RACE_NET_PENALTY_RACE:
1088                         race_penaltyeventtime = time;
1089                         race_penaltytime = ReadShort();
1090                         //race_penaltyaccumulator += race_penaltytime;
1091                         if(race_penaltyreason)
1092                                 strunzone(race_penaltyreason);
1093                         race_penaltyreason = strzone(ReadString());
1094                         break;
1095
1096                 case RACE_NET_PENALTY_QUALIFYING:
1097                         race_penaltyeventtime = time;
1098                         race_penaltytime = ReadShort();
1099                         race_penaltyaccumulator += race_penaltytime;
1100                         if(race_penaltyreason)
1101                                 strunzone(race_penaltyreason);
1102                         race_penaltyreason = strzone(ReadString());
1103                         break;
1104
1105                 case RACE_NET_SERVER_RECORD:
1106                         race_server_record = ReadInt24_t();
1107                         break;
1108                 case RACE_NET_SPEED_AWARD:
1109                         race_speedaward = ReadInt24_t();
1110                         if(race_speedaward_holder)
1111                                 strunzone(race_speedaward_holder);
1112                         race_speedaward_holder = strzone(ReadString());
1113                         break;
1114                 case RACE_NET_SPEED_AWARD_BEST:
1115                         race_speedaward_alltimebest = ReadInt24_t();
1116                         if(race_speedaward_alltimebest_holder)
1117                                 strunzone(race_speedaward_alltimebest_holder);
1118                         race_speedaward_alltimebest_holder = strzone(ReadString());
1119                         break;
1120                 case RACE_NET_SERVER_RANKINGS:
1121                         float prevpos, del;
1122             int pos = ReadShort();
1123                         prevpos = ReadShort();
1124                         del = ReadShort();
1125
1126                         // move other rankings out of the way
1127             int i;
1128                         if (prevpos) {
1129                                 for (i=prevpos-1;i>pos-1;--i) {
1130                                         grecordtime[i] = grecordtime[i-1];
1131                                         if(grecordholder[i])
1132                                                 strunzone(grecordholder[i]);
1133                                         grecordholder[i] = strzone(grecordholder[i-1]);
1134                                 }
1135                         } else if (del) { // a record has been deleted by the admin
1136                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1137                                         if (i == RANKINGS_CNT-1) { // clear out last record
1138                                                 grecordtime[i] = 0;
1139                                                 if (grecordholder[i])
1140                                                         strunzone(grecordholder[i]);
1141                                                 grecordholder[i] = string_null;
1142                                         }
1143                                         else {
1144                                                 grecordtime[i] = grecordtime[i+1];
1145                                                 if (grecordholder[i])
1146                                                         strunzone(grecordholder[i]);
1147                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1148                                         }
1149                                 }
1150                         } else { // player has no ranked record yet
1151                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1152                                         grecordtime[i] = grecordtime[i-1];
1153                                         if(grecordholder[i])
1154                                                 strunzone(grecordholder[i]);
1155                                         grecordholder[i] = strzone(grecordholder[i-1]);
1156                                 }
1157                         }
1158
1159                         // store new ranking
1160                         if(grecordholder[pos-1] != "")
1161                                 strunzone(grecordholder[pos-1]);
1162                         grecordholder[pos-1] = strzone(ReadString());
1163                         grecordtime[pos-1] = ReadInt24_t();
1164                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1165                                 race_myrank = pos;
1166                         break;
1167                 case RACE_NET_SERVER_STATUS:
1168                         race_status = ReadShort();
1169                         if(race_status_name)
1170                                 strunzone(race_status_name);
1171                         race_status_name = strzone(ReadString());
1172         }
1173 }
1174
1175 void Net_TeamNagger()
1176 {
1177         teamnagger = 1;
1178 }
1179
1180 void Net_ReadPingPLReport()
1181 {
1182         int e, pi, pl, ml;
1183         e = ReadByte();
1184         pi = ReadShort();
1185         pl = ReadByte();
1186         ml = ReadByte();
1187         if (!(playerslots[e]))
1188                 return;
1189         playerslots[e].ping = pi;
1190         playerslots[e].ping_packetloss = pl / 255.0;
1191         playerslots[e].ping_movementloss = ml / 255.0;
1192 }
1193
1194 void Net_WeaponComplain()
1195 {
1196         complain_weapon = ReadByte();
1197
1198         if(complain_weapon_name)
1199                 strunzone(complain_weapon_name);
1200         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1201
1202         complain_weapon_type = ReadByte();
1203
1204         complain_weapon_time = time;
1205         weapontime = time; // ping the weapon panel
1206
1207         switch(complain_weapon_type)
1208         {
1209                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1210                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1211                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1212         }
1213 }
1214
1215 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1216 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1217 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1218 float CSQC_Parse_TempEntity()
1219 {
1220         float bHandled;
1221                 bHandled  = true;
1222         // Acquire TE ID
1223         float nTEID;
1224                 nTEID = ReadByte();
1225
1226         if(autocvar_developer_csqcentities)
1227                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1228
1229                 // NOTE: Could just do return instead of break...
1230         switch(nTEID)
1231         {
1232                 case TE_CSQC_TARGET_MUSIC:
1233                         Net_TargetMusic();
1234                         bHandled = true;
1235                         break;
1236                 case TE_CSQC_PICTURE:
1237                         Net_MapVote_Picture();
1238                         bHandled = true;
1239                         break;
1240                 case TE_CSQC_RACE:
1241                         Net_ReadRace();
1242                         bHandled = true;
1243                         break;
1244                 case TE_CSQC_VORTEXBEAMPARTICLE:
1245                         Net_ReadVortexBeamParticle();
1246                         bHandled = true;
1247                         break;
1248                 case TE_CSQC_TEAMNAGGER:
1249                         Net_TeamNagger();
1250                         bHandled = true;
1251                         break;
1252                 case TE_CSQC_ARC:
1253                         Net_ReadArc();
1254                         bHandled = true;
1255                         break;
1256                 case TE_CSQC_PINGPLREPORT:
1257                         Net_ReadPingPLReport();
1258                         bHandled = true;
1259                         break;
1260                 case TE_CSQC_WEAPONCOMPLAIN:
1261                         Net_WeaponComplain();
1262                         bHandled = true;
1263                         break;
1264                 case TE_CSQC_VEHICLESETUP:
1265                         Net_VehicleSetup();
1266                         bHandled = true;
1267                         break;
1268                 case TE_CSQC_SVNOTICE:
1269                         cl_notice_read();
1270                         bHandled = true;
1271                         break;
1272                 case TE_CSQC_SHOCKWAVEPARTICLE:
1273                         Net_ReadShockwaveParticle();
1274                         bHandled = true;
1275                         break;
1276                 default:
1277                         // No special logic for this temporary entity; return 0 so the engine can handle it
1278                         bHandled = false;
1279                         break;
1280         }
1281
1282         return bHandled;
1283 }
1284
1285 string getcommandkey(string text, string command)
1286 {
1287         string keys;
1288         float n, j, k, l = 0;
1289
1290         if (!autocvar_hud_showbinds)
1291                 return text;
1292
1293         keys = db_get(binddb, command);
1294         if (keys == "")
1295         {
1296                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1297                 for(j = 0; j < n; ++j)
1298                 {
1299                         k = stof(argv(j));
1300                         if(k != -1)
1301                         {
1302                                 if ("" == keys)
1303                                         keys = keynumtostring(k);
1304                                 else
1305                                         keys = strcat(keys, ", ", keynumtostring(k));
1306
1307                                 ++l;
1308                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1309                                         break;
1310                         }
1311
1312                 }
1313                 if (keys == "")
1314                         keys = "NO_KEY";
1315                 db_put(binddb, command, keys);
1316         }
1317
1318         if (keys == "NO_KEY") {
1319                 if (autocvar_hud_showbinds > 1)
1320                         return sprintf(_("%s (not bound)"), text);
1321                 else
1322                         return text;
1323         }
1324         else if (autocvar_hud_showbinds > 1)
1325                 return sprintf("%s (%s)", text, keys);
1326         else
1327                 return keys;
1328 }