qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_onlyowned");
  84                                         break;
  85                                 case HUD_PANEL_AMMO:
  86                                         HUD_Write_PanelCvar_q("_onlycurrent");
  87                                         HUD_Write_PanelCvar_q("_iconalign");
  88                                         HUD_Write_PanelCvar_q("_progressbar");
  89                                         HUD_Write_PanelCvar_q("_progressbar_name");
  90                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  91                                         HUD_Write_PanelCvar_q("_text");
  92                                         break;
  93                                 case HUD_PANEL_POWERUPS:
  94                                         HUD_Write_PanelCvar_q("_flip");
  95                                         HUD_Write_PanelCvar_q("_iconalign");
  96                                         HUD_Write_PanelCvar_q("_baralign");
  97                                         HUD_Write_PanelCvar_q("_progressbar");
  98                                         HUD_Write_PanelCvar_q("_progressbar_strength");
  99                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 100                                         HUD_Write_PanelCvar_q("_text");
 101                                         break;
 102                                 case HUD_PANEL_HEALTHARMOR:
 103                                         HUD_Write_PanelCvar_q("_flip");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_baralign");
 106                                         HUD_Write_PanelCvar_q("_progressbar");
 107                                         HUD_Write_PanelCvar_q("_progressbar_health");
 108                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 109                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 110                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 111                                         HUD_Write_PanelCvar_q("_text");
 112                                         break;
 113                                 case HUD_PANEL_NOTIFY:
 114                                         HUD_Write_PanelCvar_q("_flip");
 115                                         HUD_Write_PanelCvar_q("_fontsize");
 116                                         HUD_Write_PanelCvar_q("_print");
 117                                         HUD_Write_PanelCvar_q("_time");
 118                                         HUD_Write_PanelCvar_q("_fadetime");
 119                                         break;
 120                                 case HUD_PANEL_TIMER:
 121                                         HUD_Write_PanelCvar_q("_increment");
 122                                         break;
 123                                 case HUD_PANEL_RADAR:
 124                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 125                                         HUD_Write_PanelCvar_q("_rotation");
 126                                         HUD_Write_PanelCvar_q("_zoommode");
 127                                         HUD_Write_PanelCvar_q("_scale");
 128                                         HUD_Write_PanelCvar_q("_maximized_scale");
 129                                         HUD_Write_PanelCvar_q("_maximized_size");
 130                                         break;
 131                                 case HUD_PANEL_SCORE:
 132                                         HUD_Write_PanelCvar_q("_rankings");
 133                                         break;
 134                                 case HUD_PANEL_VOTE:
 135                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 136                                         break;
 137                                 case HUD_PANEL_MODICONS:
 138                                         HUD_Write_PanelCvar_q("_dom_layout");
 139                                         break;
 140                                 case HUD_PANEL_PRESSEDKEYS:
 141                                         HUD_Write_PanelCvar_q("_aspect");
 142                                         break;
 143                                 case HUD_PANEL_ENGINEINFO:
 144                                         HUD_Write_PanelCvar_q("_framecounter_time");
 145                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 146                                         break;
 147                                 case HUD_PANEL_INFOMESSAGES:
 148                                         HUD_Write_PanelCvar_q("_flip");
 149                                         break;
 150                                 case HUD_PANEL_PHYSICS:
 151                                         HUD_Write_PanelCvar_q("_speed_unit");
 152                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 153                                         HUD_Write_PanelCvar_q("_speed_max");
 154                                         HUD_Write_PanelCvar_q("_speed_vertical");
 155                                         HUD_Write_PanelCvar_q("_topspeed");
 156                                         HUD_Write_PanelCvar_q("_topspeed_time");
 157                                         HUD_Write_PanelCvar_q("_acceleration_max");
 158                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 159                                         HUD_Write_PanelCvar_q("_flip");
 160                                         HUD_Write_PanelCvar_q("_baralign");
 161                                         HUD_Write_PanelCvar_q("_progressbar");
 162                                         HUD_Write_PanelCvar_q("_acceleration_mode");
 163                                         HUD_Write_PanelCvar_q("_text");
 164                                         break;
 165                                 case HUD_PANEL_CENTERPRINT:
 166                                         HUD_Write_PanelCvar_q("_align");
 167                                         HUD_Write_PanelCvar_q("_flip");
 168                                         HUD_Write_PanelCvar_q("_fontscale");
 169                                         HUD_Write_PanelCvar_q("_time");
 170                                         HUD_Write_PanelCvar_q("_fade_in");
 171                                         HUD_Write_PanelCvar_q("_fade_out");
 172                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 173                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 174                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 175                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 176                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 177                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 178                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 179                                         break;
 180                                 case HUD_PANEL_ITEMSTIME:
 181                                         HUD_Write_PanelCvar_q("_iconalign");
 182                                         HUD_Write_PanelCvar_q("_progressbar");
 183                                         HUD_Write_PanelCvar_q("_progressbar_name");
 184                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
 185                                         HUD_Write_PanelCvar_q("_text");
 186                                         break;
 187                         }
 188                         HUD_Write("\n");
 189                 }
 190                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 191
 192                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 193                 fclose(fh);
 194         }
 195         else
 196                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 197 }
 198
 199 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 200 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 201 {
 202         float i;
 203         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 204         vector myTarget;
 205         myTarget = myPos;
 206
 207         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 208                 if(i == highlightedPanel || !panel_enabled)
 209                         continue;
 210
 211                 HUD_Panel_UpdatePosSizeForId(i);
 212
 213                 panel_pos -= '1 1 0' * panel_bg_border;
 214                 panel_size += '2 2 0' * panel_bg_border;
 215
 216                 if(myPos_y + mySize_y < panel_pos_y)
 217                         continue;
 218                 if(myPos_y > panel_pos_y + panel_size_y)
 219                         continue;
 220
 221                 if(myPos_x + mySize_x < panel_pos_x)
 222                         continue;
 223                 if(myPos_x > panel_pos_x + panel_size_x)
 224                         continue;
 225
 226                 // OK, there IS a collision.
 227
 228                 myCenter_x = myPos_x + 0.5 * mySize_x;
 229                 myCenter_y = myPos_y + 0.5 * mySize_y;
 230
 231                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 232                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 233
 234                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 235                 {
 236                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 237                                 myTarget_x = panel_pos_x - mySize_x;
 238                         else // push it upwards
 239                                 myTarget_y = panel_pos_y - mySize_y;
 240                 }
 241                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 242                 {
 243                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 244                                 myTarget_x = panel_pos_x + panel_size_x;
 245                         else // push it upwards
 246                                 myTarget_y = panel_pos_y - mySize_y;
 247                 }
 248                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 249                 {
 250                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 251                                 myTarget_x = panel_pos_x - mySize_x;
 252                         else // push it downwards
 253                                 myTarget_y = panel_pos_y + panel_size_y;
 254                 }
 255                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 256                 {
 257                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 258                                 myTarget_x = panel_pos_x + panel_size_x;
 259                         else // push it downwards
 260                                 myTarget_y = panel_pos_y + panel_size_y;
 261                 }
 262                 //if(cvar("hud_configure_checkcollisions_debug"))
 263                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 264         }
 265
 266         return myTarget;
 267 }
 268
 269 void HUD_Panel_SetPos(vector pos)
 270 {
 271         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 272         vector mySize;
 273         mySize = panel_size;
 274
 275         //if(cvar("hud_configure_checkcollisions_debug"))
 276                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 277
 278         if(autocvar_hud_configure_grid)
 279         {
 280                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 281                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 282         }
 283
 284         if(hud_configure_checkcollisions)
 285                 pos = HUD_Panel_CheckMove(pos, mySize);
 286
 287         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 288         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 289
 290         string s;
 291         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 292
 293         HUD_Panel_GetName(highlightedPanel);
 294         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 295 }
 296
 297 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 298 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 299         float i;
 300
 301         vector targEndPos;
 302
 303         float dist_x, dist_y;
 304         float ratio;
 305         ratio = mySize_x/mySize_y;
 306
 307         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 308                 if(i == highlightedPanel || !panel_enabled)
 309                         continue;
 310
 311                 HUD_Panel_UpdatePosSizeForId(i);
 312
 313                 panel_pos -= '1 1 0' * panel_bg_border;
 314                 panel_size += '2 2 0' * panel_bg_border;
 315
 316                 targEndPos = panel_pos + panel_size;
 317
 318                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 319                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 320                         continue;
 321
 322                 if (resizeCorner == 1)
 323                 {
 324                         // check if this panel is on our way
 325                         if (resizeorigin_x <= panel_pos_x)
 326                                 continue;
 327                         if (resizeorigin_y <= panel_pos_y)
 328                                 continue;
 329                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 330                                 continue;
 331                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 332                                 continue;
 333
 334                         // there is a collision:
 335                         // detect which side of the panel we are facing is actually limiting the resizing
 336                         // (which side the resize direction finds for first) and reduce the size up to there
 337                         //
 338                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 339                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 340                         dist_x = resizeorigin_x - targEndPos_x;
 341                         dist_y = resizeorigin_y - targEndPos_y;
 342                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 343                                 mySize_x = min(mySize_x, dist_x);
 344                         else
 345                                 mySize_y = min(mySize_y, dist_y);
 346                 }
 347                 else if (resizeCorner == 2)
 348                 {
 349                         if (resizeorigin_x >= targEndPos_x)
 350                                 continue;
 351                         if (resizeorigin_y <= panel_pos_y)
 352                                 continue;
 353                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 354                                 continue;
 355                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 356                                 continue;
 357
 358                         dist_x = panel_pos_x - resizeorigin_x;
 359                         dist_y = resizeorigin_y - targEndPos_y;
 360                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 361                                 mySize_x = min(mySize_x, dist_x);
 362                         else
 363                                 mySize_y = min(mySize_y, dist_y);
 364                 }
 365                 else if (resizeCorner == 3)
 366                 {
 367                         if (resizeorigin_x <= panel_pos_x)
 368                                 continue;
 369                         if (resizeorigin_y >= targEndPos_y)
 370                                 continue;
 371                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 372                                 continue;
 373                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 374                                 continue;
 375
 376                         dist_x = resizeorigin_x - targEndPos_x;
 377                         dist_y = panel_pos_y - resizeorigin_y;
 378                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 379                                 mySize_x = min(mySize_x, dist_x);
 380                         else
 381                                 mySize_y = min(mySize_y, dist_y);
 382                 }
 383                 else if (resizeCorner == 4)
 384                 {
 385                         if (resizeorigin_x >= targEndPos_x)
 386                                 continue;
 387                         if (resizeorigin_y >= targEndPos_y)
 388                                 continue;
 389                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 390                                 continue;
 391                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 392                                 continue;
 393
 394                         dist_x = panel_pos_x - resizeorigin_x;
 395                         dist_y = panel_pos_y - resizeorigin_y;
 396                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 397                                 mySize_x = min(mySize_x, dist_x);
 398                         else
 399                                 mySize_y = min(mySize_y, dist_y);
 400                 }
 401                 //if(cvar("hud_configure_checkcollisions_debug"))
 402                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 403         }
 404
 405         return mySize;
 406 }
 407
 408 void HUD_Panel_SetPosSize(vector mySize)
 409 {
 410         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 411         vector resizeorigin;
 412         resizeorigin = panel_click_resizeorigin;
 413         local noref vector myPos; // fteqcc sucks
 414
 415         // minimum panel size cap
 416         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 417         mySize_y = max(0.025 * vid_conheight, mySize_y);
 418
 419         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 420         {
 421                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 422                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 423         }
 424
 425         // collision testing|
 426         // -----------------+
 427
 428         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 429         if(resizeCorner == 1) {
 430                 myPos_x = resizeorigin_x - mySize_x;
 431                 myPos_y = resizeorigin_y - mySize_y;
 432         } else if(resizeCorner == 2) {
 433                 myPos_x = resizeorigin_x;
 434                 myPos_y = resizeorigin_y - mySize_y;
 435         } else if(resizeCorner == 3) {
 436                 myPos_x = resizeorigin_x - mySize_x;
 437                 myPos_y = resizeorigin_y;
 438         } else { // resizeCorner == 4
 439                 myPos_x = resizeorigin_x;
 440                 myPos_y = resizeorigin_y;
 441         }
 442
 443         // left/top screen edges
 444         if(myPos_x < 0)
 445                 mySize_x = mySize_x + myPos_x;
 446         if(myPos_y < 0)
 447                 mySize_y = mySize_y + myPos_y;
 448
 449         // bottom/right screen edges
 450         if(myPos_x + mySize_x > vid_conwidth)
 451                 mySize_x = vid_conwidth - myPos_x;
 452         if(myPos_y + mySize_y > vid_conheight)
 453                 mySize_y = vid_conheight - myPos_y;
 454
 455         //if(cvar("hud_configure_checkcollisions_debug"))
 456                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 457
 458         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 459         if(autocvar_hud_configure_grid)
 460         {
 461                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 462                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 463         }
 464
 465         if(hud_configure_checkcollisions)
 466                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 467
 468         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 469         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 470         mySize_y = max(0.025 * vid_conheight, mySize_y);
 471
 472         // do another pos check, as size might have changed by now
 473         if(resizeCorner == 1) {
 474                 myPos_x = resizeorigin_x - mySize_x;
 475                 myPos_y = resizeorigin_y - mySize_y;
 476         } else if(resizeCorner == 2) {
 477                 myPos_x = resizeorigin_x;
 478                 myPos_y = resizeorigin_y - mySize_y;
 479         } else if(resizeCorner == 3) {
 480                 myPos_x = resizeorigin_x - mySize_x;
 481                 myPos_y = resizeorigin_y;
 482         } else { // resizeCorner == 4
 483                 myPos_x = resizeorigin_x;
 484                 myPos_y = resizeorigin_y;
 485         }
 486
 487         //if(cvar("hud_configure_checkcollisions_debug"))
 488                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 489
 490         HUD_Panel_GetName(highlightedPanel);
 491         string s;
 492         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 493         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 494
 495         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 496         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 497 }
 498
 499 float pressed_key_time;
 500 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 501 void HUD_Panel_Arrow_Action(float nPrimary)
 502 {
 503         if (highlightedPanel == -1)
 504                 return;
 505
 506         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 507
 508         float step;
 509         if(autocvar_hud_configure_grid)
 510         {
 511                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 512                 {
 513                         if (hudShiftState & S_SHIFT)
 514                                 step = hud_configure_realGridSize_y;
 515                         else
 516                                 step = 2 * hud_configure_realGridSize_y;
 517                 }
 518                 else
 519                 {
 520                         if (hudShiftState & S_SHIFT)
 521                                 step = hud_configure_realGridSize_x;
 522                         else
 523                                 step = 2 * hud_configure_realGridSize_x;
 524                 }
 525         }
 526         else
 527         {
 528                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 529                         step = vid_conheight;
 530                 else
 531                         step = vid_conwidth;
 532                 if (hudShiftState & S_SHIFT)
 533                         step = (step / 256); // more precision
 534                 else
 535                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 536         }
 537
 538         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 539
 540         highlightedPanel_initial_pos = panel_pos;
 541         highlightedPanel_initial_size = panel_size;
 542
 543         if (hudShiftState & S_ALT) // resize
 544         {
 545                 highlightedAction = 1;
 546                 if(nPrimary == K_UPARROW)
 547                         resizeCorner = 1;
 548                 else if(nPrimary == K_RIGHTARROW)
 549                         resizeCorner = 2;
 550                 else if(nPrimary == K_LEFTARROW)
 551                         resizeCorner = 3;
 552                 else // if(nPrimary == K_DOWNARROW)
 553                         resizeCorner = 4;
 554
 555                 // ctrl+arrow reduces the size, instead of increasing it
 556                 // Note that ctrl disables collisions check too, but it's fine
 557                 // since we don't collide with anything reducing the size
 558                 if (hudShiftState & S_CTRL) {
 559                         step = -step;
 560                         resizeCorner = 5 - resizeCorner;
 561                 }
 562
 563                 vector mySize;
 564                 mySize = panel_size;
 565                 panel_click_resizeorigin = panel_pos;
 566                 if(resizeCorner == 1) {
 567                         panel_click_resizeorigin += mySize;
 568                         mySize_y += step;
 569                 } else if(resizeCorner == 2) {
 570                         panel_click_resizeorigin_y += mySize_y;
 571                         mySize_x += step;
 572                 } else if(resizeCorner == 3) {
 573                         panel_click_resizeorigin_x += mySize_x;
 574                         mySize_x += step;
 575                 } else { // resizeCorner == 4
 576                         mySize_y += step;
 577                 }
 578                 HUD_Panel_SetPosSize(mySize);
 579         }
 580         else // move
 581         {
 582                 highlightedAction = 2;
 583                 vector pos;
 584                 pos = panel_pos;
 585                 if(nPrimary == K_UPARROW)
 586                         pos_y -= step;
 587                 else if(nPrimary == K_DOWNARROW)
 588                         pos_y += step;
 589                 else if(nPrimary == K_LEFTARROW)
 590                         pos_x -= step;
 591                 else // if(nPrimary == K_RIGHTARROW)
 592                         pos_x += step;
 593
 594                 HUD_Panel_SetPos(pos);
 595         }
 596
 597         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 598
 599         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 600         {
 601                 // backup!
 602                 panel_pos_backup = highlightedPanel_initial_pos;
 603                 panel_size_backup = highlightedPanel_initial_size;
 604                 highlightedPanel_backup = highlightedPanel;
 605         }
 606 }
 607
 608 const float S_MOUSE1 = 1;
 609 const float S_MOUSE2 = 2;
 610 const float S_MOUSE3 = 4;
 611 float mouseClicked;
 612 float prevMouseClicked; // previous state
 613 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 614 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 615
 616 void HUD_Panel_EnableMenu();
 617 float tab_panels[HUD_PANEL_NUM];
 618 float tab_panel, tab_backward;
 619 vector tab_panel_pos;
 620 void HUD_Panel_FirstInDrawQ(float id);
 621 void reset_tab_panels()
 622 {
 623         int i;
 624         for(i = 0; i < HUD_PANEL_NUM; ++i)
 625                 tab_panels[i] = -1;
 626 }
 627 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 628 {
 629         string s;
 630
 631         // we only care for keyboard events
 632         if(bInputType != 0 && bInputType != 1)
 633                 return false;
 634
 635         if(!autocvar__hud_configure)
 636                 return false;
 637
 638         // allow console bind to work
 639         string con_keys;
 640         float keys;
 641         con_keys = findkeysforcommand("toggleconsole", 0);
 642         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 643
 644         float hit_con_bind, i;
 645         for (i = 0; i < keys; ++i)
 646         {
 647                 if(nPrimary == stof(argv(i)))
 648                         hit_con_bind = 1;
 649         }
 650
 651         if(bInputType == 0) {
 652                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 653                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 654                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 655         }
 656         else if(bInputType == 1) {
 657                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 658                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 659                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 660         }
 661
 662         if(nPrimary == K_CTRL)
 663         {
 664                 if (bInputType == 1) //ctrl has been released
 665                 {
 666                         if (tab_panel != -1)
 667                         {
 668                                 //switch to selected panel
 669                                 highlightedPanel = tab_panel;
 670                                 highlightedAction = 0;
 671                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 672                         }
 673                         tab_panel = -1;
 674                         reset_tab_panels();
 675                 }
 676         }
 677
 678         if(nPrimary == K_MOUSE1)
 679         {
 680                 if(bInputType == 0) // key pressed
 681                         mouseClicked |= S_MOUSE1;
 682                 else if(bInputType == 1) // key released
 683                         mouseClicked -= (mouseClicked & S_MOUSE1);
 684         }
 685         else if(nPrimary == K_MOUSE2)
 686         {
 687                 if(bInputType == 0) // key pressed
 688                         mouseClicked |= S_MOUSE2;
 689                 else if(bInputType == 1) // key released
 690                         mouseClicked -= (mouseClicked & S_MOUSE2);
 691         }
 692         else if(nPrimary == K_ESCAPE)
 693         {
 694                 if (bInputType == 1)
 695                         return true;
 696                 menu_enabled = 1;
 697                 menu_enabled_time = time;
 698                 localcmd("menu_showhudexit\n");
 699         }
 700         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 701         {
 702                 if (bInputType == 1)
 703                         return true;
 704                 if (!menu_enabled)
 705                         cvar_set("_hud_configure", "0");
 706         }
 707         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 708         {
 709                 if (bInputType == 1 || mouseClicked)
 710                         return true;
 711
 712                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 713                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 714                 //(it should only after every other panel of the hud)
 715                 //It's a minor bug anyway, we can live with it
 716
 717                 float starting_panel;
 718                 float old_tab_panel = tab_panel;
 719                 if (tab_panel == -1) //first press of TAB
 720                 {
 721                         if (highlightedPanel != -1)
 722                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 723                         else
 724                                 panel_pos = '0 0 0';
 725                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 726                         tab_panel_pos = panel_pos; //to compute level
 727                 }
 728                 else
 729                 {
 730                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 731                                 reset_tab_panels();
 732                         starting_panel = tab_panel;
 733                 }
 734                 tab_backward = (hudShiftState & S_SHIFT);
 735
 736                 float k, level, start_pos_x;
 737                 vector candidate_pos;
 738                 const float LEVELS_NUM = 4;
 739                 float level_height = vid_conheight / LEVELS_NUM;
 740 :find_tab_panel
 741                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 742                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 743                 start_pos_x = tab_panel_pos_x;
 744                 tab_panel = -1;
 745                 k=0;
 746                 while(++k)
 747                 {
 748                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 749                         {
 750                                 if (i == tab_panels[i] || i == starting_panel)
 751                                         continue;
 752                                 HUD_Panel_UpdatePosSizeForId(i)
 753                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 754                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 755                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 756                                 {
 757                                         tab_panel = i;
 758                                         tab_panel_pos = candidate_pos = panel_pos;
 759                                 }
 760                         }
 761                         if (tab_panel != -1)
 762                                 break;
 763                         if (k == LEVELS_NUM) //tab_panel not found
 764                         {
 765                                 reset_tab_panels();
 766                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 767                                 {
 768                                         tab_panel = -1;
 769                                         return true;
 770                                 }
 771                                 starting_panel = old_tab_panel;
 772                                 old_tab_panel = -2;
 773                                 goto find_tab_panel; //u must find tab_panel!
 774                         }
 775                         if (!tab_backward)
 776                         {
 777                                 level = mod(level + level_height, vid_conheight);
 778                                 start_pos_x = 0;
 779                                 candidate_pos_x = vid_conwidth;
 780                         }
 781                         else
 782                         {
 783                                 level = mod(level - level_height, vid_conheight);
 784                                 start_pos_x = vid_conwidth;
 785                                 candidate_pos_x = 0;
 786                         }
 787                 }
 788
 789                 tab_panels[tab_panel] = tab_panel;
 790         }
 791         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 792         {
 793                 if (bInputType == 1 || mouseClicked)
 794                         return true;
 795
 796                 if (highlightedPanel != -1)
 797                 {
 798                         HUD_Panel_GetName(highlightedPanel);
 799                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 800                 }
 801                 else
 802                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 803         }
 804         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 805         {
 806                 if (bInputType == 1 || mouseClicked)
 807                         return true;
 808
 809                 if (highlightedPanel != -1)
 810                 {
 811                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 812                         panel_size_copied = panel_size;
 813                         highlightedPanel_copied = highlightedPanel;
 814                 }
 815         }
 816         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 817         {
 818                 if (bInputType == 1 || mouseClicked)
 819                         return true;
 820
 821                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 822                         return true;
 823
 824                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 825
 826                 // reduce size if it'd go beyond screen boundaries
 827                 vector tmp_size = panel_size_copied;
 828                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 829                         tmp_size_x = vid_conwidth - panel_pos_x;
 830                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 831                         tmp_size_y = vid_conheight - panel_pos_y;
 832
 833                 if (panel_size == tmp_size)
 834                         return true;
 835
 836                 // backup first!
 837                 panel_pos_backup = panel_pos;
 838                 panel_size_backup = panel_size;
 839                 highlightedPanel_backup = highlightedPanel;
 840
 841                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 842                 HUD_Panel_GetName(highlightedPanel);
 843                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 844         }
 845         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 846         {
 847                 if (bInputType == 1 || mouseClicked)
 848                         return true;
 849                 //restore previous values
 850                 if (highlightedPanel_backup != -1)
 851                 {
 852                         HUD_Panel_GetName(highlightedPanel_backup);
 853                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 854                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 855                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 856                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 857                         highlightedPanel_backup = -1;
 858                 }
 859         }
 860         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 861         {
 862                 if (bInputType == 1)
 863                 {
 864                         pressed_key_time = 0;
 865                         return true;
 866                 }
 867                 else if (pressed_key_time == 0)
 868                         pressed_key_time = time;
 869
 870                 if (!mouseClicked)
 871                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 872         }
 873         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 874         {
 875                 if (bInputType == 1)
 876                         return true;
 877                 if (highlightedPanel != -1)
 878                         HUD_Panel_EnableMenu();
 879         }
 880         else if(hit_con_bind)
 881                 return false;
 882
 883         return true;
 884 }
 885
 886 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 887 {
 888         float i, j, border;
 889
 890         while(j < HUD_PANEL_NUM)
 891         {
 892                 i = panel_order[j];
 893                 j += 1;
 894
 895                 HUD_Panel_UpdatePosSizeForId(i);
 896
 897                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 898
 899                 // move
 900                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 901                 {
 902                         return 1;
 903                 }
 904                 // resize from topleft border
 905                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 906                 {
 907                         return 2;
 908                 }
 909                 // resize from topright border
 910                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 911                 {
 912                         return 3;
 913                 }
 914                 // resize from bottomleft border
 915                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 916                 {
 917                         return 3;
 918                 }
 919                 // resize from bottomright border
 920                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 921                 {
 922                         return 2;
 923                 }
 924         }
 925         return 0;
 926 }
 927
 928 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 929 void HUD_Panel_FirstInDrawQ(float id)
 930 {
 931         float i;
 932         var float place = -1;
 933         // find out where in the array our current id is, save into place
 934         for(i = 0; i < HUD_PANEL_NUM; ++i)
 935         {
 936                 if(panel_order[i] == id)
 937                 {
 938                         place = i;
 939                         break;
 940                 }
 941         }
 942         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 943         if(place == -1)
 944                 place = HUD_PANEL_NUM - 1;
 945
 946         // move all ids up by one step in the array until "place"
 947         for(i = place; i > 0; --i)
 948         {
 949                 panel_order[i] = panel_order[i-1];
 950         }
 951         // now save the new top id
 952         panel_order[0] = id;
 953
 954         // let's save them into the cvar by some strcat trickery
 955         string s;
 956         for(i = 0; i < HUD_PANEL_NUM; ++i)
 957         {
 958                 s = strcat(s, ftos(panel_order[i]), " ");
 959         }
 960         cvar_set("_hud_panelorder", s);
 961         if(hud_panelorder_prev)
 962                 strunzone(hud_panelorder_prev);
 963         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 964 }
 965
 966 void HUD_Panel_Highlight(float allow_move)
 967 {
 968         float i, j, border;
 969
 970         while(j < HUD_PANEL_NUM)
 971         {
 972                 i = panel_order[j];
 973                 j += 1;
 974
 975                 HUD_Panel_UpdatePosSizeForId(i);
 976
 977                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 978
 979                 // move
 980                 if(allow_move && mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 981                 {
 982                         highlightedPanel = i;
 983                         HUD_Panel_FirstInDrawQ(i);
 984                         highlightedAction = 1;
 985                         panel_click_distance = mousepos - panel_pos;
 986                         return;
 987                 }
 988                 // resize from topleft border
 989                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 990                 {
 991                         highlightedPanel = i;
 992                         HUD_Panel_FirstInDrawQ(i);
 993                         highlightedAction = 2;
 994                         resizeCorner = 1;
 995                         panel_click_distance = mousepos - panel_pos;
 996                         panel_click_resizeorigin = panel_pos + panel_size;
 997                         return;
 998                 }
 999                 // resize from topright border
1000                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1001                 {
1002                         highlightedPanel = i;
1003                         HUD_Panel_FirstInDrawQ(i);
1004                         highlightedAction = 2;
1005                         resizeCorner = 2;
1006                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1007                         panel_click_distance_y = mousepos_y - panel_pos_y;
1008                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1009                         return;
1010                 }
1011                 // resize from bottomleft border
1012                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1013                 {
1014                         highlightedPanel = i;
1015                         HUD_Panel_FirstInDrawQ(i);
1016                         highlightedAction = 2;
1017                         resizeCorner = 3;
1018                         panel_click_distance_x = mousepos_x - panel_pos_x;
1019                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1020                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1021                         return;
1022                 }
1023                 // resize from bottomright border
1024                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1025                 {
1026                         highlightedPanel = i;
1027                         HUD_Panel_FirstInDrawQ(i);
1028                         highlightedAction = 2;
1029                         resizeCorner = 4;
1030                         panel_click_distance = panel_size - mousepos + panel_pos;
1031                         panel_click_resizeorigin = panel_pos;
1032                         return;
1033                 }
1034         }
1035         highlightedPanel = -1;
1036         highlightedAction = 0;
1037 }
1038
1039 void HUD_Panel_EnableMenu()
1040 {
1041         menu_enabled = 2;
1042         menu_enabled_time = time;
1043         HUD_Panel_GetName(highlightedPanel);
1044         localcmd("menu_showhudoptions ", panel_name, "\n");
1045 }
1046 float mouse_over_panel;
1047 void HUD_Panel_Mouse()
1048 {
1049         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1050         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1051                 menu_enabled = 0;
1052
1053         /*
1054         print("menu_enabled: ", ftos(menu_enabled), "\n");
1055         print("Highlighted: ", ftos(highlightedPanel), "\n");
1056         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1057         */
1058
1059         // instantly hide the editor cursor if we open the HUDExit dialog
1060         // as hud_fade_alpha doesn't decrease to 0 in this case
1061         // TODO: find a way to fade the cursor out even in this case
1062         if(menu_enabled == 1 || (menu_enabled == 2 && !hud_fade_alpha))
1063                 return;
1064
1065         mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1066
1067         mousepos_x = bound(0, mousepos_x, vid_conwidth);
1068         mousepos_y = bound(0, mousepos_y, vid_conheight);
1069
1070         if(mouseClicked)
1071         {
1072                 if(prevMouseClicked == 0)
1073                 {
1074                         if (tab_panel != -1)
1075                         {
1076                                 //stop ctrl-tab selection
1077                                 tab_panel = -1;
1078                                 reset_tab_panels();
1079                         }
1080                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1081                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1082                         if (highlightedPanel != -1)
1083                         {
1084                                 highlightedPanel_initial_pos = panel_pos;
1085                                 highlightedPanel_initial_size = panel_size;
1086                         }
1087                         // doubleclick check
1088                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1089                         {
1090                                 mouseClicked = 0; // to prevent spam, I guess.
1091                                 HUD_Panel_EnableMenu();
1092                         }
1093                         else
1094                         {
1095                                 if (mouseClicked & S_MOUSE1)
1096                                 {
1097                                         prevMouseClickedTime = time;
1098                                         prevMouseClickedPos = mousepos;
1099                                 }
1100                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1101                         }
1102                 }
1103                 else
1104                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1105
1106                 if (highlightedPanel != -1)
1107                 {
1108                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1109                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1110                         {
1111                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1112                                 // backup!
1113                                 panel_pos_backup = highlightedPanel_initial_pos;
1114                                 panel_size_backup = highlightedPanel_initial_size;
1115                                 highlightedPanel_backup = highlightedPanel;
1116                         }
1117                         else
1118                                 // in case the clicked panel is inside another panel and we aren't
1119                                 // moving it, avoid the immediate "fix" of its position/size
1120                                 // (often unwanted and hateful) by disabling collisions check
1121                                 hud_configure_checkcollisions = false;
1122                 }
1123
1124                 if(highlightedAction == 1)
1125                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1126                 else if(highlightedAction == 2)
1127                 {
1128                         vector mySize;
1129                         if(resizeCorner == 1) {
1130                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1131                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1132                         } else if(resizeCorner == 2) {
1133                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1134                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1135                         } else if(resizeCorner == 3) {
1136                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1137                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1138                         } else { // resizeCorner == 4
1139                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1140                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1141                         }
1142                         HUD_Panel_SetPosSize(mySize);
1143                 }
1144         }
1145         else
1146         {
1147                 if(menu_enabled == 2)
1148                         mouse_over_panel = 0;
1149                 else
1150                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1151                 if (mouse_over_panel && tab_panel == -1)
1152                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1153         }
1154         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1155         const vector cursorsize = '32 32 0';
1156
1157         if(!mouse_over_panel)
1158                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1159         else if(mouse_over_panel == 1)
1160                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1161         else if(mouse_over_panel == 2)
1162                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1163         else
1164                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1165
1166         prevMouseClicked = mouseClicked;
1167 }
1168
1169 const float hlBorderSize = 4;
1170 const string hlBorder = "gfx/hud/default/border_highlighted";
1171 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1172 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1173 {
1174         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1175         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1176         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1177         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1178         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1179 }