qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         // z411
 101         registercvar("cl_chat_sounds", "1");
 102
 103         if(autocvar_cl_lockview)
 104                 cvar_set("cl_lockview", "0");
 105
 106         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
 107                 cvar_settemp("_scoreboard_team_selection_available", "1");
 108         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
 109
 110         gametype = NULL;
 111
 112         postinit = false;
 113
 114         calledhooks = 0;
 115
 116         teams = Sort_Spawn();
 117         players = Sort_Spawn();
 118
 119         GetTeam(NUM_SPECTATOR, true); // add specs first
 120
 121         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 122                 weapon_accuracy[w] = -1;
 123
 124         // precaches
 125
 126         if(autocvar_cl_reticle)
 127         {
 128                 precache_pic("gfx/reticle_normal");
 129                 // weapon reticles are precached in weapon files
 130         }
 131
 132         {
 133                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 134                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 135
 136                 if (precache_pic(minimapname) == "")
 137                 {
 138                         // but maybe we have a non-clever minimap
 139                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 140                         if (precache_pic(minimapname) == "")
 141                                 minimapname = ""; // FAIL
 142                         else
 143                                 get_mi_min_max_texcoords(0); // load new texcoords
 144                 }
 145
 146                 mi_center = (mi_min + mi_max) * 0.5;
 147                 mi_scale = mi_max - mi_min;
 148                 minimapname = strzone(minimapname);
 149         }
 150
 151         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 152         LoadMenuSkinValues();
 153 }
 154
 155 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 156 void Shutdown()
 157 {
 158         WarpZone_Shutdown();
 159
 160         delete(teams);
 161         delete(players);
 162         db_close(binddb);
 163         db_close(tempdb);
 164         if(autocvar_cl_db_saveasdump)
 165                 db_dump(ClientProgsDB, "client.db");
 166         else
 167                 db_save(ClientProgsDB, "client.db");
 168         db_close(ClientProgsDB);
 169
 170         if(camera_active)
 171                 cvar_set("chase_active",ftos(chase_active_backup));
 172
 173         // unset the event chasecam's chase_active
 174         if(autocvar_chase_active < 0)
 175                 cvar_set("chase_active", "0");
 176
 177         if (autocvar_r_drawviewmodel < 0)
 178                 cvar_set("r_drawviewmodel", "0");
 179
 180         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 181
 182         if (!isdemo())
 183         {
 184                 if (!(calledhooks & HOOK_START))
 185                         localcmd("\n_cl_hook_gamestart nop\n");
 186                 if (!(calledhooks & HOOK_END))
 187                 {
 188                         int gamecount = cvar("cl_matchcount");
 189                         localcmd("\ncl_hook_gameend\n");
 190                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 191                         // earlier versions of the game abuse the hook to set this cvar
 192                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 193                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 194                 }
 195         }
 196
 197         localcmd("\ncl_hook_shutdown\n");
 198
 199         localcmd("\n-button12\n");
 200
 201         deactivate_minigame();
 202         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 203
 204         ReplicateVars(REPLICATEVARS_DESTROY);
 205 }
 206
 207 void AuditLists()
 208 {
 209         entity e;
 210         entity prev;
 211
 212         prev = players;
 213         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 214         {
 215                 if(prev != e.sort_prev)
 216                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 217         }
 218
 219         prev = teams;
 220         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 221         {
 222                 if(prev != e.sort_prev)
 223                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 224         }
 225 }
 226
 227 float RegisterPlayer(entity player)
 228 {
 229         entity pl;
 230         AuditLists();
 231         for(pl = players.sort_next; pl; pl = pl.sort_next)
 232                 if(pl == player)
 233                         error("Player already registered!");
 234         player.sort_next = players.sort_next;
 235         player.sort_prev = players;
 236         if(players.sort_next)
 237                 players.sort_next.sort_prev = player;
 238         players.sort_next = player;
 239         AuditLists();
 240         return true;
 241 }
 242
 243 void RemovePlayer(entity player)
 244 {
 245         entity pl, parent;
 246         AuditLists();
 247         parent = players;
 248         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 249                 parent = pl;
 250
 251         if(!pl)
 252         {
 253                 error("Trying to remove a player which is not in the playerlist!");
 254                 return;
 255         }
 256         parent.sort_next = player.sort_next;
 257         if(player.sort_next)
 258                 player.sort_next.sort_prev = parent;
 259         AuditLists();
 260 }
 261
 262 void MoveToLast(entity e)
 263 {
 264         AuditLists();
 265         entity ent = e.sort_next;
 266         while(ent)
 267         {
 268                 SORT_SWAP(ent, e);
 269                 ent = e.sort_next;
 270         }
 271         AuditLists();
 272 }
 273
 274 float RegisterTeam(entity Team)
 275 {
 276         assert_once(Team.team, eprint(Team));
 277         entity tm;
 278         AuditLists();
 279         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 280                 if(tm == Team)
 281                         error("Team already registered!");
 282         Team.sort_next = teams.sort_next;
 283         Team.sort_prev = teams;
 284         if(teams.sort_next)
 285                 teams.sort_next.sort_prev = Team;
 286         teams.sort_next = Team;
 287         if(Team.team && Team.team != NUM_SPECTATOR)
 288                 ++team_count;
 289         AuditLists();
 290         return true;
 291 }
 292
 293 void RemoveTeam(entity Team)
 294 {
 295         entity tm, parent;
 296         AuditLists();
 297         parent = teams;
 298         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 299                 parent = tm;
 300
 301         if(!tm)
 302         {
 303                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 304                 return;
 305         }
 306         parent.sort_next = Team.sort_next;
 307         if(Team.sort_next)
 308                 Team.sort_next.sort_prev = parent;
 309         if(Team.team && Team.team != NUM_SPECTATOR)
 310                 --team_count;
 311         AuditLists();
 312 }
 313
 314 entity GetTeam(int Team, bool add)
 315 {
 316         TC(int, Team); TC(bool, add);
 317         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 318         if(teamslots[num])
 319                 return teamslots[num];
 320         if (!add)
 321                 return NULL;
 322         entity tm = new_pure(team);
 323         tm.team = Team;
 324         teamslots[num] = tm;
 325         RegisterTeam(tm);
 326         return tm;
 327 }
 328
 329 .float has_team;
 330 bool SetTeam(entity o, int Team)
 331 {
 332         TC(int, Team);
 333         //devassert_once(Team);
 334         entity tm;
 335         if(teamplay)
 336         {
 337                 switch(Team)
 338                 {
 339                         case -1:
 340                         case NUM_TEAM_1:
 341                         case NUM_TEAM_2:
 342                         case NUM_TEAM_3:
 343                         case NUM_TEAM_4:
 344                                 break;
 345                         default:
 346                                 if(GetTeam(Team, false) == NULL)
 347                                 {
 348                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 349                                         Team = NUM_SPECTATOR;
 350                                 }
 351                                 break;
 352                 }
 353         }
 354         else
 355         {
 356                 switch(Team)
 357                 {
 358                         case -1:
 359                         case 0:
 360                                 break;
 361                         default:
 362                                 if(GetTeam(Team, false) == NULL)
 363                                 {
 364                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 365                                         Team = NUM_SPECTATOR;
 366                                 }
 367                                 break;
 368                 }
 369         }
 370         if(Team == -1) // leave
 371         {
 372                 if(o.has_team)
 373                 {
 374                         tm = GetTeam(o.team, false);
 375                         tm.team_size -= 1;
 376                         o.has_team = 0;
 377                         return true;
 378                 }
 379         }
 380         else
 381         {
 382                 if (!o.has_team)
 383                 {
 384                         o.team = Team;
 385                         tm = GetTeam(Team, true);
 386                         tm.team_size += 1;
 387                         o.has_team = 1;
 388                         return true;
 389                 }
 390                 else if(Team != o.team)
 391                 {
 392                         tm = GetTeam(o.team, false);
 393                         tm.team_size -= 1;
 394                         o.team = Team;
 395                         tm = GetTeam(Team, true);
 396                         tm.team_size += 1;
 397                         return true;
 398                 }
 399         }
 400         return false;
 401 }
 402
 403 void Playerchecker_Think(entity this)
 404 {
 405         int i;
 406         entity e;
 407         for(i = 0; i < maxclients; ++i)
 408         {
 409                 e = playerslots[i];
 410                 if(entcs_GetName(i) == "")
 411                 {
 412                         if(e.sort_prev)
 413                         {
 414                                 // player disconnected
 415                                 SetTeam(e, -1);
 416                                 RemovePlayer(e);
 417                                 e.sort_prev = NULL;
 418                                 //e.gotscores = 0;
 419                         }
 420                 }
 421                 else
 422                 {
 423                         if (!e.sort_prev)
 424                         {
 425                                 // player connected
 426                                 if (!e)
 427                                 {
 428                                         playerslots[i] = e = new_pure(playerslot);
 429                                 }
 430                                 e.sv_entnum = i;
 431                                 e.ping = 0;
 432                                 e.ping_packetloss = 0;
 433                                 e.ping_movementloss = 0;
 434                                 //e.gotscores = 0; // we might already have the scores...
 435                                 int t = entcs_GetScoreTeam(i);
 436                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 437                                 RegisterPlayer(e);
 438                                 Scoreboard_UpdatePlayerPos(e);
 439                         }
 440                 }
 441         }
 442         this.nextthink = time + 0.2;
 443 }
 444
 445 void PostInit()
 446 {
 447         entity playerchecker = new_pure(playerchecker);
 448         setthink(playerchecker, Playerchecker_Think);
 449         playerchecker.nextthink = time + 0.2;
 450
 451         TrueAim_Init();
 452
 453         // this can't be called in CSQC_Init as it'd send cvars too early
 454         ReplicateVars_Start();
 455
 456         postinit = true;
 457 }
 458
 459 void Release_Common_Keys()
 460 {
 461         localcmd("-fire\n");
 462         localcmd("-fire2\n");
 463         localcmd("-use\n");
 464         localcmd("-hook\n");
 465         localcmd("-jump\n");
 466         localcmd("-forward\n");
 467         localcmd("-back\n");
 468         localcmd("-moveleft\n");
 469         localcmd("-moveright\n");
 470 }
 471
 472 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 473 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 474 // All keys are in ascii.
 475 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 476 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 477 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 478 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 479 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 480 {
 481         TC(int, bInputType);
 482         bool override = false;
 483
 484         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 485         if (override)
 486                 return true;
 487
 488         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 489         if (override)
 490                 return true;
 491
 492         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 493
 494         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 495
 496         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 497
 498         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 499
 500         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 501
 502         if(override)
 503                 return true;
 504
 505         if(bInputType == 3 || bInputType == 2)
 506                 return false;
 507
 508         // at this point bInputType can only be 0 or 1 (key pressed or released)
 509         bool key_pressed = (bInputType == 0);
 510
 511         if(key_pressed) {
 512                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 513                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 514                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 515                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 516         }
 517         else {
 518                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 519                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 520                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 521                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 522         }
 523
 524         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 525         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 526         {
 527                 if (hudShiftState & S_TAB)
 528                 {
 529                         Scoreboard_UI_Enable(0);
 530                         return true;
 531                 }
 532                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 533                 {
 534                         localcmd("\nmenu_showgamemenudialog\n");
 535                         return true;
 536                 }
 537         }
 538
 539         return false;
 540 }
 541
 542 // END REQUIRED CSQC FUNCTIONS
 543 // --------------------------------------------------------------------------
 544
 545 // --------------------------------------------------------------------------
 546 // BEGIN OPTIONAL CSQC FUNCTIONS
 547
 548 void Ent_RemovePlayerScore(entity this)
 549 {
 550         if(this.owner) {
 551                 SetTeam(this.owner, -1);
 552                 this.owner.gotscores = 0;
 553                 FOREACH(Scores, true, {
 554                         this.owner.(scores(it)) = 0; // clear all scores
 555                 });
 556         }
 557 }
 558
 559 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 560 {
 561         make_pure(this);
 562         entity o;
 563
 564         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 565         // (no I've never heard of M-x replace-string, sed, or anything like that)
 566         bool isNew = !this.owner; // workaround for DP bug
 567         int n = ReadByte()-1;
 568
 569 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 570         if(!isNew && n != this.sv_entnum)
 571         {
 572                 //print("A CSQC entity changed its owner!\n");
 573                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 574                 isNew = true;
 575                 Ent_Remove(this);
 576         }
 577 #endif
 578
 579         this.sv_entnum = n;
 580
 581         o = playerslots[this.sv_entnum];
 582         if (!o)
 583         {
 584                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 585         }
 586         this.owner = o;
 587         o.sv_entnum = this.sv_entnum;
 588         o.gotscores = 1;
 589
 590         //if (!o.sort_prev)
 591         //      RegisterPlayer(o);
 592         //playerchecker will do this for us later, if it has not already done so
 593
 594         int sf = ReadShort();
 595         int lf = ReadShort();
 596         FOREACH(Scores, true, {
 597                 int p = 1 << (i % 16);
 598                 if (sf & p)
 599                 {
 600                         if (lf & p)
 601                                 o.(scores(it)) = ReadInt24_t();
 602                         else
 603                                 o.(scores(it)) = ReadChar();
 604                 }
 605         });
 606
 607         return = true;
 608
 609         if(o.sort_prev)
 610                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 611
 612         this.entremove = Ent_RemovePlayerScore;
 613 }
 614
 615 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 616 {
 617         make_pure(this);
 618         int i;
 619
 620         this.team = ReadByte();
 621         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 622
 623 #if MAX_TEAMSCORE <= 8
 624         int sf = ReadByte();
 625         int lf = ReadByte();
 626 #else
 627         int sf = ReadShort();
 628         int lf = ReadShort();
 629 #endif
 630         for(i = 0; i < MAX_TEAMSCORE; ++i)
 631                 if(sf & BIT(i))
 632                 {
 633                         if(lf & BIT(i))
 634                                 o.(teamscores(i)) = ReadInt24_t();
 635                         else
 636                                 o.(teamscores(i)) = ReadChar();
 637                 }
 638
 639         return = true;
 640
 641         Scoreboard_UpdateTeamPos(o);
 642 }
 643
 644 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 645 {
 646         make_pure(this);
 647         float newspectatee_status;
 648
 649         int f = ReadByte();
 650
 651         scoreboard_showscores_force = (f & BIT(0));
 652
 653         if(f & BIT(1))
 654         {
 655                 newspectatee_status = ReadByte();
 656                 if(newspectatee_status == player_localnum + 1)
 657                         newspectatee_status = -1; // observing
 658         }
 659         else
 660                 newspectatee_status = 0;
 661
 662         spectatorbutton_zoom = (f & BIT(2));
 663         observe_blocked = (f & BIT(3));
 664
 665         if(f & BIT(4))
 666         {
 667                 num_spectators = ReadByte();
 668
 669                 float i, slot;
 670
 671                 for(i = 0; i < MAX_SPECTATORS; ++i)
 672                         spectatorlist[i] = 0; // reset list first
 673
 674                 int limit = min(num_spectators, MAX_SPECTATORS);
 675                 for(i = 0; i < limit; ++i)
 676                 {
 677                         slot = ReadByte();
 678                         spectatorlist[i] = slot - 1;
 679                 }
 680         }
 681         else
 682         {
 683                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 684                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 685                 num_spectators = 0;
 686         }
 687
 688         return = true;
 689
 690         if(newspectatee_status != spectatee_status)
 691         {
 692                 // clear race stuff
 693                 race_laptime = 0;
 694                 race_checkpointtime = 0;
 695                 hud_dynamic_shake_factor = -1;
 696                 spectatee_status_changed_time = time;
 697         }
 698         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 699         {
 700                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 701                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 702                 )
 703                         prev_p_health = -1;
 704                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 705                         prev_health = -1;
 706         }
 707         spectatee_status = newspectatee_status;
 708
 709         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 710 }
 711
 712 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 713 {
 714         make_pure(this);
 715         int i, j, b, f;
 716
 717         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 718
 719         if(!(nags & BIT(2)))
 720         {
 721                 strfree(vote_called_vote);
 722                 vote_active = 0;
 723         }
 724         else
 725         {
 726                 vote_active = 1;
 727         }
 728
 729         if(nags & BIT(6))
 730         {
 731                 vote_yescount = ReadByte();
 732                 vote_nocount = ReadByte();
 733                 vote_needed = ReadByte();
 734                 vote_highlighted = ReadChar();
 735         }
 736
 737         if(nags & BIT(7))
 738         {
 739                 strcpy(vote_called_vote, ReadString());
 740         }
 741
 742         if(nags & 1)
 743         {
 744                 for(j = 0; j < maxclients; ++j)
 745                         if(playerslots[j])
 746                                 playerslots[j].ready = true;
 747                 for(i = 1; i <= maxclients; i += 8)
 748                 {
 749                         f = ReadByte();
 750                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 751                                 if (!(f & b))
 752                                         if(playerslots[j])
 753                                                 playerslots[j].ready = false;
 754                 }
 755         }
 756
 757         return = true;
 758
 759         ready_waiting = (nags & BIT(0));
 760         ready_waiting_for_me = (nags & BIT(1));
 761         vote_waiting = (nags & BIT(2));
 762         vote_waiting_for_me = (nags & BIT(3));
 763         warmup_stage = (nags & BIT(4));
 764 }
 765
 766 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 767 {
 768         make_pure(this);
 769         int sf = 0;
 770         serialize(byte, 0, sf);
 771         if (sf & 1) {
 772                 for (int j = 0; j < maxclients; ++j) {
 773                         if (playerslots[j]) {
 774                                 playerslots[j].eliminated = true;
 775                         }
 776                 }
 777                 for (int i = 1; i <= maxclients; i += 8) {
 778                         int f = 0;
 779                         serialize(byte, 0, f);
 780                         for (int b = 0; b < 8; ++b) {
 781                                 if (f & BIT(b)) continue;
 782                                 int j = i - 1 + b;
 783                                 if (playerslots[j]) {
 784                                         playerslots[j].eliminated = false;
 785                                 }
 786                         }
 787                 }
 788         }
 789         return true;
 790 }
 791
 792 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 793 {
 794         make_pure(this);
 795         prandom_debug();
 796         float s = ReadShort();
 797         psrandom(s);
 798         return true;
 799 }
 800
 801 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 802 {
 803         make_pure(this);
 804         float entnum = ReadByte();
 805
 806         int sf = ReadInt24_t();
 807         if (sf == 0) {
 808                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 809                         weapon_accuracy[w] = -1;
 810                 return true;
 811         }
 812
 813         int f = 1;
 814         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 815                 if (sf & f) {
 816                         if(entnum > 0) {
 817                                 playerslots[entnum-1].accuracy_frags[w] = ReadByte();
 818                                 playerslots[entnum-1].accuracy_hit[w] = ReadShort();
 819                                 playerslots[entnum-1].accuracy_cnt_hit[w] = ReadShort();
 820                                 playerslots[entnum-1].accuracy_cnt_fired[w] = ReadShort();
 821
 822                                 //LOG_INFOF("Duel stats ?/%d", playerslots[entnum-1].accuracy_cnt_fired[w]);
 823                         } else {
 824                                 int b = ReadByte();
 825                                 if (b == 0)
 826                                         weapon_accuracy[w] = -1;
 827                                 else if (b == 255)
 828                                         weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 829                                 else
 830                                         weapon_accuracy[w] = (b - 1.0) / 100.0;
 831                         }
 832                 }
 833                 f = (f == 0x800000) ? 1 : f * 2;
 834         }
 835         return true;
 836 }
 837
 838 void Spawn_Draw(entity this)
 839 {
 840         bool dodraw = autocvar_cl_spawn_point_particles;
 841         if(dodraw && autocvar_cl_spawn_point_dist_max)
 842         {
 843                 vector org = getpropertyvec(VF_ORIGIN);
 844                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 845         }
 846
 847         if(dodraw)
 848                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 849 }
 850
 851 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 852 {
 853         float teamnum = (ReadByte() - 1);
 854         vector spn_origin = ReadVector();
 855
 856         this.team = (teamnum + 1);
 857
 858         //if(is_new)
 859         //{
 860                 this.origin = spn_origin;
 861                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 862                 //droptofloor();
 863
 864                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 865                 {
 866                         this.mdl = "models/spawnpoint.md3";
 867                         this.colormod = Team_ColorRGB(teamnum);
 868                         precache_model(this.mdl);
 869                         setmodel(this, this.mdl);
 870                         this.drawmask = MASK_NORMAL;
 871                         //this.move_movetype = MOVETYPE_NOCLIP;
 872                         //this.draw = Spawn_Draw;
 873                         IL_PUSH(g_drawables, this);
 874                 }*/
 875                 this.draw = Spawn_Draw;
 876                 if (is_new) IL_PUSH(g_drawables, this);
 877         //}
 878
 879         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 880         return true;
 881 }
 882
 883 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 884 {
 885         // If entnum is 0, ONLY do the local spawn actions
 886         // this way the server can disable the sending of
 887         // spawn origin or such to clients if wanted.
 888         float entnum = ReadByte();
 889
 890         if(entnum)
 891         {
 892                 this.origin = ReadVector();
 893
 894                 if(is_new)
 895                 {
 896                         float teamnum = entcs_GetTeam(entnum - 1);
 897
 898                         if(autocvar_cl_spawn_event_particles)
 899                         {
 900                                 switch(teamnum)
 901                                 {
 902                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 903                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 904                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 905                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 906                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 907                                 }
 908                         }
 909                         if(autocvar_cl_spawn_event_sound)
 910                         {
 911                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 912                         }
 913                 }
 914         }
 915         return = true;
 916
 917         // local spawn actions
 918         if(is_new && (!entnum || (entnum == player_localentnum)))
 919         {
 920                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 921                 {
 922                         zoomin_effect = 1;
 923                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 924                 }
 925
 926                 if(autocvar_cl_unpress_zoom_on_spawn)
 927                 {
 928                         localcmd("-zoom\n");
 929                         button_zoom = false;
 930                 }
 931                 HUD_Radar_Hide_Maximized();
 932         }
 933         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 934 }
 935
 936 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 937 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 938 void CSQC_Ent_Update(entity this, bool isnew)
 939 {
 940         this.sourceLoc = __FILE__":"STR(__LINE__);
 941         int t = ReadByte();
 942
 943         // set up the "time" global for received entities to be correct for interpolation purposes
 944         float savetime = time;
 945         if(servertime)
 946         {
 947                 time = servertime;
 948         }
 949         else
 950         {
 951                 serverprevtime = time;
 952                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 953                 time = serverprevtime + serverdeltatime;
 954         }
 955
 956 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 957         if (this.enttype)
 958         {
 959                 if (t != this.enttype || isnew)
 960                 {
 961                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 962                         Ent_Remove(this);
 963                         ONREMOVE(this);
 964                         clearentity(this);
 965                         isnew = true;
 966                 }
 967         }
 968         else
 969         {
 970                 if (!isnew)
 971                 {
 972                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 973                         isnew = true;
 974                 }
 975         }
 976 #endif
 977         this.enttype = t;
 978         bool done = false;
 979         FOREACH(LinkedEntities, it.m_id == t, {
 980                 if (isnew) this.classname = it.netname;
 981                 if (autocvar_developer_csqcentities)
 982                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 983                 done = it.m_read(this, NULL, isnew);
 984                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 985                 break;
 986         });
 987         time = savetime;
 988         if (!done)
 989         {
 990                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 991         }
 992 }
 993
 994 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 995 // used when an entity changes its type. For an entity that someone interacts
 996 // with others, make sure it can no longer do so.
 997 void Ent_Remove(entity this)
 998 {
 999         if(this.entremove) this.entremove(this);
1000
1001         if(this.skeletonindex)
1002         {
1003                 skel_delete(this.skeletonindex);
1004                 this.skeletonindex = 0;
1005         }
1006
1007         if(this.snd_looping > 0)
1008         {
1009                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
1010                 this.snd_looping = 0;
1011         }
1012
1013         this.enttype = 0;
1014         this.classname = "";
1015         this.draw = func_null;
1016         this.entremove = func_null;
1017         // TODO possibly set more stuff to defaults
1018 }
1019 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
1020 void CSQC_Ent_Remove(entity this)
1021 {
1022         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1023         if (wasfreed(this))
1024         {
1025                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1026                 return;
1027         }
1028         if (this.enttype) Ent_Remove(this);
1029         delete(this);
1030 }
1031
1032 void Gamemode_Init()
1033 {
1034         if (!isdemo())
1035         {
1036                 if(!(calledhooks & HOOK_START))
1037                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1038                 calledhooks |= HOOK_START;
1039         }
1040 }
1041 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1042 void CSQC_Parse_StuffCmd(string strMessage)
1043 {
1044         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1045         localcmd(strMessage);
1046 }
1047 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1048 void CSQC_Parse_Print(string strMessage)
1049 {
1050         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1051         print(ColorTranslateRGB(strMessage));
1052 }
1053
1054 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1055 void CSQC_Parse_CenterPrint(string strMessage)
1056 {
1057         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1058         centerprint_AddStandard(strMessage);
1059 }
1060
1061 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1062 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1063 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1064 bool CSQC_Parse_TempEntity()
1065 {
1066         // Acquire TE ID
1067         int nTEID = ReadByte();
1068
1069         FOREACH(TempEntities, it.m_id == nTEID, {
1070                 if (autocvar_developer_csqcentities)
1071                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1072                 return it.m_read(NULL, NULL, true);
1073         });
1074
1075         if (autocvar_developer_csqcentities)
1076                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1077
1078         // No special logic for this temporary entity; return 0 so the engine can handle it
1079         return false;
1080 }
1081
1082 string forcefog;
1083 void Fog_Force()
1084 {
1085         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1086                 localcmd("\nr_drawfog 0\n");
1087         else if (forcefog != "")
1088                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1089 }
1090
1091 bool net_handle_ServerWelcome();
1092 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1093 {
1094         make_pure(this);
1095         gametype = ReadRegistered(Gametypes);
1096         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1097         HUD_ModIcons_SetFunc();
1098         FOREACH(Scores, true, {
1099                 strcpy(scores_label(it), ReadString());
1100                 scores_flags(it) = ReadByte();
1101         });
1102         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1103         {
1104                 strcpy(teamscores_label(i), ReadString());
1105                 teamscores_flags(i) = ReadByte();
1106         }
1107         bool welcome_msg_too = ReadByte();
1108         if (welcome_msg_too)
1109                 net_handle_ServerWelcome();
1110         return = true;
1111         Scoreboard_InitScores();
1112         Gamemode_Init();
1113 }
1114
1115 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1116 {
1117         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1118
1119         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1120         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1121         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1122         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1123         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1124         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1125         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1126         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1127
1128         strcpy(forcefog, ReadString());
1129
1130         armorblockpercent = ReadByte() / 255.0;
1131         damagepush_speedfactor = ReadByte() / 255.0;
1132
1133         serverflags = ReadByte();
1134
1135         g_trueaim_minrange = ReadCoord();
1136
1137         strcpy(hostname_full, ReadString());
1138         strcpy(motd_permanent, ReadString());
1139
1140         sv_timer_countdown = ReadByte();
1141
1142         return = true;
1143
1144         MUTATOR_CALLHOOK(Ent_Init);
1145
1146         if (!postinit) PostInit();
1147 }
1148
1149 NET_HANDLE(TE_CSQC_TEAMNAMES, bool isNew)
1150 {
1151         teamname_red = strzone(ReadString());
1152         teamname_blue = strzone(ReadString());
1153         teamname_yellow = strzone(ReadString());
1154         teamname_pink = strzone(ReadString());
1155
1156         return = true;
1157 }
1158
1159 NET_HANDLE(TE_CSQC_CHATSOUND, bool isNew)
1160 {
1161         string snd = ReadString();
1162         snd = strcat("chat/", snd, ".ogg");
1163
1164         precache_sound(snd);
1165         _sound(NULL, CH_INFO, snd, VOL_BASE, ATTN_NONE);
1166
1167         return = true;
1168 }
1169
1170 float GetSpeedUnitFactor(int speed_unit)
1171 {
1172         switch(speed_unit)
1173         {
1174                 default:
1175                 case 1: return 1.0;
1176                 case 2: return 0.0254;
1177                 case 3: return 0.0254 * 3.6;
1178                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1179                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1180         }
1181 }
1182
1183 string GetSpeedUnit(int speed_unit)
1184 {
1185         switch(speed_unit)
1186         {
1187                 // translator-friendly strings without the initial space
1188                 default:
1189                 case 1: return strcat(" ", _("qu/s"));
1190                 case 2: return strcat(" ", _("m/s"));
1191                 case 3: return strcat(" ", _("km/h"));
1192                 case 4: return strcat(" ", _("mph"));
1193                 case 5: return strcat(" ", _("knots"));
1194         }
1195 }
1196
1197 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1198 {
1199         int b = ReadByte();
1200
1201         switch (b)
1202         {
1203                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1204                         race_checkpoint = ReadByte();
1205                         race_time = ReadInt24_t();
1206                         race_previousbesttime = ReadInt24_t();
1207                         race_mypreviousbesttime = ReadInt24_t();
1208                         string pbestname = ReadString();
1209                         if(autocvar_cl_race_cptimes_onlyself)
1210                         {
1211                                 race_previousbesttime = race_mypreviousbesttime;
1212                                 race_mypreviousbesttime = 0;
1213                                 strcpy(race_previousbestname, "");
1214                         }
1215                         else
1216                                 strcpy(race_previousbestname, pbestname);
1217
1218                         race_checkpointtime = time;
1219
1220                         if(race_checkpoint == 0 || race_checkpoint == 254)
1221                         {
1222                                 race_penaltyaccumulator = 0;
1223                                 race_laptime = time; // valid
1224                         }
1225                         break;
1226
1227                 case RACE_NET_CHECKPOINT_CLEAR:
1228                         race_laptime = 0;
1229                         race_checkpointtime = 0;
1230                         break;
1231
1232                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1233                         race_laptime = ReadCoord();
1234                         race_checkpointtime = -99999;
1235                         // fall through
1236                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1237                         race_nextcheckpoint = ReadByte();
1238
1239                         race_nextbesttime = ReadInt24_t();
1240                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1241                                 race_mybesttime = ReadInt24_t();
1242                         string newname = ReadString();
1243                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1244                         {
1245                                 race_nextbesttime = race_mybesttime;
1246                                 race_mybesttime = 0;
1247                                 strcpy(race_nextbestname, "");
1248                         }
1249                         else
1250                                 strcpy(race_nextbestname, newname);
1251                         break;
1252
1253                 case RACE_NET_CHECKPOINT_HIT_RACE:
1254                         race_mycheckpoint = ReadByte();
1255                         race_mycheckpointtime = time;
1256                         race_mycheckpointdelta = ReadInt24_t();
1257                         race_mycheckpointlapsdelta = ReadByte();
1258                         if(race_mycheckpointlapsdelta >= 128)
1259                                 race_mycheckpointlapsdelta -= 256;
1260                         int who = ReadByte();
1261                         if(who)
1262                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1263                         else
1264                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1265                         break;
1266
1267                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1268                         race_othercheckpoint = ReadByte();
1269                         race_othercheckpointtime = time;
1270                         race_othercheckpointdelta = ReadInt24_t();
1271                         race_othercheckpointlapsdelta = ReadByte();
1272                         if(race_othercheckpointlapsdelta >= 128)
1273                                 race_othercheckpointlapsdelta -= 256;
1274                         int what = ReadByte();
1275                         if(what)
1276                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1277                         else
1278                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1279                         break;
1280
1281                 case RACE_NET_PENALTY_RACE:
1282                 case RACE_NET_PENALTY_QUALIFYING:
1283                         race_penaltyeventtime = time;
1284                         race_penaltytime = ReadShort();
1285                         string reason = ReadString();
1286                         if (reason == "missing a checkpoint")
1287                                 reason = _("missing a checkpoint");
1288                         strcpy(race_penaltyreason, reason);
1289                         if (b == RACE_NET_PENALTY_QUALIFYING)
1290                                 race_penaltyaccumulator += race_penaltytime;
1291                         break;
1292
1293                 case RACE_NET_SERVER_RECORD:
1294                         race_server_record = ReadInt24_t();
1295                         break;
1296                 case RACE_NET_SPEED_AWARD:
1297                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1298                         strcpy(race_speedaward_holder, ReadString());
1299                         break;
1300                 case RACE_NET_SPEED_AWARD_BEST:
1301                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1302                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1303                         break;
1304                 case RACE_NET_RANKINGS_CNT:
1305                         RANKINGS_DISPLAY_CNT = ReadByte();
1306                         break;
1307                 case RACE_NET_SERVER_RANKINGS:
1308                         float prevpos, del;
1309                         int pos = ReadShort();
1310                         prevpos = ReadShort();
1311                         del = ReadShort();
1312
1313                         // move other rankings out of the way
1314                         int i;
1315                         if (prevpos) {
1316                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1317                                 for (i=m-1; i>pos-1; --i) {
1318                                         grecordtime[i] = grecordtime[i-1];
1319                                         strcpy(grecordholder[i], grecordholder[i-1]);
1320                                 }
1321                         } else if (del) { // a record has been deleted by the admin
1322                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1323                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1324                                                 grecordtime[i] = 0;
1325                                                 strfree(grecordholder[i]);
1326                                         }
1327                                         else {
1328                                                 grecordtime[i] = grecordtime[i+1];
1329                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1330                                         }
1331                                 }
1332                         } else { // player has no ranked record yet
1333                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1334                                         grecordtime[i] = grecordtime[i-1];
1335                                         strcpy(grecordholder[i], grecordholder[i-1]);
1336                                 }
1337                         }
1338
1339                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1340                                 // kick off the player who fell from the last displayed position
1341                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1342                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1343                         }
1344
1345                         // store new ranking
1346                         strcpy(grecordholder[pos-1], ReadString());
1347                         grecordtime[pos-1] = ReadInt24_t();
1348                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1349                                 race_myrank = pos;
1350                         break;
1351                 case RACE_NET_SERVER_STATUS:
1352                         race_status = ReadShort();
1353                         strcpy(race_status_name, ReadString());
1354         }
1355         return true;
1356 }
1357
1358 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1359 {
1360         teamnagger = 1;
1361         return true;
1362 }
1363
1364 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1365 {
1366         int i = ReadByte();
1367         int pi = ReadShort();
1368         int pl = ReadByte();
1369         int ml = ReadByte();
1370         return = true;
1371         entity e = playerslots[i];
1372         if (!e) return;
1373         e.ping = pi;
1374         e.ping_packetloss = pl / 255.0;
1375         e.ping_movementloss = ml / 255.0;
1376 }
1377
1378 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1379 {
1380         int weapon_id = ReadByte();
1381         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1382         complain_weapon_type = ReadByte();
1383         return = true;
1384
1385         complain_weapon_time = time;
1386         weapontime = time; // ping the weapon panel
1387
1388         switch(complain_weapon_type)
1389         {
1390                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1391                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1392                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1393         }
1394 }
1395
1396 string translate_modifications(string s)
1397 {
1398         return build_mutator_list(s);
1399 }
1400
1401 string translate_weaponarena(string s)
1402 {
1403         if (s == "") return s;
1404         if (s == "All Weapons Arena") return _("All Weapons Arena");
1405         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1406         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1407         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1408         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1409         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1410         if (s == "No Weapons Arena") return _("No Weapons Arena");
1411
1412         int n = tokenizebyseparator(s, " & ");
1413         string wpn_list = "";
1414         for (int i = 0; i < n; i++)
1415         {
1416                 Weapon wep = Weapon_from_name(argv(i));
1417                 if (wep == WEP_Null)
1418                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1419                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1420         }
1421         if (wpn_list != "")
1422                 return sprintf(_("%s Arena"), wpn_list);
1423         else
1424                 return _("No Weapons Arena");
1425 }
1426
1427 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1428 {
1429         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1430         if (version_mismatch)
1431         {
1432                 if(!version_check)
1433                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1434                                 _("Your client version is outdated."), "\n\n\n",
1435                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1436                                 _("Please update!"));
1437                 else
1438                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1439                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1440                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1441         }
1442         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1443 }
1444
1445 bool net_handle_ServerWelcome()
1446 {
1447         bool campaign = ReadByte();
1448         if (campaign)
1449         {
1450                 string campaign_title = ReadString();
1451                 int campaign_level = ReadByte();
1452                 string campaign_msg = ReadString();
1453                 string welcomedialog_args;
1454                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1455                 string key = getcommandkey(_("jump"), "+jump");
1456                 string msg = strcat(
1457                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1458                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1459                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1460                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1461                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1462                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1463                 return true;
1464         }
1465
1466         strcpy(hostname, ReadString());
1467         string hostversion = ReadString();
1468         bool version_mismatch = ReadByte();
1469         bool version_check = ReadByte();
1470         srv_minplayers = ReadByte();
1471         srv_maxplayers = ReadByte();
1472         string modifications = translate_modifications(ReadString());
1473         string weaponarena_list = translate_weaponarena(ReadString());
1474         string cache_mutatormsg = ReadString();
1475         string motd = ReadString();
1476
1477         string msg = GetVersionMessage(hostversion, version_mismatch, version_check);
1478
1479         msg = strcat(msg, "\n\n", _("Gametype:"), " ^1", MapInfo_Type_ToText(gametype), "\n");
1480
1481         msg = strcat(msg, "\n", _("Map:"), " ^2");
1482         if (world.message == "")
1483                 msg = strcat(msg, mi_shortname, "\n");
1484         else
1485         {
1486                 int i = strstrofs(world.message, " by ", 0); // matches _MapInfo_Generate()
1487                 string longname = i >= 0 ? substring(world.message, 0, i) : world.message;
1488                 msg = strcat(msg, (strcasecmp(longname, mi_shortname) ? strcat(mi_shortname, " ^7// ^2") : ""), longname, "\n");
1489         }
1490
1491         if (srv_minplayers || srv_maxplayers)
1492         {
1493                 msg = strcat(msg, "\n", _("This match supports"), " ^5");
1494                 if (srv_minplayers == srv_maxplayers)
1495                         msg = strcat(msg, sprintf(_("%d players"), srv_maxplayers), "\n");
1496                 else if (srv_minplayers && srv_maxplayers)
1497                         msg = strcat(msg, sprintf(_("%d to %d players"), srv_minplayers, srv_maxplayers), "\n");
1498                 else if (srv_maxplayers)
1499                         msg = strcat(msg, sprintf(_("%d players maximum"), srv_maxplayers), "\n");
1500                 else
1501                         msg = strcat(msg, sprintf(_("%d players minimum"), srv_minplayers), "\n");
1502         }
1503
1504         modifications = cons_mid(modifications, ", ", weaponarena_list);
1505         if(modifications != "")
1506                 msg = strcat(msg, "\n", _("Active modifications:"), " ^3", modifications, "\n");
1507
1508         if (cache_mutatormsg != "")
1509                 msg = strcat(msg, "\n", _("Special gameplay tips:"), " ^7", cache_mutatormsg, "\n");
1510         string mutator_msg = "";
1511         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1512         mutator_msg = M_ARGV(0, string);
1513         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1514
1515         if (motd != "")
1516                 msg = strcat(msg, "\n^9↓ ", _("Server's message"), " ↓\n", motd);
1517
1518         strcpy(welcome_msg, msg);
1519         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1520         return true;
1521 }
1522
1523 void Welcome_Message_Show_Try()
1524 {
1525         if (!welcome_msg_menu_check_maxtime)
1526                 return;
1527
1528         // if want dialog check if menu is initialized but for a short time
1529         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1530         {
1531                 if (cvar("_menu_welcome_dialog_available"))
1532                 {
1533                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1534                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1535                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1536
1537                         if (intermission || isdemo() || !autocvar_cl_welcome)
1538                         {
1539                                 if (cvar("_menu_cmd_closemenu_available"))
1540                                 {
1541                                         // initialize the dialog without opening it
1542                                         localcmd("\nmenu_cmd closemenu Welcome ", welcomedialog_args, "\n");
1543                                 }
1544                                 else
1545                                 {
1546                                         // legacy code for clients with old menus
1547                                         // since togglemenu 0 doesn't close the dialog but only hides it,
1548                                         // playing back a demo the Welcome dialog will pop up on the first ESC press
1549                                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1550                                         // close it after it's been initialized so it can still be opened manually
1551                                         localcmd("\ntogglemenu 0\n");
1552                                 }
1553                         }
1554                         else
1555                                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1556                 }
1557
1558                 strfree(welcome_msg);
1559                 welcome_msg_menu_check_maxtime = 0;
1560         }
1561 }
1562
1563 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1564 {
1565         return net_handle_ServerWelcome();
1566 }
1567
1568 string _getcommandkey(string cmd_name, string command, bool forcename)
1569 {
1570         string keys;
1571         float n, j, k, l = 0;
1572
1573         if (!autocvar_hud_showbinds)
1574                 return cmd_name;
1575
1576         keys = db_get(binddb, command);
1577         if (keys == "")
1578         {
1579                 bool joy_active = cvar("joy_active");
1580                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1581                 for(j = 0; j < n; ++j)
1582                 {
1583                         k = stof(argv(j));
1584                         if(k != -1)
1585                         {
1586                                 string key = keynumtostring(k);
1587                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1588                                         continue;
1589
1590                                 key = translate_key(key);
1591
1592                                 if (keys == "")
1593                                         keys = key;
1594                                 else
1595                                         keys = strcat(keys, ", ", key);
1596
1597                                 ++l;
1598                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1599                                         break;
1600                         }
1601
1602                 }
1603                 if (keys == "")
1604                         keys = "NO_KEY";
1605                 db_put(binddb, command, keys);
1606         }
1607
1608         if (keys == "NO_KEY") {
1609                 if (autocvar_hud_showbinds > 1)
1610                         return sprintf(_("%s (not bound)"), cmd_name);
1611                 else
1612                         return cmd_name;
1613         }
1614         else if (autocvar_hud_showbinds > 1 || forcename)
1615                 return sprintf("%s (%s)", cmd_name, keys);
1616         else
1617                 return keys;
1618 }
1619
1620 /** engine callback */
1621 void URI_Get_Callback(int id, int status, string data)
1622 {
1623         TC(int, id); TC(int, status);
1624         if(url_URI_Get_Callback(id, status, data))
1625         {
1626                 // handled
1627         }
1628         else if (id == URI_GET_DISCARD)
1629         {
1630                 // discard
1631         }
1632         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1633         {
1634                 // sv_cmd curl
1635                 Curl_URI_Get_Callback(id, status, data);
1636         }
1637         else
1638         {
1639                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1640         }
1641 }