qcsrc/client/hud.qc

   1 /*
   2 ==================
   3 Misc HUD functions
   4 ==================
   5 */
   6
   7 // a border picture is a texture containing nine parts:
   8 //   1/4 width: left part
   9 //   1/2 width: middle part (stretched)
  10 //   1/4 width: right part
  11 // divided into
  12 //   1/4 height: top part
  13 //   1/2 height: middle part (stretched)
  14 //   1/4 height: bottom part
  15 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  16 {
  17     if (theBorderSize_x < 0 && theBorderSize_y < 0) // draw whole image as it is
  18     {
  19                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  20                 return;
  21     }
  22         if (theBorderSize_x == 0 && theBorderSize_y == 0) // no border
  23         {
  24                 // draw only the central part
  25                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  26                 return;
  27         }
  28
  29         vector dX, dY;
  30         vector width, height;
  31         vector bW, bH;
  32         //pic = draw_UseSkinFor(pic);
  33         width = eX * theSize_x;
  34         height = eY * theSize_y;
  35         if(theSize_x <= theBorderSize_x * 2)
  36         {
  37                 // not wide enough... draw just left and right then
  38                 bW = eX * (0.25 * theSize_x / (theBorderSize_x * 2));
  39                 if(theSize_y <= theBorderSize_y * 2)
  40                 {
  41                         // not high enough... draw just corners
  42                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  43                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  44                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  45                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  46                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  47                 }
  48                 else
  49                 {
  50                         dY = theBorderSize_x * eY;
  51                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  52                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  53                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  54                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  55                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  56                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  57                 }
  58         }
  59         else
  60         {
  61                 if(theSize_y <= theBorderSize_y * 2)
  62                 {
  63                         // not high enough... draw just top and bottom then
  64                         bH = eY * (0.25 * theSize_y / (theBorderSize_y * 2));
  65                         dX = theBorderSize_x * eX;
  66                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  67                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dX = theBorderSize_x * eX;
  76                         dY = theBorderSize_x * eY;
  77                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
  82                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
  83                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  84                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
  85                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
  86                 }
  87         }
  88 }
  89
  90 vector HUD_Get_Num_Color (float x, float maxvalue)
  91 {
  92         float blinkingamt;
  93         vector color;
  94         if(x >= maxvalue) {
  95                 color_x = sin(2*M_PI*time);
  96                 color_y = 1;
  97                 color_z = sin(2*M_PI*time);
  98         }
  99         else if(x > maxvalue * 0.75) {
 100                 color_x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 101                 color_y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 102                 color_z = 0;
 103         }
 104         else if(x > maxvalue * 0.5) {
 105                 color_x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 106                 color_y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 107                 color_z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 108         }
 109         else if(x > maxvalue * 0.25) {
 110                 color_x = 1;
 111                 color_y = 1;
 112                 color_z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 113         }
 114         else if(x > maxvalue * 0.1) {
 115                 color_x = 1;
 116                 color_y = (x-20)*90/27/100; // green value between 0 -> 1
 117                 color_z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 118         }
 119         else {
 120                 color_x = 1;
 121                 color_y = 0;
 122                 color_z = 0;
 123         }
 124
 125         blinkingamt = (1 - x/maxvalue/0.25);
 126         if(blinkingamt > 0)
 127         {
 128                 color_x = color_x - color_x * blinkingamt * sin(2*M_PI*time);
 129                 color_y = color_y - color_y * blinkingamt * sin(2*M_PI*time);
 130                 color_z = color_z - color_z * blinkingamt * sin(2*M_PI*time);
 131         }
 132         return color;
 133 }
 134
 135 float stringwidth_colors(string s, vector theSize)
 136 {
 137         return stringwidth(s, TRUE, theSize);
 138 }
 139
 140 float stringwidth_nocolors(string s, vector theSize)
 141 {
 142         return stringwidth(s, FALSE, theSize);
 143 }
 144
 145 void drawstringright(vector position, string text, vector scale, vector rgb, float theAlpha, float flag)
 146 {
 147         position_x -= 2 / 3 * strlen(text) * scale_x;
 148         drawstring(position, text, scale, rgb, theAlpha, flag);
 149 }
 150
 151 void drawstringcenter(vector position, string text, vector scale, vector rgb, float theAlpha, float flag)
 152 {
 153         position_x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * scale_x);
 154         drawstring(position, text, scale, rgb, theAlpha, flag);
 155 }
 156
 157 // return the string of the onscreen race timer
 158 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 159 {
 160         string col;
 161         string timestr;
 162         string cpname;
 163         string lapstr;
 164         lapstr = "";
 165
 166         if(histime == 0) // goal hit
 167         {
 168                 if(mytime > 0)
 169                 {
 170                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 171                         col = "^1";
 172                 }
 173                 else if(mytime == 0)
 174                 {
 175                         timestr = "+0.0";
 176                         col = "^3";
 177                 }
 178                 else
 179                 {
 180                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 181                         col = "^2";
 182                 }
 183
 184                 if(lapdelta > 0)
 185                 {
 186                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 187                         col = "^2";
 188                 }
 189                 else if(lapdelta < 0)
 190                 {
 191                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 192                         col = "^1";
 193                 }
 194         }
 195         else if(histime > 0) // anticipation
 196         {
 197                 if(mytime >= histime)
 198                         timestr = strcat("+", ftos_decimals(mytime - histime, TIME_DECIMALS));
 199                 else
 200                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(histime));
 201                 col = "^3";
 202         }
 203         else
 204         {
 205                 col = "^7";
 206                 timestr = "";
 207         }
 208
 209         if(cp == 254)
 210                 cpname = _("Start line");
 211         else if(cp == 255)
 212                 cpname = _("Finish line");
 213         else if(cp)
 214                 cpname = sprintf(_("Intermediate %d"), cp);
 215         else
 216                 cpname = _("Finish line");
 217
 218         if(histime < 0)
 219                 return strcat(col, cpname);
 220         else if(hisname == "")
 221                 return strcat(col, sprintf(_("%s (%s)"), cpname, timestr));
 222         else
 223                 return strcat(col, sprintf(_("%s (%s %s)"), cpname, timestr, strcat(hisname, col, lapstr)));
 224 }
 225
 226 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 227 float race_CheckName(string net_name) {
 228         float i;
 229         for (i=RANKINGS_CNT-1;i>=0;--i)
 230                 if(grecordholder[i] == net_name)
 231                         return i+1;
 232         return 0;
 233 }
 234
 235 float GetPlayerColorForce(float i)
 236 {
 237         if(!teamplay)
 238                 return 0;
 239         else
 240                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 241 }
 242
 243 float GetPlayerColor(float i)
 244 {
 245         if not(playerslots[i].gotscores) // unconnected
 246                 return NUM_SPECTATOR;
 247         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 248                 return NUM_SPECTATOR;
 249         else
 250                 return GetPlayerColorForce(i);
 251 }
 252
 253 string GetPlayerName(float i)
 254 {
 255         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 256 }
 257
 258
 259 /*
 260 ==================
 261 HUD panels
 262 ==================
 263 */
 264
 265 // draw the background/borders
 266 #define HUD_Panel_DrawBg(theAlpha)\
 267 if(panel_bg != "0")\
 268         draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER))
 269
 270 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 271 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, float vertical, float baralign, vector theColor, float theAlpha, float drawflag)
 272 {
 273         if(!length_ratio || !theAlpha)
 274                 return;
 275         if(length_ratio > 1)
 276                 length_ratio = 1;
 277         if (baralign == 3)
 278         {
 279                 if(length_ratio < -1)
 280                         length_ratio = -1;
 281         }
 282         else if(length_ratio < 0)
 283                 return;
 284
 285         vector square;
 286         vector width, height;
 287         if(vertical) {
 288                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 289                 if(precache_pic(pic) == "") {
 290                         pic = "gfx/hud/default/progressbar_vertical";
 291                 }
 292
 293         if (baralign == 1) // bottom align
 294                         theOrigin_y += (1 - length_ratio) * theSize_y;
 295         else if (baralign == 2) // center align
 296             theOrigin_y += 0.5 * (1 - length_ratio) * theSize_y;
 297         else if (baralign == 3) // center align, positive values down, negative up
 298                 {
 299                         theSize_y *= 0.5;
 300                         if (length_ratio > 0)
 301                                 theOrigin_y += theSize_y;
 302                         else
 303                         {
 304                                 theOrigin_y += (1 + length_ratio) * theSize_y;
 305                                 length_ratio = -length_ratio;
 306                         }
 307                 }
 308                 theSize_y *= length_ratio;
 309
 310                 vector bH;
 311                 width = eX * theSize_x;
 312                 height = eY * theSize_y;
 313                 if(theSize_y <= theSize_x * 2)
 314                 {
 315                         // button not high enough
 316                         // draw just upper and lower part then
 317                         square = eY * theSize_y * 0.5;
 318                         bH = eY * (0.25 * theSize_y / (theSize_x * 2));
 319                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 320                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 321                 }
 322                 else
 323                 {
 324                         square = eY * theSize_x;
 325                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 326                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 327                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 328                 }
 329         } else {
 330                 pic = strcat(hud_skin_path, "/", pic);
 331                 if(precache_pic(pic) == "") {
 332                         pic = "gfx/hud/default/progressbar";
 333                 }
 334
 335                 if (baralign == 1) // right align
 336                         theOrigin_x += (1 - length_ratio) * theSize_x;
 337         else if (baralign == 2) // center align
 338             theOrigin_x += 0.5 * (1 - length_ratio) * theSize_x;
 339         else if (baralign == 3) // center align, positive values on the right, negative on the left
 340                 {
 341                         theSize_x *= 0.5;
 342                         if (length_ratio > 0)
 343                                 theOrigin_x += theSize_x;
 344                         else
 345                         {
 346                                 theOrigin_x += (1 + length_ratio) * theSize_x;
 347                                 length_ratio = -length_ratio;
 348                         }
 349                 }
 350                 theSize_x *= length_ratio;
 351
 352                 vector bW;
 353                 width = eX * theSize_x;
 354                 height = eY * theSize_y;
 355                 if(theSize_x <= theSize_y * 2)
 356                 {
 357                         // button not wide enough
 358                         // draw just left and right part then
 359                         square = eX * theSize_x * 0.5;
 360                         bW = eX * (0.25 * theSize_x / (theSize_y * 2));
 361                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 362                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 363                 }
 364                 else
 365                 {
 366                         square = eX * theSize_y;
 367                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 368                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 369                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 370                 }
 371         }
 372 }
 373
 374 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, float drawflag)
 375 {
 376         if(!theAlpha)
 377                 return;
 378
 379         string pic;
 380         pic = strcat(hud_skin_path, "/num_leading");
 381         if(precache_pic(pic) == "") {
 382                 pic = "gfx/hud/default/num_leading";
 383         }
 384
 385         drawsubpic(pos, eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 386         if(mySize_x/mySize_y > 2)
 387                 drawsubpic(pos + eX * mySize_y, eX * (mySize_x - 2 * mySize_y) + eY * mySize_y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 388         drawsubpic(pos + eX * mySize_x - eX * min(mySize_x * 0.5, mySize_y), eX * min(mySize_x * 0.5, mySize_y) + eY * mySize_y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 389 }
 390
 391 // Weapon icons (#0)
 392 //
 393 entity weaponorder[WEP_MAXCOUNT];
 394 void weaponorder_swap(float i, float j, entity pass)
 395 {
 396         entity h;
 397         h = weaponorder[i];
 398         weaponorder[i] = weaponorder[j];
 399         weaponorder[j] = h;
 400 }
 401
 402 string weaponorder_cmp_str;
 403 float weaponorder_cmp(float i, float j, entity pass)
 404 {
 405         float ai, aj;
 406         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 407         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 408         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 409 }
 410
 411 float GetAmmoStat(float i)
 412 {
 413         switch(i)
 414         {
 415                 case 0: return STAT_SHELLS;
 416                 case 1: return STAT_NAILS;
 417                 case 2: return STAT_ROCKETS;
 418                 case 3: return STAT_CELLS;
 419                 case 4: return STAT_FUEL;
 420                 default: return -1;
 421         }
 422 }
 423
 424 float GetAmmoTypeForWep(float i)
 425 {
 426         switch(i)
 427         {
 428                 case WEP_SHOTGUN: return 0;
 429                 case WEP_UZI: return 1;
 430                 case WEP_GRENADE_LAUNCHER: return 2;
 431                 case WEP_MINE_LAYER: return 2;
 432                 case WEP_ELECTRO: return 3;
 433                 case WEP_CRYLINK: return 3;
 434                 case WEP_HLAC: return 3;
 435                 case WEP_MINSTANEX: return 3;
 436                 case WEP_NEX: return 3;
 437                 case WEP_RIFLE: return 1;
 438                 case WEP_HAGAR: return 2;
 439                 case WEP_ROCKET_LAUNCHER: return 2;
 440                 case WEP_SEEKER: return 2;
 441                 case WEP_FIREBALL: return 4;
 442                 case WEP_HOOK: return 3;
 443                 default: return -1;
 444         }
 445 }
 446
 447 void HUD_Weapons(void)
 448 {
 449         // declarations
 450         WEPSET_DECLARE_A(weapons_stat);
 451         WEPSET_COPY_AS(weapons_stat);
 452         float i, f, a;
 453         float screen_ar, center_x = 0, center_y;
 454         float weapon_count, weapon_id;
 455         float row, column, rows = 0, columns;
 456         float aspect = autocvar_hud_panel_weapons_aspect;
 457
 458         float panel_weapon_accuracy;
 459
 460         float timeout = autocvar_hud_panel_weapons_timeout;
 461         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 462         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 463
 464         float ammo_type, ammo_full;
 465         float barsize_x = 0, barsize_y = 0, baroffset_x = 0, baroffset_y = 0;
 466         vector ammo_color = '1 0 1';
 467         float ammo_alpha = 1;
 468
 469         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 470         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 471
 472         vector weapon_pos, weapon_size = '0 0 0';
 473         local noref vector old_panel_size; // fteqcc sucks
 474         vector color;
 475
 476         // check to see if we want to continue
 477         if(hud != HUD_NORMAL) { return; }
 478
 479         if(!autocvar__hud_configure)
 480         {
 481                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 482                         return;
 483                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 484                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 485                 {
 486                         weaponprevtime = time;
 487                         return;
 488                 }
 489         }
 490
 491         // update generic hud functions
 492         HUD_Panel_UpdateCvars();
 493         HUD_Panel_ApplyFadeAlpha();
 494
 495         draw_beginBoldFont();
 496
 497         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 498         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 499         {
 500                 float weapon_cnt;
 501                 if(weaponorder_bypriority)
 502                         strunzone(weaponorder_bypriority);
 503                 if(weaponorder_byimpulse)
 504                         strunzone(weaponorder_byimpulse);
 505
 506                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 507                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 508                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 509
 510                 weapon_cnt = 0;
 511                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 512                 {
 513                         self = get_weaponinfo(i);
 514                         if(self.impulse >= 0)
 515                         {
 516                                 weaponorder[weapon_cnt] = self;
 517                                 ++weapon_cnt;
 518                         }
 519                 }
 520                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 521                         weaponorder[i] = world;
 522                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 523
 524                 weaponorder_cmp_str = string_null;
 525         }
 526
 527         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 528                 complain_weapon = 0;
 529
 530         // determine which weapons are going to be shown
 531         if (autocvar_hud_panel_weapons_onlyowned)
 532         {
 533                 if(autocvar__hud_configure)
 534                 {
 535                         if (WEPSET_EMPTY_A(weapons_stat))
 536                                 for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 537                                         WEPSET_OR_AW(weapons_stat, i);
 538
 539                         if(menu_enabled != 2)
 540                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 541                 }
 542
 543                 // do we own this weapon?
 544                 weapon_count = 0;
 545                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 546                         if(WEPSET_CONTAINS_AW(weapons_stat, weaponorder[i].weapon))
 547                                 ++weapon_count;
 548
 549                 // add it anyway if weaponcomplain is shown
 550                 if(complain_weapon)
 551                         ++weapon_count;
 552
 553                 // might as well commit suicide now, no reason to live ;)
 554                 if (weapon_count == 0)
 555                 {
 556                         draw_endBoldFont();
 557                         return;
 558                 }
 559
 560                 old_panel_size = panel_size;
 561                 if(panel_bg_padding)
 562                         old_panel_size -= '2 2 0' * panel_bg_padding;
 563
 564                 // first find values for the standard table (with all the weapons)
 565                 rows = old_panel_size_y/old_panel_size_x;
 566                 rows = bound(1, floor((sqrt(4 * aspect * rows * WEP_COUNT + rows * rows) + rows + 0.5) / 2), WEP_COUNT);
 567                 columns = ceil(WEP_COUNT/rows);
 568                 weapon_size_x = old_panel_size_x / columns;
 569                 weapon_size_y = old_panel_size_y / rows;
 570
 571                 // change table values to include only the owned weapons
 572                 // weapon_size won't be changed
 573                 if(weapon_count <= rows)
 574                 {
 575                         rows = weapon_count;
 576                         columns = 1;
 577                 }
 578                 else
 579                         columns = ceil(weapon_count / rows);
 580
 581                 // reduce size of the panel
 582                 panel_size_x = columns * weapon_size_x;
 583                 panel_size_y = rows * weapon_size_y;
 584                 panel_pos_x += (old_panel_size_x - panel_size_x) / 2;
 585                 panel_pos_y += (old_panel_size_y - panel_size_y) / 2;
 586                 if(panel_bg_padding)
 587                         panel_size += '2 2 0' * panel_bg_padding;
 588         }
 589         else
 590                 weapon_count = WEP_COUNT;
 591
 592         // animation for fading in/out the panel respectively when not in use
 593         if(!autocvar__hud_configure)
 594         {
 595                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 596                 {
 597                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 598
 599                         // fade the panel alpha
 600                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 601                         {
 602                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 603                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 604                         }
 605                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 606                         {
 607                                 panel_bg_alpha *= (1 - f);
 608                                 panel_fg_alpha *= (1 - f);
 609                         }
 610
 611                         // move the panel off the screen
 612                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 613                         {
 614                                 f *= f; // for a cooler movement
 615                                 center_x = panel_pos_x + panel_size_x/2;
 616                                 center_y = panel_pos_y + panel_size_y/2;
 617                                 screen_ar = vid_conwidth/vid_conheight;
 618                                 if (center_x/center_y < screen_ar) //bottom left
 619                                 {
 620                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 621                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 622                                         else //left
 623                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 624                                 }
 625                                 else //top right
 626                                 {
 627                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 628                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 629                                         else //top
 630                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 631                                 }
 632                                 if(f == 1)
 633                                         center_x = -1; // mark the panel as off screen
 634                         }
 635                         weaponprevtime = time - (1 - f) * timein_effect_length;
 636                 }
 637                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 638                 {
 639                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 640
 641                         // fade the panel alpha
 642                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 643                         {
 644                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 645                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 646                         }
 647                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 648                         {
 649                                 panel_bg_alpha *= (f);
 650                                 panel_fg_alpha *= (f);
 651                         }
 652
 653                         // move the panel back on screen
 654                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 655                         {
 656                                 f *= f; // for a cooler movement
 657                                 f = 1 - f;
 658                                 center_x = panel_pos_x + panel_size_x/2;
 659                                 center_y = panel_pos_y + panel_size_y/2;
 660                                 screen_ar = vid_conwidth/vid_conheight;
 661                                 if (center_x/center_y < screen_ar) //bottom left
 662                                 {
 663                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //bottom
 664                                                 panel_pos_y += f * (vid_conheight - panel_pos_y);
 665                                         else //left
 666                                                 panel_pos_x -= f * (panel_pos_x + panel_size_x);
 667                                 }
 668                                 else //top right
 669                                 {
 670                                         if ((vid_conwidth - center_x)/center_y < screen_ar) //right
 671                                                 panel_pos_x += f * (vid_conwidth - panel_pos_x);
 672                                         else //top
 673                                                 panel_pos_y -= f * (panel_pos_y + panel_size_y);
 674                                 }
 675                         }
 676                 }
 677         }
 678
 679         // draw the background, then change the virtual size of it to better fit other items inside
 680         HUD_Panel_DrawBg(1);
 681
 682         if(center_x == -1)
 683         {
 684                 draw_endBoldFont();
 685                 return;
 686         }
 687
 688         if(panel_bg_padding)
 689         {
 690                 panel_pos += '1 1 0' * panel_bg_padding;
 691                 panel_size -= '2 2 0' * panel_bg_padding;
 692         }
 693
 694         // after the sizing and animations are done, update the other values
 695
 696         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 697         {
 698                 rows = panel_size_y/panel_size_x;
 699                 rows = bound(1, floor((sqrt(4 * aspect * rows * weapon_count + rows * rows) + rows + 0.5) / 2), weapon_count);
 700                 columns = ceil(weapon_count/rows);
 701                 weapon_size = eX * panel_size_x*(1/columns) + eY * panel_size_y*(1/rows);
 702         }
 703
 704         // calculate position/size for visual bar displaying ammount of ammo status
 705         if (autocvar_hud_panel_weapons_ammo)
 706         {
 707                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 708                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 709
 710                 if(weapon_size_x/weapon_size_y > aspect)
 711                 {
 712                         barsize_x = aspect * weapon_size_y;
 713                         barsize_y = weapon_size_y;
 714                         baroffset_x = (weapon_size_x - barsize_x) / 2;
 715                 }
 716                 else
 717                 {
 718                         barsize_y = 1/aspect * weapon_size_x;
 719                         barsize_x = weapon_size_x;
 720                         baroffset_y = (weapon_size_y - barsize_y) / 2;
 721                 }
 722         }
 723         if(autocvar_hud_panel_weapons_accuracy)
 724                 Accuracy_LoadColors();
 725
 726         row = column = 0;
 727         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 728         {
 729                 // retrieve information about the current weapon to be drawn
 730                 self = weaponorder[i];
 731                 weapon_id = self.impulse;
 732
 733                 // skip if this weapon doesn't exist
 734                 if(!self || weapon_id < 0) { continue; }
 735
 736                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 737                 if(autocvar_hud_panel_weapons_onlyowned)
 738                 if not(WEPSET_CONTAINS_AW(weapons_stat, self.weapon) || (self.weapon == complain_weapon))
 739                         continue;
 740
 741                 // figure out the drawing position of weapon
 742                 weapon_pos = (panel_pos
 743                         + eX * column * weapon_size_x
 744                         + eY * row * weapon_size_y);
 745
 746                 // draw background behind currently selected weapon
 747                 if(self.weapon == switchweapon)
 748                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 749
 750                 // draw the weapon accuracy
 751                 if(autocvar_hud_panel_weapons_accuracy)
 752                 {
 753                         panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 754                         if(panel_weapon_accuracy >= 0)
 755                         {
 756                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 757                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 758                         }
 759                 }
 760
 761                 // drawing all the weapon items
 762                 if(WEPSET_CONTAINS_AW(weapons_stat, self.weapon))
 763                 {
 764                         // draw the weapon image
 765                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 766
 767                         // draw weapon label string
 768                         switch(autocvar_hud_panel_weapons_label)
 769                         {
 770                                 case 1: // weapon number
 771                                         drawstring(weapon_pos, ftos(weapon_id), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 772                                         break;
 773
 774                                 case 2: // bind
 775                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 776                                         break;
 777
 778                                 case 3: // weapon name
 779                                         drawstring(weapon_pos, self.netname, '1 1 0' * 0.5 * weapon_size_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 780                                         break;
 781
 782                                 default: // nothing
 783                                         break;
 784                         }
 785
 786                         // draw ammo status bar
 787                         if(autocvar_hud_panel_weapons_ammo && self.weapon != WEP_TUBA && self.weapon != WEP_LASER && self.weapon != WEP_PORTO)
 788                         {
 789                                 a = 0;
 790                                 ammo_type = GetAmmoTypeForWep(self.weapon);
 791                                 if(ammo_type != -1)
 792                                         a = getstati(GetAmmoStat(ammo_type)); // how much ammo do we have?
 793
 794                                 if(a > 0)
 795                                 {
 796                                         switch(ammo_type) {
 797                                                 case 0: ammo_full = autocvar_hud_panel_weapons_ammo_full_shells; break;
 798                                                 case 1: ammo_full = autocvar_hud_panel_weapons_ammo_full_nails; break;
 799                                                 case 2: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 800                                                 case 3: ammo_full = autocvar_hud_panel_weapons_ammo_full_cells; break;
 801                                                 case 4: ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel; break;
 802                                                 default: ammo_full = 60;
 803                                         }
 804
 805                                         drawsetcliparea(
 806                                                 weapon_pos_x + baroffset_x,
 807                                                 weapon_pos_y + baroffset_y,
 808                                                 barsize_x * bound(0, a/ammo_full, 1),
 809                                                 barsize_y);
 810                                         drawpic_aspect_skin(weapon_pos, "weapon_ammo", weapon_size, ammo_color, ammo_alpha, DRAWFLAG_NORMAL);
 811                                         drawresetcliparea();
 812                                 }
 813                         }
 814                 }
 815                 else // draw a "ghost weapon icon" if you don't have the weapon
 816                 {
 817                         drawpic_aspect_skin(weapon_pos, strcat("weapon", self.netname), weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 818                 }
 819
 820                 // draw the complain message
 821                 if(self.weapon == complain_weapon)
 822                 {
 823                         if(fadetime)
 824                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 825                         else
 826                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 827
 828                         string s;
 829                         if(complain_weapon_type == 0) {
 830                                 s = _("Out of ammo");
 831                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 832                         }
 833                         else if(complain_weapon_type == 1) {
 834                                 s = _("Don't have");
 835                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 836                         }
 837                         else {
 838                                 s = _("Unavailable");
 839                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 840                         }
 841                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 842                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 843                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 844                 }
 845
 846                 // continue with new position for the next weapon
 847                 ++row;
 848                 if(row >= rows)
 849                 {
 850                         row = 0;
 851                         ++column;
 852                 }
 853         }
 854
 855         draw_endBoldFont();
 856 }
 857
 858 // Ammo (#1)
 859 //
 860 // TODO: macro
 861 float GetAmmoItemCode(float i)
 862 {
 863         switch(i)
 864         {
 865                 case 0: return IT_SHELLS;
 866                 case 1: return IT_NAILS;
 867                 case 2: return IT_ROCKETS;
 868                 case 3: return IT_CELLS;
 869                 case 4: return IT_FUEL;
 870                 default: return -1;
 871         }
 872 }
 873
 874 string GetAmmoPicture(float i)
 875 {
 876         switch(i)
 877         {
 878                 case 0: return "ammo_shells";
 879                 case 1: return "ammo_bullets";
 880                 case 2: return "ammo_rockets";
 881                 case 3: return "ammo_cells";
 882                 case 4: return "ammo_fuel";
 883                 default: return "";
 884         }
 885 }
 886
 887 void DrawAmmoItem(vector myPos, vector mySize, float itemcode, float currently_selected, float infinite_ammo)
 888 {
 889         float a;
 890         if(autocvar__hud_configure)
 891         {
 892                 currently_selected = (itemcode == 2); //rockets always selected
 893                 a = 31 + mod(itemcode*93, 128);
 894         }
 895         else
 896                 a = getstati(GetAmmoStat(itemcode)); // how much ammo do we have of type itemcode?
 897
 898         vector color;
 899         if(infinite_ammo)
 900                 color = '0 0.5 0.75';
 901         else if(a < 10)
 902                 color = '0.7 0 0';
 903         else
 904                 color = '1 1 1';
 905
 906         float theAlpha;
 907         if(currently_selected)
 908                 theAlpha = 1;
 909         else
 910                 theAlpha = 0.7;
 911
 912         vector picpos, numpos;
 913         if(autocvar_hud_panel_ammo_iconalign)
 914         {
 915                 numpos = myPos;
 916                 picpos = myPos + eX * 2 * mySize_y;
 917         }
 918         else
 919         {
 920                 numpos = myPos + eX * mySize_y;
 921                 picpos = myPos;
 922         }
 923
 924         if (currently_selected)
 925                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 926
 927     if(a > 0 && autocvar_hud_panel_ammo_progressbar)
 928         HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize_x, autocvar_hud_panel_ammo_progressbar_name, a/autocvar_hud_panel_ammo_maxammo, 0, 0, color, autocvar_hud_progressbar_alpha * panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 929
 930     if(autocvar_hud_panel_ammo_text)
 931     {
 932         if(a > 0 || infinite_ammo)
 933             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 934         else // "ghost" ammo count
 935             drawstring_aspect(numpos, ftos(a), eX * (2/3) * mySize_x + eY * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 936     }
 937         if(a > 0 || infinite_ammo)
 938                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
 939         else // "ghost" ammo icon
 940                 drawpic_aspect_skin(picpos, GetAmmoPicture(itemcode), '1 1 0' * mySize_y, '0 0 0', panel_fg_alpha * theAlpha * 0.5, DRAWFLAG_NORMAL);
 941 }
 942
 943 void HUD_Ammo(void)
 944 {
 945         if(hud != HUD_NORMAL) return;
 946         if(!autocvar__hud_configure)
 947         {
 948                 if(!autocvar_hud_panel_ammo) return;
 949                 if(spectatee_status == -1) return;
 950         }
 951
 952         HUD_Panel_UpdateCvars();
 953         HUD_Panel_ApplyFadeAlpha();
 954
 955         draw_beginBoldFont();
 956
 957         vector pos, mySize;
 958         pos = panel_pos;
 959         mySize = panel_size;
 960
 961         HUD_Panel_DrawBg(1);
 962         if(panel_bg_padding)
 963         {
 964                 pos += '1 1 0' * panel_bg_padding;
 965                 mySize -= '2 2 0' * panel_bg_padding;
 966         }
 967
 968         const float AMMO_COUNT = 4;
 969         float rows = 0, columns, row, column;
 970         vector ammo_size;
 971         if (autocvar_hud_panel_ammo_onlycurrent)
 972                 ammo_size = mySize;
 973         else
 974         {
 975                 rows = mySize_y/mySize_x;
 976                 rows = bound(1, floor((sqrt(4 * (3/1) * rows * AMMO_COUNT + rows * rows) + rows + 0.5) / 2), AMMO_COUNT);
 977                 //                               ^^^ ammo item aspect goes here
 978
 979                 columns = ceil(AMMO_COUNT/rows);
 980
 981                 ammo_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
 982         }
 983
 984         local vector offset = '0 0 0'; // fteqcc sucks
 985         float newSize;
 986         if(ammo_size_x/ammo_size_y > 3)
 987         {
 988                 newSize = 3 * ammo_size_y;
 989                 offset_x = ammo_size_x - newSize;
 990                 pos_x += offset_x/2;
 991                 ammo_size_x = newSize;
 992         }
 993         else
 994         {
 995                 newSize = 1/3 * ammo_size_x;
 996                 offset_y = ammo_size_y - newSize;
 997                 pos_y += offset_y/2;
 998                 ammo_size_y = newSize;
 999         }
1000
1001         float i, stat_items, currently_selected, infinite_ammo;
1002         infinite_ammo = FALSE;
1003         if (autocvar_hud_panel_ammo_onlycurrent)
1004         {
1005                 if(autocvar__hud_configure)
1006                 {
1007                         DrawAmmoItem(pos, ammo_size, 2, true, FALSE); //show rockets
1008                 }
1009                 else
1010                 {
1011                         stat_items = getstati(STAT_ITEMS, 0, 24);
1012                         if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1013                                 infinite_ammo = TRUE;
1014                         for (i = 0; i < AMMO_COUNT; ++i) {
1015                                 currently_selected = stat_items & GetAmmoItemCode(i);
1016                                 if (currently_selected)
1017                                 {
1018                                         DrawAmmoItem(pos, ammo_size, i, true, infinite_ammo);
1019                                         break;
1020                                 }
1021                         }
1022                 }
1023         }
1024         else
1025         {
1026                 stat_items = getstati(STAT_ITEMS, 0, 24);
1027                 if (stat_items & IT_UNLIMITED_WEAPON_AMMO)
1028                         infinite_ammo = TRUE;
1029                 row = column = 0;
1030                 for (i = 0; i < AMMO_COUNT; ++i) {
1031                         currently_selected = stat_items & GetAmmoItemCode(i);
1032                         DrawAmmoItem(pos + eX * column * (ammo_size_x + offset_x) + eY * row * (ammo_size_y + offset_y), ammo_size, i, currently_selected, infinite_ammo);
1033                         ++row;
1034                         if(row >= rows)
1035                         {
1036                                 row = 0;
1037                                 column = column + 1;
1038                         }
1039                 }
1040         }
1041
1042         draw_endBoldFont();
1043 }
1044
1045 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha, float fadelerp)
1046 {
1047         vector newPos = '0 0 0', newSize = '0 0 0';
1048         vector picpos, numpos;
1049
1050         if (vertical)
1051         {
1052                 if(mySize_y/mySize_x > 2)
1053                 {
1054                         newSize_y = 2 * mySize_x;
1055                         newSize_x = mySize_x;
1056
1057                         newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1058                         newPos_x = myPos_x;
1059                 }
1060                 else
1061                 {
1062                         newSize_x = 1/2 * mySize_y;
1063                         newSize_y = mySize_y;
1064
1065                         newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1066                         newPos_y = myPos_y;
1067                 }
1068
1069                 if(icon_right_align)
1070                 {
1071                         numpos = newPos;
1072                         picpos = newPos + eY * newSize_x;
1073                 }
1074                 else
1075                 {
1076                         picpos = newPos;
1077                         numpos = newPos + eY * newSize_x;
1078                 }
1079
1080                 newSize_y /= 2;
1081                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1082                 // make number smaller than icon, it looks better
1083                 // reduce only y to draw numbers with different number of digits with the same y size
1084                 numpos_y += newSize_y * ((1 - 0.7) / 2);
1085                 newSize_y *= 0.7;
1086                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1087                 return;
1088         }
1089
1090         if(mySize_x/mySize_y > 3)
1091         {
1092                 newSize_x = 3 * mySize_y;
1093                 newSize_y = mySize_y;
1094
1095                 newPos_x = myPos_x + (mySize_x - newSize_x) / 2;
1096                 newPos_y = myPos_y;
1097         }
1098         else
1099         {
1100                 newSize_y = 1/3 * mySize_x;
1101                 newSize_x = mySize_x;
1102
1103                 newPos_y = myPos_y + (mySize_y - newSize_y) / 2;
1104                 newPos_x = myPos_x;
1105         }
1106
1107         if(icon_right_align) // right align
1108         {
1109                 numpos = newPos;
1110                 picpos = newPos + eX * 2 * newSize_y;
1111         }
1112         else // left align
1113         {
1114                 numpos = newPos + eX * newSize_y;
1115                 picpos = newPos;
1116         }
1117
1118         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1119         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1120         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize_y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1121         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize_y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1122 }
1123
1124 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, float vertical, float icon_right_align, vector color, float theAlpha)
1125 {
1126         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1127 }
1128
1129 // Powerups (#2)
1130 //
1131 void HUD_Powerups(void)
1132 {
1133         float strength_time, shield_time, superweapons_time;
1134         if(!autocvar__hud_configure)
1135         {
1136                 if(!autocvar_hud_panel_powerups) return;
1137                 if(spectatee_status == -1) return;
1138                 if not(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON)) return;
1139                 if (getstati(STAT_HEALTH) <= 0) return;
1140
1141                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1142                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1143                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1144
1145                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1146                         superweapons_time = 99; // force max
1147
1148                 // prevent stuff to show up on mismatch that will be fixed next frame
1149                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1150                         superweapons_time = 0;
1151         }
1152         else
1153         {
1154                 strength_time = 15;
1155                 shield_time = 27;
1156                 superweapons_time = 13;
1157         }
1158
1159         HUD_Panel_UpdateCvars();
1160         HUD_Panel_ApplyFadeAlpha();
1161
1162         draw_beginBoldFont();
1163
1164         vector pos, mySize;
1165         pos = panel_pos;
1166         mySize = panel_size;
1167
1168         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1169         if(panel_bg_padding)
1170         {
1171                 pos += '1 1 0' * panel_bg_padding;
1172                 mySize -= '2 2 0' * panel_bg_padding;
1173         }
1174
1175         float panel_ar = mySize_x/mySize_y;
1176         float is_vertical = (panel_ar < 1);
1177         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1178
1179         float superweapons_is = -1;
1180
1181         if(superweapons_time)
1182         {
1183                 if(strength_time)
1184                 {
1185                         if(shield_time)
1186                                 superweapons_is = 0;
1187                         else
1188                                 superweapons_is = 2;
1189                 }
1190                 else
1191                 {
1192                         if(shield_time)
1193                                 superweapons_is = 1;
1194                         else
1195                                 superweapons_is = 2;
1196                 }
1197         }
1198
1199         // FIXME handle superweapons here
1200         if(superweapons_is == 0)
1201         {
1202                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1203                 {
1204                         mySize_x *= (1.0 / 3.0);
1205                         superweapons_offset_x = mySize_x;
1206                         if (autocvar_hud_panel_powerups_flip)
1207                                 shield_offset_x = 2*mySize_x;
1208                         else
1209                                 strength_offset_x = 2*mySize_x;
1210                 }
1211                 else
1212                 {
1213                         mySize_y *= (1.0 / 3.0);
1214                         superweapons_offset_y = mySize_y;
1215                         if (autocvar_hud_panel_powerups_flip)
1216                                 shield_offset_y = 2*mySize_y;
1217                         else
1218                                 strength_offset_y = 2*mySize_y;
1219                 }
1220         }
1221         else
1222         {
1223                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1224                 {
1225                         mySize_x *= 0.5;
1226                         if (autocvar_hud_panel_powerups_flip)
1227                                 shield_offset_x = mySize_x;
1228                         else
1229                                 strength_offset_x = mySize_x;
1230                 }
1231                 else
1232                 {
1233                         mySize_y *= 0.5;
1234                         if (autocvar_hud_panel_powerups_flip)
1235                                 shield_offset_y = mySize_y;
1236                         else
1237                                 strength_offset_y = mySize_y;
1238                 }
1239         }
1240
1241         float shield_baralign, strength_baralign, superweapons_baralign;
1242         float shield_iconalign, strength_iconalign, superweapons_iconalign;
1243
1244         if (autocvar_hud_panel_powerups_flip)
1245         {
1246                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1247                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1248                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1249                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1250         }
1251         else
1252         {
1253                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1254                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1255                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1256                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1257         }
1258
1259         if(superweapons_is == 0)
1260         {
1261                 superweapons_iconalign = strength_iconalign;
1262                 superweapons_baralign = 2;
1263         }
1264         else if(superweapons_is == 1)
1265         {
1266                 superweapons_offset = strength_offset;
1267                 superweapons_iconalign = strength_iconalign;
1268                 superweapons_baralign = strength_baralign;
1269         }
1270         else // if(superweapons_is == 2)
1271         {
1272                 superweapons_offset = shield_offset;
1273                 superweapons_iconalign = shield_iconalign;
1274                 superweapons_baralign = shield_baralign;
1275         }
1276
1277         if(shield_time)
1278         {
1279                 const float maxshield = 30;
1280                 float shield = ceil(shield_time);
1281                 if(autocvar_hud_panel_powerups_progressbar)
1282                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1283                 if(autocvar_hud_panel_powerups_text)
1284                 {
1285                         if(shield > 1)
1286                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1287                         if(shield <= 5)
1288                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1289                 }
1290         }
1291
1292         if(strength_time)
1293         {
1294                 const float maxstrength = 30;
1295                 float strength = ceil(strength_time);
1296                 if(autocvar_hud_panel_powerups_progressbar)
1297                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1298                 if(autocvar_hud_panel_powerups_text)
1299                 {
1300                         if(strength > 1)
1301                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1302                         if(strength <= 5)
1303                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1304                 }
1305         }
1306
1307         if(superweapons_time)
1308         {
1309                 const float maxsuperweapons = 30;
1310                 float superweapons = ceil(superweapons_time);
1311                 if(autocvar_hud_panel_powerups_progressbar)
1312                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1313                 if(autocvar_hud_panel_powerups_text)
1314                 {
1315                         if(superweapons > 1)
1316                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1317                         if(superweapons <= 5)
1318                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1319                 }
1320         }
1321
1322         draw_endBoldFont();
1323 }
1324
1325 // Health/armor (#3)
1326 //
1327
1328 // prev_* vars contain the health/armor at the previous FRAME
1329 // set to -1 when player is dead or was not playing
1330 float prev_health, prev_armor;
1331 float health_damagetime, armor_damagetime;
1332 float health_beforedamage, armor_beforedamage;
1333 // old_p_* vars keep track of previous values when smoothing value changes of the progressbar
1334 float old_p_health, old_p_armor;
1335 float old_p_healthtime, old_p_armortime;
1336 // prev_p_* vars contain the health/armor progressbar value at the previous FRAME
1337 // set to -1 to forcedly stop effects when we switch spectated player (e.g. from playerX: 70h to playerY: 50h)
1338 float prev_p_health, prev_p_armor;
1339
1340 void HUD_HealthArmor(void)
1341 {
1342         float armor, health, fuel;
1343         if(!autocvar__hud_configure)
1344         {
1345                 if(!autocvar_hud_panel_healtharmor) return;
1346                 if(hud != HUD_NORMAL) return;
1347                 if(spectatee_status == -1) return;
1348
1349                 health = getstati(STAT_HEALTH);
1350                 if(health <= 0)
1351                 {
1352                         prev_health = -1;
1353                         return;
1354                 }
1355                 armor = getstati(STAT_ARMOR);
1356
1357                 // code to check for spectatee_status changes is in Ent_ClientData()
1358                 // prev_p_health and prev_health can be set to -1 there
1359
1360                 if (prev_p_health == -1)
1361                 {
1362                         // no effect
1363                         health_beforedamage = 0;
1364                         armor_beforedamage = 0;
1365                         health_damagetime = 0;
1366                         armor_damagetime = 0;
1367                         prev_health = health;
1368                         prev_armor = armor;
1369                         old_p_health = health;
1370                         old_p_armor = armor;
1371                         prev_p_health = health;
1372                         prev_p_armor = armor;
1373                 }
1374                 else if (prev_health == -1)
1375                 {
1376                         //start the load effect
1377                         health_damagetime = 0;
1378                         armor_damagetime = 0;
1379                         prev_health = 0;
1380                         prev_armor = 0;
1381                 }
1382                 fuel = getstati(STAT_FUEL);
1383         }
1384         else
1385         {
1386                 health = 150;
1387                 armor = 75;
1388                 fuel = 20;
1389         }
1390
1391         HUD_Panel_UpdateCvars();
1392         HUD_Panel_ApplyFadeAlpha();
1393         vector pos, mySize;
1394         pos = panel_pos;
1395         mySize = panel_size;
1396
1397         HUD_Panel_DrawBg(1);
1398         if(panel_bg_padding)
1399         {
1400                 pos += '1 1 0' * panel_bg_padding;
1401                 mySize -= '2 2 0' * panel_bg_padding;
1402         }
1403
1404         float baralign = autocvar_hud_panel_healtharmor_baralign;
1405         float iconalign = autocvar_hud_panel_healtharmor_iconalign;
1406
1407     float maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1408     float maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1409         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1410         {
1411                 vector v;
1412                 v = healtharmor_maxdamage(health, armor, armorblockpercent);
1413
1414                 float x;
1415                 x = floor(v_x + 1);
1416
1417         float maxtotal = maxhealth + maxarmor;
1418                 string biggercount;
1419                 if(v_z) // NOT fully armored
1420                 {
1421                         biggercount = "health";
1422                         if(autocvar_hud_panel_healtharmor_progressbar)
1423                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1424                         if(armor)
1425             if(autocvar_hud_panel_healtharmor_text)
1426                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "armor", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1427                 }
1428                 else
1429                 {
1430                         biggercount = "armor";
1431                         if(autocvar_hud_panel_healtharmor_progressbar)
1432                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1433                         if(health)
1434             if(autocvar_hud_panel_healtharmor_text)
1435                                 drawpic_aspect_skin(pos + eX * mySize_x - eX * 0.5 * mySize_y, "health", '0.5 0.5 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1436                 }
1437         if(autocvar_hud_panel_healtharmor_text)
1438                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1439
1440                 if(fuel)
1441                         HUD_Panel_DrawProgressBar(pos, eX * mySize_x + eY * 0.2 * mySize_y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1442         }
1443         else
1444         {
1445                 float panel_ar = mySize_x/mySize_y;
1446                 float is_vertical = (panel_ar < 1);
1447                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1448                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1449                 {
1450                         mySize_x *= 0.5;
1451                         if (autocvar_hud_panel_healtharmor_flip)
1452                                 health_offset_x = mySize_x;
1453                         else
1454                                 armor_offset_x = mySize_x;
1455                 }
1456                 else
1457                 {
1458                         mySize_y *= 0.5;
1459                         if (autocvar_hud_panel_healtharmor_flip)
1460                                 health_offset_y = mySize_y;
1461                         else
1462                                 armor_offset_y = mySize_y;
1463                 }
1464
1465                 float health_baralign, armor_baralign, fuel_baralign;
1466                 float health_iconalign, armor_iconalign;
1467                 if (autocvar_hud_panel_healtharmor_flip)
1468                 {
1469                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1470                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1471                         fuel_baralign = health_baralign;
1472                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1473                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1474                 }
1475                 else
1476                 {
1477                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1478                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1479                         fuel_baralign = armor_baralign;
1480                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1481                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1482                 }
1483
1484                 //if(health)
1485                 {
1486                         if(autocvar_hud_panel_healtharmor_progressbar)
1487                         {
1488                                 float p_health, pain_health_alpha;
1489                                 p_health = health;
1490                                 pain_health_alpha = 1;
1491                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1492                                 {
1493                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1494                                         {
1495                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1496                                                 {
1497                                                         if (time - old_p_healthtime < 1)
1498                                                                 old_p_health = prev_p_health;
1499                                                         else
1500                                                                 old_p_health = prev_health;
1501                                                         old_p_healthtime = time;
1502                                                 }
1503                                                 if (time - old_p_healthtime < 1)
1504                                                 {
1505                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1506                                                         prev_p_health = p_health;
1507                                                 }
1508                                         }
1509                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1510                                         {
1511                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1512                                                 {
1513                                                         if (time - health_damagetime >= 1)
1514                                                                 health_beforedamage = prev_health;
1515                                                         health_damagetime = time;
1516                                                 }
1517                                                 if (time - health_damagetime < 1)
1518                                                 {
1519                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1520                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1521                                                 }
1522                                         }
1523                                         prev_health = health;
1524
1525                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1526                                         {
1527                                                 float BLINK_FACTOR = 0.15;
1528                                                 float BLINK_BASE = 0.85;
1529                                                 float BLINK_FREQ = 9;
1530                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1531                                         }
1532                                 }
1533                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1534                         }
1535                         if(autocvar_hud_panel_healtharmor_text)
1536                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1537                 }
1538
1539                 if(armor)
1540                 {
1541                         if(autocvar_hud_panel_healtharmor_progressbar)
1542                         {
1543                                 float p_armor;
1544                                 p_armor = armor;
1545                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1546                                 {
1547                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1548                                         {
1549                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1550                                                 {
1551                                                         if (time - old_p_armortime < 1)
1552                                                                 old_p_armor = prev_p_armor;
1553                                                         else
1554                                                                 old_p_armor = prev_armor;
1555                                                         old_p_armortime = time;
1556                                                 }
1557                                                 if (time - old_p_armortime < 1)
1558                                                 {
1559                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1560                                                         prev_p_armor = p_armor;
1561                                                 }
1562                                         }
1563                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1564                                         {
1565                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1566                                                 {
1567                                                         if (time - armor_damagetime >= 1)
1568                                                                 armor_beforedamage = prev_armor;
1569                                                         armor_damagetime = time;
1570                                                 }
1571                                                 if (time - armor_damagetime < 1)
1572                                                 {
1573                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1574                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1575                                                 }
1576                                         }
1577                                         prev_armor = armor;
1578                                 }
1579                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1580                         }
1581                         if(autocvar_hud_panel_healtharmor_text)
1582                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1583                 }
1584
1585                 if(fuel)
1586                 {
1587                         if (is_vertical)
1588                                 mySize_x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1589                         else
1590                                 mySize_y *= 0.2;
1591                         if (panel_ar >= 4)
1592                                 mySize_x *= 2; //restore full panel size
1593                         else if (panel_ar < 1/4)
1594                                 mySize_y *= 2; //restore full panel size
1595                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1596                 }
1597         }
1598 }
1599
1600 // Notification area (#4)
1601 //
1602
1603 void HUD_Notify_Push(string icon, string attacker, string victim)
1604 {
1605         if(icon != "")
1606         {
1607                 --kn_index;
1608                 if (kn_index == -1) { kn_index = KN_MAX_ENTRIES-1; }
1609                 notify_times[kn_index] = time;
1610
1611                 // icon
1612                 if(notify_icon[kn_index]) { strunzone(notify_icon[kn_index]); }
1613                 notify_icon[kn_index] = strzone(icon);
1614
1615                 // attacker
1616                 if(notify_attackers[kn_index]) { strunzone(notify_attackers[kn_index]); }
1617                 notify_attackers[kn_index] = strzone(attacker);
1618
1619                 // victim
1620                 if(notify_victims[kn_index]) { strunzone(notify_victims[kn_index]); }
1621                 notify_victims[kn_index] = strzone(victim);
1622         }
1623 }
1624
1625 void HUD_Notify(void)
1626 {
1627         if(!autocvar__hud_configure)
1628         {
1629                 if(!autocvar_hud_panel_notify) return;
1630         }
1631
1632         HUD_Panel_UpdateCvars();
1633         HUD_Panel_ApplyFadeAlpha();
1634         vector pos, mySize;
1635         pos = panel_pos;
1636         mySize = panel_size;
1637
1638         HUD_Panel_DrawBg(1);
1639         if(panel_bg_padding)
1640         {
1641                 pos += '1 1 0' * panel_bg_padding;
1642                 mySize -= '2 2 0' * panel_bg_padding;
1643         }
1644
1645         float entries, height;
1646         entries = bound(1, floor(KN_MAX_ENTRIES * mySize_y/mySize_x), KN_MAX_ENTRIES);
1647         height = mySize_y/entries;
1648
1649         vector fontsize;
1650         float fontheight = height * autocvar_hud_panel_notify_fontsize;
1651         fontsize = '0.5 0.5 0' * fontheight;
1652
1653         float a;
1654         float when;
1655         when = autocvar_hud_panel_notify_time;
1656         float fadetime;
1657         fadetime = autocvar_hud_panel_notify_fadetime;
1658
1659         vector pos_attacker, pos_victim, pos_icon;
1660         float width_attacker;
1661         string attacker, victim, icon;
1662
1663         float i, j, step, limit;
1664         if(autocvar_hud_panel_notify_flip) //order items from the top down
1665         {
1666                 i = 0;
1667                 step = +1;
1668                 limit = entries;
1669         }
1670         else //order items from the bottom up
1671         {
1672                 i = entries - 1;
1673                 step = -1;
1674                 limit = -1;
1675         }
1676
1677         for(j = kn_index;  i != limit;  i += step, ++j)
1678         {
1679                 if(autocvar__hud_configure)
1680                 {
1681                         if (step == +1)
1682                                 a = i;
1683                         else // inverse order
1684                                 a = entries - 1 - i;
1685                         attacker = textShortenToWidth(sprintf(_("Player %d"), a+1), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1686                         victim = textShortenToWidth(sprintf(_("Player %d"), a+2), 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1687                         icon = strcat("weapon", get_weaponinfo(WEP_FIRST + mod(floor(a*2.4), WEP_LAST)).netname);
1688                         a = bound(0, (when - a) / 4, 1);
1689                         goto hud_config_notifyprint;
1690                 }
1691                 else
1692                 {
1693                         if (j == KN_MAX_ENTRIES)
1694                                 j = 0;
1695
1696                         if(notify_times[j] + when > time)
1697                                 a = 1;
1698                         else if(fadetime)
1699                         {
1700                                 a = bound(0, (notify_times[j] + when + fadetime - time) / fadetime, 1);
1701                                 if(!a)
1702                                 {
1703                                         break;
1704                                 }
1705                         }
1706                         else
1707                         {
1708                                 break;
1709                         }
1710
1711                         attacker = notify_attackers[j];
1712                         victim = notify_victims[j];
1713                         icon = notify_icon[j];
1714                 }
1715
1716                 //type = notify_deathtype[j];
1717                 //w = DEATH_WEAPONOF(type);
1718
1719                 if(icon != "")
1720                 {
1721                         if((attacker != "") && (victim == ""))
1722                         {
1723                                 // Y [used by] X
1724                                 attacker = textShortenToWidth(attacker, 0.73 * mySize_x - height, fontsize, stringwidth_colors);
1725                                 pos_attacker = pos + eX * (0.27 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1726                                 pos_icon = pos + eX * 0.25 * mySize_x - eX * height + eY * i * height;
1727
1728                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1729                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1730                         }
1731                         else if((attacker != "") && (victim != ""))
1732                         {
1733                                 // X [did action to] Y
1734                                 attacker = textShortenToWidth(attacker, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1735                                 victim = textShortenToWidth(victim, 0.48 * mySize_x - height, fontsize, stringwidth_colors);
1736 :hud_config_notifyprint
1737                                 width_attacker = stringwidth(attacker, TRUE, fontsize);
1738                                 pos_attacker = pos + eX * (0.48 * mySize_x - height - width_attacker) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1739                                 pos_victim = pos + eX * (0.52 * mySize_x + height) + eY * ((0.5 * fontsize_y + i * height) + (0.5 * (height - fontheight)));
1740                                 pos_icon = pos + eX * 0.5 * mySize_x - eX * height + eY * i * height;
1741
1742                                 drawpic_aspect_skin(pos_icon, icon, '2 1 0' * height, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
1743                                 drawcolorcodedstring(pos_attacker, attacker, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1744                                 drawcolorcodedstring(pos_victim, victim, fontsize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
1745                         }
1746                 }
1747         }
1748 }
1749
1750 // Timer (#5)
1751 //
1752 // TODO: macro
1753 string seconds_tostring(float sec)
1754 {
1755         float minutes;
1756         minutes = floor(sec / 60);
1757
1758         sec -= minutes * 60;
1759         return sprintf("%d:%02d", minutes, sec);
1760 }
1761
1762 void HUD_Timer(void)
1763 {
1764         if(!autocvar__hud_configure)
1765         {
1766                 if(!autocvar_hud_panel_timer) return;
1767         }
1768
1769         HUD_Panel_UpdateCvars();
1770         HUD_Panel_ApplyFadeAlpha();
1771
1772         draw_beginBoldFont();
1773
1774         vector pos, mySize;
1775         pos = panel_pos;
1776         mySize = panel_size;
1777
1778         HUD_Panel_DrawBg(1);
1779         if(panel_bg_padding)
1780         {
1781                 pos += '1 1 0' * panel_bg_padding;
1782                 mySize -= '2 2 0' * panel_bg_padding;
1783         }
1784
1785         string timer;
1786         float timelimit, elapsedTime, timeleft, minutesLeft;
1787
1788         timelimit = getstatf(STAT_TIMELIMIT);
1789
1790         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1791         timeleft = ceil(timeleft);
1792
1793         minutesLeft = floor(timeleft / 60);
1794
1795         vector timer_color;
1796         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1797                 timer_color = '1 1 1'; //white
1798         else if(minutesLeft >= 1)
1799                 timer_color = '1 1 0'; //yellow
1800         else
1801                 timer_color = '1 0 0'; //red
1802
1803         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1804                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1805                         //while restart is still active, show 00:00
1806                         timer = seconds_tostring(0);
1807                 } else {
1808                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1809                         timer = seconds_tostring(elapsedTime);
1810                 }
1811         } else {
1812                 timer = seconds_tostring(timeleft);
1813         }
1814
1815         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1816
1817         draw_endBoldFont();
1818 }
1819
1820 // Radar (#6)
1821 //
1822 void HUD_Radar(void)
1823 {
1824         if (!autocvar__hud_configure)
1825         {
1826                 if (hud_panel_radar_maximized)
1827                 {
1828                         if (!hud_draw_maximized) return;
1829                 }
1830                 else
1831                 {
1832                         if (autocvar_hud_panel_radar == 0) return;
1833                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1834                 }
1835         }
1836
1837         HUD_Panel_UpdateCvars();
1838         HUD_Panel_ApplyFadeAlpha();
1839
1840         float f = 0;
1841
1842         if (hud_panel_radar_maximized && !autocvar__hud_configure)
1843         {
1844                 panel_size = autocvar_hud_panel_radar_maximized_size;
1845                 panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
1846                 panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
1847                 panel_pos_x = (vid_conwidth - panel_size_x) / 2;
1848                 panel_pos_y = (vid_conheight - panel_size_y) / 2;
1849
1850                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
1851                 if(precache_pic(panel_bg) == "") { panel_bg = "gfx/hud/default/border_default"; } // fallback
1852
1853                 switch(hud_panel_radar_maximized_zoommode)
1854                 {
1855                         default:
1856                         case 0:
1857                                 f = current_zoomfraction;
1858                                 break;
1859                         case 1:
1860                                 f = 1 - current_zoomfraction;
1861                                 break;
1862                         case 2:
1863                                 f = 0;
1864                                 break;
1865                         case 3:
1866                                 f = 1;
1867                                 break;
1868                 }
1869
1870                 switch(hud_panel_radar_maximized_rotation)
1871                 {
1872                         case 0:
1873                                 teamradar_angle = view_angles_y - 90;
1874                                 break;
1875                         default:
1876                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
1877                                 break;
1878                 }
1879         }
1880         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
1881         {
1882                 switch(hud_panel_radar_zoommode)
1883                 {
1884                         default:
1885                         case 0:
1886                                 f = current_zoomfraction;
1887                                 break;
1888                         case 1:
1889                                 f = 1 - current_zoomfraction;
1890                                 break;
1891                         case 2:
1892                                 f = 0;
1893                                 break;
1894                         case 3:
1895                                 f = 1;
1896                                 break;
1897                 }
1898
1899                 switch(hud_panel_radar_rotation)
1900                 {
1901                         case 0:
1902                                 teamradar_angle = view_angles_y - 90;
1903                                 break;
1904                         default:
1905                                 teamradar_angle = 90 * hud_panel_radar_rotation;
1906                                 break;
1907                 }
1908         }
1909
1910         vector pos, mySize;
1911         pos = panel_pos;
1912         mySize = panel_size;
1913
1914         HUD_Panel_DrawBg(1);
1915         if(panel_bg_padding)
1916         {
1917                 pos += '1 1 0' * panel_bg_padding;
1918                 mySize -= '2 2 0' * panel_bg_padding;
1919         }
1920
1921         float color2;
1922         entity tm;
1923         float scale2d, normalsize, bigsize;
1924
1925         teamradar_origin2d = pos + 0.5 * mySize;
1926         teamradar_size2d = mySize;
1927
1928         if(minimapname == "")
1929                 return;
1930
1931         teamradar_loadcvars();
1932
1933         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
1934         teamradar_size2d = mySize;
1935
1936         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
1937
1938         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
1939         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
1940         {
1941                 // max-min distance must fit the radar in any rotation
1942                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
1943         }
1944         else
1945         {
1946                 vector c0, c1, c2, c3, span;
1947                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
1948                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
1949                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
1950                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
1951                 span = '0 0 0';
1952                 span_x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
1953                 span_y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
1954
1955                 // max-min distance must fit the radar in x=x, y=y
1956                 bigsize = min(
1957                         teamradar_size2d_x * scale2d / (1.05 * span_x),
1958                         teamradar_size2d_y * scale2d / (1.05 * span_y)
1959                 );
1960         }
1961
1962         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
1963         if(bigsize > normalsize)
1964                 normalsize = bigsize;
1965
1966         teamradar_size =
1967                   f * bigsize
1968                 + (1 - f) * normalsize;
1969         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
1970                   f * mi_center
1971                 + (1 - f) * view_origin);
1972
1973         drawsetcliparea(
1974                 pos_x,
1975                 pos_y,
1976                 mySize_x,
1977                 mySize_y
1978         );
1979
1980         draw_teamradar_background(hud_panel_radar_foreground_alpha);
1981
1982         for(tm = world; (tm = find(tm, classname, "radarlink")); )
1983                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
1984         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
1985                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
1986         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
1987         {
1988                 color2 = GetPlayerColor(tm.sv_entnum);
1989                 //if(color == NUM_SPECTATOR || color == color2)
1990                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
1991         }
1992         draw_teamradar_player(view_origin, view_angles, '1 1 1');
1993
1994         drawresetcliparea();
1995 }
1996
1997 // Score (#7)
1998 //
1999 void HUD_UpdatePlayerTeams();
2000 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2001 {
2002         float score;
2003         entity tm = world, pl;
2004 #define SCOREPANEL_MAX_ENTRIES 6
2005 #define SCOREPANEL_ASPECTRATIO 2
2006         float entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize_y/mySize_x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2007         vector fontsize = '1 1 0' * (mySize_y/entries);
2008
2009         vector rgb, score_color;
2010         rgb = '1 1 1';
2011         score_color = '1 1 1';
2012
2013         float name_size = mySize_x*0.75;
2014         float spacing_size = mySize_x*0.04;
2015         const float highlight_alpha = 0.2;
2016         float i = 0, me_printed = 0, first_pl = 0;
2017         string s;
2018         if (autocvar__hud_configure)
2019         {
2020                 float players_per_team = 0;
2021                 if (team_count)
2022                 {
2023                         // show team scores in the first line
2024                         float score_size = mySize_x / team_count;
2025                         players_per_team = max(2, ceil((entries - 1) / team_count));
2026                         for(i=0; i<team_count; ++i) {
2027                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2028                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2029                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize_y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2030                         }
2031                         first_pl = 1;
2032                         pos_y += fontsize_y;
2033                 }
2034                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2035                 for (i=first_pl; i<entries; ++i)
2036                 {
2037                         //simulate my score is lower than all displayed players,
2038                         //so that I don't appear at all showing pure rankings.
2039                         //This is to better show the difference between the 2 ranking views
2040                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2041                         {
2042                                 rgb = '1 1 0';
2043                                 drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2044                                 s = GetPlayerName(player_localnum);
2045                                 score = 7;
2046                         }
2047                         else
2048                         {
2049                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2050                                 score -= 3;
2051                         }
2052
2053                         if (team_count)
2054                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2055                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2056                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2057                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2058                         pos_y += fontsize_y;
2059                 }
2060                 return;
2061         }
2062
2063         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2064                 HUD_UpdatePlayerTeams();
2065         if (team_count)
2066         {
2067                 // show team scores in the first line
2068                 float score_size = mySize_x / team_count;
2069                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2070                         if(tm.team == NUM_SPECTATOR)
2071                                 continue;
2072                         if (tm.team == myteam)
2073                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize_y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2074                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2075                         ++i;
2076                 }
2077                 first_pl = 1;
2078                 pos_y += fontsize_y;
2079                 tm = teams.sort_next;
2080         }
2081         i = first_pl;
2082
2083         do
2084         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2085         {
2086                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2087                         continue;
2088
2089                 if (i == entries-1 && !me_printed && pl != me)
2090                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2091                 {
2092                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2093                                 if (pl.team != NUM_SPECTATOR)
2094                                         break;
2095
2096                         if (pl)
2097                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2098                         else
2099                                 rgb = '1 0 0'; //last: red
2100                         pl = me;
2101                 }
2102
2103                 if (pl == me)
2104                 {
2105                         if (i == first_pl)
2106                                 rgb = '0 1 0'; //first: green
2107                         me_printed = 1;
2108                         drawfill(pos, eX * mySize_x + eY * fontsize_y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2109                 }
2110                 if (team_count)
2111                         score_color = Team_ColorRGB(pl.team) * 0.8;
2112                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2113                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, TRUE, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2114                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2115                 pos_y += fontsize_y;
2116                 ++i;
2117         }
2118         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2119 }
2120
2121 void HUD_Score(void)
2122 {
2123         if(!autocvar__hud_configure)
2124         {
2125                 if(!autocvar_hud_panel_score) return;
2126                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2127         }
2128
2129         HUD_Panel_UpdateCvars();
2130         HUD_Panel_ApplyFadeAlpha();
2131         vector pos, mySize;
2132         pos = panel_pos;
2133         mySize = panel_size;
2134
2135         HUD_Panel_DrawBg(1);
2136         if(panel_bg_padding)
2137         {
2138                 pos += '1 1 0' * panel_bg_padding;
2139                 mySize -= '2 2 0' * panel_bg_padding;
2140         }
2141
2142         float score, distribution = 0;
2143         string sign;
2144         vector distribution_color;
2145         entity tm, pl, me;
2146
2147 #ifdef COMPAT_XON050_ENGINE
2148         me = (spectatee_status > 0) ? playerslots[spectatee_status - 1] : playerslots[player_localentnum - 1];
2149 #else
2150         me = playerslots[player_localentnum - 1];
2151 #endif
2152
2153         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2154                 string timer, distrtimer;
2155
2156                 pl = players.sort_next;
2157                 if(pl == me)
2158                         pl = pl.sort_next;
2159                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2160                         if(pl.scores[ps_primary] == 0)
2161                                 pl = world;
2162
2163                 score = me.(scores[ps_primary]);
2164                 timer = TIME_ENCODED_TOSTRING(score);
2165
2166                 draw_beginBoldFont();
2167                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2168                         // distribution display
2169                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2170
2171                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2172
2173                         if (distribution <= 0) {
2174                                 distribution_color = '0 1 0';
2175                                 sign = "-";
2176                         }
2177                         else {
2178                                 distribution_color = '1 0 0';
2179                                 sign = "+";
2180                         }
2181                         drawstring_aspect(pos + eX * 0.75 * mySize_x, strcat(sign, distrtimer), eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2182                 }
2183                 // race record display
2184                 if (distribution <= 0)
2185                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2186                 drawstring_aspect(pos, timer, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2187                 draw_endBoldFont();
2188         } else if (!teamplay) { // non-teamgames
2189                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2190                 {
2191                         HUD_Score_Rankings(pos, mySize, me);
2192                         return;
2193                 }
2194                 // me vector := [team/connected frags id]
2195                 pl = players.sort_next;
2196                 if(pl == me)
2197                         pl = pl.sort_next;
2198
2199                 if(autocvar__hud_configure)
2200                         distribution = 42;
2201                 else if(pl)
2202                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2203                 else
2204                         distribution = 0;
2205
2206                 score = me.(scores[ps_primary]);
2207                 if(autocvar__hud_configure)
2208                         score = 123;
2209
2210                 if(distribution >= 5)
2211                         distribution_color = eY;
2212                 else if(distribution >= 0)
2213                         distribution_color = '1 1 1';
2214                 else if(distribution >= -5)
2215                         distribution_color = '1 1 0';
2216                 else
2217                         distribution_color = eX;
2218
2219                 string distribution_str;
2220                 distribution_str = ftos(distribution);
2221                 draw_beginBoldFont();
2222                 if (distribution >= 0)
2223                 {
2224                         if (distribution > 0)
2225                                 distribution_str = strcat("+", distribution_str);
2226                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2227                 }
2228                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2229                 drawstring_aspect(pos + eX * 0.75 * mySize_x, distribution_str, eX * 0.25 * mySize_x + eY * (1/3) * mySize_y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2230                 draw_endBoldFont();
2231         } else { // teamgames
2232                 float row, column, rows = 0, columns = 0;
2233                 local noref vector offset = '0 0 0';
2234                 vector score_pos, score_size; //for scores other than myteam
2235                 if (spectatee_status == -1 || autocvar_hud_panel_score_rankings)
2236                 {
2237                         if (autocvar_hud_panel_score_rankings)
2238                         {
2239                                 HUD_Score_Rankings(pos, mySize, me);
2240                                 return;
2241                         }
2242                         rows = mySize_y/mySize_x;
2243                         rows = bound(1, floor((sqrt(4 * (3/1) * rows * team_count + rows * rows) + rows + 0.5) / 2), team_count);
2244                         //                               ^^^ ammo item aspect goes here
2245
2246                         columns = ceil(team_count/rows);
2247
2248                         score_size = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2249
2250                         float newSize;
2251                         if(score_size_x/score_size_y > 3)
2252                         {
2253                                 newSize = 3 * score_size_y;
2254                                 offset_x = score_size_x - newSize;
2255                                 pos_x += offset_x/2;
2256                                 score_size_x = newSize;
2257                         }
2258                         else
2259                         {
2260                                 newSize = 1/3 * score_size_x;
2261                                 offset_y = score_size_y - newSize;
2262                                 pos_y += offset_y/2;
2263                                 score_size_y = newSize;
2264                         }
2265                 }
2266                 else
2267                         score_size = eX * mySize_x*(1/4) + eY * mySize_y*(1/3);
2268
2269                 float max_fragcount;
2270                 max_fragcount = -99;
2271                 draw_beginBoldFont();
2272                 row = column = 0;
2273                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2274                         if(tm.team == NUM_SPECTATOR)
2275                                 continue;
2276                         score = tm.(teamscores[ts_primary]);
2277                         if(autocvar__hud_configure)
2278                                 score = 123;
2279
2280                         if (score > max_fragcount)
2281                                 max_fragcount = score;
2282
2283                         if (spectatee_status == -1)
2284                         {
2285                                 score_pos = pos + eX * column * (score_size_x + offset_x) + eY * row * (score_size_y + offset_y);
2286                                 if (max_fragcount == score)
2287                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2288                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2289                                 ++row;
2290                                 if(row >= rows)
2291                                 {
2292                                         row = 0;
2293                                         ++column;
2294                                 }
2295                         }
2296                         else if(tm.team == myteam) {
2297                                 if (max_fragcount == score)
2298                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2299                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize_x + eY * mySize_y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2300                         } else {
2301                                 if (max_fragcount == score)
2302                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2303                                 drawstring_aspect(pos + eX * 0.75 * mySize_x + eY * (1/3) * rows * mySize_y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2304                                 ++rows;
2305                         }
2306                 }
2307                 draw_endBoldFont();
2308         }
2309 }
2310
2311 // Race timer (#8)
2312 //
2313 void HUD_RaceTimer (void)
2314 {
2315         if(!autocvar__hud_configure)
2316         {
2317                 if(!autocvar_hud_panel_racetimer) return;
2318                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2319                 if(spectatee_status == -1) return;
2320         }
2321
2322         HUD_Panel_UpdateCvars();
2323         HUD_Panel_ApplyFadeAlpha();
2324
2325         draw_beginBoldFont();
2326
2327         vector pos, mySize;
2328         pos = panel_pos;
2329         mySize = panel_size;
2330
2331         HUD_Panel_DrawBg(1);
2332         if(panel_bg_padding)
2333         {
2334                 pos += '1 1 0' * panel_bg_padding;
2335                 mySize -= '2 2 0' * panel_bg_padding;
2336         }
2337
2338         // always force 4:1 aspect
2339         vector newSize = '0 0 0';
2340         if(mySize_x/mySize_y > 4)
2341         {
2342                 newSize_x = 4 * mySize_y;
2343                 newSize_y = mySize_y;
2344
2345                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2346         }
2347         else
2348         {
2349                 newSize_y = 1/4 * mySize_x;
2350                 newSize_x = mySize_x;
2351
2352                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2353         }
2354         mySize = newSize;
2355
2356         float a, t;
2357         string s, forcetime;
2358
2359         if(autocvar__hud_configure)
2360         {
2361                 s = "0:13:37";
2362                 drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.60 0.60 0' * mySize_y), s, '0.60 0.60 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2363                 s = _("^1Intermediate 1 (+15.42)");
2364                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.60 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2365                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2366                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.20 * mySize_y) + eY * 0.80 * mySize_y, s, '1 1 0' * 0.20 * mySize_y, panel_fg_alpha, DRAWFLAG_NORMAL);
2367         }
2368         else if(race_checkpointtime)
2369         {
2370                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2371                 s = "";
2372                 forcetime = "";
2373                 if(a > 0) // just hit a checkpoint?
2374                 {
2375                         if(race_checkpoint != 254)
2376                         {
2377                                 if(race_time && race_previousbesttime)
2378                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2379                                 else
2380                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2381                                 if(race_time)
2382                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2383                         }
2384                 }
2385                 else
2386                 {
2387                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2388                         {
2389                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2390                                 if(a > 0) // next one?
2391                                 {
2392                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2393                                 }
2394                         }
2395                 }
2396
2397                 if(s != "" && a > 0)
2398                 {
2399                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2400                 }
2401
2402                 if(race_penaltytime)
2403                 {
2404                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2405                         if(a > 0)
2406                         {
2407                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2408                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.8 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2409                         }
2410                 }
2411
2412                 if(forcetime != "")
2413                 {
2414                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2415                         drawstring_expanding(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(forcetime, FALSE, '1 1 0' * 0.6 * mySize_y), forcetime, '1 1 0' * 0.6 * mySize_y, '1 1 1', panel_fg_alpha, 0, a);
2416                 }
2417                 else
2418                         a = 1;
2419
2420                 if(race_laptime && race_checkpoint != 255)
2421                 {
2422                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2423                         drawstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, FALSE, '0.6 0.6 0' * mySize_y), s, '0.6 0.6 0' * mySize_y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2424                 }
2425         }
2426         else
2427         {
2428                 if(race_mycheckpointtime)
2429                 {
2430                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2431                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2432                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2433                 }
2434                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2435                 {
2436                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2437                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2438                         drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2439                 }
2440
2441                 if(race_penaltytime && !race_penaltyaccumulator)
2442                 {
2443                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2444                         a = bound(0, (1 + t - time), 1);
2445                         if(a > 0)
2446                         {
2447                                 if(time < t)
2448                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2449                                 else
2450                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2451                                 drawcolorcodedstring(pos + eX * 0.5 * mySize_x - '0.5 0 0' * stringwidth(s, TRUE, '1 1 0' * 0.2 * mySize_y) + eY * 0.6 * mySize_y, s, '1 1 0' * 0.2 * mySize_y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2452                         }
2453                 }
2454         }
2455
2456         draw_endBoldFont();
2457 }
2458
2459 // Vote window (#9)
2460 //
2461 float vote_yescount;
2462 float vote_nocount;
2463 float vote_needed;
2464 float vote_highlighted; // currently selected vote
2465
2466 float vote_active; // is there an active vote?
2467 float vote_prev; // previous state of vote_active to check for a change
2468 float vote_alpha;
2469 float vote_change; // "time" when vote_active changed
2470
2471 void HUD_Vote(void)
2472 {
2473         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2474         {
2475                 vote_active = 1;
2476                 if (autocvar__hud_configure)
2477                 {
2478                         vote_yescount = 0;
2479                         vote_nocount = 0;
2480                         print(_("^1You must answer before entering hud configure mode\n"));
2481                         cvar_set("_hud_configure", "0");
2482                 }
2483                 if(vote_called_vote)
2484                         strunzone(vote_called_vote);
2485                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2486                 uid2name_dialog = 1;
2487         }
2488
2489         if(!autocvar__hud_configure)
2490         {
2491                 if(!autocvar_hud_panel_vote) return;
2492
2493                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2494                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2495
2496                 if(panel_bg_alpha_str == "") {
2497                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2498                 }
2499                 panel_bg_alpha = stof(panel_bg_alpha_str);
2500         }
2501         else
2502         {
2503                 vote_yescount = 3;
2504                 vote_nocount = 2;
2505                 vote_needed = 4;
2506         }
2507
2508         string s;
2509         float a;
2510         if(vote_active != vote_prev) {
2511                 vote_change = time;
2512                 vote_prev = vote_active;
2513         }
2514
2515         if(vote_active || autocvar__hud_configure)
2516                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2517         else
2518                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2519
2520         if(!vote_alpha)
2521                 return;
2522
2523         HUD_Panel_UpdateCvars();
2524         HUD_Panel_ApplyFadeAlpha();
2525
2526         if(uid2name_dialog)
2527         {
2528                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2529                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2530         }
2531
2532     // these must be below above block
2533         vector pos, mySize;
2534         pos = panel_pos;
2535         mySize = panel_size;
2536
2537         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2538         HUD_Panel_DrawBg(a);
2539         a = panel_fg_alpha * a;
2540
2541         if(panel_bg_padding)
2542         {
2543                 pos += '1 1 0' * panel_bg_padding;
2544                 mySize -= '2 2 0' * panel_bg_padding;
2545         }
2546
2547         // always force 3:1 aspect
2548         vector newSize = '0 0 0';
2549         if(mySize_x/mySize_y > 3)
2550         {
2551                 newSize_x = 3 * mySize_y;
2552                 newSize_y = mySize_y;
2553
2554                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
2555         }
2556         else
2557         {
2558                 newSize_y = 1/3 * mySize_x;
2559                 newSize_x = mySize_x;
2560
2561                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
2562         }
2563         mySize = newSize;
2564
2565         s = _("A vote has been called for:");
2566         if(uid2name_dialog)
2567                 s = _("Allow servers to store and display your name?");
2568         drawstring_aspect(pos, s, eX * mySize_x + eY * (2/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2569         s = textShortenToWidth(vote_called_vote, mySize_x, '1 1 0' * mySize_y * (1/8), stringwidth_colors);
2570         if(autocvar__hud_configure)
2571                 s = _("^1Configure the HUD");
2572         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize_y, s, eX * mySize_x + eY * (1.75/8) * mySize_y, a, DRAWFLAG_NORMAL);
2573
2574         // print the yes/no counts
2575     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2576         drawstring_aspect(pos + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '0 1 0', a, DRAWFLAG_NORMAL);
2577     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2578         drawstring_aspect(pos + eX * 0.5 * mySize_x + eY * (4/8) * mySize_y, s, eX * 0.5 * mySize_x + eY * (1.5/8) * mySize_y, '1 0 0', a, DRAWFLAG_NORMAL);
2579
2580         // draw the progress bar backgrounds
2581         drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_back", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2582
2583         // draw the highlights
2584         if(vote_highlighted == 1) {
2585                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5, mySize_y);
2586                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2587         }
2588         else if(vote_highlighted == -1) {
2589                 drawsetcliparea(pos_x + 0.5 * mySize_x, pos_y, mySize_x * 0.5, mySize_y);
2590                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_voted", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2591         }
2592
2593         // draw the progress bars
2594         if(vote_yescount && vote_needed)
2595         {
2596                 drawsetcliparea(pos_x, pos_y, mySize_x * 0.5 * (vote_yescount/vote_needed), mySize_y);
2597                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2598         }
2599
2600         if(vote_nocount && vote_needed)
2601         {
2602                 drawsetcliparea(pos_x + mySize_x - mySize_x * 0.5 * (vote_nocount/vote_needed), pos_y, mySize_x * 0.5, mySize_y);
2603                 drawpic_skin(pos + eY * (5/8) * mySize_y, "voteprogress_prog", eX * mySize_x + eY * (3/8) * mySize_y, '1 1 1', a, DRAWFLAG_NORMAL);
2604         }
2605
2606         drawresetcliparea();
2607 }
2608
2609 // Mod icons panel (#10)
2610 //
2611
2612 float mod_active; // is there any active mod icon?
2613
2614 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
2615 {
2616         float stat;
2617         string pic;
2618         vector color;
2619 #ifdef GMQCC
2620         stat = -1;
2621         pic = "";
2622         color = '0 0 0';
2623 #endif
2624         switch(i)
2625         {
2626                 case 0:
2627                         stat = getstati(STAT_REDALIVE);
2628                         pic = "player_red.tga";
2629                         color = '1 0 0';
2630                         break;
2631                 case 1:
2632                         stat = getstati(STAT_BLUEALIVE);
2633                         pic = "player_blue.tga";
2634                         color = '0 0 1';
2635                         break;
2636                 case 2:
2637                         stat = getstati(STAT_YELLOWALIVE);
2638                         pic = "player_yellow.tga";
2639                         color = '1 1 0';
2640                         break;
2641                 default:
2642                 case 3:
2643                         stat = getstati(STAT_PINKALIVE);
2644                         pic = "player_pink.tga";
2645                         color = '1 0 1';
2646                         break;
2647         }
2648
2649         if(mySize_x/mySize_y > aspect_ratio)
2650         {
2651                 i = aspect_ratio * mySize_y;
2652                 myPos_x = myPos_x + (mySize_x - i) / 2;
2653                 mySize_x = i;
2654         }
2655         else
2656         {
2657                 i = 1/aspect_ratio * mySize_x;
2658                 myPos_y = myPos_y + (mySize_y - i) / 2;
2659                 mySize_y = i;
2660         }
2661
2662         if(layout)
2663         {
2664                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2665                 drawstring_aspect(myPos + eX * 0.7 * mySize_x, ftos(stat), eX * 0.3 * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2666         }
2667         else
2668                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2669 }
2670
2671 // Clan Arena and Freeze Tag HUD modicons
2672 void HUD_Mod_CA(vector myPos, vector mySize)
2673 {
2674         mod_active = 1; // required in each mod function that always shows something
2675
2676         float layout;
2677         if(gametype == MAPINFO_TYPE_CA)
2678                 layout = autocvar_hud_panel_modicons_ca_layout;
2679         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2680                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2681         float rows, columns, aspect_ratio;
2682         rows = mySize_y/mySize_x;
2683         aspect_ratio = (layout) ? 2 : 1;
2684         rows = bound(1, floor((sqrt((4 * aspect_ratio * team_count + rows) * rows) + rows + 0.5) / 2), team_count);
2685         columns = ceil(team_count/rows);
2686
2687         int i;
2688         float row = 0, column = 0;
2689         vector pos, itemSize;
2690         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
2691         for(i=0; i<team_count; ++i)
2692         {
2693                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
2694
2695                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2696
2697                 ++row;
2698                 if(row >= rows)
2699                 {
2700                         row = 0;
2701                         ++column;
2702                 }
2703         }
2704 }
2705
2706 // CTF HUD modicon section
2707 float redflag_prevframe, blueflag_prevframe; // status during previous frame
2708 float redflag_prevstatus, blueflag_prevstatus; // last remembered status
2709 float redflag_statuschange_time, blueflag_statuschange_time; // time when the status changed
2710
2711 void HUD_Mod_CTF_Reset(void)
2712 {
2713         redflag_prevstatus = blueflag_prevstatus = redflag_prevframe = blueflag_prevframe = redflag_statuschange_time = blueflag_statuschange_time = 0;
2714 }
2715
2716 void HUD_Mod_CTF(vector pos, vector mySize)
2717 {
2718         vector redflag_pos, blueflag_pos;
2719         vector flag_size;
2720         float f; // every function should have that
2721
2722         float redflag, blueflag; // current status
2723         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime; // time since the status changed
2724         float stat_items;
2725
2726         stat_items = getstati(STAT_ITEMS, 0, 24);
2727         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
2728         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
2729
2730         if(redflag || blueflag)
2731                 mod_active = 1;
2732         else
2733                 mod_active = 0;
2734
2735         if(autocvar__hud_configure)
2736         {
2737                 redflag = 1;
2738                 blueflag = 2;
2739         }
2740
2741         // when status CHANGES, set old status into prevstatus and current status into status
2742         if (redflag != redflag_prevframe)
2743         {
2744                 redflag_statuschange_time = time;
2745                 redflag_prevstatus = redflag_prevframe;
2746                 redflag_prevframe = redflag;
2747         }
2748
2749         if (blueflag != blueflag_prevframe)
2750         {
2751                 blueflag_statuschange_time = time;
2752                 blueflag_prevstatus = blueflag_prevframe;
2753                 blueflag_prevframe = blueflag;
2754         }
2755
2756         redflag_statuschange_elapsedtime = time - redflag_statuschange_time;
2757         blueflag_statuschange_elapsedtime = time - blueflag_statuschange_time;
2758
2759         float BLINK_FACTOR = 0.15;
2760         float BLINK_BASE = 0.85;
2761         // note:
2762         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2763         // thus
2764         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2765         // ensure RMS == 1
2766         float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2767
2768         string red_icon, red_icon_prevstatus;
2769         float red_alpha, red_alpha_prevstatus;
2770         red_alpha = red_alpha_prevstatus = 1;
2771         switch(redflag) {
2772                 case 1: red_icon = "flag_red_taken"; break;
2773                 case 2: red_icon = "flag_red_lost"; break;
2774                 case 3: red_icon = "flag_red_carrying"; red_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2775                 default:
2776                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2777                                 red_icon = "flag_red_shielded";
2778                         else
2779                                 red_icon = string_null;
2780                         break;
2781         }
2782         switch(redflag_prevstatus) {
2783                 case 1: red_icon_prevstatus = "flag_red_taken"; break;
2784                 case 2: red_icon_prevstatus = "flag_red_lost"; break;
2785                 case 3: red_icon_prevstatus = "flag_red_carrying"; red_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2786                 default:
2787                         if(redflag == 3)
2788                                 red_icon_prevstatus = "flag_red_carrying"; // make it more visible
2789                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_2))
2790                                 red_icon_prevstatus = "flag_red_shielded";
2791                         else
2792                                 red_icon_prevstatus = string_null;
2793                         break;
2794         }
2795
2796         string blue_icon, blue_icon_prevstatus;
2797         float blue_alpha, blue_alpha_prevstatus;
2798         blue_alpha = blue_alpha_prevstatus = 1;
2799         switch(blueflag) {
2800                 case 1: blue_icon = "flag_blue_taken"; break;
2801                 case 2: blue_icon = "flag_blue_lost"; break;
2802                 case 3: blue_icon = "flag_blue_carrying"; blue_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2803                 default:
2804                         if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2805                                 blue_icon = "flag_blue_shielded";
2806                         else
2807                                 blue_icon = string_null;
2808                         break;
2809         }
2810         switch(blueflag_prevstatus) {
2811                 case 1: blue_icon_prevstatus = "flag_blue_taken"; break;
2812                 case 2: blue_icon_prevstatus = "flag_blue_lost"; break;
2813                 case 3: blue_icon_prevstatus = "flag_blue_carrying"; blue_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break;
2814                 default:
2815                         if(blueflag == 3)
2816                                 blue_icon_prevstatus = "flag_blue_carrying"; // make it more visible
2817                         else if((stat_items & IT_CTF_SHIELDED) && (myteam == NUM_TEAM_1))
2818                                 blue_icon_prevstatus = "flag_blue_shielded";
2819                         else
2820                                 blue_icon_prevstatus = string_null;
2821                         break;
2822         }
2823
2824         if(mySize_x > mySize_y) {
2825                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2826                         redflag_pos = pos;
2827                         blueflag_pos = pos + eX * 0.5 * mySize_x;
2828                 } else {
2829                         blueflag_pos = pos;
2830                         redflag_pos = pos + eX * 0.5 * mySize_x;
2831                 }
2832                 flag_size = eX * 0.5 * mySize_x + eY * mySize_y;
2833         } else {
2834                 if (myteam == NUM_TEAM_1) { // always draw own flag on left
2835                         redflag_pos = pos;
2836                         blueflag_pos = pos + eY * 0.5 * mySize_y;
2837                 } else {
2838                         blueflag_pos = pos;
2839                         redflag_pos = pos + eY * 0.5 * mySize_y;
2840                 }
2841                 flag_size = eY * 0.5 * mySize_y + eX * mySize_x;
2842         }
2843
2844         f = bound(0, redflag_statuschange_elapsedtime*2, 1);
2845         if(red_icon_prevstatus && f < 1)
2846                 drawpic_aspect_skin_expanding(redflag_pos, red_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * red_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2847         if(red_icon)
2848                 drawpic_aspect_skin(redflag_pos, red_icon, flag_size, '1 1 1', panel_fg_alpha * red_alpha * f, DRAWFLAG_NORMAL);
2849
2850         f = bound(0, blueflag_statuschange_elapsedtime*2, 1);
2851         if(blue_icon_prevstatus && f < 1)
2852                 drawpic_aspect_skin_expanding(blueflag_pos, blue_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * blue_alpha_prevstatus, DRAWFLAG_NORMAL, f);
2853         if(blue_icon)
2854                 drawpic_aspect_skin(blueflag_pos, blue_icon, flag_size, '1 1 1', panel_fg_alpha * blue_alpha * f, DRAWFLAG_NORMAL);
2855 }
2856
2857 // Keyhunt HUD modicon section
2858 float kh_runheretime;
2859
2860 void HUD_Mod_KH_Reset(void)
2861 {
2862         kh_runheretime = 0;
2863 }
2864
2865 void HUD_Mod_KH(vector pos, vector mySize)
2866 {
2867         mod_active = 1; // keyhunt should never hide the mod icons panel
2868         float kh_keys;
2869         float keyteam;
2870         float a, aa;
2871         vector p = '0 0 0', pa, kh_size = '0 0 0', kh_asize = '0 0 0';
2872
2873         kh_keys = getstati(STAT_KH_KEYS);
2874
2875         p_x = pos_x;
2876         if(mySize_x > mySize_y)
2877         {
2878                 p_y = pos_y + 0.25 * mySize_y;
2879                 pa = p - eY * 0.25 * mySize_y;
2880
2881                 kh_size_x = mySize_x * 0.25;
2882                 kh_size_y = 0.75 * mySize_y;
2883                 kh_asize_x = mySize_x * 0.25;
2884                 kh_asize_y = mySize_y * 0.25;
2885         }
2886         else
2887         {
2888                 p_y = pos_y + 0.125 * mySize_y;
2889                 pa = p - eY * 0.125 * mySize_y;
2890
2891                 kh_size_x = mySize_x * 0.5;
2892                 kh_size_y = 0.375 * mySize_y;
2893                 kh_asize_x = mySize_x * 0.5;
2894                 kh_asize_y = mySize_y * 0.125;
2895         }
2896
2897         float i, key;
2898
2899         float keycount;
2900         keycount = 0;
2901         for(i = 0; i < 4; ++i)
2902         {
2903                 key = floor(kh_keys / pow(32, i)) & 31;
2904                 keyteam = key - 1;
2905                 if(keyteam == 30 && keycount <= 4)
2906                         keycount += 4;
2907                 if(keyteam == myteam || keyteam == -1 || keyteam == 30)
2908                         keycount += 1;
2909         }
2910
2911         // this yields 8 exactly if "RUN HERE" shows
2912
2913         if(keycount == 8)
2914         {
2915                 if(!kh_runheretime)
2916                         kh_runheretime = time;
2917                 pa_y -= fabs(sin((time - kh_runheretime) * 3.5)) * 6; // make the arrows jump in case of RUN HERE
2918         }
2919         else
2920                 kh_runheretime = 0;
2921
2922         for(i = 0; i < 4; ++i)
2923         {
2924                 key = floor(kh_keys / pow(32, i)) & 31;
2925                 keyteam = key - 1;
2926                 switch(keyteam)
2927                 {
2928                         case 30: // my key
2929                                 keyteam = myteam;
2930                                 a = 1;
2931                                 aa = 1;
2932                                 break;
2933                         case -1: // no key
2934                                 a = 0;
2935                                 aa = 0;
2936                                 break;
2937                         default: // owned or dropped
2938                                 a = 0.2;
2939                                 aa = 0.5;
2940                                 break;
2941                 }
2942                 a = a * panel_fg_alpha;
2943                 aa = aa * panel_fg_alpha;
2944                 if(a > 0)
2945                 {
2946                         switch(keyteam)
2947                         {
2948                                 case NUM_TEAM_1:
2949                                         drawpic_aspect_skin(pa, "kh_redarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2950                                         break;
2951                                 case NUM_TEAM_2:
2952                                         drawpic_aspect_skin(pa, "kh_bluearrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2953                                         break;
2954                                 case NUM_TEAM_3:
2955                                         drawpic_aspect_skin(pa, "kh_yellowarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2956                                         break;
2957                                 case NUM_TEAM_4:
2958                                         drawpic_aspect_skin(pa, "kh_pinkarrow", kh_asize, '1 1 1', aa, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2959                                         break;
2960                                 default:
2961                                         break;
2962                         }
2963                         switch(i) // YAY! switch(i) inside a for loop for i. DailyWTF, here we come!
2964                         {
2965                                 case 0:
2966                                         drawpic_aspect_skin(p, "kh_red", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2967                                         break;
2968                                 case 1:
2969                                         drawpic_aspect_skin(p, "kh_blue", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2970                                         break;
2971                                 case 2:
2972                                         drawpic_aspect_skin(p, "kh_yellow", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2973                                         break;
2974                                 case 3:
2975                                         drawpic_aspect_skin(p, "kh_pink", kh_size, '1 1 1', a, DRAWFLAG_NORMAL);  // show 30% theAlpha key
2976                                         break;
2977                         }
2978                 }
2979                 if(mySize_x > mySize_y)
2980                 {
2981                         p_x += 0.25 * mySize_x;
2982                         pa_x += 0.25 * mySize_x;
2983                 }
2984                 else
2985                 {
2986                         if(i == 1)
2987                         {
2988                                 p_y = pos_y + 0.625 * mySize_y;
2989                                 pa_y = pos_y + 0.5 * mySize_y;
2990                                 p_x = pos_x;
2991                                 pa_x = pos_x;
2992                         }
2993                         else
2994                         {
2995                                 p_x += 0.5 * mySize_x;
2996                                 pa_x += 0.5 * mySize_x;
2997                         }
2998                 }
2999         }
3000 }
3001
3002 // Keepaway HUD mod icon
3003 float kaball_prevstatus; // last remembered status
3004 float kaball_statuschange_time; // time when the status changed
3005
3006 // we don't need to reset for keepaway since it immediately
3007 // autocorrects prevstatus as to if the player has the ball or not
3008
3009 void HUD_Mod_Keepaway(vector pos, vector mySize)
3010 {
3011         mod_active = 1; // keepaway should always show the mod HUD
3012
3013         float BLINK_FACTOR = 0.15;
3014         float BLINK_BASE = 0.85;
3015         float BLINK_FREQ = 5;
3016         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3017
3018         float stat_items = getstati(STAT_ITEMS, 0, 24);
3019         float kaball = (stat_items/IT_KEY1) & 1;
3020
3021         if(kaball != kaball_prevstatus)
3022         {
3023                 kaball_statuschange_time = time;
3024                 kaball_prevstatus = kaball;
3025         }
3026
3027         vector kaball_pos, kaball_size;
3028
3029         if(mySize_x > mySize_y) {
3030                 kaball_pos = pos + eX * 0.25 * mySize_x;
3031                 kaball_size = eX * 0.5 * mySize_x + eY * mySize_y;
3032         } else {
3033                 kaball_pos = pos + eY * 0.25 * mySize_y;
3034                 kaball_size = eY * 0.5 * mySize_y + eX * mySize_x;
3035         }
3036
3037         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3038         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3039
3040         if(kaball_prevstatus && f < 1)
3041                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3042
3043         if(kaball)
3044                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3045 }
3046
3047
3048 // Nexball HUD mod icon
3049 void HUD_Mod_NexBall(vector pos, vector mySize)
3050 {
3051         float stat_items, nb_pb_starttime, dt, p;
3052
3053         stat_items = getstati(STAT_ITEMS, 0, 24);
3054         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3055
3056         if (stat_items & IT_KEY1)
3057                 mod_active = 1;
3058         else
3059                 mod_active = 0;
3060
3061         //Manage the progress bar if any
3062         if (nb_pb_starttime > 0)
3063         {
3064                 dt = mod(time - nb_pb_starttime, nb_pb_period);
3065                 // one period of positive triangle
3066                 p = 2 * dt / nb_pb_period;
3067                 if (p > 1)
3068                         p = 2 - p;
3069
3070                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize_x <= mySize_y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3071         }
3072
3073         if (stat_items & IT_KEY1)
3074                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize_x + eY * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3075 }
3076
3077 // Race/CTS HUD mod icons
3078 float crecordtime_prev; // last remembered crecordtime
3079 float crecordtime_change_time; // time when crecordtime last changed
3080 float srecordtime_prev; // last remembered srecordtime
3081 float srecordtime_change_time; // time when srecordtime last changed
3082
3083 float race_status_time;
3084 float race_status_prev;
3085 string race_status_name_prev;
3086 void HUD_Mod_Race(vector pos, vector mySize)
3087 {
3088         mod_active = 1; // race should never hide the mod icons panel
3089         entity me;
3090         me = playerslots[player_localnum];
3091         float t, score;
3092         float f; // yet another function has this
3093         score = me.(scores[ps_primary]);
3094
3095         if not((scores_flags[ps_primary] & SFL_TIME) && !teamplay) // race/cts record display on HUD
3096                 return; // no records in the actual race
3097
3098         // clientside personal record
3099         string rr;
3100         if(gametype == MAPINFO_TYPE_CTS)
3101                 rr = CTS_RECORD;
3102         else
3103                 rr = RACE_RECORD;
3104         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3105
3106         if(score && (score < t || !t)) {
3107                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3108                 if(autocvar_cl_autodemo_delete_keeprecords)
3109                 {
3110                         f = autocvar_cl_autodemo_delete;
3111                         f &~= 1;
3112                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3113                 }
3114         }
3115
3116         if(t != crecordtime_prev) {
3117                 crecordtime_prev = t;
3118                 crecordtime_change_time = time;
3119         }
3120
3121         vector textPos, medalPos;
3122         float squareSize;
3123         if(mySize_x > mySize_y) {
3124                 // text on left side
3125                 squareSize = min(mySize_y, mySize_x/2);
3126                 textPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eY * 0.5 * (mySize_y - squareSize);
3127                 medalPos = pos + eX * 0.5 * max(0, mySize_x/2 - squareSize) + eX * 0.5 * mySize_x + eY * 0.5 * (mySize_y - squareSize);
3128         } else {
3129                 // text on top
3130                 squareSize = min(mySize_x, mySize_y/2);
3131                 textPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eX * 0.5 * (mySize_x - squareSize);
3132                 medalPos = pos + eY * 0.5 * max(0, mySize_y/2 - squareSize) + eY * 0.5 * mySize_y + eX * 0.5 * (mySize_x - squareSize);
3133         }
3134
3135         f = time - crecordtime_change_time;
3136
3137         if (f > 1) {
3138                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3139                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3140         } else {
3141                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3142                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3143                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3144                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3145         }
3146
3147         // server record
3148         t = race_server_record;
3149         if(t != srecordtime_prev) {
3150                 srecordtime_prev = t;
3151                 srecordtime_change_time = time;
3152         }
3153         f = time - srecordtime_change_time;
3154
3155         if (f > 1) {
3156                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3157                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3158         } else {
3159                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3160                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3161                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3162                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3163         }
3164
3165         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3166                 race_status_time = time + 5;
3167                 race_status_prev = race_status;
3168                 if (race_status_name_prev)
3169                         strunzone(race_status_name_prev);
3170                 race_status_name_prev = strzone(race_status_name);
3171         }
3172
3173         // race "awards"
3174         float a;
3175         a = bound(0, race_status_time - time, 1);
3176
3177         string s;
3178         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3179
3180         float rank;
3181         if(race_status > 0)
3182                 rank = race_CheckName(race_status_name);
3183         else
3184                 rank = 0;
3185         string rankname;
3186         rankname = count_ordinal(rank);
3187
3188         vector namepos;
3189         namepos = medalPos + '0 0.8 0' * squareSize;
3190         vector rankpos;
3191         rankpos = medalPos + '0 0.15 0' * squareSize;
3192
3193         if(race_status == 0)
3194                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3195         else if(race_status == 1) {
3196                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3197                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3198                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3199         } else if(race_status == 2) {
3200                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3201                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3202                 else
3203                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3204                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3205                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3206         } else if(race_status == 3) {
3207                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3208                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3209                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3210         }
3211
3212         if (race_status_time - time <= 0) {
3213                 race_status_prev = -1;
3214                 race_status = -1;
3215                 if(race_status_name)
3216                         strunzone(race_status_name);
3217                 race_status_name = string_null;
3218                 if(race_status_name_prev)
3219                         strunzone(race_status_name_prev);
3220                 race_status_name_prev = string_null;
3221         }
3222 }
3223
3224 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, float layout, float i)
3225 {
3226         float stat, pps_ratio;
3227         string pic;
3228         vector color;
3229 #ifdef GMQCC
3230         stat = -1;
3231         pic = "";
3232         color = '0 0 0';
3233 #endif
3234         switch(i)
3235         {
3236                 case 0:
3237                         stat = getstatf(STAT_DOM_PPS_RED);
3238                         pic = "dom_icon_red";
3239                         color = '1 0 0';
3240                         break;
3241                 case 1:
3242                         stat = getstatf(STAT_DOM_PPS_BLUE);
3243                         pic = "dom_icon_blue";
3244                         color = '0 0 1';
3245                         break;
3246                 case 2:
3247                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3248                         pic = "dom_icon_yellow";
3249                         color = '1 1 0';
3250                         break;
3251                 default:
3252                 case 3:
3253                         stat = getstatf(STAT_DOM_PPS_PINK);
3254                         pic = "dom_icon_pink";
3255                         color = '1 0 1';
3256                         break;
3257         }
3258         pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3259
3260         if(mySize_x/mySize_y > aspect_ratio)
3261         {
3262                 i = aspect_ratio * mySize_y;
3263                 myPos_x = myPos_x + (mySize_x - i) / 2;
3264                 mySize_x = i;
3265         }
3266         else
3267         {
3268                 i = 1/aspect_ratio * mySize_x;
3269                 myPos_y = myPos_y + (mySize_y - i) / 2;
3270                 mySize_y = i;
3271         }
3272
3273         if (layout) // show text too
3274         {
3275                 //draw the text
3276                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3277                 if (layout == 2) // average pps
3278                         drawstring_aspect(myPos + eX * mySize_y, ftos_decimals(stat, 2), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3279                 else // percentage of average pps
3280                         drawstring_aspect(myPos + eX * mySize_y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3281         }
3282
3283         //draw the icon
3284         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3285         if (stat > 0)
3286         {
3287                 drawsetcliparea(myPos_x, myPos_y + mySize_y * (1 - pps_ratio), mySize_y, mySize_y * pps_ratio);
3288                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3289                 drawresetcliparea();
3290         }
3291 }
3292
3293 void HUD_Mod_Dom(vector myPos, vector mySize)
3294 {
3295         mod_active = 1; // required in each mod function that always shows something
3296
3297         float layout = autocvar_hud_panel_modicons_dom_layout;
3298         float rows, columns, aspect_ratio;
3299         rows = mySize_y/mySize_x;
3300         aspect_ratio = (layout) ? 3 : 1;
3301         rows = bound(1, floor((sqrt((4 * aspect_ratio * team_count + rows) * rows) + rows + 0.5) / 2), team_count);
3302         columns = ceil(team_count/rows);
3303
3304         int i;
3305         float row = 0, column = 0;
3306         vector pos, itemSize;
3307         itemSize = eX * mySize_x*(1/columns) + eY * mySize_y*(1/rows);
3308         for(i=0; i<team_count; ++i)
3309         {
3310                 pos = myPos + eX * column * itemSize_x + eY * row * itemSize_y;
3311
3312                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3313
3314                 ++row;
3315                 if(row >= rows)
3316                 {
3317                         row = 0;
3318                         ++column;
3319                 }
3320         }
3321 }
3322
3323 void HUD_ModIcons_SetFunc()
3324 {
3325         switch(gametype)
3326         {
3327                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3328                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3329                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3330                 case MAPINFO_TYPE_CTS:
3331                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3332                 case MAPINFO_TYPE_CA:
3333                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3334                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3335                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3336         }
3337 }
3338
3339 float mod_prev; // previous state of mod_active to check for a change
3340 float mod_alpha;
3341 float mod_change; // "time" when mod_active changed
3342
3343 void HUD_ModIcons(void)
3344 {
3345         if(!autocvar__hud_configure)
3346         {
3347                 if(!autocvar_hud_panel_modicons) return;
3348                 if(!HUD_ModIcons_GameType) return;
3349         }
3350
3351         HUD_Panel_UpdateCvars();
3352         HUD_Panel_ApplyFadeAlpha();
3353
3354         draw_beginBoldFont();
3355
3356         if(mod_active != mod_prev) {
3357                 mod_change = time;
3358                 mod_prev = mod_active;
3359         }
3360
3361         if(mod_active || autocvar__hud_configure)
3362                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3363         else
3364                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3365
3366         if(mod_alpha)
3367                 HUD_Panel_DrawBg(mod_alpha);
3368
3369         if(panel_bg_padding)
3370         {
3371                 panel_pos += '1 1 0' * panel_bg_padding;
3372                 panel_size -= '2 2 0' * panel_bg_padding;
3373         }
3374
3375         if(autocvar__hud_configure)
3376                 HUD_Mod_CTF(panel_pos, panel_size);
3377         else
3378                 HUD_ModIcons_GameType(panel_pos, panel_size);
3379
3380         draw_endBoldFont();
3381 }
3382
3383 // Draw pressed keys (#11)
3384 //
3385 void HUD_PressedKeys(void)
3386 {
3387         if(!autocvar__hud_configure)
3388         {
3389                 if(!autocvar_hud_panel_pressedkeys) return;
3390                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3391         }
3392
3393         HUD_Panel_UpdateCvars();
3394         HUD_Panel_ApplyFadeAlpha();
3395         vector pos, mySize;
3396         pos = panel_pos;
3397         mySize = panel_size;
3398
3399         HUD_Panel_DrawBg(1);
3400         if(panel_bg_padding)
3401         {
3402                 pos += '1 1 0' * panel_bg_padding;
3403                 mySize -= '2 2 0' * panel_bg_padding;
3404         }
3405
3406         // force custom aspect
3407         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3408         if(aspect)
3409         {
3410                 vector newSize = '0 0 0';
3411                 if(mySize_x/mySize_y > aspect)
3412                 {
3413                         newSize_x = aspect * mySize_y;
3414                         newSize_y = mySize_y;
3415
3416                         pos_x = pos_x + (mySize_x - newSize_x) / 2;
3417                 }
3418                 else
3419                 {
3420                         newSize_y = 1/aspect * mySize_x;
3421                         newSize_x = mySize_x;
3422
3423                         pos_y = pos_y + (mySize_y - newSize_y) / 2;
3424                 }
3425                 mySize = newSize;
3426         }
3427
3428         vector keysize;
3429         keysize = eX * mySize_x * (1/3.0) + eY * mySize_y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3430         float pressedkeys;
3431         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3432
3433         if(autocvar_hud_panel_pressedkeys_attack)
3434         {
3435                 drawpic_aspect_skin(pos + eX * keysize_x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3436                 drawpic_aspect_skin(pos + eX * keysize_x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3437                 pos_y += keysize_y;
3438         }
3439
3440         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3441         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3442         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3443         pos_y += keysize_y;
3444         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3445         drawpic_aspect_skin(pos + eX * keysize_x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3446         drawpic_aspect_skin(pos + eX * keysize_x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3447 }
3448
3449 // Handle chat as a panel (#12)
3450 //
3451 void HUD_Chat(void)
3452 {
3453         if(!autocvar__hud_configure)
3454         {
3455                 if (!autocvar_hud_panel_chat)
3456                 {
3457                         if (!autocvar_con_chatrect)
3458                                 cvar_set("con_chatrect", "0");
3459                         return;
3460                 }
3461                 if(autocvar__con_chat_maximized)
3462                         if(!hud_draw_maximized) return;
3463         }
3464
3465         HUD_Panel_UpdateCvars();
3466         HUD_Panel_ApplyFadeAlpha();
3467
3468         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3469         {
3470                 panel_pos_y = panel_bg_border;
3471                 panel_size_y = vid_conheight - panel_bg_border * 2;
3472                 if(panel_bg == "0") // force a border when maximized
3473                 {
3474                         if(precache_pic(panel_bg) == "") {
3475                                 panel_bg = strcat(hud_skin_path, "/border_default");
3476                                 if(precache_pic(panel_bg) == "") {
3477                                         panel_bg = "gfx/hud/default/border_default";
3478                                 }
3479                         }
3480                 }
3481                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3482         }
3483
3484         vector pos, mySize;
3485         pos = panel_pos;
3486         mySize = panel_size;
3487
3488         HUD_Panel_DrawBg(1);
3489
3490         if(panel_bg_padding)
3491         {
3492                 pos += '1 1 0' * panel_bg_padding;
3493                 mySize -= '2 2 0' * panel_bg_padding;
3494         }
3495
3496         if (!autocvar_con_chatrect)
3497                 cvar_set("con_chatrect", "1");
3498
3499         cvar_set("con_chatrect_x", ftos(pos_x/vid_conwidth));
3500         cvar_set("con_chatrect_y", ftos(pos_y/vid_conheight));
3501
3502         cvar_set("con_chatwidth", ftos(mySize_x/vid_conwidth));
3503         cvar_set("con_chat", ftos(floor(mySize_y/autocvar_con_chatsize - 0.5)));
3504
3505         if(autocvar__hud_configure)
3506         {
3507                 vector chatsize;
3508                 chatsize = '1 1 0' * autocvar_con_chatsize;
3509                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3510                 float i, a;
3511                 for(i = 0; i < autocvar_con_chat; ++i)
3512                 {
3513                         if(i == autocvar_con_chat - 1)
3514                                 a = panel_fg_alpha;
3515                         else
3516                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3517                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize_x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3518                         pos_y += chatsize_y;
3519                 }
3520         }
3521 }
3522
3523 // Engine info panel (#13)
3524 //
3525 float prevfps;
3526 float prevfps_time;
3527 float framecounter;
3528
3529 float frametimeavg;
3530 float frametimeavg1; // 1 frame ago
3531 float frametimeavg2; // 2 frames ago
3532 void HUD_EngineInfo(void)
3533 {
3534         if(!autocvar__hud_configure)
3535         {
3536                 if(!autocvar_hud_panel_engineinfo) return;
3537         }
3538
3539         HUD_Panel_UpdateCvars();
3540         HUD_Panel_ApplyFadeAlpha();
3541         vector pos, mySize;
3542         pos = panel_pos;
3543         mySize = panel_size;
3544
3545         HUD_Panel_DrawBg(1);
3546         if(panel_bg_padding)
3547         {
3548                 pos += '1 1 0' * panel_bg_padding;
3549                 mySize -= '2 2 0' * panel_bg_padding;
3550         }
3551
3552         float currentTime = gettime(GETTIME_REALTIME);
3553         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3554         {
3555                 float currentframetime = currentTime - prevfps_time;
3556                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3557                 frametimeavg2 = frametimeavg1;
3558                 frametimeavg1 = frametimeavg;
3559
3560                 float weight;
3561                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3562                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3563                 {
3564                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3565                                 prevfps = (1/currentframetime);
3566                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3567                 }
3568                 prevfps_time = currentTime;
3569         }
3570         else
3571         {
3572                 framecounter += 1;
3573                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3574                 {
3575                         prevfps = framecounter/(currentTime - prevfps_time);
3576                         framecounter = 0;
3577                         prevfps_time = currentTime;
3578                 }
3579         }
3580
3581         vector color;
3582         color = HUD_Get_Num_Color (prevfps, 100);
3583         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3584 }
3585
3586 // Info messages panel (#14)
3587 //
3588 #define drawInfoMessage(s)\
3589         if(autocvar_hud_panel_infomessages_flip)\
3590                 o_x = pos_x + mySize_x - stringwidth(s, TRUE, fontsize);\
3591         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);\
3592         o_y += fontsize_y;
3593 void HUD_InfoMessages(void)
3594 {
3595         if(!autocvar__hud_configure)
3596         {
3597                 if(!autocvar_hud_panel_infomessages) return;
3598         }
3599
3600         HUD_Panel_UpdateCvars();
3601         HUD_Panel_ApplyFadeAlpha();
3602         vector pos, mySize;
3603         pos = panel_pos;
3604         mySize = panel_size;
3605
3606         HUD_Panel_DrawBg(1);
3607         if(panel_bg_padding)
3608         {
3609                 pos += '1 1 0' * panel_bg_padding;
3610                 mySize -= '2 2 0' * panel_bg_padding;
3611         }
3612
3613         // always force 5:1 aspect
3614         vector newSize = '0 0 0';
3615         if(mySize_x/mySize_y > 5)
3616         {
3617                 newSize_x = 5 * mySize_y;
3618                 newSize_y = mySize_y;
3619
3620                 pos_x = pos_x + (mySize_x - newSize_x) / 2;
3621         }
3622         else
3623         {
3624                 newSize_y = 1/5 * mySize_x;
3625                 newSize_x = mySize_x;
3626
3627                 pos_y = pos_y + (mySize_y - newSize_y) / 2;
3628         }
3629
3630         mySize = newSize;
3631         entity tm;
3632         vector o;
3633         o = pos;
3634
3635         vector fontsize;
3636         fontsize = '0.20 0.20 0' * mySize_y;
3637
3638         float a;
3639         a = panel_fg_alpha;
3640
3641         string s;
3642         if(!autocvar__hud_configure)
3643         {
3644                 if(spectatee_status && !intermission)
3645                 {
3646                         a = 1;
3647                         if(spectatee_status == -1)
3648                                 s = _("^1Observing");
3649                         else
3650 #ifdef COMPAT_XON050_ENGINE
3651                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(spectatee_status - 1));
3652 #else
3653                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(player_localentnum - 1));
3654 #endif
3655                         drawInfoMessage(s)
3656
3657                         if(spectatee_status == -1)
3658                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3659                         else
3660                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3661                         drawInfoMessage(s)
3662
3663                         if(spectatee_status == -1)
3664                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3665                         else
3666                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3667                         drawInfoMessage(s)
3668
3669                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3670                         drawInfoMessage(s)
3671
3672                         if(gametype == MAPINFO_TYPE_ARENA)
3673                                 s = _("^1Wait for your turn to join");
3674                         else if(gametype == MAPINFO_TYPE_LMS)
3675                         {
3676                                 entity sk;
3677                                 sk = playerslots[player_localnum];
3678                                 if(sk.(scores[ps_primary]) >= 666)
3679                                         s = _("^1Match has already begun");
3680                                 else if(sk.(scores[ps_primary]) > 0)
3681                                         s = _("^1You have no more lives left");
3682                                 else
3683                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3684                         }
3685                         else
3686                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3687                         drawInfoMessage(s)
3688
3689                         //show restart countdown:
3690                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3691                                 float countdown;
3692                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3693                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3694                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3695                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3696                                 o_y += fontsize_y;
3697                         }
3698                 }
3699                 if(warmup_stage && !intermission)
3700                 {
3701                         s = _("^2Currently in ^1warmup^2 stage!");
3702                         drawInfoMessage(s)
3703                 }
3704
3705                 string blinkcolor;
3706                 if(mod(time, 1) >= 0.5)
3707                         blinkcolor = "^1";
3708                 else
3709                         blinkcolor = "^3";
3710
3711                 if(ready_waiting && !intermission && !spectatee_status)
3712                 {
3713                         if(ready_waiting_for_me)
3714                         {
3715                                 if(warmup_stage)
3716                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3717                                 else
3718                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3719                         }
3720                         else
3721                         {
3722                                 if(warmup_stage)
3723                                         s = _("^2Waiting for others to ready up to end warmup...");
3724                                 else
3725                                         s = _("^2Waiting for others to ready up...");
3726                         }
3727                         drawInfoMessage(s)
3728                 }
3729                 else if(warmup_stage && !intermission && !spectatee_status)
3730                 {
3731                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3732                         drawInfoMessage(s)
3733                 }
3734
3735                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3736                 {
3737                         float ts_min = 0, ts_max = 0;
3738                         tm = teams.sort_next;
3739                         if (tm)
3740                         {
3741                                 for(; tm.sort_next; tm = tm.sort_next)
3742                                 {
3743                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3744                                                 continue;
3745                                         if(!ts_min) ts_min = tm.team_size;
3746                                         else ts_min = min(ts_min, tm.team_size);
3747                                         if(!ts_max) ts_max = tm.team_size;
3748                                         else ts_max = max(ts_max, tm.team_size);
3749                                 }
3750                                 if ((ts_max - ts_min) > 1)
3751                                 {
3752                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3753                                         tm = GetTeam(myteam, false);
3754                                         if (tm)
3755                                         if (tm.team != NUM_SPECTATOR)
3756                                         if (tm.team_size == ts_max)
3757                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3758                                         drawInfoMessage(s)
3759                                 }
3760                         }
3761                 }
3762         }
3763         else
3764         {
3765                 s = _("^7Press ^3ESC ^7to show HUD options.");
3766                 drawInfoMessage(s)
3767                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3768                 drawInfoMessage(s)
3769                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3770                 drawInfoMessage(s)
3771                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3772                 drawInfoMessage(s)
3773         }
3774 }
3775
3776 // Physics panel (#15)
3777 //
3778 vector acc_prevspeed;
3779 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3780 void HUD_Physics(void)
3781 {
3782         if(!autocvar__hud_configure)
3783         {
3784                 if(!autocvar_hud_panel_physics) return;
3785                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3786                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3787         }
3788
3789         HUD_Panel_UpdateCvars();
3790         HUD_Panel_ApplyFadeAlpha();
3791
3792         draw_beginBoldFont();
3793
3794         HUD_Panel_DrawBg(1);
3795         if(panel_bg_padding)
3796         {
3797                 panel_pos += '1 1 0' * panel_bg_padding;
3798                 panel_size -= '2 2 0' * panel_bg_padding;
3799         }
3800
3801         float acceleration_progressbar_scale = 0;
3802         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3803                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3804
3805         float text_scale;
3806         if (autocvar_hud_panel_physics_text_scale <= 0)
3807                 text_scale = 1;
3808         else
3809                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3810
3811         //compute speed
3812         float speed, conversion_factor;
3813         string unit;
3814
3815         switch(autocvar_hud_panel_physics_speed_unit)
3816         {
3817                 default:
3818                 case 1:
3819                         unit = _(" qu/s");
3820                         conversion_factor = 1.0;
3821                         break;
3822                 case 2:
3823                         unit = _(" m/s");
3824                         conversion_factor = 0.0254;
3825                         break;
3826                 case 3:
3827                         unit = _(" km/h");
3828                         conversion_factor = 0.0254 * 3.6;
3829                         break;
3830                 case 4:
3831                         unit = _(" mph");
3832                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3833                         break;
3834                 case 5:
3835                         unit = _(" knots");
3836                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3837                         break;
3838         }
3839
3840         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
3841
3842         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
3843         if (autocvar__hud_configure)
3844                 speed = floor( max_speed * 0.65 + 0.5 );
3845         else if(autocvar_hud_panel_physics_speed_vertical)
3846                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
3847         else
3848                 speed = floor( vlen(vel - vel_z * '0 0 1') * conversion_factor + 0.5 );
3849
3850         //compute acceleration
3851         float acceleration, f;
3852         if (autocvar__hud_configure)
3853                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
3854         else
3855         {
3856                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
3857                 f = time - acc_prevtime;
3858                 if(autocvar_hud_panel_physics_acceleration_vertical)
3859                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
3860                 else
3861                         acceleration = (vlen(vel - '0 0 1' * vel_z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed_z));
3862
3863                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
3864
3865                 acc_prevspeed = vel;
3866                 acc_prevtime = time;
3867
3868                 f = bound(0, f * 10, 1);
3869                 acc_avg = acc_avg * (1 - f) + acceleration * f;
3870         }
3871
3872         //compute layout
3873         float panel_ar = panel_size_x/panel_size_y;
3874         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
3875         if (panel_ar >= 5 && !acceleration_progressbar_scale)
3876         {
3877                 panel_size_x *= 0.5;
3878                 if (autocvar_hud_panel_physics_flip)
3879                         speed_offset_x = panel_size_x;
3880                 else
3881                         acceleration_offset_x = panel_size_x;
3882         }
3883         else
3884         {
3885                 panel_size_y *= 0.5;
3886                 if (autocvar_hud_panel_physics_flip)
3887                         speed_offset_y = panel_size_y;
3888                 else
3889                         acceleration_offset_y = panel_size_y;
3890         }
3891         float speed_baralign, acceleration_baralign;
3892         if (autocvar_hud_panel_physics_baralign == 1)
3893                 acceleration_baralign = speed_baralign = 1;
3894     else if(autocvar_hud_panel_physics_baralign == 4)
3895                 acceleration_baralign = speed_baralign = 2;
3896         else if (autocvar_hud_panel_physics_flip)
3897         {
3898                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
3899                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
3900         }
3901         else
3902         {
3903                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
3904                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
3905         }
3906         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
3907                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
3908
3909         //draw speed
3910         if(speed)
3911         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3912                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3913         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
3914         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3915         {
3916                 tmp_size_x = panel_size_x * 0.75;
3917                 tmp_size_y = panel_size_y * text_scale;
3918                 if (speed_baralign)
3919                         tmp_offset_x = panel_size_x - tmp_size_x;
3920                 //else
3921                         //tmp_offset_x = 0;
3922                 tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
3923                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3924
3925                 //draw speed unit
3926                 if (speed_baralign)
3927                         tmp_offset_x = 0;
3928                 else
3929                         tmp_offset_x = tmp_size_x;
3930                 if (autocvar_hud_panel_physics_speed_unit_show)
3931                 {
3932                         //tmp_offset_y = 0;
3933                         tmp_size_x = panel_size_x * (1 - 0.75);
3934                         tmp_size_y = panel_size_y * 0.4 * text_scale;
3935                         tmp_offset_y = (panel_size_y * 0.4 - tmp_size_y) / 2;
3936                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3937                 }
3938         }
3939
3940         //compute and draw top speed
3941         if (autocvar_hud_panel_physics_topspeed)
3942         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
3943         {
3944                 if (autocvar__hud_configure)
3945                 {
3946                         top_speed = floor( max_speed * 0.75 + 0.5 );
3947                         f = 1;
3948                 }
3949                 else
3950                 {
3951                         if (speed >= top_speed)
3952                         {
3953                                 top_speed = speed;
3954                                 top_speed_time = time;
3955                         }
3956                         if (top_speed != 0)
3957                         {
3958                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
3959                                 // divide by f to make it start from 1
3960                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
3961                         }
3962             else //hide top speed 0, it would be stupid
3963                                 f = 0;
3964                 }
3965                 if (f > 0)
3966                 {
3967                         //top speed progressbar peak
3968                         if(speed < top_speed)
3969                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
3970                         {
3971                                 float peak_offset_x;
3972                                 vector peak_size = '0 0 0';
3973                                 if (speed_baralign == 0)
3974                                         peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x;
3975                 else if (speed_baralign == 1)
3976                                         peak_offset_x = (1 - min(top_speed, max_speed)/max_speed) * panel_size_x;
3977                 else // if (speed_baralign == 2)
3978                     peak_offset_x = min(top_speed, max_speed)/max_speed * panel_size_x * 0.5;
3979                                 peak_size_x = floor(panel_size_x * 0.01 + 1.5);
3980                 peak_size_y = panel_size_y;
3981                 if (speed_baralign == 2) // draw two peaks, on both sides
3982                 {
3983                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x + peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3984                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size_x - peak_offset_x + peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3985                 }
3986                 else
3987                     drawfill(panel_pos + speed_offset + eX * (peak_offset_x - peak_size_x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3988                         }
3989
3990                         //top speed
3991                         tmp_offset_y = panel_size_y * 0.4;
3992                         tmp_size_x = panel_size_x * (1 - 0.75);
3993                         tmp_size_y = (panel_size_y - tmp_offset_y) * text_scale;
3994                         tmp_offset_y += (panel_size_y - tmp_offset_y - tmp_size_y) / 2;
3995                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
3996                 }
3997                 else
3998                         top_speed = 0;
3999         }
4000
4001         //draw acceleration
4002         if(acceleration)
4003         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4004         {
4005                 vector progressbar_color;
4006                 if(acceleration < 0)
4007                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4008                 else
4009                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4010
4011                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4012                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4013                         f = sqrt(f);
4014
4015                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4016                 {
4017                         tmp_size = acceleration_progressbar_scale * panel_size_x * eX + panel_size_y * eY;
4018
4019                         if (acceleration_baralign == 1)
4020                                 tmp_offset_x = panel_size_x - tmp_size_x;
4021                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4022                                 tmp_offset_x = (panel_size_x - tmp_size_x) / 2;
4023                         else
4024                                 tmp_offset_x = 0;
4025                         tmp_offset_y = 0;
4026                 }
4027                 else
4028                 {
4029                         tmp_size = panel_size;
4030                         tmp_offset = '0 0 0';
4031                 }
4032
4033                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4034         }
4035         tmp_size_x = panel_size_x;
4036         tmp_size_y = panel_size_y * text_scale;
4037         tmp_offset_x = 0;
4038         tmp_offset_y = (panel_size_y - tmp_size_y) / 2;
4039         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4040                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(acceleration, 2), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4041
4042         draw_endBoldFont();
4043 }
4044
4045 // CenterPrint (#16)
4046 //
4047 #define CENTERPRINT_MAX_MSGS 10
4048 #define CENTERPRINT_MAX_ENTRIES 50
4049 #define CENTERPRINT_SPACING 0.7
4050 float cpm_index;
4051 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4052 float centerprint_msgID[CENTERPRINT_MAX_MSGS];
4053 float centerprint_time[CENTERPRINT_MAX_MSGS];
4054 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4055 float centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4056 float centerprint_showing;
4057
4058 void centerprint_generic(float new_id, string strMessage, float duration, float countdown_num)
4059 {
4060         //print(sprintf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num));
4061         float i, j;
4062
4063         if(strMessage == "" && new_id == 0)
4064                 return;
4065
4066         // strip trailing newlines
4067         j = strlen(strMessage) - 1;
4068         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4069                 --j;
4070         if (j < strlen(strMessage) - 1)
4071                 strMessage = substring(strMessage, 0, j + 1);
4072
4073         if(strMessage == "" && new_id == 0)
4074                 return;
4075
4076         // strip leading newlines
4077         j = 0;
4078         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4079                 ++j;
4080         if (j > 0)
4081                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4082
4083         if(strMessage == "" && new_id == 0)
4084                 return;
4085
4086         if (!centerprint_showing)
4087                 centerprint_showing = TRUE;
4088
4089         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4090         {
4091                 if (j == CENTERPRINT_MAX_MSGS)
4092                         j = 0;
4093                 if (new_id && new_id == centerprint_msgID[j])
4094                 {
4095                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4096                         {
4097                                 // fade out the current msg (duration and countdown_num are ignored)
4098                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4099                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4100                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4101                                 return;
4102                         }
4103                         break; // found a msg with the same id, at position j
4104                 }
4105         }
4106
4107         if (i == CENTERPRINT_MAX_MSGS)
4108         {
4109                 // a msg with the same id was not found, add the msg at the next position
4110                 --cpm_index;
4111                 if (cpm_index == -1)
4112                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4113                 j = cpm_index;
4114         }
4115         if(centerprint_messages[j])
4116                 strunzone(centerprint_messages[j]);
4117         centerprint_messages[j] = strzone(strMessage);
4118         centerprint_msgID[j] = new_id;
4119         if (duration < 0)
4120         {
4121                 centerprint_time[j] = -1;
4122                 centerprint_expire_time[j] = time;
4123         }
4124         else
4125         {
4126                 if(duration == 0)
4127                         duration = max(1, autocvar_hud_panel_centerprint_time);
4128                 centerprint_time[j] = duration;
4129                 centerprint_expire_time[j] = time + duration;
4130         }
4131         centerprint_countdown_num[j] = countdown_num;
4132 }
4133
4134 void centerprint_hud(string strMessage)
4135 {
4136         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4137 }
4138
4139 void reset_centerprint_messages(void)
4140 {
4141         float i;
4142         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4143         {
4144                 centerprint_expire_time[i] = 0;
4145                 centerprint_time[i] = 1;
4146                 centerprint_msgID[i] = 0;
4147                 if(centerprint_messages[i])
4148                         strunzone(centerprint_messages[i]);
4149                 centerprint_messages[i] = string_null;
4150         }
4151 }
4152 float hud_configure_cp_generation_time;
4153 void HUD_CenterPrint (void)
4154 {
4155         if(!autocvar__hud_configure)
4156         {
4157                 if(!autocvar_hud_panel_centerprint) return;
4158
4159                 if (hud_configure_prev && hud_configure_prev != -1)
4160                         reset_centerprint_messages();
4161         }
4162         else
4163         {
4164                 if (!hud_configure_prev)
4165                         reset_centerprint_messages();
4166                 if (time > hud_configure_cp_generation_time)
4167                 {
4168                         float r;
4169                         r = random();
4170                         if (r > 0.9)
4171                                 centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: %d"), 1, 10);
4172                         else if (r > 0.8)
4173                                 centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4174                         else
4175                                 centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4176                         hud_configure_cp_generation_time = time + 1 + random()*4;
4177                 }
4178         }
4179
4180         HUD_Panel_UpdateCvars();
4181
4182         // this panel doesn't fade when showing the scoreboard
4183         if(autocvar__menu_alpha)
4184                 HUD_Panel_ApplyFadeAlpha();
4185
4186         if(scoreboard_fade_alpha)
4187         {
4188                 // move the panel below the scoreboard
4189                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4190                         return;
4191                 vector target_pos;
4192
4193                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
4194
4195                 if(target_pos_y > panel_pos_y)
4196                 {
4197                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4198                         panel_size_y = min(panel_size_y, vid_conheight - scoreboard_bottom);
4199                 }
4200         }
4201
4202         HUD_Panel_DrawBg(1);
4203
4204         if (!centerprint_showing)
4205                 return;
4206
4207         if(panel_bg_padding)
4208         {
4209                 panel_pos += '1 1 0' * panel_bg_padding;
4210                 panel_size -= '2 2 0' * panel_bg_padding;
4211         }
4212
4213         float entries, height;
4214         vector fontsize;
4215         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4216         // height = panel_size_y/entries;
4217         // fontsize = '1 1 0' * height;
4218         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4219         fontsize = '1 1 0' * height;
4220         entries = bound(1, floor(panel_size_y/height), CENTERPRINT_MAX_ENTRIES);
4221
4222         float i, j, k, n, g;
4223         float a, sz, align, current_msg_pos_y = 0, msg_size;
4224         vector pos;
4225         string ts;
4226
4227         n = -1; // if no msg will be displayed, n stays -1
4228
4229         pos = panel_pos;
4230         if (autocvar_hud_panel_centerprint_flip)
4231                 pos_y += panel_size_y;
4232         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4233         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4234         {
4235                 if (j == CENTERPRINT_MAX_MSGS)
4236                         j = 0;
4237                 if (centerprint_expire_time[j] <= time)
4238                 {
4239                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4240                         {
4241                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4242                                 if (centerprint_countdown_num[j] == 0)
4243                                         continue;
4244                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4245                         }
4246                         else if(centerprint_time[j] != -1)
4247                                 continue;
4248                 }
4249
4250
4251                 // fade the centerprint_hud in/out
4252                 if(centerprint_time[j] < 0)
4253                         a = bound(0, (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in), 1);
4254                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)
4255                         a = bound(0, (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in), 1);
4256                 else if(centerprint_expire_time[j] > time)
4257                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4258                 else
4259                         a = 0;
4260
4261                 // set the size from fading in/out before subsequent fading
4262                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4263
4264                 // also fade it based on positioning
4265                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4266                 {
4267                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4268                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4269                 }
4270
4271                 // finally set the size based on the new theAlpha from subsequent fading
4272                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4273                 drawfontscale = sz * '1 1 0';
4274
4275                 if (centerprint_countdown_num[j])
4276                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4277                 else
4278                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4279
4280                 if (autocvar_hud_panel_centerprint_flip)
4281                 {
4282                         // check if the message can be entirely shown
4283                         for(k = 0; k < n; ++k)
4284                         {
4285                                 getWrappedLine_remaining = argv(k);
4286                                 while(getWrappedLine_remaining)
4287                                 {
4288                                         ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4289                                         if (ts != "")
4290                                                 pos_y -= fontsize_y;
4291                                         else
4292                                                 pos_y -= fontsize_y * CENTERPRINT_SPACING/2;
4293                                 }
4294                         }
4295                         current_msg_pos_y = pos_y; // save starting pos (first line) of the current message
4296                 }
4297
4298                 msg_size = pos_y;
4299                 for(k = 0; k < n; ++k)
4300                 {
4301                         getWrappedLine_remaining = argv(k);
4302                         while(getWrappedLine_remaining)
4303                         {
4304                                 ts = getWrappedLine(panel_size_x * sz, fontsize, stringwidth_colors);
4305                                 if (ts != "")
4306                                 {
4307                                         if (align)
4308                                                 pos_x = panel_pos_x + (panel_size_x - stringwidth(ts, TRUE, fontsize)) * align;
4309                                         drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize_y, ts, fontsize, a * panel_fg_alpha, DRAWFLAG_NORMAL);
4310                                         pos_y += fontsize_y;
4311                                 }
4312                                 else
4313                                         pos_y += fontsize_y * CENTERPRINT_SPACING/2;
4314                         }
4315                 }
4316
4317                 ++g; // move next position number up
4318
4319                 msg_size = pos_y - msg_size;
4320                 if (autocvar_hud_panel_centerprint_flip)
4321                 {
4322                         pos_y = current_msg_pos_y - CENTERPRINT_SPACING * fontsize_y;
4323                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4324                                 pos_y += (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4325
4326                         if (pos_y < panel_pos_y) // check if the next message can be shown
4327                         {
4328                                 drawfontscale = '1 1 0';
4329                                 return;
4330                         }
4331                 }
4332                 else
4333                 {
4334                         pos_y += CENTERPRINT_SPACING * fontsize_y;
4335                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4336                                 pos_y -= (msg_size + CENTERPRINT_SPACING * fontsize_y) * (1 - sqrt(sz));
4337
4338                         if(pos_y > panel_pos_y + panel_size_y - fontsize_y) // check if the next message can be shown
4339                         {
4340                                 drawfontscale = '1 1 0';
4341                                 return;
4342                         }
4343                 }
4344         }
4345         drawfontscale = '1 1 0';
4346         if (n == -1)
4347         {
4348                 centerprint_showing = FALSE;
4349                 reset_centerprint_messages();
4350         }
4351 }
4352
4353 /*
4354 ==================
4355 Main HUD system
4356 ==================
4357 */
4358
4359 void HUD_Reset (void)
4360 {
4361         // reset gametype specific icons
4362         if(gametype == MAPINFO_TYPE_KEYHUNT)
4363                 HUD_Mod_KH_Reset();
4364         else if(gametype == MAPINFO_TYPE_CTF)
4365                 HUD_Mod_CTF_Reset();
4366 }
4367
4368 void HUD_Main (void)
4369 {
4370         float i;
4371         // global hud theAlpha fade
4372         if(menu_enabled == 1)
4373                 hud_fade_alpha = 1;
4374         else
4375                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4376
4377         if(scoreboard_fade_alpha)
4378                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4379
4380         HUD_Configure_Frame();
4381
4382         if(intermission == 2) // no hud during mapvote
4383                 hud_fade_alpha = 0;
4384         else if(autocvar__menu_alpha == 0 && scoreboard_fade_alpha == 0)
4385                 hud_fade_alpha = 1;
4386
4387         // panels that we want to be active together with the scoreboard
4388         // they must call HUD_Panel_ApplyFadeAlpha(); only when showing the menu
4389         if(scoreboard_fade_alpha == 1)
4390         {
4391                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4392                 return;
4393         }
4394
4395         if(!autocvar__hud_configure && !hud_fade_alpha)
4396                 return;
4397
4398         // Drawing stuff
4399         if (hud_skin_prev != autocvar_hud_skin)
4400         {
4401                 if (hud_skin_path)
4402                         strunzone(hud_skin_path);
4403                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4404                 if (hud_skin_prev)
4405                         strunzone(hud_skin_prev);
4406                 hud_skin_prev = strzone(autocvar_hud_skin);
4407         }
4408
4409 #ifdef COMPAT_XON050_ENGINE
4410     current_player = (spectatee_status > 0) ? spectatee_status : player_localentnum;
4411 #else
4412     current_player = player_localentnum;
4413 #endif
4414
4415         // draw the dock
4416         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4417         {
4418                 float f;
4419                 vector color;
4420                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4421                 if((teamplay) && hud_dock_color_team) {
4422                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4423                                 color = '1 0 0' * hud_dock_color_team;
4424                         else
4425                                 color = myteamcolors * hud_dock_color_team;
4426                 }
4427                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4428                         color = '1 0 0' * hud_dock_color_team;
4429                 }
4430                 else
4431                 {
4432                         string hud_dock_color = autocvar_hud_dock_color;
4433                         if(hud_dock_color == "shirt") {
4434                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4435                                 color = colormapPaletteColor(floor(f / 16), 0);
4436                         }
4437                         else if(hud_dock_color == "pants") {
4438                                 f = stof(getplayerkeyvalue(current_player - 1, "colors"));
4439                                 color = colormapPaletteColor(mod(f, 16), 1);
4440                         }
4441                         else
4442                                 color = stov(hud_dock_color);
4443                 }
4444
4445                 string pic;
4446                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4447                 if(precache_pic(pic) == "") {
4448                         pic = strcat(hud_skin_path, "/dock_medium");
4449                         if(precache_pic(pic) == "") {
4450                                 pic = "gfx/hud/default/dock_medium";
4451                         }
4452                 }
4453                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4454         }
4455
4456         // cache the panel order into the panel_order array
4457         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4458                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4459                         panel_order[i] = -1;
4460                 string s = "";
4461                 float p_num, warning = false;
4462                 float argc = tokenize_console(autocvar__hud_panelorder);
4463                 if (argc > HUD_PANEL_NUM)
4464                         warning = true;
4465                 //first detect wrong/missing panel numbers
4466                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4467                         p_num = stof(argv(i));
4468                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4469                                 if (panel_order[p_num] == -1) //found for the first time?
4470                                         s = strcat(s, ftos(p_num), " ");
4471                                 panel_order[p_num] = 1; //mark as found
4472                         }
4473                         else
4474                                 warning = true;
4475                 }
4476                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4477                         if (panel_order[i] == -1) {
4478                                 warning = true;
4479                                 s = strcat(s, ftos(i), " "); //add missing panel number
4480                         }
4481                 }
4482                 if (warning)
4483                         print(_("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n"));
4484
4485                 cvar_set("_hud_panelorder", s);
4486                 if(hud_panelorder_prev)
4487                         strunzone(hud_panelorder_prev);
4488                 hud_panelorder_prev = strzone(s);
4489
4490                 //now properly set panel_order
4491                 tokenize_console(s);
4492                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4493                         panel_order[i] = stof(argv(i));
4494                 }
4495         }
4496
4497         hud_draw_maximized = 0;
4498         // draw panels in order specified by panel_order array
4499         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4500                 (panel = hud_panel[panel_order[i]]).panel_draw();
4501
4502         hud_draw_maximized = 1; // panels that may be maximized must check this var
4503         // draw maximized panels on top
4504         if(hud_panel_radar_maximized)
4505                 (panel = HUD_PANEL(RADAR)).panel_draw();
4506         if(autocvar__con_chat_maximized)
4507                 (panel = HUD_PANEL(CHAT)).panel_draw();
4508
4509         HUD_Configure_PostDraw();
4510
4511         hud_configure_prev = autocvar__hud_configure;
4512 }